wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'mime-view)
  33 (require 'mime-edit)
  34 (require 'mime-play)
  35 (require 'elmo)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'Meadow-version 'ignore))
  39
  40 (defvar xemacs-betaname)
  41 (defvar xemacs-codename)
  42 (defvar enable-multibyte-characters)
  43 (defvar mule-version)
  44
  45 ;;; Draft
  46
  47 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  48
  49 (defalias 'wl-draft-decode-message-in-buffer
  50   'mime-edit-decode-message-in-buffer)
  51
  52 (defun wl-draft-yank-current-message-entity ()
  53   "Yank currently displayed message entity.
  54 By setting following-method as yank-content.
  55
  56 If region is active, yank region contents instead. \(this feature is available
  57 if and only if `transient-mark-mode' \(GNU Emacs\) or `zmacs-regions' \(XEmacs\)
  58 has Non-nil value\)"
  59   (let ((wl-draft-buffer (current-buffer))
  60         (mime-view-following-method-alist
  61          (list (cons 'wl-original-message-mode
  62                      (function wl-draft-yank-to-draft-buffer))))
  63         (mime-preview-following-method-alist
  64          (list (cons 'wl-original-message-mode
  65                      (function wl-draft-yank-to-draft-buffer)))))
  66     (if (get-buffer (wl-current-message-buffer))
  67         (save-excursion
  68           (set-buffer (wl-current-message-buffer))
  69           (save-restriction
  70             (widen)
  71               (if (or (and wl-on-xemacs
  72                            zmacs-regions zmacs-region-active-p)
  73                       (and transient-mark-mode mark-active))
  74                   (wl-mime-preview-follow-current-region)
  75                 (mime-preview-follow-current-entity)))))))
  76
  77 ;; modified mime-preview-follow-current-entity from mime-view.el
  78 (defun wl-mime-preview-follow-current-region ()
  79   "Write follow message to current region.
  80 It calls following-method selected from variable
  81 `mime-preview-following-method-alist'."
  82   (interactive)
  83   (let ((r-beg (region-beginning))
  84         (r-end (region-end))
  85         (entity (get-text-property (point-min)
  86                                    'mime-view-entity)))
  87     (let* ((mode (mime-preview-original-major-mode 'recursive))
  88            (new-name
  89             (format "%s-active-region" (buffer-name)))
  90            new-buf
  91            (the-buf (current-buffer))
  92            fields)
  93       (save-excursion
  94         (set-buffer (setq new-buf (get-buffer-create new-name)))
  95         (erase-buffer)
  96         (insert ?\n)
  97         (insert-buffer-substring the-buf r-beg r-end)
  98         (goto-char (point-min))
  99         (let ((current-entity
 100                (if (and (eq (mime-entity-media-type entity) 'message)
 101                         (eq (mime-entity-media-subtype entity) 'rfc822))
 102                    (car (mime-entity-children entity))
 103                  entity)))
 104           (while (and current-entity
 105                       (if (and (eq (mime-entity-media-type
 106                                     current-entity) 'message)
 107                                (eq (mime-entity-media-subtype
 108                                     current-entity) 'rfc822))
 109                           nil
 110                         (mime-insert-header current-entity fields)
 111                         t))
 112             (setq fields (std11-collect-field-names)
 113                   current-entity (mime-entity-parent current-entity))
 114             ))
 115         (let ((rest mime-view-following-required-fields-list)
 116               field-name ret)
 117           (while rest
 118             (setq field-name (car rest))
 119             (or (std11-field-body field-name)
 120                 (progn
 121                   (save-excursion
 122                     (set-buffer the-buf)
 123                     (let ((entity (when mime-mother-buffer
 124                                     (set-buffer mime-mother-buffer)
 125                                     (get-text-property (point)
 126                                                        'mime-view-entity))))
 127                       (while (and entity
 128                                   (null (setq ret (mime-entity-fetch-field
 129                                                    entity field-name))))
 130                         (setq entity (mime-entity-parent entity)))))
 131                   (if ret
 132                       (insert (concat field-name ": " ret "\n"))
 133                     )))
 134             (setq rest (cdr rest))
 135             ))
 136         )
 137       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 138         (if (functionp f)
 139             (funcall f new-buf)
 140           (message
 141            (format
 142             "Sorry, following method for %s is not implemented yet."
 143             mode))
 144           ))
 145       )))
 146
 147 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
 148
 149 (defun wl-draft-preview-message ()
 150   "Preview editing message."
 151   (interactive)
 152   (let* (recipients-message
 153          (current-point (point))
 154          (config-exec-flag wl-draft-config-exec-flag)
 155          (parent-folder wl-draft-parent-folder)
 156          (mime-display-header-hook 'wl-highlight-headers)
 157          (mime-header-encode-method-alist
 158           (append
 159            '((wl-draft-eword-encode-address-list
 160               .  (To Cc Bcc Resent-To Resent-Cc Bcc Resent-Bcc)))
 161            (if (boundp 'mime-header-encode-method-alist)
 162                (symbol-value 'mime-header-encode-method-alist))))
 163          mime-view-ignored-field-list   ; all header.
 164          (mime-edit-translate-buffer-hook
 165           (append
 166            (list
 167             (function
 168              (lambda ()
 169                (let ((wl-draft-config-exec-flag config-exec-flag)
 170                      (wl-draft-parent-folder parent-folder))
 171                  (goto-char current-point)
 172                  (run-hooks 'wl-draft-send-hook)
 173                  (setq recipients-message
 174                        (condition-case err
 175                            (concat "Recipients: "
 176                                    (mapconcat
 177                                     'identity
 178                                     (wl-draft-deduce-address-list
 179                                      (current-buffer)
 180                                      (point-min)
 181                                      (save-excursion
 182                                        (goto-char (point-min))
 183                                        (re-search-forward
 184                                         (concat
 185                                          "^"
 186                                          (regexp-quote mail-header-separator)
 187                                          "$")
 188                                         nil t)
 189                                        (point)))
 190                                     ", "))
 191                          (error
 192                           (kill-buffer (current-buffer))
 193                           (signal (car err) (cdr err)))))))))
 194            mime-edit-translate-buffer-hook)))
 195     (mime-edit-preview-message)
 196     (let ((buffer-read-only nil))
 197       (when wl-highlight-body-too
 198         (wl-highlight-body))
 199       (run-hooks 'wl-draft-preview-message-hook))
 200     (message recipients-message)))
 201
 202 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 203
 204 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 205
 206 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 207
 208 ;;; Message
 209
 210 (defun wl-message-decode-mode (outbuf inbuf)
 211   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 212         (mime-display-header-hook 'wl-highlight-headers))
 213     (mime-view-mode nil nil nil inbuf outbuf)))
 214
 215 (defun wl-message-decode-with-all-header (outbuf inbuf)
 216   (let ((mime-view-ignored-field-regexp "^:$")
 217         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 218         (mime-display-header-hook 'wl-highlight-headers)
 219         mime-view-ignored-field-list)
 220     (mime-view-mode nil nil nil inbuf outbuf)))
 221
 222 (defun wl-message-delete-mime-out-buf ()
 223   (let (mime-out-buf mime-out-win)
 224     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 225         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 226             (delete-window mime-out-win)))))
 227
 228 (defun wl-message-request-partial (folder number)
 229   (elmo-set-work-buf
 230    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 231                        number
 232                        (elmo-make-fetch-strategy 'entire)
 233                        nil
 234                        (current-buffer)
 235                        'unread)
 236    (mime-parse-buffer nil)))
 237
 238 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 239 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 240 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 241 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 242 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 243 (defalias 'wl-message-quit              'mime-preview-quit)
 244 (defalias 'wl-message-button-dispatcher-internal
 245   'mime-button-dispatcher)
 246
 247 (defsubst wl-mime-node-id-to-string (node-id)
 248   (if (consp node-id)
 249       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 250                  (reverse node-id)
 251                  ".")
 252     "0"))
 253
 254 (defun wl-message-delete-current-part ()
 255   "Delete a part under the cursor from the multipart message."
 256   (interactive)
 257   (save-restriction
 258     (widen)
 259     (let* ((entity (get-text-property (point) 'mime-view-entity))
 260            (node-id (mime-entity-node-id entity))
 261            (header-start (mime-buffer-entity-header-start-internal entity))
 262            (body-end (mime-buffer-entity-body-end-internal entity))
 263            (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 264            (number wl-message-buffer-cur-number)
 265            (msgid (elmo-message-field folder number 'message-id))
 266            (orig-buf wl-message-buffer-original-buffer))
 267       (if (eq (luna-class-name entity) 'mime-elmo-imap-entity)
 268           (error "Please fetch the entire message (by typing 'C-u .') and try again"))
 269       (with-current-buffer orig-buf
 270         (unless (string-equal
 271                  (buffer-string)
 272                  (elmo-message-fetch folder number
 273                                      (elmo-make-fetch-strategy 'entire)))
 274           (error "Buffer content differs from actual message")))
 275       (when (and (elmo-folder-writable-p folder)
 276                  (buffer-live-p orig-buf)
 277                  node-id
 278                  (yes-or-no-p
 279                   (format "Do you really want to delete part %s? "
 280                           (wl-mime-node-id-to-string node-id))))
 281         (with-temp-buffer
 282           (insert-buffer orig-buf)
 283           (kill-region header-start body-end)
 284           (goto-char header-start)
 285           (insert "Content-Type: text/plain; charset=US-ASCII\n\n")
 286           (insert "** This part has been removed by Wanderlust **\n\n")
 287           (elmo-folder-append-buffer folder t))
 288
 289         (elmo-folder-append-messages
 290          (wl-folder-get-elmo-folder wl-trash-folder)
 291          folder (list number) nil)
 292         (elmo-folder-delete-messages folder (list number))
 293
 294         (when (file-exists-p (elmo-cache-get-path msgid))
 295           (delete-file (elmo-cache-get-path msgid)))
 296
 297         (mime-preview-quit)
 298         (wl-summary-toggle-disp-msg 'off)
 299         (wl-summary-sync nil "update")))))
 300
 301 ;;; Summary
 302 (defun wl-summary-burst-subr (message-entity target number)
 303   ;; returns new number.
 304   (let (content-type entity)
 305     (setq content-type (mime-entity-content-type message-entity))
 306     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 307            (dolist (entity (mime-entity-children message-entity))
 308              (setq number (wl-summary-burst-subr
 309                            entity
 310                            target
 311                            number))))
 312           ((and (eq (cdr (assq 'type content-type)) 'message)
 313                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 314            (message "Bursting...%s" (setq number (+ 1 number)))
 315            (setq entity
 316                  (car (mime-entity-children message-entity)))
 317            (with-temp-buffer
 318              (insert (mime-entity-body message-entity))
 319              (elmo-folder-append-buffer
 320               target
 321               (mime-entity-fetch-field entity "Message-ID")))))
 322     number))
 323
 324 (defun wl-summary-burst (&optional arg)
 325   "De-capsulate embedded messages in MIME format.
 326 With ARG, ask destination folder."
 327   (interactive "P")
 328   (let ((raw-buf (wl-summary-get-original-buffer))
 329         (view-buf wl-message-buffer)
 330         children message-entity content-type target)
 331     (save-excursion
 332       (setq target wl-summary-buffer-elmo-folder)
 333       (when (or arg (not (elmo-folder-writable-p target)))
 334         (let ((fld (wl-summary-read-folder wl-default-folder "to extract to")))
 335           (setq target (wl-folder-get-elmo-folder fld))))
 336       (wl-summary-set-message-buffer-or-redisplay)
 337       (with-current-buffer view-buf
 338         (setq message-entity (get-text-property (point-min) 'mime-view-entity)))
 339       (when message-entity
 340         (message "Bursting...")
 341         (with-current-buffer raw-buf
 342           (wl-summary-burst-subr message-entity target 0))
 343         (message "Bursting...done"))
 344       (if (elmo-folder-plugged-p target)
 345           (elmo-folder-check target)))
 346     (wl-summary-sync-update)))
 347
 348 ;; internal variable.
 349 (defvar wl-mime-save-directory nil "Last saved directory.")
 350 ;;; Yet another save method.
 351 (defun wl-mime-save-content (entity situation)
 352   (let ((filename (read-file-name "Save to file: "
 353                                   (expand-file-name
 354                                    (or (mime-entity-safe-filename entity)
 355                                        ".")
 356                                    (or wl-mime-save-directory
 357                                        wl-temporary-file-directory)))))
 358     (while (file-directory-p filename)
 359       (setq filename (read-file-name "Please set filename (not directory): "
 360                                      filename)))
 361     (if (and (file-exists-p filename)
 362              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 363                                        filename))))
 364         (message "Not saved")
 365       (setq wl-mime-save-directory (file-name-directory filename))
 366       (mime-write-entity-content entity filename))))
 367
 368 ;;; Yet another combine method.
 369 (defun wl-mime-combine-message/partial-pieces (entity situation)
 370   "Internal method for wl to combine message/partial messages automatically."
 371   (interactive)
 372   (let* ((msgdb (save-excursion
 373                   (set-buffer wl-message-buffer-cur-summary-buffer)
 374                   (wl-summary-buffer-msgdb)))
 375          (mime-display-header-hook 'wl-highlight-headers)
 376          (folder wl-message-buffer-cur-folder)
 377          (id (or (cdr (assoc "id" situation)) ""))
 378          (mother (current-buffer))
 379          (summary-buf wl-message-buffer-cur-summary-buffer)
 380          subject-id overviews
 381          (root-dir (expand-file-name
 382                     (concat "m-prts-" (user-login-name))
 383                     temporary-file-directory))
 384          full-file point)
 385     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 386     (setq full-file (concat root-dir "/FULL"))
 387     (if (or (file-exists-p full-file)
 388             (not (y-or-n-p "Merge partials? ")))
 389         (with-current-buffer mother
 390           (mime-store-message/partial-piece entity situation)
 391           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 392           (make-variable-buffer-local 'mime-preview-over-to-next-method-alist)
 393           (setq mime-preview-over-to-next-method-alist
 394                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 395                       mime-preview-over-to-next-method-alist))
 396           (make-variable-buffer-local 'mime-preview-over-to-previous-method-alist)
 397           (setq mime-preview-over-to-previous-method-alist
 398                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 399                       mime-preview-over-to-previous-method-alist)))
 400       (setq subject-id
 401             (eword-decode-string
 402              (decode-mime-charset-string
 403               (mime-entity-read-field entity 'Subject)
 404               wl-summary-buffer-mime-charset)))
 405       (if (string-match "[0-9\n]+" subject-id)
 406           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 407       (setq overviews (elmo-msgdb-get-overview msgdb))
 408       (catch 'tag
 409         (while overviews
 410           (when (string-match
 411                  (regexp-quote subject-id)
 412                  (elmo-msgdb-overview-entity-get-subject (car overviews)))
 413             (let* ((message
 414                     ;; request message at the cursor in Subject buffer.
 415                     (wl-message-request-partial
 416                      folder
 417                      (elmo-msgdb-overview-entity-get-number
 418                       (car overviews))))
 419                    (situation (mime-entity-situation message))
 420                    (the-id (or (cdr (assoc "id" situation)) "")))
 421               (when (string= (downcase the-id)
 422                              (downcase id))
 423                 (with-current-buffer mother
 424                   (mime-store-message/partial-piece message situation))
 425                 (if (file-exists-p full-file)
 426                     (throw 'tag nil)))))
 427           (setq overviews (cdr overviews)))
 428         (message "Not all partials found.")))))
 429
 430 (defun wl-mime-display-text/plain (entity situation)
 431   (let ((beg (point)))
 432     (mime-display-text/plain entity situation)
 433     (wl-highlight-message beg (point-max) t t)))
 434
 435 (defun wl-mime-display-header (entity situation)
 436   (let ((elmo-message-ignored-field-list
 437          (if wl-message-buffer-all-header-flag
 438              nil
 439            wl-message-ignored-field-list))
 440         (elmo-message-visible-field-list wl-message-visible-field-list)
 441         (elmo-message-sorted-field-list wl-message-sort-field-list))
 442     (elmo-mime-insert-header entity situation)
 443     (wl-highlight-headers)))
 444
 445 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 446   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 447         (original-buffer wl-message-buffer-original-buffer))
 448     (mime-decrypt-application/pgp-encrypted entity situation)
 449     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 450     (setq wl-message-buffer-original-buffer original-buffer)))
 451
 452
 453 ;;; Setup methods.
 454 (defun wl-mime-setup ()
 455   (set-alist 'mime-preview-quitting-method-alist
 456              'wl-original-message-mode 'wl-message-exit)
 457   (set-alist 'mime-view-over-to-previous-method-alist
 458              'wl-original-message-mode 'wl-message-exit)
 459   (set-alist 'mime-view-over-to-next-method-alist
 460              'wl-original-message-mode 'wl-message-exit)
 461   (set-alist 'mime-preview-over-to-previous-method-alist
 462              'wl-original-message-mode 'wl-message-exit)
 463   (set-alist 'mime-preview-over-to-next-method-alist
 464              'wl-original-message-mode 'wl-message-exit)
 465   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 466   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 467
 468   (ctree-set-calist-strictly
 469    'mime-preview-condition
 470    '((type . text) (subtype . plain)
 471      (body . visible)
 472      (body-presentation-method . wl-mime-display-text/plain)
 473      (major-mode . wl-original-message-mode)))
 474
 475   (ctree-set-calist-strictly
 476    'mime-acting-condition
 477    '((type . message) (subtype . partial)
 478      (method .  wl-mime-combine-message/partial-pieces)
 479      (request-partial-message-method . wl-message-request-partial)
 480      (major-mode . wl-original-message-mode)))
 481
 482   (ctree-set-calist-strictly
 483    'mime-acting-condition
 484    '((type . application) (subtype . pgp-encrypted)
 485      (method . wl-mime-decrypt-application/pgp-encrypted)
 486      (major-mode . wl-original-message-mode)))
 487
 488   (ctree-set-calist-strictly
 489    'mime-acting-condition
 490    '((mode . "extract")
 491      (major-mode . wl-original-message-mode)
 492      (method . wl-mime-save-content)))
 493   (set-alist 'mime-preview-following-method-alist
 494              'wl-original-message-mode
 495              (function wl-message-follow-current-entity))
 496   (set-alist 'mime-view-following-method-alist
 497              'wl-original-message-mode
 498              (function wl-message-follow-current-entity))
 499   (set-alist 'mime-edit-message-inserter-alist
 500              'wl-draft-mode (function wl-draft-insert-current-message))
 501   (set-alist 'mime-edit-mail-inserter-alist
 502              'wl-draft-mode (function wl-draft-insert-get-message))
 503   (set-alist 'mime-edit-split-message-sender-alist
 504              'wl-draft-mode
 505              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 506   (set-alist 'mime-raw-representation-type-alist
 507              'wl-original-message-mode 'binary)
 508   ;; Sort and highlight header fields.
 509   (or wl-message-ignored-field-list
 510       (setq wl-message-ignored-field-list
 511             mime-view-ignored-field-list))
 512   (or wl-message-visible-field-list
 513       (setq wl-message-visible-field-list
 514             mime-view-visible-field-list))
 515   (set-alist 'mime-header-presentation-method-alist
 516              'wl-original-message-mode
 517              'wl-mime-display-header)
 518   ;; To avoid overriding wl-draft-mode-map.
 519   (when (boundp 'mime-setup-signature-key-alist)
 520     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 521       (setq mime-setup-signature-key-alist
 522             (cons '(wl-draft-mode . "\C-c\C-w")
 523                   mime-setup-signature-key-alist)))))
 524
 525 (require 'product)
 526 (product-provide (provide 'wl-mime) (require 'wl-version))
 527
 528 ;;; wl-mime.el ends here