wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'mime-view)
  33 (require 'mime-edit)
  34 (require 'mime-play)
  35 (require 'elmo)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'pgg-decrypt-region 'ignore)
  39   (defalias-maybe 'pgg-display-output-buffer 'ignore)
  40   (defalias-maybe 'pgg-verify-region 'ignore))
  41
  42 ;;; Draft
  43
  44 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  45
  46 (defalias 'wl-draft-decode-message-in-buffer
  47   'mime-edit-decode-message-in-buffer)
  48
  49 (defun wl-draft-yank-current-message-entity ()
  50   "Yank currently displayed message entity.
  51 By setting following-method as yank-content.
  52
  53 If region is active, yank region contents instead. \(this feature is available
  54 if and only if `transient-mark-mode' \(GNU Emacs\) or `zmacs-regions' \(XEmacs\)
  55 has Non-nil value\)"
  56   (let ((wl-draft-buffer (current-buffer))
  57         (mime-view-following-method-alist
  58          (list (cons 'wl-original-message-mode
  59                      (function wl-draft-yank-to-draft-buffer))))
  60         (mime-preview-following-method-alist
  61          (list (cons 'wl-original-message-mode
  62                      (function wl-draft-yank-to-draft-buffer))))
  63         (message-buffer (wl-current-message-buffer)))
  64     (if message-buffer
  65         (save-excursion
  66           (set-buffer message-buffer)
  67           (save-restriction
  68             (widen)
  69             (cond
  70              ((wl-region-exists-p)
  71               (wl-mime-preview-follow-current-region))
  72              ((not (eq (get-text-property (point-min)
  73                                           'wl-message-display-mime-mode)
  74                        'mime))
  75               (wl-mime-preview-follow-no-mime
  76                (get-text-property (point-min)
  77                                   'wl-message-display-mime-mode)))
  78              (t
  79               (mime-preview-follow-current-entity)))))
  80       (error "No message."))))
  81
  82 ;; modified mime-preview-follow-current-entity from mime-view.el
  83 (defun wl-mime-preview-follow-no-mime (display-mode)
  84   "Write follow message to current message, without mime.
  85 It calls following-method selected from variable
  86 `mime-preview-following-method-alist'."
  87   (interactive)
  88   (let* ((mode (mime-preview-original-major-mode 'recursive))
  89          (new-name (format "%s-no-mime" (buffer-name)))
  90          new-buf min beg end
  91          (entity (get-text-property (point-min) 'elmo-as-is-entity))
  92          (the-buf (current-buffer))
  93          fields)
  94     (save-excursion
  95       (goto-char (point-min))
  96       (setq min (point-min)
  97             beg (re-search-forward "^$" nil t)
  98             end (point-max)))
  99     (save-excursion
 100       (set-buffer (setq new-buf (get-buffer-create new-name)))
 101       (erase-buffer)
 102       (insert-buffer-substring the-buf beg end)
 103       (goto-char (point-min))
 104       ;; Insert all headers.
 105       (let ((elmo-mime-display-header-analysis (not (eq display-mode 'as-is))))
 106         (elmo-mime-insert-sorted-header entity))
 107       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 108         (if (functionp f)
 109             (funcall f new-buf)
 110           (message
 111            "Sorry, following method for %s is not implemented yet."
 112            mode))))))
 113
 114 ;; modified mime-preview-follow-current-entity from mime-view.el
 115 (defun wl-mime-preview-follow-current-region ()
 116   "Write follow message to current region.
 117 It calls following-method selected from variable
 118 `mime-preview-following-method-alist'."
 119   (interactive)
 120   (let ((r-beg (region-beginning))
 121         (r-end (region-end))
 122         (entity (get-text-property (point-min)
 123                                    'mime-view-entity)))
 124     (let* ((mode (mime-preview-original-major-mode 'recursive))
 125            (new-name
 126             (format "%s-active-region" (buffer-name)))
 127            new-buf
 128            (the-buf (current-buffer))
 129            fields)
 130       (save-excursion
 131         (set-buffer (setq new-buf (get-buffer-create new-name)))
 132         (erase-buffer)
 133         (insert ?\n)
 134         (insert-buffer-substring the-buf r-beg r-end)
 135         (goto-char (point-min))
 136         (let ((current-entity
 137                (if (and entity
 138                         (eq (mime-entity-media-type entity) 'message)
 139                         (eq (mime-entity-media-subtype entity) 'rfc822))
 140                    (car (mime-entity-children entity))
 141                  entity)))
 142           (while (and current-entity
 143                       (if (and (eq (mime-entity-media-type
 144                                     current-entity) 'message)
 145                                (eq (mime-entity-media-subtype
 146                                     current-entity) 'rfc822))
 147                           nil
 148                         (mime-insert-header current-entity fields)
 149                         t))
 150             (setq fields (std11-collect-field-names)
 151                   current-entity (mime-entity-parent current-entity))))
 152         (let ((rest mime-view-following-required-fields-list)
 153               field-name ret)
 154           (while rest
 155             (setq field-name (car rest))
 156             (or (std11-field-body field-name)
 157                 (progn
 158                   (save-excursion
 159                     (set-buffer the-buf)
 160                     (let ((entity (when mime-mother-buffer
 161                                     (set-buffer mime-mother-buffer)
 162                                     (get-text-property (point)
 163                                                        'mime-view-entity))))
 164                       (while (and entity
 165                                   (null (setq ret (mime-entity-fetch-field
 166                                                    entity field-name))))
 167                         (setq entity (mime-entity-parent entity)))))
 168                   (if ret
 169                       (insert (concat field-name ": " ret "\n")))))
 170             (setq rest (cdr rest)))))
 171       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 172         (if (functionp f)
 173             (funcall f new-buf)
 174           (message
 175            "Sorry, following method for %s is not implemented yet."
 176            mode))))))
 177
 178 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
 179
 180 (defun wl-draft-attribute-recipients ()
 181   (concat (mapconcat
 182            'identity
 183            (wl-draft-deduce-address-list
 184             (current-buffer)
 185             (point-min)
 186             (save-excursion
 187               (goto-char (point-min))
 188               (re-search-forward
 189                (concat
 190                 "^"
 191                 (regexp-quote mail-header-separator)
 192                 "$")
 193                nil t)
 194               (point)))
 195            ", ")))
 196
 197 (defun wl-draft-attribute-envelope-from ()
 198   (or wl-envelope-from
 199       (wl-address-header-extract-address wl-from)))
 200
 201 (defun wl-draft-attribute-smtp-posting-server ()
 202   (or wl-smtp-posting-server
 203       (progn (require 'smtp) smtp-server)
 204       "localhost"))
 205
 206 (defun wl-draft-attribute-smtp-posting-port ()
 207   (or wl-smtp-posting-port
 208       (progn (require 'smtp) smtp-service)))
 209
 210 (defun wl-draft-attribute-value (attr)
 211   (let ((name (symbol-name attr))
 212         fsymbol symbol)
 213     (cond ((and (setq fsymbol (intern-soft
 214                                (format "wl-draft-attribute-%s" name)))
 215                 (fboundp fsymbol))
 216            (funcall fsymbol))
 217           ((and (setq symbol (intern-soft (format "wl-%s" name)))
 218                 (boundp symbol))
 219            (symbol-value symbol))
 220           ((boundp attr)
 221            (symbol-value attr)))))
 222
 223 (defun wl-mime-quit-preview ()
 224   "Quitting method for mime-view."
 225   (let* ((temp (and (boundp 'mime-edit-temp-message-buffer) ;; for SEMI <= 1.14.6
 226                     mime-edit-temp-message-buffer))
 227          (window (selected-window))
 228          buf)
 229     (mime-preview-kill-buffer)
 230     (set-buffer temp)
 231     (setq buf mime-edit-buffer)
 232     (kill-buffer temp)
 233     (select-window window)
 234     (switch-to-buffer buf)))
 235
 236 (defun wl-draft-preview-message ()
 237   "Preview editing message."
 238   (interactive)
 239   (let* (attribute-list
 240          (orig-buffer (current-buffer))
 241          (current-point (point))
 242          (config-exec-flag wl-draft-config-exec-flag)
 243          (parent-folder wl-draft-parent-folder)
 244          (mime-display-header-hook 'wl-highlight-headers)
 245          (mime-header-encode-method-alist
 246           (append
 247            '((wl-draft-eword-encode-address-list
 248               .  (To Cc Bcc Resent-To Resent-Cc Resent-Bcc From)))
 249            (if (boundp 'mime-header-encode-method-alist)
 250                (symbol-value 'mime-header-encode-method-alist))))
 251          mime-view-ignored-field-list   ; all header.
 252          (mime-edit-translate-buffer-hook
 253           (append
 254            (list
 255             (lambda ()
 256               (let ((wl-draft-config-exec-flag config-exec-flag)
 257                     (wl-draft-parent-folder parent-folder)
 258                     (copy-buffer (current-buffer)))
 259                 (with-current-buffer orig-buffer
 260                   (wl-copy-local-variables
 261                    orig-buffer
 262                    copy-buffer
 263                    (append wl-draft-config-variables
 264                            (wl-draft-clone-local-variables))))
 265                 (goto-char current-point)
 266                 (run-hooks 'wl-draft-send-hook)
 267                 (condition-case err
 268                     (setq attribute-list
 269                           (mapcar
 270                            (lambda (attr)
 271                              (cons attr (wl-draft-attribute-value attr)))
 272                            wl-draft-preview-attributes-list))
 273                   (error
 274                    (kill-buffer (current-buffer))
 275                    (signal (car err) (cdr err)))))))
 276            mime-edit-translate-buffer-hook)))
 277     (mime-edit-preview-message)
 278     (make-local-variable 'mime-preview-quitting-method-alist)
 279     (setq mime-preview-quitting-method-alist
 280           '((mime-temp-message-mode . wl-mime-quit-preview)))
 281     (let ((buffer-read-only nil))
 282       (when wl-highlight-body-too
 283         (wl-highlight-body))
 284       (run-hooks 'wl-draft-preview-message-hook))
 285     (make-local-variable 'kill-buffer-hook)
 286     (add-hook 'kill-buffer-hook
 287               (lambda ()
 288                 (when (get-buffer-window
 289                        wl-draft-preview-attributes-buffer-name)
 290                   (select-window (get-buffer-window
 291                                   wl-draft-preview-attributes-buffer-name))
 292                   (delete-window))
 293                 (when (get-buffer wl-draft-preview-attributes-buffer-name)
 294                   (kill-buffer (get-buffer
 295                                 wl-draft-preview-attributes-buffer-name)))))
 296     (if (not wl-draft-preview-attributes)
 297         (message (concat "Recipients: "
 298                          (cdr (assq 'recipients attribute-list))))
 299       (ignore-errors ; in case when the window is too small
 300         (let* ((cur-win (selected-window))
 301                (size (min
 302                       (- (window-height cur-win)
 303                          window-min-height 1)
 304                       (- (window-height cur-win)
 305                          (max
 306                           window-min-height
 307                           (1+ wl-draft-preview-attributes-buffer-lines))))))
 308           (split-window cur-win (if (> size 0) size window-min-height))
 309           (select-window (next-window))
 310           (let ((pop-up-windows nil))
 311             (switch-to-buffer (get-buffer-create
 312                                wl-draft-preview-attributes-buffer-name)))
 313           (with-current-buffer
 314               (get-buffer wl-draft-preview-attributes-buffer-name)
 315             (setq buffer-read-only t)
 316             (let (buffer-read-only)
 317               (erase-buffer)
 318               (dolist (pair attribute-list)
 319                 (insert (capitalize (symbol-name (car pair))) ": "
 320                         (format "%s" (or (cdr pair) ""))
 321                         "\n"))
 322               (goto-char (point-min))
 323               (wl-highlight-headers)))
 324           (select-window cur-win))))))
 325
 326 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 327
 328 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 329
 330 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 331
 332 ;;; Message
 333
 334 (defun wl-message-decode-mode (outbuf inbuf)
 335   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 336         (mime-display-header-hook 'wl-highlight-headers))
 337     (mime-view-mode nil nil nil inbuf outbuf)))
 338
 339 (defun wl-message-decode-with-all-header (outbuf inbuf)
 340   (let ((mime-view-ignored-field-regexp "^:$")
 341         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 342         (mime-display-header-hook 'wl-highlight-headers)
 343         mime-view-ignored-field-list)
 344     (mime-view-mode nil nil nil inbuf outbuf)))
 345
 346 (defun wl-message-delete-mime-out-buf ()
 347   (let (mime-out-buf mime-out-win)
 348     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 349         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 350             (delete-window mime-out-win)))))
 351
 352 (defun wl-message-request-partial (folder number)
 353   (elmo-set-work-buf
 354    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 355                        number
 356                        (elmo-make-fetch-strategy 'entire)
 357                        nil
 358                        (current-buffer)
 359                        'unread)
 360    (mime-parse-buffer nil)))
 361
 362 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 363 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 364 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 365 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 366 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 367 (defalias 'wl-message-quit              'mime-preview-quit)
 368 (defalias 'wl-message-button-dispatcher-internal
 369   'mime-button-dispatcher)
 370
 371 (defsubst wl-mime-node-id-to-string (node-id)
 372   (if (consp node-id)
 373       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 374                  (reverse node-id)
 375                  ".")
 376     "0"))
 377
 378 (defun wl-message-delete-current-part ()
 379   "Delete a part under the cursor from the multipart message."
 380   (interactive)
 381   (save-restriction
 382     (widen)
 383     (let* ((entity (get-text-property (point) 'mime-view-entity))
 384            (node-id (mime-entity-node-id entity))
 385            (filename (mime-entity-safe-filename entity))
 386            (header-start (mime-buffer-entity-header-start-internal entity))
 387            (body-end (mime-buffer-entity-body-end-internal entity))
 388            (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 389            (number wl-message-buffer-cur-number)
 390            (msgid (elmo-message-field folder number 'message-id))
 391            (orig-buf wl-message-buffer-original-buffer))
 392       (if (eq (luna-class-name entity) 'mime-elmo-imap-entity)
 393           (error "Please fetch the entire message (by typing 'C-u .') and try again"))
 394       (with-current-buffer orig-buf
 395         (unless (string-equal
 396                  (buffer-string)
 397                  (elmo-message-fetch folder number
 398                                      (elmo-make-fetch-strategy 'entire)))
 399           (error "Buffer content differs from actual message")))
 400       (when (and (elmo-folder-writable-p folder)
 401                  (buffer-live-p orig-buf)
 402                  node-id
 403                  (yes-or-no-p
 404                   (format "Do you really want to delete part %s? "
 405                           (wl-mime-node-id-to-string node-id))))
 406         (when (with-temp-buffer
 407                 (insert-buffer orig-buf)
 408                 (delete-region header-start body-end)
 409                 (goto-char header-start)
 410                 (insert "Content-Type: text/plain; charset=US-ASCII\n")
 411                 (when filename
 412                   (insert
 413                    "Content-Disposition:"
 414                    (mime-encode-field-body
 415                          (concat ""
 416                                  (and filename
 417                                       (concat " inline; filename=" (std11-wrap-as-quoted-string filename))))
 418                          "Content-Disposition")
 419                    "\n"))
 420                 (insert "\n")
 421                 (insert "** This part has been removed by Wanderlust **\n\n")
 422                 (elmo-folder-append-buffer folder))
 423
 424           (elmo-folder-move-messages
 425            folder (list number)
 426            (wl-folder-get-elmo-folder wl-trash-folder))
 427           (when (and (elmo-cache-get-path msgid)
 428                      (file-exists-p (elmo-cache-get-path msgid)))
 429             (delete-file (elmo-cache-get-path msgid)))
 430
 431           (mime-preview-quit)
 432           (wl-summary-delete-messages-on-buffer (list number))
 433           (wl-summary-toggle-disp-msg 'off)
 434           (setq wl-message-buffer nil)
 435           (wl-summary-sync nil "update"))))))
 436
 437 (defun wl-message-decrypt-pgp-nonmime ()
 438   "Decrypt PGP encrypted region"
 439   (interactive)
 440   (require 'pgg)
 441   (save-excursion
 442     (beginning-of-line)
 443     (if (or (re-search-forward "^-+END PGP MESSAGE-+$" nil t)
 444             (re-search-backward "^-+END PGP MESSAGE-+$" nil t))
 445         (let (beg end status)
 446           (setq end (match-end 0))
 447           (if (setq beg (re-search-backward "^-+BEGIN PGP MESSAGE-+$" nil t))
 448               (let ((inhibit-read-only t)
 449                     (buffer-file-coding-system wl-cs-autoconv))
 450                 (setq status (pgg-decrypt-region beg end))
 451                 (pgg-display-output-buffer beg end status))
 452             (message "Cannot find pgp encrypted region")))
 453       (message "Cannot find pgp encrypted region"))))
 454
 455 (defun wl-message-verify-pgp-nonmime ()
 456   "Verify PGP signed region"
 457   (interactive)
 458   (require 'pgg)
 459   (save-excursion
 460     (beginning-of-line)
 461     (if (and (or (re-search-forward "^-+END PGP SIGNATURE-+$" nil t)
 462                  (re-search-backward "^-+END PGP SIGNATURE-+$" nil t))
 463              (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t))
 464         (let (status)
 465           (let* ((beg (point))
 466                  (situation (mime-preview-find-boundary-info))
 467                  (p-end (aref situation 1))
 468                  (entity (aref situation 2))
 469                  (count 0))
 470             (goto-char p-end)
 471             (while (< beg (point))
 472               (if (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t)
 473                   (setq count (+ count 1))
 474                 (debug)))
 475             (with-temp-buffer
 476               (set-buffer-multibyte nil)
 477               (insert (mime-entity-body entity))
 478               (goto-char (point-max))
 479               (while (> count 0)
 480                 (if (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t)
 481                     (setq count (- count 1))
 482                   (debug)))
 483               (let ((r-beg (point))
 484                     (r-end (re-search-forward "^-+END PGP SIGNATURE-+$" nil t)))
 485                 (if r-end
 486                     (setq status (pgg-verify-region r-beg r-end nil 'fetch))
 487                   (debug)))))
 488           (mime-show-echo-buffer)
 489           (set-buffer mime-echo-buffer-name)
 490           (set-window-start
 491            (get-buffer-window mime-echo-buffer-name)
 492            (point-max))
 493           (insert-buffer-substring
 494            (if status pgg-output-buffer pgg-errors-buffer)))
 495       (message "Cannot find pgp signed region"))))
 496
 497 ;; XXX: encrypted multipart isn't represented as multipart
 498 (defun wl-mime-preview-application/pgp (parent-entity entity situation)
 499   (require 'pgg)
 500   (goto-char (point-max))
 501   (let ((p (point))
 502         raw-buf to-buf representation-type child-entity)
 503     (goto-char p)
 504     (save-restriction
 505       (narrow-to-region p p)
 506       (setq to-buf (current-buffer))
 507       (with-temp-buffer
 508         (setq raw-buf (current-buffer))
 509         (mime-insert-entity entity)
 510         (when (progn
 511                 (goto-char (point-min))
 512                 (re-search-forward "^-+BEGIN PGP MESSAGE-+$" nil t))
 513           (pgg-decrypt-region (point-min)(point-max))
 514           (delete-region (point-min) (point-max))
 515           (insert-buffer pgg-output-buffer)
 516           (setq representation-type 'elmo-buffer))
 517         (setq child-entity (mime-parse-message
 518                             (mm-expand-class-name representation-type)
 519                             nil
 520                             parent-entity
 521                             (mime-entity-node-id-internal parent-entity)))
 522         (mime-display-entity
 523          child-entity
 524          nil
 525          `((header . visible)
 526            (body . visible)
 527            (entity-button . invisible))
 528          to-buf)))))
 529
 530 (defun wl-mime-preview-application/pgp-encrypted (entity situation)
 531   (let* ((entity-node-id (mime-entity-node-id entity))
 532          (mother (mime-entity-parent entity))
 533          (knum (car entity-node-id))
 534          (onum (if (> knum 0)
 535                    (1- knum)
 536                  (1+ knum)))
 537          (orig-entity (nth onum (mime-entity-children mother))))
 538     (wl-mime-preview-application/pgp entity orig-entity situation)))
 539
 540 ;;; Summary
 541 (defun wl-summary-burst-subr (message-entity target number)
 542   ;; returns new number.
 543   (let (content-type entity)
 544     (setq content-type (mime-entity-content-type message-entity))
 545     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 546            (dolist (entity (mime-entity-children message-entity))
 547              (setq number (wl-summary-burst-subr
 548                            entity
 549                            target
 550                            number))))
 551           ((and (eq (cdr (assq 'type content-type)) 'message)
 552                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 553            (message "Bursting...%s" (setq number (+ 1 number)))
 554            (setq entity
 555                  (car (mime-entity-children message-entity)))
 556            (with-temp-buffer
 557              (insert (mime-entity-body message-entity))
 558              (elmo-folder-append-buffer target))))
 559     number))
 560
 561 (defun wl-summary-burst (&optional arg)
 562   "De-capsulate embedded messages in MIME format.
 563 With ARG, ask destination folder."
 564   (interactive "P")
 565   (let ((raw-buf (wl-summary-get-original-buffer))
 566         (view-buf wl-message-buffer)
 567         message-entity target)
 568     (save-excursion
 569       (when (and (null arg)
 570                  (elmo-folder-writable-p wl-summary-buffer-elmo-folder))
 571         (setq target wl-summary-buffer-elmo-folder))
 572       (while (null target)
 573         (let ((name (wl-summary-read-folder wl-default-folder
 574                                             "to extract to")))
 575           (setq target (wl-folder-get-elmo-folder name))
 576           (unless (elmo-folder-writable-p target)
 577             (message "%s is not writable" name)
 578             (setq target nil)
 579             (sit-for 1))))
 580       (wl-summary-set-message-buffer-or-redisplay)
 581       (with-current-buffer view-buf
 582         (setq message-entity
 583               (get-text-property (point-min) 'mime-view-entity)))
 584       (when message-entity
 585         (message "Bursting...")
 586         (with-current-buffer raw-buf
 587           (wl-summary-burst-subr message-entity target 0))
 588         (message "Bursting...done"))
 589       (if (elmo-folder-plugged-p target)
 590           (elmo-folder-check target)))
 591     (when (and target
 592                (string= wl-summary-buffer-folder-name
 593                         (elmo-folder-name-internal target)))
 594       (save-excursion (wl-summary-sync-update)))))
 595
 596 ;; internal variable.
 597 (defvar wl-mime-save-directory nil "Last saved directory.")
 598 ;;; Yet another save method.
 599 (defun wl-mime-save-content (entity situation)
 600   (let ((filename (expand-file-name
 601                    (read-file-name "Save to file: "
 602                                    (expand-file-name
 603                                     (or (mime-entity-safe-filename entity)
 604                                         ".")
 605                                     (or wl-mime-save-directory
 606                                         wl-temporary-file-directory))))))
 607     (while (file-directory-p filename)
 608       (setq filename (read-file-name "Please set filename (not directory): "
 609                                      filename)))
 610     (if (and (file-exists-p filename)
 611              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 612                                        filename))))
 613         (message "Not saved")
 614       (setq wl-mime-save-directory (file-name-directory filename))
 615       (mime-write-entity-content entity filename))))
 616
 617 ;;; Yet another combine method.
 618 (defun wl-mime-combine-message/partial-pieces (entity situation)
 619   "Internal method for wl to combine message/partial messages automatically."
 620   (interactive)
 621   (let* ((folder (with-current-buffer wl-message-buffer-cur-summary-buffer
 622                    wl-summary-buffer-elmo-folder))
 623          (mime-display-header-hook 'wl-highlight-headers)
 624          (id (or (cdr (assoc "id" situation)) ""))
 625          (mother (current-buffer))
 626          (summary-buf wl-message-buffer-cur-summary-buffer)
 627          subject-id overviews
 628          (root-dir (expand-file-name
 629                     (concat "m-prts-" (user-login-name))
 630                     temporary-file-directory))
 631          full-file point)
 632     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 633     (setq full-file (concat root-dir "/FULL"))
 634     (if (or (file-exists-p full-file)
 635             (not (y-or-n-p "Merge partials? ")))
 636         (with-current-buffer mother
 637           (mime-store-message/partial-piece entity situation)
 638           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 639           (make-variable-buffer-local 'mime-preview-over-to-next-method-alist)
 640           (setq mime-preview-over-to-next-method-alist
 641                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 642                       mime-preview-over-to-next-method-alist))
 643           (make-variable-buffer-local 'mime-preview-over-to-previous-method-alist)
 644           (setq mime-preview-over-to-previous-method-alist
 645                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 646                       mime-preview-over-to-previous-method-alist)))
 647       (setq subject-id
 648             (eword-decode-string
 649              (decode-mime-charset-string
 650               (mime-entity-read-field entity 'Subject)
 651               wl-summary-buffer-mime-charset)))
 652       (if (string-match "[0-9\n]+" subject-id)
 653           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 654       (catch 'tag
 655         (elmo-folder-do-each-message-entity (entity folder)
 656           (when (string-match
 657                  (regexp-quote subject-id)
 658                  (elmo-message-entity-field entity 'subject 'decode))
 659             (let* ((message
 660                     ;; request message at the cursor in Subject buffer.
 661                     (wl-message-request-partial
 662                      (elmo-folder-name-internal folder)
 663                      (elmo-message-entity-number entity)))
 664                    (situation (mime-entity-situation message))
 665                    (the-id (or (cdr (assoc "id" situation)) "")))
 666               (when (string= (downcase the-id)
 667                              (downcase id))
 668                 (with-current-buffer mother
 669                   (mime-store-message/partial-piece message situation))
 670                 (if (file-exists-p full-file)
 671                     (throw 'tag nil))))))
 672         (message "Not all partials found.")))))
 673
 674 (defun wl-mime-display-text/plain (entity situation)
 675   (let ((beg (point)))
 676     (mime-display-text/plain entity situation)
 677     (wl-highlight-message beg (point-max) t t)))
 678
 679 (defun wl-mime-display-header (entity situation)
 680   (let ((elmo-message-ignored-field-list
 681          (if wl-message-buffer-require-all-header
 682              nil
 683            wl-message-ignored-field-list))
 684         (elmo-message-visible-field-list wl-message-visible-field-list)
 685         (elmo-message-sorted-field-list wl-message-sort-field-list))
 686     (elmo-mime-insert-header entity situation)
 687     (wl-highlight-headers)))
 688
 689 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 690   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 691         (original-buffer wl-message-buffer-original-buffer))
 692     (mime-decrypt-application/pgp-encrypted entity situation)
 693     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 694     (setq wl-message-buffer-original-buffer original-buffer)))
 695
 696
 697 ;;; Setup methods.
 698 (defun wl-mime-setup ()
 699   (set-alist 'mime-preview-quitting-method-alist
 700              'wl-original-message-mode 'wl-message-exit)
 701   (set-alist 'mime-view-over-to-previous-method-alist
 702              'wl-original-message-mode 'wl-message-exit)
 703   (set-alist 'mime-view-over-to-next-method-alist
 704              'wl-original-message-mode 'wl-message-exit)
 705   (set-alist 'mime-preview-over-to-previous-method-alist
 706              'wl-original-message-mode 'wl-message-exit)
 707   (set-alist 'mime-preview-over-to-next-method-alist
 708              'wl-original-message-mode 'wl-message-exit)
 709   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 710   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 711
 712   (ctree-set-calist-strictly
 713    'mime-preview-condition
 714    '((type . text) (subtype . plain)
 715      (body . visible)
 716      (body-presentation-method . wl-mime-display-text/plain)
 717      (major-mode . wl-original-message-mode)))
 718
 719   (ctree-set-calist-strictly
 720    'mime-preview-condition
 721    '((type . application)(subtype . pgp-encrypted)
 722      (encoding . t)
 723      (body . invisible)
 724      (body-presentation-method . wl-mime-preview-application/pgp-encrypted)
 725      (major-mode . wl-original-message-mode)))
 726
 727   (ctree-set-calist-strictly
 728    'mime-acting-condition
 729    '((type . message) (subtype . partial)
 730      (method .  wl-mime-combine-message/partial-pieces)
 731      (request-partial-message-method . wl-message-request-partial)
 732      (major-mode . wl-original-message-mode)))
 733
 734   (ctree-set-calist-strictly
 735    'mime-acting-condition
 736    '((type . application) (subtype . pgp-encrypted)
 737      (method . wl-mime-decrypt-application/pgp-encrypted)
 738      (major-mode . wl-original-message-mode)))
 739
 740   (ctree-set-calist-strictly
 741    'mime-acting-condition
 742    '((mode . "extract")
 743      (major-mode . wl-original-message-mode)
 744      (method . wl-mime-save-content)))
 745   (set-alist 'mime-preview-following-method-alist
 746              'wl-original-message-mode
 747              (function wl-message-follow-current-entity))
 748   (set-alist 'mime-view-following-method-alist
 749              'wl-original-message-mode
 750              (function wl-message-follow-current-entity))
 751   (set-alist 'mime-edit-message-inserter-alist
 752              'wl-draft-mode (function wl-draft-insert-current-message))
 753   (set-alist 'mime-edit-mail-inserter-alist
 754              'wl-draft-mode (function wl-draft-insert-get-message))
 755   (set-alist 'mime-edit-split-message-sender-alist
 756              'wl-draft-mode
 757              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 758   (set-alist 'mime-raw-representation-type-alist
 759              'wl-original-message-mode 'binary)
 760   ;; Sort and highlight header fields.
 761   (or wl-message-ignored-field-list
 762       (setq wl-message-ignored-field-list
 763             mime-view-ignored-field-list))
 764   (or wl-message-visible-field-list
 765       (setq wl-message-visible-field-list
 766             mime-view-visible-field-list))
 767   (set-alist 'mime-header-presentation-method-alist
 768              'wl-original-message-mode
 769              'wl-mime-display-header)
 770   ;; To avoid overriding wl-draft-mode-map.
 771   (when (boundp 'mime-setup-signature-key-alist)
 772     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 773       (setq mime-setup-signature-key-alist
 774             (cons '(wl-draft-mode . "\C-c\C-w")
 775                   mime-setup-signature-key-alist)))))
 776
 777 (require 'product)
 778 (product-provide (provide 'wl-mime) (require 'wl-version))
 779
 780 ;;; wl-mime.el ends here