wl/wl.el

   1 ;;; wl.el --- Wanderlust bootstrap.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 1998,1999,2000 Masahiro MURATA <muse@ba2.so-net.ne.jp>
   5
   6 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   7 ;;      Masahiro MURATA <muse@ba2.so-net.ne.jp>
   8 ;; Keywords: mail, net news
   9
  10 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
  11
  12 ;; This program is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16 ;;
  17 ;; This program is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21 ;;
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26 ;;
  27
  28 ;;; Commentary:
  29 ;;
  30
  31 ;;; Code:
  32 ;;
  33
  34 (require 'elmo)
  35 (require 'wl-version)                   ; reduce recursive-load-depth
  36
  37 ;; from x-face.el
  38 (unless (and (fboundp 'defgroup)
  39              (fboundp 'defcustom))
  40   (require 'backquote)
  41   (defmacro defgroup (&rest args))
  42   (defmacro defcustom (symbol value &optional doc &rest args)
  43     (let ((doc (concat "*" (or doc ""))))
  44       (` (defvar (, symbol) (, value) (, doc))))))
  45
  46 (require 'wl-vars)
  47 (require 'wl-util)
  48
  49 (cond (wl-on-xemacs
  50        (require 'wl-xmas))
  51       (wl-on-emacs21
  52        (require 'wl-e21))
  53       (t
  54        (require 'wl-mule)))
  55
  56 (provide 'wl)                           ; circular dependency
  57 (require 'wl-folder)
  58 (require 'wl-summary)
  59 (require 'wl-action)
  60 (require 'wl-thread)
  61 (require 'wl-address)
  62 (require 'wl-news)
  63
  64 (wl-draft-mode-setup)
  65 (require 'wl-draft)
  66 (wl-draft-key-setup)
  67
  68 (require 'wl-demo)
  69 (require 'wl-highlight)
  70
  71 (eval-when-compile
  72   (require 'cl)
  73   (require 'smtp)
  74   (require 'wl-score)
  75   (require 'wl-fldmgr)
  76   (require 'wl-mime)
  77   (require 'wl-spam))
  78
  79 (defun wl-plugged-init (&optional make-alist)
  80   (setq elmo-plugged wl-plugged)
  81   (if wl-reset-plugged-alist
  82       (elmo-set-plugged elmo-plugged))
  83   (when make-alist
  84     (wl-make-plugged-alist))
  85   ;; Plug status.
  86   (setq elmo-plugged (setq wl-plugged (elmo-plugged-p))
  87         wl-modeline-plug-status wl-plugged)
  88   (if wl-plugged
  89       (wl-toggle-plugged t 'flush)))
  90
  91 (defun wl-toggle-plugged (&optional arg queue-flush-only)
  92   (interactive)
  93   (elmo-quit) ; Disconnect current connection.
  94   (unless queue-flush-only
  95     (cond
  96      ((eq arg 'on)
  97       (setq wl-plugged t))
  98      ((eq arg 'off)
  99       (setq wl-plugged nil))
 100      (t (setq wl-plugged (not wl-plugged))))
 101     (elmo-set-plugged wl-plugged))
 102   (setq elmo-plugged wl-plugged
 103         wl-modeline-plug-status wl-plugged)
 104   (save-excursion
 105     (let ((summaries (wl-collect-summary)))
 106       (while summaries
 107         (set-buffer (pop summaries))
 108         (wl-summary-save-view)
 109         (elmo-folder-commit wl-summary-buffer-elmo-folder))))
 110   (setq wl-biff-check-folders-running nil)
 111   (if wl-plugged
 112       (progn
 113         ;; flush queue!!
 114         (elmo-dop-queue-flush)
 115         (unless queue-flush-only
 116           (when wl-biff-check-folder-list
 117             (wl-biff-check-folders)
 118             (wl-biff-start)))
 119         (if (and wl-draft-enable-queuing
 120                  wl-auto-flush-queue)
 121             (wl-draft-queue-flush))
 122 ;;      (when (and (eq major-mode 'wl-summary-mode)
 123 ;;                 (elmo-folder-plugged-p wl-summary-buffer-elmo-folder))
 124 ;;        (let* ((msgdb-dir (elmo-folder-msgdb-path
 125 ;;                           wl-summary-buffer-elmo-folder))
 126 ;;               (seen-list (elmo-msgdb-seen-load msgdb-dir)))
 127 ;;       (setq seen-list
 128 ;;                (wl-summary-flush-pending-append-operations seen-list))
 129 ;;          (elmo-msgdb-seen-save msgdb-dir seen-list)))
 130         (run-hooks 'wl-plugged-hook))
 131     (wl-biff-stop)
 132     (run-hooks 'wl-unplugged-hook))
 133   (force-mode-line-update t))
 134
 135 ;;; wl-plugged-mode
 136
 137 (defvar wl-plugged-port-label-alist
 138   (list (cons 119 "nntp")
 139         (cons 143 "imap4")
 140         (cons 110 "pop3")
 141         (cons 25 "smtp")))
 142         ;;(cons elmo-pop-before-smtp-port "pop3")
 143
 144 (defconst wl-plugged-switch-variables
 145   '(("Queuing" . wl-draft-enable-queuing)
 146     ("AutoFlushQueue" . wl-auto-flush-queue)
 147     ("DisconnectedOperation" . elmo-enable-disconnected-operation)))
 148
 149 (defvar wl-plugged-buf-name "Plugged")
 150 (defvar wl-plugged-mode-map nil)
 151 (defvar wl-plugged-alist nil)
 152 (defvar wl-plugged-switch nil)
 153 (defvar wl-plugged-winconf nil)
 154 (defvar wl-plugged-sending-queue-alist nil)
 155 (defvar wl-plugged-dop-queue-alist nil)
 156 (defvar wl-plugged-alist-modified nil)
 157
 158 (defvar wl-plugged-mode-menu-spec
 159   '("Plugged"
 160     ["Toggle plugged" wl-plugged-toggle t]
 161     ["Toggle All plugged" wl-plugged-toggle-all t]
 162     ["Prev Port"      wl-plugged-move-to-previous t]
 163     ["Next Port"      wl-plugged-move-to-next t]
 164     ["Prev Server"    wl-plugged-move-to-previous-server t]
 165     ["Next Server"    wl-plugged-move-to-next-server t]
 166     ["Flush queue"    wl-plugged-flush-queue t]
 167     "----"
 168     ["Exit"           wl-plugged-exit t]))
 169
 170 (eval-and-compile
 171   (if wl-on-xemacs
 172       (defun wl-plugged-setup-mouse ()
 173         (define-key wl-plugged-mode-map 'button2 'wl-plugged-click))
 174     (defun wl-plugged-setup-mouse ()
 175       (define-key wl-plugged-mode-map [mouse-2] 'wl-plugged-click))))
 176
 177 (unless wl-plugged-mode-map
 178   (setq wl-plugged-mode-map (make-sparse-keymap))
 179   (define-key wl-plugged-mode-map " "    'wl-plugged-toggle)
 180   (define-key wl-plugged-mode-map "\C-m" 'wl-plugged-toggle)
 181   (define-key wl-plugged-mode-map "\M-t" 'wl-plugged-toggle-all)
 182   (define-key wl-plugged-mode-map "q"    'wl-plugged-exit)
 183   (define-key wl-plugged-mode-map "\C-t" 'wl-plugged-exit)
 184   (define-key wl-plugged-mode-map "F"    'wl-plugged-flush-queue)
 185   (define-key wl-plugged-mode-map "P"    'wl-plugged-move-to-previous-server)
 186   (define-key wl-plugged-mode-map "N"    'wl-plugged-move-to-next-server)
 187   (define-key wl-plugged-mode-map "p"    'wl-plugged-move-to-previous)
 188   (define-key wl-plugged-mode-map "n"    'wl-plugged-move-to-next)
 189   (define-key wl-plugged-mode-map "\e\t" 'wl-plugged-move-to-previous)
 190   (define-key wl-plugged-mode-map "\t"   'wl-plugged-move-to-next)
 191   (wl-plugged-setup-mouse)
 192   (easy-menu-define
 193    wl-plugged-mode-menu
 194    wl-plugged-mode-map
 195    "Menu used in Plugged mode."
 196    wl-plugged-mode-menu-spec))
 197
 198 (defun wl-plugged-mode ()
 199   "Mode for setting Wanderlust plugged.
 200 See info under Wanderlust for full documentation.
 201
 202 Special commands:
 203 \\{wl-plugged-mode-map}
 204
 205 Entering Plugged mode calls the value of `wl-plugged-mode-hook'."
 206   (interactive)
 207   (kill-all-local-variables)
 208   (use-local-map wl-plugged-mode-map)
 209   (setq major-mode 'wl-plugged-mode)
 210   (setq mode-name "Plugged")
 211   (easy-menu-add wl-plugged-mode-menu)
 212   (wl-mode-line-buffer-identification)
 213   (setq wl-plugged-switch wl-plugged)
 214   (setq wl-plugged-alist-modified nil)
 215   (setq buffer-read-only t)
 216   (run-hooks 'wl-plugged-mode-hook))
 217
 218 (defmacro wl-plugged-string (plugged &optional time)
 219   (` (if (, time) wl-plugged-auto-off
 220        (if (, plugged) wl-plugged-plug-on wl-plugged-plug-off))))
 221
 222 (defmacro wl-plugged-server-indent ()
 223   (` (make-string wl-plugged-server-indent ? )))
 224
 225 (defun wl-plugged-set-variables ()
 226   (setq wl-plugged-sending-queue-alist
 227         (wl-plugged-sending-queue-info))
 228   (setq wl-plugged-dop-queue-alist
 229         (wl-plugged-dop-queue-info))
 230   (setq wl-plugged-alist
 231         (sort (copy-sequence elmo-plugged-alist)
 232               '(lambda (a b)
 233                  (string< (caar a) (caar b))))))
 234
 235 (defun wl-plugged-sending-queue-info ()
 236   ;; sending queue status
 237   (let (alist msgs sent-via server port)
 238     (setq msgs (elmo-folder-list-messages
 239                 (wl-folder-get-elmo-folder wl-queue-folder)))
 240     (while msgs
 241       (setq sent-via (wl-draft-queue-info-operation (car msgs) 'get-sent-via))
 242       (while sent-via
 243         (when (eq (nth 1 (car sent-via)) 'unplugged)
 244           (setq server (car (nth 2 (car sent-via)))
 245                 port (cdr (nth 2 (car sent-via))))
 246           (elmo-plugged-p server port)  ;; add elmo-plugged-alist if nothing.
 247           (setq alist
 248                 (wl-append-assoc-list
 249                  (cons server port)
 250                  (car msgs)
 251                  alist)))
 252         (setq sent-via (cdr sent-via)))
 253       (setq msgs (cdr msgs)))
 254     alist))
 255
 256 (defun wl-plugged-sending-queue-status (qinfo)
 257   ;; sending queue status
 258   (let ((len (length (cdr qinfo))))
 259     (concat (wl-plugged-set-folder-icon
 260              wl-queue-folder
 261              (wl-folder-get-petname wl-queue-folder))
 262             (if (> len 1)
 263                 (format ": %d msgs (" len)
 264               (format ": %d msg (" len))
 265             (mapconcat (function int-to-string) (cdr qinfo) ",")
 266             ")")))
 267
 268 (defun wl-plugged-dop-queue-info ()
 269   ;; dop queue status
 270   (let* ((count 0)
 271          (elmo-dop-queue (copy-sequence elmo-dop-queue))
 272          dop-queue last alist server-info
 273          ope operation)
 274     ;(elmo-dop-queue-load)
 275     (elmo-dop-queue-merge)
 276     (setq dop-queue (sort elmo-dop-queue '(lambda (a b)
 277                                             (string< (elmo-dop-queue-fname a)
 278                                                      (elmo-dop-queue-fname b)))))
 279     (wl-append dop-queue (list nil)) ;; terminate(dummy)
 280     (when (car dop-queue)
 281       (setq last (elmo-dop-queue-fname (car dop-queue)))) ;; first
 282     (while dop-queue
 283       (when (car dop-queue)
 284         (setq ope (cons (elmo-dop-queue-method-name (car dop-queue))
 285                         (length
 286                          (if (listp
 287                               (car
 288                                (elmo-dop-queue-arguments (car dop-queue))))
 289                              (car (elmo-dop-queue-arguments
 290                                    (car dop-queue))))))))
 291       (if (and (car dop-queue)
 292                (string= last (elmo-dop-queue-fname (car dop-queue))))
 293           (wl-append operation (list ope))
 294         ;;(setq count (1+ count))
 295         (when (and last (setq server-info (elmo-net-port-info
 296                                            (wl-folder-get-elmo-folder last))))
 297           (setq alist
 298                 (wl-append-assoc-list
 299                  server-info
 300                  (cons last operation)
 301                  alist)))
 302         (when (car dop-queue)
 303           (setq last (elmo-dop-queue-fname (car dop-queue))
 304                 operation (list ope))))
 305       (setq dop-queue (cdr dop-queue)))
 306     alist))
 307
 308 (defun wl-plugged-dop-queue-status (qinfo &optional column)
 309   ;; dop queue status
 310   (let ((operations (cdr qinfo))
 311         (column (or column wl-plugged-queue-status-column)))
 312     (mapconcat
 313      '(lambda (folder-ope)
 314         (concat (wl-plugged-set-folder-icon
 315                  (car folder-ope)
 316                  (wl-folder-get-petname (car folder-ope)))
 317                 "("
 318                 (let ((opes (cdr folder-ope))
 319                       pair shrinked)
 320                   (while opes
 321                     (if (setq pair (assoc (car (car opes)) shrinked))
 322                         (setcdr pair (+ (cdr pair)
 323                                         (max (cdr (car opes)) 1)))
 324                       (setq shrinked (cons
 325                                       (cons (car (car opes))
 326                                             (max (cdr (car opes)) 1))
 327                                       shrinked)))
 328                     (setq opes (cdr opes)))
 329                   (mapconcat
 330                    '(lambda (ope)
 331                       (if (> (cdr ope) 0)
 332                           (format "%s:%d" (car ope) (cdr ope))
 333                         (format "%s" (car ope))))
 334                    (nreverse shrinked) ","))
 335                 ")"))
 336      operations
 337      (concat "\n" (wl-set-string-width column "")))))
 338
 339 (defun wl-plugged-drawing (plugged-alist)
 340   (let ((buffer-read-only nil)
 341         (alist plugged-alist)
 342         (vars wl-plugged-switch-variables)
 343         last server port stream-type label plugged time
 344         line len qinfo column)
 345     (erase-buffer)
 346     (while vars
 347       (insert (format "%s:[%s]%s"
 348                       (caar vars)
 349                       (wl-plugged-string (symbol-value (cdar vars)))
 350                       (if (cdr vars) " " "")))
 351       (setq vars (cdr vars)))
 352     (insert "\n")
 353     (let ((elmo-plugged wl-plugged-switch))
 354       (setq line (format "[%s](wl-plugged)"
 355                          (wl-plugged-string (elmo-plugged-p))))
 356       ;; sending queue status
 357       (when (setq qinfo (assoc (cons nil nil) wl-plugged-sending-queue-alist))
 358         (setq line (concat
 359                     (wl-set-string-width wl-plugged-queue-status-column line)
 360                     (wl-plugged-sending-queue-status qinfo))))
 361       (insert line "\n"))
 362     (while alist
 363       (setq server (nth 0 (caar alist))
 364             port (nth 1 (caar alist))
 365             stream-type (nth 2 (caar alist))
 366             label (nth 1 (car alist))
 367             plugged (nth 2 (car alist))
 368             time (nth 3 (car alist)))
 369       (unless (string= last server)
 370         ;; server plug
 371         (insert (format "%s[%s]%s\n"
 372                         (wl-plugged-server-indent)
 373                         (wl-plugged-string
 374                          (elmo-plugged-p server nil plugged-alist))
 375                         server))
 376         (setq last server))
 377       ;; port plug
 378       (setq line
 379             (format "%s[%s]%s"
 380                     (make-string wl-plugged-port-indent ? )
 381                     (wl-plugged-string plugged time)
 382                     (cond
 383                      ((stringp port)
 384                       port)
 385                      (t
 386                       (format "%s(%d)"
 387                               (or label
 388                                   (cdr (assq port wl-plugged-port-label-alist))
 389                                   "")
 390                               port)))))
 391       (setq column (max (if line (1+ (string-width line)) 0)
 392                         wl-plugged-queue-status-column))
 393       (cond
 394        ;; sending queue status
 395        ((setq qinfo (assoc (cons server port) wl-plugged-sending-queue-alist))
 396         (setq line
 397               (concat
 398                (wl-set-string-width column line)
 399                (wl-plugged-sending-queue-status qinfo))))
 400        ;; dop queue status
 401        ((setq qinfo (assoc (list server port stream-type)
 402                            wl-plugged-dop-queue-alist))
 403         (setq line
 404               (concat
 405                (wl-set-string-width column line)
 406                (wl-plugged-dop-queue-status qinfo column)))))
 407       (insert line "\n")
 408       (setq alist (cdr alist)))
 409     (delete-region (1- (point-max)) (point-max)) ;; delete line at the end.
 410     (goto-char (point-min))
 411     (while (not (eobp))
 412       (wl-highlight-plugged-current-line)
 413       (forward-line 1)))
 414   (set-buffer-modified-p nil)
 415   (count-lines (point-min) (point-max)))
 416
 417 (defun wl-plugged-redrawing-switch (indent switch &optional time)
 418   (beginning-of-line)
 419   (when (re-search-forward
 420          (format "^%s\\[\\([^]]+\\)\\]" (make-string indent ? )))
 421     (goto-char (match-beginning 1))
 422     (delete-region (match-beginning 1) (match-end 1))
 423     (insert (wl-plugged-string switch time))
 424     (wl-highlight-plugged-current-line)
 425     (forward-line 1)))
 426
 427 (defun wl-plugged-redrawing (plugged-alist)
 428   (let ((buffer-read-only nil)
 429         (alist plugged-alist)
 430         last server port plugged time)
 431     (goto-char (point-min))
 432     (wl-plugged-redrawing-switch 0 (elmo-plugged-p))
 433     (while alist
 434       (setq server (caaar alist)
 435             port (cdaar alist)
 436             plugged (nth 2 (car alist))
 437             time (nth 3 (car alist)))
 438       (unless (string= last server)
 439         ;; server plug
 440         (wl-plugged-redrawing-switch
 441          wl-plugged-server-indent
 442          (elmo-plugged-p server nil plugged-alist))
 443         (setq last server))
 444       ;; port plug
 445       (wl-plugged-redrawing-switch
 446        wl-plugged-port-indent plugged time)
 447       (setq alist (cdr alist))))
 448   (sit-for 0)
 449   (set-buffer-modified-p nil))
 450
 451 (defun wl-plugged-change ()
 452   (interactive)
 453   (if (not elmo-plugged-alist)
 454       (message "No plugged info")
 455     (setq wl-plugged-winconf (current-window-configuration))
 456     (let* ((cur-win (selected-window))
 457            (max-lines (if (eq major-mode 'wl-summary-mode)
 458                           (/ (frame-height) 2)
 459                         (window-height)))
 460            window-lines lines)
 461       (save-excursion
 462         (set-buffer (get-buffer-create wl-plugged-buf-name))
 463         (wl-plugged-mode)
 464         (buffer-disable-undo (current-buffer))
 465         (delete-windows-on (current-buffer))
 466         (wl-plugged-set-variables)
 467         (setq lines (wl-plugged-drawing wl-plugged-alist)))
 468       (select-window cur-win)
 469       (setq window-lines (min max-lines (max lines window-min-height)))
 470       (when (> (- (window-height) window-lines) window-min-height)
 471         (split-window cur-win (- (window-height) window-lines)))
 472       (switch-to-buffer wl-plugged-buf-name)
 473       (condition-case nil
 474           (progn
 475             (enlarge-window (- window-lines (window-height)))
 476             (when (fboundp 'pos-visible-in-window-p)
 477               (goto-char (point-min))
 478               (while (and (< (window-height) max-lines)
 479                           (not (pos-visible-in-window-p (1- (point-max)))))
 480                 (enlarge-window 2))))
 481         (error))
 482       (goto-char (point-min))
 483       (forward-line 1)
 484       (wl-plugged-move-to-next)))) ;; goto first entry
 485
 486 (defsubst wl-plugged-get-server ()
 487   (save-excursion
 488     (end-of-line)
 489     (wl-plugged-move-to-previous-server)
 490     (beginning-of-line)
 491     (when (looking-at (format "^%s\\[[^]]+\\]\\(.*\\)"
 492                               (wl-plugged-server-indent)))
 493       (elmo-match-buffer 1))))
 494
 495 (defun wl-plugged-toggle ()
 496   (interactive)
 497   (let ((cur-point (point)))
 498     (save-excursion
 499       (beginning-of-line)
 500       (cond
 501        ;; switch variable
 502        ((bobp)
 503         (let (variable switch name)
 504           (goto-char cur-point)
 505           (when (and (not (bobp))
 506                      (not (eq (char-before) ? )))
 507             (if (re-search-backward " [^ ]+" nil t)
 508                 (forward-char 1)
 509               (re-search-backward "^[^ ]+" nil t)))
 510           (when (looking-at "\\([^ :[]+\\):?\\[\\([^]]+\\)\\]")
 511             (setq name (elmo-match-buffer 1))
 512             (setq switch (not (string= (elmo-match-buffer 2) wl-plugged-plug-on)))
 513             (when (setq variable (cdr (assoc name wl-plugged-switch-variables)))
 514               (set variable switch))
 515             (goto-char (match-beginning 2))
 516             (let ((buffer-read-only nil))
 517               (delete-region (match-beginning 2) (match-end 2))
 518               (insert (wl-plugged-string switch))
 519               (set-buffer-modified-p nil)))))
 520        ;; switch plug
 521        ((looking-at "^\\( *\\)\\[\\([^]]+\\)\\]\\([^ \n]*\\)")
 522         (let* ((indent (length (elmo-match-buffer 1)))
 523                (switch (elmo-match-buffer 2))
 524                (name (elmo-match-buffer 3))
 525                (plugged (not (string= switch wl-plugged-plug-on)))
 526                (alist wl-plugged-alist)
 527                server port stream-type name-1)
 528           (cond
 529            ((eq indent wl-plugged-port-indent)  ;; toggle port plug
 530             (cond
 531              ((string-match "\\([^([]*\\)(\\([^)[]+\\))" name)
 532               (setq port (string-to-int (elmo-match-string 2 name)))
 533               (if (string-match "!" (setq name-1 (elmo-match-string 1 name)))
 534                   (setq stream-type
 535                         (intern (substring name-1 (match-end 0))))))
 536              (t
 537               (setq port name)))
 538             (setq server (wl-plugged-get-server))
 539             (elmo-set-plugged plugged server port stream-type nil alist))
 540            ((eq indent wl-plugged-server-indent)  ;; toggle server plug
 541             (elmo-set-plugged plugged name nil nil nil alist))
 542            ((eq indent 0)  ;; toggle all plug
 543             (elmo-set-plugged plugged nil nil nil nil alist)))
 544           ;; redraw
 545           (wl-plugged-redrawing wl-plugged-alist)
 546           ;; show plugged status in modeline
 547           (let ((elmo-plugged wl-plugged-switch))
 548             (setq wl-plugged-switch (elmo-plugged-p)
 549                   wl-modeline-plug-status wl-plugged-switch)
 550             (force-mode-line-update t))))))
 551     (setq wl-plugged-alist-modified t)
 552     (goto-char cur-point)))
 553
 554 (defun wl-plugged-click (e)
 555   (interactive "e")
 556   (mouse-set-point e)
 557   (wl-plugged-toggle))
 558
 559 (defun wl-plugged-toggle-all ()
 560   (interactive)
 561   (let ((cur-point (point)))
 562     (setq wl-plugged-switch (not wl-plugged-switch))
 563     (elmo-set-plugged wl-plugged-switch nil nil nil nil wl-plugged-alist)
 564     (wl-plugged-redrawing wl-plugged-alist)
 565     (goto-char cur-point)
 566     (setq wl-plugged-alist-modified t)
 567     ;; show plugged status in modeline
 568     (setq wl-modeline-plug-status wl-plugged-switch)
 569     (force-mode-line-update t)))
 570
 571 (defun wl-plugged-exit ()
 572   (interactive)
 573   (setq ;;elmo-plugged-alist wl-plugged-alist
 574         wl-plugged wl-plugged-switch
 575         wl-plugged-alist nil
 576         wl-plugged-sending-queue-alist nil
 577         wl-plugged-dop-queue-alist nil)
 578   (run-hooks 'wl-plugged-exit-hook)
 579   (when wl-plugged-alist-modified
 580     (wl-toggle-plugged (if wl-plugged 'on 'off) t))
 581   (kill-buffer (current-buffer))
 582   (if wl-plugged-winconf
 583       (set-window-configuration wl-plugged-winconf)))
 584
 585 (defun wl-plugged-flush-queue ()
 586   (interactive)
 587   (let ((cur-point (point))
 588         (dop-status (elmo-dop-queue-flush))
 589         (send-status (wl-draft-queue-flush)))
 590     (unless (or dop-status send-status)
 591       (message "No processing queue."))
 592     (wl-plugged-set-variables)
 593     (wl-plugged-drawing wl-plugged-alist)
 594     (goto-char cur-point)))
 595
 596 (defun wl-plugged-move-to-next ()
 597   (interactive)
 598   (when (re-search-forward "\\[\\([^]]+\\)\\]" nil t)
 599     (let ((pos (match-beginning 1)))
 600       (if (invisible-p pos)
 601           (goto-char (next-visible-point pos))
 602         (goto-char pos)))))
 603
 604 (defun wl-plugged-move-to-previous ()
 605   (interactive)
 606   (if (eq (char-before) ?\]) (forward-char -1))
 607   (when (re-search-backward "\\[\\([^]]+\\)\\]" nil t)
 608     (let ((pos (match-beginning 1)))
 609       (if (invisible-p pos)
 610           (goto-char (next-visible-point pos))
 611         (goto-char pos)))))
 612
 613 (defun wl-plugged-move-to-next-server ()
 614   (interactive)
 615   (let ((regexp
 616          (format "^%s\\[\\([^]]+\\)\\]" (wl-plugged-server-indent)))
 617         point)
 618     (save-excursion
 619       (end-of-line)
 620       (if (re-search-forward regexp nil t)
 621           (setq point (match-beginning 1))))
 622     (if point (goto-char point))))
 623
 624 (defun wl-plugged-move-to-previous-server ()
 625   (interactive)
 626   (let ((regexp
 627          (format "^%s\\[\\([^]]+\\)\\]" (wl-plugged-server-indent))))
 628     (if (re-search-backward regexp nil t)
 629         (goto-char (match-beginning 1)))))
 630
 631 ;;; end of wl-plugged-mode
 632
 633 (defun wl-save ()
 634   "Save summary and folder status."
 635   (interactive)
 636   (wl-save-status 'keep-summary)
 637   (run-hooks 'wl-save-hook))
 638
 639 (defun wl-execute-temp-marks ()
 640   "Execute temporary marks in summary buffers."
 641   (interactive)
 642   (let ((summaries (wl-collect-summary)))
 643     (while summaries
 644       (with-current-buffer (car summaries)
 645         (wl-summary-exec-with-confirmation)
 646         (wl-summary-save-status))
 647       (setq summaries (cdr summaries)))))
 648
 649 (defun wl-save-status (&optional keep-summary)
 650   (message "Saving summary and folder status...")
 651   (save-excursion
 652     (let ((summaries (wl-collect-summary)))
 653       (while summaries
 654         (with-current-buffer (car summaries)
 655           (unless keep-summary
 656             (wl-summary-cleanup-temp-marks))
 657           (wl-summary-save-view)
 658           (elmo-folder-commit wl-summary-buffer-elmo-folder)
 659           (unless keep-summary
 660             (kill-buffer (car summaries))))
 661         (setq summaries (cdr summaries)))))
 662   (wl-refile-alist-save)
 663   (wl-folder-info-save)
 664   (and (featurep 'wl-fldmgr) (wl-fldmgr-exit))
 665   (and (featurep 'wl-spam) (wl-spam-save-status))
 666   (elmo-crosspost-message-alist-save)
 667   (message "Saving summary and folder status...done"))
 668
 669 (defun wl-exit ()
 670   (interactive)
 671   (when (or (not wl-interactive-exit)
 672             (y-or-n-p "Do you really want to quit Wanderlust? "))
 673     (elmo-quit)
 674     (when wl-use-acap (funcall (symbol-function 'wl-acap-exit)))
 675     (wl-biff-stop)
 676     (elmo-clear-signal-slots)
 677     (run-hooks 'wl-exit-hook)
 678     (wl-save-status)
 679     (wl-folder-cleanup-variables)
 680     (wl-message-buffer-cache-clean-up)
 681     (wl-kill-buffers
 682      (format "^\\(%s\\)$"
 683              (mapconcat 'identity
 684                         (list wl-folder-buffer-name
 685                               wl-plugged-buf-name)
 686                         "\\|")))
 687     (when wl-delete-startup-frame-function
 688       (funcall wl-delete-startup-frame-function))
 689 ;;    (if (and wl-folder-use-frame
 690 ;;           (> (length (visible-frame-list)) 1))
 691 ;;      (delete-frame))
 692     (setq wl-init nil)
 693     (remove-hook 'kill-emacs-hook 'wl-save-status)
 694     (elmo-passwd-alist-clear)
 695     t)
 696   (message "") ; empty minibuffer.
 697   )
 698
 699 (defun wl-init ()
 700   (when (not wl-init)
 701     (require 'mime-setup)
 702     (setq elmo-plugged wl-plugged)
 703     (add-hook 'kill-emacs-hook 'wl-save-status)
 704     (wl-address-init)
 705     (wl-draft-setup)
 706     (wl-refile-alist-setup)
 707     (require 'wl-mime)
 708     ;; defined above.
 709     (wl-mime-setup)
 710     (fset 'wl-summary-from-func-internal
 711           (symbol-value 'wl-summary-from-function))
 712     (fset 'wl-summary-subject-func-internal
 713           (symbol-value 'wl-summary-subject-function))
 714     (fset 'wl-summary-subject-filter-func-internal
 715           (symbol-value 'wl-summary-subject-filter-function))
 716     (wl-summary-define-sort-command)
 717     (wl-summary-define-mark-action)
 718     (dolist (spec wl-summary-flag-alist)
 719       (set-face-foreground
 720        (make-face (intern
 721                    (format "wl-highlight-summary-%s-flag-face" (car spec))))
 722        (nth 1 spec)))
 723     (setq elmo-get-folder-function #'wl-folder-make-elmo-folder
 724           elmo-progress-callback-function #'wl-progress-callback-function)
 725     (setq elmo-no-from wl-summary-no-from-message)
 726     (setq elmo-no-subject wl-summary-no-subject-message)
 727     (elmo-global-flags-initialize (mapcar 'car wl-summary-flag-alist))
 728     (elmo-connect-signal
 729      nil
 730      'message-number-changed
 731      'wl-draft
 732      (elmo-define-signal-handler (listener folder old-number new-number)
 733        (dolist (buffer (wl-collect-draft))
 734          (with-current-buffer buffer
 735            (wl-draft-buffer-change-number old-number new-number)))
 736        (wl-draft-rename-saved-config old-number new-number))
 737      (elmo-define-signal-filter (listener folder old-number new-number)
 738        (and folder
 739             (string= (elmo-folder-name-internal folder) wl-draft-folder))))
 740     (wl-news-check)
 741     (setq wl-init t)
 742     ;; This hook may contain the functions `wl-plugged-init-icons' and
 743     ;; `wl-biff-init-icons' for reasons of system internal to accord
 744     ;; facilities for the Emacs variants.
 745     (run-hooks 'wl-init-hook)))
 746
 747 (defun wl-check-environment (no-check-folder)
 748   (unless wl-from (error "Please set `wl-from' to your mail address"))
 749   ;; Message-ID
 750   (when wl-insert-message-id
 751     (let ((message-id (funcall wl-message-id-function))
 752           domain)
 753       (unless (string-match "^<\\([^@]*\\)@\\([^@]*\\)>$" message-id)
 754         (cond
 755          ((string-match "@" wl-message-id-domain)
 756           (error "Please remove `@' from `wl-message-id-domain'"))
 757          (t
 758           (error
 759            "Check around `wl-message-id-function' to get valid Message-ID string"))))
 760       (setq domain (match-string 2 message-id))
 761       (if (or (not (string-match "[^.]\\.[^.]" domain))
 762               (string= domain "localhost.localdomain"))
 763           (elmo-warning
 764            "Please set `wl-message-id-domain' to get valid Message-ID string."))))
 765   ;; folders
 766   (when (not no-check-folder)
 767     (let ((draft-folder (wl-folder-get-elmo-folder wl-draft-folder))
 768           (queue-folder (wl-folder-get-elmo-folder wl-queue-folder))
 769           (lost+found-folder (wl-folder-get-elmo-folder
 770                               elmo-lost+found-folder)))
 771       (unless (elmo-folder-exists-p draft-folder)
 772         (if (y-or-n-p
 773              (format "Draft Folder %s does not exist, create it? "
 774                      wl-draft-folder))
 775             (elmo-folder-create draft-folder)
 776           (error "Draft Folder is not created")))
 777       (if (and wl-draft-enable-queuing
 778                (not (elmo-folder-exists-p queue-folder)))
 779           (if (y-or-n-p
 780                (format "Queue Folder %s does not exist, create it? "
 781                        wl-queue-folder))
 782               (elmo-folder-create queue-folder)
 783             (error "Queue Folder is not created")))
 784       (when (not (eq no-check-folder 'wl-draft))
 785         (unless (elmo-folder-exists-p lost+found-folder)
 786           (elmo-folder-create lost+found-folder)))
 787       ;; tmp dir
 788       (unless (file-exists-p wl-temporary-file-directory)
 789         (if (y-or-n-p
 790              (format "Temp directory (to save multipart) %s does not exist, create it now? "
 791                      wl-temporary-file-directory))
 792             (make-directory wl-temporary-file-directory)
 793           (error "Temp directory is not created"))))))
 794
 795 (defconst wl-check-variables-alist
 796   '((numberp . elmo-pop3-default-port)
 797     (symbolp . elmo-pop3-default-authenticate-type)
 798     (numberp . elmo-imap4-default-port)
 799     (symbolp . elmo-imap4-default-authenticate-type)
 800     (numberp . elmo-nntp-default-port)
 801     (numberp . wl-pop-before-smtp-port)
 802     (symbolp . wl-pop-before-smtp-authenticate-type)))
 803
 804 (defun wl-check-variables ()
 805   (let ((type-variables wl-check-variables-alist)
 806         type)
 807     (while (setq type (car type-variables))
 808       (if (and (eval (cdr type))
 809                (not (funcall (car type)
 810                              (eval (cdr type)))))
 811           (error "%s must be %s: %S"
 812                  (cdr type)
 813                  (substring (format "%s" (car type)) 0 -1)
 814                  (eval (cdr type))))
 815       (setq type-variables (cdr type-variables)))))
 816
 817 (defun wl-check-variables-2 ()
 818   (if (< wl-message-buffer-cache-size 1)
 819       (error "`wl-message-buffer-cache-size' must be larger than 0"))
 820   (when wl-message-buffer-prefetch-depth
 821     (if (not (< wl-message-buffer-prefetch-depth
 822                 wl-message-buffer-cache-size))
 823         (error (concat
 824                 "`wl-message-buffer-prefetch-depth' must be smaller than "
 825                 "`wl-message-buffer-cache-size' - 1.")))))
 826
 827 ;;;###autoload
 828 (defun wl (&optional arg)
 829   "Start Wanderlust -- Yet Another Message Interface On Emacsen.
 830 If ARG (prefix argument) is specified, folder checkings are skipped."
 831   (interactive "P")
 832   (unless wl-init
 833     (wl-load-profile)
 834     (elmo-init))
 835   (let (demo-buf check)
 836     (unless wl-init
 837       (if wl-demo (setq demo-buf (wl-demo)))
 838       (setq check t))
 839     (wl-init)
 840     (condition-case obj
 841         (progn
 842           (if check
 843               (progn
 844                 (message "Checking environment...")
 845                 (wl-check-environment arg)
 846                 (message "Checking environment...done")
 847                 (message "Checking type of variables...")
 848                 (wl-check-variables)
 849                 (wl-check-variables-2)
 850                 (message "Checking type of variables...done")))
 851           (let ((inhibit-quit t))
 852             (wl-plugged-init (wl-folder)))
 853           (unless arg
 854             (run-hooks 'wl-auto-check-folder-pre-hook)
 855             (wl-folder-auto-check)
 856             (run-hooks 'wl-auto-check-folder-hook)))
 857       (error
 858        (if (buffer-live-p demo-buf)
 859            (kill-buffer demo-buf))
 860        (signal (car obj)(cdr obj)))
 861       (quit))
 862     (when wl-biff-check-folder-list
 863       (unless arg (wl-biff-check-folders))
 864       (wl-biff-start))
 865     (if (buffer-live-p demo-buf)
 866         (kill-buffer demo-buf)))
 867   (run-hooks 'wl-hook))
 868
 869 (defvar wl-delete-startup-frame-function nil)
 870
 871 ;;;###autoload
 872 (defun wl-other-frame (&optional arg)
 873   "Pop up a frame to read messages via Wanderlust."
 874   (interactive)
 875   (if wl-folder-use-frame
 876       (wl arg)
 877     (let ((focusing-functions (append '(raise-frame select-frame)
 878                                       (if (fboundp 'x-focus-frame)
 879                                           '(x-focus-frame)
 880                                         '(focus-frame))))
 881           (folder (get-buffer wl-folder-buffer-name))
 882           window frame wl-folder-use-frame)
 883       (if (and folder
 884                (setq window (get-buffer-window folder t))
 885                (window-live-p window)
 886                (setq frame (window-frame window)))
 887           (progn
 888             (while focusing-functions
 889               (funcall (car focusing-functions) frame)
 890               (setq focusing-functions (cdr focusing-functions)))
 891             (wl arg))
 892         (setq frame (make-frame))
 893         (while focusing-functions
 894           (funcall (car focusing-functions) frame)
 895           (setq focusing-functions (cdr focusing-functions)))
 896         (setq wl-delete-startup-frame-function
 897               `(lambda ()
 898                  (setq wl-delete-startup-frame-function nil)
 899                  (let ((frame ,frame))
 900                    (if (eq (selected-frame) frame)
 901                        (delete-frame frame)))))
 902         (wl arg)))))
 903
 904 ;; Define some autoload functions WL might use.
 905 (eval-and-compile
 906   ;; This little mapcar goes through the list below and marks the
 907   ;; symbols in question as autoloaded functions.
 908   (mapcar
 909    (function
 910     (lambda (package)
 911       (let ((interactive (nth 1 (memq ':interactive package))))
 912         (mapcar
 913          (function
 914           (lambda (function)
 915             (let (keymap)
 916               (when (consp function)
 917                 (setq keymap (car (memq 'keymap function)))
 918                 (setq function (car function)))
 919               (autoload function (car package) nil interactive keymap))))
 920          (if (eq (nth 1 package) ':interactive)
 921              (cdddr package)
 922            (cdr package))))))
 923    '(("wl-fldmgr" :interactive t
 924       wl-fldmgr-access-display-all wl-fldmgr-access-display-normal
 925       wl-fldmgr-add wl-fldmgr-clear-cut-entity-list wl-fldmgr-copy
 926       wl-fldmgr-copy-region wl-fldmgr-cut wl-fldmgr-cut-region
 927       wl-fldmgr-make-access-group wl-fldmgr-make-filter
 928       wl-fldmgr-make-group wl-fldmgr-make-multi
 929       wl-fldmgr-reconst-entity-hashtb wl-fldmgr-rename wl-fldmgr-delete
 930       wl-fldmgr-save-folders wl-fldmgr-set-petname wl-fldmgr-sort
 931       wl-fldmgr-subscribe wl-fldmgr-subscribe-region
 932       wl-fldmgr-unsubscribe wl-fldmgr-unsubscribe-region wl-fldmgr-yank )
 933      ("wl-acap" wl-acap-init)
 934      ("wl-acap" :interactive t wl-acap-store)
 935      ("wl-fldmgr"
 936       (wl-fldmgr-mode-map keymap)
 937       wl-fldmgr-add-entity-hashtb)
 938      ("wl-expire" :interactive t
 939       wl-folder-archive-current-entity
 940       wl-folder-expire-current-entity wl-summary-archive
 941       wl-summary-expire )
 942      ("wl-score"
 943       wl-score-save wl-summary-rescore-msgs wl-summary-score-headers
 944       wl-summary-score-update-all-lines )
 945      ("wl-score" :interactive t
 946       wl-score-change-score-file wl-score-edit-current-scores
 947       wl-score-edit-file wl-score-flush-cache wl-summary-rescore
 948       wl-score-set-mark-below wl-score-set-expunge-below
 949       wl-summary-increase-score wl-summary-lower-score )
 950      ("wl-draft" wl-draft-rename-saved-config))))
 951
 952 ;; for backward compatibility
 953 (defalias 'wl-summary-from-func-petname 'wl-summary-default-from)
 954
 955 (require 'product)
 956 (product-provide (provide 'wl) (require 'wl-version))
 957
 958 ;;; wl.el ends here