Buffers
*******

A buffer is a Lisp object containing text to be edited.  Buffers are used to hold the contents of files that are being visited; there may also be buffers that are not visiting files.  While several buffers may exist at one time, exactly one buffer is designated the current buffer at any time.  Most editing commands act on the contents of the current buffer.  Each buffer, including the current buffer, may or may not be displayed in any windows.

Buffer Basics
=============

A buffer is a Lisp object containing text to be edited.  Buffers are used to hold the contents of files that are being visited; there may also be buffers that are not visiting files.  While several buffers may exist at one time, exactly one buffer is designated the current buffer at any time.  Most editing commands act on the contents of the current buffer.  Each buffer, including the current buffer, may or may not be displayed in any windows.

Buffers in Emacs editing are objects that have distinct names and hold text that can be edited.  Buffers appear to Lisp programs as a special data type.  You can think of the contents of a buffer as an extendable string; insertions and deletions may occur in any part of the buffer. See Text.

A Lisp buffer object contains numerous pieces of information.  Some of this information is directly accessible to the programmer through variables, while other information is accessible only through special-purpose functions.  For example, the visited file name is directly accessible through a variable, while the value of point is accessible only through a primitive function.

Buffer-specific information that is directly accessible is stored in buffer-local variable bindings, which are variable values that are effective only in a particular buffer.  This feature allows each buffer to override the values of certain variables.  Most major modes override variables such as fill-column or comment-column in this way.  For more information about buffer-local variables and functions related to them, see Buffer-Local Variables.

For functions and variables related to visiting files in buffers, see Visiting Files and Saving Buffers.  For functions and variables related to the display of buffers in windows, see Buffers and Windows.

 -- Function: bufferp object
     This function returns t if OBJECT is a buffer, nil otherwise.

The Current Buffer
==================

There are, in general, many buffers in an Emacs session.  At any time, one of them is designated as the current buffer.  This is the buffer in which most editing takes place, because most of the primitives for examining or changing text in a buffer operate implicitly on the current buffer (see Text).  Normally the buffer that is displayed on the screen in the selected window is the current buffer, but this is not always so: a Lisp program can designate any buffer as current temporarily in order to operate on its contents, without changing what is displayed on the screen.

The way to designate a current buffer in a Lisp program is by calling set-buffer.  The specified buffer remains current until a new one is designated.

When an editing command returns to the editor command loop, the command loop designates the buffer displayed in the selected window as current, to prevent confusion: the buffer that the cursor is in when Emacs reads a command is the buffer that the command will apply to. (see Command Loop.)  Therefore, set-buffer is not the way to switch visibly to a different buffer so that the user can edit it.  For this, you must use the functions described in Displaying Buffers.

