;;; pgg-pgp.el --- PGP 2.* and 6.* support for PGG.

;; Copyright (C) 1999 Daiki Ueno

;; Author: Daiki Ueno <ueno@ueda.info.waseda.ac.jp>
;; Created: 1999/11/02
;; Keywords: PGP, OpenPGP

;; This file is part of SEMI (Secure Emacs MIME Interface).

;; This program is free software; you can redistribute it and/or
;; modify it under the terms of the GNU General Public License as
;; published by the Free Software Foundation; either version 2, or (at
;; your option) any later version.

;; This program is distributed in the hope that it will be useful, but
;; WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;; General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Code:

(eval-when-compile (require 'pgg))

(defgroup pgg-pgp ()
  "PGP 2.* and 6.* interface"
  :group 'pgg)

(defcustom pgg-pgp-program "pgp" 
  "PGP 2.* and 6.* executable."
  :group 'pgg-pgp
  :type 'string)

(defcustom pgg-pgp-shell-file-name "/bin/sh"
  "The GnuPG executable."
  :group 'pgg-pgp
  :type 'string)

(defcustom pgg-pgp-extra-args nil
  "Extra arguments for every PGP invocation."
  :group 'pgg-pgp
  :type 'string)

(eval-and-compile
  (luna-define-class pgg-scheme-pgp (pgg-scheme))
  )
  
(defvar pgg-pgp-user-id nil
  "GnuPG ID of your default identity.")

(defvar pgg-scheme-pgp-instance nil)

;;;###autoload
(defun pgg-make-scheme-pgp ()
  (or pgg-scheme-pgp-instance
      (setq pgg-scheme-pgp-instance
	    (luna-make-entity 'pgg-scheme-pgp))))

(defun pgg-pgp-process-region (start end passphrase program args)
  (let* ((errors-file-name
	  (concat temporary-file-directory 
		  (make-temp-name "pgg-errors")))
	 (args 
	  (append args 
		  pgg-pgp-extra-args
		  (list (concat "2>" errors-file-name))))
	 (shell-file-name pgg-pgp-shell-file-name)
	 (output-buffer pgg-output-buffer)
	 (errors-buffer pgg-errors-buffer)
	 (process-connection-type nil)
	 process status exit-status)
    (with-current-buffer (get-buffer-create output-buffer)
      (buffer-disable-undo)
      (erase-buffer))
    (setq process
	  (apply #'start-process-shell-command "*PGP*" output-buffer
		 program args))
    (set-process-sentinel process 'ignore)
    (when passphrase
      (setenv "PGPPASSFD" "0")
      (process-send-string process (concat passphrase "\n")))
    (process-send-region process start end)
    (process-send-eof process)
    (while (eq 'run (process-status process))
      (accept-process-output process 5))
    (setq status (process-status process)
	  exit-status (process-exit-status process))
    (delete-process process)
    (with-current-buffer output-buffer
      (goto-char (point-min))
      (while (search-forward "\r$" nil t)
	(replace-match ""))
      (if (memq status '(stop signal))
	  (error "%s exited abnormally: '%s'" program exit-status))
      (if (= 127 exit-status)
	  (error "%s could not be found" program))

      (set-buffer (get-buffer-create errors-buffer))
      (buffer-disable-undo)
      (erase-buffer)
      (insert-file-contents errors-file-name)
      (delete-file errors-file-name)
      
      (if (and process (eq 'run (process-status process)))
	  (interrupt-process process))
      )
    ))

(luna-define-method encrypt-region ((scheme pgg-scheme-pgp) 
				    start end recipients)
  (let* ((pgg-pgp-user-id pgg-default-user-id)
	 (passphrase
	  (pgg-read-passphrase 
	   (format "PGP passphrase for %s: " pgg-pgp-user-id)))
	 (args 
	  `("+encrypttoself=off +verbose=1" "+batchmode"
	    "+language=us" "-fate"
	    ,@(if recipients
		  (mapcar (lambda (rcpt) (concat "\"" rcpt "\""))
			  recipients)))))
    (pgg-pgp-process-region start end passphrase 
			    pgg-pgp-program args)
    (with-current-buffer pgg-output-buffer
      (when (zerop (buffer-size))
	(insert-buffer-substring pgg-errors-buffer)))
    ))

(luna-define-method decrypt-region ((scheme pgg-scheme-pgp) 
				    start end)
  (let* ((pgg-pgp-user-id pgg-default-user-id)
	 (passphrase
	  (pgg-read-passphrase 
	   (format "PGP passphrase for %s: " pgg-pgp-user-id)))
	 (args 
	  '("+verbose=1" "+batchmode" "+language=us" "-f")))
    (pgg-pgp-process-region start end passphrase 
			    pgg-pgp-program args)
    (with-current-buffer pgg-output-buffer
      (when (zerop (buffer-size))
	(insert-buffer-substring pgg-errors-buffer)))
    ))

(luna-define-method sign-region ((scheme pgg-scheme-pgp) 
				 start end)
  (let* ((pgg-pgp-user-id pgg-default-user-id)
	 (passphrase
	  (pgg-read-passphrase 
	   (format "PGP passphrase for %s: " pgg-pgp-user-id)))
	 (args 
	  (list "-fbast" "+verbose=1" "+language=us" "+batchmode"
		"-u" pgg-pgp-user-id)))
    (pgg-pgp-process-region start end passphrase 
			     pgg-pgp-program args)
    (with-current-buffer pgg-output-buffer
      (when (zerop (buffer-size))
	(insert-buffer-substring pgg-errors-buffer)))
    ))

(luna-define-method verify-region ((scheme pgg-scheme-pgp) 
				   start end &optional signature)
  (let* ((basename (expand-file-name "pgg" temporary-file-directory))
	 (orig-file (make-temp-name basename))
	 (args '("+verbose=1" "+batchmode" "+language=us")))
    (write-region-as-binary start end orig-file)
    (when (stringp signature)
      (copy-file signature (setq signature (concat orig-file ".asc")))
      (setq args (append args (list signature orig-file)))
      )
    (pgg-pgp-process-region (point-min)(point-max) nil
			    pgg-pgp-program args)
    (delete-file orig-file)
    (delete-file signature)
    (set-buffer pgg-output-buffer)
    (with-current-buffer pgg-output-buffer
      (when (zerop (buffer-size))
	(insert-buffer-substring pgg-errors-buffer)))
    ))

(luna-define-method insert-key ((scheme pgg-scheme-pgp))
  (let* ((pgg-pgp-user-id pgg-default-user-id)
	 (args
	  (list "+verbose=1" "+batchmode" "+language=us" "-kxaf" 
		(concat "\"" pgg-pgp-user-id "\""))))
    (pgg-pgp-process-region (point)(point) nil
			     pgg-pgp-program args)
    (insert-buffer-substring pgg-output-buffer)
    ))

(luna-define-method snarf-keys-region ((scheme pgg-scheme-pgp)
				       start end)
  (let* ((pgg-pgp-user-id pgg-default-user-id)
	 (basename (expand-file-name "pgg" temporary-file-directory))
	 (key-file (make-temp-name basename))
	 (args 
	  (list "+verbose=1" "+batchmode" "+language=us" "-kaf" 
		key-file)))
    (write-region-as-raw-text-CRLF start end key-file)
    (pgg-pgp-process-region start end nil
			    pgg-pgp-program args)
    (delete-file key-file)
    ))

(provide 'pgg-pgp)

;;; pgg-pgp.el ends here