wl/wl-util.el

   1 ;;; wl-util.el --- Utility modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 2000 A. SAGATA <sagata@nttvdt.hil.ntt.co.jp>
   5 ;; Copyright (C) 2000 Katsumi Yamaoka <yamaoka@jpl.org>
   6
   7 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   8 ;;      A. SAGATA <sagata@nttvdt.hil.ntt.co.jp>
   9 ;;      Katsumi Yamaoka <yamaoka@jpl.org>
  10 ;; Keywords: mail, net news
  11
  12 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
  13
  14 ;; This program is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18 ;;
  19 ;; This program is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23 ;;
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  27 ;; Boston, MA 02111-1307, USA.
  28 ;;
  29
  30 ;;; Commentary:
  31 ;;
  32
  33 ;;; Code:
  34 ;;
  35 (require 'bytecomp)
  36 (eval-when-compile
  37   (require 'elmo-util))
  38
  39 (condition-case nil (require 'pp) (error nil))
  40
  41 (eval-when-compile
  42   (require 'time-stamp)
  43   (defalias-maybe 'next-command-event 'ignore)
  44   (defalias-maybe 'event-to-character 'ignore)
  45   (defalias-maybe 'key-press-event-p 'ignore)
  46   (defalias-maybe 'button-press-event-p 'ignore)
  47   (defalias-maybe 'set-process-kanji-code 'ignore)
  48   (defalias-maybe 'set-process-coding-system 'ignore)
  49   (defalias-maybe 'dispatch-event 'ignore))
  50
  51 (defalias 'wl-set-work-buf 'elmo-set-work-buf)
  52 (make-obsolete 'wl-set-work-buf 'elmo-set-work-buf)
  53
  54 (defmacro wl-append (val func)
  55   (list 'if val
  56       (list 'nconc val func)
  57     (list 'setq val func)))
  58
  59 (defalias 'wl-parse 'elmo-parse)
  60 (make-obsolete 'wl-parse 'elmo-parse)
  61
  62 (defun wl-delete-duplicates (list &optional all hack-addresses)
  63   "Delete duplicate equivalent strings from the LIST.
  64 If ALL is t, then if there is more than one occurrence of a string in the LIST,
  65  then all occurrences of it are removed instead of just the subsequent ones.
  66 If HACK-ADDRESSES is t, then the strings are considered to be mail addresses,
  67  and only the address part is compared (so that \"Name <foo>\" and \"foo\"
  68  would be considered to be equivalent.)"
  69   (let ((hashtable (make-vector 29 0))
  70         (new-list nil)
  71         sym-string sym)
  72     (fillarray hashtable 0)
  73     (while list
  74       (setq sym-string
  75             (if hack-addresses
  76                 (wl-address-header-extract-address (car list))
  77               (car list))
  78             sym-string (or sym-string "-unparseable-garbage-")
  79             sym (intern sym-string hashtable))
  80       (if (boundp sym)
  81           (and all (setcar (symbol-value sym) nil))
  82         (setq new-list (cons (car list) new-list))
  83         (set sym new-list))
  84       (setq list (cdr list)))
  85     (delq nil (nreverse new-list))))
  86
  87 ;; string utils.
  88 (defalias 'wl-string-member 'elmo-string-member)
  89 (defalias 'wl-string-match-member 'elmo-string-match-member)
  90 (defalias 'wl-string-delete-match 'elmo-string-delete-match)
  91 (defalias 'wl-string-match-assoc 'elmo-string-match-assoc)
  92 (defalias 'wl-string-assoc 'elmo-string-assoc)
  93 (defalias 'wl-string-rassoc 'elmo-string-rassoc)
  94
  95 (defun wl-parse-addresses (string)
  96   (if (null string)
  97       ()
  98     (elmo-set-work-buf
  99      ;;(unwind-protect
 100      (let (list start s char)
 101        (insert string)
 102        (goto-char (point-min))
 103        (skip-chars-forward "\t\f\n\r ")
 104        (setq start (point))
 105        (while (not (eobp))
 106          (skip-chars-forward "^\"\\,(")
 107          (setq char (following-char))
 108          (cond ((= char ?\\)
 109                 (forward-char 1)
 110                 (if (not (eobp))
 111                     (forward-char 1)))
 112                ((= char ?,)
 113                 (setq s (buffer-substring start (point)))
 114                 (if (or (null (string-match "^[\t\f\n\r ]+$" s))
 115                         (not (string= s "")))
 116                     (setq list (cons s list)))
 117                 (skip-chars-forward ",\t\f\n\r ")
 118                 (setq start (point)))
 119                ((= char ?\")
 120                 (re-search-forward "[^\\]\"" nil 0))
 121                ((= char ?\()
 122                 (let ((parens 1))
 123                   (forward-char 1)
 124                   (while (and (not (eobp)) (not (zerop parens)))
 125                     (re-search-forward "[()]" nil 0)
 126                     (cond ((or (eobp)
 127                                (= (char-after (- (point) 2)) ?\\)))
 128                           ((= (preceding-char) ?\()
 129                            (setq parens (1+ parens)))
 130                           (t
 131                            (setq parens (1- parens)))))))))
 132        (setq s (buffer-substring start (point)))
 133        (if (and (null (string-match "^[\t\f\n\r ]+$" s))
 134                 (not (string= s "")))
 135            (setq list (cons s list)))
 136        (nreverse list)) ; jwz: fixed order
 137      )))
 138
 139 (defun wl-append-element (list element)
 140   (if element
 141       (append list (list element))
 142     list))
 143
 144 (defmacro wl-push (v l)
 145   "Insert V at the head of the list stored in L."
 146   (list 'setq l (list 'cons v l)))
 147
 148 (defmacro wl-pop (l)
 149   "Remove the head of the list stored in L."
 150   (list 'car (list 'prog1 l (list 'setq l (list 'cdr l)))))
 151
 152 (defun wl-ask-folder (func mes-string)
 153   (let* (key keve
 154              (cmd (if (featurep 'xemacs)
 155                       (event-to-character last-command-event)
 156                     (string-to-char (format "%s" (this-command-keys))))))
 157     (message mes-string)
 158     (setq key (car (setq keve (wl-read-event-char))))
 159     (if (or (equal key ?\ )
 160             (and cmd
 161                  (equal key cmd)))
 162         (progn
 163           (message "")
 164           (funcall func))
 165       (wl-push (cdr keve) unread-command-events))))
 166
 167 ;(defalias 'wl-make-hash 'elmo-make-hash)
 168 ;;(make-obsolete 'wl-make-hash 'elmo-make-hash)
 169
 170 ;;(defalias 'wl-get-hash-val 'elmo-get-hash-val)
 171 ;;(make-obsolete 'wl-get-hash-val 'elmo-get-hash-val)
 172
 173 ;;(defalias 'wl-set-hash-val 'elmo-set-hash-val)
 174 ;;(make-obsolete 'wl-set-hash-val 'elmo-set-hash-val)
 175
 176 (defsubst wl-set-string-width (width string &optional padding)
 177   "Make a new string which have specified WIDTH and content of STRING.
 178 If WIDTH is negative number, padding chars are added to the head and
 179 otherwise, padding chars are added to the tail of the string.
 180 The optional 3rd arg PADDING, if non-nil, specifies a padding character
 181 to add the result instead of white space."
 182   (static-cond
 183    ((and (fboundp 'string-width) (fboundp 'truncate-string-to-width)
 184          (not (featurep 'xemacs)))
 185     (if (> (string-width string) (abs width))
 186         (setq string (truncate-string-to-width string (abs width))))
 187     (if (= (string-width string) (abs width))
 188         string
 189       (let ((paddings (make-string (- (abs width) (string-width string))
 190                                    (or padding ?\ ))))
 191         (if (< width 0)
 192             (concat paddings string)
 193           (concat string paddings)))))
 194    (t
 195     (elmo-set-work-buf
 196      (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 197      (insert string)
 198      (when (> (current-column) (abs width))
 199        (when (> (move-to-column (abs width)) (abs width))
 200          (condition-case nil ; ignore error
 201              (backward-char 1)
 202            (error)))
 203        (setq string (buffer-substring (point-min) (point))))
 204      (if (= (current-column) (abs width))
 205          string
 206        (let ((paddings (make-string (- (abs width) (current-column))
 207                                     (or padding ?\ ))))
 208          (if (< width 0)
 209              (concat paddings string)
 210            (concat string paddings))))))))
 211
 212 (defun wl-mode-line-buffer-identification (&optional id)
 213   (let ((priorities '(biff plug title)))
 214     (let ((items (reverse wl-mode-line-display-priority-list))
 215           item)
 216       (while items
 217         (setq item (car items)
 218               items (cdr items))
 219         (unless (memq item '(biff plug))
 220           (setq item 'title))
 221         (setq priorities (cons item (delq item priorities)))))
 222     (let (priority result)
 223       (while priorities
 224         (setq priority (car priorities)
 225               priorities (cdr priorities))
 226         (cond
 227          ((eq 'biff priority)
 228           (when wl-biff-check-folder-list
 229             (setq result (append result '((wl-modeline-biff-status
 230                                            wl-modeline-biff-state-on
 231                                            wl-modeline-biff-state-off))))))
 232          ((eq 'plug priority)
 233           (when wl-show-plug-status-on-modeline
 234             (setq result (append result '((wl-modeline-plug-status
 235                                            wl-modeline-plug-state-on
 236                                            wl-modeline-plug-state-off))))))
 237          (t
 238           (setq result (append result (or id '("Wanderlust: %12b")))))))
 239       (prog1
 240           (setq mode-line-buffer-identification (if (stringp (car result))
 241                                                     result
 242                                                   (cons "" result)))
 243         (force-mode-line-update t)))))
 244
 245 (defalias 'wl-display-error 'elmo-display-error)
 246 (make-obsolete 'wl-display-error 'elmo-display-error)
 247
 248 (defun wl-get-assoc-list-value (assoc-list folder &optional match)
 249   (catch 'found
 250     (let ((alist assoc-list)
 251           value pair)
 252       (while alist
 253         (setq pair (car alist))
 254         (if (string-match (car pair) folder)
 255             (cond ((eq match 'all)
 256                    (setq value (append value (list (cdr pair)))))
 257                   ((eq match 'all-list)
 258                    (setq value (append value (cdr pair))))
 259                   ((not match)
 260                    (throw 'found (cdr pair)))))
 261         (setq alist (cdr alist)))
 262       value)))
 263
 264 (defmacro wl-match-string (pos string)
 265   "Substring POSth matched STRING."
 266   (` (substring (, string) (match-beginning (, pos)) (match-end (, pos)))))
 267
 268 (defmacro wl-match-buffer (pos)
 269   "Substring POSth matched from the current buffer."
 270   (` (buffer-substring-no-properties
 271       (match-beginning (, pos)) (match-end (, pos)))))
 272
 273 (put 'wl-as-coding-system 'lisp-indent-function 1)
 274 (put 'wl-as-mime-charset 'lisp-indent-function 1)
 275
 276 (eval-and-compile
 277   (if wl-on-mule3
 278       (defmacro wl-as-coding-system (coding-system &rest body)
 279         (` (let ((coding-system-for-read (, coding-system))
 280                  (coding-system-for-write (, coding-system)))
 281              (,@ body))))
 282     (if wl-on-mule
 283         (defmacro wl-as-coding-system (coding-system &rest body)
 284           (` (let ((file-coding-system-for-read (, coding-system))
 285                    (file-coding-system (, coding-system)))
 286                (,@ body)))))))
 287
 288 (defmacro wl-as-mime-charset (mime-charset &rest body)
 289   (` (wl-as-coding-system (mime-charset-to-coding-system (, mime-charset))
 290        (,@ body))))
 291
 292 (defalias 'wl-string 'elmo-string)
 293 (make-obsolete 'wl-string 'elmo-string)
 294
 295 ;; Check if active region exists or not.
 296 (if (boundp 'mark-active)
 297     (defmacro wl-region-exists-p ()
 298       'mark-active)
 299   (if (fboundp 'region-exists-p)
 300       (defmacro wl-region-exists-p ()
 301         (list 'region-exists-p))))
 302
 303 (if (not (fboundp 'overlays-in))
 304     (defun overlays-in (beg end)
 305       "Return a list of the overlays that overlap the region BEG ... END.
 306 Overlap means that at least one character is contained within the overlay
 307 and also contained within the specified region.
 308 Empty overlays are included in the result if they are located at BEG
 309 or between BEG and END."
 310       (let ((ovls (overlay-lists))
 311             tmp retval)
 312         (if (< end beg)
 313             (setq tmp end
 314                   end beg
 315                   beg tmp))
 316         (setq ovls (nconc (car ovls) (cdr ovls)))
 317         (while ovls
 318           (setq tmp (car ovls)
 319                 ovls (cdr ovls))
 320           (if (or (and (<= (overlay-start tmp) end)
 321                        (>= (overlay-start tmp) beg))
 322                   (and (<= (overlay-end tmp) end)
 323                        (>= (overlay-end tmp) beg)))
 324               (setq retval (cons tmp retval))))
 325         retval)))
 326
 327 (defsubst wl-repeat-string (str times)
 328   (let ((loop times)
 329         ret-val)
 330     (while (> loop 0)
 331       (setq ret-val (concat ret-val str))
 332       (setq loop (- loop 1)))
 333     ret-val))
 334
 335 (defun wl-list-diff (list1 list2)
 336   "Return a list of elements of LIST1 that do not appear in LIST2."
 337   (let ((list1 (copy-sequence list1)))
 338     (while list2
 339       (setq list1 (delq (car list2) list1))
 340       (setq list2 (cdr list2)))
 341     list1))
 342
 343 (defun wl-append-assoc-list (item value alist)
 344   "make assoc list '((item1 value1-1 value1-2 ...)) (item2 value2-1 ...)))"
 345   (let ((entry (assoc item alist)))
 346     (if entry
 347         (progn
 348           (when (not (member value (cdr entry)))
 349             (nconc entry (list value)))
 350           alist)
 351       (append alist
 352               (list (list item value))))))
 353
 354 (defun wl-delete-alist (key alist)
 355   "Delete by side effect any entries specified with KEY from ALIST.
 356 Return the modified ALIST.  Key comparison is done with `assq'.
 357 Write `(setq foo (wl-delete-alist key foo))' to be sure of changing
 358 the value of `foo'."
 359   (let (entry)
 360     (while (setq entry (assq key alist))
 361       (setq alist (delq entry alist)))
 362     alist))
 363
 364 (defun wl-delete-associations (keys alist)
 365   "Delete by side effect any entries specified with KEYS from ALIST.
 366 Return the modified ALIST.  KEYS must be a list of keys for ALIST.
 367 Deletion is done with `wl-delete-alist'.
 368 Write `(setq foo (wl-delete-associations keys foo))' to be sure of
 369 changing the value of `foo'."
 370   (while keys
 371     (setq alist (wl-delete-alist (car keys) alist))
 372     (setq keys (cdr keys)))
 373   alist)
 374
 375 (defun wl-inverse-alist (keys alist)
 376   "Inverse ALIST, copying.
 377 Return an association list represents the inverse mapping of ALIST,
 378 from objects to KEYS.
 379 The objects mapped (cdrs of elements of the ALIST) are shared."
 380   (let (x y tmp result)
 381     (while keys
 382       (setq x (car keys))
 383       (setq y (cdr (assq x alist)))
 384       (if y
 385           (if (setq tmp (assoc y result))
 386               (setq result (cons (append tmp (list x))
 387                                  (delete tmp result)))
 388             (setq result (cons (list y x) result))))
 389       (setq keys (cdr keys)))
 390     result))
 391
 392 (eval-when-compile
 393   (require 'static))
 394 (static-unless (fboundp 'pp)
 395   (defvar pp-escape-newlines t)
 396   (defun pp (object &optional stream)
 397     "Output the pretty-printed representation of OBJECT, any Lisp object.
 398 Quoting characters are printed when needed to make output that `read'
 399 can handle, whenever this is possible.
 400 Output stream is STREAM, or value of `standard-output' (which see)."
 401     (princ (pp-to-string object) (or stream standard-output)))
 402
 403   (defun pp-to-string (object)
 404     "Return a string containing the pretty-printed representation of OBJECT,
 405 any Lisp object.  Quoting characters are used when needed to make output
 406 that `read' can handle, whenever this is possible."
 407     (save-excursion
 408       (set-buffer (generate-new-buffer " pp-to-string"))
 409       (unwind-protect
 410           (progn
 411             (lisp-mode-variables t)
 412             (let ((print-escape-newlines pp-escape-newlines))
 413               (prin1 object (current-buffer)))
 414             (goto-char (point-min))
 415             (while (not (eobp))
 416               (cond
 417                ((looking-at "\\s(\\|#\\s(")
 418                 (while (looking-at "\\s(\\|#\\s(")
 419                   (forward-char 1)))
 420                ((and (looking-at "\\(quote[ \t]+\\)\\([^.)]\\)")
 421                      (> (match-beginning 1) 1)
 422                      (= ?\( (char-after (1- (match-beginning 1))))
 423                      ;; Make sure this is a two-element list.
 424                      (save-excursion
 425                        (goto-char (match-beginning 2))
 426                        (forward-sexp)
 427                        ;; Avoid mucking with match-data; does this test work?
 428                        (char-equal ?\) (char-after (point)))))
 429                 ;; -1 gets the paren preceding the quote as well.
 430                 (delete-region (1- (match-beginning 1)) (match-end 1))
 431                 (insert "'")
 432                 (forward-sexp 1)
 433                 (if (looking-at "[ \t]*\)")
 434                     (delete-region (match-beginning 0) (match-end 0))
 435                   (error "Malformed quote"))
 436                 (backward-sexp 1))
 437                ((condition-case err-var
 438                     (prog1 t (down-list 1))
 439                   (error nil))
 440                 (backward-char 1)
 441                 (skip-chars-backward " \t")
 442                 (delete-region
 443                  (point)
 444                  (progn (skip-chars-forward " \t") (point)))
 445                 (if (not (char-equal ?' (char-after (1- (point)))))
 446                     (insert ?\n)))
 447                ((condition-case err-var
 448                     (prog1 t (up-list 1))
 449                   (error nil))
 450                 (while (looking-at "\\s)")
 451                   (forward-char 1))
 452                 (skip-chars-backward " \t")
 453                 (delete-region
 454                  (point)
 455                  (progn (skip-chars-forward " \t") (point)))
 456                 (if (not (char-equal ?' (char-after (1- (point)))))
 457                     (insert ?\n)))
 458                (t (goto-char (point-max)))))
 459             (goto-char (point-min))
 460             (indent-sexp)
 461             (buffer-string))
 462         (kill-buffer (current-buffer))))))
 463
 464 (defsubst wl-get-date-iso8601 (date)
 465   (or (get-text-property 0 'wl-date date)
 466       (let* ((d1 (timezone-fix-time date nil nil))
 467              (time (format "%04d%02d%02dT%02d%02d%02d"
 468                            (aref d1 0) (aref d1 1) (aref d1 2)
 469                            (aref d1 3) (aref d1 4) (aref d1 5))))
 470         (put-text-property 0 1 'wl-date time date)
 471         time)))
 472
 473 (defun wl-make-date-string ()
 474   (let ((s (current-time-string)))
 475     (string-match "\\`\\([A-Z][a-z][a-z]\\) +[A-Z][a-z][a-z] +[0-9][0-9]? *[0-9][0-9]?:[0-9][0-9]:[0-9][0-9] *[0-9]?[0-9]?[0-9][0-9]"
 476                   s)
 477     (concat (wl-match-string 1 s) ", "
 478             (timezone-make-date-arpa-standard s (current-time-zone)))))
 479
 480 (defun wl-date-iso8601 (date)
 481   "Convert the DATE to YYMMDDTHHMMSS."
 482   (condition-case ()
 483       (wl-get-date-iso8601 date)
 484     (error "")))
 485
 486 (defun wl-day-number (date)
 487   (let ((dat (mapcar '(lambda (s) (and s (string-to-int s)) )
 488                      (timezone-parse-date date))))
 489     (timezone-absolute-from-gregorian
 490      (nth 1 dat) (nth 2 dat) (car dat))))
 491
 492 (defun wl-url-news (url &rest args)
 493   (interactive "sURL: ")
 494   (if (string-match "^news:\\(.*\\)$" url)
 495       (wl-summary-goto-folder-subr
 496        (concat "-" (elmo-match-string 1 url)) nil nil nil t)
 497     (message "Not a news: url.")))
 498
 499 (defun wl-url-nntp (url &rest args)
 500   (interactive "sURL: ")
 501   (let (folder fld-name server port msg)
 502     (if (string-match
 503          "^nntp://\\([^:/]*\\):?\\([0-9]*\\)/\\([^/]*\\)/\\([0-9]*\\).*$" url)
 504         (progn
 505           (if (eq (length (setq fld-name
 506                                 (elmo-match-string 3 url))) 0)
 507               (setq fld-name nil))
 508           (if (eq (length (setq port
 509                                 (elmo-match-string 2 url))) 0)
 510               (setq port (int-to-string elmo-nntp-default-port)))
 511           (if (eq (length (setq server
 512                                 (elmo-match-string 1 url))) 0)
 513               (setq server elmo-nntp-default-server))
 514           (setq folder (concat "-" fld-name "@" server ":" port))
 515           (if (eq (length (setq msg
 516                                 (elmo-match-string 4 url))) 0)
 517               (wl-summary-goto-folder-subr
 518                folder nil nil nil t)
 519             (wl-summary-goto-folder-subr
 520              folder 'update nil nil t)
 521             (goto-char (point-min))
 522             (re-search-forward (concat "^ *" msg) nil t)
 523             (wl-summary-redisplay)))
 524       (message "Not a nntp: url."))))
 525
 526 (defmacro wl-concat-list (list separator)
 527   (` (mapconcat 'identity (delete "" (delq nil (, list))) (, separator))))
 528
 529 (defmacro wl-current-message-buffer ()
 530   (` (save-excursion
 531        (if (buffer-live-p wl-current-summary-buffer)
 532            (set-buffer wl-current-summary-buffer))
 533        wl-message-buffer)))
 534
 535 (defmacro wl-kill-buffers (regexp)
 536   (` (mapcar (function
 537               (lambda (x)
 538                 (if (and (buffer-name x)
 539                          (string-match (, regexp) (buffer-name x)))
 540                     (and (get-buffer x)
 541                          (kill-buffer x)))))
 542              (buffer-list))))
 543
 544 (defun wl-collect-summary ()
 545   (let (result)
 546     (mapcar
 547      (function (lambda (x)
 548                  (if (and (string-match "^Summary"
 549                                         (buffer-name x))
 550                           (save-excursion
 551                             (set-buffer x)
 552                             (equal major-mode 'wl-summary-mode)))
 553                      (setq result (nconc result (list x))))))
 554      (buffer-list))
 555     result))
 556
 557 (defun wl-collect-draft ()
 558   (let ((draft-regexp (concat
 559                        "^" (regexp-quote
 560                             (elmo-localdir-folder-directory-internal
 561                              (wl-folder-get-elmo-folder wl-draft-folder)))))
 562         result buf)
 563     (mapcar
 564      (function (lambda (x)
 565                  (if (and
 566                       (setq buf (with-current-buffer x
 567                                   wl-draft-buffer-file-name))
 568                       (string-match draft-regexp buf))
 569                      (setq result (nconc result (list x))))))
 570      (buffer-list))
 571     result))
 572
 573 (static-if (fboundp 'read-directory-name)
 574     (defalias 'wl-read-directory-name 'read-directory-name)
 575   (defun wl-read-directory-name (prompt dir)
 576     (let ((dir (read-file-name prompt dir)))
 577       (unless (file-directory-p dir)
 578         (error "%s is not directory" dir))
 579       dir)))
 580
 581 ;; local variable check.
 582 (static-if (fboundp 'local-variable-p)
 583     (defalias 'wl-local-variable-p 'local-variable-p)
 584   (defmacro wl-local-variable-p (symbol &optional buffer)
 585     (` (if (assq (, symbol) (buffer-local-variables (, buffer)))
 586            t))))
 587
 588 (defun wl-number-base36 (num len)
 589   (if (if (< len 0)
 590           (<= num 0)
 591         (= len 0))
 592       ""
 593     (concat (wl-number-base36 (/ num 36) (1- len))
 594             (char-to-string (aref "zyxwvutsrqponmlkjihgfedcba9876543210"
 595                                   (% num 36))))))
 596
 597 (defvar wl-unique-id-char nil)
 598
 599 (defun wl-unique-id ()
 600   ;; Don't use microseconds from (current-time), they may be unsupported.
 601   ;; Instead we use this randomly inited counter.
 602   (setq wl-unique-id-char
 603         (% (1+ (or wl-unique-id-char (logand (random t) (1- (lsh 1 20)))))
 604            ;; (current-time) returns 16-bit ints,
 605            ;; and 2^16*25 just fits into 4 digits i base 36.
 606            (* 25 25)))
 607   (let ((tm (static-if (fboundp 'current-time)
 608                 (current-time)
 609               (let* ((cts (split-string (current-time-string) "[ :]"))
 610                      (m (cdr (assoc (nth 1 cts)
 611                                     '(("Jan" . "01") ("Feb" . "02")
 612                                       ("Mar" . "03") ("Apr" . "04")
 613                                       ("May" . "05") ("Jun" . "06")
 614                                       ("Jul" . "07") ("Aug" . "08")
 615                                       ("Sep" . "09") ("Oct" . "10")
 616                                       ("Nov" . "11") ("Dec" . "12"))))))
 617                 (list (string-to-int (concat (nth 6 cts) m
 618                                              (substring (nth 2 cts) 0 1)))
 619                       (string-to-int (concat (substring (nth 2 cts) 1)
 620                                              (nth 4 cts) (nth 5 cts)
 621                                              (nth 6 cts))))))))
 622     (concat
 623      (if (memq system-type '(ms-dos emx vax-vms))
 624          (let ((user (downcase (user-login-name))))
 625            (while (string-match "[^a-z0-9_]" user)
 626              (aset user (match-beginning 0) ?_))
 627            user)
 628        (wl-number-base36 (user-uid) -1))
 629      (wl-number-base36 (+ (car   tm)
 630                           (lsh (% wl-unique-id-char 25) 16)) 4)
 631      (wl-number-base36 (+ (nth 1 tm)
 632                           (lsh (/ wl-unique-id-char 25) 16)) 4)
 633      ;; Append the name of the message interface, because while the
 634      ;; generated ID is unique to this newsreader, other newsreaders
 635      ;; might otherwise generate the same ID via another algorithm.
 636      wl-unique-id-suffix)))
 637
 638 (defvar wl-message-id-function 'wl-draft-make-message-id-string)
 639 (defun wl-draft-make-message-id-string ()
 640   "Return Message-ID field value."
 641   (concat "<" (wl-unique-id)
 642           (let (from user domain)
 643             (if (and wl-message-id-use-wl-from
 644                      (progn
 645                        (setq from (wl-address-header-extract-address wl-from))
 646                        (and (string-match "^\\(.*\\)@\\(.*\\)$" from)
 647                             (setq user   (match-string 1 from))
 648                             (setq domain (match-string 2 from)))))
 649                 (format "%%%s@%s>" user domain)
 650               (format "@%s>"
 651                       (or wl-message-id-domain
 652                           (if wl-local-domain
 653                               (concat (system-name) "." wl-local-domain)
 654                             (system-name))))))))
 655
 656 ;;; Profile loading.
 657 (defvar wl-load-profile-function 'wl-local-load-profile)
 658 (defun wl-local-load-profile ()
 659   "Load `wl-init-file'."
 660   (message "Initializing ...")
 661   (load wl-init-file 'noerror 'nomessage))
 662
 663 (defun wl-load-profile ()
 664   "Call `wl-load-profile-function' function."
 665   (funcall wl-load-profile-function))
 666
 667 ;;;
 668
 669 (defmacro wl-count-lines ()
 670   (` (save-excursion
 671        (beginning-of-line)
 672        (count-lines 1 (point)))))
 673
 674 (defun wl-horizontal-recenter ()
 675   "Recenter the current buffer horizontally."
 676   (beginning-of-line)
 677   (re-search-forward "[[<]" (point-at-eol) t)
 678   (if (< (current-column) (/ (window-width) 2))
 679       (set-window-hscroll (get-buffer-window (current-buffer) t) 0)
 680     (let* ((orig (point))
 681            (end (window-end (get-buffer-window (current-buffer) t)))
 682            (max 0))
 683       (when end
 684         ;; Find the longest line currently displayed in the window.
 685         (goto-char (window-start))
 686         (while (and (not (eobp))
 687                     (< (point) end))
 688           (end-of-line)
 689           (setq max (max max (current-column)))
 690           (forward-line 1))
 691         (goto-char orig)
 692         ;; Scroll horizontally to center (sort of) the point.
 693         (if (> max (window-width))
 694             (set-window-hscroll
 695              (get-buffer-window (current-buffer) t)
 696              (min (- (current-column) (/ (window-width) 3))
 697                   (+ 2 (- max (window-width)))))
 698           (set-window-hscroll (get-buffer-window (current-buffer) t) 0))
 699         max))))
 700
 701 ;; Biff
 702 (static-cond
 703  (wl-on-xemacs
 704   (defvar wl-biff-timer-name "wl-biff")
 705
 706   (defun wl-biff-stop ()
 707     (when (get-itimer wl-biff-timer-name)
 708       (delete-itimer wl-biff-timer-name)))
 709
 710   (defun wl-biff-start ()
 711     (wl-biff-stop)
 712     (when wl-biff-check-folder-list
 713       (wl-biff-check-folders)
 714       (start-itimer wl-biff-timer-name 'wl-biff-check-folders
 715                     wl-biff-check-interval wl-biff-check-interval))))
 716
 717  ((and (condition-case nil (require 'timer) (error nil));; FSFmacs 19+
 718        (fboundp 'timer-activate))
 719
 720   (defun wl-biff-stop ()
 721     (when (get 'wl-biff 'timer)
 722       (cancel-timer (get 'wl-biff 'timer))))
 723
 724   (defun wl-biff-start ()
 725     (require 'timer)
 726     (when wl-biff-check-folder-list
 727       (wl-biff-check-folders)
 728       (if (get 'wl-biff 'timer)
 729           (timer-activate (get 'wl-biff 'timer))
 730         (put 'wl-biff 'timer (run-at-time
 731                               (timer-next-integral-multiple-of-time
 732                                (current-time) wl-biff-check-interval)
 733                               wl-biff-check-interval
 734                               'wl-biff-event-handler)))))
 735
 736   (defun-maybe timer-next-integral-multiple-of-time (time secs)
 737     "Yield the next value after TIME that is an integral multiple of SECS.
 738 More precisely, the next value, after TIME, that is an integral multiple
 739 of SECS seconds since the epoch.  SECS may be a fraction.
 740 This function is imported from Emacs 20.7."
 741     (let ((time-base (ash 1 16)))
 742       (if (fboundp 'atan)
 743           ;; Use floating point, taking care to not lose precision.
 744           (let* ((float-time-base (float time-base))
 745                  (million 1000000.0)
 746                  (time-usec (+ (* million
 747                                   (+ (* float-time-base (nth 0 time))
 748                                      (nth 1 time)))
 749                                (nth 2 time)))
 750                  (secs-usec (* million secs))
 751                  (mod-usec (mod time-usec secs-usec))
 752                  (next-usec (+ (- time-usec mod-usec) secs-usec))
 753                  (time-base-million (* float-time-base million)))
 754             (list (floor next-usec time-base-million)
 755                   (floor (mod next-usec time-base-million) million)
 756                   (floor (mod next-usec million))))
 757         ;; Floating point is not supported.
 758         ;; Use integer arithmetic, avoiding overflow if possible.
 759         (let* ((mod-sec (mod (+ (* (mod time-base secs)
 760                                    (mod (nth 0 time) secs))
 761                                 (nth 1 time))
 762                              secs))
 763                (next-1-sec (+ (- (nth 1 time) mod-sec) secs)))
 764           (list (+ (nth 0 time) (floor next-1-sec time-base))
 765                 (mod next-1-sec time-base)
 766                 0)))))
 767
 768   (defun wl-biff-event-handler ()
 769     ;; PAKURing from FSF:time.el
 770     (wl-biff-check-folders)
 771     ;; Do redisplay right now, if no input pending.
 772     (sit-for 0)
 773     (let* ((current (current-time))
 774            (timer (get 'wl-biff 'timer))
 775            ;; Compute the time when this timer will run again, next.
 776            (next-time (timer-relative-time
 777                        (list (aref timer 1) (aref timer 2) (aref timer 3))
 778                        (* 5 (aref timer 4)) 0)))
 779       ;; If the activation time is far in the past,
 780       ;; skip executions until we reach a time in the future.
 781       ;; This avoids a long pause if Emacs has been suspended for hours.
 782       (or (> (nth 0 next-time) (nth 0 current))
 783           (and (= (nth 0 next-time) (nth 0 current))
 784                (> (nth 1 next-time) (nth 1 current)))
 785           (and (= (nth 0 next-time) (nth 0 current))
 786                (= (nth 1 next-time) (nth 1 current))
 787                (> (nth 2 next-time) (nth 2 current)))
 788           (progn
 789             (timer-set-time timer (timer-next-integral-multiple-of-time
 790                                    current wl-biff-check-interval)
 791                             wl-biff-check-interval)
 792             (timer-activate timer))))))
 793  (t
 794   (fset 'wl-biff-stop 'ignore)
 795   (fset 'wl-biff-start 'ignore)))
 796
 797 (defsubst wl-biff-notify (new-mails notify-minibuf)
 798   (when (and (not wl-modeline-biff-status) (> new-mails 0))
 799     (run-hooks 'wl-biff-notify-hook))
 800   (when (and wl-modeline-biff-status (eq new-mails 0))
 801     (run-hooks 'wl-biff-unnotify-hook))
 802   (setq wl-modeline-biff-status (> new-mails 0))
 803   (force-mode-line-update t)
 804   (when notify-minibuf
 805     (cond ((zerop new-mails) (message "No mail."))
 806           ((= 1 new-mails) (message "You have a new mail."))
 807           (t (message "You have %d new mails." new-mails)))))
 808
 809 ;; Internal variable.
 810 (defvar wl-biff-check-folders-running nil)
 811
 812 (defun wl-biff-check-folders ()
 813   (interactive)
 814   (if wl-biff-check-folders-running
 815       (when (interactive-p)
 816         (message "Biff process is running."))
 817     (setq wl-biff-check-folders-running t)
 818     (when (interactive-p)
 819       (message "Checking new mails..."))
 820     (let ((new-mails 0)
 821           (flist (or wl-biff-check-folder-list (list wl-default-folder)))
 822           folder)
 823       (if (eq (length flist) 1)
 824           (wl-biff-check-folder-async (wl-folder-get-elmo-folder
 825                                        (car flist) 'biff) (interactive-p))
 826         (unwind-protect
 827             (while flist
 828               (setq folder (wl-folder-get-elmo-folder (car flist))
 829                     flist (cdr flist))
 830               (when (elmo-folder-plugged-p folder)
 831                 (setq new-mails
 832                       (+ new-mails
 833                          (nth 0 (wl-biff-check-folder folder))))))
 834           (setq wl-biff-check-folders-running nil)
 835           (wl-biff-notify new-mails (interactive-p)))))))
 836
 837 (defun wl-biff-check-folder (folder)
 838   (if (eq (elmo-folder-type-internal folder) 'pop3)
 839       (unless (elmo-pop3-get-session folder 'if-exists)
 840         (wl-folder-check-one-entity (elmo-folder-name-internal folder)
 841                                     'biff))
 842     (wl-folder-check-one-entity (elmo-folder-name-internal folder)
 843                                 'biff)))
 844
 845 (defun wl-biff-check-folder-async-callback (diff data)
 846   (if (nth 1 data)
 847       (with-current-buffer (nth 1 data)
 848         (wl-folder-entity-hashtb-set wl-folder-entity-hashtb
 849                                      (nth 0 data)
 850                                      (list (nth 0 diff)
 851                                            (- (nth 1 diff) (nth 0 diff))
 852                                            (nth 2 diff))
 853                                      (current-buffer))))
 854   (setq wl-folder-info-alist-modified t)
 855   (setq wl-biff-check-folders-running nil)
 856   (sit-for 0)
 857   (wl-biff-notify (car diff) (nth 2 data)))
 858
 859 (defun wl-biff-check-folder-async (folder notify-minibuf)
 860   (when (elmo-folder-plugged-p folder)
 861     (elmo-folder-set-biff-internal folder t)
 862     (if (and (eq (elmo-folder-type-internal folder) 'imap4)
 863              (elmo-folder-use-flag-p folder))
 864         ;; Check asynchronously only when IMAP4 and use server diff.
 865         (progn
 866           (setq elmo-folder-diff-async-callback
 867                 'wl-biff-check-folder-async-callback)
 868           (setq elmo-folder-diff-async-callback-data
 869                 (list (elmo-folder-name-internal folder)
 870                       (get-buffer wl-folder-buffer-name)
 871                       notify-minibuf))
 872           (elmo-folder-diff-async folder))
 873       (unwind-protect
 874           (wl-biff-notify (car (wl-biff-check-folder folder))
 875                           notify-minibuf)
 876         (setq wl-biff-check-folders-running nil)))))
 877
 878 (if (and (fboundp 'regexp-opt)
 879          (not (featurep 'xemacs)))
 880     (defalias 'wl-regexp-opt 'regexp-opt)
 881   (defun wl-regexp-opt (strings &optional paren)
 882     "Return a regexp to match a string in STRINGS.
 883 Each string should be unique in STRINGS and should not contain any regexps,
 884 quoted or not.  If optional PAREN is non-nil, ensure that the returned regexp
 885 is enclosed by at least one regexp grouping construct."
 886     (let ((open-paren (if paren "\\(" "")) (close-paren (if paren "\\)" "")))
 887       (concat open-paren (mapconcat 'regexp-quote strings "\\|")
 888               close-paren))))
 889
 890 (defun wl-expand-newtext (newtext original)
 891   (let ((len (length newtext))
 892         (pos 0)
 893         c expanded beg N did-expand)
 894     (while (< pos len)
 895       (setq beg pos)
 896       (while (and (< pos len)
 897                   (not (= (aref newtext pos) ?\\)))
 898         (setq pos (1+ pos)))
 899       (unless (= beg pos)
 900         (push (substring newtext beg pos) expanded))
 901       (when (< pos len)
 902         ;; We hit a \; expand it.
 903         (setq did-expand t
 904               pos (1+ pos)
 905               c (aref newtext pos))
 906         (if (not (or (= c ?\&)
 907                      (and (>= c ?1)
 908                           (<= c ?9))))
 909             ;; \ followed by some character we don't expand.
 910             (push (char-to-string c) expanded)
 911           ;; \& or \N
 912           (if (= c ?\&)
 913               (setq N 0)
 914             (setq N (- c ?0)))
 915           (when (match-beginning N)
 916             (push (substring original (match-beginning N) (match-end N))
 917                   expanded))))
 918       (setq pos (1+ pos)))
 919     (if did-expand
 920         (apply (function concat) (nreverse expanded))
 921       newtext)))
 922
 923 (defvar wl-line-string)
 924 (defun wl-line-parse-format (format spec-alist)
 925   "Make a formatter from FORMAT and SPEC-ALIST."
 926   (let (f spec specs stack)
 927     (setq f
 928           (with-temp-buffer
 929             (insert format)
 930             (goto-char (point-min))
 931             (while (search-forward "%" nil t)
 932               (cond
 933                ((looking-at "%")
 934                 (goto-char (match-end 0)))
 935                ((looking-at "\\(-?\\(0?\\)[0-9]*\\)\\([^0-9]\\)")
 936                 (cond
 937                  ((string= (match-string 3) "(")
 938                   (if (zerop (length (match-string 1)))
 939                       (error "No number specification for %%( line format"))
 940                   (push (list
 941                          (match-beginning 0) ; start
 942                          (match-end 0)       ; start-content
 943                          (string-to-number
 944                           (match-string 1))  ; width
 945                          specs) ; specs
 946                         stack)
 947                   (setq specs nil))
 948                  ((string= (match-string 3) ")")
 949                   (let ((entry (pop stack))
 950                         form)
 951                     (unless entry
 952                       (error
 953                        "No matching %%( parenthesis in summary line format"))
 954                     (goto-char (car entry)) ; start
 955                     (setq form (buffer-substring (nth 1 entry) ; start-content
 956                                                  (- (match-beginning 0) 1)))
 957                     (delete-region (car entry) (match-end 0))
 958                     (insert "s")
 959                     (setq specs
 960                           (append
 961                            (nth 3 entry)
 962                            (list (list 'wl-set-string-width (nth 2 entry)
 963                                        (append
 964                                         (list 'format form)
 965                                         specs)))))))
 966                  (t
 967                   (setq spec
 968                         (if (setq spec (assq (string-to-char (match-string 3))
 969                                              spec-alist))
 970                             (nth 1 spec)
 971                           (match-string 3)))
 972                   (unless (string= "" (match-string 1))
 973                     (setq spec (list 'wl-set-string-width
 974                                      (string-to-number (match-string 1))
 975                                      spec
 976                                      (unless (string= "" (match-string 2))
 977                                        (string-to-char (match-string 2))))))
 978                   (replace-match "s" 'fixed)
 979                   (setq specs (append specs
 980                                       (list
 981                                        (list
 982                                         'setq 'wl-line-string
 983                                         spec)))))))))
 984             (buffer-string)))
 985     (append (list 'format f) specs)))
 986
 987 (defmacro wl-line-formatter-setup (formatter format alist)
 988   (` (let (byte-compile-warnings)
 989        (setq (, formatter)
 990              (byte-compile
 991               (list 'lambda ()
 992                     (wl-line-parse-format (, format) (, alist)))))
 993        (when (get-buffer "*Compile-Log*")
 994          (bury-buffer "*Compile-Log*"))
 995        (when (get-buffer "*Compile-Log-Show*")
 996          (bury-buffer "*Compile-Log-Show*")))))
 997
 998 (require 'product)
 999 (product-provide (provide 'wl-util) (require 'wl-version))
1000
1001 ;;; wl-util.el ends here