;;;
;;; tm-mh-e.el --- MIME extender for mh-e
;;;
;;; Copyright (C) 1995 Free Software Foundation, Inc.
;;; Copyright (C) 1993,1994,1995 MORIOKA Tomohiko
;;;
;;; Author: MORIOKA Tomohiko <morioka@jaist.ac.jp>
;;; Keywords: mail, MH, MIME, multimedia, encoded-word, multilingual
;;;
;;; This file is part of tm (Tools for MIME).
;;;

;;; @ require modules
;;;

(require 'tl-str)
(require 'tl-misc)
(require 'mh-e)
(if (not (boundp 'mh-e-version))
    (require 'tm-mh-e3)
  )
(require 'tm-view)


;;; @ version
;;;

(defconst tm-mh-e/RCS-ID
  "$Id: tm-mh-e.el,v 7.1 1995/10/07 08:26:47 morioka Exp $")

(defconst tm-mh-e/version (get-version-string tm-mh-e/RCS-ID))


;;; @ variable
;;;

(defvar tm-mh-e/decode-all t
  "*If t, decode all of the message. Otherwise decode header only.")


;;; @ functions
;;;

(defun tm-mh-e/display-msg (msg-num folder &optional show-buffer mode)
  (or mode
      (setq mode tm-mh-e/decode-all)
      )
  ;; Display message NUMBER of FOLDER.
  ;; Sets the current buffer to the show buffer.
  (set-buffer folder)
  (or show-buffer
      (setq show-buffer mh-show-buffer))
  ;; Bind variables in folder buffer in case they are local
  (let ((msg-filename (mh-msg-filename msg-num)))
    (if (not (file-exists-p msg-filename))
	(error "Message %d does not exist" msg-num))
    (set-buffer show-buffer)
    (cond ((not (equal msg-filename buffer-file-name))
	   ;; Buffer does not yet contain message.
	   (clear-visited-file-modtime)
	   (unlock-buffer)
	   (setq buffer-file-name nil)	; no locking during setup
	   (setq buffer-read-only nil)
	   (erase-buffer)
	   (if mode
	       (progn
		 (let ((file-coding-system-for-read
			(if (boundp 'MULE) *noconv*))
		       kanji-fileio-code)
		   (insert-file-contents msg-filename)
		   ;; (goto-char (point-min))
		   (while (re-search-forward "\r$" nil t)
		     (replace-match "")
		     )
		   )
		 (set-buffer-modified-p nil)
		 (setq buffer-read-only t)
		 (mh-show-mode)
		 (mime/viewer-mode)
		 (goto-char (point-min))
		 )
	     (let ((clean-message-header mh-clean-message-header)
		   (invisible-headers mh-invisible-headers)
		   (visible-headers mh-visible-headers)
		   )
	       ;; 1995/9/21
	       ;;   modified by ARIURA <ariura@cc.tuat.ac.jp>
	       ;;   to support mhl.
	       (if mhl-formfile
		   (mh-exec-lib-cmd-output "mhl" "-nobell" "-noclear"
					   (if (stringp mhl-formfile)
					       (list "-form" mhl-formfile))
					   msg-filename)
		 (insert-file-contents msg-filename))
	       ;; end
	       (goto-char (point-min))
	       (cond (clean-message-header
		      (mh-clean-msg-header (point-min)
					   invisible-headers
					   visible-headers)
		      (goto-char (point-min)))
		     (t
		      (mh-start-of-uncleaned-message)))
	       (mime/decode-message-header)
	       (set-buffer-modified-p nil)
	       (setq buffer-read-only t)
	       (mh-show-mode)
	       ))
	   (or (eq buffer-undo-list t)	;don't save undo info for prev msgs
	       (setq buffer-undo-list nil))
	   (setq buffer-file-name msg-filename)
	   (set-mark nil)
	   (setq mode-line-buffer-identification
		 (list (format mh-show-buffer-mode-line-buffer-id
			       folder msg-num)))
	   (set-buffer folder)
	   (setq mh-showing-with-headers nil)))))

(fset 'mh-display-msg (symbol-function 'tm-mh-e/display-msg))

(defun tm-mh-e/view-message (&optional msg)
  "MIME decode and play this message."
  (interactive)
  (mh-invalidate-show-buffer)
  (let ((tm-mh-e/decode-all t))
    (mh-show-msg msg)
    )
  (pop-to-buffer (save-window-excursion
		   (switch-to-buffer mh-show-buffer)
		   mime::article/preview-buffer))
  )

(defun tm-mh-e/toggle-decoding-mode (arg)
  "Toggle MIME processing mode.
With arg, turn MIME processing on if arg is positive."
  (interactive "P")
  (setq tm-mh-e/decode-all
	(if (null arg)
	    (not tm-mh-e/decode-all)
	  arg))
  (save-window-excursion
    (switch-to-buffer mh-show-buffer)
    (if (null tm-mh-e/decode-all)
	(if (and mime::article/preview-buffer
		 (get-buffer mime::article/preview-buffer))
	    (kill-buffer mime::article/preview-buffer)
	  )))
  (mh-show (mh-get-msg-num t))
  (if tm-mh-e/decode-all
      (let ((the-buf (current-buffer)))
	(if mime::article/preview-buffer
	    (pop-to-buffer (save-excursion
			     (switch-to-buffer mh-show-buffer)
			     mime::article/preview-buffer))
	  (tm-mh-e/view-message (mh-get-msg-num t)))
	(pop-to-buffer the-buf)
	)))

(defun tm-mh-e/page-msg ()
  (interactive)
  (if tm-mh-e/decode-all
      (scroll-other-window)
    (mh-page-msg)
    ))

(defun tm-mh-e/previous-page ()
  (interactive)
  (if tm-mh-e/decode-all
      (scroll-other-window (- (save-window-excursion
				(other-window 1)
				(window-height))))
    (mh-previous-page)
    ))

(defun tm-mh-e/cite ()
  (interactive)
  (if tm-mh-e/decode-all
      (progn
	(if mh-delete-yanked-msg-window
	    (save-excursion
	      (set-buffer mh-sent-from-folder)
	      (set-buffer mh-show-buffer)
	      (delete-windows-on mime::article/preview-buffer)
	      ))
	(save-excursion
	  (save-restriction
	    (insert-buffer
	     (save-excursion
	       ;; 1995/9/21,
	       ;;   modified by Eric Ding <ericding@San-Jose.ate.slb.com>
	       ;;   (c.f. tm-eng:104)
	       (set-buffer mh-sent-from-folder)
	       (set-buffer mh-show-buffer)
	       (or mime::article/preview-buffer (current-buffer))
	       ;; end
	       ))
	    (if (looking-at "^\\[.+\\(\n[ \t].+\\)*\\]\n")
		(replace-match ""))
	    (narrow-to-region (point)(point-max))
	    (mh-insert-prefix-string mh-ins-buf-prefix)
	    )))
    (mh-yank-cur-msg)
    ))

(defun tm-mh-e/toggle-showing ()
  "Toggle the scanning mode/showing mode of displaying messages."
  (interactive)
  (if mh-showing
      (if tm-mh-e/decode-all
	  (let ((pbuf
		 (save-window-excursion
		   (set-buffer mh-show-buffer)
		   mime::article/preview-buffer)))
	    (if (get-buffer pbuf)
		(delete-windows-on pbuf)
	      )
	    (setq mh-showing nil)
	    (set-buffer-modified-p (buffer-modified-p)) ;force mode line update
	    (if mh-recenter-summary-p
		(mh-recenter nil)
	      ))
	(mh-set-scan-mode)
	)
    (mh-show)
    ))


;;; @ for tm-view
;;;

(fset 'tm-mh-e/code-convert-region-to-emacs
      (symbol-function 'mime/code-convert-region-to-emacs))

(defun tm-mh-e/content-header-filter ()
  (goto-char (point-min))
  (while (and (re-search-forward mime-viewer/ignored-field-regexp nil t)
	      (progn
		(delete-region
		 (match-beginning 0)
		 (save-excursion
		   (and
		    (re-search-forward "^\\([^ \t]\\|$\\)" nil t)
		    (match-beginning 0)
		    )))
		t)))
  (tm-mh-e/code-convert-region-to-emacs (point-min)(point-max)
					mime/default-coding-system)
  (mime/decode-message-header)
  (if (featurep 'hilit19)
      (hilit-rehighlight-buffer-quietly)
    )
  )

(defun tm-mh-e/quitting-method ()
  (let ((win (get-buffer-window
	      mime/output-buffer-name))
	(buf mime::preview/article-buffer)
	)
    (if win
	(delete-window win)
      )
    (pop-to-buffer
     (let ((name (buffer-name buf)))
       (substring name 5)
       ))
    (if (not tm-mh-e/decode-all)
	(mh-show (mh-get-msg-num t))
      )))


;;; @ for tm-comp
;;;

(defun tm-mh-e::make-message (folder number)
  (vector folder number)
  )

(defun tm-mh-e::message/folder (message)
  (elt message 0)
  )

(defun tm-mh-e::message/number (message)
  (elt message 1)
  )

(defun tm-mh-e::message/file-name (message)
  (expand-file-name
   (tm-mh-e::message/number message)
   (mh-expand-file-name (tm-mh-e::message/folder message))
   ))
  
(defun tm-mh-e::prompt-for-message (prompt folder &optional default)
  (let ((files
	 (directory-files (mh-expand-file-name folder) nil "^[0-9]+$")
	 ))
    (completing-read prompt
		     (let ((i 0))
		       (mapcar (function
				(lambda (file)
				  (setq i (+ i 1))
				  (list file i)
				  ))
			       files)
		       ))
    ))
				  
(defun tm-mh-e::query-message ()
  (let* ((folder (mh-prompt-for-folder "Visit" "+inbox" nil))
	 (number (tm-mh-e::prompt-for-message "Number?" folder))
	 )
    (tm-mh-e::make-message folder number)
    ))

(defun tm-mh-e::insert-message (&optional message)
  (if (null message)
      (setq message (tm-mh-e::query-message))
    )
  (insert-file (tm-mh-e::message/file-name message))
  )

(call-after-loaded
 'tm-comp
 (function
  (lambda ()
    (set-alist
     'tm-comp/message-inserter-alist
     'mh-letter-mode (function tm-mh-e::insert-message))
    )))


;;; @ set up
;;;

;;(add-hook 'mh-show-mode-hook (function mime/viewer-mode))

(define-key mh-folder-mode-map "v" (function tm-mh-e/view-message))
(define-key mh-folder-mode-map "\et" (function tm-mh-e/toggle-decoding-mode))
(define-key mh-folder-mode-map "t" (function tm-mh-e/toggle-showing))
(define-key mh-folder-mode-map "\r"
  (function (lambda ()
	      (interactive)
	      (scroll-other-window 1)
	      )))
(define-key mh-folder-mode-map "\e\r"
  (function (lambda ()
	      (interactive)
	      (scroll-other-window -1)
	      )))
(define-key mh-folder-mode-map " " (function tm-mh-e/page-msg))
(define-key mh-folder-mode-map "\177" (function tm-mh-e/previous-page))

(add-hook 'mh-letter-mode-hook
	  (function
	   (lambda ()
	     (define-key mh-letter-mode-map "\C-c\C-y" (function tm-mh-e/cite))
	     )))

(defun tm-mh-e/summary-before-quit ()
  (let ((buf (get-buffer mh-show-buffer)))
    (if buf
	(let ((the-buf (current-buffer)))
	  (switch-to-buffer buf)
	  (if (and mime::article/preview-buffer
		   (setq buf (get-buffer mime::article/preview-buffer))
		   )
	      (progn
		(switch-to-buffer the-buf)
		(kill-buffer buf)
		)
	    (switch-to-buffer the-buf)
	    )
	  ))))

(add-hook 'mh-before-quit-hook (function tm-mh-e/summary-before-quit))
	     
(set-alist 'mime-viewer/quitting-method-alist
	   'mh-show-mode
	   (function tm-mh-e/quitting-method))

(set-alist 'mime-viewer/content-header-filter-alist
	   'mh-show-mode
	   (function tm-mh-e/content-header-filter))

(set-alist 'mime-viewer/code-converter-alist
	   'mh-show-mode
	   (function tm-mh-e/code-convert-region-to-emacs))


;;; @ end
;;;

(provide 'tm-mh-e)

(run-hooks 'tm-mh-e-load-hook)