+(defun mml-insert-buffer (buffer)
+ "Insert BUFFER at point and quote any MML markup."
+ (save-restriction
+ (narrow-to-region (point) (point))
+ (insert-buffer-substring buffer)
+ (mml-quote-region (point-min) (point-max))
+ (goto-char (point-max))))
+
+;;;
+;;; Transforming MIME to MML
+;;;
+
+(defun mime-to-mml ()
+ "Translate the current buffer (which should be a message) into MML."
+ ;; First decode the head.
+ (save-restriction
+ (message-narrow-to-head)
+ (mail-decode-encoded-word-region (point-min) (point-max)))
+ (let ((handles (mm-dissect-buffer t)))
+ (goto-char (point-min))
+ (search-forward "\n\n" nil t)
+ (delete-region (point) (point-max))
+ (if (stringp (car handles))
+ (mml-insert-mime handles)
+ (mml-insert-mime handles t))
+ (mm-destroy-parts handles))
+ (save-restriction
+ (message-narrow-to-head)
+ ;; Remove them, they are confusing.
+ (message-remove-header "Content-Type")
+ (message-remove-header "MIME-Version")
+ (message-remove-header "Content-Transfer-Encoding")))
+
+(defun mml-to-mime ()
+ "Translate the current buffer from MML to MIME."
+ (message-encode-message-body)
+ (save-restriction
+ (message-narrow-to-headers-or-head)
+ (let ((mail-parse-charset message-default-charset))
+ (mail-encode-encoded-word-buffer))))
+
+(defun mml-insert-mime (handle &optional no-markup)
+ (let (textp buffer mmlp)
+ ;; Determine type and stuff.
+ (unless (stringp (car handle))
+ (unless (setq textp (equal (mm-handle-media-supertype handle) "text"))
+ (save-excursion
+ (set-buffer (setq buffer (mml-generate-new-buffer " *mml*")))
+ (mm-insert-part handle)
+ (if (setq mmlp (equal (mm-handle-media-type handle)
+ "message/rfc822"))
+ (mime-to-mml)))))
+ (if mmlp
+ (mml-insert-mml-markup handle nil t t)
+ (unless (and no-markup
+ (equal (mm-handle-media-type handle) "text/plain"))
+ (mml-insert-mml-markup handle buffer textp)))
+ (cond
+ (mmlp
+ (insert-buffer buffer)
+ (goto-char (point-max))
+ (insert "<#/mml>\n"))
+ ((stringp (car handle))
+ (mapcar 'mml-insert-mime (cdr handle))
+ (insert "<#/multipart>\n"))
+ (textp
+ (let ((text (mm-get-part handle))
+ (charset (mail-content-type-get
+ (mm-handle-type handle) 'charset)))
+ (insert (mm-decode-string text charset)))
+ (goto-char (point-max)))
+ (t
+ (insert "<#/part>\n")))))
+
+(defun mml-insert-mml-markup (handle &optional buffer nofile mmlp)
+ "Take a MIME handle and insert an MML tag."
+ (if (stringp (car handle))
+ (insert "<#multipart type=" (mm-handle-media-subtype handle)
+ ">\n")
+ (if mmlp
+ (insert "<#mml type=" (mm-handle-media-type handle))
+ (insert "<#part type=" (mm-handle-media-type handle)))
+ (dolist (elem (append (cdr (mm-handle-type handle))
+ (cdr (mm-handle-disposition handle))))
+ (insert " " (symbol-name (car elem)) "=\"" (cdr elem) "\""))
+ (when (mm-handle-disposition handle)
+ (insert " disposition=" (car (mm-handle-disposition handle))))
+ (when buffer
+ (insert " buffer=\"" (buffer-name buffer) "\""))
+ (when nofile
+ (insert " nofile=yes"))
+ (when (mm-handle-description handle)
+ (insert " description=\"" (mm-handle-description handle) "\""))
+ (insert ">\n")))
+
+(defun mml-insert-parameter (&rest parameters)
+ "Insert PARAMETERS in a nice way."
+ (dolist (param parameters)
+ (insert ";")
+ (let ((point (point)))
+ (insert " " param)
+ (when (> (current-column) 71)
+ (goto-char point)
+ (insert "\n ")
+ (end-of-line)))))
+
+;;;
+;;; Mode for inserting and editing MML forms
+;;;
+
+(defvar mml-mode-map
+ (let ((sign (make-sparse-keymap))
+ (encrypt (make-sparse-keymap))
+ (map (make-sparse-keymap))
+ (main (make-sparse-keymap)))
+ (define-key sign "p" 'mml-secure-sign-pgpmime)
+ (define-key sign "s" 'mml-secure-sign-smime)
+ (define-key encrypt "p" 'mml-secure-encrypt-pgpmime)
+ (define-key encrypt "s" 'mml-secure-encrypt-smime)
+ (define-key map "f" 'mml-attach-file)
+ (define-key map "b" 'mml-attach-buffer)
+ (define-key map "e" 'mml-attach-external)
+ (define-key map "q" 'mml-quote-region)
+ (define-key map "m" 'mml-insert-multipart)
+ (define-key map "p" 'mml-insert-part)
+ (define-key map "v" 'mml-validate)
+ (define-key map "P" 'mml-preview)
+ (define-key map "s" sign)
+ (define-key map "c" encrypt)
+ ;;(define-key map "n" 'mml-narrow-to-part)
+ (define-key main "\M-m" map)
+ main))
+
+(easy-menu-define
+ mml-menu mml-mode-map ""
+ '("MML"
+ ("Attach"
+ ["File" mml-attach-file t]
+ ["Buffer" mml-attach-buffer t]
+ ["External" mml-attach-external t])
+ ("Insert"
+ ["Multipart" mml-insert-multipart t]
+ ["Part" mml-insert-part t])
+ ("Security"
+ ("Sign"
+ ["PGP/MIME" mml-secure-sign-pgpmime t]
+ ["S/MIME" mml-secure-sign-smime t])
+ ("Encrypt"
+ ["PGP/MIME" mml-secure-encrypt-pgpmime t]
+ ["S/MIME" mml-secure-encrypt-smime t]))
+ ;;["Narrow" mml-narrow-to-part t]
+ ["Quote" mml-quote-region t]
+ ["Validate" mml-validate t]
+ ["Preview" mml-preview t]))
+
+(defvar mml-mode nil
+ "Minor mode for editing MML.")
+
+(defun mml-mode (&optional arg)
+ "Minor mode for editing MML.
+
+\\{mml-mode-map}"
+ (interactive "P")
+ (when (set (make-local-variable 'mml-mode)
+ (if (null arg) (not mml-mode)
+ (> (prefix-numeric-value arg) 0)))
+ (gnus-add-minor-mode 'mml-mode " MML" mml-mode-map)
+ (easy-menu-add mml-menu mml-mode-map)
+ (run-hooks 'mml-mode-hook)))
+
+;;;
+;;; Helper functions for reading MIME stuff from the minibuffer and
+;;; inserting stuff to the buffer.
+;;;
+
+(defun mml-minibuffer-read-file (prompt)
+ (let ((file (read-file-name prompt nil nil t)))
+ ;; Prevent some common errors. This is inspired by similar code in
+ ;; VM.
+ (when (file-directory-p file)
+ (error "%s is a directory, cannot attach" file))
+ (unless (file-exists-p file)
+ (error "No such file: %s" file))
+ (unless (file-readable-p file)
+ (error "Permission denied: %s" file))
+ file))
+
+(defun mml-minibuffer-read-type (name &optional default)
+ (mailcap-parse-mimetypes)
+ (let* ((default (or default
+ (mm-default-file-encoding name)
+ ;; Perhaps here we should check what the file
+ ;; looks like, and offer text/plain if it looks
+ ;; like text/plain.
+ "application/octet-stream"))
+ (string (completing-read
+ (format "Content type (default %s): " default)
+ (mapcar 'list (mailcap-mime-types)))))
+ (if (not (equal string ""))
+ string
+ default)))
+
+(defun mml-minibuffer-read-description ()
+ (let ((description (read-string "One line description: ")))
+ (when (string-match "\\`[ \t]*\\'" description)
+ (setq description nil))
+ description))
+
+(defun mml-quote-region (beg end)
+ "Quote the MML tags in the region."
+ (interactive "r")
+ (save-excursion
+ (save-restriction
+ ;; Temporarily narrow the region to defend from changes
+ ;; invalidating END.
+ (narrow-to-region beg end)
+ (goto-char (point-min))
+ ;; Quote parts.
+ (while (re-search-forward
+ "<#!*/?\\(multipart\\|part\\|external\\|mml\\)" nil t)
+ ;; Insert ! after the #.
+ (goto-char (+ (match-beginning 0) 2))
+ (insert "!")))))
+
+(defun mml-insert-tag (name &rest plist)
+ "Insert an MML tag described by NAME and PLIST."
+ (when (symbolp name)
+ (setq name (symbol-name name)))
+ (insert "<#" name)
+ (while plist
+ (let ((key (pop plist))
+ (value (pop plist)))
+ (when value
+ ;; Quote VALUE if it contains suspicious characters.
+ (when (string-match "[\"'\\~/*;() \t\n]" value)
+ (setq value (prin1-to-string value)))
+ (insert (format " %s=%s" key value)))))
+ (insert ">\n"))
+
+(defun mml-insert-empty-tag (name &rest plist)
+ "Insert an empty MML tag described by NAME and PLIST."
+ (when (symbolp name)
+ (setq name (symbol-name name)))
+ (apply #'mml-insert-tag name plist)
+ (insert "<#/" name ">\n"))
+
+;;; Attachment functions.
+
+(defun mml-attach-file (file &optional type description)
+ "Attach a file to the outgoing MIME message.
+The file is not inserted or encoded until you send the message with
+`\\[message-send-and-exit]' or `\\[message-send]'.
+
+FILE is the name of the file to attach. TYPE is its content-type, a
+string of the form \"type/subtype\". DESCRIPTION is a one-line
+description of the attachment."
+ (interactive
+ (let* ((file (mml-minibuffer-read-file "Attach file: "))
+ (type (mml-minibuffer-read-type file))
+ (description (mml-minibuffer-read-description)))
+ (list file type description)))
+ (mml-insert-empty-tag 'part 'type type 'filename file
+ 'disposition "attachment" 'description description))
+
+(defun mml-attach-buffer (buffer &optional type description)
+ "Attach a buffer to the outgoing MIME message.
+See `mml-attach-file' for details of operation."
+ (interactive
+ (let* ((buffer (read-buffer "Attach buffer: "))
+ (type (mml-minibuffer-read-type buffer "text/plain"))
+ (description (mml-minibuffer-read-description)))
+ (list buffer type description)))
+ (mml-insert-empty-tag 'part 'type type 'buffer buffer
+ 'disposition "attachment" 'description description))
+
+(defun mml-attach-external (file &optional type description)
+ "Attach an external file into the buffer.
+FILE is an ange-ftp/efs specification of the part location.
+TYPE is the MIME type to use."
+ (interactive
+ (let* ((file (mml-minibuffer-read-file "Attach external file: "))
+ (type (mml-minibuffer-read-type file))
+ (description (mml-minibuffer-read-description)))
+ (list file type description)))
+ (mml-insert-empty-tag 'external 'type type 'name file
+ 'disposition "attachment" 'description description))
+
+(defun mml-insert-multipart (&optional type)
+ (interactive (list (completing-read "Multipart type (default mixed): "
+ '(("mixed") ("alternative") ("digest") ("parallel")
+ ("signed") ("encrypted"))
+ nil nil "mixed")))
+ (or type
+ (setq type "mixed"))
+ (mml-insert-empty-tag "multipart" 'type type)
+ (forward-line -1))
+
+(defun mml-insert-part (&optional type)
+ (interactive
+ (list (mml-minibuffer-read-type "")))
+ (mml-insert-tag 'part 'type type 'disposition "inline")
+ (forward-line -1))
+
+(defun mml-preview (&optional raw)
+ "Display current buffer with Gnus, in a new buffer.
+If RAW, don't highlight the article."
+ (interactive "P")
+ (let ((buf (current-buffer))
+ (message-options message-options)
+ (message-posting-charset (or (gnus-setup-posting-charset
+ (save-restriction
+ (message-narrow-to-headers-or-head)
+ (message-fetch-field "Newsgroups")))
+ message-posting-charset)))
+ (message-options-set-recipient)
+ (switch-to-buffer (generate-new-buffer
+ (concat (if raw "*Raw MIME preview of "
+ "*MIME preview of ") (buffer-name))))
+ (erase-buffer)
+ (insert-buffer buf)
+ (if (re-search-forward
+ (concat "^" (regexp-quote mail-header-separator) "\n") nil t)
+ (replace-match "\n"))
+ (mml-to-mime)
+ (if raw
+ (when (fboundp 'set-buffer-multibyte)
+ (let ((s (buffer-string)))
+ ;; Insert the content into unibyte buffer.
+ (erase-buffer)
+ (mm-disable-multibyte)
+ (insert s)))
+ (let ((gnus-newsgroup-charset (car message-posting-charset)))
+ (run-hooks 'gnus-article-decode-hook)
+ (let ((gnus-newsgroup-name "dummy"))
+ (gnus-article-prepare-display))))
+ (fundamental-mode)
+ (setq buffer-read-only t)
+ (goto-char (point-min))))
+
+(defun mml-validate ()
+ "Validate the current MML document."
+ (interactive)
+ (mml-parse))
+