wl/wl-mule.el

   1 ;;; wl-mule.el -- Wanderlust modules for Mule compatible Emacsen.
   2 ;;                (Mule2.3@19.28, Mule2.3@19.34, Emacs 20.x)
   3
   4 ;; Copyright 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   5
   6 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   7 ;; Keywords: mail, net news
   8
   9 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25 ;;
  26
  27 ;;; Commentary:
  28 ;;
  29
  30 ;;; Code:
  31 ;;
  32
  33 (eval-when-compile
  34   (require 'wl-folder)
  35   (require 'wl-summary)
  36   (require 'wl-draft)
  37   (require 'wl-message)
  38   (require 'wl-highlight)
  39   (require 'wl-vars)
  40   (defvar-maybe wl-draft-mode-map (make-sparse-keymap)))
  41
  42 (defun wl-draft-mode-setup ()
  43   (require 'derived)
  44   (define-derived-mode wl-draft-mode mail-mode "Draft"
  45     "draft mode for Wanderlust derived from mail mode.
  46 See info under Wanderlust for full documentation.
  47
  48 Special commands:
  49 \\{wl-draft-mode-map}"))
  50
  51 ;; Common implementations.
  52 (defun wl-highlight-folder-current-line (&optional numbers)
  53   "Highlight current folder line."
  54   (interactive)
  55   (save-excursion
  56     (end-of-line)
  57     (let ((end (point))
  58           (start (progn (beginning-of-line) (point)))
  59           (inhibit-read-only t)
  60           (text-face
  61            (cond ((looking-at wl-highlight-folder-opened-regexp)
  62                   'wl-highlight-folder-opened-face)
  63                  ((looking-at wl-highlight-folder-closed-regexp)
  64                   'wl-highlight-folder-closed-face)
  65                  (t
  66                   (if (looking-at (format "^[ \t]*\\(%s\\|%s\\)"
  67                                           wl-folder-unsubscribe-mark
  68                                           wl-folder-removed-mark))
  69                       'wl-highlight-folder-killed-face
  70                     'wl-highlight-folder-unknown-face)))))
  71       (if (and wl-highlight-folder-by-numbers
  72                numbers (nth 0 numbers) (nth 1 numbers)
  73                (re-search-forward "[0-9-]+/[0-9-]+/[0-9-]+" end t))
  74           (let* ((unsync (nth 0 numbers))
  75                  (unread (nth 1 numbers))
  76                  (face (cond
  77                         ((and unsync (zerop unsync))
  78                          (if (and unread (zerop unread))
  79                              'wl-highlight-folder-zero-face
  80                            'wl-highlight-folder-unread-face))
  81                         ((and unsync
  82                               (>= unsync wl-folder-many-unsync-threshold))
  83                          'wl-highlight-folder-many-face)
  84                         (t
  85                          'wl-highlight-folder-few-face))))
  86             (if (numberp wl-highlight-folder-by-numbers)
  87                 (progn
  88                   (put-text-property start (match-beginning 0) 'face text-face)
  89                   (put-text-property (match-beginning 0) (point) 'face face))
  90               ;; Remove previous face.
  91               (put-text-property start (point) 'face nil)
  92               (put-text-property start (point) 'face face))
  93             (goto-char start))
  94         (put-text-property start end 'face text-face)))
  95     (when wl-use-highlight-mouse-line
  96       (wl-highlight-folder-mouse-line))))
  97
  98 (defun wl-highlight-plugged-current-line ())
  99 (defun wl-plugged-set-folder-icon (folder string)
 100   string)
 101
 102 (defun wl-message-overload-functions ()
 103   (local-set-key "l" 'wl-message-toggle-disp-summary)
 104   (local-set-key [mouse-2] 'wl-message-refer-article-or-url)
 105   (local-set-key [mouse-4] 'wl-message-wheel-down)
 106   (local-set-key [mouse-5] 'wl-message-wheel-up)
 107   (local-set-key [S-mouse-4] 'wl-message-wheel-down)
 108   (local-set-key [S-mouse-5] 'wl-message-wheel-up)
 109   (set-keymap-parent wl-message-button-map (current-local-map))
 110   (define-key wl-message-button-map [mouse-2]
 111     'wl-message-button-dispatcher))
 112
 113 (defun wl-message-wheel-up (event)
 114   (interactive "e")
 115   (if (string-match wl-message-buf-name (buffer-name))
 116       (wl-message-next-page)
 117     (let ((cur-buf (current-buffer))
 118           proceed)
 119       (save-selected-window
 120         (select-window (posn-window (event-start event)))
 121         (set-buffer cur-buf)
 122         (setq proceed (wl-message-next-page)))
 123       (if proceed
 124           (if (memq 'shift (event-modifiers event))
 125               (wl-summary-down t)
 126             (wl-summary-next t))))))
 127
 128 (defun wl-message-wheel-down (event)
 129   (interactive "e")
 130   (if (string-match wl-message-buf-name (buffer-name))
 131       (wl-message-prev-page)
 132     (let ((cur-buf (current-buffer))
 133           proceed)
 134       (save-selected-window
 135         (select-window (posn-window (event-start event)))
 136         (set-buffer cur-buf)
 137         (setq proceed (wl-message-prev-page)))
 138       (if proceed
 139           (if (memq 'shift (event-modifiers event))
 140               (wl-summary-up t)
 141             (wl-summary-prev t))))))
 142
 143 (defun wl-draft-key-setup ()
 144   (define-key wl-draft-mode-map "\C-c\C-y" 'wl-draft-yank-original)
 145   (define-key wl-draft-mode-map "\C-c\C-a" 'wl-draft-insert-x-face-field)
 146   (define-key wl-draft-mode-map "\C-c\C-s" 'wl-draft-send)
 147   (define-key wl-draft-mode-map "\C-c\C-c" 'wl-draft-send-and-exit)
 148   (define-key wl-draft-mode-map "\C-c\C-z" 'wl-draft-save-and-exit)
 149   (define-key wl-draft-mode-map "\C-c\C-k" 'wl-draft-kill)
 150   (define-key wl-draft-mode-map "\C-l"     'wl-draft-highlight-and-recenter)
 151   (define-key wl-draft-mode-map "\C-i"     'wl-complete-field-body-or-tab)
 152   (define-key wl-draft-mode-map "\C-c\C-r" 'wl-draft-caesar-region)
 153   (define-key wl-draft-mode-map "\M-t"     'wl-toggle-plugged)
 154   (define-key wl-draft-mode-map "\C-c\C-o" 'wl-jump-to-draft-buffer)
 155   (define-key wl-draft-mode-map "\C-c\C-e" 'wl-draft-config-exec)
 156   (define-key wl-draft-mode-map "\C-c\C-j" 'wl-template-select)
 157   (define-key wl-draft-mode-map "\C-c\C-p" 'wl-draft-preview-message)
 158   (define-key wl-draft-mode-map "\C-x\C-s" 'wl-draft-save)
 159   (define-key wl-draft-mode-map "\C-xk" 'wl-draft-mimic-kill-buffer))
 160
 161 (defun wl-draft-overload-menubar ()
 162   (local-set-key [menu-bar mail send]
 163     '("Send Message" . wl-draft-send-and-exit))
 164   (local-set-key [menu-bar mail send-stay]
 165     '("Send, Keep Editing" . wl-draft-send))
 166   (local-set-key [menu-bar mail cancel]
 167     '("Kill Current Draft" . wl-draft-kill))
 168   (local-set-key [menu-bar mail yank]
 169     '("Cite Message" . wl-draft-yank-original))
 170   (local-set-key [menu-bar mail signature]
 171     '("Insert Signature" . insert-signature))
 172   (local-set-key [menu-bar headers fcc]
 173     '("FCC" . wl-draft-fcc)))
 174
 175 (defun wl-draft-overload-functions ()
 176   (wl-mode-line-buffer-identification)
 177   (local-set-key "\C-c\C-s" 'wl-draft-send);; override
 178   (wl-draft-overload-menubar))
 179
 180 ;; for "ja-mule-canna-2.3.mini" on PocketBSD
 181 (defun-maybe make-face (a))
 182
 183 (eval-when-compile
 184   (require 'static))
 185 (static-cond
 186  ((and (fboundp 'defface)
 187        (not (featurep 'tinycustom)))
 188   (defalias 'wl-defface 'defface)
 189   (eval-when-compile
 190     (defun wl-face-spec-set-match-display (display frame))
 191     (defun wl-frame-parameter (frame property &optional default))
 192     (defun wl-get-frame-properties (&optional frame))))
 193  (t
 194   (defmacro wl-defface (face spec doc &rest args)
 195     (nconc (list 'wl-declare-face (list 'quote face) spec)))
 196
 197   (defun wl-declare-face (face spec)
 198     (make-face face)
 199     (while spec
 200       (let* ((entry (car spec))
 201              (display (nth 0 entry))
 202              (atts (nth 1 entry)))
 203         (setq spec (cdr spec))
 204         (when (wl-face-spec-set-match-display display nil)
 205           (apply 'wl-face-attributes-set face nil atts)))))
 206
 207   (defconst wl-face-attributes
 208     '((:bold set-face-bold-p)
 209       (:italic set-face-italic-p)
 210       (:underline set-face-underline-p)
 211       (:foreground set-face-foreground)
 212       (:background set-face-background)
 213       (:stipple set-face-stipple)))
 214
 215   (defun wl-face-attributes-set (face frame &rest atts)
 216     "For FACE on FRAME set the attributes [KEYWORD VALUE]....
 217 Each keyword should be listed in `custom-face-attributes'.
 218
 219 If FRAME is nil, set the default face."
 220     (while atts
 221       (let* ((name (nth 0 atts))
 222              (value (nth 1 atts))
 223              (fun (nth 1 (assq name wl-face-attributes))))
 224         (setq atts (cdr (cdr atts)))
 225         (condition-case nil
 226             (funcall fun face value frame)
 227           (error nil)))))
 228
 229   (defun wl-frame-parameter (frame property &optional default)
 230     "Return FRAME's value for property PROPERTY."
 231     (or (cdr (assq property (frame-parameters frame)))
 232         default))
 233
 234   (eval-when-compile
 235     (defun-maybe x-display-grayscale-p ()))
 236
 237   (defun wl-get-frame-properties (&optional frame)
 238     "Return a plist with the frame properties of FRAME used by custom."
 239     (list (cons 'type window-system)
 240           (cons 'class (or (wl-frame-parameter frame 'display-type)
 241                            (when window-system
 242                              (cond ((x-display-color-p)
 243                                     'color)
 244                                    ((and (fboundp 'x-display-grayscale-p)
 245                                          (x-display-grayscale-p))
 246                                     'grayscale)
 247                                    (t 'mono)))))
 248           (cons 'background (or (wl-frame-parameter frame 'background-mode)
 249                                 wl-highlight-background-mode))))
 250
 251   (defun wl-face-spec-set-match-display (display frame)
 252     "Non-nil iff DISPLAY matches FRAME.
 253 If FRAME is nil, the current FRAME is used."
 254     ;; This is a kludge to get started, we really should use specifiers!
 255     (if (eq display t)
 256         t
 257       (let* ((props (wl-get-frame-properties frame))
 258              (type (cdr (assq 'type props)))
 259              (class (cdr (assq 'class props)))
 260              (background (cdr (assq 'background props)))
 261              (match t)
 262              (entries display)
 263              entry req options)
 264         (while (and entries match)
 265           (setq entry (car entries)
 266                 entries (cdr entries)
 267                 req (car entry)
 268                 options (cdr entry)
 269                 match (cond ((eq req 'type)
 270                              (memq type options))
 271                             ((eq req 'class)
 272                              (memq class options))
 273                             ((eq req 'background)
 274                              (memq background options))
 275                             (t
 276                              (message (format "\
 277 Warning: Unknown req `%S' with options `%S'" req options))
 278                              nil))))
 279         match)))))
 280
 281 (require 'product)
 282 (product-provide (provide 'wl-mule) (require 'wl-version))
 283
 284 ;;; wl-mule.el ends here