wl/wl-util.el

   1 ;;; wl-util.el --- Utility modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 2000 A. SAGATA <sagata@nttvdt.hil.ntt.co.jp>
   5 ;; Copyright (C) 2000 Katsumi Yamaoka <yamaoka@jpl.org>
   6
   7 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   8 ;;      A. SAGATA <sagata@nttvdt.hil.ntt.co.jp>
   9 ;;      Katsumi Yamaoka <yamaoka@jpl.org>
  10 ;; Keywords: mail, net news
  11
  12 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
  13
  14 ;; This program is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18 ;;
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23 ;;
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  27 ;; Boston, MA 02111-1307, USA.
  28 ;;
  29
  30 ;;; Commentary:
  31 ;;
  32
  33 ;;; Code:
  34 ;;
  35 (require 'bytecomp)
  36 (eval-when-compile
  37   (require 'elmo-util))
  38
  39 (condition-case nil (require 'pp) (error nil))
  40
  41 (eval-when-compile
  42   (require 'time-stamp)
  43   (defalias-maybe 'next-command-event 'ignore)
  44   (defalias-maybe 'event-to-character 'ignore)
  45   (defalias-maybe 'key-press-event-p 'ignore)
  46   (defalias-maybe 'button-press-event-p 'ignore)
  47   (defalias-maybe 'set-process-kanji-code 'ignore)
  48   (defalias-maybe 'set-process-coding-system 'ignore)
  49   (defalias-maybe 'dispatch-event 'ignore))
  50
  51 (defalias 'wl-set-work-buf 'elmo-set-work-buf)
  52 (make-obsolete 'wl-set-work-buf 'elmo-set-work-buf)
  53
  54 (defmacro wl-append (val func)
  55   (list 'if val
  56       (list 'nconc val func)
  57     (list 'setq val func)))
  58
  59 (defalias 'wl-parse 'elmo-parse)
  60 (make-obsolete 'wl-parse 'elmo-parse)
  61
  62 (defun wl-delete-duplicates (list &optional all hack-addresses)
  63   "Delete duplicate equivalent strings from the LIST.
  64 If ALL is t, then if there is more than one occurrence of a string in the LIST,
  65  then all occurrences of it are removed instead of just the subsequent ones.
  66 If HACK-ADDRESSES is t, then the strings are considered to be mail addresses,
  67  and only the address part is compared (so that \"Name <foo>\" and \"foo\"
  68  would be considered to be equivalent.)"
  69   (let ((hashtable (make-vector 29 0))
  70         (new-list nil)
  71         sym-string sym)
  72     (fillarray hashtable 0)
  73     (while list
  74       (setq sym-string
  75             (if hack-addresses
  76                 (wl-address-header-extract-address (car list))
  77               (car list))
  78             sym-string (or sym-string "-unparseable-garbage-")
  79             sym (intern sym-string hashtable))
  80       (if (boundp sym)
  81           (and all (setcar (symbol-value sym) nil))
  82         (setq new-list (cons (car list) new-list))
  83         (set sym new-list))
  84       (setq list (cdr list)))
  85     (delq nil (nreverse new-list))))
  86
  87 ;; string utils.
  88 (defalias 'wl-string-member 'elmo-string-member)
  89 (defalias 'wl-string-match-member 'elmo-string-match-member)
  90 (defalias 'wl-string-delete-match 'elmo-string-delete-match)
  91 (defalias 'wl-string-match-assoc 'elmo-string-match-assoc)
  92 (defalias 'wl-string-assoc 'elmo-string-assoc)
  93 (defalias 'wl-string-rassoc 'elmo-string-rassoc)
  94
  95 (defun wl-parse-addresses (string)
  96   (if (null string)
  97       ()
  98     (elmo-set-work-buf
  99      ;;(unwind-protect
 100      (let (list start s char)
 101        (insert string)
 102        (goto-char (point-min))
 103        (skip-chars-forward "\t\f\n\r ")
 104        (setq start (point))
 105        (while (not (eobp))
 106          (skip-chars-forward "^\"\\,(")
 107          (setq char (following-char))
 108          (cond ((= char ?\\)
 109                 (forward-char 1)
 110                 (if (not (eobp))
 111                     (forward-char 1)))
 112                ((= char ?,)
 113                 (setq s (buffer-substring start (point)))
 114                 (if (or (null (string-match "^[\t\f\n\r ]+$" s))
 115                         (not (string= s "")))
 116                     (setq list (cons s list)))
 117                 (skip-chars-forward ",\t\f\n\r ")
 118                 (setq start (point)))
 119                ((= char ?\")
 120                 (re-search-forward "[^\\]\"" nil 0))
 121                ((= char ?\()
 122                 (let ((parens 1))
 123                   (forward-char 1)
 124                   (while (and (not (eobp)) (not (zerop parens)))
 125                     (re-search-forward "[()]" nil 0)
 126                     (cond ((or (eobp)
 127                                (= (char-after (- (point) 2)) ?\\)))
 128                           ((= (preceding-char) ?\()
 129                            (setq parens (1+ parens)))
 130                           (t
 131                            (setq parens (1- parens)))))))))
 132        (setq s (buffer-substring start (point)))
 133        (if (and (null (string-match "^[\t\f\n\r ]+$" s))
 134                 (not (string= s "")))
 135            (setq list (cons s list)))
 136        (nreverse list)) ; jwz: fixed order
 137      )))
 138
 139 (defun wl-append-element (list element)
 140   (if element
 141       (append list (list element))
 142     list))
 143
 144 (defmacro wl-push (v l)
 145   "Insert V at the head of the list stored in L."
 146   (list 'setq l (list 'cons v l)))
 147
 148 (defmacro wl-pop (l)
 149   "Remove the head of the list stored in L."
 150   (list 'car (list 'prog1 l (list 'setq l (list 'cdr l)))))
 151
 152 (defun wl-ask-folder (func mes-string)
 153   (let* (key keve
 154              (cmd (if (featurep 'xemacs)
 155                       (event-to-character last-command-event)
 156                     (string-to-char (format "%s" (this-command-keys))))))
 157     (message "%s" mes-string)
 158     (setq key (car (setq keve (wl-read-event-char))))
 159     (if (or (equal key ?\ )
 160             (and cmd
 161                  (equal key cmd)))
 162         (progn
 163           (message "")
 164           (funcall func))
 165       (wl-push (cdr keve) unread-command-events))))
 166
 167 (defun wl-require-update-all-folder-p (name)
 168   "Return non-nil if NAME is draft or queue folder."
 169   (or (string= name wl-draft-folder)
 170       (string= name wl-queue-folder)))
 171
 172 ;(defalias 'wl-make-hash 'elmo-make-hash)
 173 ;;(make-obsolete 'wl-make-hash 'elmo-make-hash)
 174
 175 ;;(defalias 'wl-get-hash-val 'elmo-get-hash-val)
 176 ;;(make-obsolete 'wl-get-hash-val 'elmo-get-hash-val)
 177
 178 ;;(defalias 'wl-set-hash-val 'elmo-set-hash-val)
 179 ;;(make-obsolete 'wl-set-hash-val 'elmo-set-hash-val)
 180
 181 (defsubst wl-set-string-width (width string &optional padding ignore-invalid)
 182   "Make a new string which have specified WIDTH and content of STRING.
 183 `wl-invalid-character-message' is used when invalid character is contained.
 184 If WIDTH is negative number, padding chars are added to the head and
 185 otherwise, padding chars are added to the tail of the string.
 186 The optional 3rd arg PADDING, if non-nil, specifies a padding character
 187 to add the result instead of white space.
 188 If optional 4th argument is non-nil, don't use `wl-invalid-character-message'
 189 even when invalid character is contained."
 190   (static-cond
 191    ((and (fboundp 'string-width) (fboundp 'truncate-string-to-width)
 192          (not (featurep 'xemacs)))
 193     (if (> (string-width string) (abs width))
 194         (setq string (truncate-string-to-width string (abs width))))
 195     (if (= (string-width string) (abs width))
 196         string
 197       (when (and (not ignore-invalid)
 198                  (< (abs width) (string-width string)))
 199         (setq string
 200               (truncate-string-to-width wl-invalid-character-message
 201                                         (abs width))))
 202       (let ((paddings (make-string
 203                        (max 0 (- (abs width) (string-width string)))
 204                        (or padding ?\ ))))
 205         (if (< width 0)
 206             (concat paddings string)
 207           (concat string paddings)))))
 208    (t
 209     (elmo-set-work-buf
 210      (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 211      (insert string)
 212      (when (> (current-column) (abs width))
 213        (when (> (move-to-column (abs width)) (abs width))
 214          (condition-case nil ; ignore error
 215              (backward-char 1)
 216            (error)))
 217        (setq string (buffer-substring (point-min) (point))))
 218      (if (= (current-column) (abs width))
 219          string
 220        (let ((paddings (make-string (- (abs width) (current-column))
 221                                     (or padding ?\ ))))
 222          (if (< width 0)
 223              (concat paddings string)
 224            (concat string paddings))))))))
 225
 226 (defun wl-mode-line-buffer-identification (&optional id)
 227   (let ((priorities '(biff plug title)))
 228     (let ((items (reverse wl-mode-line-display-priority-list))
 229           item)
 230       (while items
 231         (setq item (car items)
 232               items (cdr items))
 233         (unless (memq item '(biff plug))
 234           (setq item 'title))
 235         (setq priorities (cons item (delq item priorities)))))
 236     (let (priority result)
 237       (while priorities
 238         (setq priority (car priorities)
 239               priorities (cdr priorities))
 240         (cond
 241          ((eq 'biff priority)
 242           (when wl-biff-check-folder-list
 243             (setq result (append result '((wl-modeline-biff-status
 244                                            wl-modeline-biff-state-on
 245                                            wl-modeline-biff-state-off))))))
 246          ((eq 'plug priority)
 247           (when wl-show-plug-status-on-modeline
 248             (setq result (append result '((wl-modeline-plug-status
 249                                            wl-modeline-plug-state-on
 250                                            wl-modeline-plug-state-off))))))
 251          (t
 252           (setq result (append result (or id '("Wanderlust: %12b")))))))
 253       (prog1
 254           (setq mode-line-buffer-identification (if (stringp (car result))
 255                                                     result
 256                                                   (cons "" result)))
 257         (force-mode-line-update t)))))
 258
 259 (defalias 'wl-display-error 'elmo-display-error)
 260 (make-obsolete 'wl-display-error 'elmo-display-error)
 261
 262 (defun wl-get-assoc-list-value (assoc-list folder &optional match)
 263   (catch 'found
 264     (let ((alist assoc-list)
 265           value pair)
 266       (while alist
 267         (setq pair (car alist))
 268         (if (and (eq match 'function)
 269                  (functionp (car pair)))
 270             (when (funcall (car pair) folder)
 271               (throw 'found (cdr pair)))
 272           (if (string-match (car pair) folder)
 273               (cond ((eq match 'all)
 274                      (setq value (append value (list (cdr pair)))))
 275                     ((eq match 'all-list)
 276                      (setq value (append value (cdr pair))))
 277                     ((or (not match) (eq match 'function))
 278                      (throw 'found (cdr pair))))))
 279         (setq alist (cdr alist)))
 280       value)))
 281
 282 (defmacro wl-match-string (pos string)
 283   "Substring POSth matched STRING."
 284   (` (substring (, string) (match-beginning (, pos)) (match-end (, pos)))))
 285
 286 (defmacro wl-match-buffer (pos)
 287   "Substring POSth matched from the current buffer."
 288   (` (buffer-substring-no-properties
 289       (match-beginning (, pos)) (match-end (, pos)))))
 290
 291 (put 'wl-as-coding-system 'lisp-indent-function 1)
 292 (put 'wl-as-mime-charset 'lisp-indent-function 1)
 293
 294 (eval-and-compile
 295   (cond
 296    (wl-on-mule3
 297     (defmacro wl-as-coding-system (coding-system &rest body)
 298       (` (let ((coding-system-for-read (, coding-system))
 299                (coding-system-for-write (, coding-system)))
 300            (,@ body)))))
 301    (wl-on-mule
 302     (defmacro wl-as-coding-system (coding-system &rest body)
 303       (` (let ((file-coding-system-for-read (, coding-system))
 304                (file-coding-system (, coding-system)))
 305            (,@ body)))))
 306    (t
 307     (defmacro wl-as-coding-system (coding-system &rest body)
 308       (` (progn (,@ body)))))))
 309
 310 (defmacro wl-as-mime-charset (mime-charset &rest body)
 311   (` (wl-as-coding-system (mime-charset-to-coding-system (, mime-charset))
 312        (,@ body))))
 313
 314 (defalias 'wl-string 'elmo-string)
 315 (make-obsolete 'wl-string 'elmo-string)
 316
 317 (if (not (fboundp 'overlays-in))
 318     (defun overlays-in (beg end)
 319       "Return a list of the overlays that overlap the region BEG ... END.
 320 Overlap means that at least one character is contained within the overlay
 321 and also contained within the specified region.
 322 Empty overlays are included in the result if they are located at BEG
 323 or between BEG and END."
 324       (let ((ovls (overlay-lists))
 325             tmp retval)
 326         (if (< end beg)
 327             (setq tmp end
 328                   end beg
 329                   beg tmp))
 330         (setq ovls (nconc (car ovls) (cdr ovls)))
 331         (while ovls
 332           (setq tmp (car ovls)
 333                 ovls (cdr ovls))
 334           (if (or (and (<= (overlay-start tmp) end)
 335                        (>= (overlay-start tmp) beg))
 336                   (and (<= (overlay-end tmp) end)
 337                        (>= (overlay-end tmp) beg)))
 338               (setq retval (cons tmp retval))))
 339         retval)))
 340
 341 (defsubst wl-repeat-string (str times)
 342   (let ((loop times)
 343         ret-val)
 344     (while (> loop 0)
 345       (setq ret-val (concat ret-val str))
 346       (setq loop (- loop 1)))
 347     ret-val))
 348
 349 (defun wl-append-assoc-list (item value alist)
 350   "make assoc list '((item1 value1-1 value1-2 ...)) (item2 value2-1 ...)))"
 351   (let ((entry (assoc item alist)))
 352     (if entry
 353         (progn
 354           (when (not (member value (cdr entry)))
 355             (nconc entry (list value)))
 356           alist)
 357       (append alist
 358               (list (list item value))))))
 359
 360 (defun wl-delete-alist (key alist)
 361   "Delete by side effect any entries specified with KEY from ALIST.
 362 Return the modified ALIST.  Key comparison is done with `assq'.
 363 Write `(setq foo (wl-delete-alist key foo))' to be sure of changing
 364 the value of `foo'."
 365   (let (entry)
 366     (while (setq entry (assq key alist))
 367       (setq alist (delq entry alist)))
 368     alist))
 369
 370 (defun wl-delete-associations (keys alist)
 371   "Delete by side effect any entries specified with KEYS from ALIST.
 372 Return the modified ALIST.  KEYS must be a list of keys for ALIST.
 373 Deletion is done with `wl-delete-alist'.
 374 Write `(setq foo (wl-delete-associations keys foo))' to be sure of
 375 changing the value of `foo'."
 376   (while keys
 377     (setq alist (wl-delete-alist (car keys) alist))
 378     (setq keys (cdr keys)))
 379   alist)
 380
 381 (defun wl-inverse-alist (keys alist)
 382   "Inverse ALIST, copying.
 383 Return an association list represents the inverse mapping of ALIST,
 384 from objects to KEYS.
 385 The objects mapped (cdrs of elements of the ALIST) are shared."
 386   (let (x y tmp result)
 387     (while keys
 388       (setq x (car keys))
 389       (setq y (cdr (assq x alist)))
 390       (if y
 391           (if (setq tmp (assoc y result))
 392               (setq result (cons (append tmp (list x))
 393                                  (delete tmp result)))
 394             (setq result (cons (list y x) result))))
 395       (setq keys (cdr keys)))
 396     result))
 397
 398 (eval-when-compile
 399   (require 'static))
 400 (static-unless (fboundp 'pp)
 401   (defvar pp-escape-newlines t)
 402   (defun pp (object &optional stream)
 403     "Output the pretty-printed representation of OBJECT, any Lisp object.
 404 Quoting characters are printed when needed to make output that `read'
 405 can handle, whenever this is possible.
 406 Output stream is STREAM, or value of `standard-output' (which see)."
 407     (princ (pp-to-string object) (or stream standard-output)))
 408
 409   (defun pp-to-string (object)
 410     "Return a string containing the pretty-printed representation of OBJECT,
 411 any Lisp object.  Quoting characters are used when needed to make output
 412 that `read' can handle, whenever this is possible."
 413     (save-excursion
 414       (set-buffer (generate-new-buffer " pp-to-string"))
 415       (unwind-protect
 416           (progn
 417             (lisp-mode-variables t)
 418             (let ((print-escape-newlines pp-escape-newlines))
 419               (prin1 object (current-buffer)))
 420             (goto-char (point-min))
 421             (while (not (eobp))
 422               (cond
 423                ((looking-at "\\s(\\|#\\s(")
 424                 (while (looking-at "\\s(\\|#\\s(")
 425                   (forward-char 1)))
 426                ((and (looking-at "\\(quote[ \t]+\\)\\([^.)]\\)")
 427                      (> (match-beginning 1) 1)
 428                      (= ?\( (char-after (1- (match-beginning 1))))
 429                      ;; Make sure this is a two-element list.
 430                      (save-excursion
 431                        (goto-char (match-beginning 2))
 432                        (forward-sexp)
 433                        ;; Avoid mucking with match-data; does this test work?
 434                        (char-equal ?\) (char-after (point)))))
 435                 ;; -1 gets the paren preceding the quote as well.
 436                 (delete-region (1- (match-beginning 1)) (match-end 1))
 437                 (insert "'")
 438                 (forward-sexp 1)
 439                 (if (looking-at "[ \t]*\)")
 440                     (delete-region (match-beginning 0) (match-end 0))
 441                   (error "Malformed quote"))
 442                 (backward-sexp 1))
 443                ((condition-case err-var
 444                     (prog1 t (down-list 1))
 445                   (error nil))
 446                 (backward-char 1)
 447                 (skip-chars-backward " \t")
 448                 (delete-region
 449                  (point)
 450                  (progn (skip-chars-forward " \t") (point)))
 451                 (if (not (char-equal ?' (char-after (1- (point)))))
 452                     (insert ?\n)))
 453                ((condition-case err-var
 454                     (prog1 t (up-list 1))
 455                   (error nil))
 456                 (while (looking-at "\\s)")
 457                   (forward-char 1))
 458                 (skip-chars-backward " \t")
 459                 (delete-region
 460                  (point)
 461                  (progn (skip-chars-forward " \t") (point)))
 462                 (if (not (char-equal ?' (char-after (1- (point)))))
 463                     (insert ?\n)))
 464                (t (goto-char (point-max)))))
 465             (goto-char (point-min))
 466             (indent-sexp)
 467             (buffer-string))
 468         (kill-buffer (current-buffer))))))
 469
 470 (defsubst wl-get-date-iso8601 (date)
 471   (or (get-text-property 0 'wl-date date)
 472       (let* ((d1 (timezone-fix-time date nil nil))
 473              (time (format "%04d%02d%02dT%02d%02d%02d"
 474                            (aref d1 0) (aref d1 1) (aref d1 2)
 475                            (aref d1 3) (aref d1 4) (aref d1 5))))
 476         (put-text-property 0 1 'wl-date time date)
 477         time)))
 478
 479 (defun wl-make-date-string ()
 480   (let ((s (current-time-string)))
 481     (string-match "\\`\\([A-Z][a-z][a-z]\\) +[A-Z][a-z][a-z] +[0-9][0-9]? *[0-9][0-9]?:[0-9][0-9]:[0-9][0-9] *[0-9]?[0-9]?[0-9][0-9]"
 482                   s)
 483     (concat (wl-match-string 1 s) ", "
 484             (timezone-make-date-arpa-standard s (current-time-zone)))))
 485
 486 (defun wl-date-iso8601 (date)
 487   "Convert the DATE to YYMMDDTHHMMSS."
 488   (condition-case ()
 489       (wl-get-date-iso8601 date)
 490     (error "")))
 491
 492 (defun wl-day-number (date)
 493   (let ((dat (mapcar '(lambda (s) (and s (string-to-int s)) )
 494                      (timezone-parse-date date))))
 495     (timezone-absolute-from-gregorian
 496      (nth 1 dat) (nth 2 dat) (car dat))))
 497
 498 (defun wl-url-news (url &rest args)
 499   (interactive "sURL: ")
 500   (if (string-match "^news:\\(.*\\)$" url)
 501       (wl-summary-goto-folder-subr
 502        (concat "-" (elmo-match-string 1 url)) nil nil nil t)
 503     (message "Not a news: url.")))
 504
 505 (defun wl-url-nntp (url &rest args)
 506   (interactive "sURL: ")
 507   (let (folder fld-name server port msg)
 508     (if (string-match
 509          "^nntp://\\([^:/]*\\):?\\([0-9]*\\)/\\([^/]*\\)/\\([0-9]*\\).*$" url)
 510         (progn
 511           (if (eq (length (setq fld-name
 512                                 (elmo-match-string 3 url))) 0)
 513               (setq fld-name nil))
 514           (if (eq (length (setq port
 515                                 (elmo-match-string 2 url))) 0)
 516               (setq port (int-to-string elmo-nntp-default-port)))
 517           (if (eq (length (setq server
 518                                 (elmo-match-string 1 url))) 0)
 519               (setq server elmo-nntp-default-server))
 520           (setq folder (concat "-" fld-name "@" server ":" port))
 521           (if (eq (length (setq msg
 522                                 (elmo-match-string 4 url))) 0)
 523               (wl-summary-goto-folder-subr
 524                folder nil nil nil t)
 525             (wl-summary-goto-folder-subr
 526              folder 'update nil nil t)
 527             (wl-summary-jump-to-msg (string-to-number msg))
 528             (wl-summary-redisplay)))
 529       (message "Not a nntp: url."))))
 530
 531 (defmacro wl-concat-list (list separator)
 532   (` (mapconcat 'identity (delete "" (delq nil (, list))) (, separator))))
 533
 534 (defun wl-current-message-buffer ()
 535   (when (buffer-live-p wl-current-summary-buffer)
 536     (with-current-buffer wl-current-summary-buffer
 537       (or wl-message-buffer
 538           (and (wl-summary-message-number)
 539                (car (wl-message-buffer-display wl-summary-buffer-elmo-folder
 540                                                (wl-summary-message-number)
 541                                                'mime)))))))
 542
 543 (defmacro wl-kill-buffers (regexp)
 544   (` (mapcar (function
 545               (lambda (x)
 546                 (if (and (buffer-name x)
 547                          (string-match (, regexp) (buffer-name x)))
 548                     (and (get-buffer x)
 549                          (kill-buffer x)))))
 550              (buffer-list))))
 551
 552 (defun wl-collect-summary ()
 553   (let (result)
 554     (mapcar
 555      (function (lambda (x)
 556                  (if (and (string-match "^Summary"
 557                                         (buffer-name x))
 558                           (save-excursion
 559                             (set-buffer x)
 560                             (equal major-mode 'wl-summary-mode)))
 561                      (setq result (nconc result (list x))))))
 562      (buffer-list))
 563     result))
 564
 565 (defun wl-collect-draft ()
 566   (let ((draft-regexp (concat
 567                        "^" (regexp-quote wl-draft-folder)))
 568         result buf)
 569     (mapcar
 570      (function (lambda (x)
 571                  (if (with-current-buffer x
 572                        (and (eq major-mode 'wl-draft-mode)
 573                             (buffer-name)
 574                             (string-match draft-regexp (buffer-name))))
 575                      (setq result (nconc result (list x))))))
 576      (buffer-list))
 577     result))
 578
 579 (static-if (fboundp 'read-directory-name)
 580     (defun wl-read-directory-name (prompt dir)
 581       (read-directory-name prompt dir dir))
 582   (defun wl-read-directory-name (prompt dir)
 583     (let ((dir (read-file-name prompt dir)))
 584       (unless (file-directory-p dir)
 585         (error "%s is not directory" dir))
 586       dir)))
 587
 588 ;; local variable check.
 589 (static-if (fboundp 'local-variable-p)
 590     (defalias 'wl-local-variable-p 'local-variable-p)
 591   (defmacro wl-local-variable-p (symbol &optional buffer)
 592     (` (if (assq (, symbol) (buffer-local-variables (, buffer)))
 593            t))))
 594
 595 (defun wl-number-base36 (num len)
 596   (if (if (< len 0)
 597           (<= num 0)
 598         (= len 0))
 599       ""
 600     (concat (wl-number-base36 (/ num 36) (1- len))
 601             (char-to-string (aref "zyxwvutsrqponmlkjihgfedcba9876543210"
 602                                   (% num 36))))))
 603
 604 (defvar wl-unique-id-char nil)
 605
 606 (defun wl-unique-id ()
 607   ;; Don't use microseconds from (current-time), they may be unsupported.
 608   ;; Instead we use this randomly inited counter.
 609   (setq wl-unique-id-char
 610         (% (1+ (or wl-unique-id-char (logand (random t) (1- (lsh 1 20)))))
 611            ;; (current-time) returns 16-bit ints,
 612            ;; and 2^16*25 just fits into 4 digits i base 36.
 613            (* 25 25)))
 614   (let ((tm (static-if (fboundp 'current-time)
 615                 (current-time)
 616               (let* ((cts (split-string (current-time-string) "[ :]"))
 617                      (m (cdr (assoc (nth 1 cts)
 618                                     '(("Jan" . "01") ("Feb" . "02")
 619                                       ("Mar" . "03") ("Apr" . "04")
 620                                       ("May" . "05") ("Jun" . "06")
 621                                       ("Jul" . "07") ("Aug" . "08")
 622                                       ("Sep" . "09") ("Oct" . "10")
 623                                       ("Nov" . "11") ("Dec" . "12"))))))
 624                 (list (string-to-int (concat (nth 6 cts) m
 625                                              (substring (nth 2 cts) 0 1)))
 626                       (string-to-int (concat (substring (nth 2 cts) 1)
 627                                              (nth 4 cts) (nth 5 cts)
 628                                              (nth 6 cts))))))))
 629     (concat
 630      (if (memq system-type '(ms-dos emx vax-vms))
 631          (let ((user (downcase (user-login-name))))
 632            (while (string-match "[^a-z0-9_]" user)
 633              (aset user (match-beginning 0) ?_))
 634            user)
 635        (wl-number-base36 (user-uid) -1))
 636      (wl-number-base36 (+ (car   tm)
 637                           (lsh (% wl-unique-id-char 25) 16)) 4)
 638      (wl-number-base36 (+ (nth 1 tm)
 639                           (lsh (/ wl-unique-id-char 25) 16)) 4)
 640      ;; Append the name of the message interface, because while the
 641      ;; generated ID is unique to this newsreader, other newsreaders
 642      ;; might otherwise generate the same ID via another algorithm.
 643      wl-unique-id-suffix)))
 644
 645 (defvar wl-message-id-function 'wl-draft-make-message-id-string)
 646 (defun wl-draft-make-message-id-string ()
 647   "Return Message-ID field value."
 648   (concat "<" (wl-unique-id)
 649           (let (from user domain)
 650             (if (and wl-message-id-use-wl-from
 651                      (progn
 652                        (setq from (wl-address-header-extract-address wl-from))
 653                        (and (string-match "^\\(.*\\)@\\(.*\\)$" from)
 654                             (setq user   (match-string 1 from))
 655                             (setq domain (match-string 2 from)))))
 656                 (format "%%%s@%s>" user domain)
 657               (format "@%s>"
 658                       (or wl-message-id-domain
 659                           (if wl-local-domain
 660                               (concat (system-name) "." wl-local-domain)
 661                             (system-name))))))))
 662
 663 ;;; Profile loading.
 664 (defvar wl-load-profile-function 'wl-local-load-profile)
 665 (defun wl-local-load-profile ()
 666   "Load `wl-init-file'."
 667   (message "Initializing...")
 668   (load wl-init-file 'noerror 'nomessage))
 669
 670 (defun wl-load-profile ()
 671   "Call `wl-load-profile-function' function."
 672   (funcall wl-load-profile-function))
 673
 674 ;;;
 675
 676 (defmacro wl-count-lines ()
 677   (` (save-excursion
 678        (beginning-of-line)
 679        (count-lines 1 (point)))))
 680
 681 (defun wl-horizontal-recenter ()
 682   "Recenter the current buffer horizontally."
 683   (beginning-of-line)
 684   (re-search-forward "[[<]" (point-at-eol) t)
 685   (if (< (current-column) (/ (window-width) 2))
 686       (set-window-hscroll (get-buffer-window (current-buffer) t) 0)
 687     (let* ((orig (point))
 688            (end (window-end (get-buffer-window (current-buffer) t)))
 689            (max 0))
 690       (when end
 691         ;; Find the longest line currently displayed in the window.
 692         (goto-char (window-start))
 693         (while (and (not (eobp))
 694                     (< (point) end))
 695           (end-of-line)
 696           (setq max (max max (current-column)))
 697           (forward-line 1))
 698         (goto-char orig)
 699         ;; Scroll horizontally to center (sort of) the point.
 700         (if (> max (window-width))
 701             (set-window-hscroll
 702              (get-buffer-window (current-buffer) t)
 703              (min (- (current-column) (/ (window-width) 3))
 704                   (+ 2 (- max (window-width)))))
 705           (set-window-hscroll (get-buffer-window (current-buffer) t) 0))
 706         max))))
 707
 708 ;; Biff
 709 (static-cond
 710  (wl-on-xemacs
 711   (defvar wl-biff-timer-name "wl-biff")
 712
 713   (defun wl-biff-stop ()
 714     (when (get-itimer wl-biff-timer-name)
 715       (delete-itimer wl-biff-timer-name)))
 716
 717   (defun wl-biff-start ()
 718     (wl-biff-stop)
 719     (when wl-biff-check-folder-list
 720       (wl-biff-check-folders)
 721       (start-itimer wl-biff-timer-name 'wl-biff-check-folders
 722                     wl-biff-check-interval wl-biff-check-interval))))
 723
 724  ((and (condition-case nil (require 'timer) (error nil));; FSFmacs 19+
 725        (fboundp 'timer-activate))
 726
 727   (defun wl-biff-stop ()
 728     (when (get 'wl-biff 'timer)
 729       (cancel-timer (get 'wl-biff 'timer))))
 730
 731   (defun wl-biff-start ()
 732     (require 'timer)
 733     (when wl-biff-check-folder-list
 734       (wl-biff-check-folders)
 735       (if (get 'wl-biff 'timer)
 736           (timer-activate (get 'wl-biff 'timer))
 737         (put 'wl-biff 'timer (run-at-time
 738                               (timer-next-integral-multiple-of-time
 739                                (current-time) wl-biff-check-interval)
 740                               wl-biff-check-interval
 741                               'wl-biff-event-handler)))))
 742
 743   (defun-maybe timer-next-integral-multiple-of-time (time secs)
 744     "Yield the next value after TIME that is an integral multiple of SECS.
 745 More precisely, the next value, after TIME, that is an integral multiple
 746 of SECS seconds since the epoch.  SECS may be a fraction.
 747 This function is imported from Emacs 20.7."
 748     (let ((time-base (ash 1 16)))
 749       (if (fboundp 'atan)
 750           ;; Use floating point, taking care to not lose precision.
 751           (let* ((float-time-base (float time-base))
 752                  (million 1000000.0)
 753                  (time-usec (+ (* million
 754                                   (+ (* float-time-base (nth 0 time))
 755                                      (nth 1 time)))
 756                                (nth 2 time)))
 757                  (secs-usec (* million secs))
 758                  (mod-usec (mod time-usec secs-usec))
 759                  (next-usec (+ (- time-usec mod-usec) secs-usec))
 760                  (time-base-million (* float-time-base million)))
 761             (list (floor next-usec time-base-million)
 762                   (floor (mod next-usec time-base-million) million)
 763                   (floor (mod next-usec million))))
 764         ;; Floating point is not supported.
 765         ;; Use integer arithmetic, avoiding overflow if possible.
 766         (let* ((mod-sec (mod (+ (* (mod time-base secs)
 767                                    (mod (nth 0 time) secs))
 768                                 (nth 1 time))
 769                              secs))
 770                (next-1-sec (+ (- (nth 1 time) mod-sec) secs)))
 771           (list (+ (nth 0 time) (floor next-1-sec time-base))
 772                 (mod next-1-sec time-base)
 773                 0)))))
 774
 775   (defun wl-biff-event-handler ()
 776     ;; PAKURing from FSF:time.el
 777     (wl-biff-check-folders)
 778     ;; Do redisplay right now, if no input pending.
 779     (sit-for 0)
 780     (let* ((current (current-time))
 781            (timer (get 'wl-biff 'timer))
 782            ;; Compute the time when this timer will run again, next.
 783            (next-time (timer-relative-time
 784                        (list (aref timer 1) (aref timer 2) (aref timer 3))
 785                        (* 5 (aref timer 4)) 0)))
 786       ;; If the activation time is far in the past,
 787       ;; skip executions until we reach a time in the future.
 788       ;; This avoids a long pause if Emacs has been suspended for hours.
 789       (or (> (nth 0 next-time) (nth 0 current))
 790           (and (= (nth 0 next-time) (nth 0 current))
 791                (> (nth 1 next-time) (nth 1 current)))
 792           (and (= (nth 0 next-time) (nth 0 current))
 793                (= (nth 1 next-time) (nth 1 current))
 794                (> (nth 2 next-time) (nth 2 current)))
 795           (progn
 796             (timer-set-time timer (timer-next-integral-multiple-of-time
 797                                    current wl-biff-check-interval)
 798                             wl-biff-check-interval)
 799             (timer-activate timer))))))
 800  (t
 801   (fset 'wl-biff-stop 'ignore)
 802   (fset 'wl-biff-start 'ignore)))
 803
 804 (defsubst wl-biff-notify (new-mails notify-minibuf)
 805   (when (and (not wl-modeline-biff-status) (> new-mails 0))
 806     (run-hooks 'wl-biff-notify-hook))
 807   (when (and wl-modeline-biff-status (eq new-mails 0))
 808     (run-hooks 'wl-biff-unnotify-hook))
 809   (setq wl-modeline-biff-status (> new-mails 0))
 810   (force-mode-line-update t)
 811   (when notify-minibuf
 812     (cond ((zerop new-mails) (message "No mail."))
 813           ((= 1 new-mails) (message "You have a new mail."))
 814           (t (message "You have %d new mails." new-mails)))))
 815
 816 ;; Internal variable.
 817 (defvar wl-biff-check-folders-running nil)
 818
 819 (defun wl-biff-check-folders ()
 820   (interactive)
 821   (if wl-biff-check-folders-running
 822       (when (interactive-p)
 823         (message "Biff process is running."))
 824     (setq wl-biff-check-folders-running t)
 825     (when (interactive-p)
 826       (message "Checking new mails..."))
 827     (let ((new-mails 0)
 828           (flist (or wl-biff-check-folder-list (list wl-default-folder)))
 829           folder)
 830       (if (eq (length flist) 1)
 831           (wl-biff-check-folder-async (wl-folder-get-elmo-folder
 832                                        (car flist) 'biff) (interactive-p))
 833         (unwind-protect
 834             (while flist
 835               (setq folder (wl-folder-get-elmo-folder (car flist))
 836                     flist (cdr flist))
 837               (when (elmo-folder-plugged-p folder)
 838                 (setq new-mails
 839                       (+ new-mails
 840                          (nth 0 (wl-biff-check-folder folder))))))
 841           (setq wl-biff-check-folders-running nil)
 842           (wl-biff-notify new-mails (interactive-p)))))))
 843
 844 (defun wl-biff-check-folder (folder)
 845   (if (eq (elmo-folder-type-internal folder) 'pop3)
 846       (unless (elmo-pop3-get-session folder 'any-exists)
 847         (wl-folder-check-one-entity (elmo-folder-name-internal folder)
 848                                     'biff))
 849     (wl-folder-check-one-entity (elmo-folder-name-internal folder)
 850                                 'biff)))
 851
 852 (defun wl-biff-check-folder-async-callback (diff data)
 853   (if (nth 1 data)
 854       (with-current-buffer (nth 1 data)
 855         (wl-folder-entity-hashtb-set wl-folder-entity-hashtb
 856                                      (nth 0 data)
 857                                      (list (nth 0 diff)
 858                                            (- (nth 1 diff) (nth 0 diff))
 859                                            (nth 2 diff))
 860                                      (current-buffer))))
 861   (setq wl-folder-info-alist-modified t)
 862   (setq wl-biff-check-folders-running nil)
 863   (sit-for 0)
 864   (wl-biff-notify (car diff) (nth 2 data)))
 865
 866 (defun wl-biff-check-folder-async (folder notify-minibuf)
 867   (when (elmo-folder-plugged-p folder)
 868     (elmo-folder-set-biff-internal folder t)
 869     (if (and (eq (elmo-folder-type-internal folder) 'imap4)
 870              (elmo-folder-use-flag-p folder))
 871         ;; Check asynchronously only when IMAP4 and use server diff.
 872         (progn
 873           (setq elmo-folder-diff-async-callback
 874                 'wl-biff-check-folder-async-callback)
 875           (setq elmo-folder-diff-async-callback-data
 876                 (list (elmo-folder-name-internal folder)
 877                       (get-buffer wl-folder-buffer-name)
 878                       notify-minibuf))
 879           (elmo-folder-diff-async folder))
 880       (unwind-protect
 881           (wl-biff-notify (car (wl-biff-check-folder folder))
 882                           notify-minibuf)
 883         (setq wl-biff-check-folders-running nil)))))
 884
 885 (if (and (fboundp 'regexp-opt)
 886          (not (featurep 'xemacs)))
 887     (defalias 'wl-regexp-opt 'regexp-opt)
 888   (defun wl-regexp-opt (strings &optional paren)
 889     "Return a regexp to match a string in STRINGS.
 890 Each string should be unique in STRINGS and should not contain any regexps,
 891 quoted or not.  If optional PAREN is non-nil, ensure that the returned regexp
 892 is enclosed by at least one regexp grouping construct."
 893     (let ((open-paren (if paren "\\(" "")) (close-paren (if paren "\\)" "")))
 894       (concat open-paren (mapconcat 'regexp-quote strings "\\|")
 895               close-paren))))
 896
 897 (defalias 'wl-expand-newtext 'elmo-expand-newtext)
 898 (defalias 'wl-regexp-opt 'elmo-regexp-opt)
 899
 900 (defun wl-region-exists-p ()
 901   "Return non-nil if a region exists on current buffer."
 902   (static-if (featurep 'xemacs)
 903       (region-active-p)
 904     (and transient-mark-mode mark-active)))
 905
 906 (defun wl-deactivate-region ()
 907   "Deactivate region on current buffer"
 908   (static-if (not (featurep 'xemacs))
 909       (setq mark-active nil)))
 910
 911 (defvar wl-line-string)
 912 (defun wl-line-parse-format (format spec-alist)
 913   "Make a formatter from FORMAT and SPEC-ALIST."
 914   (let (f spec specs stack)
 915     (setq f
 916           (with-temp-buffer
 917             (insert format)
 918             (goto-char (point-min))
 919             (while (search-forward "%" nil t)
 920               (cond
 921                ((looking-at "%")
 922                 (goto-char (match-end 0)))
 923                ((looking-at "\\(-?\\(0?\\)[0-9]*\\)\\([^0-9]\\)")
 924                 (cond
 925                  ((string= (match-string 3) "(")
 926                   (if (zerop (length (match-string 1)))
 927                       (error "No number specification for %%( line format"))
 928                   (push (list
 929                          (match-beginning 0) ; start
 930                          (match-end 0)       ; start-content
 931                          (string-to-number
 932                           (match-string 1))  ; width
 933                          specs) ; specs
 934                         stack)
 935                   (setq specs nil))
 936                  ((string= (match-string 3) ")")
 937                   (let ((entry (pop stack))
 938                         form)
 939                     (unless entry
 940                       (error
 941                        "No matching %%( parenthesis in summary line format"))
 942                     (goto-char (car entry)) ; start
 943                     (setq form (buffer-substring (nth 1 entry) ; start-content
 944                                                  (- (match-beginning 0) 1)))
 945                     (delete-region (car entry) (match-end 0))
 946                     (insert "s")
 947                     (setq specs
 948                           (append
 949                            (nth 3 entry)
 950                            (list (list 'wl-set-string-width (nth 2 entry)
 951                                        (append
 952                                         (list 'format form)
 953                                         specs)))))))
 954                  (t
 955                   (setq spec
 956                         (if (setq spec (assq (string-to-char (match-string 3))
 957                                              spec-alist))
 958                             (nth 1 spec)
 959                           (match-string 3)))
 960                   (unless (string= "" (match-string 1))
 961                     (setq spec (list 'wl-set-string-width
 962                                      (string-to-number (match-string 1))
 963                                      spec
 964                                      (unless (string= "" (match-string 2))
 965                                        (string-to-char (match-string 2))))))
 966                   (replace-match "s" 'fixed)
 967                   (setq specs (append specs
 968                                       (list
 969                                        (list
 970                                         'setq 'wl-line-string
 971                                         spec)))))))))
 972             (buffer-string)))
 973     (append (list 'format f) specs)))
 974
 975 (defmacro wl-line-formatter-setup (formatter format alist)
 976   (` (let (byte-compile-warnings)
 977        (setq (, formatter)
 978              (byte-compile
 979               (list 'lambda ()
 980                     (wl-line-parse-format (, format) (, alist)))))
 981        (when (get-buffer "*Compile-Log*")
 982          (bury-buffer "*Compile-Log*"))
 983        (when (get-buffer "*Compile-Log-Show*")
 984          (bury-buffer "*Compile-Log-Show*")))))
 985
 986 (defsubst wl-copy-local-variables (src dst local-variables)
 987   "Copy value of LOCAL-VARIABLES from SRC buffer to DST buffer."
 988   (with-current-buffer dst
 989     (dolist (variable local-variables)
 990       (set (make-local-variable variable)
 991            (with-current-buffer src
 992              (symbol-value variable))))))
 993
 994 (require 'product)
 995 (product-provide (provide 'wl-util) (require 'wl-version))
 996
 997 ;;; wl-util.el ends here