wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'mime-view)
  33 (require 'mime-edit)
  34 (require 'mime-play)
  35 (require 'elmo)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'pgg-decrypt-region 'ignore)
  39   (defalias-maybe 'pgg-display-output-buffer 'ignore)
  40   (defalias-maybe 'pgg-verify-region 'ignore))
  41
  42 ;;; Draft
  43
  44 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  45
  46 (defalias 'wl-draft-decode-message-in-buffer
  47   'mime-edit-decode-message-in-buffer)
  48
  49 (defun wl-draft-yank-current-message-entity ()
  50   "Yank currently displayed message entity.
  51 By setting following-method as yank-content.
  52
  53 If region is active, yank region contents instead. \(this feature is available
  54 if and only if `transient-mark-mode' \(GNU Emacs\) or `zmacs-regions' \(XEmacs\)
  55 has Non-nil value\)"
  56   (let ((wl-draft-buffer (current-buffer))
  57         (mime-view-following-method-alist
  58          (list (cons 'wl-original-message-mode
  59                      (function wl-draft-yank-to-draft-buffer))))
  60         (mime-preview-following-method-alist
  61          (list (cons 'wl-original-message-mode
  62                      (function wl-draft-yank-to-draft-buffer))))
  63         (message-buffer (wl-current-message-buffer)))
  64     (if message-buffer
  65         (save-excursion
  66           (set-buffer message-buffer)
  67           (save-restriction
  68             (widen)
  69             (cond
  70              ((wl-region-exists-p)
  71               (wl-mime-preview-follow-current-region))
  72              ((get-text-property (point-min) 'mime-view-entity)
  73               (mime-preview-follow-current-entity))
  74              (t
  75               (wl-mime-preview-follow-no-mime)))))
  76       (error "No message."))))
  77
  78 ;; modified mime-preview-follow-current-entity from mime-view.el
  79 (defun wl-mime-preview-follow-no-mime ()
  80   "Write follow message to current message, without mime.
  81 It calls following-method selected from variable
  82 `mime-preview-following-method-alist'."
  83   (interactive)
  84   (let* ((mode (mime-preview-original-major-mode 'recursive))
  85          (new-name (format "%s-no-mime" (buffer-name)))
  86          new-buf beg end
  87          (entity (get-text-property (point-min) 'elmo-as-is-entity))
  88          (the-buf (current-buffer))
  89          fields)
  90     (save-excursion
  91       (goto-char (point-min))
  92       (setq beg (re-search-forward "^$" nil t)
  93             end (point-max)))
  94     (save-excursion
  95       (set-buffer (setq new-buf (get-buffer-create new-name)))
  96       (erase-buffer)
  97       (insert-buffer-substring the-buf beg end)
  98       (goto-char (point-min))
  99       ;; Insert all headers.
 100       (mime-insert-header entity)
 101       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 102         (if (functionp f)
 103             (funcall f new-buf)
 104           (message
 105            "Sorry, following method for %s is not implemented yet."
 106            mode))))))
 107
 108 ;; modified mime-preview-follow-current-entity from mime-view.el
 109 (defun wl-mime-preview-follow-current-region ()
 110   "Write follow message to current region.
 111 It calls following-method selected from variable
 112 `mime-preview-following-method-alist'."
 113   (interactive)
 114   (let ((r-beg (region-beginning))
 115         (r-end (region-end))
 116         (entity (get-text-property (point-min)
 117                                    'mime-view-entity)))
 118     (let* ((mode (mime-preview-original-major-mode 'recursive))
 119            (new-name
 120             (format "%s-active-region" (buffer-name)))
 121            new-buf
 122            (the-buf (current-buffer))
 123            fields)
 124       (save-excursion
 125         (set-buffer (setq new-buf (get-buffer-create new-name)))
 126         (erase-buffer)
 127         (insert ?\n)
 128         (insert-buffer-substring the-buf r-beg r-end)
 129         (goto-char (point-min))
 130         (let ((current-entity
 131                (if (and entity
 132                         (eq (mime-entity-media-type entity) 'message)
 133                         (eq (mime-entity-media-subtype entity) 'rfc822))
 134                    (car (mime-entity-children entity))
 135                  entity)))
 136           (while (and current-entity
 137                       (if (and (eq (mime-entity-media-type
 138                                     current-entity) 'message)
 139                                (eq (mime-entity-media-subtype
 140                                     current-entity) 'rfc822))
 141                           nil
 142                         (mime-insert-header current-entity fields)
 143                         t))
 144             (setq fields (std11-collect-field-names)
 145                   current-entity (mime-entity-parent current-entity))))
 146         (let ((rest mime-view-following-required-fields-list)
 147               field-name ret)
 148           (while rest
 149             (setq field-name (car rest))
 150             (or (std11-field-body field-name)
 151                 (progn
 152                   (save-excursion
 153                     (set-buffer the-buf)
 154                     (let ((entity (when mime-mother-buffer
 155                                     (set-buffer mime-mother-buffer)
 156                                     (get-text-property (point)
 157                                                        'mime-view-entity))))
 158                       (while (and entity
 159                                   (null (setq ret (mime-entity-fetch-field
 160                                                    entity field-name))))
 161                         (setq entity (mime-entity-parent entity)))))
 162                   (if ret
 163                       (insert (concat field-name ": " ret "\n")))))
 164             (setq rest (cdr rest)))))
 165       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 166         (if (functionp f)
 167             (funcall f new-buf)
 168           (message
 169            "Sorry, following method for %s is not implemented yet."
 170            mode))))))
 171
 172 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
 173
 174 (defun wl-draft-attribute-recipients ()
 175   (concat (mapconcat
 176            'identity
 177            (wl-draft-deduce-address-list
 178             (current-buffer)
 179             (point-min)
 180             (save-excursion
 181               (goto-char (point-min))
 182               (re-search-forward
 183                (concat
 184                 "^"
 185                 (regexp-quote mail-header-separator)
 186                 "$")
 187                nil t)
 188               (point)))
 189            ", ")))
 190
 191 (defun wl-draft-attribute-envelope-from ()
 192   (or wl-envelope-from
 193       (wl-address-header-extract-address wl-from)))
 194
 195 (defun wl-draft-attribute-smtp-posting-server ()
 196   (or wl-smtp-posting-server
 197       (progn (require 'smtp) smtp-server)
 198       "localhost"))
 199
 200 (defun wl-draft-attribute-smtp-posting-port ()
 201   (or wl-smtp-posting-port
 202       (progn (require 'smtp) smtp-service)))
 203
 204 (defun wl-draft-attribute-value (attr)
 205   (let ((name (symbol-name attr))
 206         fsymbol symbol)
 207     (cond ((and (setq fsymbol (intern-soft
 208                                (format "wl-draft-attribute-%s" name)))
 209                 (fboundp fsymbol))
 210            (funcall fsymbol))
 211           ((and (setq symbol (intern-soft (format "wl-%s" name)))
 212                 (boundp symbol))
 213            (symbol-value symbol))
 214           ((boundp attr)
 215            (symbol-value attr)))))
 216
 217 (defun wl-mime-quit-preview ()
 218   "Quitting method for mime-view."
 219   (let* ((temp (and (boundp 'mime-edit-temp-message-buffer) ;; for SEMI <= 1.14.6
 220                     mime-edit-temp-message-buffer))
 221          (window (selected-window))
 222          buf)
 223     (mime-preview-kill-buffer)
 224     (set-buffer temp)
 225     (setq buf mime-edit-buffer)
 226     (kill-buffer temp)
 227     (select-window window)
 228     (switch-to-buffer buf)))
 229
 230 (defun wl-draft-preview-message ()
 231   "Preview editing message."
 232   (interactive)
 233   (let* (attribute-list
 234          (orig-buffer (current-buffer))
 235          (current-point (point))
 236          (config-exec-flag wl-draft-config-exec-flag)
 237          (parent-folder wl-draft-parent-folder)
 238          (mime-display-header-hook 'wl-highlight-headers)
 239          (mime-header-encode-method-alist
 240           (append
 241            '((wl-draft-eword-encode-address-list
 242               .  (To Cc Bcc Resent-To Resent-Cc Resent-Bcc From)))
 243            (if (boundp 'mime-header-encode-method-alist)
 244                (symbol-value 'mime-header-encode-method-alist))))
 245          mime-view-ignored-field-list   ; all header.
 246          (mime-edit-translate-buffer-hook
 247           (append
 248            (list
 249             (lambda ()
 250               (let ((wl-draft-config-exec-flag config-exec-flag)
 251                     (wl-draft-parent-folder parent-folder)
 252                     (copy-buffer (current-buffer)))
 253                 (with-current-buffer orig-buffer
 254                   (wl-copy-local-variables
 255                    orig-buffer
 256                    copy-buffer
 257                    (append wl-draft-config-variables
 258                            (wl-draft-clone-local-variables))))
 259                 (goto-char current-point)
 260                 (run-hooks 'wl-draft-send-hook)
 261                 (condition-case err
 262                     (setq attribute-list
 263                           (mapcar
 264                            (lambda (attr)
 265                              (cons attr (wl-draft-attribute-value attr)))
 266                            wl-draft-preview-attributes-list))
 267                   (error
 268                    (kill-buffer (current-buffer))
 269                    (signal (car err) (cdr err)))))))
 270            mime-edit-translate-buffer-hook)))
 271     (mime-edit-preview-message)
 272     (make-local-variable 'mime-preview-quitting-method-alist)
 273     (setq mime-preview-quitting-method-alist
 274           '((mime-temp-message-mode . wl-mime-quit-preview)))
 275     (let ((buffer-read-only nil))
 276       (when wl-highlight-body-too
 277         (wl-highlight-body))
 278       (run-hooks 'wl-draft-preview-message-hook))
 279     (make-local-variable 'kill-buffer-hook)
 280     (add-hook 'kill-buffer-hook
 281               (lambda ()
 282                 (when (get-buffer-window
 283                        wl-draft-preview-attributes-buffer-name)
 284                   (select-window (get-buffer-window
 285                                   wl-draft-preview-attributes-buffer-name))
 286                   (delete-window))
 287                 (when (get-buffer wl-draft-preview-attributes-buffer-name)
 288                   (kill-buffer (get-buffer
 289                                 wl-draft-preview-attributes-buffer-name)))))
 290     (if (not wl-draft-preview-attributes)
 291         (message (concat "Recipients: "
 292                          (cdr (assq 'recipients attribute-list))))
 293       (ignore-errors ; in case when the window is too small
 294         (let* ((cur-win (selected-window))
 295                (size (min
 296                       (- (window-height cur-win)
 297                          window-min-height 1)
 298                       (- (window-height cur-win)
 299                          (max
 300                           window-min-height
 301                           (1+ wl-draft-preview-attributes-buffer-lines))))))
 302           (split-window cur-win (if (> size 0) size window-min-height))
 303           (select-window (next-window))
 304           (let ((pop-up-windows nil))
 305             (switch-to-buffer (get-buffer-create
 306                                wl-draft-preview-attributes-buffer-name)))
 307           (with-current-buffer
 308               (get-buffer wl-draft-preview-attributes-buffer-name)
 309             (setq buffer-read-only t)
 310             (let (buffer-read-only)
 311               (erase-buffer)
 312               (dolist (pair attribute-list)
 313                 (insert (capitalize (symbol-name (car pair))) ": "
 314                         (format "%s" (or (cdr pair) ""))
 315                         "\n"))
 316               (goto-char (point-min))
 317               (wl-highlight-headers)))
 318           (select-window cur-win))))))
 319
 320 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 321
 322 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 323
 324 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 325
 326 ;;; Message
 327
 328 (defun wl-message-decode-mode (outbuf inbuf)
 329   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 330         (mime-display-header-hook 'wl-highlight-headers))
 331     (mime-view-mode nil nil nil inbuf outbuf)))
 332
 333 (defun wl-message-decode-with-all-header (outbuf inbuf)
 334   (let ((mime-view-ignored-field-regexp "^:$")
 335         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 336         (mime-display-header-hook 'wl-highlight-headers)
 337         mime-view-ignored-field-list)
 338     (mime-view-mode nil nil nil inbuf outbuf)))
 339
 340 (defun wl-message-delete-mime-out-buf ()
 341   (let (mime-out-buf mime-out-win)
 342     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 343         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 344             (delete-window mime-out-win)))))
 345
 346 (defun wl-message-request-partial (folder number)
 347   (elmo-set-work-buf
 348    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 349                        number
 350                        (elmo-make-fetch-strategy 'entire)
 351                        nil
 352                        (current-buffer)
 353                        'unread)
 354    (mime-parse-buffer nil)))
 355
 356 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 357 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 358 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 359 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 360 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 361 (defalias 'wl-message-quit              'mime-preview-quit)
 362 (defalias 'wl-message-button-dispatcher-internal
 363   'mime-button-dispatcher)
 364
 365 (defsubst wl-mime-node-id-to-string (node-id)
 366   (if (consp node-id)
 367       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 368                  (reverse node-id)
 369                  ".")
 370     "0"))
 371
 372 (defun wl-message-delete-current-part ()
 373   "Delete a part under the cursor from the multipart message."
 374   (interactive)
 375   (save-restriction
 376     (widen)
 377     (let* ((entity (get-text-property (point) 'mime-view-entity))
 378            (node-id (mime-entity-node-id entity))
 379            (filename (mime-entity-safe-filename entity))
 380            (header-start (mime-buffer-entity-header-start-internal entity))
 381            (body-end (mime-buffer-entity-body-end-internal entity))
 382            (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 383            (number wl-message-buffer-cur-number)
 384            (msgid (elmo-message-field folder number 'message-id))
 385            (orig-buf wl-message-buffer-original-buffer))
 386       (if (eq (luna-class-name entity) 'mime-elmo-imap-entity)
 387           (error "Please fetch the entire message (by typing 'C-u .') and try again"))
 388       (with-current-buffer orig-buf
 389         (unless (string-equal
 390                  (buffer-string)
 391                  (elmo-message-fetch folder number
 392                                      (elmo-make-fetch-strategy 'entire)))
 393           (error "Buffer content differs from actual message")))
 394       (when (and (elmo-folder-writable-p folder)
 395                  (buffer-live-p orig-buf)
 396                  node-id
 397                  (yes-or-no-p
 398                   (format "Do you really want to delete part %s? "
 399                           (wl-mime-node-id-to-string node-id))))
 400         (when (with-temp-buffer
 401                 (insert-buffer orig-buf)
 402                 (delete-region header-start body-end)
 403                 (goto-char header-start)
 404                 (insert "Content-Type: text/plain; charset=US-ASCII\n")
 405                 (when filename
 406                   (insert
 407                    "Content-Disposition:"
 408                    (mime-encode-field-body
 409                          (concat ""
 410                                  (and filename
 411                                       (concat " inline; filename=" (std11-wrap-as-quoted-string filename))))
 412                          "Content-Disposition")
 413                    "\n"))
 414                 (insert "\n")
 415                 (insert "** This part has been removed by Wanderlust **\n\n")
 416                 (elmo-folder-append-buffer folder))
 417
 418           (elmo-folder-move-messages
 419            folder (list number)
 420            (wl-folder-get-elmo-folder wl-trash-folder))
 421           (when (and (elmo-cache-get-path msgid)
 422                      (file-exists-p (elmo-cache-get-path msgid)))
 423             (delete-file (elmo-cache-get-path msgid)))
 424
 425           (mime-preview-quit)
 426           (wl-summary-delete-messages-on-buffer (list number))
 427           (wl-summary-toggle-disp-msg 'off)
 428           (setq wl-message-buffer nil)
 429           (wl-summary-sync nil "update"))))))
 430
 431 (defun wl-message-decrypt-pgp-nonmime ()
 432   "Decrypt PGP encrypted region"
 433   (interactive)
 434   (require 'pgg)
 435   (save-excursion
 436     (beginning-of-line)
 437     (if (or (re-search-forward "^-+END PGP MESSAGE-+$" nil t)
 438             (re-search-backward "^-+END PGP MESSAGE-+$" nil t))
 439         (let (beg end status)
 440           (setq end (match-end 0))
 441           (if (setq beg (re-search-backward "^-+BEGIN PGP MESSAGE-+$" nil t))
 442               (let ((inhibit-read-only t)
 443                     (buffer-file-coding-system wl-cs-autoconv))
 444                 (setq status (pgg-decrypt-region beg end))
 445                 (pgg-display-output-buffer beg end status))
 446             (message "Cannot find pgp encrypted region")))
 447       (message "Cannot find pgp encrypted region"))))
 448
 449 (defun wl-message-verify-pgp-nonmime ()
 450   "Verify PGP signed region"
 451   (interactive)
 452   (require 'pgg)
 453   (save-excursion
 454     (beginning-of-line)
 455     (if (and (or (re-search-forward "^-+END PGP SIGNATURE-+$" nil t)
 456                  (re-search-backward "^-+END PGP SIGNATURE-+$" nil t))
 457              (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t))
 458         (let (status)
 459           (let* ((beg (point))
 460                  (situation (mime-preview-find-boundary-info))
 461                  (p-end (aref situation 1))
 462                  (entity (aref situation 2))
 463                  (count 0))
 464             (goto-char p-end)
 465             (while (< beg (point))
 466               (if (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t)
 467                   (setq count (+ count 1))
 468                 (debug)))
 469             (with-temp-buffer
 470               (set-buffer-multibyte nil)
 471               (insert (mime-entity-body entity))
 472               (goto-char (point-max))
 473               (while (> count 0)
 474                 (if (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t)
 475                     (setq count (- count 1))
 476                   (debug)))
 477               (let ((r-beg (point))
 478                     (r-end (re-search-forward "^-+END PGP SIGNATURE-+$" nil t)))
 479                 (if r-end
 480                     (setq status (pgg-verify-region r-beg r-end nil 'fetch))
 481                   (debug)))))
 482           (mime-show-echo-buffer)
 483           (set-buffer mime-echo-buffer-name)
 484           (set-window-start
 485            (get-buffer-window mime-echo-buffer-name)
 486            (point-max))
 487           (insert-buffer-substring
 488            (if status pgg-output-buffer pgg-errors-buffer)))
 489       (message "Cannot find pgp signed region"))))
 490
 491 ;; XXX: encrypted multipart isn't represented as multipart
 492 (defun wl-mime-preview-application/pgp (parent-entity entity situation)
 493   (require 'pgg)
 494   (goto-char (point-max))
 495   (let ((p (point))
 496         raw-buf to-buf representation-type child-entity)
 497     (goto-char p)
 498     (save-restriction
 499       (narrow-to-region p p)
 500       (setq to-buf (current-buffer))
 501       (with-temp-buffer
 502         (setq raw-buf (current-buffer))
 503         (mime-insert-entity entity)
 504         (when (progn
 505                 (goto-char (point-min))
 506                 (re-search-forward "^-+BEGIN PGP MESSAGE-+$" nil t))
 507           (pgg-decrypt-region (point-min)(point-max))
 508           (delete-region (point-min) (point-max))
 509           (insert-buffer pgg-output-buffer)
 510           (setq representation-type 'elmo-buffer))
 511         (setq child-entity (mime-parse-message
 512                             (mm-expand-class-name representation-type)
 513                             nil
 514                             parent-entity
 515                             (mime-entity-node-id-internal parent-entity)))
 516         (mime-display-entity
 517          child-entity
 518          nil
 519          `((header . visible)
 520            (body . visible)
 521            (entity-button . invisible))
 522          to-buf)))))
 523
 524 (defun wl-mime-preview-application/pgp-encrypted (entity situation)
 525   (let* ((entity-node-id (mime-entity-node-id entity))
 526          (mother (mime-entity-parent entity))
 527          (knum (car entity-node-id))
 528          (onum (if (> knum 0)
 529                    (1- knum)
 530                  (1+ knum)))
 531          (orig-entity (nth onum (mime-entity-children mother))))
 532     (wl-mime-preview-application/pgp entity orig-entity situation)))
 533
 534 ;;; Summary
 535 (defun wl-summary-burst-subr (message-entity target number)
 536   ;; returns new number.
 537   (let (content-type entity)
 538     (setq content-type (mime-entity-content-type message-entity))
 539     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 540            (dolist (entity (mime-entity-children message-entity))
 541              (setq number (wl-summary-burst-subr
 542                            entity
 543                            target
 544                            number))))
 545           ((and (eq (cdr (assq 'type content-type)) 'message)
 546                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 547            (message "Bursting...%s" (setq number (+ 1 number)))
 548            (setq entity
 549                  (car (mime-entity-children message-entity)))
 550            (with-temp-buffer
 551              (insert (mime-entity-body message-entity))
 552              (elmo-folder-append-buffer target))))
 553     number))
 554
 555 (defun wl-summary-burst (&optional arg)
 556   "De-capsulate embedded messages in MIME format.
 557 With ARG, ask destination folder."
 558   (interactive "P")
 559   (let ((raw-buf (wl-summary-get-original-buffer))
 560         (view-buf wl-message-buffer)
 561         message-entity target)
 562     (save-excursion
 563       (when (and (null arg)
 564                  (elmo-folder-writable-p wl-summary-buffer-elmo-folder))
 565         (setq target wl-summary-buffer-elmo-folder))
 566       (while (null target)
 567         (let ((name (wl-summary-read-folder wl-default-folder
 568                                             "to extract to")))
 569           (setq target (wl-folder-get-elmo-folder name))
 570           (unless (elmo-folder-writable-p target)
 571             (message "%s is not writable" name)
 572             (setq target nil)
 573             (sit-for 1))))
 574       (wl-summary-set-message-buffer-or-redisplay)
 575       (with-current-buffer view-buf
 576         (setq message-entity
 577               (get-text-property (point-min) 'mime-view-entity)))
 578       (when message-entity
 579         (message "Bursting...")
 580         (with-current-buffer raw-buf
 581           (wl-summary-burst-subr message-entity target 0))
 582         (message "Bursting...done"))
 583       (if (elmo-folder-plugged-p target)
 584           (elmo-folder-check target)))
 585     (when (and target
 586                (string= wl-summary-buffer-folder-name
 587                         (elmo-folder-name-internal target)))
 588       (save-excursion (wl-summary-sync-update)))))
 589
 590 ;; internal variable.
 591 (defvar wl-mime-save-directory nil "Last saved directory.")
 592 ;;; Yet another save method.
 593 (defun wl-mime-save-content (entity situation)
 594   (let ((filename (expand-file-name
 595                    (read-file-name "Save to file: "
 596                                    (expand-file-name
 597                                     (or (mime-entity-safe-filename entity)
 598                                         ".")
 599                                     (or wl-mime-save-directory
 600                                         wl-temporary-file-directory))))))
 601     (while (file-directory-p filename)
 602       (setq filename (read-file-name "Please set filename (not directory): "
 603                                      filename)))
 604     (if (and (file-exists-p filename)
 605              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 606                                        filename))))
 607         (message "Not saved")
 608       (setq wl-mime-save-directory (file-name-directory filename))
 609       (mime-write-entity-content entity filename))))
 610
 611 ;;; Yet another combine method.
 612 (defun wl-mime-combine-message/partial-pieces (entity situation)
 613   "Internal method for wl to combine message/partial messages automatically."
 614   (interactive)
 615   (let* ((folder (with-current-buffer wl-message-buffer-cur-summary-buffer
 616                    wl-summary-buffer-elmo-folder))
 617          (mime-display-header-hook 'wl-highlight-headers)
 618          (id (or (cdr (assoc "id" situation)) ""))
 619          (mother (current-buffer))
 620          (summary-buf wl-message-buffer-cur-summary-buffer)
 621          subject-id overviews
 622          (root-dir (expand-file-name
 623                     (concat "m-prts-" (user-login-name))
 624                     temporary-file-directory))
 625          full-file point)
 626     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 627     (setq full-file (concat root-dir "/FULL"))
 628     (if (or (file-exists-p full-file)
 629             (not (y-or-n-p "Merge partials? ")))
 630         (with-current-buffer mother
 631           (mime-store-message/partial-piece entity situation)
 632           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 633           (make-variable-buffer-local 'mime-preview-over-to-next-method-alist)
 634           (setq mime-preview-over-to-next-method-alist
 635                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 636                       mime-preview-over-to-next-method-alist))
 637           (make-variable-buffer-local 'mime-preview-over-to-previous-method-alist)
 638           (setq mime-preview-over-to-previous-method-alist
 639                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 640                       mime-preview-over-to-previous-method-alist)))
 641       (setq subject-id
 642             (eword-decode-string
 643              (decode-mime-charset-string
 644               (mime-entity-read-field entity 'Subject)
 645               wl-summary-buffer-mime-charset)))
 646       (if (string-match "[0-9\n]+" subject-id)
 647           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 648       (catch 'tag
 649         (elmo-folder-do-each-message-entity (entity folder)
 650           (when (string-match
 651                  (regexp-quote subject-id)
 652                  (elmo-message-entity-field entity 'subject 'decode))
 653             (let* ((message
 654                     ;; request message at the cursor in Subject buffer.
 655                     (wl-message-request-partial
 656                      (elmo-folder-name-internal folder)
 657                      (elmo-message-entity-number entity)))
 658                    (situation (mime-entity-situation message))
 659                    (the-id (or (cdr (assoc "id" situation)) "")))
 660               (when (string= (downcase the-id)
 661                              (downcase id))
 662                 (with-current-buffer mother
 663                   (mime-store-message/partial-piece message situation))
 664                 (if (file-exists-p full-file)
 665                     (throw 'tag nil))))))
 666         (message "Not all partials found.")))))
 667
 668 (defun wl-mime-display-text/plain (entity situation)
 669   (let ((beg (point)))
 670     (mime-display-text/plain entity situation)
 671     (wl-highlight-message beg (point-max) t t)))
 672
 673 (defun wl-mime-display-header (entity situation)
 674   (let ((elmo-message-ignored-field-list
 675          (if wl-message-buffer-require-all-header
 676              nil
 677            wl-message-ignored-field-list))
 678         (elmo-message-visible-field-list wl-message-visible-field-list)
 679         (elmo-message-sorted-field-list wl-message-sort-field-list))
 680     (elmo-mime-insert-header entity situation)
 681     (wl-highlight-headers)))
 682
 683 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 684   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 685         (original-buffer wl-message-buffer-original-buffer))
 686     (mime-decrypt-application/pgp-encrypted entity situation)
 687     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 688     (setq wl-message-buffer-original-buffer original-buffer)))
 689
 690
 691 ;;; Setup methods.
 692 (defun wl-mime-setup ()
 693   (set-alist 'mime-preview-quitting-method-alist
 694              'wl-original-message-mode 'wl-message-exit)
 695   (set-alist 'mime-view-over-to-previous-method-alist
 696              'wl-original-message-mode 'wl-message-exit)
 697   (set-alist 'mime-view-over-to-next-method-alist
 698              'wl-original-message-mode 'wl-message-exit)
 699   (set-alist 'mime-preview-over-to-previous-method-alist
 700              'wl-original-message-mode 'wl-message-exit)
 701   (set-alist 'mime-preview-over-to-next-method-alist
 702              'wl-original-message-mode 'wl-message-exit)
 703   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 704   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 705
 706   (ctree-set-calist-strictly
 707    'mime-preview-condition
 708    '((type . text) (subtype . plain)
 709      (body . visible)
 710      (body-presentation-method . wl-mime-display-text/plain)
 711      (major-mode . wl-original-message-mode)))
 712
 713   (ctree-set-calist-strictly
 714    'mime-preview-condition
 715    '((type . application)(subtype . pgp-encrypted)
 716      (encoding . t)
 717      (body . invisible)
 718      (body-presentation-method . wl-mime-preview-application/pgp-encrypted)
 719      (major-mode . wl-original-message-mode)))
 720
 721   (ctree-set-calist-strictly
 722    'mime-acting-condition
 723    '((type . message) (subtype . partial)
 724      (method .  wl-mime-combine-message/partial-pieces)
 725      (request-partial-message-method . wl-message-request-partial)
 726      (major-mode . wl-original-message-mode)))
 727
 728   (ctree-set-calist-strictly
 729    'mime-acting-condition
 730    '((type . application) (subtype . pgp-encrypted)
 731      (method . wl-mime-decrypt-application/pgp-encrypted)
 732      (major-mode . wl-original-message-mode)))
 733
 734   (ctree-set-calist-strictly
 735    'mime-acting-condition
 736    '((mode . "extract")
 737      (major-mode . wl-original-message-mode)
 738      (method . wl-mime-save-content)))
 739   (set-alist 'mime-preview-following-method-alist
 740              'wl-original-message-mode
 741              (function wl-message-follow-current-entity))
 742   (set-alist 'mime-view-following-method-alist
 743              'wl-original-message-mode
 744              (function wl-message-follow-current-entity))
 745   (set-alist 'mime-edit-message-inserter-alist
 746              'wl-draft-mode (function wl-draft-insert-current-message))
 747   (set-alist 'mime-edit-mail-inserter-alist
 748              'wl-draft-mode (function wl-draft-insert-get-message))
 749   (set-alist 'mime-edit-split-message-sender-alist
 750              'wl-draft-mode
 751              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 752   (set-alist 'mime-raw-representation-type-alist
 753              'wl-original-message-mode 'binary)
 754   ;; Sort and highlight header fields.
 755   (or wl-message-ignored-field-list
 756       (setq wl-message-ignored-field-list
 757             mime-view-ignored-field-list))
 758   (or wl-message-visible-field-list
 759       (setq wl-message-visible-field-list
 760             mime-view-visible-field-list))
 761   (set-alist 'mime-header-presentation-method-alist
 762              'wl-original-message-mode
 763              'wl-mime-display-header)
 764   ;; To avoid overriding wl-draft-mode-map.
 765   (when (boundp 'mime-setup-signature-key-alist)
 766     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 767       (setq mime-setup-signature-key-alist
 768             (cons '(wl-draft-mode . "\C-c\C-w")
 769                   mime-setup-signature-key-alist)))))
 770
 771 (require 'product)
 772 (product-provide (provide 'wl-mime) (require 'wl-version))
 773
 774 ;;; wl-mime.el ends here