wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'mime-view)
  33 (require 'mime-edit)
  34 (require 'mime-play)
  35 (require 'elmo)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'Meadow-version 'ignore))
  39
  40 (defvar xemacs-betaname)
  41 (defvar xemacs-codename)
  42 (defvar enable-multibyte-characters)
  43 (defvar mule-version)
  44
  45 ;;; Draft
  46
  47 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  48
  49 (defalias 'wl-draft-decode-message-in-buffer
  50   'mime-edit-decode-message-in-buffer)
  51
  52 (defun wl-draft-yank-current-message-entity ()
  53   "Yank currently displayed message entity.
  54 By setting following-method as yank-content."
  55   (let ((wl-draft-buffer (current-buffer))
  56         (mime-view-following-method-alist
  57          (list (cons 'wl-original-message-mode
  58                      (function wl-draft-yank-to-draft-buffer))))
  59         (mime-preview-following-method-alist
  60          (list (cons 'wl-original-message-mode
  61                      (function wl-draft-yank-to-draft-buffer)))))
  62     (if (get-buffer (wl-current-message-buffer))
  63         (save-excursion
  64           (save-restriction
  65             (set-buffer (wl-current-message-buffer))
  66             (widen)
  67             (mime-preview-follow-current-entity))))))
  68
  69 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
  70
  71 (defun wl-draft-preview-message ()
  72   "Preview editing message."
  73   (interactive)
  74   (let* (recipients-message
  75          (current-point (point))
  76          (config-exec-flag wl-draft-config-exec-flag)
  77          (parent-folder wl-draft-parent-folder)
  78          (mime-display-header-hook 'wl-highlight-headers)
  79          (mime-header-encode-method-alist
  80           (append
  81            '((wl-draft-eword-encode-address-list
  82               .  (To Cc Bcc Resent-To Resent-Cc Bcc Resent-Bcc)))
  83            (if (boundp 'mime-header-encode-method-alist)
  84                (symbol-value 'mime-header-encode-method-alist))))
  85          mime-view-ignored-field-list   ; all header.
  86          (mime-edit-translate-buffer-hook
  87           (append
  88            (list
  89             (function
  90              (lambda ()
  91                (let ((wl-draft-config-exec-flag config-exec-flag)
  92                      (wl-draft-parent-folder parent-folder))
  93                  (goto-char current-point)
  94                  (run-hooks 'wl-draft-send-hook)
  95                  (setq recipients-message
  96                        (condition-case err
  97                            (concat "Recipients: "
  98                                    (mapconcat
  99                                     'identity
 100                                     (wl-draft-deduce-address-list
 101                                      (current-buffer)
 102                                      (point-min)
 103                                      (save-excursion
 104                                        (goto-char (point-min))
 105                                        (re-search-forward
 106                                         (concat
 107                                          "^"
 108                                          (regexp-quote mail-header-separator)
 109                                          "$")
 110                                         nil t)
 111                                        (point)))
 112                                     ", "))
 113                          (error
 114                           (kill-buffer (current-buffer))
 115                           (signal (car err) (cdr err)))))))))
 116            mime-edit-translate-buffer-hook)))
 117     (mime-edit-preview-message)
 118     (let ((buffer-read-only nil))
 119       (when wl-highlight-body-too
 120         (wl-highlight-body))
 121       (run-hooks 'wl-draft-preview-message-hook))
 122     (message recipients-message)))
 123
 124 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 125
 126 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 127
 128 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 129
 130 ;;; Message
 131
 132 (defun wl-message-decode-mode (outbuf inbuf)
 133   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 134         (mime-display-header-hook 'wl-highlight-headers))
 135     (mime-view-mode nil nil nil inbuf outbuf)))
 136
 137 (defun wl-message-decode-with-all-header (outbuf inbuf)
 138   (let ((mime-view-ignored-field-regexp "^:$")
 139         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 140         (mime-display-header-hook 'wl-highlight-headers)
 141         mime-view-ignored-field-list)
 142     (mime-view-mode nil nil nil inbuf outbuf)))
 143
 144 (defun wl-message-delete-mime-out-buf ()
 145   (let (mime-out-buf mime-out-win)
 146     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 147         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 148             (delete-window mime-out-win)))))
 149
 150 (defun wl-message-request-partial (folder number)
 151   (elmo-set-work-buf
 152    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 153                        number
 154                        (elmo-make-fetch-strategy 'entire)
 155                        nil
 156                        (current-buffer)
 157                        'unread)
 158    (mime-parse-buffer nil)))
 159
 160 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 161 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 162 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 163 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 164 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 165 (defalias 'wl-message-quit              'mime-preview-quit)
 166 (defalias 'wl-message-button-dispatcher-internal
 167   'mime-button-dispatcher)
 168
 169 (defsubst wl-mime-node-id-to-string (node-id)
 170   (if (consp node-id)
 171       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 172                  (reverse node-id)
 173                  ".")
 174     "0"))
 175
 176 (defun wl-message-delete-current-part ()
 177   "Delete a part under the cursor from the multipart message."
 178   (interactive)
 179   (let* ((entity (get-text-property (point) 'mime-view-entity))
 180          (node-id (mime-entity-node-id entity))
 181          (header-start (mime-buffer-entity-header-start-internal entity))
 182          (body-end (mime-buffer-entity-body-end-internal entity))
 183          (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 184          (number wl-message-buffer-cur-number)
 185          (msgid (elmo-message-field folder number 'message-id))
 186          (orig-buf wl-message-buffer-original-buffer))
 187     (when (and (elmo-folder-writable-p folder)
 188                (buffer-live-p orig-buf)
 189                node-id
 190                (yes-or-no-p
 191                 (format "Do you really want to delete part %s? "
 192                         (wl-mime-node-id-to-string node-id))))
 193       (with-temp-buffer
 194         (insert-buffer orig-buf)
 195         (kill-region header-start body-end)
 196         (goto-char header-start)
 197         (insert "Content-Type: text/plain; charset=US-ASCII\n\n")
 198         (insert "** This part has been removed by Wanderlust **\n\n")
 199         (elmo-folder-append-buffer folder t))
 200
 201       (elmo-folder-append-messages
 202        (wl-folder-get-elmo-folder wl-trash-folder)
 203        folder (list number) nil)
 204       (elmo-folder-delete-messages folder (list number))
 205
 206       (when (file-exists-p (elmo-cache-get-path msgid))
 207         (delete-file (elmo-cache-get-path msgid)))
 208
 209       (mime-preview-quit)
 210       (wl-summary-toggle-disp-msg 'off)
 211       (wl-summary-sync nil "update"))))
 212
 213 ;;; Summary
 214 (defun wl-summary-burst-subr (message-entity target number)
 215   ;; returns new number.
 216   (let (content-type entity)
 217     (setq content-type (mime-entity-content-type message-entity))
 218     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 219            (dolist (entity (mime-entity-children message-entity))
 220              (setq number (wl-summary-burst-subr
 221                            entity
 222                            target
 223                            number))))
 224           ((and (eq (cdr (assq 'type content-type)) 'message)
 225                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 226            (message "Bursting...%s" (setq number (+ 1 number)))
 227            (setq entity
 228                  (car (mime-entity-children message-entity)))
 229            (with-temp-buffer
 230              (insert (mime-entity-body message-entity))
 231              (elmo-folder-append-buffer
 232               target
 233               (mime-entity-fetch-field entity "Message-ID")))))
 234     number))
 235
 236 (defun wl-summary-burst (&optional arg)
 237   "De-capsulate embedded messages in MIME format.
 238 With ARG, ask destination folder."
 239   (interactive "P")
 240   (let ((raw-buf (wl-summary-get-original-buffer))
 241         (view-buf wl-message-buffer)
 242         children message-entity content-type target)
 243     (save-excursion
 244       (setq target wl-summary-buffer-elmo-folder)
 245       (when (or arg (not (elmo-folder-writable-p target)))
 246         (let ((fld (wl-summary-read-folder wl-default-folder "to extract to")))
 247           (setq target (wl-folder-get-elmo-folder fld))))
 248       (wl-summary-set-message-buffer-or-redisplay)
 249       (with-current-buffer view-buf
 250         (setq message-entity (get-text-property (point-min) 'mime-view-entity)))
 251       (when message-entity
 252         (message "Bursting...")
 253         (with-current-buffer raw-buf
 254           (wl-summary-burst-subr message-entity target 0))
 255         (message "Bursting...done"))
 256       (if (elmo-folder-plugged-p target)
 257           (elmo-folder-check target)))
 258     (wl-summary-sync-update)))
 259
 260 ;; internal variable.
 261 (defvar wl-mime-save-directory nil "Last saved directory.")
 262 ;;; Yet another save method.
 263 (defun wl-mime-save-content (entity situation)
 264   (let ((filename (read-file-name "Save to file: "
 265                                   (expand-file-name
 266                                    (or (mime-entity-safe-filename entity)
 267                                        ".")
 268                                    (or wl-mime-save-directory
 269                                        wl-temporary-file-directory)))))
 270     (while (file-directory-p filename)
 271       (setq filename (read-file-name "Please set filename (not directory): "
 272                                      filename)))
 273     (if (and (file-exists-p filename)
 274              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 275                                        filename))))
 276         (message "Not saved")
 277       (setq wl-mime-save-directory (file-name-directory filename))
 278       (mime-write-entity-content entity filename))))
 279
 280 ;;; Yet another combine method.
 281 (defun wl-mime-combine-message/partial-pieces (entity situation)
 282   "Internal method for wl to combine message/partial messages automatically."
 283   (interactive)
 284   (let* ((msgdb (save-excursion
 285                   (set-buffer wl-message-buffer-cur-summary-buffer)
 286                   (wl-summary-buffer-msgdb)))
 287          (mime-display-header-hook 'wl-highlight-headers)
 288          (folder wl-message-buffer-cur-folder)
 289          (id (or (cdr (assoc "id" situation)) ""))
 290          (mother (current-buffer))
 291          (summary-buf wl-message-buffer-cur-summary-buffer)
 292          subject-id overviews
 293          (root-dir (expand-file-name
 294                     (concat "m-prts-" (user-login-name))
 295                     temporary-file-directory))
 296          full-file point)
 297     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 298     (setq full-file (concat root-dir "/FULL"))
 299     (if (or (file-exists-p full-file)
 300             (not (y-or-n-p "Merge partials? ")))
 301         (with-current-buffer mother
 302           (mime-store-message/partial-piece entity situation)
 303           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 304           (make-variable-buffer-local 'mime-preview-over-to-next-method-alist)
 305           (setq mime-preview-over-to-next-method-alist
 306                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 307                       mime-preview-over-to-next-method-alist))
 308           (make-variable-buffer-local 'mime-preview-over-to-previous-method-alist)
 309           (setq mime-preview-over-to-previous-method-alist
 310                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 311                       mime-preview-over-to-previous-method-alist)))
 312       (setq subject-id
 313             (eword-decode-string
 314              (decode-mime-charset-string
 315               (mime-entity-read-field entity 'Subject)
 316               wl-summary-buffer-mime-charset)))
 317       (if (string-match "[0-9\n]+" subject-id)
 318           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 319       (setq overviews (elmo-msgdb-get-overview msgdb))
 320       (catch 'tag
 321         (while overviews
 322           (when (string-match
 323                  (regexp-quote subject-id)
 324                  (elmo-msgdb-overview-entity-get-subject (car overviews)))
 325             (let* ((message
 326                     ;; request message at the cursor in Subject buffer.
 327                     (wl-message-request-partial
 328                      folder
 329                      (elmo-msgdb-overview-entity-get-number
 330                       (car overviews))))
 331                    (situation (mime-entity-situation message))
 332                    (the-id (or (cdr (assoc "id" situation)) "")))
 333               (when (string= (downcase the-id)
 334                              (downcase id))
 335                 (with-current-buffer mother
 336                   (mime-store-message/partial-piece message situation))
 337                 (if (file-exists-p full-file)
 338                     (throw 'tag nil)))))
 339           (setq overviews (cdr overviews)))
 340         (message "Not all partials found.")))))
 341
 342 (defun wl-mime-display-text/plain (entity situation)
 343   (let ((beg (point)))
 344     (mime-display-text/plain entity situation)
 345     (wl-highlight-message beg (point-max) t t)))
 346
 347 (defun wl-mime-display-header (entity situation)
 348   (let ((elmo-message-ignored-field-list
 349          (if wl-message-buffer-all-header-flag
 350              nil
 351            wl-message-ignored-field-list))
 352         (elmo-message-visible-field-list wl-message-visible-field-list)
 353         (elmo-message-sorted-field-list wl-message-sort-field-list))
 354     (elmo-mime-insert-header entity situation)
 355     (wl-highlight-headers)))
 356
 357 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 358   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 359         (original-buffer wl-message-buffer-original-buffer))
 360     (mime-decrypt-application/pgp-encrypted entity situation)
 361     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 362     (setq wl-message-buffer-original-buffer original-buffer)))
 363
 364
 365 ;;; Setup methods.
 366 (defun wl-mime-setup ()
 367   (set-alist 'mime-preview-quitting-method-alist
 368              'wl-original-message-mode 'wl-message-exit)
 369   (set-alist 'mime-view-over-to-previous-method-alist
 370              'wl-original-message-mode 'wl-message-exit)
 371   (set-alist 'mime-view-over-to-next-method-alist
 372              'wl-original-message-mode 'wl-message-exit)
 373   (set-alist 'mime-preview-over-to-previous-method-alist
 374              'wl-original-message-mode 'wl-message-exit)
 375   (set-alist 'mime-preview-over-to-next-method-alist
 376              'wl-original-message-mode 'wl-message-exit)
 377   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 378   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 379
 380   (ctree-set-calist-strictly
 381    'mime-preview-condition
 382    '((type . text) (subtype . plain)
 383      (body . visible)
 384      (body-presentation-method . wl-mime-display-text/plain)
 385      (major-mode . wl-original-message-mode)))
 386
 387   (ctree-set-calist-strictly
 388    'mime-acting-condition
 389    '((type . message) (subtype . partial)
 390      (method .  wl-mime-combine-message/partial-pieces)
 391      (request-partial-message-method . wl-message-request-partial)
 392      (major-mode . wl-original-message-mode)))
 393
 394   (ctree-set-calist-strictly
 395    'mime-acting-condition
 396    '((type . application) (subtype . pgp-encrypted)
 397      (method . wl-mime-decrypt-application/pgp-encrypted)
 398      (major-mode . wl-original-message-mode)))
 399
 400   (ctree-set-calist-strictly
 401    'mime-acting-condition
 402    '((mode . "extract")
 403      (major-mode . wl-original-message-mode)
 404      (method . wl-mime-save-content)))
 405   (set-alist 'mime-preview-following-method-alist
 406              'wl-original-message-mode
 407              (function wl-message-follow-current-entity))
 408   (set-alist 'mime-view-following-method-alist
 409              'wl-original-message-mode
 410              (function wl-message-follow-current-entity))
 411   (set-alist 'mime-edit-message-inserter-alist
 412              'wl-draft-mode (function wl-draft-insert-current-message))
 413   (set-alist 'mime-edit-mail-inserter-alist
 414              'wl-draft-mode (function wl-draft-insert-get-message))
 415   (set-alist 'mime-edit-split-message-sender-alist
 416              'wl-draft-mode
 417              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 418   (set-alist 'mime-raw-representation-type-alist
 419              'wl-original-message-mode 'binary)
 420   ;; Sort and highlight header fields.
 421   (or wl-message-ignored-field-list
 422       (setq wl-message-ignored-field-list
 423             mime-view-ignored-field-list))
 424   (or wl-message-visible-field-list
 425       (setq wl-message-visible-field-list
 426             mime-view-visible-field-list))
 427   (set-alist 'mime-header-presentation-method-alist
 428              'wl-original-message-mode
 429              'wl-mime-display-header)
 430   ;; To avoid overriding wl-draft-mode-map.
 431   (when (boundp 'mime-setup-signature-key-alist)
 432     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 433       (setq mime-setup-signature-key-alist
 434             (cons '(wl-draft-mode . "\C-c\C-w")
 435                   mime-setup-signature-key-alist)))))
 436
 437 (require 'product)
 438 (product-provide (provide 'wl-mime) (require 'wl-version))
 439
 440 ;;; wl-mime.el ends here