However, Lisp functions that change to a different current buffer should not depend on the command loop to set it back afterwards. Editing commands written in XEmacs Lisp can be called from other programs as well as from the command loop.  It is convenient for the caller if the subroutine does not change which buffer is current (unless, of course, that is the subroutine's purpose).  Therefore, you should normally use set-buffer within a save-excursion that will restore the current buffer when your function is done (see Excursions).  Here is an example, the code for the command append-to-buffer (with the documentation string abridged):

     (defun append-to-buffer (buffer start end)
       "Append to specified buffer the text of the region.
     ..."
       (interactive "BAppend to buffer: \nr")
       (let ((oldbuf (current-buffer)))
         (save-excursion
           (set-buffer (get-buffer-create buffer))
           (insert-buffer-substring oldbuf start end))))

This function binds a local variable to the current buffer, and then save-excursion records the values of point, the mark, and the original buffer.  Next, set-buffer makes another buffer current. Finally, insert-buffer-substring copies the string from the original current buffer to the new current buffer.

If the buffer appended to happens to be displayed in some window, the next redisplay will show how its text has changed.  Otherwise, you will not see the change immediately on the screen.  The buffer becomes current temporarily during the execution of the command, but this does not cause it to be displayed.

If you make local bindings (with let or function arguments) for a variable that may also have buffer-local bindings, make sure that the same buffer is current at the beginning and at the end of the local binding's scope.  Otherwise you might bind it in one buffer and unbind it in another!  There are two ways to do this.  In simple cases, you may see that nothing ever changes the current buffer within the scope of the binding.  Otherwise, use save-excursion to make sure that the buffer current at the beginning is current again whenever the variable is unbound.

It is not reliable to change the current buffer back with set-buffer, because that won't do the job if a quit happens while the wrong buffer is current.  Here is what not to do:

     (let (buffer-read-only
           (obuf (current-buffer)))
       (set-buffer ...)
       ...
       (set-buffer obuf))

Using save-excursion, as shown below, handles quitting, errors, and throw, as well as ordinary evaluation.

     (let (buffer-read-only)
       (save-excursion
         (set-buffer ...)
         ...))

 -- Function: current-buffer
     This function returns the current buffer.

          (current-buffer)
               => #<buffer buffers.texi>

 -- Function: set-buffer buffer-or-name
     This function makes BUFFER-OR-NAME the current buffer.  It does not display the buffer in the currently selected window or in any other window, so the user cannot necessarily see the buffer.  But Lisp programs can in any case work on it.

     This function returns the buffer identified by BUFFER-OR-NAME. An error is signaled if BUFFER-OR-NAME does not identify an existing buffer.

Buffer Names
============

Each buffer has a unique name, which is a string.  Many of the functions that work on buffers accept either a buffer or a buffer name as an argument.  Any argument called BUFFER-OR-NAME is of this sort, and an error is signaled if it is neither a string nor a buffer. Any argument called BUFFER must be an actual buffer object, not a name.

Buffers that are ephemeral and generally uninteresting to the user have names starting with a space, so that the list-buffers and buffer-menu commands don't mention them.  A name starting with space also initially disables recording undo information; see Undo.

 -- Function: buffer-name &optional buffer
     This function returns the name of BUFFER as a string.  If BUFFER is not supplied, it defaults to the current buffer.

     If buffer-name returns nil, it means that BUFFER has been killed.  See Killing Buffers.

          (buffer-name)
               => "buffers.texi"

          (setq foo (get-buffer "temp"))
               => #<buffer temp>

          (kill-buffer foo)
               => nil

          (buffer-name foo)
               => nil

          foo
               => #<killed buffer>

 -- Command: rename-buffer newname &optional unique
     This function renames the current buffer to NEWNAME.  An error is signaled if NEWNAME is not a string, or if there is already a buffer with that name.  The function returns nil.

     Ordinarily, rename-buffer signals an error if NEWNAME is already in use.  However, if UNIQUE is non-nil, it modifies NEWNAME to make a name that is not in use.  Interactively, you can make UNIQUE non-nil with a numeric prefix argument.

     One application of this command is to rename the *shell* buffer to some other name, thus making it possible to create a second shell buffer under the name *shell*.

 -- Function: get-buffer buffer-or-name
     This function returns the buffer specified by BUFFER-OR-NAME. If BUFFER-OR-NAME is a string and there is no buffer with that name, the value is nil.  If BUFFER-OR-NAME is a buffer, it is returned as given.  (That is not very useful, so the argument is usually a name.)  For example:

          (setq b (get-buffer "lewis"))
               => #<buffer lewis>

          (get-buffer b)
               => #<buffer lewis>

          (get-buffer "Frazzle-nots")
               => nil

     See also the function get-buffer-create in Creating Buffers.

 -- Function: generate-new-buffer-name starting-name &optional ignore
     This function returns a name that would be unique for a new buffer---but does not create the buffer.  It starts with STARTING-NAME, and produces a name not currently in use for any buffer by appending a number inside of <...>.

     If IGNORE is given, it specifies a name that is okay to use (if it is in the sequence to be tried), even if a buffer with that name exists.

     See the related function generate-new-buffer in Creating Buffers.

Buffer File Name
================

The buffer file name is the name of the file that is visited in that buffer.  When a buffer is not visiting a file, its buffer file name is nil.  Most of the time, the buffer name is the same as the nondirectory part of the buffer file name, but the buffer file name and the buffer name are distinct and can be set independently. See Visiting Files.

 -- Function: buffer-file-name &optional buffer
     This function returns the absolute file name of the file that BUFFER is visiting.  If BUFFER is not visiting any file, buffer-file-name returns nil.  If BUFFER is not supplied, it defaults to the current buffer.

          (buffer-file-name (other-buffer))
               => "/usr/user/lewis/manual/files.texi"

 -- Variable: buffer-file-name
     This buffer-local variable contains the name of the file being visited in the current buffer, or nil if it is not visiting a file.  It is a permanent local, unaffected by kill-local-variables.

          buffer-file-name
               => "/usr/user/lewis/manual/buffers.texi"

     It is risky to change this variable's value without doing various other things.  See the definition of set-visited-file-name in files.el; some of the things done there, such as changing the buffer name, are not strictly necessary, but others are essential to avoid confusing XEmacs.

 -- Variable: buffer-file-truename
     This buffer-local variable holds the truename of the file visited in the current buffer, or nil if no file is visited.  It is a permanent local, unaffected by kill-local-variables.  See Truenames.

 -- Variable: buffer-file-number
     This buffer-local variable holds the file number and directory device number of the file visited in the current buffer, or nil if no file or a nonexistent file is visited.  It is a permanent local, unaffected by kill-local-variables.  See Truenames.

     The value is normally a list of the form (FILENUM DEVNUM).  This pair of numbers uniquely identifies the file among all files accessible on the system.  See the function file-attributes, in File Attributes, for more information about them.

 -- Function: get-file-buffer filename
     This function returns the buffer visiting file FILENAME.  If there is no such buffer, it returns nil.  The argument FILENAME, which must be a string, is expanded (see File Name Expansion), then compared against the visited file names of all live buffers.

          (get-file-buffer "buffers.texi")
              => #<buffer buffers.texi>

     In unusual circumstances, there can be more than one buffer visiting the same file name.  In such cases, this function returns the first such buffer in the buffer list.

 -- Command: set-visited-file-name filename
     If FILENAME is a non-empty string, this function changes the name of the file visited in current buffer to FILENAME.  (If the buffer had no visited file, this gives it one.)  The next time the buffer is saved it will go in the newly-specified file.  This command marks the buffer as modified, since it does not (as far as XEmacs knows) match the contents of FILENAME, even if it matched the former visited file.

     If FILENAME is nil or the empty string, that stands for ``no visited file''.  In this case, set-visited-file-name marks the buffer as having no visited file.

     When the function set-visited-file-name is called interactively, it prompts for FILENAME in the minibuffer.

     See also clear-visited-file-modtime and verify-visited-file-modtime in Buffer Modification.

 -- Variable: list-buffers-directory
     This buffer-local variable records a string to display in a buffer listing in place of the visited file name, for buffers that don't have a visited file name.  Dired buffers use this variable.

Buffer Modification
===================

XEmacs keeps a flag called the modified flag for each buffer, to record whether you have changed the text of the buffer.  This flag is set to t whenever you alter the contents of the buffer, and cleared to nil when you save it.  Thus, the flag shows whether there are unsaved changes.  The flag value is normally shown in the modeline (see Modeline Variables), and controls saving (see Saving Buffers) and auto-saving (see Auto-Saving).

Some Lisp programs set the flag explicitly.  For example, the function set-visited-file-name sets the flag to t, because the text does not match the newly-visited file, even if it is unchanged from the file formerly visited.

The functions that modify the contents of buffers are described in Text.

 -- Function: buffer-modified-p &optional buffer
     This function returns t if the buffer BUFFER has been modified since it was last read in from a file or saved, or nil otherwise.  If BUFFER is not supplied, the current buffer is tested.

 -- Function: set-buffer-modified-p flag
     This function marks the current buffer as modified if FLAG is non-nil, or as unmodified if the flag is nil.

     Another effect of calling this function is to cause unconditional redisplay of the modeline for the current buffer.  In fact, the function redraw-modeline works by doing this:

          (set-buffer-modified-p (buffer-modified-p))

 -- Command: not-modified &optional arg
     This command marks the current buffer as unmodified, and not needing to be saved. (If ARG is non-nil, the buffer is instead marked as modified.) Don't use this function in programs, since it prints a message in the echo area; use set-buffer-modified-p (above) instead.

 -- Function: buffer-modified-tick &optional buffer
     This function returns BUFFER`s modification-count.  This is a counter that increments every time the buffer is modified.  If BUFFER is nil (or omitted), the current buffer is used.

Comparison of Modification Time
===============================

Suppose that you visit a file and make changes in its buffer, and meanwhile the file itself is changed on disk.  At this point, saving the buffer would overwrite the changes in the file.  Occasionally this may be what you want, but usually it would lose valuable information.  XEmacs therefore checks the file's modification time using the functions described below before saving the file.

 -- Function: verify-visited-file-modtime buffer
     This function compares what BUFFER has recorded for the modification time of its visited file against the actual modification time of the file as recorded by the operating system.  The two should be the same unless some other process has written the file since XEmacs visited or saved it.

     The function returns t if the last actual modification time and XEmacs's recorded modification time are the same, nil otherwise.

 -- Function: clear-visited-file-modtime
     This function clears out the record of the last modification time of the file being visited by the current buffer.  As a result, the next attempt to save this buffer will not complain of a discrepancy in file modification times.

     This function is called in set-visited-file-name and other exceptional places where the usual test to avoid overwriting a changed file should not be done.

 -- Function: visited-file-modtime
     This function returns the buffer's recorded last file modification time, as a list of the form (HIGH . LOW).  (This is the same format that file-attributes uses to return time values; see File Attributes.)

 -- Function: set-visited-file-modtime &optional time
     This function updates the buffer's record of the last modification time of the visited file, to the value specified by TIME if TIME is not nil, and otherwise to the last modification time of the visited file.

     If TIME is not nil, it should have the form (HIGH . LOW) or (HIGH LOW), in either case containing two integers, each of which holds 16 bits of the time.

     This function is useful if the buffer was not read from the file normally, or if the file itself has been changed for some known benign reason.

 -- Function: ask-user-about-supersession-threat filename
     This function is used to ask a user how to proceed after an attempt to modify an obsolete buffer visiting file FILENAME.  An obsolete buffer is an unmodified buffer for which the associated file on disk is newer than the last save-time of the buffer.  This means some other program has probably altered the file.

     Depending on the user's answer, the function may return normally, in which case the modification of the buffer proceeds, or it may signal a file-supersession error with data (FILENAME), in which case the proposed buffer modification is not allowed.

     This function is called automatically by XEmacs on the proper occasions.  It exists so you can customize XEmacs by redefining it. See the file userlock.el for the standard definition.

     See also the file locking mechanism in File Locks.

Read-Only Buffers
=================

If a buffer is read-only, then you cannot change its contents, although you may change your view of the contents by scrolling and narrowing.

Read-only buffers are used in two kinds of situations:

  * A buffer visiting a write-protected file is normally read-only.

     Here, the purpose is to show the user that editing the buffer with the aim of saving it in the file may be futile or undesirable.  The user who wants to change the buffer text despite this can do so after clearing the read-only flag with C-x C-q.

  * Modes such as Dired and Rmail make buffers read-only when altering the contents with the usual editing commands is probably a mistake.

     The special commands of these modes bind buffer-read-only to nil (with let) or bind inhibit-read-only to t around the places where they change the text.

 -- Variable: buffer-read-only
     This buffer-local variable specifies whether the buffer is read-only. The buffer is read-only if this variable is non-nil.

 -- Variable: inhibit-read-only
     If this variable is non-nil, then read-only buffers and read-only characters may be modified.  Read-only characters in a buffer are those that have non-nil read-only properties (either text properties or extent properties).  See Extent Properties, for more information about text properties and extent properties.

     If inhibit-read-only is t, all read-only character properties have no effect.  If inhibit-read-only is a list, then read-only character properties have no effect if they are members of the list (comparison is done with eq).

 -- Command: toggle-read-only
     This command changes whether the current buffer is read-only.  It is intended for interactive use; don't use it in programs.  At any given point in a program, you should know whether you want the read-only flag on or off; so you can set buffer-read-only explicitly to the proper value, t or nil.

 -- Function: barf-if-buffer-read-only
     This function signals a buffer-read-only error if the current buffer is read-only.  See Interactive Call, for another way to signal an error if the current buffer is read-only.

The Buffer List
===============

The buffer list is a list of all live buffers.  Creating a buffer adds it to this list, and killing a buffer deletes it.  The order of the buffers in the list is based primarily on how recently each buffer has been displayed in the selected window.  Buffers move to the front of the list when they are selected and to the end when they are buried.  Several functions, notably other-buffer, use this ordering.  A buffer list displayed for the user also follows this order.

Every frame has its own order for the buffer list.  Switching to a new buffer inside of a particular frame changes the buffer list order for that frame, but does not affect the buffer list order of any other frames.  In addition, there is a global, non-frame buffer list order that is independent of the buffer list orders for any particular frame.

Note that the different buffer lists all contain the same elements.  It is only the order of those elements that is different.

 -- Function: buffer-list &optional frame
     This function returns a list of all buffers, including those whose names begin with a space.  The elements are actual buffers, not their names.  The order of the list is specific to FRAME, which defaults to the current frame.  If FRAME is t, the global, non-frame ordering is returned instead.

          (buffer-list)
               => (#<buffer buffers.texi>
                   #<buffer  *Minibuf-1*> #<buffer buffer.c>
                   #<buffer *Help*> #<buffer TAGS>)

          ;; Note that the name of the minibuffer
          ;;   begins with a space!
          (mapcar (function buffer-name) (buffer-list))
              => ("buffers.texi" " *Minibuf-1*"
                  "buffer.c" "*Help*" "TAGS")

     Buffers appear earlier in the list if they were current more recently.

     This list is a copy of a list used inside XEmacs; modifying it has no effect on the buffers.

 -- Function: other-buffer &optional buffer-or-name frame visible-ok
     This function returns the first buffer in the buffer list other than BUFFER-OR-NAME, in FRAME's ordering for the buffer list. (FRAME defaults to the current frame.  If FRAME is t, then the global, non-frame ordering is used.) Usually this is the buffer most recently shown in the selected window, aside from BUFFER-OR-NAME.  Buffers are moved to the front of the list when they are selected and to the end when they are buried.  Buffers whose names start with a space are not considered.

     If BUFFER-OR-NAME is not supplied (or if it is not a buffer), then other-buffer returns the first buffer on the buffer list that is not visible in any window in a visible frame.

     If the selected frame has a non-nil buffer-predicate property, then other-buffer uses that predicate to decide which buffers to consider.  It calls the predicate once for each buffer, and if the value is nil, that buffer is ignored.  See X Frame Properties.

     If VISIBLE-OK is nil, other-buffer avoids returning a buffer visible in any window on any visible frame, except as a last resort.   If VISIBLE-OK is non-nil, then it does not matter whether a buffer is displayed somewhere or not.

     If no suitable buffer exists, the buffer *scratch* is returned (and created, if necessary).

     Note that in FSF Emacs 19, there is no FRAME argument, and VISIBLE-OK is the second argument instead of the third. FSF Emacs 19.

 -- Command: list-buffers &optional files-only
     This function displays a listing of the names of existing buffers.  It clears the buffer *Buffer List*, then inserts the listing into that buffer and displays it in a window.  list-buffers is intended for interactive use, and is described fully in The XEmacs Reference Manual.  It returns nil.

 -- Command: bury-buffer &optional buffer-or-name
     This function puts BUFFER-OR-NAME at the end of the buffer list without changing the order of any of the other buffers on the list. This buffer therefore becomes the least desirable candidate for other-buffer to return.

     If BUFFER-OR-NAME is nil or omitted, this means to bury the current buffer.  In addition, if the buffer is displayed in the selected window, this switches to some other buffer (obtained using other-buffer) in the selected window.  But if the buffer is displayed in some other window, it remains displayed there.

     If you wish to replace a buffer in all the windows that display it, use replace-buffer-in-windows.  See Buffers and Windows.

Creating Buffers
================

This section describes the two primitives for creating buffers. get-buffer-create creates a buffer if it finds no existing buffer with the specified name; generate-new-buffer always creates a new buffer and gives it a unique name.

Other functions you can use to create buffers include with-output-to-temp-buffer (see Temporary Displays) and create-file-buffer (see Visiting Files).  Starting a subprocess can also create a buffer (see Processes).

 -- Function: get-buffer-create name
     This function returns a buffer named NAME.  It returns an existing buffer with that name, if one exists; otherwise, it creates a new buffer.  The buffer does not become the current buffer---this function does not change which buffer is current.

     An error is signaled if NAME is not a string.

          (get-buffer-create "foo")
               => #<buffer foo>

     The major mode for the new buffer is set to Fundamental mode.  The variable default-major-mode is handled at a higher level. See Auto Major Mode.

 -- Function: generate-new-buffer name
     This function returns a newly created, empty buffer, but does not make it current.  If there is no buffer named NAME, then that is the name of the new buffer.  If that name is in use, this function adds suffixes of the form <N> to NAME, where N is an integer.  It tries successive integers starting with 2 until it finds an available name.

     An error is signaled if NAME is not a string.

          (generate-new-buffer "bar")
               => #<buffer bar>

          (generate-new-buffer "bar")
               => #<buffer bar<2>>

          (generate-new-buffer "bar")
               => #<buffer bar<3>>

     The major mode for the new buffer is set to Fundamental mode.  The variable default-major-mode is handled at a higher level. See Auto Major Mode.

     See the related function generate-new-buffer-name in Buffer Names.

Killing Buffers
===============

Killing a buffer makes its name unknown to XEmacs and makes its text space available for other use.

The buffer object for the buffer that has been killed remains in existence as long as anything refers to it, but it is specially marked so that you cannot make it current or display it.  Killed buffers retain their identity, however; two distinct buffers, when killed, remain distinct according to eq.

If you kill a buffer that is current or displayed in a window, XEmacs automatically selects or displays some other buffer instead.  This means that killing a buffer can in general change the current buffer. Therefore, when you kill a buffer, you should also take the precautions associated with changing the current buffer (unless you happen to know that the buffer being killed isn't current).  See Current Buffer.

If you kill a buffer that is the base buffer of one or more indirect buffers, the indirect buffers are automatically killed as well.

The buffer-name of a killed buffer is nil.  To test whether a buffer has been killed, you can either use this feature or the function buffer-live-p.

 -- Function: buffer-live-p buffer
     This function returns nil if BUFFER is deleted, and t otherwise.

 -- Command: kill-buffer buffer-or-name
     This function kills the buffer BUFFER-OR-NAME, freeing all its memory for use as space for other buffers.  (Emacs version 18 and older was unable to return the memory to the operating system.)  It returns nil.

     Any processes that have this buffer as the process-buffer are sent the SIGHUP signal, which normally causes them to terminate. (The basic meaning of SIGHUP is that a dialup line has been disconnected.)  See Deleting Processes.

     If the buffer is visiting a file and contains unsaved changes, kill-buffer asks the user to confirm before the buffer is killed. It does this even if not called interactively.  To prevent the request for confirmation, clear the modified flag before calling kill-buffer.  See Buffer Modification.

     Killing a buffer that is already dead has no effect.

          (kill-buffer "foo.unchanged")
               => nil
          (kill-buffer "foo.changed")

          ---------- Buffer: Minibuffer ----------
          Buffer foo.changed modified; kill anyway? (yes or no) yes
          ---------- Buffer: Minibuffer ----------

               => nil

 -- Variable: kill-buffer-query-functions
     After confirming unsaved changes, kill-buffer calls the functions in the list kill-buffer-query-functions, in order of appearance, with no arguments.  The buffer being killed is the current buffer when they are called.  The idea is that these functions ask for confirmation from the user for various nonstandard reasons.  If any of them returns nil, kill-buffer spares the buffer's life.

 -- Variable: kill-buffer-hook
     This is a normal hook run by kill-buffer after asking all the questions it is going to ask, just before actually killing the buffer. The buffer to be killed is current when the hook functions run. See Hooks.

 -- Variable: buffer-offer-save
     This variable, if non-nil in a particular buffer, tells save-buffers-kill-emacs and save-some-buffers to offer to save that buffer, just as they offer to save file-visiting buffers.  The variable buffer-offer-save automatically becomes buffer-local when set for any reason.  See Buffer-Local Variables.

Indirect Buffers
================

An indirect buffer shares the text of some other buffer, which is called the base buffer of the indirect buffer.  In some ways it is the analogue, for buffers, of a symbolic link among files.  The base buffer may not itself be an indirect buffer.  One base buffer may have several indirect children.

The text of the indirect buffer is always identical to the text of its base buffer; changes made by editing either one are visible immediately in the other.

But in all other respects, the indirect buffer and its base buffer are completely separate.  They have different names, different values of point and mark, different narrowing, different markers and extents (though inserting or deleting text in either buffer relocates the markers and extents for both), different major modes, and different local variables.  Unlike in FSF Emacs, XEmacs indirect buffers do not automatically share text properties among themselves and their base buffer.

An indirect buffer cannot visit a file, but its base buffer can.  If you try to save the indirect buffer, that actually works by saving the base buffer.

Killing an indirect buffer has no effect on its base buffer.  Killing the base buffer kills all its indirect children.

 -- Command: make-indirect-buffer base-buffer name
     This creates an indirect buffer named NAME whose base buffer is BASE-BUFFER.  The argument BASE-BUFFER may be a buffer or a string.

     If BASE-BUFFER is an indirect buffer, its base buffer is used as the base for the new buffer.

          (make-indirect-buffer "*scratch*" "indirect")
               => #<buffer "indirect">

 -- Function: buffer-base-buffer &optional buffer
     This function returns the base buffer of BUFFER.  If BUFFER is not indirect, the value is nil.  Otherwise, the value is another buffer, which is never an indirect buffer.  If BUFFER is not supplied, it defaults to the current buffer.

          (buffer-base-buffer (get-buffer "indirect"))
               => #<buffer "*scratch*">

 -- Function: buffer-indirect-children &optional buffer
     This function returns a list of all indirect buffers whose base buffer is BUFFER.  If BUFFER is indirect, the return value will always be nil; see make-indirect-buffer.  If BUFFER is not supplied, it defaults to the current buffer.

          (buffer-indirect-children (get-buffer "*scratch*"))
               => (#<buffer "indirect">)