wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'mime-view)
  33 (require 'mime-edit)
  34 (require 'mime-play)
  35 (require 'elmo)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'pgg-decrypt-region 'ignore)
  39   (defalias-maybe 'pgg-display-output-buffer 'ignore)
  40   (defalias-maybe 'pgg-verify-region 'ignore))
  41
  42 (defvar mime-edit-temp-message-buffer)
  43
  44 ;;; Draft
  45
  46 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  47
  48 (defalias 'wl-draft-decode-message-in-buffer
  49   'mime-edit-decode-message-in-buffer)
  50
  51 (defun wl-draft-yank-current-message-entity ()
  52   "Yank currently displayed message entity.
  53 By setting following-method as yank-content.
  54
  55 If region is active, yank region contents instead. \(this feature is available
  56 if and only if `transient-mark-mode' \(GNU Emacs\) or `zmacs-regions' \(XEmacs\)
  57 has Non-nil value\)"
  58   (let ((wl-draft-buffer (current-buffer))
  59         (mime-view-following-method-alist
  60          (list (cons 'wl-original-message-mode
  61                      (function wl-draft-yank-to-draft-buffer))))
  62         (mime-preview-following-method-alist
  63          (list (cons 'wl-original-message-mode
  64                      (function wl-draft-yank-to-draft-buffer))))
  65         (message-buffer (wl-current-message-buffer)))
  66     (if message-buffer
  67         (save-excursion
  68           (set-buffer message-buffer)
  69           (save-restriction
  70             (widen)
  71             (if (wl-region-exists-p)
  72                 (wl-mime-preview-follow-current-region)
  73               (mime-preview-follow-current-entity))))
  74       (error "No message."))))
  75
  76 ;; modified mime-preview-follow-current-entity from mime-view.el
  77 (defun wl-mime-preview-follow-current-region ()
  78   "Write follow message to current region.
  79 It calls following-method selected from variable
  80 `mime-preview-following-method-alist'."
  81   (interactive)
  82   (let ((r-beg (region-beginning))
  83         (r-end (region-end))
  84         (entity (get-text-property (point-min)
  85                                    'mime-view-entity)))
  86     (let* ((mode (mime-preview-original-major-mode 'recursive))
  87            (new-name
  88             (format "%s-active-region" (buffer-name)))
  89            new-buf
  90            (the-buf (current-buffer))
  91            fields)
  92       (save-excursion
  93         (set-buffer (setq new-buf (get-buffer-create new-name)))
  94         (erase-buffer)
  95         (insert ?\n)
  96         (insert-buffer-substring the-buf r-beg r-end)
  97         (goto-char (point-min))
  98         (let ((current-entity
  99                (if (and (eq (mime-entity-media-type entity) 'message)
 100                         (eq (mime-entity-media-subtype entity) 'rfc822))
 101                    (car (mime-entity-children entity))
 102                  entity)))
 103           (while (and current-entity
 104                       (if (and (eq (mime-entity-media-type
 105                                     current-entity) 'message)
 106                                (eq (mime-entity-media-subtype
 107                                     current-entity) 'rfc822))
 108                           nil
 109                         (mime-insert-header current-entity fields)
 110                         t))
 111             (setq fields (std11-collect-field-names)
 112                   current-entity (mime-entity-parent current-entity))
 113             ))
 114         (let ((rest mime-view-following-required-fields-list)
 115               field-name ret)
 116           (while rest
 117             (setq field-name (car rest))
 118             (or (std11-field-body field-name)
 119                 (progn
 120                   (save-excursion
 121                     (set-buffer the-buf)
 122                     (let ((entity (when mime-mother-buffer
 123                                     (set-buffer mime-mother-buffer)
 124                                     (get-text-property (point)
 125                                                        'mime-view-entity))))
 126                       (while (and entity
 127                                   (null (setq ret (mime-entity-fetch-field
 128                                                    entity field-name))))
 129                         (setq entity (mime-entity-parent entity)))))
 130                   (if ret
 131                       (insert (concat field-name ": " ret "\n"))
 132                     )))
 133             (setq rest (cdr rest))
 134             ))
 135         )
 136       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 137         (if (functionp f)
 138             (funcall f new-buf)
 139           (message
 140            "Sorry, following method for %s is not implemented yet."
 141            mode)
 142           ))
 143       )))
 144
 145 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
 146
 147 (defun wl-draft-attribute-recipients ()
 148   (concat (mapconcat
 149            'identity
 150            (wl-draft-deduce-address-list
 151             (current-buffer)
 152             (point-min)
 153             (save-excursion
 154               (goto-char (point-min))
 155               (re-search-forward
 156                (concat
 157                 "^"
 158                 (regexp-quote mail-header-separator)
 159                 "$")
 160                nil t)
 161               (point)))
 162            ", ")))
 163
 164 (defun wl-draft-attribute-envelope-from ()
 165   (or wl-envelope-from
 166       (wl-address-header-extract-address wl-from)))
 167
 168 (defun wl-draft-attribute-smtp-posting-server ()
 169   (or wl-smtp-posting-server
 170       (progn (require 'smtp) smtp-server)
 171       "localhost"))
 172
 173 (defun wl-draft-attribute-smtp-posting-port ()
 174   (or wl-smtp-posting-port
 175       (progn (require 'smtp) smtp-service)))
 176
 177 (defun wl-draft-attribute-value (attr)
 178   (let ((name (symbol-name attr))
 179         fsymbol symbol)
 180     (cond ((and (setq fsymbol (intern-soft
 181                                (format "wl-draft-attribute-%s" name)))
 182                 (fboundp fsymbol))
 183            (funcall fsymbol))
 184           ((and (setq symbol (intern-soft (format "wl-%s" name)))
 185                 (boundp symbol))
 186            (symbol-value symbol))
 187           ((boundp attr)
 188            (symbol-value attr)))))
 189
 190 (defun wl-mime-quit-preview ()
 191   "Quitting method for mime-view."
 192   (let* ((temp mime-edit-temp-message-buffer)
 193          (window (selected-window))
 194          buf)
 195     (mime-preview-kill-buffer)
 196     (set-buffer temp)
 197     (setq buf mime-edit-buffer)
 198     (kill-buffer temp)
 199     (select-window window)
 200     (switch-to-buffer buf)))
 201
 202 (defun wl-draft-preview-message ()
 203   "Preview editing message."
 204   (interactive)
 205   (let* (attribute-list
 206          (orig-buffer (current-buffer))
 207          (current-point (point))
 208          (config-exec-flag wl-draft-config-exec-flag)
 209          (parent-folder wl-draft-parent-folder)
 210          (mime-display-header-hook 'wl-highlight-headers)
 211          (mime-header-encode-method-alist
 212           (append
 213            '((wl-draft-eword-encode-address-list
 214               .  (To Cc Bcc Resent-To Resent-Cc Resent-Bcc From)))
 215            (if (boundp 'mime-header-encode-method-alist)
 216                (symbol-value 'mime-header-encode-method-alist))))
 217          mime-view-ignored-field-list   ; all header.
 218          (mime-edit-translate-buffer-hook
 219           (append
 220            (list
 221             (lambda ()
 222               (let ((wl-draft-config-exec-flag config-exec-flag)
 223                     (wl-draft-parent-folder parent-folder)
 224                     (copy-buffer (current-buffer)))
 225                 (with-current-buffer orig-buffer
 226                   (wl-copy-local-variables
 227                    orig-buffer
 228                    copy-buffer
 229                    (append wl-draft-config-variables
 230                            (wl-draft-clone-local-variables))))
 231                 (goto-char current-point)
 232                 (run-hooks 'wl-draft-send-hook)
 233                 (condition-case err
 234                     (setq attribute-list
 235                           (mapcar
 236                            (lambda (attr)
 237                              (cons attr (wl-draft-attribute-value attr)))
 238                            wl-draft-preview-attributes-list))
 239                   (error
 240                    (kill-buffer (current-buffer))
 241                    (signal (car err) (cdr err)))))))
 242            mime-edit-translate-buffer-hook)))
 243     (mime-edit-preview-message)
 244     (make-local-variable 'mime-preview-quitting-method-alist)
 245     (setq mime-preview-quitting-method-alist
 246           '((mime-temp-message-mode . wl-mime-quit-preview)))
 247     (let ((buffer-read-only nil))
 248       (when wl-highlight-body-too
 249         (wl-highlight-body))
 250       (run-hooks 'wl-draft-preview-message-hook))
 251     (make-local-variable 'kill-buffer-hook)
 252     (add-hook 'kill-buffer-hook
 253               (lambda ()
 254                 (when (get-buffer-window
 255                        wl-draft-preview-attributes-buffer-name)
 256                   (select-window (get-buffer-window
 257                                   wl-draft-preview-attributes-buffer-name))
 258                   (delete-window))
 259                 (when (get-buffer wl-draft-preview-attributes-buffer-name)
 260                   (kill-buffer (get-buffer
 261                                 wl-draft-preview-attributes-buffer-name)))))
 262     (if (not wl-draft-preview-attributes)
 263         (message (concat "Recipients: "
 264                          (cdr (assq 'recipients attribute-list))))
 265       (ignore-errors ; in case when the window is too small
 266         (let* ((cur-win (selected-window))
 267                (size (min
 268                       (- (window-height cur-win)
 269                          window-min-height 1)
 270                       (- (window-height cur-win)
 271                          (max
 272                           window-min-height
 273                           (1+ wl-draft-preview-attributes-buffer-lines))))))
 274           (split-window cur-win (if (> size 0) size window-min-height))
 275           (select-window (next-window))
 276           (let ((pop-up-windows nil))
 277             (switch-to-buffer (get-buffer-create
 278                                wl-draft-preview-attributes-buffer-name)))
 279           (with-current-buffer
 280               (get-buffer wl-draft-preview-attributes-buffer-name)
 281             (setq buffer-read-only t)
 282             (let (buffer-read-only)
 283               (erase-buffer)
 284               (dolist (pair attribute-list)
 285                 (insert (capitalize (symbol-name (car pair))) ": "
 286                         (format "%s" (or (cdr pair) ""))
 287                         "\n"))
 288               (goto-char (point-min))
 289               (wl-highlight-headers)))
 290           (select-window cur-win))))))
 291
 292 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 293
 294 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 295
 296 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 297
 298 ;;; Message
 299
 300 (defun wl-message-decode-mode (outbuf inbuf)
 301   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 302         (mime-display-header-hook 'wl-highlight-headers))
 303     (mime-view-mode nil nil nil inbuf outbuf)))
 304
 305 (defun wl-message-decode-with-all-header (outbuf inbuf)
 306   (let ((mime-view-ignored-field-regexp "^:$")
 307         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 308         (mime-display-header-hook 'wl-highlight-headers)
 309         mime-view-ignored-field-list)
 310     (mime-view-mode nil nil nil inbuf outbuf)))
 311
 312 (defun wl-message-delete-mime-out-buf ()
 313   (let (mime-out-buf mime-out-win)
 314     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 315         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 316             (delete-window mime-out-win)))))
 317
 318 (defun wl-message-request-partial (folder number)
 319   (elmo-set-work-buf
 320    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 321                        number
 322                        (elmo-make-fetch-strategy 'entire)
 323                        nil
 324                        (current-buffer)
 325                        'unread)
 326    (mime-parse-buffer nil)))
 327
 328 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 329 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 330 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 331 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 332 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 333 (defalias 'wl-message-quit              'mime-preview-quit)
 334 (defalias 'wl-message-button-dispatcher-internal
 335   'mime-button-dispatcher)
 336
 337 (defsubst wl-mime-node-id-to-string (node-id)
 338   (if (consp node-id)
 339       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 340                  (reverse node-id)
 341                  ".")
 342     "0"))
 343
 344 (defun wl-message-delete-current-part ()
 345   "Delete a part under the cursor from the multipart message."
 346   (interactive)
 347   (save-restriction
 348     (widen)
 349     (let* ((entity (get-text-property (point) 'mime-view-entity))
 350            (node-id (mime-entity-node-id entity))
 351            (filename (mime-entity-safe-filename entity))
 352            (header-start (mime-buffer-entity-header-start-internal entity))
 353            (body-end (mime-buffer-entity-body-end-internal entity))
 354            (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 355            (number wl-message-buffer-cur-number)
 356            (msgid (elmo-message-field folder number 'message-id))
 357            (orig-buf wl-message-buffer-original-buffer))
 358       (if (eq (luna-class-name entity) 'mime-elmo-imap-entity)
 359           (error "Please fetch the entire message (by typing 'C-u .') and try again"))
 360       (with-current-buffer orig-buf
 361         (unless (string-equal
 362                  (buffer-string)
 363                  (elmo-message-fetch folder number
 364                                      (elmo-make-fetch-strategy 'entire)))
 365           (error "Buffer content differs from actual message")))
 366       (when (and (elmo-folder-writable-p folder)
 367                  (buffer-live-p orig-buf)
 368                  node-id
 369                  (yes-or-no-p
 370                   (format "Do you really want to delete part %s? "
 371                           (wl-mime-node-id-to-string node-id))))
 372         (when (with-temp-buffer
 373                 (insert-buffer orig-buf)
 374                 (delete-region header-start body-end)
 375                 (goto-char header-start)
 376                 (insert "Content-Type: text/plain; charset=US-ASCII\n")
 377                 (when filename
 378                   (insert
 379                    "Content-Disposition:"
 380                    (mime-encode-field-body
 381                          (concat ""
 382                                  (and filename
 383                                       (concat " inline; filename=" (std11-wrap-as-quoted-string filename))))
 384                          "Content-Disposition")
 385                    "\n"))
 386                 (insert "\n")
 387                 (insert "** This part has been removed by Wanderlust **\n\n")
 388                 (elmo-folder-append-buffer folder))
 389
 390           (elmo-folder-move-messages
 391            folder (list number)
 392            (wl-folder-get-elmo-folder wl-trash-folder))
 393           (when (and (elmo-cache-get-path msgid)
 394                      (file-exists-p (elmo-cache-get-path msgid)))
 395             (delete-file (elmo-cache-get-path msgid)))
 396
 397           (mime-preview-quit)
 398           (wl-summary-delete-messages-on-buffer (list number))
 399           (wl-summary-toggle-disp-msg 'off)
 400           (setq wl-message-buffer nil)
 401           (wl-summary-sync nil "update"))))))
 402
 403 (defun wl-message-decrypt-pgp-nonmime ()
 404   "Decrypt PGP encrypted region"
 405   (interactive)
 406   (require 'pgg)
 407   (save-excursion
 408     (beginning-of-line)
 409     (if (or (re-search-forward "^-+END PGP MESSAGE-+$" nil t)
 410             (re-search-backward "^-+END PGP MESSAGE-+$" nil t))
 411         (let (beg end status)
 412           (setq end (match-end 0))
 413           (if (setq beg (re-search-backward "^-+BEGIN PGP MESSAGE-+$" nil t))
 414               (let ((inhibit-read-only t)
 415                     (buffer-file-coding-system wl-cs-autoconv))
 416                 (setq status (pgg-decrypt-region beg end))
 417                 (pgg-display-output-buffer beg end status))
 418             (message "Cannot find pgp encrypted region")))
 419       (message "Cannot find pgp encrypted region"))))
 420
 421 (defun wl-message-verify-pgp-nonmime ()
 422   "Verify PGP signed region"
 423   (interactive)
 424   (require 'pgg)
 425   (save-excursion
 426     (beginning-of-line)
 427     (if (and (or (re-search-forward "^-+END PGP SIGNATURE-+$" nil t)
 428                  (re-search-backward "^-+END PGP SIGNATURE-+$" nil t))
 429              (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t))
 430         (let (status)
 431           (let* ((beg (point))
 432                  (situation (mime-preview-find-boundary-info))
 433                  (p-end (aref situation 1))
 434                  (entity (aref situation 2))
 435                  (count 0))
 436             (goto-char p-end)
 437             (while (< beg (point))
 438               (if (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t)
 439                   (setq count (+ count 1))
 440                 (debug)))
 441             (with-temp-buffer
 442               (set-buffer-multibyte nil)
 443               (insert (mime-entity-body entity))
 444               (goto-char (point-max))
 445               (while (> count 0)
 446                 (if (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t)
 447                     (setq count (- count 1))
 448                   (debug)))
 449               (let ((r-beg (point))
 450                     (r-end (re-search-forward "^-+END PGP SIGNATURE-+$" nil t)))
 451                 (if r-end
 452                     (setq status (pgg-verify-region r-beg r-end nil 'fetch))
 453                   (debug)))))
 454           (mime-show-echo-buffer)
 455           (set-buffer mime-echo-buffer-name)
 456           (set-window-start
 457            (get-buffer-window mime-echo-buffer-name)
 458            (point-max))
 459           (insert-buffer-substring
 460            (if status pgg-output-buffer pgg-errors-buffer)))
 461       (message "Cannot find pgp signed region"))))
 462
 463 ;; XXX: encrypted multipart isn't represented as multipart
 464 (defun wl-mime-preview-application/pgp (parent-entity entity situation)
 465   (require 'pgg)
 466   (goto-char (point-max))
 467   (let ((p (point))
 468         raw-buf to-buf representation-type child-entity)
 469     (goto-char p)
 470     (save-restriction
 471       (narrow-to-region p p)
 472       (setq to-buf (current-buffer))
 473       (with-temp-buffer
 474         (setq raw-buf (current-buffer))
 475         (mime-insert-entity entity)
 476         (when (progn
 477                 (goto-char (point-min))
 478                 (re-search-forward "^-+BEGIN PGP MESSAGE-+$" nil t))
 479           (pgg-decrypt-region (point-min)(point-max))
 480           (delete-region (point-min) (point-max))
 481           (insert-buffer pgg-output-buffer)
 482           (setq representation-type 'elmo-buffer))
 483         (setq child-entity (mime-parse-message
 484                             (mm-expand-class-name representation-type)
 485                             nil
 486                             parent-entity
 487                             (mime-entity-node-id-internal parent-entity)))
 488         (mime-display-entity
 489          child-entity
 490          nil
 491          `((header . visible)
 492            (body . visible)
 493            (entity-button . invisible))
 494          to-buf)))))
 495
 496 (defun wl-mime-preview-application/pgp-encrypted (entity situation)
 497   (let* ((entity-node-id (mime-entity-node-id entity))
 498          (mother (mime-entity-parent entity))
 499          (knum (car entity-node-id))
 500          (onum (if (> knum 0)
 501                    (1- knum)
 502                  (1+ knum)))
 503          (orig-entity (nth onum (mime-entity-children mother))))
 504     (wl-mime-preview-application/pgp entity orig-entity situation)))
 505
 506 ;;; Summary
 507 (defun wl-summary-burst-subr (message-entity target number)
 508   ;; returns new number.
 509   (let (content-type entity)
 510     (setq content-type (mime-entity-content-type message-entity))
 511     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 512            (dolist (entity (mime-entity-children message-entity))
 513              (setq number (wl-summary-burst-subr
 514                            entity
 515                            target
 516                            number))))
 517           ((and (eq (cdr (assq 'type content-type)) 'message)
 518                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 519            (message "Bursting...%s" (setq number (+ 1 number)))
 520            (setq entity
 521                  (car (mime-entity-children message-entity)))
 522            (with-temp-buffer
 523              (insert (mime-entity-body message-entity))
 524              (elmo-folder-append-buffer target))))
 525     number))
 526
 527 (defun wl-summary-burst (&optional arg)
 528   "De-capsulate embedded messages in MIME format.
 529 With ARG, ask destination folder."
 530   (interactive "P")
 531   (let ((raw-buf (wl-summary-get-original-buffer))
 532         (view-buf wl-message-buffer)
 533         message-entity target)
 534     (save-excursion
 535       (when (and (null arg)
 536                  (elmo-folder-writable-p wl-summary-buffer-elmo-folder))
 537         (setq target wl-summary-buffer-elmo-folder))
 538       (while (null target)
 539         (let ((name (wl-summary-read-folder wl-default-folder
 540                                             "to extract to")))
 541           (setq target (wl-folder-get-elmo-folder name))
 542           (unless (elmo-folder-writable-p target)
 543             (message "%s is not writable" name)
 544             (setq target nil)
 545             (sit-for 1))))
 546       (wl-summary-set-message-buffer-or-redisplay)
 547       (with-current-buffer view-buf
 548         (setq message-entity
 549               (get-text-property (point-min) 'mime-view-entity)))
 550       (when message-entity
 551         (message "Bursting...")
 552         (with-current-buffer raw-buf
 553           (wl-summary-burst-subr message-entity target 0))
 554         (message "Bursting...done"))
 555       (if (elmo-folder-plugged-p target)
 556           (elmo-folder-check target)))
 557     (when (and target
 558                (string= wl-summary-buffer-folder-name
 559                         (elmo-folder-name-internal target)))
 560       (save-excursion (wl-summary-sync-update)))))
 561
 562 ;; internal variable.
 563 (defvar wl-mime-save-directory nil "Last saved directory.")
 564 ;;; Yet another save method.
 565 (defun wl-mime-save-content (entity situation)
 566   (let ((filename (expand-file-name
 567                    (read-file-name "Save to file: "
 568                                    (expand-file-name
 569                                     (or (mime-entity-safe-filename entity)
 570                                         ".")
 571                                     (or wl-mime-save-directory
 572                                         wl-temporary-file-directory))))))
 573     (while (file-directory-p filename)
 574       (setq filename (read-file-name "Please set filename (not directory): "
 575                                      filename)))
 576     (if (and (file-exists-p filename)
 577              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 578                                        filename))))
 579         (message "Not saved")
 580       (setq wl-mime-save-directory (file-name-directory filename))
 581       (mime-write-entity-content entity filename))))
 582
 583 ;;; Yet another combine method.
 584 (defun wl-mime-combine-message/partial-pieces (entity situation)
 585   "Internal method for wl to combine message/partial messages automatically."
 586   (interactive)
 587   (let* ((folder (with-current-buffer wl-message-buffer-cur-summary-buffer
 588                    wl-summary-buffer-elmo-folder))
 589          (mime-display-header-hook 'wl-highlight-headers)
 590          (id (or (cdr (assoc "id" situation)) ""))
 591          (mother (current-buffer))
 592          (summary-buf wl-message-buffer-cur-summary-buffer)
 593          subject-id overviews
 594          (root-dir (expand-file-name
 595                     (concat "m-prts-" (user-login-name))
 596                     temporary-file-directory))
 597          full-file point)
 598     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 599     (setq full-file (concat root-dir "/FULL"))
 600     (if (or (file-exists-p full-file)
 601             (not (y-or-n-p "Merge partials? ")))
 602         (with-current-buffer mother
 603           (mime-store-message/partial-piece entity situation)
 604           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 605           (make-variable-buffer-local 'mime-preview-over-to-next-method-alist)
 606           (setq mime-preview-over-to-next-method-alist
 607                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 608                       mime-preview-over-to-next-method-alist))
 609           (make-variable-buffer-local 'mime-preview-over-to-previous-method-alist)
 610           (setq mime-preview-over-to-previous-method-alist
 611                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 612                       mime-preview-over-to-previous-method-alist)))
 613       (setq subject-id
 614             (eword-decode-string
 615              (decode-mime-charset-string
 616               (mime-entity-read-field entity 'Subject)
 617               wl-summary-buffer-mime-charset)))
 618       (if (string-match "[0-9\n]+" subject-id)
 619           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 620       (catch 'tag
 621         (elmo-folder-do-each-message-entity (entity folder)
 622           (when (string-match
 623                  (regexp-quote subject-id)
 624                  (elmo-message-entity-field entity 'subject 'decode))
 625             (let* ((message
 626                     ;; request message at the cursor in Subject buffer.
 627                     (wl-message-request-partial
 628                      (elmo-folder-name-internal folder)
 629                      (elmo-message-entity-number entity)))
 630                    (situation (mime-entity-situation message))
 631                    (the-id (or (cdr (assoc "id" situation)) "")))
 632               (when (string= (downcase the-id)
 633                              (downcase id))
 634                 (with-current-buffer mother
 635                   (mime-store-message/partial-piece message situation))
 636                 (if (file-exists-p full-file)
 637                     (throw 'tag nil))))))
 638         (message "Not all partials found.")))))
 639
 640 (defun wl-mime-display-text/plain (entity situation)
 641   (let ((beg (point)))
 642     (mime-display-text/plain entity situation)
 643     (wl-highlight-message beg (point-max) t t)))
 644
 645 (defun wl-mime-display-header (entity situation)
 646   (let ((elmo-message-ignored-field-list
 647          (if wl-message-buffer-require-all-header
 648              nil
 649            wl-message-ignored-field-list))
 650         (elmo-message-visible-field-list wl-message-visible-field-list)
 651         (elmo-message-sorted-field-list wl-message-sort-field-list))
 652     (elmo-mime-insert-header entity situation)
 653     (wl-highlight-headers)))
 654
 655 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 656   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 657         (original-buffer wl-message-buffer-original-buffer))
 658     (mime-decrypt-application/pgp-encrypted entity situation)
 659     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 660     (setq wl-message-buffer-original-buffer original-buffer)))
 661
 662
 663 ;;; Setup methods.
 664 (defun wl-mime-setup ()
 665   (set-alist 'mime-preview-quitting-method-alist
 666              'wl-original-message-mode 'wl-message-exit)
 667   (set-alist 'mime-view-over-to-previous-method-alist
 668              'wl-original-message-mode 'wl-message-exit)
 669   (set-alist 'mime-view-over-to-next-method-alist
 670              'wl-original-message-mode 'wl-message-exit)
 671   (set-alist 'mime-preview-over-to-previous-method-alist
 672              'wl-original-message-mode 'wl-message-exit)
 673   (set-alist 'mime-preview-over-to-next-method-alist
 674              'wl-original-message-mode 'wl-message-exit)
 675   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 676   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 677
 678   (ctree-set-calist-strictly
 679    'mime-preview-condition
 680    '((type . text) (subtype . plain)
 681      (body . visible)
 682      (body-presentation-method . wl-mime-display-text/plain)
 683      (major-mode . wl-original-message-mode)))
 684
 685   (ctree-set-calist-strictly
 686    'mime-preview-condition
 687    '((type . application)(subtype . pgp-encrypted)
 688      (encoding . t)
 689      (body . invisible)
 690      (body-presentation-method . wl-mime-preview-application/pgp-encrypted)
 691      (major-mode . wl-original-message-mode)))
 692
 693   (ctree-set-calist-strictly
 694    'mime-acting-condition
 695    '((type . message) (subtype . partial)
 696      (method .  wl-mime-combine-message/partial-pieces)
 697      (request-partial-message-method . wl-message-request-partial)
 698      (major-mode . wl-original-message-mode)))
 699
 700   (ctree-set-calist-strictly
 701    'mime-acting-condition
 702    '((type . application) (subtype . pgp-encrypted)
 703      (method . wl-mime-decrypt-application/pgp-encrypted)
 704      (major-mode . wl-original-message-mode)))
 705
 706   (ctree-set-calist-strictly
 707    'mime-acting-condition
 708    '((mode . "extract")
 709      (major-mode . wl-original-message-mode)
 710      (method . wl-mime-save-content)))
 711   (set-alist 'mime-preview-following-method-alist
 712              'wl-original-message-mode
 713              (function wl-message-follow-current-entity))
 714   (set-alist 'mime-view-following-method-alist
 715              'wl-original-message-mode
 716              (function wl-message-follow-current-entity))
 717   (set-alist 'mime-edit-message-inserter-alist
 718              'wl-draft-mode (function wl-draft-insert-current-message))
 719   (set-alist 'mime-edit-mail-inserter-alist
 720              'wl-draft-mode (function wl-draft-insert-get-message))
 721   (set-alist 'mime-edit-split-message-sender-alist
 722              'wl-draft-mode
 723              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 724   (set-alist 'mime-raw-representation-type-alist
 725              'wl-original-message-mode 'binary)
 726   ;; Sort and highlight header fields.
 727   (or wl-message-ignored-field-list
 728       (setq wl-message-ignored-field-list
 729             mime-view-ignored-field-list))
 730   (or wl-message-visible-field-list
 731       (setq wl-message-visible-field-list
 732             mime-view-visible-field-list))
 733   (set-alist 'mime-header-presentation-method-alist
 734              'wl-original-message-mode
 735              'wl-mime-display-header)
 736   ;; To avoid overriding wl-draft-mode-map.
 737   (when (boundp 'mime-setup-signature-key-alist)
 738     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 739       (setq mime-setup-signature-key-alist
 740             (cons '(wl-draft-mode . "\C-c\C-w")
 741                   mime-setup-signature-key-alist)))))
 742
 743 (require 'product)
 744 (product-provide (provide 'wl-mime) (require 'wl-version))
 745
 746 ;;; wl-mime.el ends here