wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'mime-view)
  33 (require 'mime-edit)
  34 (require 'mime-play)
  35 (require 'elmo)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'pgg-decrypt-region 'ignore)
  39   (defalias-maybe 'pgg-display-output-buffer 'ignore)
  40   (defalias-maybe 'pgg-verify-region 'ignore))
  41
  42 ;;; Draft
  43
  44 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  45
  46 (defalias 'wl-draft-decode-message-in-buffer
  47   'mime-edit-decode-message-in-buffer)
  48
  49 (defun wl-draft-yank-current-message-entity ()
  50   "Yank currently displayed message entity.
  51 By setting following-method as yank-content.
  52
  53 If region is active, yank region contents instead. \(this feature is available
  54 if and only if `transient-mark-mode' \(GNU Emacs\) or `zmacs-regions' \(XEmacs\)
  55 has Non-nil value\)"
  56   (let ((wl-draft-buffer (current-buffer))
  57         (mime-view-following-method-alist
  58          (list (cons 'wl-original-message-mode
  59                      (function wl-draft-yank-to-draft-buffer))))
  60         (mime-preview-following-method-alist
  61          (list (cons 'wl-original-message-mode
  62                      (function wl-draft-yank-to-draft-buffer))))
  63         (message-buffer (wl-current-message-buffer)))
  64     (if message-buffer
  65         (save-excursion
  66           (set-buffer message-buffer)
  67           (save-restriction
  68             (widen)
  69             (if (wl-region-exists-p)
  70                 (wl-mime-preview-follow-current-region)
  71               (mime-preview-follow-current-entity))))
  72       (error "No message."))))
  73
  74 ;; modified mime-preview-follow-current-entity from mime-view.el
  75 (defun wl-mime-preview-follow-current-region ()
  76   "Write follow message to current region.
  77 It calls following-method selected from variable
  78 `mime-preview-following-method-alist'."
  79   (interactive)
  80   (let ((r-beg (region-beginning))
  81         (r-end (region-end))
  82         (entity (get-text-property (point-min)
  83                                    'mime-view-entity)))
  84     (let* ((mode (mime-preview-original-major-mode 'recursive))
  85            (new-name
  86             (format "%s-active-region" (buffer-name)))
  87            new-buf
  88            (the-buf (current-buffer))
  89            fields)
  90       (save-excursion
  91         (set-buffer (setq new-buf (get-buffer-create new-name)))
  92         (erase-buffer)
  93         (insert ?\n)
  94         (insert-buffer-substring the-buf r-beg r-end)
  95         (goto-char (point-min))
  96         (let ((current-entity
  97                (if (and (eq (mime-entity-media-type entity) 'message)
  98                         (eq (mime-entity-media-subtype entity) 'rfc822))
  99                    (car (mime-entity-children entity))
 100                  entity)))
 101           (while (and current-entity
 102                       (if (and (eq (mime-entity-media-type
 103                                     current-entity) 'message)
 104                                (eq (mime-entity-media-subtype
 105                                     current-entity) 'rfc822))
 106                           nil
 107                         (mime-insert-header current-entity fields)
 108                         t))
 109             (setq fields (std11-collect-field-names)
 110                   current-entity (mime-entity-parent current-entity))
 111             ))
 112         (let ((rest mime-view-following-required-fields-list)
 113               field-name ret)
 114           (while rest
 115             (setq field-name (car rest))
 116             (or (std11-field-body field-name)
 117                 (progn
 118                   (save-excursion
 119                     (set-buffer the-buf)
 120                     (let ((entity (when mime-mother-buffer
 121                                     (set-buffer mime-mother-buffer)
 122                                     (get-text-property (point)
 123                                                        'mime-view-entity))))
 124                       (while (and entity
 125                                   (null (setq ret (mime-entity-fetch-field
 126                                                    entity field-name))))
 127                         (setq entity (mime-entity-parent entity)))))
 128                   (if ret
 129                       (insert (concat field-name ": " ret "\n"))
 130                     )))
 131             (setq rest (cdr rest))
 132             ))
 133         )
 134       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 135         (if (functionp f)
 136             (funcall f new-buf)
 137           (message
 138            "Sorry, following method for %s is not implemented yet."
 139            mode)
 140           ))
 141       )))
 142
 143 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
 144
 145 (defun wl-draft-attribute-recipients ()
 146   (concat (mapconcat
 147            'identity
 148            (wl-draft-deduce-address-list
 149             (current-buffer)
 150             (point-min)
 151             (save-excursion
 152               (goto-char (point-min))
 153               (re-search-forward
 154                (concat
 155                 "^"
 156                 (regexp-quote mail-header-separator)
 157                 "$")
 158                nil t)
 159               (point)))
 160            ", ")))
 161
 162 (defun wl-draft-attribute-envelope-from ()
 163   (or wl-envelope-from
 164       (wl-address-header-extract-address wl-from)))
 165
 166 (defun wl-draft-attribute-smtp-posting-server ()
 167   (or wl-smtp-posting-server
 168       (progn (require 'smtp) smtp-server)
 169       "localhost"))
 170
 171 (defun wl-draft-attribute-smtp-posting-port ()
 172   (or wl-smtp-posting-port
 173       (progn (require 'smtp) smtp-service)))
 174
 175 (defun wl-draft-attribute-value (attr)
 176   (let ((name (symbol-name attr))
 177         fsymbol symbol)
 178     (cond ((and (setq fsymbol (intern-soft
 179                                (format "wl-draft-attribute-%s" name)))
 180                 (fboundp fsymbol))
 181            (funcall fsymbol))
 182           ((and (setq symbol (intern-soft (format "wl-%s" name)))
 183                 (boundp symbol))
 184            (symbol-value symbol))
 185           ((boundp attr)
 186            (symbol-value attr)))))
 187
 188 (defun wl-draft-preview-message ()
 189   "Preview editing message."
 190   (interactive)
 191   (let* (attribute-list
 192          (orig-buffer (current-buffer))
 193          (current-point (point))
 194          (config-exec-flag wl-draft-config-exec-flag)
 195          (parent-folder wl-draft-parent-folder)
 196          (mime-display-header-hook 'wl-highlight-headers)
 197          (mime-header-encode-method-alist
 198           (append
 199            '((wl-draft-eword-encode-address-list
 200               .  (To Cc Bcc Resent-To Resent-Cc Resent-Bcc From)))
 201            (if (boundp 'mime-header-encode-method-alist)
 202                (symbol-value 'mime-header-encode-method-alist))))
 203          mime-view-ignored-field-list   ; all header.
 204          (mime-edit-translate-buffer-hook
 205           (append
 206            (list
 207             (lambda ()
 208               (let ((wl-draft-config-exec-flag config-exec-flag)
 209                     (wl-draft-parent-folder parent-folder)
 210                     (copy-buffer (current-buffer)))
 211                 (with-current-buffer orig-buffer
 212                   (wl-copy-local-variables
 213                    orig-buffer
 214                    copy-buffer
 215                    (append wl-draft-config-variables
 216                            (wl-draft-clone-local-variables))))
 217                 (goto-char current-point)
 218                 (run-hooks 'wl-draft-send-hook)
 219                 (condition-case err
 220                     (setq attribute-list
 221                           (mapcar
 222                            (lambda (attr)
 223                              (cons attr (wl-draft-attribute-value attr)))
 224                            wl-draft-preview-attributes-list))
 225                   (error
 226                    (kill-buffer (current-buffer))
 227                    (signal (car err) (cdr err)))))))
 228            mime-edit-translate-buffer-hook)))
 229     (mime-edit-preview-message)
 230     (let ((buffer-read-only nil))
 231       (when wl-highlight-body-too
 232         (wl-highlight-body))
 233       (run-hooks 'wl-draft-preview-message-hook))
 234     (make-local-variable 'kill-buffer-hook)
 235     (add-hook 'kill-buffer-hook
 236               (lambda ()
 237                 (when (get-buffer-window
 238                        wl-draft-preview-attributes-buffer-name)
 239                   (select-window (get-buffer-window
 240                                   wl-draft-preview-attributes-buffer-name))
 241                   (delete-window))
 242                 (when (get-buffer wl-draft-preview-attributes-buffer-name)
 243                   (kill-buffer (get-buffer
 244                                 wl-draft-preview-attributes-buffer-name)))))
 245     (if (not wl-draft-preview-attributes)
 246         (message (concat "Recipients: "
 247                          (cdr (assq 'reciepient attribute-list))))
 248       (ignore-errors ; in case when the window is too small
 249         (let* ((cur-win (selected-window))
 250                (size (min
 251                       (- (window-height cur-win)
 252                          window-min-height 1)
 253                       (- (window-height cur-win)
 254                          (max
 255                           window-min-height
 256                           (1+ wl-draft-preview-attributes-buffer-lines))))))
 257           (split-window cur-win (if (> size 0) size window-min-height))
 258           (select-window (next-window))
 259           (let ((pop-up-windows nil))
 260             (switch-to-buffer (get-buffer-create
 261                                wl-draft-preview-attributes-buffer-name)))
 262           (with-current-buffer
 263               (get-buffer wl-draft-preview-attributes-buffer-name)
 264             (setq buffer-read-only t)
 265             (let (buffer-read-only)
 266               (erase-buffer)
 267               (dolist (pair attribute-list)
 268                 (insert (capitalize (symbol-name (car pair))) ": "
 269                         (format "%s" (or (cdr pair) ""))
 270                         "\n"))
 271               (goto-char (point-min))
 272               (wl-highlight-headers)))
 273           (select-window cur-win))))))
 274
 275 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 276
 277 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 278
 279 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 280
 281 ;;; Message
 282
 283 (defun wl-message-decode-mode (outbuf inbuf)
 284   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 285         (mime-display-header-hook 'wl-highlight-headers))
 286     (mime-view-mode nil nil nil inbuf outbuf)))
 287
 288 (defun wl-message-decode-with-all-header (outbuf inbuf)
 289   (let ((mime-view-ignored-field-regexp "^:$")
 290         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 291         (mime-display-header-hook 'wl-highlight-headers)
 292         mime-view-ignored-field-list)
 293     (mime-view-mode nil nil nil inbuf outbuf)))
 294
 295 (defun wl-message-delete-mime-out-buf ()
 296   (let (mime-out-buf mime-out-win)
 297     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 298         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 299             (delete-window mime-out-win)))))
 300
 301 (defun wl-message-request-partial (folder number)
 302   (elmo-set-work-buf
 303    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 304                        number
 305                        (elmo-make-fetch-strategy 'entire)
 306                        nil
 307                        (current-buffer)
 308                        'unread)
 309    (mime-parse-buffer nil)))
 310
 311 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 312 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 313 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 314 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 315 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 316 (defalias 'wl-message-quit              'mime-preview-quit)
 317 (defalias 'wl-message-button-dispatcher-internal
 318   'mime-button-dispatcher)
 319
 320 (defsubst wl-mime-node-id-to-string (node-id)
 321   (if (consp node-id)
 322       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 323                  (reverse node-id)
 324                  ".")
 325     "0"))
 326
 327 (defun wl-message-delete-current-part ()
 328   "Delete a part under the cursor from the multipart message."
 329   (interactive)
 330   (save-restriction
 331     (widen)
 332     (let* ((entity (get-text-property (point) 'mime-view-entity))
 333            (node-id (mime-entity-node-id entity))
 334            (header-start (mime-buffer-entity-header-start-internal entity))
 335            (body-end (mime-buffer-entity-body-end-internal entity))
 336            (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 337            (number wl-message-buffer-cur-number)
 338            (msgid (elmo-message-field folder number 'message-id))
 339            (orig-buf wl-message-buffer-original-buffer))
 340       (if (eq (luna-class-name entity) 'mime-elmo-imap-entity)
 341           (error "Please fetch the entire message (by typing 'C-u .') and try again"))
 342       (with-current-buffer orig-buf
 343         (unless (string-equal
 344                  (buffer-string)
 345                  (elmo-message-fetch folder number
 346                                      (elmo-make-fetch-strategy 'entire)))
 347           (error "Buffer content differs from actual message")))
 348       (when (and (elmo-folder-writable-p folder)
 349                  (buffer-live-p orig-buf)
 350                  node-id
 351                  (yes-or-no-p
 352                   (format "Do you really want to delete part %s? "
 353                           (wl-mime-node-id-to-string node-id))))
 354         (when (with-temp-buffer
 355                 (insert-buffer orig-buf)
 356                 (delete-region header-start body-end)
 357                 (goto-char header-start)
 358                 (insert "Content-Type: text/plain; charset=US-ASCII\n\n")
 359                 (insert "** This part has been removed by Wanderlust **\n\n")
 360                 (elmo-folder-append-buffer folder))
 361
 362           (elmo-folder-move-messages
 363            folder (list number)
 364            (wl-folder-get-elmo-folder wl-trash-folder))
 365           (when (and (elmo-cache-get-path msgid)
 366                      (file-exists-p (elmo-cache-get-path msgid)))
 367             (delete-file (elmo-cache-get-path msgid)))
 368
 369           (mime-preview-quit)
 370           (wl-summary-delete-messages-on-buffer (list number))
 371           (wl-summary-toggle-disp-msg 'off)
 372           (setq wl-message-buffer nil)
 373           (wl-summary-sync nil "update"))))))
 374
 375 (defun wl-message-decrypt-pgp-nonmime ()
 376   "Decrypt PGP encrypted region"
 377   (interactive)
 378   (require 'pgg)
 379   (save-excursion
 380     (beginning-of-line)
 381     (if (or (re-search-forward "^-+END PGP MESSAGE-+$" nil t)
 382             (re-search-backward "^-+END PGP MESSAGE-+$" nil t))
 383         (let (beg end status)
 384           (setq end (match-end 0))
 385           (if (setq beg (re-search-backward "^-+BEGIN PGP MESSAGE-+$" nil t))
 386               (let ((inhibit-read-only t)
 387                     (buffer-file-coding-system wl-cs-autoconv))
 388                 (setq status (pgg-decrypt-region beg end))
 389                 (pgg-display-output-buffer beg end status))
 390             (message "Cannot find pgp encrypted region")))
 391       (message "Cannot find pgp encrypted region"))))
 392
 393 (defun wl-message-verify-pgp-nonmime ()
 394   "Verify PGP signed region"
 395   (interactive)
 396   (require 'pgg)
 397   (save-excursion
 398     (beginning-of-line)
 399     (if (and (or (re-search-forward "^-+END PGP SIGNATURE-+$" nil t)
 400                  (re-search-backward "^-+END PGP SIGNATURE-+$" nil t))
 401              (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t))
 402         (let (status)
 403           (let* ((beg (point))
 404                  (situation (mime-preview-find-boundary-info))
 405                  (p-end (aref situation 1))
 406                  (entity (aref situation 2))
 407                  (count 0))
 408             (goto-char p-end)
 409             (while (< beg (point))
 410               (if (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t)
 411                   (setq count (+ count 1))
 412                 (debug)))
 413             (with-temp-buffer
 414               (set-buffer-multibyte nil)
 415               (insert (mime-entity-body entity))
 416               (goto-char (point-max))
 417               (while (> count 0)
 418                 (if (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t)
 419                     (setq count (- count 1))
 420                   (debug)))
 421               (let ((r-beg (point))
 422                     (r-end (re-search-forward "^-+END PGP SIGNATURE-+$" nil t)))
 423                 (if r-end
 424                     (setq status (pgg-verify-region r-beg r-end nil 'fetch))
 425                   (debug)))))
 426           (mime-show-echo-buffer)
 427           (set-buffer mime-echo-buffer-name)
 428           (set-window-start
 429            (get-buffer-window mime-echo-buffer-name)
 430            (point-max))
 431           (insert-buffer-substring
 432            (if status pgg-output-buffer pgg-errors-buffer)))
 433       (message "Cannot find pgp signed region"))))
 434
 435 ;; XXX: encrypted multipart isn't represented as multipart
 436 (defun wl-mime-preview-application/pgp (parent-entity entity situation)
 437   (require 'pgg)
 438   (goto-char (point-max))
 439   (let ((p (point))
 440         raw-buf to-buf representation-type child-entity)
 441     (goto-char p)
 442     (save-restriction
 443       (narrow-to-region p p)
 444       (setq to-buf (current-buffer))
 445       (with-temp-buffer
 446         (setq raw-buf (current-buffer))
 447         (mime-insert-entity entity)
 448         (when (progn
 449                 (goto-char (point-min))
 450                 (re-search-forward "^-+BEGIN PGP MESSAGE-+$" nil t))
 451           (pgg-decrypt-region (point-min)(point-max))
 452           (delete-region (point-min) (point-max))
 453           (insert-buffer pgg-output-buffer)
 454           (setq representation-type 'elmo-buffer))
 455         (setq child-entity (mime-parse-message
 456                             (mm-expand-class-name representation-type)
 457                             nil
 458                             parent-entity
 459                             (mime-entity-node-id-internal parent-entity)))
 460         (mime-display-entity
 461          child-entity
 462          nil
 463          `((header . visible)
 464            (body . visible)
 465            (entity-button . invisible))
 466          to-buf)))))
 467
 468 (defun wl-mime-preview-application/pgp-encrypted (entity situation)
 469   (let* ((entity-node-id (mime-entity-node-id entity))
 470          (mother (mime-entity-parent entity))
 471          (knum (car entity-node-id))
 472          (onum (if (> knum 0)
 473                    (1- knum)
 474                  (1+ knum)))
 475          (orig-entity (nth onum (mime-entity-children mother))))
 476     (wl-mime-preview-application/pgp entity orig-entity situation)))
 477
 478 ;;; Summary
 479 (defun wl-summary-burst-subr (message-entity target number)
 480   ;; returns new number.
 481   (let (content-type entity)
 482     (setq content-type (mime-entity-content-type message-entity))
 483     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 484            (dolist (entity (mime-entity-children message-entity))
 485              (setq number (wl-summary-burst-subr
 486                            entity
 487                            target
 488                            number))))
 489           ((and (eq (cdr (assq 'type content-type)) 'message)
 490                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 491            (message "Bursting...%s" (setq number (+ 1 number)))
 492            (setq entity
 493                  (car (mime-entity-children message-entity)))
 494            (with-temp-buffer
 495              (insert (mime-entity-body message-entity))
 496              (elmo-folder-append-buffer target))))
 497     number))
 498
 499 (defun wl-summary-burst (&optional arg)
 500   "De-capsulate embedded messages in MIME format.
 501 With ARG, ask destination folder."
 502   (interactive "P")
 503   (let ((raw-buf (wl-summary-get-original-buffer))
 504         (view-buf wl-message-buffer)
 505         message-entity target)
 506     (save-excursion
 507       (when (and (null arg)
 508                  (elmo-folder-writable-p wl-summary-buffer-elmo-folder))
 509         (setq target wl-summary-buffer-elmo-folder))
 510       (while (null target)
 511         (let ((name (wl-summary-read-folder wl-default-folder
 512                                             "to extract to")))
 513           (setq target (wl-folder-get-elmo-folder name))
 514           (unless (elmo-folder-writable-p target)
 515             (message "%s is not writable" name)
 516             (setq target nil)
 517             (sit-for 1))))
 518       (wl-summary-set-message-buffer-or-redisplay)
 519       (with-current-buffer view-buf
 520         (setq message-entity
 521               (get-text-property (point-min) 'mime-view-entity)))
 522       (when message-entity
 523         (message "Bursting...")
 524         (with-current-buffer raw-buf
 525           (wl-summary-burst-subr message-entity target 0))
 526         (message "Bursting...done"))
 527       (if (elmo-folder-plugged-p target)
 528           (elmo-folder-check target)))
 529     (when (and target
 530                (string= wl-summary-buffer-folder-name
 531                         (elmo-folder-name-internal target)))
 532       (save-excursion (wl-summary-sync-update)))))
 533
 534 ;; internal variable.
 535 (defvar wl-mime-save-directory nil "Last saved directory.")
 536 ;;; Yet another save method.
 537 (defun wl-mime-save-content (entity situation)
 538   (let ((filename (read-file-name "Save to file: "
 539                                   (expand-file-name
 540                                    (or (mime-entity-safe-filename entity)
 541                                        ".")
 542                                    (or wl-mime-save-directory
 543                                        wl-temporary-file-directory)))))
 544     (while (file-directory-p filename)
 545       (setq filename (read-file-name "Please set filename (not directory): "
 546                                      filename)))
 547     (if (and (file-exists-p filename)
 548              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 549                                        filename))))
 550         (message "Not saved")
 551       (setq wl-mime-save-directory (file-name-directory filename))
 552       (mime-write-entity-content entity filename))))
 553
 554 ;;; Yet another combine method.
 555 (defun wl-mime-combine-message/partial-pieces (entity situation)
 556   "Internal method for wl to combine message/partial messages automatically."
 557   (interactive)
 558   (let* ((folder (with-current-buffer wl-message-buffer-cur-summary-buffer
 559                    wl-summary-buffer-elmo-folder))
 560          (mime-display-header-hook 'wl-highlight-headers)
 561          (id (or (cdr (assoc "id" situation)) ""))
 562          (mother (current-buffer))
 563          (summary-buf wl-message-buffer-cur-summary-buffer)
 564          subject-id overviews
 565          (root-dir (expand-file-name
 566                     (concat "m-prts-" (user-login-name))
 567                     temporary-file-directory))
 568          full-file point)
 569     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 570     (setq full-file (concat root-dir "/FULL"))
 571     (if (or (file-exists-p full-file)
 572             (not (y-or-n-p "Merge partials? ")))
 573         (with-current-buffer mother
 574           (mime-store-message/partial-piece entity situation)
 575           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 576           (make-variable-buffer-local 'mime-preview-over-to-next-method-alist)
 577           (setq mime-preview-over-to-next-method-alist
 578                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 579                       mime-preview-over-to-next-method-alist))
 580           (make-variable-buffer-local 'mime-preview-over-to-previous-method-alist)
 581           (setq mime-preview-over-to-previous-method-alist
 582                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 583                       mime-preview-over-to-previous-method-alist)))
 584       (setq subject-id
 585             (eword-decode-string
 586              (decode-mime-charset-string
 587               (mime-entity-read-field entity 'Subject)
 588               wl-summary-buffer-mime-charset)))
 589       (if (string-match "[0-9\n]+" subject-id)
 590           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 591       (catch 'tag
 592         (elmo-folder-do-each-message-entity (entity folder)
 593           (when (string-match
 594                  (regexp-quote subject-id)
 595                  (elmo-message-entity-field entity 'subject 'decode))
 596             (let* ((message
 597                     ;; request message at the cursor in Subject buffer.
 598                     (wl-message-request-partial
 599                      (elmo-folder-name-internal folder)
 600                      (elmo-message-entity-number entity)))
 601                    (situation (mime-entity-situation message))
 602                    (the-id (or (cdr (assoc "id" situation)) "")))
 603               (when (string= (downcase the-id)
 604                              (downcase id))
 605                 (with-current-buffer mother
 606                   (mime-store-message/partial-piece message situation))
 607                 (if (file-exists-p full-file)
 608                     (throw 'tag nil))))))
 609         (message "Not all partials found.")))))
 610
 611 (defun wl-mime-display-text/plain (entity situation)
 612   (let ((beg (point)))
 613     (mime-display-text/plain entity situation)
 614     (wl-highlight-message beg (point-max) t t)))
 615
 616 (defun wl-mime-display-header (entity situation)
 617   (let ((elmo-message-ignored-field-list
 618          (if wl-message-buffer-all-header-flag
 619              nil
 620            wl-message-ignored-field-list))
 621         (elmo-message-visible-field-list wl-message-visible-field-list)
 622         (elmo-message-sorted-field-list wl-message-sort-field-list))
 623     (elmo-mime-insert-header entity situation)
 624     (wl-highlight-headers)))
 625
 626 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 627   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 628         (original-buffer wl-message-buffer-original-buffer))
 629     (mime-decrypt-application/pgp-encrypted entity situation)
 630     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 631     (setq wl-message-buffer-original-buffer original-buffer)))
 632
 633
 634 ;;; Setup methods.
 635 (defun wl-mime-setup ()
 636   (set-alist 'mime-preview-quitting-method-alist
 637              'wl-original-message-mode 'wl-message-exit)
 638   (set-alist 'mime-view-over-to-previous-method-alist
 639              'wl-original-message-mode 'wl-message-exit)
 640   (set-alist 'mime-view-over-to-next-method-alist
 641              'wl-original-message-mode 'wl-message-exit)
 642   (set-alist 'mime-preview-over-to-previous-method-alist
 643              'wl-original-message-mode 'wl-message-exit)
 644   (set-alist 'mime-preview-over-to-next-method-alist
 645              'wl-original-message-mode 'wl-message-exit)
 646   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 647   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 648
 649   (ctree-set-calist-strictly
 650    'mime-preview-condition
 651    '((type . text) (subtype . plain)
 652      (body . visible)
 653      (body-presentation-method . wl-mime-display-text/plain)
 654      (major-mode . wl-original-message-mode)))
 655
 656   (ctree-set-calist-strictly
 657    'mime-preview-condition
 658    '((type . application)(subtype . pgp-encrypted)
 659      (encoding . t)
 660      (body . invisible)
 661      (body-presentation-method . wl-mime-preview-application/pgp-encrypted)
 662      (major-mode . wl-original-message-mode)))
 663
 664   (ctree-set-calist-strictly
 665    'mime-acting-condition
 666    '((type . message) (subtype . partial)
 667      (method .  wl-mime-combine-message/partial-pieces)
 668      (request-partial-message-method . wl-message-request-partial)
 669      (major-mode . wl-original-message-mode)))
 670
 671   (ctree-set-calist-strictly
 672    'mime-acting-condition
 673    '((type . application) (subtype . pgp-encrypted)
 674      (method . wl-mime-decrypt-application/pgp-encrypted)
 675      (major-mode . wl-original-message-mode)))
 676
 677   (ctree-set-calist-strictly
 678    'mime-acting-condition
 679    '((mode . "extract")
 680      (major-mode . wl-original-message-mode)
 681      (method . wl-mime-save-content)))
 682   (set-alist 'mime-preview-following-method-alist
 683              'wl-original-message-mode
 684              (function wl-message-follow-current-entity))
 685   (set-alist 'mime-view-following-method-alist
 686              'wl-original-message-mode
 687              (function wl-message-follow-current-entity))
 688   (set-alist 'mime-edit-message-inserter-alist
 689              'wl-draft-mode (function wl-draft-insert-current-message))
 690   (set-alist 'mime-edit-mail-inserter-alist
 691              'wl-draft-mode (function wl-draft-insert-get-message))
 692   (set-alist 'mime-edit-split-message-sender-alist
 693              'wl-draft-mode
 694              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 695   (set-alist 'mime-raw-representation-type-alist
 696              'wl-original-message-mode 'binary)
 697   ;; Sort and highlight header fields.
 698   (or wl-message-ignored-field-list
 699       (setq wl-message-ignored-field-list
 700             mime-view-ignored-field-list))
 701   (or wl-message-visible-field-list
 702       (setq wl-message-visible-field-list
 703             mime-view-visible-field-list))
 704   (set-alist 'mime-header-presentation-method-alist
 705              'wl-original-message-mode
 706              'wl-mime-display-header)
 707   ;; To avoid overriding wl-draft-mode-map.
 708   (when (boundp 'mime-setup-signature-key-alist)
 709     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 710       (setq mime-setup-signature-key-alist
 711             (cons '(wl-draft-mode . "\C-c\C-w")
 712                   mime-setup-signature-key-alist)))))
 713
 714 (require 'product)
 715 (product-provide (provide 'wl-mime) (require 'wl-version))
 716
 717 ;;; wl-mime.el ends here