wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'mime-view)
  33 (require 'mime-edit)
  34 (require 'mime-play)
  35 (require 'elmo)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'pgg-decrypt-region 'ignore)
  39   (defalias-maybe 'pgg-display-output-buffer 'ignore)
  40   (defalias-maybe 'pgg-verify-region 'ignore))
  41
  42 ;;; Draft
  43
  44 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  45
  46 (defalias 'wl-draft-decode-message-in-buffer
  47   'mime-edit-decode-message-in-buffer)
  48
  49 (defun wl-draft-yank-current-message-entity ()
  50   "Yank currently displayed message entity.
  51 By setting following-method as yank-content.
  52
  53 If region is active, yank region contents instead. \(this feature is available
  54 if and only if `transient-mark-mode' \(GNU Emacs\) or `zmacs-regions' \(XEmacs\)
  55 has Non-nil value\)"
  56   (let ((wl-draft-buffer (current-buffer))
  57         (mime-view-following-method-alist
  58          (list (cons 'wl-original-message-mode
  59                      (function wl-draft-yank-to-draft-buffer))))
  60         (mime-preview-following-method-alist
  61          (list (cons 'wl-original-message-mode
  62                      (function wl-draft-yank-to-draft-buffer)))))
  63     (if (get-buffer (wl-current-message-buffer))
  64         (save-excursion
  65           (set-buffer (wl-current-message-buffer))
  66           (save-restriction
  67             (widen)
  68             (if (wl-region-exists-p)
  69                 (wl-mime-preview-follow-current-region)
  70               (mime-preview-follow-current-entity)))))))
  71
  72 ;; modified mime-preview-follow-current-entity from mime-view.el
  73 (defun wl-mime-preview-follow-current-region ()
  74   "Write follow message to current region.
  75 It calls following-method selected from variable
  76 `mime-preview-following-method-alist'."
  77   (interactive)
  78   (let ((r-beg (region-beginning))
  79         (r-end (region-end))
  80         (entity (get-text-property (point-min)
  81                                    'mime-view-entity)))
  82     (let* ((mode (mime-preview-original-major-mode 'recursive))
  83            (new-name
  84             (format "%s-active-region" (buffer-name)))
  85            new-buf
  86            (the-buf (current-buffer))
  87            fields)
  88       (save-excursion
  89         (set-buffer (setq new-buf (get-buffer-create new-name)))
  90         (erase-buffer)
  91         (insert ?\n)
  92         (insert-buffer-substring the-buf r-beg r-end)
  93         (goto-char (point-min))
  94         (let ((current-entity
  95                (if (and (eq (mime-entity-media-type entity) 'message)
  96                         (eq (mime-entity-media-subtype entity) 'rfc822))
  97                    (car (mime-entity-children entity))
  98                  entity)))
  99           (while (and current-entity
 100                       (if (and (eq (mime-entity-media-type
 101                                     current-entity) 'message)
 102                                (eq (mime-entity-media-subtype
 103                                     current-entity) 'rfc822))
 104                           nil
 105                         (mime-insert-header current-entity fields)
 106                         t))
 107             (setq fields (std11-collect-field-names)
 108                   current-entity (mime-entity-parent current-entity))
 109             ))
 110         (let ((rest mime-view-following-required-fields-list)
 111               field-name ret)
 112           (while rest
 113             (setq field-name (car rest))
 114             (or (std11-field-body field-name)
 115                 (progn
 116                   (save-excursion
 117                     (set-buffer the-buf)
 118                     (let ((entity (when mime-mother-buffer
 119                                     (set-buffer mime-mother-buffer)
 120                                     (get-text-property (point)
 121                                                        'mime-view-entity))))
 122                       (while (and entity
 123                                   (null (setq ret (mime-entity-fetch-field
 124                                                    entity field-name))))
 125                         (setq entity (mime-entity-parent entity)))))
 126                   (if ret
 127                       (insert (concat field-name ": " ret "\n"))
 128                     )))
 129             (setq rest (cdr rest))
 130             ))
 131         )
 132       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 133         (if (functionp f)
 134             (funcall f new-buf)
 135           (message
 136            (format
 137             "Sorry, following method for %s is not implemented yet."
 138             mode))
 139           ))
 140       )))
 141
 142 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
 143
 144 (defun wl-draft-preview-message ()
 145   "Preview editing message."
 146   (interactive)
 147   (let* (recipients-message
 148          (current-point (point))
 149          (config-exec-flag wl-draft-config-exec-flag)
 150          (parent-folder wl-draft-parent-folder)
 151          (mime-display-header-hook 'wl-highlight-headers)
 152          (mime-header-encode-method-alist
 153           (append
 154            '((wl-draft-eword-encode-address-list
 155               .  (To Cc Bcc Resent-To Resent-Cc Bcc Resent-Bcc)))
 156            (if (boundp 'mime-header-encode-method-alist)
 157                (symbol-value 'mime-header-encode-method-alist))))
 158          mime-view-ignored-field-list   ; all header.
 159          (mime-edit-translate-buffer-hook
 160           (append
 161            (list
 162             (function
 163              (lambda ()
 164                (let ((wl-draft-config-exec-flag config-exec-flag)
 165                      (wl-draft-parent-folder parent-folder))
 166                  (goto-char current-point)
 167                  (run-hooks 'wl-draft-send-hook)
 168                  (setq recipients-message
 169                        (condition-case err
 170                            (concat "Recipients: "
 171                                    (mapconcat
 172                                     'identity
 173                                     (wl-draft-deduce-address-list
 174                                      (current-buffer)
 175                                      (point-min)
 176                                      (save-excursion
 177                                        (goto-char (point-min))
 178                                        (re-search-forward
 179                                         (concat
 180                                          "^"
 181                                          (regexp-quote mail-header-separator)
 182                                          "$")
 183                                         nil t)
 184                                        (point)))
 185                                     ", "))
 186                          (error
 187                           (kill-buffer (current-buffer))
 188                           (signal (car err) (cdr err)))))))))
 189            mime-edit-translate-buffer-hook)))
 190     (mime-edit-preview-message)
 191     (let ((buffer-read-only nil))
 192       (when wl-highlight-body-too
 193         (wl-highlight-body))
 194       (run-hooks 'wl-draft-preview-message-hook))
 195     (message recipients-message)))
 196
 197 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 198
 199 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 200
 201 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 202
 203 ;;; Message
 204
 205 (defun wl-message-decode-mode (outbuf inbuf)
 206   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 207         (mime-display-header-hook 'wl-highlight-headers))
 208     (mime-view-mode nil nil nil inbuf outbuf)))
 209
 210 (defun wl-message-decode-with-all-header (outbuf inbuf)
 211   (let ((mime-view-ignored-field-regexp "^:$")
 212         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 213         (mime-display-header-hook 'wl-highlight-headers)
 214         mime-view-ignored-field-list)
 215     (mime-view-mode nil nil nil inbuf outbuf)))
 216
 217 (defun wl-message-delete-mime-out-buf ()
 218   (let (mime-out-buf mime-out-win)
 219     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 220         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 221             (delete-window mime-out-win)))))
 222
 223 (defun wl-message-request-partial (folder number)
 224   (elmo-set-work-buf
 225    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 226                        number
 227                        (elmo-make-fetch-strategy 'entire)
 228                        nil
 229                        (current-buffer)
 230                        'unread)
 231    (mime-parse-buffer nil)))
 232
 233 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 234 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 235 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 236 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 237 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 238 (defalias 'wl-message-quit              'mime-preview-quit)
 239 (defalias 'wl-message-button-dispatcher-internal
 240   'mime-button-dispatcher)
 241
 242 (defsubst wl-mime-node-id-to-string (node-id)
 243   (if (consp node-id)
 244       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 245                  (reverse node-id)
 246                  ".")
 247     "0"))
 248
 249 (defun wl-message-delete-current-part ()
 250   "Delete a part under the cursor from the multipart message."
 251   (interactive)
 252   (save-restriction
 253     (widen)
 254     (let* ((entity (get-text-property (point) 'mime-view-entity))
 255            (node-id (mime-entity-node-id entity))
 256            (header-start (mime-buffer-entity-header-start-internal entity))
 257            (body-end (mime-buffer-entity-body-end-internal entity))
 258            (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 259            (number wl-message-buffer-cur-number)
 260            (msgid (elmo-message-field folder number 'message-id))
 261            (orig-buf wl-message-buffer-original-buffer))
 262       (if (eq (luna-class-name entity) 'mime-elmo-imap-entity)
 263           (error "Please fetch the entire message (by typing 'C-u .') and try again"))
 264       (with-current-buffer orig-buf
 265         (unless (string-equal
 266                  (buffer-string)
 267                  (elmo-message-fetch folder number
 268                                      (elmo-make-fetch-strategy 'entire)))
 269           (error "Buffer content differs from actual message")))
 270       (when (and (elmo-folder-writable-p folder)
 271                  (buffer-live-p orig-buf)
 272                  node-id
 273                  (yes-or-no-p
 274                   (format "Do you really want to delete part %s? "
 275                           (wl-mime-node-id-to-string node-id))))
 276         (with-temp-buffer
 277           (insert-buffer orig-buf)
 278           (delete-region header-start body-end)
 279           (goto-char header-start)
 280           (insert "Content-Type: text/plain; charset=US-ASCII\n\n")
 281           (insert "** This part has been removed by Wanderlust **\n\n")
 282           (elmo-folder-append-buffer folder t))
 283
 284         (elmo-folder-append-messages
 285          (wl-folder-get-elmo-folder wl-trash-folder)
 286          folder (list number) nil)
 287         (elmo-folder-delete-messages folder (list number))
 288
 289         (when (file-exists-p (elmo-cache-get-path msgid))
 290           (delete-file (elmo-cache-get-path msgid)))
 291
 292         (mime-preview-quit)
 293         (wl-summary-toggle-disp-msg 'off)
 294         (wl-summary-sync nil "update")))))
 295
 296 (defun wl-message-decrypt-pgp-nonmime ()
 297   "Decrypt PGP encrypted region"
 298   (interactive)
 299   (require 'pgg)
 300   (save-excursion
 301     (beginning-of-line)
 302     (if (or (re-search-forward "^-+END PGP MESSAGE-+$" nil t)
 303             (re-search-backward "^-+END PGP MESSAGE-+$" nil t))
 304         (let (beg end status)
 305           (setq end (match-end 0))
 306           (if (setq beg (re-search-backward "^-+BEGIN PGP MESSAGE-+$" nil t))
 307               (let ((inhibit-read-only t)
 308                     (buffer-file-coding-system wl-cs-autoconv))
 309                 (setq status (pgg-decrypt-region beg end))
 310                 (pgg-display-output-buffer beg end status))
 311             (message "Cannot find pgp encrypted region")))
 312       (message "Cannot find pgp encrypted region"))))
 313
 314 (defun wl-message-verify-pgp-nonmime (&optional arg)
 315   "Verify PGP signed region.
 316 With ARG, ask coding system and encode the region with it before verifying."
 317   (interactive "P")
 318   (require 'pgg)
 319   (save-excursion
 320     (beginning-of-line)
 321     (let ((msg-buf (current-buffer))
 322           beg end status m-beg)
 323       (if (and (when (or (re-search-forward "^-+END PGP SIGNATURE-+$" nil t)
 324                          (re-search-backward "^-+END PGP SIGNATURE-+$" nil t))
 325                  (setq end (match-end 0)))
 326                (setq beg (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t)))
 327           (progn
 328             (if arg
 329                 (with-temp-buffer
 330                   (insert-buffer-substring msg-buf beg end)
 331                   (set-mark (point-min))
 332                   (goto-char (point-max))
 333                   (call-interactively 'encode-coding-region)
 334                   (setq status (pgg-verify-region (point-min) (point-max) nil 'fetch)))
 335               (let* ((situation (mime-preview-find-boundary-info))
 336                      (p-end (aref situation 1))
 337                      (entity (aref situation 2))
 338                      (count 0))
 339                 (goto-char p-end)
 340                 (while (< beg (point))
 341                   (if (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t)
 342                       (setq count (+ count 1))
 343                     (debug)))
 344                 (with-temp-buffer
 345                   (insert (mime-entity-body entity))
 346                   (goto-char (point-max))
 347                   (while (> count 0)
 348                     (if (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t)
 349                         (setq count (- count 1))
 350                       (debug)))
 351                   (let ((r-beg (point))
 352                         (r-end (re-search-forward "^-+END PGP SIGNATURE-+$" nil t)))
 353                     (if r-end
 354                         (setq status (pgg-verify-region r-beg r-end nil 'fetch))
 355                       (debug))))))
 356             (mime-show-echo-buffer)
 357             (set-buffer mime-echo-buffer-name)
 358             (set-window-start
 359              (get-buffer-window mime-echo-buffer-name)
 360              (point-max))
 361             (setq m-beg (point))
 362             (insert-buffer-substring
 363              (if status pgg-output-buffer pgg-errors-buffer))
 364             (encode-coding-region m-beg (point) buffer-file-coding-system)
 365             (decode-coding-region m-beg (point) wl-cs-autoconv))
 366         (message "Cannot find pgp signed region")))))
 367
 368 ;; XXX: encrypted multipart isn't represented as multipart
 369 (defun wl-mime-preview-application/pgp (parent-entity entity situation)
 370   (require 'pgg)
 371   (goto-char (point-max))
 372   (let ((p (point))
 373         raw-buf to-buf representation-type child-entity)
 374     (goto-char p)
 375     (save-restriction
 376       (narrow-to-region p p)
 377       (setq to-buf (current-buffer))
 378       (with-temp-buffer
 379         (setq raw-buf (current-buffer))
 380         (mime-insert-entity entity)
 381         (when (progn
 382                 (goto-char (point-min))
 383                 (re-search-forward "^-+BEGIN PGP MESSAGE-+$" nil t))
 384           (pgg-decrypt-region (point-min)(point-max))
 385           (delete-region (point-min) (point-max))
 386           (insert-buffer pgg-output-buffer)
 387           (setq representation-type 'elmo-buffer))
 388         (setq child-entity (mime-parse-message
 389                             (mm-expand-class-name representation-type)
 390                             nil
 391                             parent-entity
 392                             (mime-entity-node-id-internal parent-entity)))
 393         (mime-display-entity
 394          child-entity
 395          nil
 396          `((header . visible)
 397            (body . visible)
 398            (entity-button . invisible))
 399          to-buf)))))
 400
 401 (defun wl-mime-preview-application/pgp-encrypted (entity situation)
 402   (let* ((entity-node-id (mime-entity-node-id entity))
 403          (mother (mime-entity-parent entity))
 404          (knum (car entity-node-id))
 405          (onum (if (> knum 0)
 406                    (1- knum)
 407                  (1+ knum)))
 408          (orig-entity (nth onum (mime-entity-children mother))))
 409     (wl-mime-preview-application/pgp entity orig-entity situation)))
 410
 411 ;;; Summary
 412 (defun wl-summary-burst-subr (message-entity target number)
 413   ;; returns new number.
 414   (let (content-type entity)
 415     (setq content-type (mime-entity-content-type message-entity))
 416     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 417            (dolist (entity (mime-entity-children message-entity))
 418              (setq number (wl-summary-burst-subr
 419                            entity
 420                            target
 421                            number))))
 422           ((and (eq (cdr (assq 'type content-type)) 'message)
 423                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 424            (message "Bursting...%s" (setq number (+ 1 number)))
 425            (setq entity
 426                  (car (mime-entity-children message-entity)))
 427            (with-temp-buffer
 428              (insert (mime-entity-body message-entity))
 429              (elmo-folder-append-buffer
 430               target
 431               (mime-entity-fetch-field entity "Message-ID")))))
 432     number))
 433
 434 (defun wl-summary-burst (&optional arg)
 435   "De-capsulate embedded messages in MIME format.
 436 With ARG, ask destination folder."
 437   (interactive "P")
 438   (let ((raw-buf (wl-summary-get-original-buffer))
 439         (view-buf wl-message-buffer)
 440         children message-entity content-type target)
 441     (save-excursion
 442       (setq target wl-summary-buffer-elmo-folder)
 443       (when (or arg (not (elmo-folder-writable-p target)))
 444         (let ((fld (wl-summary-read-folder wl-default-folder "to extract to")))
 445           (setq target (wl-folder-get-elmo-folder fld))))
 446       (wl-summary-set-message-buffer-or-redisplay)
 447       (with-current-buffer view-buf
 448         (setq message-entity (get-text-property (point-min) 'mime-view-entity)))
 449       (when message-entity
 450         (message "Bursting...")
 451         (with-current-buffer raw-buf
 452           (wl-summary-burst-subr message-entity target 0))
 453         (message "Bursting...done"))
 454       (if (elmo-folder-plugged-p target)
 455           (elmo-folder-check target)))
 456     (wl-summary-sync-update)))
 457
 458 ;; internal variable.
 459 (defvar wl-mime-save-directory nil "Last saved directory.")
 460 ;;; Yet another save method.
 461 (defun wl-mime-save-content (entity situation)
 462   (let ((filename (read-file-name "Save to file: "
 463                                   (expand-file-name
 464                                    (or (mime-entity-safe-filename entity)
 465                                        ".")
 466                                    (or wl-mime-save-directory
 467                                        wl-temporary-file-directory)))))
 468     (while (file-directory-p filename)
 469       (setq filename (read-file-name "Please set filename (not directory): "
 470                                      filename)))
 471     (if (and (file-exists-p filename)
 472              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 473                                        filename))))
 474         (message "Not saved")
 475       (setq wl-mime-save-directory (file-name-directory filename))
 476       (mime-write-entity-content entity filename))))
 477
 478 ;;; Yet another combine method.
 479 (defun wl-mime-combine-message/partial-pieces (entity situation)
 480   "Internal method for wl to combine message/partial messages automatically."
 481   (interactive)
 482   (let* ((msgdb (save-excursion
 483                   (set-buffer wl-message-buffer-cur-summary-buffer)
 484                   (wl-summary-buffer-msgdb)))
 485          (mime-display-header-hook 'wl-highlight-headers)
 486          (folder wl-message-buffer-cur-folder)
 487          (id (or (cdr (assoc "id" situation)) ""))
 488          (mother (current-buffer))
 489          (summary-buf wl-message-buffer-cur-summary-buffer)
 490          subject-id overviews
 491          (root-dir (expand-file-name
 492                     (concat "m-prts-" (user-login-name))
 493                     temporary-file-directory))
 494          full-file point)
 495     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 496     (setq full-file (concat root-dir "/FULL"))
 497     (if (or (file-exists-p full-file)
 498             (not (y-or-n-p "Merge partials? ")))
 499         (with-current-buffer mother
 500           (mime-store-message/partial-piece entity situation)
 501           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 502           (make-variable-buffer-local 'mime-preview-over-to-next-method-alist)
 503           (setq mime-preview-over-to-next-method-alist
 504                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 505                       mime-preview-over-to-next-method-alist))
 506           (make-variable-buffer-local 'mime-preview-over-to-previous-method-alist)
 507           (setq mime-preview-over-to-previous-method-alist
 508                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 509                       mime-preview-over-to-previous-method-alist)))
 510       (setq subject-id
 511             (eword-decode-string
 512              (decode-mime-charset-string
 513               (mime-entity-read-field entity 'Subject)
 514               wl-summary-buffer-mime-charset)))
 515       (if (string-match "[0-9\n]+" subject-id)
 516           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 517       (setq overviews (elmo-msgdb-get-overview msgdb))
 518       (catch 'tag
 519         (while overviews
 520           (when (string-match
 521                  (regexp-quote subject-id)
 522                  (elmo-msgdb-overview-entity-get-subject (car overviews)))
 523             (let* ((message
 524                     ;; request message at the cursor in Subject buffer.
 525                     (wl-message-request-partial
 526                      folder
 527                      (elmo-msgdb-overview-entity-get-number
 528                       (car overviews))))
 529                    (situation (mime-entity-situation message))
 530                    (the-id (or (cdr (assoc "id" situation)) "")))
 531               (when (string= (downcase the-id)
 532                              (downcase id))
 533                 (with-current-buffer mother
 534                   (mime-store-message/partial-piece message situation))
 535                 (if (file-exists-p full-file)
 536                     (throw 'tag nil)))))
 537           (setq overviews (cdr overviews)))
 538         (message "Not all partials found.")))))
 539
 540 (defun wl-mime-display-text/plain (entity situation)
 541   (let ((beg (point)))
 542     (mime-display-text/plain entity situation)
 543     (wl-highlight-message beg (point-max) t t)))
 544
 545 (defun wl-mime-display-header (entity situation)
 546   (let ((elmo-message-ignored-field-list
 547          (if wl-message-buffer-all-header-flag
 548              nil
 549            wl-message-ignored-field-list))
 550         (elmo-message-visible-field-list wl-message-visible-field-list)
 551         (elmo-message-sorted-field-list wl-message-sort-field-list))
 552     (elmo-mime-insert-header entity situation)
 553     (wl-highlight-headers)))
 554
 555 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 556   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 557         (original-buffer wl-message-buffer-original-buffer))
 558     (mime-decrypt-application/pgp-encrypted entity situation)
 559     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 560     (setq wl-message-buffer-original-buffer original-buffer)))
 561
 562
 563 ;;; Setup methods.
 564 (defun wl-mime-setup ()
 565   (set-alist 'mime-preview-quitting-method-alist
 566              'wl-original-message-mode 'wl-message-exit)
 567   (set-alist 'mime-view-over-to-previous-method-alist
 568              'wl-original-message-mode 'wl-message-exit)
 569   (set-alist 'mime-view-over-to-next-method-alist
 570              'wl-original-message-mode 'wl-message-exit)
 571   (set-alist 'mime-preview-over-to-previous-method-alist
 572              'wl-original-message-mode 'wl-message-exit)
 573   (set-alist 'mime-preview-over-to-next-method-alist
 574              'wl-original-message-mode 'wl-message-exit)
 575   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 576   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 577
 578   (ctree-set-calist-strictly
 579    'mime-preview-condition
 580    '((type . text) (subtype . plain)
 581      (body . visible)
 582      (body-presentation-method . wl-mime-display-text/plain)
 583      (major-mode . wl-original-message-mode)))
 584
 585   (ctree-set-calist-strictly
 586    'mime-preview-condition
 587    '((type . application)(subtype . pgp-encrypted)
 588      (encoding . t)
 589      (body . invisible)
 590      (body-presentation-method . wl-mime-preview-application/pgp-encrypted)
 591      (major-mode . wl-original-message-mode)))
 592
 593   (ctree-set-calist-strictly
 594    'mime-acting-condition
 595    '((type . message) (subtype . partial)
 596      (method .  wl-mime-combine-message/partial-pieces)
 597      (request-partial-message-method . wl-message-request-partial)
 598      (major-mode . wl-original-message-mode)))
 599
 600   (ctree-set-calist-strictly
 601    'mime-acting-condition
 602    '((type . application) (subtype . pgp-encrypted)
 603      (method . wl-mime-decrypt-application/pgp-encrypted)
 604      (major-mode . wl-original-message-mode)))
 605
 606   (ctree-set-calist-strictly
 607    'mime-acting-condition
 608    '((mode . "extract")
 609      (major-mode . wl-original-message-mode)
 610      (method . wl-mime-save-content)))
 611   (set-alist 'mime-preview-following-method-alist
 612              'wl-original-message-mode
 613              (function wl-message-follow-current-entity))
 614   (set-alist 'mime-view-following-method-alist
 615              'wl-original-message-mode
 616              (function wl-message-follow-current-entity))
 617   (set-alist 'mime-edit-message-inserter-alist
 618              'wl-draft-mode (function wl-draft-insert-current-message))
 619   (set-alist 'mime-edit-mail-inserter-alist
 620              'wl-draft-mode (function wl-draft-insert-get-message))
 621   (set-alist 'mime-edit-split-message-sender-alist
 622              'wl-draft-mode
 623              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 624   (set-alist 'mime-raw-representation-type-alist
 625              'wl-original-message-mode 'binary)
 626   ;; Sort and highlight header fields.
 627   (or wl-message-ignored-field-list
 628       (setq wl-message-ignored-field-list
 629             mime-view-ignored-field-list))
 630   (or wl-message-visible-field-list
 631       (setq wl-message-visible-field-list
 632             mime-view-visible-field-list))
 633   (set-alist 'mime-header-presentation-method-alist
 634              'wl-original-message-mode
 635              'wl-mime-display-header)
 636   ;; To avoid overriding wl-draft-mode-map.
 637   (when (boundp 'mime-setup-signature-key-alist)
 638     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 639       (setq mime-setup-signature-key-alist
 640             (cons '(wl-draft-mode . "\C-c\C-w")
 641                   mime-setup-signature-key-alist)))))
 642
 643 (require 'product)
 644 (product-provide (provide 'wl-mime) (require 'wl-version))
 645
 646 ;;; wl-mime.el ends here