;;; epa.el --- EasyPG Assistant, GUI of EasyPG
;; Copyright (C) 2006 Daiki Ueno

;; Author: Daiki Ueno <ueno@unixuser.org>
;; Keywords: PGP, GnuPG

;; This file is part of EasyPG.

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.	 See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Code:

(require 'epg)
(require 'font-lock)
(require 'widget)
(eval-when-compile (require 'wid-edit))

(defgroup epa nil
  "EasyPG Assistant, GUI of EasyPG."
  :group 'epg)

(defgroup epa-faces nil
  "Faces for epa-mode."
  :group 'epa)

(defvar epa-buffer nil)

(defface epa-validity-high-face
  '((((class color) (background dark))
     (:foreground "PaleTurquoise" :bold t))
    (t
     (:bold t)))
  "Face used for displaying the high validity."
  :group 'epa-faces)
(defvar epa-validity-high-face 'epa-validity-high-face)

(defface epa-validity-medium-face
  '((((class color) (background dark))
     (:foreground "PaleTurquoise" :italic t))
    (t
     ()))
  "Face used for displaying the medium validity."
  :group 'epa-faces)
(defvar epa-validity-medium-face 'epa-validity-medium-face)

(defface epa-validity-low-face
  '((t
     (:italic t)))
  "Face used for displaying the low validity."
  :group 'epa-faces)
(defvar epa-validity-low-face 'epa-validity-low-face)

(defface epa-validity-disabled-face
  '((t
     (:italic t :inverse-video t)))
  "Face used for displaying the disabled validity."
  :group 'epa-faces)
(defvar epa-validity-disabled-face 'epa-validity-disabled-face)

(defface epa-string-face
  '((((class color)
      (background dark))
     (:foreground "lightyellow"))
    (((class color)
      (background light))
     (:foreground "blue4"))
    (t
     ()))
  "Face used for displaying the string."
  :group 'epa-faces)
(defvar epa-string-face 'epa-string-face)

(defface epa-field-name-face
  '((((class color) (background dark))
     (:foreground "PaleTurquoise" :bold t))
    (t (:bold t)))
  "Face for the name of the attribute field."
  :group 'epa)
(defvar epa-field-name-face 'epa-field-name-face)

(defface epa-field-body-face
  '((((class color) (background dark))
     (:foreground "turquoise" :italic t))
    (t (:italic t)))
  "Face for the body of the attribute field."
  :group 'epa)
(defvar epa-field-body-face 'epa-field-body-face)

(defcustom epa-validity-face-alist
  '((?o . epa-validity-disabled-face)
    (?i . epa-validity-disabled-face)
    (?d . epa-validity-disabled-face)
    (?r . epa-validity-disabled-face)
    (?e . epa-validity-disabled-face)
    (?- . epa-validity-low-face)
    (?q . epa-validity-low-face)
    (?n . epa-validity-low-face)
    (?m . epa-validity-medium-face)
    (?f . epa-validity-high-face)
    (?u . epa-validity-high-face))
  "An alist mapping marks on epa-keys-buffer to faces."
  :type 'list
  :group 'epa)

(defcustom epa-font-lock-keywords
  '(("^[* ]\\(\\([oidreqnmfu-]\\) .*\\)"
     (1 (cdr (assq (aref (match-string 2) 0)
		   epa-validity-face-alist))))
    ("^\t\\([^\t:]+:\\)[ \t]*\\(.*\\)$"
     (1 epa-field-name-face)
     (2 epa-field-body-face)))
  "Default expressions to addon in epa-mode."
  :type '(repeat (list string))
  :group 'epa)

(defconst epa-pubkey-algorithm-letter-alist
  '((1 . ?R)
    (2 . ?r)
    (3 . ?s)
    (16 . ?g)
    (17 . ?D)
    (20 . G)))

(defvar epa-keys-buffer nil)
(defvar epa-key-buffer-alist nil)
(defvar epa-key nil)

(defvar epa-keys-mode-map
  (let ((keymap (make-sparse-keymap)))
    (define-key keymap "m" 'epa-mark)
    (define-key keymap "u" 'epa-unmark)
    (define-key keymap "n" 'next-line)
    (define-key keymap "p" 'previous-line)
    (define-key keymap " " 'scroll-up)
    (define-key keymap [delete] 'scroll-down)
    (define-key keymap "q" 'bury-buffer)
    keymap))

(defun epa-keys-mode ()
  "Major mode for `epa-list-keys'."
  (kill-all-local-variables)
  (buffer-disable-undo)
  (setq major-mode 'epa-keys-mode
	mode-name "Keys"
	truncate-lines t
	buffer-read-only t)
  (use-local-map epa-keys-mode-map)
  (set-keymap-parent (current-local-map) widget-keymap)
  (make-local-variable 'font-lock-defaults)
  (setq font-lock-defaults '(epa-font-lock-keywords t))
  ;; In XEmacs, auto-initialization of font-lock is not effective
  ;; if buffer-file-name is not set.
  (font-lock-set-defaults)
  (widget-setup)
  (run-hooks 'epa-keys-mode-hook))

(defvar epa-key-mode-map
  (let ((keymap (make-sparse-keymap)))
    (define-key keymap "q" 'bury-buffer)
    keymap))

(defun epa-key-mode ()
  "Major mode for `epa-show-key'."
  (kill-all-local-variables)
  (buffer-disable-undo)
  (setq major-mode 'epa-key-mode
	mode-name "Key"
	truncate-lines t
	buffer-read-only t)
  (use-local-map epa-key-mode-map)
  (make-local-variable 'font-lock-defaults)
  (setq font-lock-defaults '(epa-font-lock-keywords t))
  ;; In XEmacs, auto-initialization of font-lock is not effective
  ;; if buffer-file-name is not set.
  (font-lock-set-defaults)
  (run-hooks 'epa-key-mode-hook))

;;;###autoload
(defun epa-list-keys (&optional name)
  (interactive "sPattern: ")
  (unless (and epa-keys-buffer
	       (buffer-live-p epa-keys-buffer))
    (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
  (set-buffer epa-keys-buffer)
  (erase-buffer)
  (epa-list-keys-1 name)
  (epa-keys-mode)
  (goto-char (point-min))
  (pop-to-buffer (current-buffer)))

(defun epa-list-keys-1 (name)
  (let ((inhibit-read-only t)
	buffer-read-only
	keys point primary-sub-key primary-user-id)
    (setq keys (epg-list-keys))
    (while keys
      (setq point (point)
	    primary-sub-key (car (epg-key-sub-key-list (car keys)))
	    primary-user-id (car (epg-key-user-id-list (car keys))))
      (insert " " (or (char-to-string
		       (car (rassq (epg-sub-key-validity primary-sub-key)
				   epg-key-validity-alist)))
		      " ") " ")
      (widget-create 'link 
		     :tag (epg-sub-key-id primary-sub-key)
		     :notify 'epa-show-key-notify
		     (car keys))
      (insert " " (epg-user-id-name primary-user-id) "\n")
      (put-text-property point (point) 'epa-key (car keys))
      (setq keys (cdr keys)))))

(defun epa-ask-keys (prompt function &optional names &rest args)
  (unless (and epa-keys-buffer
	       (buffer-live-p epa-keys-buffer))
    (setq epa-keys-buffer (generate-new-buffer "*Keys*")))
  (let ((buffer (current-buffer))
	(inhibit-read-only t)
	buffer-read-only)
    (set-buffer epa-keys-buffer)
    (erase-buffer)
    (insert prompt)
    (widget-create 'push-button
		   :tag "Done"
		   :notify (lambda (widget &rest ignore)
			     (let ((callback (widget-value widget))
				   keys key)
			       (while (re-search-forward "^\\*" nil t)
				 (if (setq key (get-text-property (point)
								  'epa-key))
				     (setq keys (cons key keys))))
			       (set-buffer (car callback))
			       (apply (car (cdr callback)) keys
				      (cdr (cdr callback)))))
		   (cons buffer (cons function args)))
    (insert "\n\n")
    (if names
	(while names
	  (epa-list-keys-1 (car names))
	  (setq names (cdr names)))
      (epa-list-keys-1 nil))
    (epa-keys-mode)
    (goto-char (point-min))
    (pop-to-buffer (current-buffer))))

(defun epa-show-key (key)
  (let* ((primary-sub-key (car (epg-key-sub-key-list key)))
	 (entry (assoc (epg-sub-key-id primary-sub-key)
		       epa-key-buffer-alist))
	 (inhibit-read-only t)
	 buffer-read-only
	 pointer)
    (unless entry
      (setq entry (cons (epg-sub-key-id primary-sub-key) nil)
	    epa-key-buffer-alist (cons entry epa-key-buffer-alist)))
    (unless (and (cdr entry)
		 (buffer-live-p (cdr entry)))
      (setcdr entry (generate-new-buffer
		     (format "*Key*%s" (epg-sub-key-id primary-sub-key)))))
    (set-buffer (cdr entry))
    (make-local-variable 'epa-key)
    (setq epa-key key)
    (erase-buffer)
    (setq pointer (epg-key-user-id-list key))
    (while pointer
      (insert " "
	      (char-to-string
	       (car (rassq (epg-user-id-validity (car pointer))
			   epg-key-validity-alist)))
	      " "
	      (epg-user-id-name (car pointer))
	      "\n")
      (setq pointer (cdr pointer)))
    (setq pointer (epg-key-sub-key-list key))
    (while pointer
      (insert " "
	      (char-to-string
	       (car (rassq (epg-sub-key-validity (car pointer))
			   epg-key-validity-alist)))
	      " "
	      (epg-sub-key-id (car pointer))
	      " "
	      (format "%dbits"
		      (epg-sub-key-length (car pointer)))
	      " "
	      (cdr (assq (epg-sub-key-algorithm (car pointer))
			 epg-pubkey-algorithm-alist))
	      "\n\tCreated: "
	      (epg-sub-key-creation-time (car pointer))
	      (if (epg-sub-key-expiration-time (car pointer))
		  (format "\n\tExpires: %s" (epg-sub-key-expiration-time
						  (car pointer)))
		"")
	      "\n\tCapabilities: "
	      (mapconcat #'symbol-name
			 (epg-sub-key-capability (car pointer))
			 " ")
	      "\n\tFingerprint: "
	      (epg-sub-key-fingerprint (car pointer))
	      "\n")
      (setq pointer (cdr pointer)))
    (goto-char (point-min))
    (pop-to-buffer (current-buffer))
    (epa-key-mode)))

(defun epa-show-key-notify (widget &rest ignore)
  (epa-show-key (widget-value widget)))

(defun epa-mark ()
  "Mark the current line."
  (interactive)
  (let ((inhibit-read-only t)
	buffer-read-only
	properties)
    (beginning-of-line)
    (setq properties (text-properties-at (point)))
    (delete-char 1)
    (insert "*")
    (set-text-properties (1- (point)) (point) properties)
    (forward-line)))

(defun epa-unmark ()
  "Unmark the current line."
  (interactive)
  (let ((inhibit-read-only t)
	buffer-read-only
	properties)
    (beginning-of-line)
    (setq properties (text-properties-at (point)))
    (delete-char 1)
    (insert " ")
    (set-text-properties (1- (point)) (point) properties)
    (forward-line)))

(provide 'epa)

;;; epa.el ends here