wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (require 'mime-view)
  32 (require 'mime-edit)
  33 (require 'mime-play)
  34 (require 'elmo)
  35 (require 'wl-vars)
  36
  37 ;;; Draft
  38
  39 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  40
  41 (defalias 'wl-draft-decode-message-in-buffer
  42   'mime-edit-decode-message-in-buffer)
  43
  44 (defun wl-draft-yank-current-message-entity ()
  45   "Yank currently displayed message entity.
  46 By setting following-method as yank-content.
  47
  48 If region is active, yank region contents instead. \(this feature is available
  49 if and only if `transient-mark-mode' \(GNU Emacs\) or `zmacs-regions' \(XEmacs\)
  50 has Non-nil value\)"
  51   (let ((wl-draft-buffer (current-buffer))
  52         (mime-view-following-method-alist
  53          (list (cons 'wl-original-message-mode
  54                      (function wl-draft-yank-to-draft-buffer))))
  55         (mime-preview-following-method-alist
  56          (list (cons 'wl-original-message-mode
  57                      (function wl-draft-yank-to-draft-buffer))))
  58         (message-buffer (wl-current-message-buffer)))
  59     (if message-buffer
  60         (save-excursion
  61           (set-buffer message-buffer)
  62           (save-restriction
  63             (widen)
  64             (cond
  65              ((wl-region-exists-p)
  66               (wl-mime-preview-follow-current-region))
  67              ((not (wl-message-mime-analysis-p
  68                     (wl-message-buffer-display-type)))
  69               (wl-mime-preview-follow-no-mime
  70                (wl-message-buffer-display-type)))
  71              (t
  72               (mime-preview-follow-current-entity)))))
  73       (error "No message."))))
  74
  75 ;; modified mime-preview-follow-current-entity from mime-view.el
  76 (defun wl-mime-preview-follow-no-mime (display-type)
  77   "Write follow message to current message, without mime.
  78 It calls following-method selected from variable
  79 `mime-preview-following-method-alist'."
  80   (interactive)
  81   (let* ((mode (mime-preview-original-major-mode 'recursive))
  82          (new-name (format "%s-no-mime" (buffer-name)))
  83          new-buf min beg end
  84          (entity (get-text-property (point-min) 'elmo-as-is-entity))
  85          (the-buf (current-buffer))
  86          fields)
  87     (save-excursion
  88       (goto-char (point-min))
  89       (setq min (point-min)
  90             beg (re-search-forward "^$" nil t)
  91             end (point-max)))
  92     (save-excursion
  93       (set-buffer (setq new-buf (get-buffer-create new-name)))
  94       (erase-buffer)
  95       (insert-buffer-substring the-buf beg end)
  96       (goto-char (point-min))
  97       ;; Insert all headers.
  98       (let ((elmo-mime-display-header-analysis
  99              (wl-message-mime-analysis-p display-type 'header)))
 100         (elmo-mime-insert-sorted-header entity))
 101       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 102         (if (functionp f)
 103             (funcall f new-buf)
 104           (message
 105            "Sorry, following method for %s is not implemented yet."
 106            mode))))))
 107
 108 ;; modified mime-preview-follow-current-entity from mime-view.el
 109 (defun wl-mime-preview-follow-current-region ()
 110   "Write follow message to current region.
 111 It calls following-method selected from variable
 112 `mime-preview-following-method-alist'."
 113   (interactive)
 114   (let ((r-beg (region-beginning))
 115         (r-end (region-end))
 116         (entity (get-text-property (point-min)
 117                                    'mime-view-entity)))
 118     (let* ((mode (mime-preview-original-major-mode 'recursive))
 119            (new-name
 120             (format "%s-active-region" (buffer-name)))
 121            new-buf
 122            (the-buf (current-buffer))
 123            fields)
 124       (save-excursion
 125         (set-buffer (setq new-buf (get-buffer-create new-name)))
 126         (erase-buffer)
 127         (insert ?\n)
 128         (insert-buffer-substring the-buf r-beg r-end)
 129         (goto-char (point-min))
 130         (let ((current-entity
 131                (if (and entity
 132                         (eq (mime-entity-media-type entity) 'message)
 133                         (eq (mime-entity-media-subtype entity) 'rfc822))
 134                    (car (mime-entity-children entity))
 135                  entity)))
 136           (while (and current-entity
 137                       (if (and (eq (mime-entity-media-type
 138                                     current-entity) 'message)
 139                                (eq (mime-entity-media-subtype
 140                                     current-entity) 'rfc822))
 141                           nil
 142                         (mime-insert-header current-entity fields)
 143                         t))
 144             (setq fields (std11-collect-field-names)
 145                   current-entity (mime-entity-parent current-entity))))
 146         (let ((rest mime-view-following-required-fields-list)
 147               field-name ret)
 148           (while rest
 149             (setq field-name (car rest))
 150             (or (std11-field-body field-name)
 151                 (progn
 152                   (save-excursion
 153                     (set-buffer the-buf)
 154                     (let ((entity (when mime-mother-buffer
 155                                     (set-buffer mime-mother-buffer)
 156                                     (get-text-property (point)
 157                                                        'mime-view-entity))))
 158                       (while (and entity
 159                                   (null (setq ret (mime-entity-fetch-field
 160                                                    entity field-name))))
 161                         (setq entity (mime-entity-parent entity)))))
 162                   (if ret
 163                       (insert (concat field-name ": " ret "\n")))))
 164             (setq rest (cdr rest)))))
 165       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 166         (if (functionp f)
 167             (funcall f new-buf)
 168           (message
 169            "Sorry, following method for %s is not implemented yet."
 170            mode))))))
 171
 172 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
 173
 174 (defun wl-draft-preview-attributes-list ()
 175   (if (listp (car wl-draft-preview-attributes-list))
 176       (elmo-uniq-list
 177        (nconc (and (wl-message-mail-p)
 178                    (copy-sequence
 179                     (cdr (assq 'mail wl-draft-preview-attributes-list))))
 180               (and (wl-message-news-p)
 181                    (copy-sequence
 182                     (cdr (assq 'news wl-draft-preview-attributes-list))))))
 183     wl-draft-preview-attributes-list))
 184
 185 (defun wl-draft-show-attributes-buffer (attribute-values)
 186   (let* ((cur-win (selected-window))
 187          (size (min
 188                 (- (window-height cur-win)
 189                    window-min-height 1)
 190                 (- (window-height cur-win)
 191                    (max
 192                     window-min-height
 193                     (1+ wl-draft-preview-attributes-buffer-lines))))))
 194     (split-window cur-win (if (> size 0) size window-min-height))
 195     (select-window (next-window))
 196     (let ((pop-up-windows nil))
 197       (switch-to-buffer (get-buffer-create
 198                          wl-draft-preview-attributes-buffer-name)))
 199     (with-current-buffer
 200         (get-buffer wl-draft-preview-attributes-buffer-name)
 201       (setq buffer-read-only t)
 202       (let (buffer-read-only)
 203         (erase-buffer)
 204         (dolist (pair attribute-values)
 205           (insert (capitalize (symbol-name (car pair))) ": "
 206                   (format "%s" (or (cdr pair) ""))
 207                   "\n"))
 208         (goto-char (point-min))
 209         (wl-highlight-headers)))
 210     (select-window cur-win)))
 211
 212 (defun wl-draft-hide-attributes-buffer ()
 213   (let (window buffer)
 214     (when (setq window (get-buffer-window
 215                         wl-draft-preview-attributes-buffer-name))
 216       (select-window window)
 217       (delete-window))
 218     (when (setq buffer (get-buffer wl-draft-preview-attributes-buffer-name))
 219       (kill-buffer buffer))))
 220
 221 (defun wl-draft-attribute-recipients ()
 222   (let (wl-draft-remove-group-list-contents)
 223     (mapconcat
 224      'identity
 225      (nconc
 226       (wl-draft-deduce-address-list
 227        (current-buffer)
 228        (point-min)
 229        (save-excursion
 230          (goto-char (point-min))
 231          (re-search-forward
 232           (concat
 233            "^"
 234            (regexp-quote mail-header-separator)
 235            "$")
 236           nil t)
 237          (point)))
 238       (wl-draft-parse-mailbox-list wl-draft-mime-bcc-field-name))
 239      ", ")))
 240
 241 (defun wl-draft-attribute-envelope-from ()
 242   (or wl-envelope-from
 243       (wl-address-header-extract-address wl-from)))
 244
 245 (defun wl-draft-attribute-smtp-posting-server ()
 246   (or wl-smtp-posting-server
 247       (progn (require 'smtp) smtp-server)
 248       "localhost"))
 249
 250 (defun wl-draft-attribute-smtp-posting-port ()
 251   (or wl-smtp-posting-port
 252       (progn (require 'smtp) smtp-service)))
 253
 254 (defun wl-draft-attribute-newsgroups ()
 255   (std11-field-body "Newsgroups"))
 256
 257 (defun wl-draft-nntp-attribute (attribute &optional alternatives)
 258   (let ((config (cdr (elmo-string-matched-assoc
 259                       (std11-field-body "newsgroups")
 260                       wl-nntp-posting-config-alist)))
 261         entry)
 262     (when (stringp config)
 263       (setq config (list (cons 'server config))))
 264     (if (setq entry (assq attribute config))
 265         ;; maybe nil
 266         (cdr entry)
 267       (let (value)
 268         (while alternatives
 269           (if (setq value (symbol-value (car alternatives)))
 270               (setq alternatives nil)
 271             (setq alternatives (cdr alternatives))))
 272         value))))
 273
 274 (defun wl-draft-attribute-nntp-posting-server ()
 275   (wl-draft-nntp-attribute
 276    'server
 277    '(wl-nntp-posting-server elmo-nntp-default-server)))
 278
 279 (defun wl-draft-attribute-nntp-posting-port ()
 280   (wl-draft-nntp-attribute
 281    'port
 282    '(wl-nntp-posting-port elmo-nntp-default-port)))
 283
 284 (defun wl-draft-attribute-value (attr)
 285   (let ((name (symbol-name attr))
 286         fsymbol symbol)
 287     (cond ((and (setq fsymbol (intern-soft
 288                                (format "wl-draft-attribute-%s" name)))
 289                 (fboundp fsymbol))
 290            (funcall fsymbol))
 291           ((and (setq symbol (intern-soft (format "wl-%s" name)))
 292                 (boundp symbol))
 293            (symbol-value symbol))
 294           ((boundp attr)
 295            (symbol-value attr)))))
 296
 297 (defun wl-mime-quit-preview ()
 298   "Quitting method for mime-view."
 299   (let* ((temp (and (boundp 'mime-edit-temp-message-buffer) ;; for SEMI <= 1.14.6
 300                     mime-edit-temp-message-buffer))
 301          (window (selected-window))
 302          buf)
 303     (mime-preview-kill-buffer)
 304     (set-buffer temp)
 305     (setq buf mime-edit-buffer)
 306     (kill-buffer temp)
 307     (select-window window)
 308     (switch-to-buffer buf)))
 309
 310 (defun wl-draft-preview-message ()
 311   "Preview editing message."
 312   (interactive)
 313   (let* (attribute-values
 314          (orig-buffer (current-buffer))
 315          (current-point (point))
 316          (config-exec-flag wl-draft-config-exec-flag)
 317          (parent-folder wl-draft-parent-folder)
 318          (mime-display-header-hook 'wl-highlight-headers)
 319          (mime-header-encode-method-alist
 320           (append
 321            '((wl-draft-eword-encode-address-list
 322               .  (To Cc Bcc Resent-To Resent-Cc Resent-Bcc From)))
 323            (if (boundp 'mime-header-encode-method-alist)
 324                (symbol-value 'mime-header-encode-method-alist))))
 325          mime-view-ignored-field-list   ; all header.
 326          (mime-edit-translate-buffer-hook
 327           (cons
 328            (lambda ()
 329              (let ((wl-draft-config-exec-flag config-exec-flag)
 330                    (wl-draft-parent-folder parent-folder)
 331                    (copy-buffer (current-buffer)))
 332                (wl-copy-local-variables
 333                 orig-buffer
 334                 copy-buffer
 335                 (with-current-buffer orig-buffer
 336                   (append wl-draft-config-variables
 337                           (wl-draft-clone-local-variables))))
 338                (goto-char current-point)
 339                (run-hooks 'wl-draft-send-hook)
 340                (condition-case err
 341                    (setq attribute-values
 342                          (mapcar
 343                           (lambda (attr)
 344                             (cons attr (wl-draft-attribute-value attr)))
 345                           (if wl-draft-preview-attributes
 346                               (wl-draft-preview-attributes-list)
 347                             '(recipients))))
 348                  (error
 349                   (kill-buffer (current-buffer))
 350                   (signal (car err) (cdr err))))))
 351            mime-edit-translate-buffer-hook)))
 352     (mime-edit-preview-message)
 353     (make-local-variable 'mime-preview-quitting-method-alist)
 354     (setq mime-preview-quitting-method-alist
 355           '((mime-temp-message-mode . wl-mime-quit-preview)))
 356     (let ((buffer-read-only nil))
 357       (when wl-highlight-body-too
 358         (wl-highlight-body))
 359       (run-hooks 'wl-draft-preview-message-hook))
 360     (make-local-hook 'kill-buffer-hook)
 361     (add-hook 'kill-buffer-hook #'wl-draft-hide-attributes-buffer nil t)
 362     (if wl-draft-preview-attributes
 363         (ignore-errors ; in case when the window is too small
 364          (wl-draft-show-attributes-buffer attribute-values))
 365       (message (concat "Recipients: "
 366                        (cdr (assq 'recipients attribute-values)))))))
 367
 368 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 369
 370 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 371
 372 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 373
 374 ;;; Message
 375
 376 (defun wl-message-decode-mode (outbuf inbuf)
 377   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 378         (mime-display-header-hook 'wl-highlight-headers))
 379     (mime-view-mode nil nil nil inbuf outbuf)))
 380
 381 (defun wl-message-decode-with-all-header (outbuf inbuf)
 382   (let ((mime-view-ignored-field-regexp "^:$")
 383         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 384         (mime-display-header-hook 'wl-highlight-headers)
 385         mime-view-ignored-field-list)
 386     (mime-view-mode nil nil nil inbuf outbuf)))
 387
 388 (defun wl-message-delete-mime-out-buf ()
 389   (let (mime-out-buf mime-out-win)
 390     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 391         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 392             (delete-window mime-out-win)))))
 393
 394 (defun wl-message-request-partial (folder number)
 395   (elmo-set-work-buf
 396    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 397                        number
 398                        (elmo-make-fetch-strategy 'entire)
 399                        'unread)
 400    (mime-parse-buffer nil)))
 401
 402 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 403 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 404 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 405 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 406 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 407 (defalias 'wl-message-quit              'mime-preview-quit)
 408 (defalias 'wl-message-button-dispatcher-internal
 409   'mime-button-dispatcher)
 410
 411 (defsubst wl-mime-node-id-to-string (node-id)
 412   (if (consp node-id)
 413       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 414                  (reverse node-id)
 415                  ".")
 416     "0"))
 417
 418 (defun wl-message-delete-current-part ()
 419   "Delete a part under the cursor from the multipart message."
 420   (interactive)
 421   (save-restriction
 422     (widen)
 423     (let* ((entity (get-text-property (point) 'mime-view-entity))
 424            (node-id (mime-entity-node-id entity))
 425            (filename (mime-entity-safe-filename entity))
 426            (header-start (mime-buffer-entity-header-start-internal entity))
 427            (body-end (mime-buffer-entity-body-end-internal entity))
 428            (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 429            (number wl-message-buffer-cur-number)
 430            (msgid (elmo-message-field folder number 'message-id))
 431            (orig-buf wl-message-buffer-original-buffer))
 432       (if (eq (luna-class-name entity) 'mime-elmo-imap-entity)
 433           (error "Please fetch the entire message (by typing 'C-u .') and try again"))
 434       (with-current-buffer orig-buf
 435         (unless (string-equal
 436                  (buffer-string)
 437                  (elmo-message-fetch-string
 438                   folder number
 439                   (elmo-make-fetch-strategy 'entire)))
 440           (error "Buffer content differs from actual message")))
 441       (when (and (elmo-folder-writable-p folder)
 442                  (buffer-live-p orig-buf)
 443                  node-id
 444                  (yes-or-no-p
 445                   (format "Do you really want to delete part %s? "
 446                           (wl-mime-node-id-to-string node-id))))
 447         (when (with-temp-buffer
 448                 (insert-buffer orig-buf)
 449                 (delete-region header-start body-end)
 450                 (goto-char header-start)
 451                 (insert "Content-Type: text/plain; charset=US-ASCII\n")
 452                 (when filename
 453                   (insert
 454                    "Content-Disposition:"
 455                    (mime-encode-field-body
 456                          (concat ""
 457                                  (and filename
 458                                       (concat " inline; filename=" (std11-wrap-as-quoted-string filename))))
 459                          "Content-Disposition")
 460                    "\n"))
 461                 (insert "\n")
 462                 (insert "** This part has been removed by Wanderlust **\n\n")
 463                 (elmo-folder-append-buffer folder))
 464
 465           (elmo-folder-move-messages
 466            folder (list number)
 467            (wl-folder-get-elmo-folder wl-trash-folder))
 468           (when (and (elmo-cache-get-path msgid)
 469                      (file-exists-p (elmo-cache-get-path msgid)))
 470             (delete-file (elmo-cache-get-path msgid)))
 471
 472           (mime-preview-quit)
 473           (wl-summary-delete-messages-on-buffer (list number))
 474           (wl-summary-toggle-disp-msg 'off)
 475           (setq wl-message-buffer nil)
 476           (wl-summary-sync nil "update"))))))
 477
 478 ;; PGP
 479 (static-cond
 480  ((require 'epg nil t)
 481   (defun wl-mime-pgp-decrypt-region (beg end &optional no-decode)
 482     (require 'epg)
 483     (let ((plain (decode-coding-string
 484                   (epg-decrypt-string
 485                    (epg-make-context)
 486                    (buffer-substring beg end))
 487                   (if no-decode 'raw-text wl-cs-autoconv))))
 488       (delete-region beg end)
 489       (insert plain)))
 490
 491   (defun wl-mime-pgp-verify-region (beg end &optional coding-system)
 492     (require 'epg)
 493     (let ((message-buffer (current-buffer))
 494           (context (epg-make-context)))
 495       (epg-verify-string
 496        context
 497        (with-temp-buffer
 498          (insert-buffer-substring message-buffer beg end)
 499          (when coding-system
 500            (encode-coding-region (point-min) (point-max) coding-system))
 501          (goto-char (point-min))
 502          (while (search-forward "\n" nil t)
 503            (replace-match "\r\n"))
 504          (buffer-substring (point-min) (point-max))))
 505       (message "%s"
 506                (epg-verify-result-to-string
 507                 (epg-context-result-for context 'verify))))))
 508
 509  ((require 'pgg nil t)
 510   (defun wl-mime-pgp-decrypt-region (beg end &optional no-decode)
 511     (require 'pgg)
 512     (let ((buffer-file-coding-system wl-cs-autoconv)
 513           status)
 514       (setq status (pgg-decrypt-region beg end))
 515       (if no-decode
 516           (when status
 517             (delete-region beg end)
 518             (insert-buffer-substring pgg-output-buffer))
 519         (pgg-display-output-buffer beg end status))
 520       (unless status
 521         (error "Decryption is failed"))))
 522
 523   (defun wl-mime-pgp-verify-region (beg end &optional coding-system)
 524     (require 'pgg)
 525     (let ((message-buffer (current-buffer))
 526           success)
 527       (with-temp-buffer
 528         (insert-buffer-substring message-buffer beg end)
 529         (when coding-system
 530           (encode-coding-region (point-min) (point-max) coding-system))
 531         (setq success (pgg-verify-region (point-min) (point-max) nil 'fetch)))
 532       (mime-show-echo-buffer)
 533       (set-buffer mime-echo-buffer-name)
 534       (set-window-start
 535        (get-buffer-window mime-echo-buffer-name)
 536        (point-max))
 537       (insert-buffer-substring
 538        (if success
 539            pgg-output-buffer
 540          pgg-errors-buffer)))))
 541  (t
 542   (defun wl-mime-pgp-decrypt-region (beg end &optional no-decode)
 543     (error "Does not support PGP decryption"))
 544
 545   (defun wl-mime-pgp-verify-region (beg end &optional coding-system)
 546     (error "Does not support PGP verification"))))
 547
 548 (defun wl-message-decrypt-pgp-nonmime ()
 549   "Decrypt PGP encrypted region"
 550   (interactive)
 551   (save-excursion
 552     (beginning-of-line)
 553     (if (or (re-search-forward "^-+END PGP MESSAGE-+$" nil t)
 554             (re-search-backward "^-+END PGP MESSAGE-+$" nil t))
 555         (let (beg end status)
 556           (setq end (match-end 0))
 557           (if (setq beg (re-search-backward "^-+BEGIN PGP MESSAGE-+$" nil t))
 558               (let ((inhibit-read-only t))
 559                 (wl-mime-pgp-decrypt-region beg end))
 560             (message "Cannot find pgp encrypted region")))
 561       (message "Cannot find pgp encrypted region"))))
 562
 563 (defun wl-message-verify-pgp-nonmime (&optional arg)
 564   "Verify PGP signed region.
 565 With ARG, ask coding system and encode the region with it before verifying."
 566   (interactive "P")
 567   (save-excursion
 568     (beginning-of-line)
 569     (let ((message-buffer (current-buffer))
 570           beg end coding-system success)
 571       (setq end (and (or (re-search-forward "^-+END PGP SIGNATURE-+$" nil t)
 572                          (re-search-backward "^-+END PGP SIGNATURE-+$" nil t)
 573                          (error "Cannot find pgp signed region"))
 574                      (match-end 0)))
 575       (setq beg (or (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t)
 576                     (error "Cannot find pgp signed region")))
 577       (setq coding-system
 578             (or (let* ((situation (mime-preview-find-boundary-info))
 579                        (entity (aref situation 2)))
 580                   (mime-charset-to-coding-system
 581                    (mime-content-type-parameter
 582                     (mime-entity-content-type entity)
 583                     "charset")))
 584                 buffer-file-coding-system))
 585       (when arg
 586         (setq coding-system (read-coding-system
 587                              (format "Coding system (%S): " coding-system)
 588                              coding-system)))
 589       (wl-mime-pgp-verify-region beg end coding-system))))
 590
 591 ;; XXX: encrypted multipart isn't represented as multipart
 592 (defun wl-mime-preview-application/pgp (parent-entity entity situation)
 593   (goto-char (point-max))
 594   (let ((p (point))
 595         raw-buf to-buf representation-type child-entity)
 596     (goto-char p)
 597     (save-restriction
 598       (narrow-to-region p p)
 599       (setq to-buf (current-buffer))
 600       (with-temp-buffer
 601         (setq raw-buf (current-buffer))
 602         (mime-insert-entity entity)
 603         (when (progn
 604                 (goto-char (point-min))
 605                 (re-search-forward "^-+BEGIN PGP MESSAGE-+$" nil t))
 606           (wl-mime-pgp-decrypt-region (point-min) (point-max) 'no-decode)
 607           (setq representation-type 'elmo-buffer))
 608         (setq child-entity (mime-parse-message
 609                             (mm-expand-class-name representation-type)
 610                             nil
 611                             parent-entity
 612                             (mime-entity-node-id-internal parent-entity)))
 613         (mime-display-entity
 614          child-entity
 615          nil
 616          `((header . visible)
 617            (body . visible)
 618            (entity-button . invisible))
 619          to-buf)))))
 620
 621 (defun wl-mime-preview-application/pgp-encrypted (entity situation)
 622   (let* ((entity-node-id (mime-entity-node-id entity))
 623          (mother (mime-entity-parent entity))
 624          (knum (car entity-node-id))
 625          (onum (if (> knum 0)
 626                    (1- knum)
 627                  (1+ knum)))
 628          (orig-entity (nth onum (mime-entity-children mother))))
 629     (wl-mime-preview-application/pgp entity orig-entity situation)))
 630
 631 ;;; Summary
 632 (defun wl-summary-burst-subr (message-entity target number)
 633   ;; returns new number.
 634   (let (content-type entity)
 635     (setq content-type (mime-entity-content-type message-entity))
 636     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 637            (dolist (entity (mime-entity-children message-entity))
 638              (setq number (wl-summary-burst-subr
 639                            entity
 640                            target
 641                            number))))
 642           ((and (eq (cdr (assq 'type content-type)) 'message)
 643                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 644            (message "Bursting...%s" (setq number (+ 1 number)))
 645            (setq entity
 646                  (car (mime-entity-children message-entity)))
 647            (with-temp-buffer
 648              (set-buffer-multibyte nil)
 649              (insert (mime-entity-body message-entity))
 650              (elmo-folder-append-buffer target))))
 651     number))
 652
 653 (defun wl-summary-burst (&optional arg)
 654   "De-capsulate embedded messages in MIME format.
 655 With ARG, ask destination folder."
 656   (interactive "P")
 657   (let ((raw-buf (wl-summary-get-original-buffer))
 658         (view-buf wl-message-buffer)
 659         message-entity target)
 660     (save-excursion
 661       (when (and (null arg)
 662                  (elmo-folder-writable-p wl-summary-buffer-elmo-folder))
 663         (setq target wl-summary-buffer-elmo-folder))
 664       (while (null target)
 665         (let ((name (wl-summary-read-folder wl-default-folder
 666                                             "to extract to")))
 667           (setq target (wl-folder-get-elmo-folder name))
 668           (unless (elmo-folder-writable-p target)
 669             (message "%s is not writable" name)
 670             (setq target nil)
 671             (sit-for 1))))
 672       (wl-summary-set-message-buffer-or-redisplay)
 673       (with-current-buffer view-buf
 674         (setq message-entity
 675               (get-text-property (point-min) 'mime-view-entity)))
 676       (when message-entity
 677         (message "Bursting...")
 678         (with-current-buffer raw-buf
 679           (wl-summary-burst-subr message-entity target 0))
 680         (message "Bursting...done"))
 681       (if (elmo-folder-plugged-p target)
 682           (elmo-folder-check target)))
 683     (when (and target
 684                (string= wl-summary-buffer-folder-name
 685                         (elmo-folder-name-internal target)))
 686       (save-excursion (wl-summary-sync-update)))))
 687
 688 ;; internal variable.
 689 (defvar wl-mime-save-directory nil "Last saved directory.")
 690 ;;; Yet another save method.
 691 (defun wl-mime-save-content (entity situation)
 692   (let ((filename (expand-file-name
 693                    (read-file-name "Save to file: "
 694                                    (expand-file-name
 695                                     (or (mime-entity-safe-filename entity)
 696                                         ".")
 697                                     (or wl-mime-save-directory
 698                                         wl-temporary-file-directory))))))
 699     (while (file-directory-p filename)
 700       (setq filename (read-file-name "Please set filename (not directory): "
 701                                      filename)))
 702     (if (and (file-exists-p filename)
 703              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 704                                        filename))))
 705         (message "Not saved")
 706       (setq wl-mime-save-directory (file-name-directory filename))
 707       (mime-write-entity-content entity filename))))
 708
 709 ;;; Yet another combine method.
 710 (defun wl-mime-combine-message/partial-pieces (entity situation)
 711   "Internal method for wl to combine message/partial messages automatically."
 712   (interactive)
 713   (let* ((folder (with-current-buffer wl-message-buffer-cur-summary-buffer
 714                    wl-summary-buffer-elmo-folder))
 715          (mime-display-header-hook 'wl-highlight-headers)
 716          (id (or (cdr (assoc "id" situation)) ""))
 717          (mother (current-buffer))
 718          (summary-buf wl-message-buffer-cur-summary-buffer)
 719          subject-id overviews
 720          (root-dir (expand-file-name
 721                     (concat "m-prts-" (user-login-name))
 722                     temporary-file-directory))
 723          full-file point)
 724     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 725     (setq full-file (concat root-dir "/FULL"))
 726     (if (or (file-exists-p full-file)
 727             (not (y-or-n-p "Merge partials? ")))
 728         (with-current-buffer mother
 729           (mime-store-message/partial-piece entity situation)
 730           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 731           (make-local-variable 'mime-preview-over-to-next-method-alist)
 732           (setq mime-preview-over-to-next-method-alist
 733                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 734                       mime-preview-over-to-next-method-alist))
 735           (make-local-variable 'mime-preview-over-to-previous-method-alist)
 736           (setq mime-preview-over-to-previous-method-alist
 737                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 738                       mime-preview-over-to-previous-method-alist)))
 739       (setq subject-id
 740             (eword-decode-string
 741              (decode-mime-charset-string
 742               (mime-entity-read-field entity 'Subject)
 743               wl-summary-buffer-mime-charset)))
 744       (if (string-match "[0-9\n]+" subject-id)
 745           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 746       (catch 'tag
 747         (elmo-folder-do-each-message-entity (entity folder)
 748           (when (string-match
 749                  (regexp-quote subject-id)
 750                  (elmo-message-entity-field entity 'subject))
 751             (let* ((message
 752                     ;; request message at the cursor in Subject buffer.
 753                     (wl-message-request-partial
 754                      (elmo-folder-name-internal folder)
 755                      (elmo-message-entity-number entity)))
 756                    (situation (mime-entity-situation message))
 757                    (the-id (or (cdr (assoc "id" situation)) "")))
 758               (when (string= (downcase the-id)
 759                              (downcase id))
 760                 (with-current-buffer mother
 761                   (mime-store-message/partial-piece message situation))
 762                 (if (file-exists-p full-file)
 763                     (throw 'tag nil))))))
 764         (message "Not all partials found.")))))
 765
 766 (defun wl-mime-display-text/plain (entity situation)
 767   (let ((beg (point)))
 768     (mime-display-text/plain entity situation)
 769     (wl-highlight-message beg (point-max) t t)))
 770
 771 (defun wl-mime-display-header (entity situation)
 772   (let ((elmo-message-ignored-field-list
 773          (if wl-message-buffer-require-all-header
 774              nil
 775            wl-message-ignored-field-list))
 776         (elmo-message-visible-field-list wl-message-visible-field-list)
 777         (elmo-message-sorted-field-list wl-message-sort-field-list))
 778     (elmo-mime-insert-header entity situation)
 779     (wl-highlight-headers)))
 780
 781 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 782   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 783         (original-buffer wl-message-buffer-original-buffer))
 784     (mime-decrypt-application/pgp-encrypted entity situation)
 785     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 786     (setq wl-message-buffer-original-buffer original-buffer)))
 787
 788
 789 ;;; Setup methods.
 790 (defun wl-mime-setup ()
 791   (set-alist 'mime-preview-quitting-method-alist
 792              'wl-original-message-mode 'wl-message-exit)
 793   (set-alist 'mime-view-over-to-previous-method-alist
 794              'wl-original-message-mode 'wl-message-exit)
 795   (set-alist 'mime-view-over-to-next-method-alist
 796              'wl-original-message-mode 'wl-message-exit)
 797   (set-alist 'mime-preview-over-to-previous-method-alist
 798              'wl-original-message-mode 'wl-message-exit)
 799   (set-alist 'mime-preview-over-to-next-method-alist
 800              'wl-original-message-mode 'wl-message-exit)
 801   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 802   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 803
 804   (ctree-set-calist-strictly
 805    'mime-preview-condition
 806    '((type . text) (subtype . plain)
 807      (body . visible)
 808      (body-presentation-method . wl-mime-display-text/plain)
 809      (major-mode . wl-original-message-mode)))
 810
 811   (ctree-set-calist-strictly
 812    'mime-preview-condition
 813    '((type . application)(subtype . pgp-encrypted)
 814      (encoding . t)
 815      (body . invisible)
 816      (body-presentation-method . wl-mime-preview-application/pgp-encrypted)
 817      (major-mode . wl-original-message-mode)))
 818
 819   (ctree-set-calist-strictly
 820    'mime-acting-condition
 821    '((type . message) (subtype . partial)
 822      (method .  wl-mime-combine-message/partial-pieces)
 823      (request-partial-message-method . wl-message-request-partial)
 824      (major-mode . wl-original-message-mode)))
 825
 826   (ctree-set-calist-strictly
 827    'mime-acting-condition
 828    '((type . application) (subtype . pgp-encrypted)
 829      (method . wl-mime-decrypt-application/pgp-encrypted)
 830      (major-mode . wl-original-message-mode)))
 831
 832   (ctree-set-calist-strictly
 833    'mime-acting-condition
 834    '((mode . "extract")
 835      (major-mode . wl-original-message-mode)
 836      (method . wl-mime-save-content)))
 837   (set-alist 'mime-preview-following-method-alist
 838              'wl-original-message-mode
 839              (function wl-message-follow-current-entity))
 840   (set-alist 'mime-view-following-method-alist
 841              'wl-original-message-mode
 842              (function wl-message-follow-current-entity))
 843   (set-alist 'mime-edit-message-inserter-alist
 844              'wl-draft-mode (function wl-draft-insert-current-message))
 845   (set-alist 'mime-edit-mail-inserter-alist
 846              'wl-draft-mode (function wl-draft-insert-get-message))
 847   (set-alist 'mime-edit-split-message-sender-alist
 848              'wl-draft-mode
 849              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 850   (set-alist 'mime-raw-representation-type-alist
 851              'wl-original-message-mode 'binary)
 852   ;; Sort and highlight header fields.
 853   (or wl-message-ignored-field-list
 854       (setq wl-message-ignored-field-list
 855             mime-view-ignored-field-list))
 856   (or wl-message-visible-field-list
 857       (setq wl-message-visible-field-list
 858             mime-view-visible-field-list))
 859   (set-alist 'mime-header-presentation-method-alist
 860              'wl-original-message-mode
 861              'wl-mime-display-header)
 862   ;; To avoid overriding wl-draft-mode-map.
 863   (when (boundp 'mime-setup-signature-key-alist)
 864     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 865       (setq mime-setup-signature-key-alist
 866             (cons '(wl-draft-mode . "\C-c\C-w")
 867                   mime-setup-signature-key-alist)))))
 868
 869 (require 'product)
 870 (product-provide (provide 'wl-mime) (require 'wl-version))
 871
 872 ;;; wl-mime.el ends here