wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'mime-view)
  33 (require 'mime-edit)
  34 (require 'mime-play)
  35 (require 'elmo)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'Meadow-version 'ignore))
  39
  40 (defvar xemacs-betaname)
  41 (defvar xemacs-codename)
  42 (defvar enable-multibyte-characters)
  43 (defvar mule-version)
  44
  45 ;;; Draft
  46
  47 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  48
  49 (defalias 'wl-draft-decode-message-in-buffer
  50   'mime-edit-decode-message-in-buffer)
  51
  52 (defun wl-draft-yank-current-message-entity ()
  53   "Yank currently displayed message entity.
  54 By setting following-method as yank-content."
  55   (let ((wl-draft-buffer (current-buffer))
  56         (mime-view-following-method-alist
  57          (list (cons 'wl-original-message-mode
  58                      (function wl-draft-yank-to-draft-buffer))))
  59         (mime-preview-following-method-alist
  60          (list (cons 'wl-original-message-mode
  61                      (function wl-draft-yank-to-draft-buffer)))))
  62     (if (get-buffer (wl-current-message-buffer))
  63         (save-excursion
  64           (save-restriction
  65             (set-buffer (wl-current-message-buffer))
  66             (widen)
  67             (mime-preview-follow-current-entity))))))
  68
  69 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
  70
  71 (defun wl-draft-preview-message ()
  72   ""
  73   (interactive)
  74   (let* (recipients-message
  75          (config-exec-flag wl-draft-config-exec-flag)
  76          (mime-display-header-hook 'wl-highlight-headers)
  77          (mime-header-encode-method-alist
  78           (append
  79            '((wl-draft-eword-encode-address-list
  80               .  (To Cc Bcc Resent-To Resent-Cc Bcc Resent-Bcc)))
  81            mime-header-encode-method-alist))
  82          mime-view-ignored-field-list   ; all header.
  83          (mime-edit-translate-buffer-hook
  84           (append
  85            (list
  86             (function
  87              (lambda ()
  88                (let ((wl-draft-config-exec-flag config-exec-flag))
  89                  (run-hooks 'wl-draft-send-hook)
  90                  (setq recipients-message
  91                        (condition-case err
  92                            (concat "Recipients: "
  93                                    (mapconcat
  94                                     'identity
  95                                     (wl-draft-deduce-address-list
  96                                      (current-buffer)
  97                                      (point-min)
  98                                      (save-excursion
  99                                        (goto-char (point-min))
 100                                        (re-search-forward
 101                                         (concat
 102                                          "^"
 103                                          (regexp-quote mail-header-separator)
 104                                          "$")
 105                                         nil t)
 106                                        (point)))
 107                                     ", "))
 108                          (error
 109                           (kill-buffer (current-buffer))
 110                           (signal (car err) (cdr err)))))))))
 111            mime-edit-translate-buffer-hook)))
 112     (mime-edit-preview-message)
 113     (let ((buffer-read-only nil))
 114       (when wl-highlight-body-too
 115         (wl-highlight-body))
 116       (run-hooks 'wl-draft-preview-message-hook))
 117     (message recipients-message)))
 118
 119 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 120
 121 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 122
 123 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 124
 125 ;;; Message
 126
 127 (defun wl-message-decode-mode (outbuf inbuf)
 128   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 129         (mime-display-header-hook 'wl-highlight-headers))
 130     (mime-view-mode nil nil nil inbuf outbuf)))
 131
 132 (defun wl-message-decode-with-all-header (outbuf inbuf)
 133   (let ((mime-view-ignored-field-regexp "^:$")
 134         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 135         (mime-display-header-hook 'wl-highlight-headers)
 136         mime-view-ignored-field-list)
 137     (mime-view-mode nil nil nil inbuf outbuf)))
 138
 139 (defun wl-message-delete-mime-out-buf ()
 140   (let (mime-out-buf mime-out-win)
 141     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 142         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 143             (delete-window mime-out-win)))))
 144
 145 (defun wl-message-request-partial (folder number)
 146   (elmo-set-work-buf
 147    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 148                        number
 149                        (elmo-make-fetch-strategy 'entire)
 150                        nil
 151                        (current-buffer)
 152                        'unread)
 153    (mime-parse-buffer nil)))
 154
 155 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 156 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 157 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 158 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 159 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 160 (defalias 'wl-message-quit              'mime-preview-quit)
 161 (defalias 'wl-message-button-dispatcher-internal
 162   'mime-button-dispatcher)
 163
 164 ;;; Summary
 165 (defun wl-summary-burst-subr (message-entity target number)
 166   ;; returns new number.
 167   (let (content-type entity)
 168     (setq content-type (mime-entity-content-type message-entity))
 169     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 170            (dolist (entity (mime-entity-children message-entity))
 171              (setq number (wl-summary-burst-subr
 172                            entity
 173                            target
 174                            number))))
 175           ((and (eq (cdr (assq 'type content-type)) 'message)
 176                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 177            (message "Bursting...%s" (setq number (+ 1 number)))
 178            (setq entity
 179                  (car (mime-entity-children message-entity)))
 180            (with-temp-buffer
 181              (insert (mime-entity-body message-entity))
 182              (elmo-folder-append-buffer
 183               target
 184               (mime-entity-fetch-field entity "Message-ID")))))
 185     number))
 186
 187 (defun wl-summary-burst ()
 188   ""
 189   (interactive)
 190   (let ((raw-buf (wl-summary-get-original-buffer))
 191         (view-buf wl-message-buffer)
 192         children message-entity content-type target)
 193     (save-excursion
 194       (setq target wl-summary-buffer-elmo-folder)
 195       (while (not (elmo-folder-writable-p target))
 196         (setq target
 197               (wl-summary-read-folder wl-default-folder "to extract to")))
 198       (wl-summary-set-message-buffer-or-redisplay)
 199       (with-current-buffer view-buf
 200         (setq message-entity (get-text-property (point-min) 'mime-view-entity)))
 201       (when message-entity
 202         (message "Bursting...")
 203         (with-current-buffer raw-buf
 204           (wl-summary-burst-subr message-entity target 0))
 205         (message "Bursting...done"))
 206       (if (elmo-folder-plugged-p target)
 207           (elmo-folder-check target)))
 208     (wl-summary-sync-update)))
 209
 210 ;; internal variable.
 211 (defvar wl-mime-save-directory nil "Last saved directory.")
 212 ;;; Yet another save method.
 213 (defun wl-mime-save-content (entity situation)
 214   (let ((filename (read-file-name "Save to file: "
 215                                   (expand-file-name
 216                                    (or (mime-entity-safe-filename entity)
 217                                        ".")
 218                                    (or wl-mime-save-directory
 219                                        wl-temporary-file-directory)))))
 220     (while (file-directory-p filename)
 221       (setq filename (read-file-name "Please set filename (not directory): "
 222                                      filename)))
 223     (if (file-exists-p filename)
 224         (or (yes-or-no-p (format "File %s exists. Save anyway? " filename))
 225             (message "Not saved")))
 226     (setq wl-mime-save-directory (file-name-directory filename))
 227     (mime-write-entity-content entity filename)))
 228
 229 ;;; Yet another combine method.
 230 (defun wl-mime-combine-message/partial-pieces (entity situation)
 231   "Internal method for wl to combine message/partial messages automatically."
 232   (interactive)
 233   (let* ((msgdb (save-excursion
 234                   (set-buffer wl-message-buffer-cur-summary-buffer)
 235                   (wl-summary-buffer-msgdb)))
 236          (mime-display-header-hook 'wl-highlight-headers)
 237          (folder wl-message-buffer-cur-folder)
 238          (id (or (cdr (assoc "id" situation)) ""))
 239          (mother (current-buffer))
 240          (summary-buf wl-message-buffer-cur-summary-buffer)
 241          subject-id overviews
 242          (root-dir (expand-file-name
 243                     (concat "m-prts-" (user-login-name))
 244                     temporary-file-directory))
 245          full-file point)
 246     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 247     (setq full-file (concat root-dir "/FULL"))
 248     (if (or (file-exists-p full-file)
 249             (not (y-or-n-p "Merge partials? ")))
 250         (with-current-buffer mother
 251           (mime-store-message/partial-piece entity situation)
 252           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 253           (make-variable-buffer-local 'mime-preview-over-to-next-method-alist)
 254           (setq mime-preview-over-to-next-method-alist
 255                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 256                       mime-preview-over-to-next-method-alist))
 257           (make-variable-buffer-local 'mime-preview-over-to-previous-method-alist)
 258           (setq mime-preview-over-to-previous-method-alist
 259                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 260                       mime-preview-over-to-previous-method-alist)))
 261       (setq subject-id
 262             (eword-decode-string
 263              (decode-mime-charset-string
 264               (mime-entity-read-field entity 'Subject)
 265               wl-summary-buffer-mime-charset)))
 266       (if (string-match "[0-9\n]+" subject-id)
 267           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 268       (setq overviews (elmo-msgdb-get-overview msgdb))
 269       (catch 'tag
 270         (while overviews
 271           (when (string-match
 272                  (regexp-quote subject-id)
 273                  (elmo-msgdb-overview-entity-get-subject (car overviews)))
 274             (let* ((message
 275                     ;; request message at the cursor in Subject buffer.
 276                     (wl-message-request-partial
 277                      folder
 278                      (elmo-msgdb-overview-entity-get-number
 279                       (car overviews))))
 280                    (situation (mime-entity-situation message))
 281                    (the-id (or (cdr (assoc "id" situation)) "")))
 282               (when (string= (downcase the-id)
 283                              (downcase id))
 284                 (with-current-buffer mother
 285                   (mime-store-message/partial-piece message situation))
 286                 (if (file-exists-p full-file)
 287                     (throw 'tag nil)))))
 288           (setq overviews (cdr overviews)))
 289         (message "Not all partials found.")))))
 290
 291 (defun wl-mime-display-text/plain (entity situation)
 292   (let ((beg (point)))
 293     (mime-display-text/plain entity situation)
 294     (wl-highlight-message beg (point-max) t t)))
 295
 296 (defun wl-mime-display-header (entity situation)
 297   (let ((elmo-message-ignored-field-list
 298          (if wl-message-buffer-all-header-flag
 299              nil
 300            wl-message-ignored-field-list))
 301         (elmo-message-visible-field-list wl-message-visible-field-list)
 302         (elmo-message-sorted-field-list wl-message-sort-field-list))
 303     (elmo-mime-insert-header entity situation)
 304     (wl-highlight-headers)))
 305
 306 ;;; Setup methods.
 307 (defun wl-mime-setup ()
 308   (set-alist 'mime-preview-quitting-method-alist
 309              'wl-original-message-mode 'wl-message-exit)
 310   (set-alist 'mime-view-over-to-previous-method-alist
 311              'wl-original-message-mode 'wl-message-exit)
 312   (set-alist 'mime-view-over-to-next-method-alist
 313              'wl-original-message-mode 'wl-message-exit)
 314   (set-alist 'mime-preview-over-to-previous-method-alist
 315              'wl-original-message-mode 'wl-message-exit)
 316   (set-alist 'mime-preview-over-to-next-method-alist
 317              'wl-original-message-mode 'wl-message-exit)
 318   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 319   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 320
 321   (ctree-set-calist-strictly
 322    'mime-preview-condition
 323    '((type . text) (subtype . plain)
 324      (body . visible)
 325      (body-presentation-method . wl-mime-display-text/plain)
 326      (major-mode . wl-original-message-mode)))
 327
 328   (ctree-set-calist-strictly
 329    'mime-acting-condition
 330    '((type . message) (subtype . partial)
 331      (method .  wl-mime-combine-message/partial-pieces)
 332      (request-partial-message-method . wl-message-request-partial)
 333      (major-mode . wl-original-message-mode)))
 334
 335   (ctree-set-calist-strictly
 336    'mime-acting-condition
 337    '((mode . "extract")
 338      (major-mode . wl-original-message-mode)
 339      (method . wl-mime-save-content)))
 340   (set-alist 'mime-preview-following-method-alist
 341              'wl-original-message-mode
 342              (function wl-message-follow-current-entity))
 343   (set-alist 'mime-view-following-method-alist
 344              'wl-original-message-mode
 345              (function wl-message-follow-current-entity))
 346   (set-alist 'mime-edit-message-inserter-alist
 347              'wl-draft-mode (function wl-draft-insert-current-message))
 348   (set-alist 'mime-edit-mail-inserter-alist
 349              'wl-draft-mode (function wl-draft-insert-get-message))
 350   (set-alist 'mime-edit-split-message-sender-alist
 351              'wl-draft-mode
 352              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 353   (set-alist 'mime-raw-representation-type-alist
 354              'wl-original-message-mode 'binary)
 355   ;; Sort and highlight header fields.
 356   (or wl-message-ignored-field-list
 357       (setq wl-message-ignored-field-list
 358             mime-view-ignored-field-list))
 359   (or wl-message-visible-field-list
 360       (setq wl-message-visible-field-list
 361             mime-view-visible-field-list))
 362   (set-alist 'mime-header-presentation-method-alist
 363              'wl-original-message-mode
 364              'wl-mime-display-header)
 365   ;; To avoid overriding wl-draft-mode-map.
 366   (when (boundp 'mime-setup-signature-key-alist)
 367     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 368       (setq mime-setup-signature-key-alist
 369             (cons '(wl-draft-mode . "\C-c\C-w")
 370                   mime-setup-signature-key-alist)))))
 371
 372 (require 'product)
 373 (product-provide (provide 'wl-mime) (require 'wl-version))
 374
 375 ;;; wl-mime.el ends here