wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (require 'mime-view)
  32 (require 'mime-edit)
  33 (require 'mime-play)
  34 (require 'elmo)
  35 (require 'wl-vars)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'pgg-decrypt-region 'ignore)
  39   (defalias-maybe 'pgg-display-output-buffer 'ignore)
  40   (defalias-maybe 'pgg-verify-region 'ignore))
  41
  42 ;;; Draft
  43
  44 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  45
  46 (defalias 'wl-draft-decode-message-in-buffer
  47   'mime-edit-decode-message-in-buffer)
  48
  49 (defun wl-draft-yank-current-message-entity ()
  50   "Yank currently displayed message entity.
  51 By setting following-method as yank-content.
  52
  53 If region is active, yank region contents instead. \(this feature is available
  54 if and only if `transient-mark-mode' \(GNU Emacs\) or `zmacs-regions' \(XEmacs\)
  55 has Non-nil value\)"
  56   (let ((wl-draft-buffer (current-buffer))
  57         (mime-view-following-method-alist
  58          (list (cons 'wl-original-message-mode
  59                      (function wl-draft-yank-to-draft-buffer))))
  60         (mime-preview-following-method-alist
  61          (list (cons 'wl-original-message-mode
  62                      (function wl-draft-yank-to-draft-buffer))))
  63         (message-buffer (wl-current-message-buffer)))
  64     (if message-buffer
  65         (save-excursion
  66           (set-buffer message-buffer)
  67           (save-restriction
  68             (widen)
  69             (cond
  70              ((wl-region-exists-p)
  71               (wl-mime-preview-follow-current-region))
  72              ((not (wl-message-mime-analysis-p
  73                     (wl-message-buffer-display-type)))
  74               (wl-mime-preview-follow-no-mime
  75                (wl-message-buffer-display-type)))
  76              (t
  77               (mime-preview-follow-current-entity)))))
  78       (error "No message."))))
  79
  80 ;; modified mime-preview-follow-current-entity from mime-view.el
  81 (defun wl-mime-preview-follow-no-mime (display-type)
  82   "Write follow message to current message, without mime.
  83 It calls following-method selected from variable
  84 `mime-preview-following-method-alist'."
  85   (interactive)
  86   (let* ((mode (mime-preview-original-major-mode 'recursive))
  87          (new-name (format "%s-no-mime" (buffer-name)))
  88          new-buf min beg end
  89          (entity (get-text-property (point-min) 'elmo-as-is-entity))
  90          (the-buf (current-buffer))
  91          fields)
  92     (save-excursion
  93       (goto-char (point-min))
  94       (setq min (point-min)
  95             beg (re-search-forward "^$" nil t)
  96             end (point-max)))
  97     (save-excursion
  98       (set-buffer (setq new-buf (get-buffer-create new-name)))
  99       (erase-buffer)
 100       (insert-buffer-substring the-buf beg end)
 101       (goto-char (point-min))
 102       ;; Insert all headers.
 103       (let ((elmo-mime-display-header-analysis
 104              (wl-message-mime-analysis-p display-type 'header)))
 105         (elmo-mime-insert-sorted-header entity))
 106       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 107         (if (functionp f)
 108             (funcall f new-buf)
 109           (message
 110            "Sorry, following method for %s is not implemented yet."
 111            mode))))))
 112
 113 ;; modified mime-preview-follow-current-entity from mime-view.el
 114 (defun wl-mime-preview-follow-current-region ()
 115   "Write follow message to current region.
 116 It calls following-method selected from variable
 117 `mime-preview-following-method-alist'."
 118   (interactive)
 119   (let ((r-beg (region-beginning))
 120         (r-end (region-end))
 121         (entity (get-text-property (point-min)
 122                                    'mime-view-entity)))
 123     (let* ((mode (mime-preview-original-major-mode 'recursive))
 124            (new-name
 125             (format "%s-active-region" (buffer-name)))
 126            new-buf
 127            (the-buf (current-buffer))
 128            fields)
 129       (save-excursion
 130         (set-buffer (setq new-buf (get-buffer-create new-name)))
 131         (erase-buffer)
 132         (insert ?\n)
 133         (insert-buffer-substring the-buf r-beg r-end)
 134         (goto-char (point-min))
 135         (let ((current-entity
 136                (if (and entity
 137                         (eq (mime-entity-media-type entity) 'message)
 138                         (eq (mime-entity-media-subtype entity) 'rfc822))
 139                    (car (mime-entity-children entity))
 140                  entity)))
 141           (while (and current-entity
 142                       (if (and (eq (mime-entity-media-type
 143                                     current-entity) 'message)
 144                                (eq (mime-entity-media-subtype
 145                                     current-entity) 'rfc822))
 146                           nil
 147                         (mime-insert-header current-entity fields)
 148                         t))
 149             (setq fields (std11-collect-field-names)
 150                   current-entity (mime-entity-parent current-entity))))
 151         (let ((rest mime-view-following-required-fields-list)
 152               field-name ret)
 153           (while rest
 154             (setq field-name (car rest))
 155             (or (std11-field-body field-name)
 156                 (progn
 157                   (save-excursion
 158                     (set-buffer the-buf)
 159                     (let ((entity (when mime-mother-buffer
 160                                     (set-buffer mime-mother-buffer)
 161                                     (get-text-property (point)
 162                                                        'mime-view-entity))))
 163                       (while (and entity
 164                                   (null (setq ret (mime-entity-fetch-field
 165                                                    entity field-name))))
 166                         (setq entity (mime-entity-parent entity)))))
 167                   (if ret
 168                       (insert (concat field-name ": " ret "\n")))))
 169             (setq rest (cdr rest)))))
 170       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 171         (if (functionp f)
 172             (funcall f new-buf)
 173           (message
 174            "Sorry, following method for %s is not implemented yet."
 175            mode))))))
 176
 177 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
 178
 179 (defun wl-draft-preview-attributes-list ()
 180   (if (listp (car wl-draft-preview-attributes-list))
 181       (elmo-uniq-list
 182        (nconc (and (wl-message-mail-p)
 183                    (copy-sequence
 184                     (cdr (assq 'mail wl-draft-preview-attributes-list))))
 185               (and (wl-message-news-p)
 186                    (copy-sequence
 187                     (cdr (assq 'news wl-draft-preview-attributes-list))))))
 188     wl-draft-preview-attributes-list))
 189
 190 (defun wl-draft-show-attributes-buffer (attribute-values)
 191   (let* ((cur-win (selected-window))
 192          (size (min
 193                 (- (window-height cur-win)
 194                    window-min-height 1)
 195                 (- (window-height cur-win)
 196                    (max
 197                     window-min-height
 198                     (1+ wl-draft-preview-attributes-buffer-lines))))))
 199     (split-window cur-win (if (> size 0) size window-min-height))
 200     (select-window (next-window))
 201     (let ((pop-up-windows nil))
 202       (switch-to-buffer (get-buffer-create
 203                          wl-draft-preview-attributes-buffer-name)))
 204     (with-current-buffer
 205         (get-buffer wl-draft-preview-attributes-buffer-name)
 206       (setq buffer-read-only t)
 207       (let (buffer-read-only)
 208         (erase-buffer)
 209         (dolist (pair attribute-values)
 210           (insert (capitalize (symbol-name (car pair))) ": "
 211                   (format "%s" (or (cdr pair) ""))
 212                   "\n"))
 213         (goto-char (point-min))
 214         (wl-highlight-headers)))
 215     (select-window cur-win)))
 216
 217 (defun wl-draft-hide-attributes-buffer ()
 218   (let (window buffer)
 219     (when (setq window (get-buffer-window
 220                         wl-draft-preview-attributes-buffer-name))
 221       (select-window window)
 222       (delete-window))
 223     (when (setq buffer (get-buffer wl-draft-preview-attributes-buffer-name))
 224       (kill-buffer buffer))))
 225
 226 (defun wl-draft-attribute-recipients ()
 227   (let (wl-draft-remove-group-list-contents)
 228     (mapconcat
 229      'identity
 230      (nconc
 231       (wl-draft-deduce-address-list
 232        (current-buffer)
 233        (point-min)
 234        (save-excursion
 235          (goto-char (point-min))
 236          (re-search-forward
 237           (concat
 238            "^"
 239            (regexp-quote mail-header-separator)
 240            "$")
 241           nil t)
 242          (point)))
 243       (wl-draft-parse-mailbox-list wl-draft-mime-bcc-field-name))
 244      ", ")))
 245
 246 (defun wl-draft-attribute-envelope-from ()
 247   (or wl-envelope-from
 248       (wl-address-header-extract-address wl-from)))
 249
 250 (defun wl-draft-attribute-smtp-posting-server ()
 251   (or wl-smtp-posting-server
 252       (progn (require 'smtp) smtp-server)
 253       "localhost"))
 254
 255 (defun wl-draft-attribute-smtp-posting-port ()
 256   (or wl-smtp-posting-port
 257       (progn (require 'smtp) smtp-service)))
 258
 259 (defun wl-draft-attribute-newsgroups ()
 260   (std11-field-body "Newsgroups"))
 261
 262 (defun wl-draft-nntp-attribute (attribute &optional alternatives)
 263   (let ((config (cdr (elmo-string-matched-assoc
 264                       (std11-field-body "newsgroups")
 265                       wl-nntp-posting-config-alist)))
 266         entry)
 267     (when (stringp config)
 268       (setq config (list (cons 'server config))))
 269     (if (setq entry (assq attribute config))
 270         ;; maybe nil
 271         (cdr entry)
 272       (let (value)
 273         (while alternatives
 274           (if (setq value (symbol-value (car alternatives)))
 275               (setq alternatives nil)
 276             (setq alternatives (cdr alternatives))))
 277         value))))
 278
 279 (defun wl-draft-attribute-nntp-posting-server ()
 280   (wl-draft-nntp-attribute
 281    'server
 282    '(wl-nntp-posting-server elmo-nntp-default-server)))
 283
 284 (defun wl-draft-attribute-nntp-posting-port ()
 285   (wl-draft-nntp-attribute
 286    'port
 287    '(wl-nntp-posting-port elmo-nntp-default-port)))
 288
 289 (defun wl-draft-attribute-value (attr)
 290   (let ((name (symbol-name attr))
 291         fsymbol symbol)
 292     (cond ((and (setq fsymbol (intern-soft
 293                                (format "wl-draft-attribute-%s" name)))
 294                 (fboundp fsymbol))
 295            (funcall fsymbol))
 296           ((and (setq symbol (intern-soft (format "wl-%s" name)))
 297                 (boundp symbol))
 298            (symbol-value symbol))
 299           ((boundp attr)
 300            (symbol-value attr)))))
 301
 302 (defun wl-mime-quit-preview ()
 303   "Quitting method for mime-view."
 304   (let* ((temp (and (boundp 'mime-edit-temp-message-buffer) ;; for SEMI <= 1.14.6
 305                     mime-edit-temp-message-buffer))
 306          (window (selected-window))
 307          buf)
 308     (mime-preview-kill-buffer)
 309     (set-buffer temp)
 310     (setq buf mime-edit-buffer)
 311     (kill-buffer temp)
 312     (select-window window)
 313     (switch-to-buffer buf)))
 314
 315 (defun wl-draft-preview-message ()
 316   "Preview editing message."
 317   (interactive)
 318   (let* (attribute-values
 319          (orig-buffer (current-buffer))
 320          (current-point (point))
 321          (config-exec-flag wl-draft-config-exec-flag)
 322          (parent-folder wl-draft-parent-folder)
 323          (mime-display-header-hook 'wl-highlight-headers)
 324          (mime-header-encode-method-alist
 325           (append
 326            '((wl-draft-eword-encode-address-list
 327               .  (To Cc Bcc Resent-To Resent-Cc Resent-Bcc From)))
 328            (if (boundp 'mime-header-encode-method-alist)
 329                (symbol-value 'mime-header-encode-method-alist))))
 330          mime-view-ignored-field-list   ; all header.
 331          (mime-edit-translate-buffer-hook
 332           (cons
 333            (lambda ()
 334              (let ((wl-draft-config-exec-flag config-exec-flag)
 335                    (wl-draft-parent-folder parent-folder)
 336                    (copy-buffer (current-buffer)))
 337                (wl-copy-local-variables
 338                 orig-buffer
 339                 copy-buffer
 340                 (with-current-buffer orig-buffer
 341                   (append wl-draft-config-variables
 342                           (wl-draft-clone-local-variables))))
 343                (goto-char current-point)
 344                (run-hooks 'wl-draft-send-hook)
 345                (condition-case err
 346                    (setq attribute-values
 347                          (mapcar
 348                           (lambda (attr)
 349                             (cons attr (wl-draft-attribute-value attr)))
 350                           (if wl-draft-preview-attributes
 351                               (wl-draft-preview-attributes-list)
 352                             '(recipients))))
 353                  (error
 354                   (kill-buffer (current-buffer))
 355                   (signal (car err) (cdr err))))))
 356            mime-edit-translate-buffer-hook)))
 357     (mime-edit-preview-message)
 358     (make-local-variable 'mime-preview-quitting-method-alist)
 359     (setq mime-preview-quitting-method-alist
 360           '((mime-temp-message-mode . wl-mime-quit-preview)))
 361     (let ((buffer-read-only nil))
 362       (when wl-highlight-body-too
 363         (wl-highlight-body))
 364       (run-hooks 'wl-draft-preview-message-hook))
 365     (make-local-hook 'kill-buffer-hook)
 366     (add-hook 'kill-buffer-hook #'wl-draft-hide-attributes-buffer nil t)
 367     (if wl-draft-preview-attributes
 368         (ignore-errors ; in case when the window is too small
 369          (wl-draft-show-attributes-buffer attribute-values))
 370       (message (concat "Recipients: "
 371                        (cdr (assq 'recipients attribute-values)))))))
 372
 373 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 374
 375 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 376
 377 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 378
 379 ;;; Message
 380
 381 (defun wl-message-decode-mode (outbuf inbuf)
 382   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 383         (mime-display-header-hook 'wl-highlight-headers))
 384     (mime-view-mode nil nil nil inbuf outbuf)))
 385
 386 (defun wl-message-decode-with-all-header (outbuf inbuf)
 387   (let ((mime-view-ignored-field-regexp "^:$")
 388         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 389         (mime-display-header-hook 'wl-highlight-headers)
 390         mime-view-ignored-field-list)
 391     (mime-view-mode nil nil nil inbuf outbuf)))
 392
 393 (defun wl-message-delete-mime-out-buf ()
 394   (let (mime-out-buf mime-out-win)
 395     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 396         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 397             (delete-window mime-out-win)))))
 398
 399 (defun wl-message-request-partial (folder number)
 400   (elmo-set-work-buf
 401    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 402                        number
 403                        (elmo-make-fetch-strategy 'entire)
 404                        'unread)
 405    (mime-parse-buffer nil)))
 406
 407 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 408 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 409 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 410 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 411 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 412 (defalias 'wl-message-quit              'mime-preview-quit)
 413 (defalias 'wl-message-button-dispatcher-internal
 414   'mime-button-dispatcher)
 415
 416 (defsubst wl-mime-node-id-to-string (node-id)
 417   (if (consp node-id)
 418       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 419                  (reverse node-id)
 420                  ".")
 421     "0"))
 422
 423 (defun wl-message-delete-current-part ()
 424   "Delete a part under the cursor from the multipart message."
 425   (interactive)
 426   (save-restriction
 427     (widen)
 428     (let* ((entity (get-text-property (point) 'mime-view-entity))
 429            (node-id (mime-entity-node-id entity))
 430            (filename (mime-entity-safe-filename entity))
 431            (header-start (mime-buffer-entity-header-start-internal entity))
 432            (body-end (mime-buffer-entity-body-end-internal entity))
 433            (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 434            (number wl-message-buffer-cur-number)
 435            (msgid (elmo-message-field folder number 'message-id))
 436            (orig-buf wl-message-buffer-original-buffer))
 437       (if (eq (luna-class-name entity) 'mime-elmo-imap-entity)
 438           (error "Please fetch the entire message (by typing 'C-u .') and try again"))
 439       (with-current-buffer orig-buf
 440         (unless (string-equal
 441                  (buffer-string)
 442                  (elmo-message-fetch-string
 443                   folder number
 444                   (elmo-make-fetch-strategy 'entire)))
 445           (error "Buffer content differs from actual message")))
 446       (when (and (elmo-folder-writable-p folder)
 447                  (buffer-live-p orig-buf)
 448                  node-id
 449                  (yes-or-no-p
 450                   (format "Do you really want to delete part %s? "
 451                           (wl-mime-node-id-to-string node-id))))
 452         (when (with-temp-buffer
 453                 (insert-buffer orig-buf)
 454                 (delete-region header-start body-end)
 455                 (goto-char header-start)
 456                 (insert "Content-Type: text/plain; charset=US-ASCII\n")
 457                 (when filename
 458                   (insert
 459                    "Content-Disposition:"
 460                    (mime-encode-field-body
 461                          (concat ""
 462                                  (and filename
 463                                       (concat " inline; filename=" (std11-wrap-as-quoted-string filename))))
 464                          "Content-Disposition")
 465                    "\n"))
 466                 (insert "\n")
 467                 (insert "** This part has been removed by Wanderlust **\n\n")
 468                 (elmo-folder-append-buffer folder))
 469
 470           (elmo-folder-move-messages
 471            folder (list number)
 472            (wl-folder-get-elmo-folder wl-trash-folder))
 473           (when (and (elmo-cache-get-path msgid)
 474                      (file-exists-p (elmo-cache-get-path msgid)))
 475             (delete-file (elmo-cache-get-path msgid)))
 476
 477           (mime-preview-quit)
 478           (wl-summary-delete-messages-on-buffer (list number))
 479           (wl-summary-toggle-disp-msg 'off)
 480           (setq wl-message-buffer nil)
 481           (wl-summary-sync nil "update"))))))
 482
 483 (defun wl-message-decrypt-pgp-nonmime ()
 484   "Decrypt PGP encrypted region"
 485   (interactive)
 486   (require 'pgg)
 487   (save-excursion
 488     (beginning-of-line)
 489     (if (or (re-search-forward "^-+END PGP MESSAGE-+$" nil t)
 490             (re-search-backward "^-+END PGP MESSAGE-+$" nil t))
 491         (let (beg end status)
 492           (setq end (match-end 0))
 493           (if (setq beg (re-search-backward "^-+BEGIN PGP MESSAGE-+$" nil t))
 494               (let ((inhibit-read-only t)
 495                     (buffer-file-coding-system wl-cs-autoconv))
 496                 (setq status (pgg-decrypt-region beg end))
 497                 (pgg-display-output-buffer beg end status))
 498             (message "Cannot find pgp encrypted region")))
 499       (message "Cannot find pgp encrypted region"))))
 500
 501 (defun wl-message-verify-pgp-nonmime (&optional arg)
 502   "Verify PGP signed region.
 503 With ARG, ask coding system and encode the region with it before verifying."
 504   (interactive "P")
 505   (require 'pgg)
 506   (save-excursion
 507     (beginning-of-line)
 508     (let ((message-buffer (current-buffer))
 509           beg end coding-system success)
 510       (setq end (and (or (re-search-forward "^-+END PGP SIGNATURE-+$" nil t)
 511                          (re-search-backward "^-+END PGP SIGNATURE-+$" nil t)
 512                          (error "Cannot find pgp signed region"))
 513                      (match-end 0)))
 514       (setq beg (or (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t)
 515                     (error "Cannot find pgp signed region")))
 516       (setq coding-system
 517             (or (let* ((situation (mime-preview-find-boundary-info))
 518                        (entity (aref situation 2)))
 519                   (mime-charset-to-coding-system
 520                    (mime-content-type-parameter
 521                     (mime-entity-content-type entity)
 522                     "charset")))
 523                 buffer-file-coding-system))
 524       (when arg
 525         (setq coding-system (read-coding-system
 526                              (format "Coding system (%S): " coding-system)
 527                              coding-system)))
 528       (with-temp-buffer
 529         (insert-buffer-substring message-buffer beg end)
 530         (encode-coding-region (point-min) (point-max) coding-system)
 531         (setq success (pgg-verify-region (point-min) (point-max) nil 'fetch)))
 532       (mime-show-echo-buffer)
 533       (set-buffer mime-echo-buffer-name)
 534       (set-window-start
 535        (get-buffer-window mime-echo-buffer-name)
 536        (point-max))
 537       (insert-buffer-substring
 538        (if success pgg-output-buffer pgg-errors-buffer)))))
 539
 540 ;; XXX: encrypted multipart isn't represented as multipart
 541 (defun wl-mime-preview-application/pgp (parent-entity entity situation)
 542   (require 'pgg)
 543   (goto-char (point-max))
 544   (let ((p (point))
 545         raw-buf to-buf representation-type child-entity)
 546     (goto-char p)
 547     (save-restriction
 548       (narrow-to-region p p)
 549       (setq to-buf (current-buffer))
 550       (with-temp-buffer
 551         (setq raw-buf (current-buffer))
 552         (mime-insert-entity entity)
 553         (when (progn
 554                 (goto-char (point-min))
 555                 (re-search-forward "^-+BEGIN PGP MESSAGE-+$" nil t))
 556           (pgg-decrypt-region (point-min)(point-max))
 557           (delete-region (point-min) (point-max))
 558           (insert-buffer pgg-output-buffer)
 559           (setq representation-type 'elmo-buffer))
 560         (setq child-entity (mime-parse-message
 561                             (mm-expand-class-name representation-type)
 562                             nil
 563                             parent-entity
 564                             (mime-entity-node-id-internal parent-entity)))
 565         (mime-display-entity
 566          child-entity
 567          nil
 568          `((header . visible)
 569            (body . visible)
 570            (entity-button . invisible))
 571          to-buf)))))
 572
 573 (defun wl-mime-preview-application/pgp-encrypted (entity situation)
 574   (let* ((entity-node-id (mime-entity-node-id entity))
 575          (mother (mime-entity-parent entity))
 576          (knum (car entity-node-id))
 577          (onum (if (> knum 0)
 578                    (1- knum)
 579                  (1+ knum)))
 580          (orig-entity (nth onum (mime-entity-children mother))))
 581     (wl-mime-preview-application/pgp entity orig-entity situation)))
 582
 583 ;;; Summary
 584 (defun wl-summary-burst-subr (message-entity target number)
 585   ;; returns new number.
 586   (let (content-type entity)
 587     (setq content-type (mime-entity-content-type message-entity))
 588     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 589            (dolist (entity (mime-entity-children message-entity))
 590              (setq number (wl-summary-burst-subr
 591                            entity
 592                            target
 593                            number))))
 594           ((and (eq (cdr (assq 'type content-type)) 'message)
 595                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 596            (message "Bursting...%s" (setq number (+ 1 number)))
 597            (setq entity
 598                  (car (mime-entity-children message-entity)))
 599            (with-temp-buffer
 600              (set-buffer-multibyte nil)
 601              (insert (mime-entity-body message-entity))
 602              (elmo-folder-append-buffer target))))
 603     number))
 604
 605 (defun wl-summary-burst (&optional arg)
 606   "De-capsulate embedded messages in MIME format.
 607 With ARG, ask destination folder."
 608   (interactive "P")
 609   (let ((raw-buf (wl-summary-get-original-buffer))
 610         (view-buf wl-message-buffer)
 611         message-entity target)
 612     (save-excursion
 613       (when (and (null arg)
 614                  (elmo-folder-writable-p wl-summary-buffer-elmo-folder))
 615         (setq target wl-summary-buffer-elmo-folder))
 616       (while (null target)
 617         (let ((name (wl-summary-read-folder wl-default-folder
 618                                             "to extract to")))
 619           (setq target (wl-folder-get-elmo-folder name))
 620           (unless (elmo-folder-writable-p target)
 621             (message "%s is not writable" name)
 622             (setq target nil)
 623             (sit-for 1))))
 624       (wl-summary-set-message-buffer-or-redisplay)
 625       (with-current-buffer view-buf
 626         (setq message-entity
 627               (get-text-property (point-min) 'mime-view-entity)))
 628       (when message-entity
 629         (message "Bursting...")
 630         (with-current-buffer raw-buf
 631           (wl-summary-burst-subr message-entity target 0))
 632         (message "Bursting...done"))
 633       (if (elmo-folder-plugged-p target)
 634           (elmo-folder-check target)))
 635     (when (and target
 636                (string= wl-summary-buffer-folder-name
 637                         (elmo-folder-name-internal target)))
 638       (save-excursion (wl-summary-sync-update)))))
 639
 640 ;; internal variable.
 641 (defvar wl-mime-save-directory nil "Last saved directory.")
 642 ;;; Yet another save method.
 643 (defun wl-mime-save-content (entity situation)
 644   (let ((filename (expand-file-name
 645                    (read-file-name "Save to file: "
 646                                    (expand-file-name
 647                                     (or (mime-entity-safe-filename entity)
 648                                         ".")
 649                                     (or wl-mime-save-directory
 650                                         wl-temporary-file-directory))))))
 651     (while (file-directory-p filename)
 652       (setq filename (read-file-name "Please set filename (not directory): "
 653                                      filename)))
 654     (if (and (file-exists-p filename)
 655              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 656                                        filename))))
 657         (message "Not saved")
 658       (setq wl-mime-save-directory (file-name-directory filename))
 659       (mime-write-entity-content entity filename))))
 660
 661 ;;; Yet another combine method.
 662 (defun wl-mime-combine-message/partial-pieces (entity situation)
 663   "Internal method for wl to combine message/partial messages automatically."
 664   (interactive)
 665   (let* ((folder (with-current-buffer wl-message-buffer-cur-summary-buffer
 666                    wl-summary-buffer-elmo-folder))
 667          (mime-display-header-hook 'wl-highlight-headers)
 668          (id (or (cdr (assoc "id" situation)) ""))
 669          (mother (current-buffer))
 670          (summary-buf wl-message-buffer-cur-summary-buffer)
 671          subject-id overviews
 672          (root-dir (expand-file-name
 673                     (concat "m-prts-" (user-login-name))
 674                     temporary-file-directory))
 675          full-file point)
 676     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 677     (setq full-file (concat root-dir "/FULL"))
 678     (if (or (file-exists-p full-file)
 679             (not (y-or-n-p "Merge partials? ")))
 680         (with-current-buffer mother
 681           (mime-store-message/partial-piece entity situation)
 682           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 683           (make-local-variable 'mime-preview-over-to-next-method-alist)
 684           (setq mime-preview-over-to-next-method-alist
 685                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 686                       mime-preview-over-to-next-method-alist))
 687           (make-local-variable 'mime-preview-over-to-previous-method-alist)
 688           (setq mime-preview-over-to-previous-method-alist
 689                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 690                       mime-preview-over-to-previous-method-alist)))
 691       (setq subject-id
 692             (eword-decode-string
 693              (decode-mime-charset-string
 694               (mime-entity-read-field entity 'Subject)
 695               wl-summary-buffer-mime-charset)))
 696       (if (string-match "[0-9\n]+" subject-id)
 697           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 698       (catch 'tag
 699         (elmo-folder-do-each-message-entity (entity folder)
 700           (when (string-match
 701                  (regexp-quote subject-id)
 702                  (elmo-message-entity-field entity 'subject))
 703             (let* ((message
 704                     ;; request message at the cursor in Subject buffer.
 705                     (wl-message-request-partial
 706                      (elmo-folder-name-internal folder)
 707                      (elmo-message-entity-number entity)))
 708                    (situation (mime-entity-situation message))
 709                    (the-id (or (cdr (assoc "id" situation)) "")))
 710               (when (string= (downcase the-id)
 711                              (downcase id))
 712                 (with-current-buffer mother
 713                   (mime-store-message/partial-piece message situation))
 714                 (if (file-exists-p full-file)
 715                     (throw 'tag nil))))))
 716         (message "Not all partials found.")))))
 717
 718 (defun wl-mime-display-text/plain (entity situation)
 719   (let ((beg (point)))
 720     (mime-display-text/plain entity situation)
 721     (wl-highlight-message beg (point-max) t t)))
 722
 723 (defun wl-mime-display-header (entity situation)
 724   (let ((elmo-message-ignored-field-list
 725          (if wl-message-buffer-require-all-header
 726              nil
 727            wl-message-ignored-field-list))
 728         (elmo-message-visible-field-list wl-message-visible-field-list)
 729         (elmo-message-sorted-field-list wl-message-sort-field-list))
 730     (elmo-mime-insert-header entity situation)
 731     (wl-highlight-headers)))
 732
 733 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 734   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 735         (original-buffer wl-message-buffer-original-buffer))
 736     (mime-decrypt-application/pgp-encrypted entity situation)
 737     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 738     (setq wl-message-buffer-original-buffer original-buffer)))
 739
 740
 741 ;;; Setup methods.
 742 (defun wl-mime-setup ()
 743   (set-alist 'mime-preview-quitting-method-alist
 744              'wl-original-message-mode 'wl-message-exit)
 745   (set-alist 'mime-view-over-to-previous-method-alist
 746              'wl-original-message-mode 'wl-message-exit)
 747   (set-alist 'mime-view-over-to-next-method-alist
 748              'wl-original-message-mode 'wl-message-exit)
 749   (set-alist 'mime-preview-over-to-previous-method-alist
 750              'wl-original-message-mode 'wl-message-exit)
 751   (set-alist 'mime-preview-over-to-next-method-alist
 752              'wl-original-message-mode 'wl-message-exit)
 753   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 754   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 755
 756   (ctree-set-calist-strictly
 757    'mime-preview-condition
 758    '((type . text) (subtype . plain)
 759      (body . visible)
 760      (body-presentation-method . wl-mime-display-text/plain)
 761      (major-mode . wl-original-message-mode)))
 762
 763   (ctree-set-calist-strictly
 764    'mime-preview-condition
 765    '((type . application)(subtype . pgp-encrypted)
 766      (encoding . t)
 767      (body . invisible)
 768      (body-presentation-method . wl-mime-preview-application/pgp-encrypted)
 769      (major-mode . wl-original-message-mode)))
 770
 771   (ctree-set-calist-strictly
 772    'mime-acting-condition
 773    '((type . message) (subtype . partial)
 774      (method .  wl-mime-combine-message/partial-pieces)
 775      (request-partial-message-method . wl-message-request-partial)
 776      (major-mode . wl-original-message-mode)))
 777
 778   (ctree-set-calist-strictly
 779    'mime-acting-condition
 780    '((type . application) (subtype . pgp-encrypted)
 781      (method . wl-mime-decrypt-application/pgp-encrypted)
 782      (major-mode . wl-original-message-mode)))
 783
 784   (ctree-set-calist-strictly
 785    'mime-acting-condition
 786    '((mode . "extract")
 787      (major-mode . wl-original-message-mode)
 788      (method . wl-mime-save-content)))
 789   (set-alist 'mime-preview-following-method-alist
 790              'wl-original-message-mode
 791              (function wl-message-follow-current-entity))
 792   (set-alist 'mime-view-following-method-alist
 793              'wl-original-message-mode
 794              (function wl-message-follow-current-entity))
 795   (set-alist 'mime-edit-message-inserter-alist
 796              'wl-draft-mode (function wl-draft-insert-current-message))
 797   (set-alist 'mime-edit-mail-inserter-alist
 798              'wl-draft-mode (function wl-draft-insert-get-message))
 799   (set-alist 'mime-edit-split-message-sender-alist
 800              'wl-draft-mode
 801              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 802   (set-alist 'mime-raw-representation-type-alist
 803              'wl-original-message-mode 'binary)
 804   ;; Sort and highlight header fields.
 805   (or wl-message-ignored-field-list
 806       (setq wl-message-ignored-field-list
 807             mime-view-ignored-field-list))
 808   (or wl-message-visible-field-list
 809       (setq wl-message-visible-field-list
 810             mime-view-visible-field-list))
 811   (set-alist 'mime-header-presentation-method-alist
 812              'wl-original-message-mode
 813              'wl-mime-display-header)
 814   ;; To avoid overriding wl-draft-mode-map.
 815   (when (boundp 'mime-setup-signature-key-alist)
 816     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 817       (setq mime-setup-signature-key-alist
 818             (cons '(wl-draft-mode . "\C-c\C-w")
 819                   mime-setup-signature-key-alist)))))
 820
 821 (require 'product)
 822 (product-provide (provide 'wl-mime) (require 'wl-version))
 823
 824 ;;; wl-mime.el ends here