wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (require 'mime-view)
  32 (require 'mime-edit)
  33 (require 'mime-play)
  34 (require 'elmo)
  35 (require 'wl-vars)
  36 (eval-when-compile (require 'cl))
  37
  38 ;;; Draft
  39
  40 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  41
  42 (defalias 'wl-draft-decode-message-in-buffer
  43   'mime-edit-decode-message-in-buffer)
  44
  45 (defun wl-draft-yank-current-message-entity ()
  46   "Yank currently displayed message entity.
  47 By setting following-method as yank-content.
  48
  49 If region is active, yank region contents instead. \(this feature is available
  50 if and only if `transient-mark-mode' \(GNU Emacs\) or `zmacs-regions' \(XEmacs\)
  51 has Non-nil value\)"
  52   (let ((wl-draft-buffer (current-buffer))
  53         (mime-view-following-method-alist
  54          (list (cons 'wl-original-message-mode
  55                      (function wl-draft-yank-to-draft-buffer))))
  56         (mime-preview-following-method-alist
  57          (list (cons 'wl-original-message-mode
  58                      (function wl-draft-yank-to-draft-buffer))))
  59         (message-buffer (wl-current-message-buffer)))
  60     (if message-buffer
  61         (save-excursion
  62           (set-buffer message-buffer)
  63           (save-restriction
  64             (widen)
  65             (cond
  66              ((wl-region-exists-p)
  67               (wl-mime-preview-follow-current-region))
  68              ((not (wl-message-mime-analysis-p
  69                     (wl-message-buffer-display-type)))
  70               (wl-mime-preview-follow-no-mime
  71                (wl-message-buffer-display-type)))
  72              (t
  73               (mime-preview-follow-current-entity)))))
  74       (error "No message."))))
  75
  76 ;; modified mime-preview-follow-current-entity from mime-view.el
  77 (defun wl-mime-preview-follow-no-mime (display-type)
  78   "Write follow message to current message, without mime.
  79 It calls following-method selected from variable
  80 `mime-preview-following-method-alist'."
  81   (interactive)
  82   (let* ((mode (mime-preview-original-major-mode 'recursive))
  83          (new-name (format "%s-no-mime" (buffer-name)))
  84          new-buf min beg end
  85          (entity (get-text-property (point-min) 'elmo-as-is-entity))
  86          (the-buf (current-buffer))
  87          fields)
  88     (save-excursion
  89       (goto-char (point-min))
  90       (setq min (point-min)
  91             beg (re-search-forward "^$" nil t)
  92             end (point-max)))
  93     (save-excursion
  94       (set-buffer (setq new-buf (get-buffer-create new-name)))
  95       (erase-buffer)
  96       (insert-buffer-substring the-buf beg end)
  97       (goto-char (point-min))
  98       ;; Insert all headers.
  99       (let ((elmo-mime-display-header-analysis
 100              (wl-message-mime-analysis-p display-type 'header)))
 101         (elmo-mime-insert-sorted-header entity))
 102       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 103         (if (functionp f)
 104             (funcall f new-buf)
 105           (message
 106            "Sorry, following method for %s is not implemented yet."
 107            mode))))))
 108
 109 ;; modified mime-preview-follow-current-entity from mime-view.el
 110 (defun wl-mime-preview-follow-current-region ()
 111   "Write follow message to current region.
 112 It calls following-method selected from variable
 113 `mime-preview-following-method-alist'."
 114   (interactive)
 115   (let ((r-beg (region-beginning))
 116         (r-end (region-end))
 117         (entity (get-text-property (point-min)
 118                                    'mime-view-entity)))
 119     (let* ((mode (mime-preview-original-major-mode 'recursive))
 120            (new-name
 121             (format "%s-active-region" (buffer-name)))
 122            new-buf
 123            (the-buf (current-buffer))
 124            fields)
 125       (save-excursion
 126         (set-buffer (setq new-buf (get-buffer-create new-name)))
 127         (erase-buffer)
 128         (insert ?\n)
 129         (insert-buffer-substring the-buf r-beg r-end)
 130         (goto-char (point-min))
 131         (let ((current-entity
 132                (if (and entity
 133                         (eq (mime-entity-media-type entity) 'message)
 134                         (eq (mime-entity-media-subtype entity) 'rfc822))
 135                    (car (mime-entity-children entity))
 136                  entity)))
 137           (while (and current-entity
 138                       (if (and (eq (mime-entity-media-type
 139                                     current-entity) 'message)
 140                                (eq (mime-entity-media-subtype
 141                                     current-entity) 'rfc822))
 142                           nil
 143                         (mime-insert-header current-entity fields)
 144                         t))
 145             (setq fields (std11-collect-field-names)
 146                   current-entity (mime-entity-parent current-entity))))
 147         (let ((rest mime-view-following-required-fields-list)
 148               field-name ret)
 149           (while rest
 150             (setq field-name (car rest))
 151             (or (std11-field-body field-name)
 152                 (progn
 153                   (save-excursion
 154                     (set-buffer the-buf)
 155                     (let ((entity (when mime-mother-buffer
 156                                     (set-buffer mime-mother-buffer)
 157                                     (get-text-property (point)
 158                                                        'mime-view-entity))))
 159                       (while (and entity
 160                                   (null (setq ret (mime-entity-fetch-field
 161                                                    entity field-name))))
 162                         (setq entity (mime-entity-parent entity)))))
 163                   (if ret
 164                       (insert (concat field-name ": " ret "\n")))))
 165             (setq rest (cdr rest)))))
 166       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 167         (if (functionp f)
 168             (funcall f new-buf)
 169           (message
 170            "Sorry, following method for %s is not implemented yet."
 171            mode))))))
 172
 173 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
 174
 175 (defun wl-draft-preview-attributes-list ()
 176   (if (listp (car wl-draft-preview-attributes-list))
 177       (elmo-uniq-list
 178        (nconc (and (wl-message-mail-p)
 179                    (copy-sequence
 180                     (cdr (assq 'mail wl-draft-preview-attributes-list))))
 181               (and (wl-message-news-p)
 182                    (copy-sequence
 183                     (cdr (assq 'news wl-draft-preview-attributes-list))))))
 184     wl-draft-preview-attributes-list))
 185
 186 (defun wl-draft-show-attributes-buffer (attribute-values)
 187   (let* ((cur-win (selected-window))
 188          (size (min
 189                 (- (window-height cur-win)
 190                    window-min-height 1)
 191                 (- (window-height cur-win)
 192                    (max
 193                     window-min-height
 194                     (1+ wl-draft-preview-attributes-buffer-lines))))))
 195     (split-window cur-win (if (> size 0) size window-min-height))
 196     (select-window (next-window))
 197     (let ((pop-up-windows nil))
 198       (switch-to-buffer (get-buffer-create
 199                          wl-draft-preview-attributes-buffer-name)))
 200     (with-current-buffer
 201         (get-buffer wl-draft-preview-attributes-buffer-name)
 202       (setq buffer-read-only t)
 203       (let (buffer-read-only)
 204         (erase-buffer)
 205         (dolist (pair attribute-values)
 206           (insert (capitalize (symbol-name (car pair))) ": "
 207                   (format "%s" (or (cdr pair) ""))
 208                   "\n"))
 209         (goto-char (point-min))
 210         (wl-highlight-headers)))
 211     (select-window cur-win)))
 212
 213 (defun wl-draft-hide-attributes-buffer ()
 214   (let (window buffer)
 215     (when (setq window (get-buffer-window
 216                         wl-draft-preview-attributes-buffer-name))
 217       (select-window window)
 218       (delete-window))
 219     (when (setq buffer (get-buffer wl-draft-preview-attributes-buffer-name))
 220       (kill-buffer buffer))))
 221
 222 (defun wl-draft-attribute-recipients ()
 223   (let (wl-draft-remove-group-list-contents)
 224     (mapconcat
 225      'identity
 226      (nconc
 227       (wl-draft-deduce-address-list
 228        (current-buffer)
 229        (point-min)
 230        (save-excursion
 231          (goto-char (point-min))
 232          (re-search-forward
 233           (concat
 234            "^"
 235            (regexp-quote mail-header-separator)
 236            "$")
 237           nil t)
 238          (point)))
 239       (wl-draft-parse-mailbox-list wl-draft-mime-bcc-field-name))
 240      ", ")))
 241
 242 (defun wl-draft-attribute-envelope-from ()
 243   (or wl-envelope-from
 244       (wl-address-header-extract-address wl-from)))
 245
 246 (defun wl-draft-attribute-smtp-posting-server ()
 247   (or wl-smtp-posting-server
 248       (progn (require 'smtp) smtp-server)
 249       "localhost"))
 250
 251 (defun wl-draft-attribute-smtp-posting-port ()
 252   (or wl-smtp-posting-port
 253       (progn (require 'smtp) smtp-service)))
 254
 255 (defun wl-draft-attribute-newsgroups ()
 256   (std11-field-body "Newsgroups"))
 257
 258 (defun wl-draft-nntp-attribute (attribute &optional alternatives)
 259   (let ((config (cdr (elmo-string-matched-assoc
 260                       (std11-field-body "newsgroups")
 261                       wl-nntp-posting-config-alist)))
 262         entry)
 263     (when (stringp config)
 264       (setq config (list (cons 'server config))))
 265     (if (setq entry (assq attribute config))
 266         ;; maybe nil
 267         (cdr entry)
 268       (let (value)
 269         (while alternatives
 270           (if (setq value (symbol-value (car alternatives)))
 271               (setq alternatives nil)
 272             (setq alternatives (cdr alternatives))))
 273         value))))
 274
 275 (defun wl-draft-attribute-nntp-posting-server ()
 276   (wl-draft-nntp-attribute
 277    'server
 278    '(wl-nntp-posting-server elmo-nntp-default-server)))
 279
 280 (defun wl-draft-attribute-nntp-posting-port ()
 281   (wl-draft-nntp-attribute
 282    'port
 283    '(wl-nntp-posting-port elmo-nntp-default-port)))
 284
 285 (defun wl-draft-attribute-value (attr)
 286   (let ((name (symbol-name attr))
 287         fsymbol symbol)
 288     (cond ((and (setq fsymbol (intern-soft
 289                                (format "wl-draft-attribute-%s" name)))
 290                 (fboundp fsymbol))
 291            (funcall fsymbol))
 292           ((and (setq symbol (intern-soft (format "wl-%s" name)))
 293                 (boundp symbol))
 294            (symbol-value symbol))
 295           ((boundp attr)
 296            (symbol-value attr)))))
 297
 298 (defun wl-mime-quit-preview ()
 299   "Quitting method for mime-view."
 300   (let* ((temp (and (boundp 'mime-edit-temp-message-buffer) ;; for SEMI <= 1.14.6
 301                     mime-edit-temp-message-buffer))
 302          (window (selected-window))
 303          buf)
 304     (mime-preview-kill-buffer)
 305     (set-buffer temp)
 306     (setq buf mime-edit-buffer)
 307     (kill-buffer temp)
 308     (select-window window)
 309     (switch-to-buffer buf)))
 310
 311 (defun wl-draft-preview-message ()
 312   "Preview editing message."
 313   (interactive)
 314   (let* (attribute-values
 315          (orig-buffer (current-buffer))
 316          (current-point (point))
 317          (config-exec-flag wl-draft-config-exec-flag)
 318          (parent-folder wl-draft-parent-folder)
 319          (mime-display-header-hook 'wl-highlight-headers)
 320          (mime-header-encode-method-alist
 321           (append
 322            '((wl-draft-eword-encode-address-list
 323               .  (To Cc Bcc Resent-To Resent-Cc Resent-Bcc From)))
 324            (if (boundp 'mime-header-encode-method-alist)
 325                (symbol-value 'mime-header-encode-method-alist))))
 326          mime-view-ignored-field-list   ; all header.
 327          (mime-edit-translate-buffer-hook
 328           (cons
 329            (lambda ()
 330              (let ((wl-draft-config-exec-flag config-exec-flag)
 331                    (wl-draft-parent-folder parent-folder)
 332                    (copy-buffer (current-buffer)))
 333                (wl-copy-local-variables
 334                 orig-buffer
 335                 copy-buffer
 336                 (with-current-buffer orig-buffer
 337                   (append wl-draft-config-variables
 338                           (wl-draft-clone-local-variables))))
 339                (goto-char current-point)
 340                (run-hooks 'wl-draft-send-hook)
 341                (condition-case err
 342                    (setq attribute-values
 343                          (mapcar
 344                           (lambda (attr)
 345                             (cons attr (wl-draft-attribute-value attr)))
 346                           (if wl-draft-preview-attributes
 347                               (wl-draft-preview-attributes-list)
 348                             '(recipients))))
 349                  (error
 350                   (kill-buffer (current-buffer))
 351                   (signal (car err) (cdr err))))))
 352            mime-edit-translate-buffer-hook)))
 353     (mime-edit-preview-message)
 354     (make-local-variable 'mime-preview-quitting-method-alist)
 355     (setq mime-preview-quitting-method-alist
 356           '((mime-temp-message-mode . wl-mime-quit-preview)))
 357     (let ((buffer-read-only nil))
 358       (when wl-highlight-body-too
 359         (wl-highlight-body))
 360       (run-hooks 'wl-draft-preview-message-hook))
 361     (make-local-hook 'kill-buffer-hook)
 362     (add-hook 'kill-buffer-hook #'wl-draft-hide-attributes-buffer nil t)
 363     (if wl-draft-preview-attributes
 364         (ignore-errors ; in case when the window is too small
 365          (wl-draft-show-attributes-buffer attribute-values))
 366       (message (concat "Recipients: "
 367                        (cdr (assq 'recipients attribute-values)))))))
 368
 369 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 370
 371 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 372
 373 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 374
 375 ;;; Message
 376
 377 (defun wl-message-decode-mode (outbuf inbuf)
 378   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 379         (mime-display-header-hook 'wl-highlight-headers))
 380     (mime-view-mode nil nil nil inbuf outbuf)))
 381
 382 (defun wl-message-decode-with-all-header (outbuf inbuf)
 383   (let ((mime-view-ignored-field-regexp "^:$")
 384         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 385         (mime-display-header-hook 'wl-highlight-headers)
 386         mime-view-ignored-field-list)
 387     (mime-view-mode nil nil nil inbuf outbuf)))
 388
 389 (defun wl-message-delete-popup-windows ()
 390   (dolist (buffer wl-message-popup-buffers)
 391     (when (or (stringp buffer)
 392               (and (symbolp buffer)
 393                    (boundp buffer)
 394                    (setq buffer (symbol-value buffer))))
 395       (let ((window (get-buffer-window buffer)))
 396         (when window
 397           (delete-window window))))))
 398
 399 (defun wl-message-request-partial (folder number)
 400   (elmo-set-work-buf
 401    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 402                        number
 403                        (elmo-make-fetch-strategy 'entire)
 404                        'unread)
 405    (mime-parse-buffer nil)))
 406
 407 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 408 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 409 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 410 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 411 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 412 (defalias 'wl-message-quit              'mime-preview-quit)
 413 (defalias 'wl-message-button-dispatcher-internal
 414   'mime-button-dispatcher)
 415
 416 (defsubst wl-mime-node-id-to-string (node-id)
 417   (if (consp node-id)
 418       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 419                  (reverse node-id)
 420                  ".")
 421     "0"))
 422
 423 (defun wl-message-delete-current-part ()
 424   "Delete a part under the cursor from the multipart message."
 425   (interactive)
 426   (save-restriction
 427     (widen)
 428     (let* ((entity (get-text-property (point) 'mime-view-entity))
 429            (node-id (mime-entity-node-id entity))
 430            (filename (mime-entity-safe-filename entity))
 431            (header-start (mime-buffer-entity-header-start-internal entity))
 432            (body-end (mime-buffer-entity-body-end-internal entity))
 433            (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 434            (number wl-message-buffer-cur-number)
 435            (msgid (elmo-message-field folder number 'message-id))
 436            (orig-buf wl-message-buffer-original-buffer))
 437       (if (eq (luna-class-name entity) 'mime-elmo-imap-entity)
 438           (error "Please fetch the entire message (by typing 'C-u .') and try again"))
 439       (with-current-buffer orig-buf
 440         (unless (string-equal
 441                  (buffer-string)
 442                  (elmo-message-fetch-string
 443                   folder number
 444                   (elmo-make-fetch-strategy 'entire)))
 445           (error "Buffer content differs from actual message")))
 446       (when (and (elmo-folder-writable-p folder)
 447                  (buffer-live-p orig-buf)
 448                  node-id
 449                  (yes-or-no-p
 450                   (format "Do you really want to delete part %s? "
 451                           (wl-mime-node-id-to-string node-id))))
 452         (when (with-temp-buffer
 453                 (insert-buffer orig-buf)
 454                 (delete-region header-start body-end)
 455                 (goto-char header-start)
 456                 (insert "Content-Type: text/plain; charset=US-ASCII\n")
 457                 (when filename
 458                   (insert
 459                    "Content-Disposition:"
 460                    (mime-encode-field-body
 461                          (concat ""
 462                                  (and filename
 463                                       (concat " inline; filename=" (std11-wrap-as-quoted-string filename))))
 464                          "Content-Disposition")
 465                    "\n"))
 466                 (insert "\n")
 467                 (insert "** This part has been removed by Wanderlust **\n\n")
 468                 (elmo-folder-append-buffer folder))
 469
 470           (elmo-folder-move-messages
 471            folder (list number)
 472            (wl-folder-get-elmo-folder wl-trash-folder))
 473           (when (and (elmo-cache-get-path msgid)
 474                      (file-exists-p (elmo-cache-get-path msgid)))
 475             (delete-file (elmo-cache-get-path msgid)))
 476
 477           (mime-preview-quit)
 478           (wl-summary-delete-messages-on-buffer (list number))
 479           (wl-summary-toggle-disp-msg 'off)
 480           (setq wl-message-buffer nil)
 481           (wl-summary-sync nil "update"))))))
 482
 483 ;; PGP
 484 (eval-when-compile
 485   (defmacro wl-define-dummy-functions (&rest symbols)
 486     `(dolist (symbol (quote ,symbols))
 487        (defalias symbol 'ignore)))
 488
 489   (condition-case nil
 490       (require 'epa)
 491     (error
 492      (wl-define-dummy-functions epg-make-context
 493                                 epg-decrypt-string
 494                                 epg-verify-string
 495                                 epg-context-set-progress-callback
 496                                 epg-context-result-for
 497                                 epg-verify-result-to-string
 498                                 epa-display-info)))
 499   (condition-case nil
 500       (require 'pgg)
 501     (error
 502      (wl-define-dummy-functions pgg-decrypt-region
 503                                 pgg-verify-region
 504                                 pgg-display-output-buffer))))
 505
 506 (defun wl-epg-progress-callback (context what char current total reporter)
 507   (let ((label (elmo-progress-counter-label reporter)))
 508     (when label
 509       (elmo-progress-notify label :set current :total total))))
 510
 511 (defun wl-mime-pgp-decrypt-region-with-epg (beg end &optional no-decode)
 512   (require 'epg)
 513   (let ((context (epg-make-context)))
 514     (elmo-with-progress-display (epg-decript nil reporter)
 515         "Decrypting"
 516       (epg-context-set-progress-callback context
 517                                          (cons #'wl-epg-progress-callback
 518                                                reporter))
 519       (insert (prog1
 520                   (decode-coding-string
 521                    (epg-decrypt-string
 522                     context
 523                     (buffer-substring beg end))
 524                    (if no-decode 'raw-text wl-cs-autoconv))
 525                 (delete-region beg end)))))
 526   last-coding-system-used)
 527
 528 (defun wl-mime-pgp-verify-region-with-epg (beg end &optional coding-system)
 529   (require 'epa)
 530   (let ((context (epg-make-context)))
 531     (elmo-with-progress-display (epg-verify nil reporter)
 532         "Verifying"
 533       (epg-context-set-progress-callback context
 534                                          (cons #'wl-epg-progress-callback
 535                                                reporter))
 536       (epg-verify-string
 537        context
 538        (encode-coding-string
 539         (buffer-substring beg end)
 540         (if coding-system
 541             (coding-system-change-eol-conversion coding-system 'dos)
 542           'raw-text-dos))))
 543     (when (epg-context-result-for context 'verify)
 544       (epa-display-info (epg-verify-result-to-string
 545                          (epg-context-result-for context 'verify))))))
 546
 547 (defun wl-mime-pgp-decrypt-region-with-pgg (beg end &optional no-decode)
 548   (require 'pgg)
 549   (let ((buffer-file-coding-system wl-cs-autoconv)
 550         status)
 551     (setq status (pgg-decrypt-region beg end))
 552     (if no-decode
 553         (when status
 554           (delete-region beg end)
 555           (insert-buffer-substring pgg-output-buffer))
 556       (pgg-display-output-buffer beg end status))
 557     (unless status
 558       (error "Decryption is failed"))
 559     last-coding-system-used))
 560
 561 (defun wl-mime-pgp-verify-region-with-pgg (beg end &optional coding-system)
 562   (require 'pgg)
 563   (let ((message-buffer (current-buffer))
 564         success)
 565     (with-temp-buffer
 566       (insert-buffer-substring message-buffer beg end)
 567       (when coding-system
 568         (encode-coding-region (point-min) (point-max) coding-system))
 569       (setq success (pgg-verify-region (point-min) (point-max) nil 'fetch)))
 570     (mime-show-echo-buffer)
 571     (set-buffer mime-echo-buffer-name)
 572     (set-window-start
 573      (get-buffer-window mime-echo-buffer-name)
 574      (point-max))
 575     (insert-buffer-substring
 576      (if success
 577          pgg-output-buffer
 578        pgg-errors-buffer))))
 579
 580 (defsubst wl-mime-pgp-decrypt-region (beg end &optional no-decode)
 581   (case wl-use-pgp-module
 582     (epg
 583      (wl-mime-pgp-decrypt-region-with-epg beg end no-decode))
 584     (pgg
 585      (wl-mime-pgp-decrypt-region-with-pgg beg end no-decode))
 586     (t
 587      (error "Don't support PGP decryption"))))
 588
 589 (defsubst wl-mime-pgp-verify-region (beg end &optional coding-system)
 590   (case wl-use-pgp-module
 591     (epg
 592      (wl-mime-pgp-verify-region-with-epg beg end coding-system))
 593     (pgg
 594      (wl-mime-pgp-verify-region-with-pgg beg end coding-system))
 595     (t
 596      (error "Don't support PGP decryption"))))
 597
 598 (defun wl-message-decrypt-pgp-nonmime ()
 599   "Decrypt PGP encrypted region"
 600   (interactive)
 601   (save-excursion
 602     (beginning-of-line)
 603     (let ((region (wl-find-region "^-+BEGIN PGP MESSAGE-+$"
 604                                   "^-+END PGP MESSAGE-+$"))
 605           (inhibit-read-only t)
 606           coding-system)
 607       (unless region
 608         (error "Cannot find pgp encrypted region"))
 609       (save-restriction
 610         (let ((props (text-properties-at (car region))))
 611           (narrow-to-region (car region) (cdr region))
 612           (when (setq coding-system
 613                       (wl-mime-pgp-decrypt-region (point-min) (point-max)))
 614             (setq props (plist-put props
 615                                    'wl-mime-decoded-coding-system
 616                                    coding-system)))
 617           (set-text-properties (point-min) (point-max) props))))))
 618
 619 (defun wl-message-verify-pgp-nonmime (&optional arg)
 620   "Verify PGP signed region.
 621 With ARG, ask coding system and encode the region with it before verifying."
 622   (interactive "P")
 623   (save-excursion
 624     (beginning-of-line)
 625     (let ((region (wl-find-region "^-+BEGIN PGP SIGNED MESSAGE-+$"
 626                                   "^-+END PGP SIGNATURE-+$"))
 627           coding-system)
 628       (setq coding-system
 629             (or (get-text-property (car region) 'wl-mime-decoded-coding-system)
 630                 (let* ((situation (mime-preview-find-boundary-info))
 631                        (entity (aref situation 2)))
 632                   (mime-charset-to-coding-system
 633                    (mime-content-type-parameter
 634                     (mime-entity-content-type entity)
 635                     "charset")))
 636                 buffer-file-coding-system))
 637       (when arg
 638         (setq coding-system (read-coding-system
 639                              (format "Coding system (%S): " coding-system)
 640                              coding-system)))
 641       (wl-mime-pgp-verify-region (car region) (cdr region) coding-system))))
 642
 643 ;; XXX: encrypted multipart isn't represented as multipart
 644 (defun wl-mime-preview-application/pgp (parent-entity entity situation)
 645   (goto-char (point-max))
 646   (let ((p (point))
 647         raw-buf to-buf representation-type child-entity)
 648     (goto-char p)
 649     (save-restriction
 650       (narrow-to-region p p)
 651       (setq to-buf (current-buffer))
 652       (with-temp-buffer
 653         (setq raw-buf (current-buffer))
 654         (mime-insert-entity entity)
 655         (when (progn
 656                 (goto-char (point-min))
 657                 (re-search-forward "^-+BEGIN PGP MESSAGE-+$" nil t))
 658           (wl-mime-pgp-decrypt-region (point-min) (point-max) 'no-decode)
 659           (setq representation-type 'elmo-buffer))
 660         (setq child-entity (mime-parse-message
 661                             (mm-expand-class-name representation-type)
 662                             nil
 663                             parent-entity
 664                             (mime-entity-node-id-internal parent-entity)))
 665         (mime-display-entity
 666          child-entity
 667          nil
 668          `((header . visible)
 669            (body . visible)
 670            (entity-button . invisible))
 671          to-buf)))))
 672
 673 (defun wl-mime-preview-application/pgp-encrypted (entity situation)
 674   (let* ((entity-node-id (mime-entity-node-id entity))
 675          (mother (mime-entity-parent entity))
 676          (knum (car entity-node-id))
 677          (onum (if (> knum 0)
 678                    (1- knum)
 679                  (1+ knum)))
 680          (orig-entity (nth onum (mime-entity-children mother))))
 681     (wl-mime-preview-application/pgp entity orig-entity situation)))
 682
 683 ;;; Summary
 684 (defun wl-summary-burst-subr (message-entity target number)
 685   ;; returns new number.
 686   (let (content-type entity)
 687     (setq content-type (mime-entity-content-type message-entity))
 688     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 689            (dolist (entity (mime-entity-children message-entity))
 690              (setq number (wl-summary-burst-subr
 691                            entity
 692                            target
 693                            number))))
 694           ((and (eq (cdr (assq 'type content-type)) 'message)
 695                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 696            (message "Bursting...%s" (setq number (+ 1 number)))
 697            (setq entity
 698                  (car (mime-entity-children message-entity)))
 699            (with-temp-buffer
 700              (set-buffer-multibyte nil)
 701              (insert (mime-entity-body message-entity))
 702              (elmo-folder-append-buffer target))))
 703     number))
 704
 705 (defun wl-summary-burst (&optional arg)
 706   "De-capsulate embedded messages in MIME format.
 707 With ARG, ask destination folder."
 708   (interactive "P")
 709   (let ((raw-buf (wl-summary-get-original-buffer))
 710         (view-buf wl-message-buffer)
 711         message-entity target)
 712     (save-excursion
 713       (when (and (null arg)
 714                  (elmo-folder-writable-p wl-summary-buffer-elmo-folder))
 715         (setq target wl-summary-buffer-elmo-folder))
 716       (while (null target)
 717         (let ((name (wl-summary-read-folder wl-default-folder
 718                                             "to extract to")))
 719           (setq target (wl-folder-get-elmo-folder name))
 720           (unless (elmo-folder-writable-p target)
 721             (message "%s is not writable" name)
 722             (setq target nil)
 723             (sit-for 1))))
 724       (wl-summary-set-message-buffer-or-redisplay)
 725       (with-current-buffer view-buf
 726         (setq message-entity
 727               (get-text-property (point-min) 'mime-view-entity)))
 728       (when message-entity
 729         (message "Bursting...")
 730         (with-current-buffer raw-buf
 731           (wl-summary-burst-subr message-entity target 0))
 732         (message "Bursting...done"))
 733       (if (elmo-folder-plugged-p target)
 734           (elmo-folder-check target)))
 735     (when (and target
 736                (string= wl-summary-buffer-folder-name
 737                         (elmo-folder-name-internal target)))
 738       (save-excursion (wl-summary-sync-update)))))
 739
 740 ;; internal variable.
 741 (defvar wl-mime-save-directory nil "Last saved directory.")
 742 ;;; Yet another save method.
 743 (defun wl-mime-save-content (entity situation)
 744   (let ((filename (expand-file-name
 745                    (read-file-name "Save to file: "
 746                                    (expand-file-name
 747                                     (or (mime-entity-safe-filename entity)
 748                                         ".")
 749                                     (or wl-mime-save-directory
 750                                         wl-temporary-file-directory))))))
 751     (while (file-directory-p filename)
 752       (setq filename (read-file-name "Please set filename (not directory): "
 753                                      filename)))
 754     (if (and (file-exists-p filename)
 755              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 756                                        filename))))
 757         (message "Not saved")
 758       (setq wl-mime-save-directory (file-name-directory filename))
 759       (mime-write-entity-content entity filename))))
 760
 761 (defun wl-summary-extract-attachments-1 (message-entity directory number)
 762   ;; returns new number.
 763   (let (children filename)
 764     (cond
 765      ((setq children (mime-entity-children message-entity))
 766       (dolist (entity children)
 767         (setq number
 768               (wl-summary-extract-attachments-1 entity directory number))))
 769      ((and (eq (mime-content-disposition-type
 770                 (mime-entity-content-disposition message-entity))
 771                'attachment)
 772            (setq filename (mime-entity-safe-filename message-entity)))
 773       (let ((full (expand-file-name filename directory)))
 774         (when (or (not (file-exists-p full))
 775                   (yes-or-no-p
 776                    (format "File %s exists. Save anyway? " filename)))
 777           (message "Extracting...%s" (setq number (+ 1 number)))
 778           (mime-write-entity-content message-entity full)))))
 779     number))
 780
 781 (defun wl-summary-extract-attachments (directory)
 782   "Extract attachment parts in MIME format into the DIRECTORY."
 783   (interactive
 784    (let* ((default (or wl-mime-save-directory
 785                        wl-temporary-file-directory))
 786           (directory (read-directory-name "Extract to " default default t)))
 787      (list (if (> (length directory) 0) directory default))))
 788   (unless (and (file-writable-p directory)
 789                (file-directory-p directory))
 790     (error "%s is not writable" directory))
 791   (save-excursion
 792     (wl-summary-set-message-buffer-or-redisplay)
 793     (let ((entity (get-text-property (point-min) 'mime-view-entity)))
 794       (when entity
 795         (message "Extracting...")
 796         (wl-summary-extract-attachments-1 entity directory 0)
 797         (message "Extracting...done")))))
 798
 799 ;;; Yet another combine method.
 800 (defun wl-mime-combine-message/partial-pieces (entity situation)
 801   "Internal method for wl to combine message/partial messages automatically."
 802   (interactive)
 803   (let* ((folder (with-current-buffer wl-message-buffer-cur-summary-buffer
 804                    wl-summary-buffer-elmo-folder))
 805          (mime-display-header-hook 'wl-highlight-headers)
 806          (id (or (cdr (assoc "id" situation)) ""))
 807          (mother (current-buffer))
 808          (summary-buf wl-message-buffer-cur-summary-buffer)
 809          subject-id overviews
 810          (root-dir (expand-file-name
 811                     (concat "m-prts-" (user-login-name))
 812                     temporary-file-directory))
 813          full-file point)
 814     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 815     (setq full-file (concat root-dir "/FULL"))
 816     (if (or (file-exists-p full-file)
 817             (not (y-or-n-p "Merge partials? ")))
 818         (with-current-buffer mother
 819           (mime-store-message/partial-piece entity situation)
 820           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 821           (make-local-variable 'mime-preview-over-to-next-method-alist)
 822           (setq mime-preview-over-to-next-method-alist
 823                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 824                       mime-preview-over-to-next-method-alist))
 825           (make-local-variable 'mime-preview-over-to-previous-method-alist)
 826           (setq mime-preview-over-to-previous-method-alist
 827                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 828                       mime-preview-over-to-previous-method-alist)))
 829       (setq subject-id
 830             (eword-decode-string
 831              (decode-mime-charset-string
 832               (mime-entity-read-field entity 'Subject)
 833               wl-summary-buffer-mime-charset)))
 834       (if (string-match "[0-9\n]+" subject-id)
 835           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 836       (catch 'tag
 837         (elmo-folder-do-each-message-entity (entity folder)
 838           (when (string-match
 839                  (regexp-quote subject-id)
 840                  (elmo-message-entity-field entity 'subject))
 841             (let* ((message
 842                     ;; request message at the cursor in Subject buffer.
 843                     (wl-message-request-partial
 844                      (elmo-folder-name-internal folder)
 845                      (elmo-message-entity-number entity)))
 846                    (situation (mime-entity-situation message))
 847                    (the-id (or (cdr (assoc "id" situation)) "")))
 848               (when (string= (downcase the-id)
 849                              (downcase id))
 850                 (with-current-buffer mother
 851                   (mime-store-message/partial-piece message situation))
 852                 (if (file-exists-p full-file)
 853                     (throw 'tag nil))))))
 854         (message "Not all partials found.")))))
 855
 856 (defun wl-mime-display-text/plain (entity situation)
 857   (let ((beg (point)))
 858     (mime-display-text/plain entity situation)
 859     (wl-highlight-message beg (point-max) t t)))
 860
 861 (defun wl-mime-display-header (entity situation)
 862   (let ((elmo-message-ignored-field-list
 863          (if wl-message-buffer-require-all-header
 864              nil
 865            wl-message-ignored-field-list))
 866         (elmo-message-visible-field-list wl-message-visible-field-list)
 867         (elmo-message-sorted-field-list wl-message-sort-field-list))
 868     (elmo-mime-insert-header entity situation)
 869     (goto-char (point-min))
 870     (delete-matching-lines "^$")
 871     (wl-highlight-headers)))
 872
 873 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 874   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 875         (original-buffer wl-message-buffer-original-buffer))
 876     (mime-decrypt-application/pgp-encrypted entity situation)
 877     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 878     (setq wl-message-buffer-original-buffer original-buffer)))
 879
 880
 881 ;;; Setup methods.
 882 (defun wl-mime-setup ()
 883   (set-alist 'mime-preview-quitting-method-alist
 884              'wl-original-message-mode 'wl-message-exit)
 885   (set-alist 'mime-view-over-to-previous-method-alist
 886              'wl-original-message-mode 'wl-message-exit)
 887   (set-alist 'mime-view-over-to-next-method-alist
 888              'wl-original-message-mode 'wl-message-exit)
 889   (set-alist 'mime-preview-over-to-previous-method-alist
 890              'wl-original-message-mode 'wl-message-exit)
 891   (set-alist 'mime-preview-over-to-next-method-alist
 892              'wl-original-message-mode 'wl-message-exit)
 893   (add-hook 'wl-summary-toggle-disp-off-hook 'wl-message-delete-popup-windows)
 894   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-popup-windows)
 895   (add-hook 'wl-message-exit-hook 'wl-message-delete-popup-windows)
 896
 897   (ctree-set-calist-strictly
 898    'mime-preview-condition
 899    '((type . text) (subtype . plain)
 900      (body . visible)
 901      (body-presentation-method . wl-mime-display-text/plain)
 902      (major-mode . wl-original-message-mode)))
 903
 904   (ctree-set-calist-strictly
 905    'mime-preview-condition
 906    '((type . application)(subtype . pgp-encrypted)
 907      (encoding . t)
 908      (body . invisible)
 909      (body-presentation-method . wl-mime-preview-application/pgp-encrypted)
 910      (major-mode . wl-original-message-mode)))
 911
 912   (ctree-set-calist-strictly
 913    'mime-acting-condition
 914    '((type . message) (subtype . partial)
 915      (method .  wl-mime-combine-message/partial-pieces)
 916      (request-partial-message-method . wl-message-request-partial)
 917      (major-mode . wl-original-message-mode)))
 918
 919   (ctree-set-calist-strictly
 920    'mime-acting-condition
 921    '((type . application) (subtype . pgp-encrypted)
 922      (method . wl-mime-decrypt-application/pgp-encrypted)
 923      (major-mode . wl-original-message-mode)))
 924
 925   (ctree-set-calist-strictly
 926    'mime-acting-condition
 927    '((mode . "extract")
 928      (major-mode . wl-original-message-mode)
 929      (method . wl-mime-save-content)))
 930   (set-alist 'mime-preview-following-method-alist
 931              'wl-original-message-mode
 932              (function wl-message-follow-current-entity))
 933   (set-alist 'mime-view-following-method-alist
 934              'wl-original-message-mode
 935              (function wl-message-follow-current-entity))
 936   (set-alist 'mime-edit-message-inserter-alist
 937              'wl-draft-mode (function wl-draft-insert-current-message))
 938   (set-alist 'mime-edit-mail-inserter-alist
 939              'wl-draft-mode (function wl-draft-insert-get-message))
 940   (set-alist 'mime-edit-split-message-sender-alist
 941              'wl-draft-mode
 942              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 943   (set-alist 'mime-raw-representation-type-alist
 944              'wl-original-message-mode 'binary)
 945   ;; Sort and highlight header fields.
 946   (or wl-message-ignored-field-list
 947       (setq wl-message-ignored-field-list
 948             mime-view-ignored-field-list))
 949   (or wl-message-visible-field-list
 950       (setq wl-message-visible-field-list
 951             mime-view-visible-field-list))
 952   (set-alist 'mime-header-presentation-method-alist
 953              'wl-original-message-mode
 954              'wl-mime-display-header)
 955   ;; To avoid overriding wl-draft-mode-map.
 956   (when (boundp 'mime-setup-signature-key-alist)
 957     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 958       (setq mime-setup-signature-key-alist
 959             (cons '(wl-draft-mode . "\C-c\C-w")
 960                   mime-setup-signature-key-alist)))))
 961
 962 (require 'product)
 963 (product-provide (provide 'wl-mime) (require 'wl-version))
 964
 965 ;;; wl-mime.el ends here