wl/wl-mule.el

   1 ;;; wl-mule.el --- Wanderlust modules for Mule compatible Emacsen.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;; For Mule2.3@19.34, Emacs 20.x
  28
  29 ;;; Code:
  30 ;;
  31
  32 (eval-when-compile
  33   (require 'wl-folder)
  34   (require 'wl-summary)
  35   (require 'wl-draft)
  36   (require 'wl-message)
  37   (require 'wl-highlight)
  38   (require 'wl-vars)
  39   (defvar-maybe wl-draft-mode-map (make-sparse-keymap)))
  40
  41 (defun wl-draft-mode-setup ()
  42   (require 'derived)
  43   (define-derived-mode wl-draft-mode mail-mode "Draft"
  44     "draft mode for Wanderlust derived from mail mode.
  45 See info under Wanderlust for full documentation.
  46
  47 Special commands:
  48 \\{wl-draft-mode-map}"))
  49
  50 ;; Common implementations.
  51 (defun wl-highlight-folder-current-line (&optional numbers)
  52   "Highlight current folder line."
  53   (interactive)
  54   (save-excursion
  55     (end-of-line)
  56     (let ((end (point))
  57           (start (progn (beginning-of-line) (point)))
  58           (inhibit-read-only t)
  59           (text-face
  60            (cond ((looking-at wl-highlight-folder-opened-regexp)
  61                   'wl-highlight-folder-opened-face)
  62                  ((looking-at wl-highlight-folder-closed-regexp)
  63                   'wl-highlight-folder-closed-face)
  64                  (t
  65                   (if (looking-at (format "^[ \t]*\\(%s\\|%s\\)"
  66                                           wl-folder-unsubscribe-mark
  67                                           wl-folder-removed-mark))
  68                       'wl-highlight-folder-killed-face
  69                     'wl-highlight-folder-unknown-face)))))
  70       (if (and wl-highlight-folder-by-numbers
  71                numbers (nth 0 numbers) (nth 1 numbers)
  72                (re-search-forward "[0-9-]+/[0-9-]+/[0-9-]+" end t))
  73           (let* ((unsync (nth 0 numbers))
  74                  (unread (nth 1 numbers))
  75                  (face (cond
  76                         ((and unsync (zerop unsync))
  77                          (if (and unread (zerop unread))
  78                              'wl-highlight-folder-zero-face
  79                            'wl-highlight-folder-unread-face))
  80                         ((and unsync
  81                               (>= unsync wl-folder-many-unsync-threshold))
  82                          'wl-highlight-folder-many-face)
  83                         (t
  84                          'wl-highlight-folder-few-face))))
  85             (if (numberp wl-highlight-folder-by-numbers)
  86                 (progn
  87                   (put-text-property start (match-beginning 0) 'face text-face)
  88                   (put-text-property (match-beginning 0) (point) 'face face))
  89               ;; Remove previous face.
  90               (put-text-property start (point) 'face nil)
  91               (put-text-property start (point) 'face face))
  92             (goto-char start))
  93         (put-text-property start end 'face text-face)))
  94     (when wl-use-highlight-mouse-line
  95       (wl-highlight-folder-mouse-line))))
  96
  97 (defun wl-highlight-plugged-current-line ())
  98 (defun wl-plugged-set-folder-icon (folder string)
  99   string)
 100
 101 (defun wl-message-define-keymap ()
 102   (let ((keymap (make-sparse-keymap)))
 103     (define-key keymap "D" 'wl-message-delete-current-part)
 104     (define-key keymap "l" 'wl-message-toggle-disp-summary)
 105     (define-key keymap [mouse-4] 'wl-message-wheel-down)
 106     (define-key keymap [mouse-5] 'wl-message-wheel-up)
 107     (define-key keymap [S-mouse-4] 'wl-message-wheel-down)
 108     (define-key keymap [S-mouse-5] 'wl-message-wheel-up)
 109     (set-keymap-parent wl-message-button-map keymap)
 110     (define-key wl-message-button-map [mouse-2]
 111       'wl-message-button-dispatcher)
 112     keymap))
 113
 114 (defun wl-message-wheel-up (event)
 115   (interactive "e")
 116   (if (string-match (regexp-quote wl-message-buffer-name)
 117                     (regexp-quote (buffer-name)))
 118       (wl-message-next-page)
 119     (let ((cur-buf (current-buffer))
 120           proceed)
 121       (save-selected-window
 122         (select-window (posn-window (event-start event)))
 123         (set-buffer cur-buf)
 124         (setq proceed (wl-message-next-page)))
 125       (if proceed
 126           (if (memq 'shift (event-modifiers event))
 127               (wl-summary-down t)
 128             (wl-summary-next t))))))
 129
 130 (defun wl-message-wheel-down (event)
 131   (interactive "e")
 132   (if (string-match (regexp-quote wl-message-buffer-name)
 133                     (regexp-quote (buffer-name)))
 134       (wl-message-prev-page)
 135     (let ((cur-buf (current-buffer))
 136           proceed)
 137       (save-selected-window
 138         (select-window (posn-window (event-start event)))
 139         (set-buffer cur-buf)
 140         (setq proceed (wl-message-prev-page)))
 141       (if proceed
 142           (if (memq 'shift (event-modifiers event))
 143               (wl-summary-up t)
 144             (wl-summary-prev t))))))
 145
 146 (defun wl-draft-key-setup ()
 147   (define-key wl-draft-mode-map "\C-c\C-y" 'wl-draft-yank-original)
 148   (define-key wl-draft-mode-map "\C-c\C-s" 'wl-draft-send)
 149   (define-key wl-draft-mode-map "\C-c\C-c" 'wl-draft-send-and-exit)
 150   (define-key wl-draft-mode-map "\C-c\C-z" 'wl-draft-save-and-exit)
 151   (define-key wl-draft-mode-map "\C-c\C-k" 'wl-draft-kill)
 152   (define-key wl-draft-mode-map "\C-l"     'wl-draft-highlight-and-recenter)
 153   (define-key wl-draft-mode-map "\C-i"     'wl-complete-field-body-or-tab)
 154   (define-key wl-draft-mode-map "\C-c\C-r" 'wl-draft-caesar-region)
 155   (define-key wl-draft-mode-map "\M-t"     'wl-toggle-plugged)
 156   (define-key wl-draft-mode-map "\C-c\C-o" 'wl-jump-to-draft-buffer)
 157   (define-key wl-draft-mode-map "\C-c\C-e" 'wl-draft-config-exec)
 158   (define-key wl-draft-mode-map "\C-c\C-j" 'wl-template-select)
 159   (define-key wl-draft-mode-map "\C-c\C-p" 'wl-draft-preview-message)
 160 ;;   (define-key wl-draft-mode-map "\C-x\C-s" 'wl-draft-save)
 161   (define-key wl-draft-mode-map "\C-c\C-a" 'wl-addrmgr)
 162   (define-key wl-draft-mode-map "\C-xk" 'wl-draft-mimic-kill-buffer)
 163   (define-key wl-draft-mode-map "\C-c\C-d" 'wl-draft-elide-region)
 164   (define-key wl-draft-mode-map "\C-a" 'wl-draft-beginning-of-line))
 165
 166 (defun wl-draft-overload-menubar ()
 167   (let ((keymap (current-local-map)))
 168     (define-key keymap [menu-bar mail send]
 169       '("Send Message" . wl-draft-send-and-exit))
 170     (define-key keymap [menu-bar mail send-stay]
 171       '("Send, Keep Editing" . wl-draft-send))
 172     (define-key-after (lookup-key keymap [menu-bar mail])
 173       [mail-sep-send] '("--")
 174       'send-stay)
 175     (define-key keymap [menu-bar mail cancel]
 176       '("Kill Current Draft" . wl-draft-kill))
 177     (define-key-after (lookup-key keymap [menu-bar mail])
 178       [save] '("Save Draft and Exit" . wl-draft-save-and-exit)
 179       'cancel)
 180     (define-key-after (lookup-key keymap [menu-bar mail])
 181       [mail-sep-exit] '("--")
 182       'save)
 183     (define-key-after (lookup-key keymap [menu-bar mail])
 184       [preview] '("Preview Message" . wl-draft-preview-message)
 185       'mail-sep-exit)
 186     (define-key keymap [menu-bar mail yank]
 187       '("Cite Message" . wl-draft-yank-original))
 188     (define-key keymap [menu-bar mail signature]
 189       '("Insert Signature" . insert-signature))
 190     (define-key keymap [menu-bar headers fcc]
 191       '("Fcc" . wl-draft-fcc))))
 192
 193 (defun wl-draft-overload-functions ()
 194   (wl-mode-line-buffer-identification)
 195 ;;  (local-set-key "\C-c\C-s" 'wl-draft-send);; override
 196   (wl-draft-overload-menubar))
 197
 198 ;; for "ja-mule-canna-2.3.mini" on PocketBSD
 199 (defun-maybe make-face (a))
 200
 201 (eval-when-compile
 202   (require 'static))
 203 (static-cond
 204  ((and (fboundp 'defface)
 205        (not (featurep 'tinycustom)))
 206   (defalias 'wl-defface 'defface)
 207   (eval-when-compile
 208     (defun wl-face-spec-set-match-display (display frame))
 209     (defun wl-frame-parameter (frame property &optional default))
 210     (defun wl-get-frame-properties (&optional frame))))
 211  (t
 212   (defmacro wl-defface (face spec doc &rest args)
 213     (nconc (list 'wl-declare-face (list 'quote face) spec)))
 214
 215   (defun wl-declare-face (face spec)
 216     (make-face face)
 217     (while spec
 218       (let* ((entry (car spec))
 219              (display (nth 0 entry))
 220              (atts (nth 1 entry)))
 221         (setq spec (cdr spec))
 222         (when (wl-face-spec-set-match-display display nil)
 223           (apply 'wl-face-attributes-set face nil atts)))))
 224
 225   (defconst wl-face-attributes
 226     '((:bold set-face-bold-p)
 227       (:italic set-face-italic-p)
 228       (:underline set-face-underline-p)
 229       (:foreground set-face-foreground)
 230       (:background set-face-background)
 231       (:stipple set-face-stipple)))
 232
 233   (defun wl-face-attributes-set (face frame &rest atts)
 234     "For FACE on FRAME set the attributes [KEYWORD VALUE]....
 235 Each keyword should be listed in `custom-face-attributes'.
 236
 237 If FRAME is nil, set the default face."
 238     (while atts
 239       (let* ((name (nth 0 atts))
 240              (value (nth 1 atts))
 241              (fun (nth 1 (assq name wl-face-attributes))))
 242         (setq atts (cdr (cdr atts)))
 243         (condition-case nil
 244             (funcall fun face value frame)
 245           (error nil)))))
 246
 247   (defun wl-frame-parameter (frame property &optional default)
 248     "Return FRAME's value for property PROPERTY."
 249     (or (cdr (assq property (frame-parameters frame)))
 250         default))
 251
 252   (eval-when-compile
 253     (defun-maybe x-display-grayscale-p ()))
 254
 255   (defun wl-get-frame-properties (&optional frame)
 256     "Return a plist with the frame properties of FRAME used by custom."
 257     (list (cons 'type window-system)
 258           (cons 'class (or (wl-frame-parameter frame 'display-type)
 259                            (when window-system
 260                              (cond ((x-display-color-p)
 261                                     'color)
 262                                    ((and (fboundp 'x-display-grayscale-p)
 263                                          (x-display-grayscale-p))
 264                                     'grayscale)
 265                                    (t 'mono)))))
 266           (cons 'background (or (wl-frame-parameter frame 'background-mode)
 267                                 wl-highlight-background-mode))))
 268
 269   (defun wl-face-spec-set-match-display (display frame)
 270     "Non-nil iff DISPLAY matches FRAME.
 271 If FRAME is nil, the current FRAME is used."
 272     ;; This is a kludge to get started, we really should use specifiers!
 273     (if (eq display t)
 274         t
 275       (let* ((props (wl-get-frame-properties frame))
 276              (type (cdr (assq 'type props)))
 277              (class (cdr (assq 'class props)))
 278              (background (cdr (assq 'background props)))
 279              (match t)
 280              (entries display)
 281              entry req options)
 282         (while (and entries match)
 283           (setq entry (car entries)
 284                 entries (cdr entries)
 285                 req (car entry)
 286                 options (cdr entry)
 287                 match (cond ((eq req 'type)
 288                              (memq type options))
 289                             ((eq req 'class)
 290                              (memq class options))
 291                             ((eq req 'background)
 292                              (memq background options))
 293                             (t
 294                              (message "\
 295 Warning: Unknown req `%S' with options `%S'" req options)
 296                              nil))))
 297         match)))))
 298
 299 (defun wl-read-event-char ()
 300   "Get the next event."
 301   (let ((event (read-event)))
 302     (cons (and (numberp event) event) event)))
 303
 304 (require 'product)
 305 (product-provide (provide 'wl-mule) (require 'wl-version))
 306
 307 ;;; wl-mule.el ends here