wl/wl-mime.el

   1 ;;; wl-mime.el -- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'mime-view)
  33 (require 'mime-edit)
  34 (require 'mime-play)
  35 (require 'mmelmo)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'Meadow-version 'ignore))
  39
  40 (defvar xemacs-betaname)
  41 (defvar xemacs-codename)
  42 (defvar enable-multibyte-characters)
  43 (defvar mule-version)
  44
  45 ;;; Draft
  46
  47 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  48
  49 (defalias 'wl-draft-decode-message-in-buffer
  50   'mime-edit-decode-message-in-buffer)
  51
  52 (defun wl-draft-yank-current-message-entity ()
  53   "Yank currently displayed message entity.
  54 By setting following-method as yank-content."
  55   (let ((wl-draft-buffer (current-buffer))
  56         (mime-view-following-method-alist
  57          (list (cons 'mmelmo-original-mode
  58                      (function wl-draft-yank-to-draft-buffer))))
  59         (mime-preview-following-method-alist
  60          (list (cons 'mmelmo-original-mode
  61                      (function wl-draft-yank-to-draft-buffer)))))
  62     (if (get-buffer (wl-current-message-buffer))
  63         (save-excursion
  64           (save-restriction
  65             (set-buffer (wl-current-message-buffer))
  66             (widen)
  67             (mime-preview-follow-current-entity))))))
  68
  69 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
  70
  71 ;; SEMI 1.13.5 or later.
  72 ;; (mime-display-message
  73 ;;  MESSAGE &optional
  74 ;;  PREVIEW-BUFFER MOTHER DEFAULT-KEYMAP-OR-FUNCTION ORIGINAL-MAJOR-MODE)
  75 ;; SEMI 1.13.4 or earlier.
  76 ;; (mime-display-message
  77 ;;  MESSAGE &optional
  78 ;;  PREVIEW-BUFFER MOTHER DEFAULT-KEYMAP-OR-FUNCTION)
  79 (static-if (or (and mime-user-interface-product
  80                     (eq (nth 0 (aref mime-user-interface-product 1)) 1)
  81                     (>= (nth 1 (aref mime-user-interface-product 1)) 14))
  82                (and mime-user-interface-product
  83                     (eq (nth 0 (aref mime-user-interface-product 1)) 1)
  84                     (eq (nth 1 (aref mime-user-interface-product 1)) 13)
  85                     (>= (nth 2 (aref mime-user-interface-product 1)) 5)))
  86     ;; Has original-major-mode optional argument.
  87     (defalias 'wl-mime-display-message 'mime-display-message)
  88   (defmacro wl-mime-display-message (message &optional
  89                                              preview-buffer mother
  90                                              default-keymap-or-function
  91                                              original-major-mode)
  92     (` (mime-display-message (, message) (, preview-buffer) (, mother)
  93                              (, default-keymap-or-function))))
  94   ;; User agent field of XEmacs has problem on SEMI 1.13.4 or earlier.
  95   (setq mime-edit-user-agent-value
  96         (concat
  97          (mime-product-name mime-user-interface-product) "/"
  98          (mapconcat
  99           #'number-to-string
 100           (mime-product-version mime-user-interface-product) ".")
 101          " (" (mime-product-code-name mime-user-interface-product)
 102          ") " (mime-product-name mime-library-product)
 103          "/" (mapconcat #'number-to-string
 104                         (mime-product-version mime-library-product) ".")
 105          " (" (mime-product-code-name mime-library-product) ") "
 106          (if (featurep 'xemacs)
 107              (concat
 108               (if (featurep 'mule) "MULE")
 109               " XEmacs"
 110               (if (string-match "\\s +\\((\\|\\\"\\)" emacs-version)
 111                   (concat "/" (substring emacs-version 0
 112                                          (match-beginning 0))
 113                           (if (and (boundp 'xemacs-betaname)
 114                                    ;; It does not exist in XEmacs
 115                                    ;; versions prior to 20.3.
 116                                    xemacs-betaname)
 117                               (concat " " xemacs-betaname)
 118                             "")
 119                           " (" xemacs-codename ") ("
 120                           system-configuration ")")
 121                 " (" emacs-version ")"))
 122            (let ((ver (if (string-match "\\.[0-9]+$" emacs-version)
 123                           (substring emacs-version 0 (match-beginning 0))
 124                         emacs-version)))
 125              (if (featurep 'mule)
 126                  (if (boundp 'enable-multibyte-characters)
 127                      (concat "Emacs/" ver
 128                              " (" system-configuration ")"
 129                              (if enable-multibyte-characters
 130                                  (concat " MULE/" mule-version)
 131                                " (with unibyte mode)")
 132                              (if (featurep 'meadow)
 133                                  (let ((mver (Meadow-version)))
 134                                    (if (string-match "^Meadow-" mver)
 135                                        (concat " Meadow/"
 136                                                (substring mver
 137                                                           (match-end 0)))))))
 138                    (concat "MULE/" mule-version
 139                            " (based on Emacs " ver ")"))
 140                (concat "Emacs/" ver " (" system-configuration ")")))))))
 141
 142 ;; FLIM 1.12.7
 143 ;; (mime-read-field FIELD-NAME &optional ENTITY)
 144 ;; FLIM 1.13.2 or later
 145 ;; (mime-entity-read-field ENTITY FIELD-NAME)
 146 (static-if (fboundp 'mime-entity-read-field)
 147     (defalias 'wl-mime-entity-read-field 'mime-entity-read-field)
 148   (defmacro wl-mime-entity-read-field (entity field-name)
 149     (` (mime-read-field (, field-name) (, entity)))))
 150
 151 (defun wl-draft-preview-message ()
 152   (interactive)
 153   (let ((mime-display-header-hook 'wl-highlight-headers)
 154         mime-view-ignored-field-list ; all header.
 155         (mime-edit-translate-buffer-hook (append
 156                                           (list 'wl-draft-config-exec)
 157                                           mime-edit-translate-buffer-hook)))
 158     (mime-edit-preview-message)
 159     (let ((buffer-read-only nil))
 160       (when wl-highlight-body-too
 161         (wl-highlight-body))
 162       (run-hooks 'wl-draft-preview-message-hook))))
 163
 164 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 165
 166 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 167
 168 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 169
 170 ;;; Message
 171
 172 (defun wl-message-decode-mode (outbuf inbuf)
 173   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 174         (mime-display-header-hook 'wl-highlight-headers))
 175     (mime-view-mode nil nil nil inbuf outbuf)))
 176
 177 (defun wl-message-decode-with-all-header (outbuf inbuf)
 178   (let ((mime-view-ignored-field-regexp "^:$")
 179         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 180         (mime-display-header-hook 'wl-highlight-headers)
 181         mime-view-ignored-field-list)
 182     (mime-view-mode nil nil nil inbuf outbuf)))
 183
 184 (defun wl-message-delete-mime-out-buf ()
 185   (let (mime-out-buf mime-out-win)
 186     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 187         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 188             (delete-window mime-out-win)))))
 189
 190 (defun wl-message-request-partial (folder number)
 191   (elmo-set-work-buf
 192    (elmo-read-msg-no-cache folder number (current-buffer))
 193    (mime-parse-buffer nil))); 'mime-buffer-entity)))
 194
 195 (defalias 'wl-message-read            'mime-preview-scroll-up-entity)
 196 (defalias 'wl-message-next-content    'mime-preview-move-to-next)
 197 (defalias 'wl-message-prev-content    'mime-preview-move-to-previous)
 198 (defalias 'wl-message-play-content    'mime-preview-play-current-entity)
 199 (defalias 'wl-message-extract-content 'mime-preview-extract-current-entity)
 200 (defalias 'wl-message-quit            'mime-preview-quit)
 201 (defalias 'wl-message-button-dispatcher-internal
 202   'mime-button-dispatcher)
 203
 204 ;;; Summary
 205 (defun wl-summary-burst-subr (children target number)
 206   ;; returns new number.
 207   (let (content-type message-entity granch)
 208     (while children
 209       (setq content-type (mime-entity-content-type (car children)))
 210       (if (eq (cdr (assq 'type content-type)) 'multipart)
 211           (setq number (wl-summary-burst-subr
 212                         (mime-entity-children (car children))
 213                         target
 214                         number))
 215         (when (and (eq (cdr (assq 'type content-type)) 'message)
 216                    (eq (cdr (assq 'subtype content-type)) 'rfc822))
 217           (message (format "Bursting...%s" (setq number (+ 1 number))))
 218           (setq message-entity
 219                 (car (mime-entity-children (car children))))
 220           (elmo-append-msg target
 221                            (mime-entity-body (car children))
 222                            (mime-entity-fetch-field message-entity
 223                                                     "Message-ID"))))
 224       (setq children (cdr children)))
 225     number))
 226
 227 (defun wl-summary-burst ()
 228   (interactive)
 229   (let ((raw-buf (wl-message-get-original-buffer))
 230         children message-entity content-type target)
 231     (save-excursion
 232       (setq target wl-summary-buffer-folder-name)
 233       (while (not (elmo-folder-writable-p target))
 234         (setq target
 235               (wl-summary-read-folder wl-default-folder "to extract to")))
 236       (wl-summary-set-message-buffer-or-redisplay)
 237       (save-excursion
 238         (set-buffer (get-buffer wl-message-buf-name))
 239         (setq message-entity (get-text-property (point-min) 'mime-view-entity)))
 240       (set-buffer raw-buf)
 241       (setq children (mime-entity-children message-entity))
 242       (when children
 243         (message "Bursting...")
 244         (wl-summary-burst-subr children target 0)
 245         (message "Bursting...done."))
 246       (if (elmo-folder-plugged-p target)
 247           (elmo-commit target)))
 248     (wl-summary-sync-update3)))
 249
 250 ;; internal variable.
 251 (defvar wl-mime-save-dir nil "Last saved directory.")
 252 ;;; Yet another save method.
 253 (defun wl-mime-save-content (entity situation)
 254   (let ((filename (read-file-name "Save to file: "
 255                                   (expand-file-name
 256                                    (or (mime-entity-safe-filename entity)
 257                                        ".")
 258                                    (or wl-mime-save-dir
 259                                        wl-tmp-dir)))))
 260     (while (file-directory-p filename)
 261       (setq filename (read-file-name "Please set filename (not directory): "
 262                                      filename)))
 263     (if (file-exists-p filename)
 264         (or (yes-or-no-p (format "File %s exists. Save anyway? " filename))
 265             (error "Not saved")))
 266     (setq wl-mime-save-dir (file-name-directory filename))
 267     (mime-write-entity-content entity filename)))
 268
 269 ;;; Yet another combine method.
 270 (defun wl-mime-combine-message/partial-pieces (entity situation)
 271   "Internal method for wl to combine message/partial messages
 272 automatically."
 273   (interactive)
 274   (let* ((msgdb (save-excursion
 275                   (set-buffer wl-message-buffer-cur-summary-buffer)
 276                   wl-summary-buffer-msgdb))
 277          (mime-display-header-hook 'wl-highlight-headers)
 278          (folder wl-message-buffer-cur-folder)
 279          (id (or (cdr (assoc "id" situation)) ""))
 280          (mother (current-buffer))
 281          subject-id overviews
 282          (root-dir (expand-file-name
 283                     (concat "m-prts-" (user-login-name))
 284                     temporary-file-directory))
 285          full-file)
 286     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 287     (setq full-file (concat root-dir "/FULL"))
 288     (if (or (file-exists-p full-file)
 289             (not (y-or-n-p "Merge partials?")))
 290         (with-current-buffer mother
 291           (mime-store-message/partial-piece entity situation))
 292       (setq subject-id
 293             (eword-decode-string
 294              (decode-mime-charset-string
 295               (wl-mime-entity-read-field entity 'Subject)
 296               wl-summary-buffer-mime-charset)))
 297       (if (string-match "[0-9\n]+" subject-id)
 298           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 299       (setq overviews (elmo-msgdb-get-overview msgdb))
 300       (catch 'tag
 301         (while overviews
 302           (when (string-match
 303                  (regexp-quote subject-id)
 304                  (elmo-msgdb-overview-entity-get-subject (car overviews)))
 305             (let* ((message
 306                     ;; request message at the cursor in Subject buffer.
 307                     (wl-message-request-partial
 308                      folder
 309                      (elmo-msgdb-overview-entity-get-number (car overviews))))
 310                    (situation (mime-entity-situation message))
 311                    (the-id (or (cdr (assoc "id" situation)) "")))
 312               (when (string= (downcase the-id)
 313                              (downcase id))
 314                 (with-current-buffer mother
 315                   (mime-store-message/partial-piece message situation))
 316                 (if (file-exists-p full-file)
 317                     (throw 'tag nil)))))
 318           (setq overviews (cdr overviews)))
 319         (message "Not all partials found.")))))
 320
 321 (defun wl-mime-header-presentation-method (entity situation)
 322   (let ((mmelmo-sort-field-list wl-message-sort-field-list))
 323     (mime-insert-header entity
 324                         wl-message-ignored-field-list
 325                         wl-message-visible-field-list)
 326     (wl-highlight-headers)))
 327
 328 ;;; Setup methods.
 329 (defun wl-mime-setup ()
 330   (set-alist 'mime-preview-quitting-method-alist
 331              'mmelmo-original-mode 'wl-message-exit)
 332   (set-alist 'mime-view-over-to-previous-method-alist
 333              'mmelmo-original-mode 'wl-message-exit)
 334   (set-alist 'mime-view-over-to-next-method-alist
 335              'mmelmo-original-mode 'wl-message-exit)
 336   (set-alist 'mime-preview-over-to-previous-method-alist
 337              'mmelmo-original-mode 'wl-message-exit)
 338   (set-alist 'mime-preview-over-to-next-method-alist
 339              'mmelmo-original-mode 'wl-message-exit)
 340   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 341   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 342
 343   (ctree-set-calist-strictly
 344    'mime-acting-condition
 345    '((type . message) (subtype . partial)
 346      (method .  wl-mime-combine-message/partial-pieces)
 347      (request-partial-message-method . wl-message-request-partial)
 348      (major-mode . mmelmo-original-mode)))
 349   (ctree-set-calist-strictly
 350    'mime-acting-condition
 351    '((mode . "extract")
 352      (major-mode . mmelmo-original-mode)
 353      (method . wl-mime-save-content)))
 354   (set-alist 'mime-preview-following-method-alist
 355              'mmelmo-original-mode
 356              (function wl-message-follow-current-entity))
 357   (set-alist 'mime-view-following-method-alist
 358              'mmelmo-original-mode
 359              (function wl-message-follow-current-entity))
 360   (set-alist 'mime-edit-message-inserter-alist
 361              'wl-draft-mode (function wl-draft-insert-current-message))
 362   (set-alist 'mime-edit-mail-inserter-alist
 363              'wl-draft-mode (function wl-draft-insert-get-message))
 364   (set-alist 'mime-edit-split-message-sender-alist
 365              'wl-draft-mode
 366              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 367   (set-alist 'mime-raw-representation-type-alist
 368              'mmelmo-original-mode 'binary)
 369   ;; Sort and highlight header fields.
 370   (or wl-message-ignored-field-list
 371       (setq wl-message-ignored-field-list
 372             mime-view-ignored-field-list))
 373   (or wl-message-visible-field-list
 374       (setq wl-message-visible-field-list
 375             mime-view-visible-field-list))
 376   (set-alist 'mime-header-presentation-method-alist
 377              'mmelmo-original-mode
 378              (function wl-mime-header-presentation-method))
 379   (add-hook 'mmelmo-entity-content-inserted-hook 'wl-highlight-body))
 380
 381
 382 (require 'product)
 383 (product-provide (provide 'wl-mime) (require 'wl-version))
 384
 385 ;;; wl-mime.el ends here