wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'mime-view)
  33 (require 'mime-edit)
  34 (require 'mime-play)
  35 (require 'elmo)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'Meadow-version 'ignore))
  39
  40 (defvar xemacs-betaname)
  41 (defvar xemacs-codename)
  42 (defvar enable-multibyte-characters)
  43 (defvar mule-version)
  44
  45 ;;; Draft
  46
  47 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  48
  49 (defalias 'wl-draft-decode-message-in-buffer
  50   'mime-edit-decode-message-in-buffer)
  51
  52 (defun wl-draft-yank-current-message-entity ()
  53   "Yank currently displayed message entity.
  54 By setting following-method as yank-content."
  55   (let ((wl-draft-buffer (current-buffer))
  56         (mime-view-following-method-alist
  57          (list (cons 'wl-original-message-mode
  58                      (function wl-draft-yank-to-draft-buffer))))
  59         (mime-preview-following-method-alist
  60          (list (cons 'wl-original-message-mode
  61                      (function wl-draft-yank-to-draft-buffer)))))
  62     (if (get-buffer (wl-current-message-buffer))
  63         (save-excursion
  64           (save-restriction
  65             (set-buffer (wl-current-message-buffer))
  66             (widen)
  67             (mime-preview-follow-current-entity))))))
  68
  69 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
  70
  71 (defun wl-draft-preview-message ()
  72   "Preview editing message."
  73   (interactive)
  74   (let* (recipients-message
  75          (current-point (point))
  76          (config-exec-flag wl-draft-config-exec-flag)
  77          (parent-folder wl-draft-parent-folder)
  78          (mime-display-header-hook 'wl-highlight-headers)
  79          (mime-header-encode-method-alist
  80           (append
  81            '((wl-draft-eword-encode-address-list
  82               .  (To Cc Bcc Resent-To Resent-Cc Bcc Resent-Bcc)))
  83            (if (boundp 'mime-header-encode-method-alist)
  84                (symbol-value 'mime-header-encode-method-alist))))
  85          mime-view-ignored-field-list   ; all header.
  86          (mime-edit-translate-buffer-hook
  87           (append
  88            (list
  89             (function
  90              (lambda ()
  91                (let ((wl-draft-config-exec-flag config-exec-flag)
  92                      (wl-draft-parent-folder parent-folder))
  93                  (goto-char current-point)
  94                  (run-hooks 'wl-draft-send-hook)
  95                  (setq recipients-message
  96                        (condition-case err
  97                            (concat "Recipients: "
  98                                    (mapconcat
  99                                     'identity
 100                                     (wl-draft-deduce-address-list
 101                                      (current-buffer)
 102                                      (point-min)
 103                                      (save-excursion
 104                                        (goto-char (point-min))
 105                                        (re-search-forward
 106                                         (concat
 107                                          "^"
 108                                          (regexp-quote mail-header-separator)
 109                                          "$")
 110                                         nil t)
 111                                        (point)))
 112                                     ", "))
 113                          (error
 114                           (kill-buffer (current-buffer))
 115                           (signal (car err) (cdr err)))))))))
 116            mime-edit-translate-buffer-hook)))
 117     (mime-edit-preview-message)
 118     (let ((buffer-read-only nil))
 119       (when wl-highlight-body-too
 120         (wl-highlight-body))
 121       (run-hooks 'wl-draft-preview-message-hook))
 122     (message recipients-message)))
 123
 124 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 125
 126 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 127
 128 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 129
 130 ;;; Message
 131
 132 (defun wl-message-decode-mode (outbuf inbuf)
 133   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 134         (mime-display-header-hook 'wl-highlight-headers))
 135     (mime-view-mode nil nil nil inbuf outbuf)))
 136
 137 (defun wl-message-decode-with-all-header (outbuf inbuf)
 138   (let ((mime-view-ignored-field-regexp "^:$")
 139         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 140         (mime-display-header-hook 'wl-highlight-headers)
 141         mime-view-ignored-field-list)
 142     (mime-view-mode nil nil nil inbuf outbuf)))
 143
 144 (defun wl-message-delete-mime-out-buf ()
 145   (let (mime-out-buf mime-out-win)
 146     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 147         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 148             (delete-window mime-out-win)))))
 149
 150 (defun wl-message-request-partial (folder number)
 151   (elmo-set-work-buf
 152    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 153                        number
 154                        (elmo-make-fetch-strategy 'entire)
 155                        nil
 156                        (current-buffer)
 157                        'unread)
 158    (mime-parse-buffer nil)))
 159
 160 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 161 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 162 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 163 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 164 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 165 (defalias 'wl-message-quit              'mime-preview-quit)
 166 (defalias 'wl-message-button-dispatcher-internal
 167   'mime-button-dispatcher)
 168
 169 (defsubst wl-mime-node-id-to-string (node-id)
 170   (if (consp node-id)
 171       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 172                  (reverse node-id)
 173                  ".")
 174     "0"))
 175
 176 (defun wl-message-delete-current-part ()
 177   "Delete a part under the cursor from the multipart message."
 178   (interactive)
 179   (let* ((entity (get-text-property (point) 'mime-view-entity))
 180          (node-id (mime-entity-node-id entity))
 181          (header-start (mime-buffer-entity-header-start-internal entity))
 182          (body-end (mime-buffer-entity-body-end-internal entity))
 183          (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 184          (number wl-message-buffer-cur-number)
 185          (msgid (elmo-message-field folder number 'message-id)))
 186     (when (and node-id
 187                (yes-or-no-p
 188                 (format "Do you really want to delete part %s? "
 189                         (wl-mime-node-id-to-string node-id))))
 190       (with-temp-buffer
 191         (elmo-message-fetch folder
 192                             number
 193                             (elmo-make-fetch-strategy 'entire)
 194                             nil
 195                             (current-buffer)
 196                             'unread)
 197         (kill-region header-start body-end)
 198         (goto-char header-start)
 199         (insert "Content-Type: text/plain; charset=US-ASCII\n\n")
 200         (insert "** This part has been removed by Wanderlust **\n\n")
 201         (elmo-folder-append-buffer folder t))
 202
 203       (elmo-folder-append-messages
 204        (wl-folder-get-elmo-folder wl-trash-folder)
 205        folder (list number) nil)
 206       (elmo-folder-delete-messages folder (list number))
 207
 208       (when (file-exists-p (elmo-cache-get-path msgid))
 209         (delete-file (elmo-cache-get-path msgid)))
 210
 211       (mime-preview-quit)
 212       (wl-summary-toggle-disp-msg 'off)
 213       (wl-summary-sync nil "update"))))
 214
 215 ;;; Summary
 216 (defun wl-summary-burst-subr (message-entity target number)
 217   ;; returns new number.
 218   (let (content-type entity)
 219     (setq content-type (mime-entity-content-type message-entity))
 220     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 221            (dolist (entity (mime-entity-children message-entity))
 222              (setq number (wl-summary-burst-subr
 223                            entity
 224                            target
 225                            number))))
 226           ((and (eq (cdr (assq 'type content-type)) 'message)
 227                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 228            (message "Bursting...%s" (setq number (+ 1 number)))
 229            (setq entity
 230                  (car (mime-entity-children message-entity)))
 231            (with-temp-buffer
 232              (insert (mime-entity-body message-entity))
 233              (elmo-folder-append-buffer
 234               target
 235               (mime-entity-fetch-field entity "Message-ID")))))
 236     number))
 237
 238 (defun wl-summary-burst (&optional arg)
 239   "De-capsulate embedded messages in MIME format.
 240 With ARG, ask destination folder."
 241   (interactive "P")
 242   (let ((raw-buf (wl-summary-get-original-buffer))
 243         (view-buf wl-message-buffer)
 244         children message-entity content-type target)
 245     (save-excursion
 246       (setq target wl-summary-buffer-elmo-folder)
 247       (when (or arg (not (elmo-folder-writable-p target)))
 248         (let ((fld (wl-summary-read-folder wl-default-folder "to extract to")))
 249           (setq target (wl-folder-get-elmo-folder fld))))
 250       (wl-summary-set-message-buffer-or-redisplay)
 251       (with-current-buffer view-buf
 252         (setq message-entity (get-text-property (point-min) 'mime-view-entity)))
 253       (when message-entity
 254         (message "Bursting...")
 255         (with-current-buffer raw-buf
 256           (wl-summary-burst-subr message-entity target 0))
 257         (message "Bursting...done"))
 258       (if (elmo-folder-plugged-p target)
 259           (elmo-folder-check target)))
 260     (wl-summary-sync-update)))
 261
 262 ;; internal variable.
 263 (defvar wl-mime-save-directory nil "Last saved directory.")
 264 ;;; Yet another save method.
 265 (defun wl-mime-save-content (entity situation)
 266   (let ((filename (read-file-name "Save to file: "
 267                                   (expand-file-name
 268                                    (or (mime-entity-safe-filename entity)
 269                                        ".")
 270                                    (or wl-mime-save-directory
 271                                        wl-temporary-file-directory)))))
 272     (while (file-directory-p filename)
 273       (setq filename (read-file-name "Please set filename (not directory): "
 274                                      filename)))
 275     (if (and (file-exists-p filename)
 276              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 277                                        filename))))
 278         (message "Not saved")
 279       (setq wl-mime-save-directory (file-name-directory filename))
 280       (mime-write-entity-content entity filename))))
 281
 282 ;;; Yet another combine method.
 283 (defun wl-mime-combine-message/partial-pieces (entity situation)
 284   "Internal method for wl to combine message/partial messages automatically."
 285   (interactive)
 286   (let* ((msgdb (save-excursion
 287                   (set-buffer wl-message-buffer-cur-summary-buffer)
 288                   (wl-summary-buffer-msgdb)))
 289          (mime-display-header-hook 'wl-highlight-headers)
 290          (folder wl-message-buffer-cur-folder)
 291          (id (or (cdr (assoc "id" situation)) ""))
 292          (mother (current-buffer))
 293          (summary-buf wl-message-buffer-cur-summary-buffer)
 294          subject-id overviews
 295          (root-dir (expand-file-name
 296                     (concat "m-prts-" (user-login-name))
 297                     temporary-file-directory))
 298          full-file point)
 299     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 300     (setq full-file (concat root-dir "/FULL"))
 301     (if (or (file-exists-p full-file)
 302             (not (y-or-n-p "Merge partials? ")))
 303         (with-current-buffer mother
 304           (mime-store-message/partial-piece entity situation)
 305           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 306           (make-variable-buffer-local 'mime-preview-over-to-next-method-alist)
 307           (setq mime-preview-over-to-next-method-alist
 308                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 309                       mime-preview-over-to-next-method-alist))
 310           (make-variable-buffer-local 'mime-preview-over-to-previous-method-alist)
 311           (setq mime-preview-over-to-previous-method-alist
 312                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 313                       mime-preview-over-to-previous-method-alist)))
 314       (setq subject-id
 315             (eword-decode-string
 316              (decode-mime-charset-string
 317               (mime-entity-read-field entity 'Subject)
 318               wl-summary-buffer-mime-charset)))
 319       (if (string-match "[0-9\n]+" subject-id)
 320           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 321       (setq overviews (elmo-msgdb-get-overview msgdb))
 322       (catch 'tag
 323         (while overviews
 324           (when (string-match
 325                  (regexp-quote subject-id)
 326                  (elmo-msgdb-overview-entity-get-subject (car overviews)))
 327             (let* ((message
 328                     ;; request message at the cursor in Subject buffer.
 329                     (wl-message-request-partial
 330                      folder
 331                      (elmo-msgdb-overview-entity-get-number
 332                       (car overviews))))
 333                    (situation (mime-entity-situation message))
 334                    (the-id (or (cdr (assoc "id" situation)) "")))
 335               (when (string= (downcase the-id)
 336                              (downcase id))
 337                 (with-current-buffer mother
 338                   (mime-store-message/partial-piece message situation))
 339                 (if (file-exists-p full-file)
 340                     (throw 'tag nil)))))
 341           (setq overviews (cdr overviews)))
 342         (message "Not all partials found.")))))
 343
 344 (defun wl-mime-display-text/plain (entity situation)
 345   (let ((beg (point)))
 346     (mime-display-text/plain entity situation)
 347     (wl-highlight-message beg (point-max) t t)))
 348
 349 (defun wl-mime-display-header (entity situation)
 350   (let ((elmo-message-ignored-field-list
 351          (if wl-message-buffer-all-header-flag
 352              nil
 353            wl-message-ignored-field-list))
 354         (elmo-message-visible-field-list wl-message-visible-field-list)
 355         (elmo-message-sorted-field-list wl-message-sort-field-list))
 356     (elmo-mime-insert-header entity situation)
 357     (wl-highlight-headers)))
 358
 359 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 360   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 361         (original-buffer wl-message-buffer-original-buffer))
 362     (mime-decrypt-application/pgp-encrypted entity situation)
 363     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 364     (setq wl-message-buffer-original-buffer original-buffer)))
 365
 366
 367 ;;; Setup methods.
 368 (defun wl-mime-setup ()
 369   (set-alist 'mime-preview-quitting-method-alist
 370              'wl-original-message-mode 'wl-message-exit)
 371   (set-alist 'mime-view-over-to-previous-method-alist
 372              'wl-original-message-mode 'wl-message-exit)
 373   (set-alist 'mime-view-over-to-next-method-alist
 374              'wl-original-message-mode 'wl-message-exit)
 375   (set-alist 'mime-preview-over-to-previous-method-alist
 376              'wl-original-message-mode 'wl-message-exit)
 377   (set-alist 'mime-preview-over-to-next-method-alist
 378              'wl-original-message-mode 'wl-message-exit)
 379   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 380   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 381
 382   (ctree-set-calist-strictly
 383    'mime-preview-condition
 384    '((type . text) (subtype . plain)
 385      (body . visible)
 386      (body-presentation-method . wl-mime-display-text/plain)
 387      (major-mode . wl-original-message-mode)))
 388
 389   (ctree-set-calist-strictly
 390    'mime-acting-condition
 391    '((type . message) (subtype . partial)
 392      (method .  wl-mime-combine-message/partial-pieces)
 393      (request-partial-message-method . wl-message-request-partial)
 394      (major-mode . wl-original-message-mode)))
 395
 396   (ctree-set-calist-strictly
 397    'mime-acting-condition
 398    '((type . application) (subtype . pgp-encrypted)
 399      (method . wl-mime-decrypt-application/pgp-encrypted)
 400      (major-mode . wl-original-message-mode)))
 401
 402   (ctree-set-calist-strictly
 403    'mime-acting-condition
 404    '((mode . "extract")
 405      (major-mode . wl-original-message-mode)
 406      (method . wl-mime-save-content)))
 407   (set-alist 'mime-preview-following-method-alist
 408              'wl-original-message-mode
 409              (function wl-message-follow-current-entity))
 410   (set-alist 'mime-view-following-method-alist
 411              'wl-original-message-mode
 412              (function wl-message-follow-current-entity))
 413   (set-alist 'mime-edit-message-inserter-alist
 414              'wl-draft-mode (function wl-draft-insert-current-message))
 415   (set-alist 'mime-edit-mail-inserter-alist
 416              'wl-draft-mode (function wl-draft-insert-get-message))
 417   (set-alist 'mime-edit-split-message-sender-alist
 418              'wl-draft-mode
 419              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 420   (set-alist 'mime-raw-representation-type-alist
 421              'wl-original-message-mode 'binary)
 422   ;; Sort and highlight header fields.
 423   (or wl-message-ignored-field-list
 424       (setq wl-message-ignored-field-list
 425             mime-view-ignored-field-list))
 426   (or wl-message-visible-field-list
 427       (setq wl-message-visible-field-list
 428             mime-view-visible-field-list))
 429   (set-alist 'mime-header-presentation-method-alist
 430              'wl-original-message-mode
 431              'wl-mime-display-header)
 432   ;; To avoid overriding wl-draft-mode-map.
 433   (when (boundp 'mime-setup-signature-key-alist)
 434     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 435       (setq mime-setup-signature-key-alist
 436             (cons '(wl-draft-mode . "\C-c\C-w")
 437                   mime-setup-signature-key-alist)))))
 438
 439 (require 'product)
 440 (product-provide (provide 'wl-mime) (require 'wl-version))
 441
 442 ;;; wl-mime.el ends here