wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'mime-view)
  33 (require 'mime-edit)
  34 (require 'mime-play)
  35 (require 'elmo)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'Meadow-version 'ignore))
  39
  40 (defvar xemacs-betaname)
  41 (defvar xemacs-codename)
  42 (defvar enable-multibyte-characters)
  43 (defvar mule-version)
  44
  45 ;;; Draft
  46
  47 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  48
  49 (defalias 'wl-draft-decode-message-in-buffer
  50   'mime-edit-decode-message-in-buffer)
  51
  52 (defun wl-draft-yank-current-message-entity ()
  53   "Yank currently displayed message entity.
  54 By setting following-method as yank-content."
  55   (let ((wl-draft-buffer (current-buffer))
  56         (mime-view-following-method-alist
  57          (list (cons 'wl-original-message-mode
  58                      (function wl-draft-yank-to-draft-buffer))))
  59         (mime-preview-following-method-alist
  60          (list (cons 'wl-original-message-mode
  61                      (function wl-draft-yank-to-draft-buffer)))))
  62     (if (get-buffer (wl-current-message-buffer))
  63         (save-excursion
  64           (save-restriction
  65             (set-buffer (wl-current-message-buffer))
  66             (widen)
  67             (mime-preview-follow-current-entity))))))
  68
  69 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
  70
  71 (defun wl-draft-preview-message ()
  72   "Preview editing message."
  73   (interactive)
  74   (let* (recipients-message
  75          (current-point (point))
  76          (config-exec-flag wl-draft-config-exec-flag)
  77          (parent-folder wl-draft-parent-folder)
  78          (mime-display-header-hook 'wl-highlight-headers)
  79          (mime-header-encode-method-alist
  80           (append
  81            '((wl-draft-eword-encode-address-list
  82               .  (To Cc Bcc Resent-To Resent-Cc Bcc Resent-Bcc)))
  83            (if (boundp 'mime-header-encode-method-alist)
  84                (symbol-value 'mime-header-encode-method-alist))))
  85          mime-view-ignored-field-list   ; all header.
  86          (mime-edit-translate-buffer-hook
  87           (append
  88            (list
  89             (function
  90              (lambda ()
  91                (let ((wl-draft-config-exec-flag config-exec-flag)
  92                      (wl-draft-parent-folder parent-folder))
  93                  (goto-char current-point)
  94                  (run-hooks 'wl-draft-send-hook)
  95                  (setq recipients-message
  96                        (condition-case err
  97                            (concat "Recipients: "
  98                                    (mapconcat
  99                                     'identity
 100                                     (wl-draft-deduce-address-list
 101                                      (current-buffer)
 102                                      (point-min)
 103                                      (save-excursion
 104                                        (goto-char (point-min))
 105                                        (re-search-forward
 106                                         (concat
 107                                          "^"
 108                                          (regexp-quote mail-header-separator)
 109                                          "$")
 110                                         nil t)
 111                                        (point)))
 112                                     ", "))
 113                          (error
 114                           (kill-buffer (current-buffer))
 115                           (signal (car err) (cdr err)))))))))
 116            mime-edit-translate-buffer-hook)))
 117     (mime-edit-preview-message)
 118     (let ((buffer-read-only nil))
 119       (when wl-highlight-body-too
 120         (wl-highlight-body))
 121       (run-hooks 'wl-draft-preview-message-hook))
 122     (message recipients-message)))
 123
 124 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 125
 126 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 127
 128 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 129
 130 ;;; Message
 131
 132 (defun wl-message-decode-mode (outbuf inbuf)
 133   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 134         (mime-display-header-hook 'wl-highlight-headers))
 135     (mime-view-mode nil nil nil inbuf outbuf)))
 136
 137 (defun wl-message-decode-with-all-header (outbuf inbuf)
 138   (let ((mime-view-ignored-field-regexp "^:$")
 139         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 140         (mime-display-header-hook 'wl-highlight-headers)
 141         mime-view-ignored-field-list)
 142     (mime-view-mode nil nil nil inbuf outbuf)))
 143
 144 (defun wl-message-delete-mime-out-buf ()
 145   (let (mime-out-buf mime-out-win)
 146     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 147         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 148             (delete-window mime-out-win)))))
 149
 150 (defun wl-message-request-partial (folder number)
 151   (elmo-set-work-buf
 152    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 153                        number
 154                        (elmo-make-fetch-strategy 'entire)
 155                        nil
 156                        (current-buffer)
 157                        'unread)
 158    (mime-parse-buffer nil)))
 159
 160 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 161 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 162 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 163 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 164 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 165 (defalias 'wl-message-quit              'mime-preview-quit)
 166 (defalias 'wl-message-button-dispatcher-internal
 167   'mime-button-dispatcher)
 168
 169 (defsubst wl-mime-node-id-to-string (node-id)
 170   (if (consp node-id)
 171       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 172                  (reverse node-id)
 173                  ".")
 174     "0"))
 175
 176 (defun wl-message-delete-current-part ()
 177   "Delete a part under the cursor from the multipart message."
 178   (interactive)
 179   (let* ((entity (get-text-property (point) 'mime-view-entity))
 180          (node-id (mime-entity-node-id entity))
 181          (header-start (mime-buffer-entity-header-start-internal entity))
 182          (body-end (mime-buffer-entity-body-end-internal entity))
 183          (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 184          (number wl-message-buffer-cur-number)
 185          (msgid (elmo-message-field folder number 'message-id))
 186          (orig-buf wl-message-buffer-original-buffer))
 187     (if (eq (luna-class-name entity) 'mime-elmo-imap-entity)
 188         (error "Please fetch the entire message (by typing 'C-u .') and try again"))
 189     (with-current-buffer orig-buf
 190       (unless (string-equal
 191                (buffer-string)
 192                (elmo-message-fetch folder number
 193                                    (elmo-make-fetch-strategy 'entire)))
 194         (error "Buffer content differs from actual message")))
 195     (when (and (elmo-folder-writable-p folder)
 196                (buffer-live-p orig-buf)
 197                node-id
 198                (yes-or-no-p
 199                 (format "Do you really want to delete part %s? "
 200                         (wl-mime-node-id-to-string node-id))))
 201       (with-temp-buffer
 202         (insert-buffer orig-buf)
 203         (kill-region header-start body-end)
 204         (goto-char header-start)
 205         (insert "Content-Type: text/plain; charset=US-ASCII\n\n")
 206         (insert "** This part has been removed by Wanderlust **\n\n")
 207         (elmo-folder-append-buffer folder t))
 208
 209       (elmo-folder-append-messages
 210        (wl-folder-get-elmo-folder wl-trash-folder)
 211        folder (list number) nil)
 212       (elmo-folder-delete-messages folder (list number))
 213
 214       (when (file-exists-p (elmo-cache-get-path msgid))
 215         (delete-file (elmo-cache-get-path msgid)))
 216
 217       (mime-preview-quit)
 218       (wl-summary-toggle-disp-msg 'off)
 219       (wl-summary-sync nil "update"))))
 220
 221 ;;; Summary
 222 (defun wl-summary-burst-subr (message-entity target number)
 223   ;; returns new number.
 224   (let (content-type entity)
 225     (setq content-type (mime-entity-content-type message-entity))
 226     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 227            (dolist (entity (mime-entity-children message-entity))
 228              (setq number (wl-summary-burst-subr
 229                            entity
 230                            target
 231                            number))))
 232           ((and (eq (cdr (assq 'type content-type)) 'message)
 233                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 234            (message "Bursting...%s" (setq number (+ 1 number)))
 235            (setq entity
 236                  (car (mime-entity-children message-entity)))
 237            (with-temp-buffer
 238              (insert (mime-entity-body message-entity))
 239              (elmo-folder-append-buffer
 240               target
 241               (mime-entity-fetch-field entity "Message-ID")))))
 242     number))
 243
 244 (defun wl-summary-burst (&optional arg)
 245   "De-capsulate embedded messages in MIME format.
 246 With ARG, ask destination folder."
 247   (interactive "P")
 248   (let ((raw-buf (wl-summary-get-original-buffer))
 249         (view-buf wl-message-buffer)
 250         children message-entity content-type target)
 251     (save-excursion
 252       (setq target wl-summary-buffer-elmo-folder)
 253       (when (or arg (not (elmo-folder-writable-p target)))
 254         (let ((fld (wl-summary-read-folder wl-default-folder "to extract to")))
 255           (setq target (wl-folder-get-elmo-folder fld))))
 256       (wl-summary-set-message-buffer-or-redisplay)
 257       (with-current-buffer view-buf
 258         (setq message-entity (get-text-property (point-min) 'mime-view-entity)))
 259       (when message-entity
 260         (message "Bursting...")
 261         (with-current-buffer raw-buf
 262           (wl-summary-burst-subr message-entity target 0))
 263         (message "Bursting...done"))
 264       (if (elmo-folder-plugged-p target)
 265           (elmo-folder-check target)))
 266     (wl-summary-sync-update)))
 267
 268 ;; internal variable.
 269 (defvar wl-mime-save-directory nil "Last saved directory.")
 270 ;;; Yet another save method.
 271 (defun wl-mime-save-content (entity situation)
 272   (let ((filename (read-file-name "Save to file: "
 273                                   (expand-file-name
 274                                    (or (mime-entity-safe-filename entity)
 275                                        ".")
 276                                    (or wl-mime-save-directory
 277                                        wl-temporary-file-directory)))))
 278     (while (file-directory-p filename)
 279       (setq filename (read-file-name "Please set filename (not directory): "
 280                                      filename)))
 281     (if (and (file-exists-p filename)
 282              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 283                                        filename))))
 284         (message "Not saved")
 285       (setq wl-mime-save-directory (file-name-directory filename))
 286       (mime-write-entity-content entity filename))))
 287
 288 ;;; Yet another combine method.
 289 (defun wl-mime-combine-message/partial-pieces (entity situation)
 290   "Internal method for wl to combine message/partial messages automatically."
 291   (interactive)
 292   (let* ((msgdb (save-excursion
 293                   (set-buffer wl-message-buffer-cur-summary-buffer)
 294                   (wl-summary-buffer-msgdb)))
 295          (mime-display-header-hook 'wl-highlight-headers)
 296          (folder wl-message-buffer-cur-folder)
 297          (id (or (cdr (assoc "id" situation)) ""))
 298          (mother (current-buffer))
 299          (summary-buf wl-message-buffer-cur-summary-buffer)
 300          subject-id overviews
 301          (root-dir (expand-file-name
 302                     (concat "m-prts-" (user-login-name))
 303                     temporary-file-directory))
 304          full-file point)
 305     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 306     (setq full-file (concat root-dir "/FULL"))
 307     (if (or (file-exists-p full-file)
 308             (not (y-or-n-p "Merge partials? ")))
 309         (with-current-buffer mother
 310           (mime-store-message/partial-piece entity situation)
 311           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 312           (make-variable-buffer-local 'mime-preview-over-to-next-method-alist)
 313           (setq mime-preview-over-to-next-method-alist
 314                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 315                       mime-preview-over-to-next-method-alist))
 316           (make-variable-buffer-local 'mime-preview-over-to-previous-method-alist)
 317           (setq mime-preview-over-to-previous-method-alist
 318                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 319                       mime-preview-over-to-previous-method-alist)))
 320       (setq subject-id
 321             (eword-decode-string
 322              (decode-mime-charset-string
 323               (mime-entity-read-field entity 'Subject)
 324               wl-summary-buffer-mime-charset)))
 325       (if (string-match "[0-9\n]+" subject-id)
 326           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 327       (setq overviews (elmo-msgdb-get-overview msgdb))
 328       (catch 'tag
 329         (while overviews
 330           (when (string-match
 331                  (regexp-quote subject-id)
 332                  (elmo-msgdb-overview-entity-get-subject (car overviews)))
 333             (let* ((message
 334                     ;; request message at the cursor in Subject buffer.
 335                     (wl-message-request-partial
 336                      folder
 337                      (elmo-msgdb-overview-entity-get-number
 338                       (car overviews))))
 339                    (situation (mime-entity-situation message))
 340                    (the-id (or (cdr (assoc "id" situation)) "")))
 341               (when (string= (downcase the-id)
 342                              (downcase id))
 343                 (with-current-buffer mother
 344                   (mime-store-message/partial-piece message situation))
 345                 (if (file-exists-p full-file)
 346                     (throw 'tag nil)))))
 347           (setq overviews (cdr overviews)))
 348         (message "Not all partials found.")))))
 349
 350 (defun wl-mime-display-text/plain (entity situation)
 351   (let ((beg (point)))
 352     (mime-display-text/plain entity situation)
 353     (wl-highlight-message beg (point-max) t t)))
 354
 355 (defun wl-mime-display-header (entity situation)
 356   (let ((elmo-message-ignored-field-list
 357          (if wl-message-buffer-all-header-flag
 358              nil
 359            wl-message-ignored-field-list))
 360         (elmo-message-visible-field-list wl-message-visible-field-list)
 361         (elmo-message-sorted-field-list wl-message-sort-field-list))
 362     (elmo-mime-insert-header entity situation)
 363     (wl-highlight-headers)))
 364
 365 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 366   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 367         (original-buffer wl-message-buffer-original-buffer))
 368     (mime-decrypt-application/pgp-encrypted entity situation)
 369     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 370     (setq wl-message-buffer-original-buffer original-buffer)))
 371
 372
 373 ;;; Setup methods.
 374 (defun wl-mime-setup ()
 375   (set-alist 'mime-preview-quitting-method-alist
 376              'wl-original-message-mode 'wl-message-exit)
 377   (set-alist 'mime-view-over-to-previous-method-alist
 378              'wl-original-message-mode 'wl-message-exit)
 379   (set-alist 'mime-view-over-to-next-method-alist
 380              'wl-original-message-mode 'wl-message-exit)
 381   (set-alist 'mime-preview-over-to-previous-method-alist
 382              'wl-original-message-mode 'wl-message-exit)
 383   (set-alist 'mime-preview-over-to-next-method-alist
 384              'wl-original-message-mode 'wl-message-exit)
 385   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 386   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 387
 388   (ctree-set-calist-strictly
 389    'mime-preview-condition
 390    '((type . text) (subtype . plain)
 391      (body . visible)
 392      (body-presentation-method . wl-mime-display-text/plain)
 393      (major-mode . wl-original-message-mode)))
 394
 395   (ctree-set-calist-strictly
 396    'mime-acting-condition
 397    '((type . message) (subtype . partial)
 398      (method .  wl-mime-combine-message/partial-pieces)
 399      (request-partial-message-method . wl-message-request-partial)
 400      (major-mode . wl-original-message-mode)))
 401
 402   (ctree-set-calist-strictly
 403    'mime-acting-condition
 404    '((type . application) (subtype . pgp-encrypted)
 405      (method . wl-mime-decrypt-application/pgp-encrypted)
 406      (major-mode . wl-original-message-mode)))
 407
 408   (ctree-set-calist-strictly
 409    'mime-acting-condition
 410    '((mode . "extract")
 411      (major-mode . wl-original-message-mode)
 412      (method . wl-mime-save-content)))
 413   (set-alist 'mime-preview-following-method-alist
 414              'wl-original-message-mode
 415              (function wl-message-follow-current-entity))
 416   (set-alist 'mime-view-following-method-alist
 417              'wl-original-message-mode
 418              (function wl-message-follow-current-entity))
 419   (set-alist 'mime-edit-message-inserter-alist
 420              'wl-draft-mode (function wl-draft-insert-current-message))
 421   (set-alist 'mime-edit-mail-inserter-alist
 422              'wl-draft-mode (function wl-draft-insert-get-message))
 423   (set-alist 'mime-edit-split-message-sender-alist
 424              'wl-draft-mode
 425              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 426   (set-alist 'mime-raw-representation-type-alist
 427              'wl-original-message-mode 'binary)
 428   ;; Sort and highlight header fields.
 429   (or wl-message-ignored-field-list
 430       (setq wl-message-ignored-field-list
 431             mime-view-ignored-field-list))
 432   (or wl-message-visible-field-list
 433       (setq wl-message-visible-field-list
 434             mime-view-visible-field-list))
 435   (set-alist 'mime-header-presentation-method-alist
 436              'wl-original-message-mode
 437              'wl-mime-display-header)
 438   ;; To avoid overriding wl-draft-mode-map.
 439   (when (boundp 'mime-setup-signature-key-alist)
 440     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 441       (setq mime-setup-signature-key-alist
 442             (cons '(wl-draft-mode . "\C-c\C-w")
 443                   mime-setup-signature-key-alist)))))
 444
 445 (require 'product)
 446 (product-provide (provide 'wl-mime) (require 'wl-version))
 447
 448 ;;; wl-mime.el ends here