0e645ae8b005e540d4762f2f50d2ee16cd7f8a51
[chise/xemacs-chise.git.1] / configure.in
1 dnl Define our own header notice with own copyright
2 define([AC_INIT_NOTICE],
3 [#### Configuration script for XEmacs.  Largely divergent from FSF.
4 #### Guess values for system-dependent variables and create Makefiles.
5 #### Generated automatically using autoconf version] AC_ACVERSION [
6 #### Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000 Free Software Foundation, Inc.
7 #### Copyright (C) 1993-1995 Board of Trustees, University of Illinois.
8 #### Copyright (C) 1996, 1997 Sun Microsystems, Inc.
9 #### Copyright (C) 1995, 1996, 2005 Ben Wing.
10 #### Copyright (C) 2000, 2001 Martin Buchholz.
11 #### Copyright (C) 1998, 1999 J. Kean Johnston.
12
13 ### Don't edit this script!
14 ### This script was automatically generated by the `autoconf' program
15 ### from the file `./configure.in'.
16 ### To rebuild it, execute the command
17 ###     autoconf
18 ### in the this directory.  You must have autoconf version 2.13 or later.
19 ### Note: this script has not yet been ported to autoconf version 2.5x.
20
21 ### This file is part of XEmacs.
22
23 ### XEmacs is free software; you can redistribute it and/or modify it
24 ### under the terms of the GNU General Public License as published by
25 ### the Free Software Foundation; either version 2, or (at your
26 ### option) any later version.
27
28 ### XEmacs is distributed in the hope that it will be useful, but
29 ### WITHOUT ANY WARRANTY; without even the implied warranty of
30 ### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
31 ### General Public License for more details.
32
33 ### You should have received a copy of the GNU General Public License
34 ### along with XEmacs; see the file COPYING.  If not, write to the Free
35 ### Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
36 ### 02111-1307, USA.
37
38 ### For usage, run `./configure --help'
39 ### For more detailed information on building and installing XEmacs,
40 ### read the file `INSTALL'.
41 ###
42 ### If configure succeeds, it leaves its status in config.status.
43 ### A log of configuration tests can be found in config.log.
44 ### If configure fails after disturbing the status quo,
45 ###     config.status is removed.
46 ])
47
48 dnl Since XEmacs has configuration requirements that autoconf cannot
49 dnl meet, this file is an unholy marriage of custom-baked
50 dnl configuration code and autoconf macros.
51
52 dnl We use the m4 quoting characters [ ] (as established by the
53 dnl autoconf system), so quote them like this: [[foo]]
54
55 AC_PREREQ(2.13)dnl
56 dnl Redefine some standard autoconf macros
57 dnl here is how XEmacs is different:
58 dnl - no cache file
59 dnl - non-standard options
60 dnl - support for extra-verbosity
61 dnl - ordinary libs are handled separately from X libs (might be a mistake)
62 dnl - various random kludges (e.g. -with-dnet=no)
63
64 dnl PRINT_VAR(var var ...)  prints values of shell variables
65 define([PRINT_VAR],[for var in patsubst([$1],[[
66 ]+],[ ]); do eval "echo \"$var = '\$$var'\""; done])
67
68 dnl Disable cache files:
69 dnl This is controversial, but I am convinced this is the right way to go,
70 dnl at least by default.  Otherwise there are too many surprises.
71 define([AC_CACHE_LOAD], )dnl
72 define([AC_CACHE_SAVE], )dnl
73 define([AC_CACHE_VAL], [
74 $2
75 ])dnl
76
77 dnl Redefine AC_TRY_RUN_NATIVE to not throw away stderr while running
78 dnl AC_TRY_RUN_NATIVE(PROGRAM, [ACTION-IF-TRUE [, ACTION-IF-FALSE]])
79 define([AC_TRY_RUN_NATIVE],
80 [cat > conftest.$ac_ext <<EOF
81 [#]line __oline__ "configure"
82 #include "confdefs.h"
83 [$1]
84 EOF
85 if AC_TRY_EVAL(ac_link) && test -s conftest && (./conftest; exit $?) 2>&AC_FD_CC
86 then
87 dnl Do not remove the temporary files here, so they can be examined.
88   ifelse([$2], , :, [$2])
89 else
90   conftest_rc="$?"
91   echo "configure: failed program was:" >&AC_FD_CC
92   cat conftest.$ac_ext >&AC_FD_CC
93 ifelse([$3], , , [  rm -fr conftest*
94   $3
95 ])dnl
96 fi
97 rm -fr conftest*])dnl AC_TRY_RUN_NATIVE
98
99
100 dnl Avoid spurious cross-compiling warnings from AC_TRY_RUN
101 dnl XEmacs is unlikely to ever cross-compile
102 define([AC_TRY_RUN],[AC_TRY_RUN_NATIVE([$1], [$2], [$3])])dnl
103
104 dnl Redefine AC_DEFINE* to provide more output if extra_verbose
105 dnl Set VARIABLE to VALUE, verbatim, or 1.
106 dnl AC_DEFINE(VARIABLE [, VALUE])
107 define([AC_DEFINE],
108 [{ test "$extra_verbose" = "yes" && cat << \EOF
109     Defining $1[]ifelse($#, 2, [ = $2],)
110 EOF
111 cat >> confdefs.h <<\EOF
112 [#define] $1 ifelse($#, 2, [$2], 1)
113 EOF
114 }
115 ])dnl AC_DEFINE
116
117 define([AC_DEFINE_UNQUOTED],
118 [{ test "$extra_verbose" = "yes" && cat << EOF
119     Defining $1[]ifelse($#, 2, [ = $2],)
120 EOF
121 cat >> confdefs.h <<EOF
122 [#define] $1 ifelse($#, 2, [$2], 1)
123 EOF
124 }
125 ])dnl AC_DEFINE_UNQUOTED
126
127 dnl redefine AC_CHECK_LIB in accordance with our own value of ac_link
128 dnl Add in extra kludgy check to support with_dnet=no
129 dnl Add in extra LDFLAGS arg, which PRECEDES libs
130 dnl Support --with-dnet=no
131
132 dnl AC_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND
133 dnl             [, OTHER-LIBRARIES] [, LDFLAGS]]]])
134 define([AC_CHECK_LIB],
135 [ifelse([$1],dnet, [if test "$with_dnet" = "no" ; then
136 ac_cv_lib_dnet_dnet_ntoa=no
137 ifelse([$4], , , [$4]
138 )dnl
139 else
140 ])]
141 AC_CHECK_LIB_ORIG_HACKED([$1],[$2],[$3],[$4],[$5], [$6])
142 [ifelse([$1],dnet,[fi
143 ])]dnl
144 )dnl AC_CHECK_LIB
145
146 define([AC_CHECK_LIB_ORIG_HACKED],
147 [ifelse([$5],,AC_MSG_CHECKING([for $2 in -l$1]),
148 xe_msg_checking="for [$2] in -l[$1]"
149 test -n "[$5]" && xe_msg_checking="$xe_msg_checking using extra libs [$5]"
150 AC_MSG_CHECKING("$xe_msg_checking"))
151 dnl Use a cache variable name containing both the library and function name,
152 dnl because the test really is for library $1 defining function $2, not
153 dnl just for library $1.  Separate tests with the same $1 and different $2s
154 dnl may have different results.
155 ac_lib_var=`echo $1['_']$2 | sed 'y%./+-%__p_%'`
156 AC_CACHE_VAL(ac_cv_lib_$ac_lib_var,
157 [xe_check_libs="$6 -l$1 $5"
158 AC_TRY_LINK(dnl
159 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
160 [/* Override any gcc2 internal prototype to avoid an error.  */
161 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
162 extern "C"
163 #endif
164 ])dnl
165 [/* We use char because int might match the return type of a gcc2
166     builtin and then its argument prototype would still apply.  */
167 char $2();
168 ]),
169             [$2()],
170             eval "ac_cv_lib_$ac_lib_var=yes",
171             eval "ac_cv_lib_$ac_lib_var=no")
172 xe_check_libs=""
173 ])dnl
174 if eval "test \"`echo '$ac_cv_lib_'$ac_lib_var`\" = yes" ; then
175   AC_MSG_RESULT(yes)
176   ifelse([$3], ,
177 [changequote(, )dnl
178   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
179     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
180 changequote([, ])dnl
181   AC_DEFINE_UNQUOTED($ac_tr_lib)
182   XE_PREPEND([-l$1], LIBS)
183 ], [$3])
184 else
185   AC_MSG_RESULT(no)
186 ifelse([$4], , , [$4
187 ])dnl
188 fi
189 ])dnl AC_CHECK_LIB_ORIG_HACKED
190
191
192 dnl AC_LANG_C()
193 define([AC_LANG_C],
194 [define([AC_LANG], [C])dnl
195 ac_ext=c
196 dnl CFLAGS is not in ac_cpp because -g, -O, etc. are not valid cpp options.
197 dnl ac_cpp='$CPP $CPPFLAGS'
198 dnl ac_compile='${CC-cc} -c $CFLAGS $CPPFLAGS conftest.$ac_ext 1>&AC_FD_CC'
199 dnl ac_link='${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS conftest.$ac_ext $LIBS 1>&AC_FD_CC'
200 xe_cppflags='$CPPFLAGS $c_switch_site $c_switch_machine $c_switch_system $c_switch_x_site $X_CFLAGS'
201 xe_ldflags='$LDFLAGS $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_x_site $ld_switch_run'
202 xe_libs='$ld_call_shared $xe_check_libs $X_EXTRA_LIBS $libs_x $libs_gtk $X_PRE_LIBS $LIBS $libs_machine $libs_system $libs_standard'
203 ac_cpp='$CPP '"$xe_cppflags"
204 ac_compile='${CC-cc} -c $CFLAGS '"$xe_cppflags"' conftest.$ac_ext 1>&AC_FD_CC'
205 ac_link='${CC-cc} -o conftest $CFLAGS '"$xe_cppflags $xe_ldflags"' conftest.$ac_ext '"$xe_libs"' 1>&AC_FD_CC'
206 cross_compiling=no
207 ]) dnl AC_LANG_C
208
209 dnl The construct foo=`echo $w1 $w2 $w3` fails on some systems if $w1 = -e or -n
210 dnl So we use the following instead.
211 dnl XE_SPACE(var, words)
212 define([XE_SPACE],[
213 T=""
214 for W in $2; do if test -z "$T"; then T="$W"; else T="$T $W"; fi; done
215 $1="$T"
216 ])dnl XE_SPACE
217
218 dnl XE_ADD_OBJS(foo.o ...)
219 define([XE_ADD_OBJS],
220 [extra_objs="$extra_objs [$1]" && dnl
221  if test "$extra_verbose" = "yes"; then
222    echo "    xemacs will be linked with \"[$1]\""
223  fi])dnl XE_ADD_OBJS
224
225 dnl XE_APPEND(value, varname)
226 define([XE_APPEND],
227 [[$2]="$[$2] [$1]" && dnl
228  if test "$extra_verbose" = "yes"; then echo "    Appending \"[$1]\" to \$[$2]"; fi])
229
230 dnl XE_PREPEND(value, varname)
231 define([XE_PREPEND],
232 [[$2]="[$1] $[$2]" && dnl
233  if test "$extra_verbose" = "yes"; then echo "    Prepending \"[$1]\" to \$[$2]"; fi])
234
235 dnl XE_DIE(message)
236 define([XE_DIE], [{ echo "Error:" $1 >&2; exit 1; }])
237
238 dnl XE_STRIP_4TH_COMPONENT(var)
239 dnl Changes i986-pc-linux-gnu to i986-pc-linux, as God (not RMS) intended.
240 define([XE_STRIP_4TH_COMPONENT],
241 [$1=`echo "$$1" | sed '[s/^\([^-][^-]*-[^-][^-]*-[^-][^-]*\)-.*$/\1/]'`])
242
243 dnl Initialize some variables set by options.
244 dnl The variables have the same names as the options, with
245 dnl dashes changed to underlines.
246
247 define([AC_INIT_PARSE_ARGS],[
248
249 dnl Get sane consistent behavior from various shells
250 dnl Avoid losing with weird user CDPATHs
251
252 if test -n "$ZSH_VERSION"; then
253   dnl zsh's Bourne shell emulation options
254   setopt NO_BAD_PATTERN NO_BANG_HIST NO_BG_NICE NO_EQUALS NO_FUNCTION_ARGZERO
255   setopt GLOB_SUBST NO_HUP INTERACTIVE_COMMENTS KSH_ARRAYS NO_MULTIOS NO_NOMATCH
256   setopt RM_STAR_SILENT POSIX_BUILTINS SH_FILE_EXPANSION SH_GLOB SH_OPTION_LETTERS
257   setopt SH_WORD_SPLIT BSD_ECHO IGNORE_BRACES
258   dnl zsh-3.1-beta drops core on the following
259   dnl unset CDPATH
260   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
261 elif test -n "$BASH_VERSION"; then
262   dnl Use Posix mode with bash
263   set -o posix
264   unset CDPATH
265 else
266   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
267 fi
268
269 dnl Initialize some variables set by options.
270 dnl The variables have the same names as the options, with
271 dnl dashes changed to underlines.
272 exec_prefix=NONE
273 host=NONE
274 no_create=
275 nonopt=NONE
276 no_recursion=
277 prefix=NONE
278 program_prefix=NONE
279 program_suffix=NONE
280 program_transform_name=s,x,x,
281 silent=
282 site=
283 srcdir=
284 target=NONE
285 verbose=
286 x_includes=NONE
287 x_libraries=NONE
288
289 dnl Initialize some other variables.
290 subdirs=
291 MFLAGS= MAKEFLAGS=
292 SHELL=${CONFIG_SHELL-/bin/sh}
293 dnl Maximum number of lines to put in a shell here document.
294 ac_max_here_lines=12
295 ])dnl AC_INIT_PARSE_ARGS
296
297 AC_INIT(src/lisp.h)dnl
298 AC_CONFIG_HEADER(src/config.h lwlib/config.h)
299 dnl Remove any more than one leading "." element from the path name.
300 dnl If we do not remove them, then another "./" will be prepended to
301 dnl the file name each time we use config.status, and the program name
302 dnl will get larger and larger.  This would not be a problem, except
303 dnl that since progname gets recorded in all the Makefiles this script
304 dnl produces, move-if-change thinks they're different when they're
305 dnl not.
306 dnl
307 dnl It would be nice if we could put the ./ in a \( \) group and then
308 dnl apply the * operator to that, so we remove as many leading './././'s
309 dnl as are present, but some seds (like Ultrix's sed) don't allow you to
310 dnl apply * to a \( \) group.  Bleah.
311 progname="`echo $0 | sed 's:^\./\./:\./:'`"
312
313 dnl -----------------------------
314 dnl Establish some default values
315 dnl -----------------------------
316
317 XE_APPEND(lib-src, MAKE_SUBDIR)
318 XE_APPEND(lib-src, INSTALL_ARCH_DEP_SUBDIR)
319
320 prefix='/usr/local'
321 exec_prefix='${prefix}'
322 bindir='${exec_prefix}/bin'
323 dnl FSF 19.29 changes to:
324 dnl datadir='${prefix}/share'
325 dnl sharedstatedir='${prefix}/com'
326 dnl libexecdir='${exec_prefix}/libexec'
327 datadir='${prefix}/lib'
328 statedir='${prefix}/lib'
329 libdir='${exec_prefix}/lib'
330 mandir='${prefix}/man/man1'
331 inststaticdir='${PROGNAME}'
332 instvardir='${PROGNAME}-${version}'
333 infodir='${datadir}/${instvardir}/info'
334 infopath=''
335 install_pp=''
336 lispdir='${datadir}/${instvardir}/lisp'
337 moduledir='${libdir}/${instvardir}/${configuration}/modules'
338 sitelispdir='${datadir}/${inststaticdir}/site-lisp'
339 sitemoduledir='${libdir}/${inststaticdir}/site-modules'
340 pkgdir='${datadir}/${instvardir}/lisp'
341 package_path=''
342 etcdir='${datadir}/${instvardir}/etc'
343 archlibdir='${libdir}/${instvardir}/${configuration}'
344 docdir='${archlibdir}'
345 with_netinstall="no"
346 with_prefix='yes'
347 with_site_lisp='no'
348 with_site_modules='yes'
349 with_menubars=''
350 with_scrollbars=''
351 dnl can't turn off widgets here because of systems where they are demanded
352 with_widgets=''
353 with_dialogs=''
354 with_file_coding=''
355 cpp='' cppflags='' libs='' ldflags=''
356 extra_includes=''
357 dynamic=''
358 with_x11=''
359 with_msw=''
360 rel_alloc='default'
361 with_system_malloc='default'
362 with_dlmalloc='default'
363 use_regex_malloc='yes'
364 dnl ESD is associated with crashes and lockups due to incorrect signal use.
365 with_esd_sound='no'
366 native_sound_lib=''
367 dnl These should be set to the empty string when we want gtk / gnome to
368 dnl be auto-detected instead of manually specified.
369 with_gtk='no'
370 with_gnome='no'
371 dnl use_assertions should be 'yes' by default.  Too many people in this
372 dnl world have core dumps turned off by default or \"cannot find where the
373 dnl core file went\".  At least we should get some useful output ...
374 use_assertions="yes"
375 dnl the following is set to yes or no later.
376 with_toolbars=""
377 with_tty=""
378 use_union_type="no"
379 with_dnet=""
380 dnl pdump now defaults by opsys
381 pdump=''
382 dnl dragndrop is still experimental.  When it is stable, comment out the following line:
383 with_dragndrop="no"
384 dnl Too annoying, even if mandated by IPv6 (and I'm not even sure of that)
385 with_ipv6_cname="no"
386
387 dnl ------------------
388 dnl Options Processing
389 dnl ------------------
390
391 define([USAGE_ERROR],
392 [(echo "$progname: Usage error:"
393 echo " " $1
394 echo "  Use \`$progname --help' to show usage.") >&2 && exit 1])
395
396 dnl Record all the arguments, so we can save them in config.status.
397 arguments="$@"
398
399 dnl Shell Magic: Quote the quoted arguments in ARGUMENTS.  At a later date,
400 dnl in order to get the arguments back in $@, we have to do an
401 dnl 'eval set x "$quoted_arguments"; shift'
402 dnl # We use sed to turn embedded ' into '"'"'.  I truly hate sh quoting.
403 quoted_sed_magic=s/"'"/"'"'"'"'"'"'"'"/g
404 quoted_arguments=
405 for i in "$@"; do
406    case "$i" in
407    -no-create | --no-create | --no-creat | --no-crea | --no-cre \
408    | --no-cr | --no-c) ;;
409    -no-recursion | --no-recursion | --no-recursio | --no-recursi \
410    | --no-recurs | --no-recur | --no-recu | --no-rec | --no-re | --no-r) ;;
411    *)
412    quoted_i="`echo '' $i | sed -e 's:^ ::' -e $quoted_sed_magic`"
413    quoted_arguments="$quoted_arguments '$quoted_i'" ;;
414    esac
415 done
416
417 dnl Do not use shift -- that destroys the argument list, which autoconf needs
418 dnl to produce config.status.  It turns out that "set - $arguments" does not
419 dnl work portably.
420 dnl However, it also turns out that many shells cannot expand ${10} at all.
421 dnl So using an index variable does not work either.  It is possible to use
422 dnl some shell magic to make 'set x "$arguments"; shift' work portably.
423 while test $# != 0; do
424   arg="$1"; shift
425   case "$arg" in
426     --no-create|--no-recursion) ;;
427     dnl Anything starting with a hyphen we assume is an option.
428     -* )
429       dnl Separate the switch name from the value it is being given.
430       case "$arg" in
431         -*=*)
432           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\([[^=]]*\)=.*$:\1:'`
433           val=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*[[^=]]*=\(.*\)$:\1:'`
434           valomitted=no
435         ;;
436            dnl special case these strings since echo may silently eat them:
437            dnl --help ) opt=help val=yes valomitted=yes ;;
438            dnl --version ) opt=version val=yes valomitted=yes ;;
439            dnl -e ) opt=e val=yes valomitted=yes ;;
440            dnl -E ) opt=E val=yes valomitted=yes ;;
441            dnl -n ) opt=n val=yes valomitted=yes ;;
442         -*)
443            dnl If FOO is a boolean argument, --FOO is equivalent to
444            dnl --FOO=yes.  Otherwise, the value comes from the next
445            dnl argument - see below.
446           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\(.*\)$:\1:'`
447           val="yes" valomitted=yes
448         ;;
449       esac
450
451       dnl translate "-" in option string to "_"
452       optname="$opt"
453       opt="`echo '' $opt | sed -e 's:^ ::' | tr - _`"
454
455       dnl Support --without-FOO as a synonym for --with-FOO=no
456       case "${valomitted}-${opt}" in yes-without_* )
457         opt=`echo $opt | sed 's/without/with/'`
458         valomitted="no" val="no" ;;
459       esac
460
461       dnl Process the option.
462       case "$opt" in
463
464       dnl Process (many) boolean options
465         with_site_lisp  | \
466         with_prefix     | \
467         with_site_modules | \
468         with_x          | \
469         with_x11        | \
470         with_gtk        | \
471         with_gnome      | \
472         with_msw        | \
473         with_gcc        | \
474         dynamic         | \
475         with_ncurses    | \
476         with_dnet       | \
477         with_socks      | \
478         with_dragndrop  | \
479         with_cde        | \
480         with_offix      | \
481         with_gpm        | \
482         with_xpm        | \
483         with_xface      | \
484         with_gif        | \
485         with_jpeg       | \
486         with_png        | \
487         with_tiff       | \
488         with_wmcommand  | \
489         with_xmu        | \
490         with_purify     | \
491         with_quantify   | \
492         with_toolbars   | \
493         with_tty        | \
494         with_xfs        | \
495         with_i18n3      | \
496         with_mule       | \
497         with_file_coding| \
498         with_canna      | \
499         with_wnn        | \
500         with_wnn6       | \
501         with_workshop   | \
502         with_sparcworks | \
503         with_tooltalk   | \
504         with_ldap       | \
505         with_postgresql | \
506         with_pop        | \
507         with_kerberos   | \
508         with_hesiod     | \
509         with_dnet       | \
510         with_infodock   | \
511         with_netinstall | \
512         with_ipv6_cname | \
513         external_widget | \
514         verbose         | \
515         extra_verbose   | \
516         usage_tracking  | \
517         use_union_type  | \
518         pdump           | \
519         debug           | \
520         use_assertions  | \
521         use_regex_malloc | \
522         memory_usage_stats | \
523         with_clash_detection | \
524         with_modules    | \
525         quick_build )
526           dnl Make sure the value given was either "yes" or "no".
527           case "$val" in
528             y | ye | yes )      val=yes ;;
529             n | no )            val=no  ;;
530             * ) USAGE_ERROR("The \`--$optname' option requires a boolean value: \`yes' or \`no'.") ;;
531           esac
532           eval "$opt=\"$val\"" ;;
533
534
535         dnl Options that take a user-supplied value, as in --x-includes=/usr/X11R6/include
536         dnl The cache-file option is ignored (for compatibility with other configures)
537         srcdir          | \
538         compiler        | \
539         cflags          | \
540         cpp             | \
541         cppflags        | \
542         libs            | \
543         ldflags         | \
544         cache_file      | \
545         native_sound_lib| \
546         site_lisp       | \
547         x_includes      | \
548         x_libraries     | \
549         site_includes   | \
550         site_libraries  | \
551         site_prefixes   | \
552         site_runtime_libraries )
553           dnl If the value was omitted, get it from the next argument.
554           if test "$valomitted" = "yes" ; then
555             dnl Get the next argument from the argument list, if there is one.
556             if test "$#" = 0 ; then
557               USAGE_ERROR("The \`--$optname' option requires a value.");
558             fi
559             val="$1"; shift
560           fi
561           eval "$opt=\"$val\""
562         ;;
563
564         dnl Options that take "yes", "no", or "default" values
565         rel_alloc | \
566         with_dlmalloc | \
567         with_debug_malloc  | use_debug_malloc | \
568         with_system_malloc | use_system_malloc )
569           case "$val" in
570             y | ye | yes )      val=yes ;;
571             n | no )            val=no  ;;
572             d | de | def | defa | defau | defaul | default ) val=default ;;
573             * ) USAGE_ERROR(["The \`--$optname' option requires one of these values:
574   \`yes', \`no', or \`default'."]) ;;
575           esac
576           case "$opt" in use_* ) opt="`echo $opt | sed s/use/with/`" ;; esac
577           eval "$opt=\"$val\""
578         ;;
579
580         dnl Has the user requested database support?
581         "with_database" )
582           with_database_berkdb=no
583           with_database_dbm=no
584           with_database_gdbm=no
585           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
586             case "$x" in
587               no ) ;;
588               b | be | ber | berk | berkd | berkdb )       with_database_berkdb=yes ;;
589               d | db | dbm )                               with_database_dbm=yes    ;;
590               g | gn | gnu | gnud | gnudb | gnudbm | gdbm) with_database_gdbm=yes   ;;
591               * ) USAGE_ERROR(["The \`--$optname' option value
592   must be either \`no' or a comma-separated list
593   of one or more of \`berkdb' and either \`dbm' or \`gnudbm'."]) ;;
594             esac
595           done
596           if test "$with_database_dbm"  = "yes" -a \
597                   "$with_database_gdbm" = "yes"; then
598           USAGE_ERROR("Only one of \`dbm' and \`gnudbm' may be specified
599   with the \`--$optname' option.")
600           fi
601         ;;
602
603         dnl Has the user requested sound support?
604         "with_sound" )
605         dnl values is a subset of all,native,nas,esd
606         dnl or their negatives: none,nonative,nonas,noesd
607           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
608             case "$x" in
609               dnl all and none are only permitted as the first in the list.
610               n | no | non | none ) new_sdefault=no ;;
611               a | al | all | both ) new_sdefault=yes ;;
612
613               native )       with_native_sound=yes ;;
614               nonative )     with_native_sound=no ;;
615
616               nas )          with_nas_sound=yes ;;
617               nonas )        with_nas_sound=no ;;
618
619               esd )          with_esd_sound=yes ;;
620               noesd )        with_esd_sound=no ;;
621
622               * ) bogus_sound=yes ;;
623             esac
624             if test "$bogus_sound" -o \
625                  \( -n "$new_sdefault" -a -n "$sound_notfirst" \) ; then
626                 types="\`all', \`none', \`(no)native', \`no(nas)', \`(no)esd'."
627                 USAGE_ERROR(["Valid types for the \`--$optname' option are:
628   $types.
629 Option \`all' or \`none' must be first in the list.
630 The default is to autodetect native and NAS sound support."])
631             elif test -n "$new_sdefault" ; then
632                 with_native_sound=$new_sdefault
633                 with_nas_sound=$new_sdefault
634                 with_esd_sound=$new_sdefault
635                 new_sdefault=   # reset this
636             fi
637             sound_notfirst=true
638           done
639         ;;
640
641         dnl Has the user specified a preferred Athena widget set?
642         dnl This bit expands any alias names out for us...
643         "with_athena" )
644           case "$val" in
645             xa | xaw )                    val=xaw    ;;
646             3 | 3d | xaw3d )              val=3d     ;;
647             dnl No `n' for next, someone may try `no'
648             ne | nex | next | naxtaw)     val=next   ;;
649             dnl Have not tested the next two...
650             9 | 95 | xaw95 )              val=95     ;;
651             xp | xpm | xawxpm )           val=xpm    ;;
652             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
653   \`xaw', \`3d', \`next', \`95', or \`xpm'."]) ;;
654           esac
655           eval "$opt=\"$val\""
656         ;;
657
658         dnl Has the user requested XIM support?
659         "with_xim" )
660           case "$val" in
661             y | ye | yes )                val=yes   ;;
662             n | no | non | none )         val=no    ;;
663             x | xl | xli | xlib )         val=xlib  ;;
664             m | mo | mot | moti | motif ) val=motif ;;
665             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
666   \`motif', \`xlib', \`yes', or \`no'."]) ;;
667           esac
668           eval "$opt=\"$val\""
669         ;;
670
671         dnl Mail locking specification
672         "mail_locking" )
673           case "$val" in
674             lockf )     val=lockf ;;
675             flock )     val=flock ;;
676             file | dot ) val=file  ;;
677             locking )   val=locking  ;;
678             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
679   \`lockf', \`flock', \`file', \`locking', or \`mmdf'."]) ;;
680           esac
681           eval "$opt=\"$val\""
682         ;;
683
684         dnl Has the user requested error-checking?
685         "error_checking" )
686           dnl value can be all, none, and/or a list of categories to check.
687           dnl Example: --error-checking=all,noextents,nobufpos
688           dnl Example: --error-checking=none,malloc,gc
689
690           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
691             case "$x" in
692               dnl all and none are only permitted as the first in the list.
693               n | no | non | none ) new_default=no ;;
694               a | al | all )        new_default=yes ;;
695
696               extents )       error_check_extents=yes ;;
697               noextents )     error_check_extents=no ;;
698
699               typecheck )     error_check_typecheck=yes ;;
700               notypecheck )   error_check_typecheck=no ;;
701
702               bufpos )        error_check_bufpos=yes ;;
703               nobufpos )      error_check_bufpos=no ;;
704
705               gc )            error_check_gc=yes ;;
706               nogc )          error_check_gc=no ;;
707
708               malloc )        error_check_malloc=yes ;;
709               nomalloc )      error_check_malloc=no ;;
710
711               byte_code )     error_check_byte_code=yes ;;
712               nobyte_code )   error_check_byte_code=no ;;
713
714               glyphs )     error_check_glyphs=yes ;;
715               noglyphs )   error_check_glyphs=no ;;
716
717               * ) bogus_error_check=yes ;;
718             esac
719             if test "$bogus_error_check" -o \
720                  \( -n "$new_default" -a -n "$echeck_notfirst" \) ; then
721                 if test "$error_check_default" = yes ; then
722                   types="\`all' (default), \`none', \`noextents', \`notypecheck', \`nobufpos', \`nogc', \`nomalloc', \`noglyphs' and \`nobyte-code'."
723                 else
724                   types="\`all', \`none' (default), \`extents', \`typecheck', \`bufpos', \`gc', \`malloc', \`glyphs' and \`byte-code'."
725                 fi
726                 USAGE_ERROR(["Valid types for the \`--$optname' option are:
727   $types."])
728             elif test -n "$new_default" ; then
729                 error_check_extents=$new_default
730                 error_check_typecheck=$new_default
731                 error_check_bufpos=$new_default
732                 error_check_gc=$new_default
733                 error_check_malloc=$new_default
734                 error_check_byte_code=$new_default
735                 error_check_glyphs=$new_default
736                 new_default=    # reset this
737             fi
738             echeck_notfirst=true
739           done
740         ;;
741
742         dnl Has the user tried to tell us where the X files are?
743         dnl I think these are dopey, but no less than three alpha
744         dnl testers, at large sites, have said they have their X files
745         dnl installed in odd places.
746
747         dnl Has the user specified one of the path options?
748         prefix | exec_prefix | bindir | datadir | statedir | libdir | \
749         mandir | infodir | infopath | lispdir | etcdir | pkgdir | \
750         archlibdir | docdir | package_path | moduledir )
751            dnl If the value was omitted, get it from the next argument.
752            if test "$valomitted" = "yes"; then
753              if test "$#" = 0; then
754                  USAGE_ERROR("The \`--$optname' option requires a value.");
755              fi
756              val="$1"; shift
757            fi
758            eval "$opt=\"$val\""
759
760            dnl You need to synchronize this with the way the
761            dnl default values are built.
762            case "$opt" in
763              dnl prefix is taken care of by --with-prefix
764              exec_prefix ) AC_DEFINE(EXEC_PREFIX_USER_DEFINED) ;;
765              lispdir ) AC_DEFINE(LISPDIR_USER_DEFINED) ;;
766              sitelispdir ) AC_DEFINE(SITELISPDIR_USER_DEFINED) ;;
767              moduledir ) AC_DEFINE(MODULEDIR_USER_DEFINED) ;;
768              etcdir  )  AC_DEFINE(ETCDIR_USER_DEFINED) ;;
769              infodir ) AC_DEFINE(INFODIR_USER_DEFINED) ;;
770              infopath ) AC_DEFINE(INFOPATH_USER_DEFINED) ;;
771              package_path ) AC_DEFINE(PACKAGE_PATH_USER_DEFINED) ;;
772              datadir )
773                 AC_DEFINE(INFODIR_USER_DEFINED)
774                 AC_DEFINE(LISPDIR_USER_DEFINED)
775                 AC_DEFINE(MODULEDIR_USER_DEFINED)
776                 AC_DEFINE(ETCDIR_USER_DEFINED)
777                 AC_DEFINE(DOCDIR_USER_DEFINED)
778                 AC_DEFINE(ARCHLIBDIR_USER_DEFINED) ;;
779              docdir ) AC_DEFINE(DOCDIR_USER_DEFINED) ;;
780              exec_prefix | libdir | archlibdir ) AC_DEFINE(ARCHLIBDIR_USER_DEFINED) ;;
781            esac
782         ;;
783
784         dnl --no-create added by autoconf for use by config.status
785         "no_create" ) ;;
786
787         dnl Has the user asked for some help?
788         "usage" | "help" ) ${PAGER-more} ${srcdir}/configure.usage; exit 0 ;;
789
790         dnl Has the user specified the toolkit(s) to use for GUI elements?
791         "with_menubars"   | \
792         "with_scrollbars" | \
793         "with_dialogs"    | \
794         "with_widgets" )
795           case "$val" in
796             l | lu | luc | luci | lucid )               val=lucid  ;;
797             mo | mot | moti | motif )                   val=motif  ;;
798             a | at | ath | athe | athen | athena )      val=athena ;;
799             n | no | non | none )                       val=no     ;;
800             y | ye | yes )                              val=yes    ;;
801             dnl Explicit --with-widgets on command line means yes.
802             "")                                         val=yes    ;;
803             g | gt | gtk )                              val=gtk    ;;
804             ms | msw )                                  val=msw    ;;
805             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
806   \`gtk', \`lucid', \`motif', \`athena', \`yes', or \`no'."]) ;;
807           esac
808           eval "$opt=\"$val\""
809         ;;
810
811         dnl Obsolete legacy argument?  Warn, but otherwise ignore.
812         "use_minimal_tagbits" | \
813         "use_indexed_lrecord_implementation" | \
814         "run_in_place"  | \
815         "const_is_losing" | \
816         "with_gnu_make" )
817           AC_MSG_WARN([Obsolete option \`--$optname' ignored.])
818         ;;
819
820         dnl Unrecognized option?  No mercy for user errors.
821         * ) USAGE_ERROR("Unrecognized option: $arg") ;;
822
823       esac
824     ;;
825
826     dnl Assume anything with multiple hyphens is a configuration name.
827     *-*-*) configuration="$arg" ;;
828
829     dnl Unrecognized argument?  No mercy for user errors.
830     *) USAGE_ERROR("Unrecognized argument: $arg") ;;
831
832   esac
833 done
834
835 dnl -------------------------
836 dnl Finish options processing
837 dnl -------------------------
838
839 dnl Several options are equivalent to, and override, environment variables.
840 test -n "$cpp"      && CPP="$cpp"
841 test -n "$cppflags" && CPPFLAGS="$cppflags"
842 test -n "$libs"     && LIBS="$libs"
843 test -n "$ldflags"  && LDFLAGS="$ldflags"
844
845 dnl Get the arguments back.  See the diatribe on Shell Magic above.
846 eval set x "$quoted_arguments"; shift
847
848 dnl --extra-verbose implies --verbose
849 test "$extra_verbose" = "yes" && verbose=yes
850
851 dnl with_x is an obsolete synonym for with_x11
852 test -n "$with_x" && with_x11="$with_x"
853
854 dnl --with-quantify or --with-purify imply --use-system-malloc
855 if test "$with_purify" = "yes" -o "$with_quantify" = "yes"; then
856   test "$with_system_malloc" = "default" && with_system_malloc=yes
857 fi
858
859 dnl XE_CHECK_FEATURE_DEPENDENCY(feature1, feature2)
860 define([XE_CHECK_FEATURE_DEPENDENCY],
861 [if test "$with_$1 $with_$2" = "yes no"; then
862   USAGE_ERROR("--with-$1 requires --with-$2")
863 elif test "$with_$2" = "no" ; then with_$1=no
864 elif test "$with_$1" = "yes"; then with_$2=yes
865 fi
866 ])
867
868 dnl CDE requires tooltalk
869 XE_CHECK_FEATURE_DEPENDENCY(cde, tooltalk)
870
871 dnl Find the source directory.
872 case "$srcdir" in
873
874   dnl If srcdir is not specified, see if  "." or ".." might work.
875   "" )
876     for dir in "`echo $0 | sed 's|//|/|' | sed 's|/[[^/]]*$||'`" "." ".." ; do
877       if test -f "$dir/src/lisp.h" -a \
878               -f "$dir/lisp/version.el" ; then
879         srcdir="$dir"
880         break
881       fi
882     done
883     if test -z "$srcdir" ; then
884       USAGE_ERROR(["Neither the current directory nor its parent seem to
885   contain the XEmacs sources.  If you do not want to build XEmacs in its
886   source tree, you should run \`$progname' in the directory in which
887   you wish to build XEmacs, using the \`--srcdir' option to say where the
888   sources may be found."])
889     fi
890   ;;
891
892   dnl Otherwise, check if the directory they specified is okay.
893   * )
894     if test ! -f "$srcdir/src/lisp.h" -o \
895             ! -f "$srcdir/lisp/version.el" ; then
896       USAGE_ERROR(["The directory specified with the \`--srcdir' option,
897   \`$srcdir', doesn't seem to contain the XEmacs sources.  You should
898   either run the \`$progname' script at the top of the XEmacs source
899   tree, or use the \`--srcdir' option to specify the XEmacs source directory."])
900     fi
901   ;;
902 esac
903
904 dnl ###########################################################################
905 if test -z "$configuration"; then
906   dnl Guess the configuration
907   configuration=`${CONFIG_SHELL-/bin/sh} $srcdir/config.guess`
908   if test -z "$configuration"; then
909     USAGE_ERROR(["XEmacs has not been ported to this host type.
910 Try explicitly specifying the CONFIGURATION when rerunning configure."])
911   fi
912 fi
913
914 AC_PROG_LN_S
915
916 dnl Make symlinks for etc, lisp, and info directories while the path
917 dnl is still relative.  We do not symlink lock because someone may
918 dnl have stuck the source on a read-only partition.  Instead we
919 dnl create it as an actual directory later on if it does not already
920 dnl exist.
921 for dir in lisp etc man info tests; do
922   if test ! -d "$dir" ; then
923     echo Making symbolic link to "$srcdir/$dir"
924     ${LN_S} "$srcdir/$dir" "$dir"
925   fi
926 done
927
928 dnl Do our best to deal with automounter brokenness
929 dnl CANONICALIZE_PATH(varname)
930 define([CANONICALIZE_PATH],
931 [if test -d "/net"; then
932   if test -d "/tmp_mnt/net"; then tdir="tmp_mnt/net"; else tdir="tmp_mnt"; fi
933   $1=`echo "[$]$1" | \
934    sed -e "s|^${tdir}/|/net/|" -e "s|^/a/|/net/|" -e "s|^/amd/|/net/|"`
935 fi])dnl
936
937 dnl Calculate canonical name for blddir (i.e. current directory).
938 dnl PWD may already be the preferable absolute name for ".",
939 dnl but we can't trust it - it is sometimes inaccurate.
940 absolute_pwd="`pwd`";
941 if test -n "$PWD" -a "`cd $PWD && pwd`" = "$absolute_pwd"
942 then blddir="$PWD"
943 else blddir="$absolute_pwd"; CANONICALIZE_PATH(blddir)
944 fi
945 AC_SUBST(blddir)
946
947 dnl Make srcdir absolute, if not already.  It is important to
948 dnl avoid running the path through pwd unnecessary, since pwd can
949 dnl give you automounter prefixes, which can go away.
950 case "$srcdir" in
951   /* ) ;;
952   .  ) srcdir="$blddir" ;;
953   *  ) srcdir="`cd $srcdir && pwd`"; CANONICALIZE_PATH(srcdir) ;;
954 esac
955
956 dnl Check if the source directory already has a configured system in it.
957 if test `pwd` != `sh -c cd $srcdir && pwd`  \
958    && test -f "$srcdir/src/config.h"; then
959   (echo "$progname: WARNING: The directory tree \`$srcdir' is being used"
960    echo "   as a build directory right now; it has been configured in its own"
961    echo "   right.  To configure in another directory as well, you MUST"
962    echo "   use GNU make.  If you do not have GNU make, then you must"
963    echo "   now do \`make distclean' in $srcdir,"
964    echo "   and then run $progname again.") >&2
965   extrasub='/^VPATH[[    ]]*=/c\
966 vpath %.c $(srcdir)\
967 vpath %.h $(srcdir)\
968 vpath %.y $(srcdir)\
969 vpath %.l $(srcdir)\
970 vpath %.s $(srcdir)\
971 vpath %.in $(srcdir)'
972 fi
973
974 dnl ----------------------------------------
975 dnl Find out which version of XEmacs this is
976 dnl ----------------------------------------
977 . "$srcdir/version.sh" || exit 1;
978 dnl Must do the following first to determine verbosity for AC_DEFINE
979 if test -n "$emacs_is_beta"; then beta=yes; else beta=no; fi
980 : "${extra_verbose=$beta}"
981 version="${emacs_major_version}.${emacs_minor_version}"
982 AC_DEFINE_UNQUOTED(EMACS_MAJOR_VERSION, $emacs_major_version)
983 AC_DEFINE_UNQUOTED(EMACS_MINOR_VERSION, $emacs_minor_version)
984 if test -n "$emacs_beta_version" ; then
985   if test "$beta" = "yes"; then
986         version="${version}-b${emacs_beta_version}"
987         AC_DEFINE_UNQUOTED(EMACS_BETA_VERSION, $emacs_beta_version)
988   else
989         version="${version}.${emacs_beta_version}"
990         AC_DEFINE_UNQUOTED(EMACS_PATCH_LEVEL, $emacs_beta_version)
991   fi
992 fi
993 AC_DEFINE_UNQUOTED(XEMACS_CODENAME, "$xemacs_codename")
994 AC_DEFINE_UNQUOTED(EMACS_VERSION, "$version")
995
996 if test "$with_infodock" = "yes"; then
997   if test ! -f ../../ID-INSTALL; then
998     echo "Cannot build InfoDock without InfoDock sources"
999     with_infodock=no
1000   fi
1001 fi
1002
1003 if test "$with_infodock" = "yes"; then
1004   dnl InfoDock version numbers.  XEmacs will use the same style of numbering
1005   dnl after the release of XEmacs 21.0.
1006   AC_DEFINE_UNQUOTED(INFODOCK_MAJOR_VERSION, $infodock_major_version)
1007   AC_DEFINE_UNQUOTED(INFODOCK_MINOR_VERSION, $infodock_minor_version)
1008   AC_DEFINE_UNQUOTED(INFODOCK_BUILD_VERSION, $infodock_build_version)
1009   version=${infodock_major_version}.${infodock_minor_version}.${infodock_build_version}
1010   PROGNAME=infodock
1011   CPPFLAGS="$CPPFLAGS -DINFODOCK"
1012 else
1013   PROGNAME=xemacs
1014 fi
1015
1016 AC_DEFINE_UNQUOTED(EMACS_PROGNAME, "$PROGNAME")
1017
1018 dnl ----------------------------------
1019 dnl Error checking and debugging flags
1020 dnl ----------------------------------
1021 dnl Error checking default to "yes" in beta versions, to "no" in releases.
1022 dnl Same goes for --debug and --extra-verbosity.
1023 if test -n "$emacs_is_beta"; then beta=yes; else beta=no; fi
1024 test "${error_check_extents=$beta}"   = yes && AC_DEFINE(ERROR_CHECK_EXTENTS)
1025 test "${error_check_typecheck=$beta}" = yes && AC_DEFINE(ERROR_CHECK_TYPECHECK)
1026 test "${error_check_bufpos=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_BUFPOS)
1027 test "${error_check_gc=$beta}"        = yes && AC_DEFINE(ERROR_CHECK_GC)
1028 test "${error_check_malloc=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_MALLOC)
1029 test "${error_check_byte_code=$beta}" = yes && AC_DEFINE(ERROR_CHECK_BYTE_CODE)
1030 test "${error_check_glyphs=$beta}" = yes && AC_DEFINE(ERROR_CHECK_GLYPHS)
1031 dnl debug=yes must be set when error checking is present.  This should be
1032 dnl fixed up.
1033 dnl debug implies other options
1034 if test "${debug:=$beta}" = "yes"; then
1035   use_assertions=yes memory_usage_stats=yes
1036   XE_ADD_OBJS(debug.o)
1037   XE_ADD_OBJS(tests.o)
1038   AC_DEFINE(DEBUG_XEMACS)
1039 fi
1040 test "$use_assertions"     = "yes" && AC_DEFINE(USE_ASSERTIONS)
1041 test "$memory_usage_stats" = "yes" && AC_DEFINE(MEMORY_USAGE_STATS)
1042
1043 dnl ------------------------------
1044 dnl Determine the s&m files to use
1045 dnl ------------------------------
1046 dnl Given the configuration name, set machfile and opsysfile to the
1047 dnl names of the m/*.h and s/*.h files we should use.
1048
1049 dnl Canonicalize the configuration name.
1050 AC_MSG_CHECKING("host system type")
1051 dnl allow -workshop suffix on configuration name
1052 internal_configuration=`echo $configuration | sed 's/-\(workshop\)//'`
1053 canonical=`${CONFIG_SHELL-/bin/sh} $srcdir/config.sub "$internal_configuration"`
1054 XE_STRIP_4TH_COMPONENT(configuration)
1055 XE_STRIP_4TH_COMPONENT(canonical)
1056 AC_MSG_RESULT($configuration)
1057
1058 dnl If you add support for a new configuration, add code to this
1059 dnl switch statement to recognize your configuration name and select
1060 dnl the appropriate operating system and machine description files.
1061
1062 dnl You would hope that you could choose an m/*.h file pretty much
1063 dnl based on the machine portion of the configuration name, and an s-
1064 dnl file based on the operating system portion.  However, it turns out
1065 dnl that each m/*.h file is pretty manufacturer-specific - for
1066 dnl example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
1067 dnl all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
1068 dnl machines.  So we basically have to have a special case for each
1069 dnl configuration name.
1070
1071 dnl As far as handling version numbers on operating systems is
1072 dnl concerned, make sure things will fail in a fixable way.  If
1073 dnl /etc/MACHINES says nothing about version numbers, be
1074 dnl prepared to handle anything reasonably.  If version numbers
1075 dnl matter, be sure /etc/MACHINES says something about it.
1076
1077 dnl Eric Raymond says we should accept strings like "sysvr4" to mean
1078 dnl "System V Release 4"; he writes, "The old convention encouraged"
1079 dnl "confusion between `system' and `release' levels'."
1080
1081 machine='' opsys=''
1082
1083 dnl Straightforward machine determination
1084 case "$canonical" in
1085   sparc-*-*        ) machine=sparc ;;
1086   alpha*-*-*       ) machine=alpha ;;
1087   vax-*-*          ) machine=vax ;;
1088   mips-dec-*       ) machine=pmax ;;
1089   mips-sgi-irix6*  ) machine=iris6d ;;
1090   mips-sgi-*       ) machine=iris4d ;;
1091   mips*-linux      ) machine=mips ;;
1092   romp-ibm-*       ) machine=ibmrt ;;
1093   rs6000-ibm-aix*  ) machine=ibmrs6000 ;;
1094   powerpc-ibm-aix* ) machine=ibmrs6000 ;;
1095   powerpc*-*       ) machine=powerpc ;;
1096   hppa-*-*         ) machine=hp800 ;;
1097   m88k-dg-*        ) machine=aviion ;;
1098   m68*-sony-*      ) machine=news ;;
1099   mips-sony-*      ) machine=news-risc ;;
1100   clipper-*        ) machine=clipper ;;
1101   arm*             ) machine=arm ;;
1102   ns32k-*          ) machine=ns32000 ;;
1103 esac
1104
1105 dnl Straightforward OS determination
1106 case "$canonical" in
1107   *-*-linux*    ) opsys=linux ;;
1108   *-*-netbsd*   ) opsys=netbsd ;;
1109   *-*-openbsd*  ) opsys=openbsd ;;
1110   *-*-nextstep* ) opsys=nextstep ;;
1111   *-*-vms       ) opsys=vms ;;
1112
1113   dnl DEC OSF
1114   *-dec-osf1.3 | *-dec-osf2* ) opsys=decosf1-3 ;;
1115   *-dec-osf1.2 | *-dec-osf1* ) opsys=decosf1-2 ;;
1116   *-dec-osf3.[[2-9]]         ) opsys=decosf3-2 ;;
1117   *-dec-osf3*                ) opsys=decosf3-1 ;;
1118   *-dec-osf[[4-9]]*          ) opsys=decosf4-0 ;;
1119
1120   dnl DEC Ultrix
1121   *-*-ultrix[[0-3]].* | *-*-ultrix4.0* ) opsys=bsd4-2 ;;
1122   *-*-ultrix4.[[12]]* ) opsys=bsd4-3 ;;
1123   *-*-ultrix* )         opsys=ultrix4-3 ;;
1124
1125   dnl AIX
1126   *-*-aix3.1*     ) opsys=aix3-1   ;;
1127   *-*-aix3.2.5    ) opsys=aix3-2-5 ;;
1128   *-*-aix3*       ) opsys=aix3-2   ;;
1129   *-*-aix4.0*     ) opsys=aix4     ;;
1130   *-*-aix4.1*     ) opsys=aix4-1   ;;
1131   *-*-aix[[4-9]]* ) opsys=aix4-2   ;;
1132
1133   dnl Other generic OSes
1134   *-gnu* )                      opsys=gnu    ;;
1135   *-*-bsd4.[[01]] )             opsys=bsd4-1 ;;
1136   *-*-bsd4.2 )                  opsys=bsd4-2 ;;
1137   *-*-bsd4.3 )                  opsys=bsd4-3 ;;
1138   *-*-aos4.2 )                  opsys=bsd4-2 ;;
1139   *-*-aos*   )                  opsys=bsd4-3 ;;
1140   *-*-sysv0    | *-*-sysvr0 )   opsys=usg5-0 ;;
1141   *-*-sysv2    | *-*-sysvr2 )   opsys=usg5-2 ;;
1142   *-*-sysv2.2  | *-*-sysvr2.2 ) opsys=usg5-2-2 ;;
1143   *-*-sysv3*   | *-*-sysvr3* )  opsys=usg5-3 ;;
1144   *-*-sysv4.1* | *-*-sysvr4.1* )opsys=usg5-4 NON_GNU_CPP=/usr/lib/cpp ;;
1145   *-*-sysv4.[[2-9]]* | *-sysvr4.[[2-9]]* )
1146         if test -z "$NON_GNU_CPP" ; then
1147           for prog in "/usr/ccs/lib/cpp" "/lib/cpp"; do
1148             if test -f "$prog"; then NON_GNU_CPP="$prog"; break; fi
1149           done
1150         fi
1151         opsys=usg5-4-2 ;;
1152     *-sysv4* | *-sysvr4* )      opsys=usg5-4 ;;
1153     *-*-mach_bsd4.3* )          opsys=mach-bsd4-3 ;;
1154 esac
1155
1156 case "$canonical" in
1157
1158   dnl NetBSD ports
1159   *-*-netbsd* )
1160     case "$canonical" in
1161       i[[3-9]]86-*-netbsd*) machine=intel386 ;;
1162       hp300-*-netbsd* | amiga-*-netbsd* | sun3-*-netbsd* | mac68k-*-netbsd* | da30-*-netbsd* | m68k-*-netbsd* )
1163                       dnl Yes, this is somewhat bogus.
1164                       machine=hp9000s300 ;;
1165       pc532-*-netbsd* | ns32k-*-netbsd* )  machine=ns32000 ;;
1166       pmax-*-netbsd*  | mips-*-netbsd*  )  machine=pmax ;;
1167     esac
1168   ;;
1169
1170   dnl OpenBSD ports
1171   *-*-openbsd* )
1172     case "${canonical}" in
1173       i386-*-openbsd*)          machine=intel386 ;;
1174       m68k-*-openbsd*)          machine=hp9000s300 ;;
1175       mipsel-*-openbsd*)        machine=pmax ;;
1176      esac
1177    ;;
1178
1179   dnl Acorn RISCiX:
1180   arm-acorn-riscix1.1* ) machine=acorn opsys=riscix1-1 ;;
1181   arm-acorn-riscix1.2* | arm-acorn-riscix ) machine=acorn opsys=riscix1-2 ;;
1182
1183   dnl Alliant machines
1184   fx80-alliant-* ) machine=alliant4     opsys=bsd4-2 ;;
1185   i860-alliant-* ) machine=alliant-2800 opsys=bsd4-3 ;;
1186
1187   dnl Altos 3068
1188   m68*-altos-sysv* ) machine=altos opsys=usg5-2 ;;
1189
1190   dnl Amdahl UTS
1191   580-amdahl-sysv* ) machine=amdahl opsys=usg5-2-2 ;;
1192
1193   dnl Apollo, Domain/OS
1194   m68*-apollo-* ) machine=apollo opsys=bsd4-3 ;;
1195
1196   dnl AT&T 3b2, 3b5, 3b15, 3b20
1197   we32k-att-sysv* ) machine=att3b opsys=usg5-2-2 ;;
1198
1199   dnl AT&T 3b1 - The Mighty Unix PC!
1200   m68*-att-sysv* ) machine=7300 opsys=usg5-2-2 ;;
1201
1202   dnl Bull machines
1203   rs6000-bull-bosx* ) machine=ibmrs6000 opsys=aix3-2 ;; # dpx20
1204   m68*-bull-sysv3*  ) machine=dpx2      opsys=usg5-3 ;; # dpx2
1205   m68*-bull-sysv2*  ) machine=sps7      opsys=usg5-2 ;; # sps7
1206
1207   dnl CCI 5/32, 6/32 -- see "Tahoe".
1208
1209   dnl Celerity
1210   celerity-celerity-bsd* ) machine=celerity opsys=bsd4-2 ;;
1211
1212   dnl Convex
1213   *-convex-bsd* | *-convex-convexos* )
1214     machine=convex opsys=bsd4-3
1215     NON_GNU_CPP="cc -E -P"
1216   ;;
1217
1218   dnl Cubix QBx/386
1219   i[[3-9]]86-cubix-sysv* ) machine=intel386 opsys=usg5-3 ;;
1220
1221   dnl Darwin, a.k.a. MacOS X (based on Mach and Freebsd)
1222   *-*-darwin*)
1223     opsys=darwin
1224     RANLIB="ranlib -c" dnl Avoids a link error with lwlib-config.c
1225     ;;
1226
1227   dnl Data General AViiON Machines
1228   i586-dg-dgux*R4*   | i586-dg-dgux5.4.4* ) machine=aviion opsys=dgux5-4r4 ;;
1229   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* ) opsys=dgux5-4r3 ;;
1230   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* ) opsys=dgux5-4r2 ;;
1231   m88k-dg-dgux*                           ) opsys=dgux     ;;
1232
1233   dnl Motorola Delta machines
1234   m68k-motorola-sysv* | m68000-motorola-sysv* ) machine=delta opsys=usg5-3 ;;
1235   m88k-motorola-sysv4* )
1236     dnl jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
1237     dnl needs POSIX_SIGNALS and therefore needs usg5-4-2.
1238     dnl I hope there are not other 4.0 versions for this machine
1239     dnl which really need usg5-4 instead.
1240     machine=delta88k opsys=usg5-4-2
1241   ;;
1242   m88k-motorola-sysv* | m88k-motorola-m88kbcs* ) machine=delta88k opsys=usg5-3 ;;
1243
1244   dnl Dual machines
1245   m68*-dual-sysv*    ) machine=dual opsys=usg5-2   ;;
1246   m68*-dual-uniplus* ) machine=dual opsys=unipl5-2 ;;
1247
1248   dnl Encore machines
1249   ns16k-encore-bsd* ) machine=ns16000 opsys=umax ;;
1250
1251   dnl Gould Power Node and NP1
1252   pn-gould-bsd4.2* ) machine=gould     opsys=bsd4-2 ;;
1253   pn-gould-bsd4.3* ) machine=gould     opsys=bsd4-3 ;;
1254   np1-gould-bsd* )   machine=gould-np1 opsys=bsd4-3 ;;
1255
1256   dnl Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
1257   dnl as far as XEmacs is concerned).
1258   m88k-harris-cxux* )
1259     dnl Build needs to be different on 7.0 and later releases
1260     case "`uname -r`" in
1261        [[56]].[[0-9]] ) machine=nh4000 opsys=cxux  ;;
1262        [[7]].[[0-9]]  ) machine=nh4000 opsys=cxux7 ;;
1263     esac
1264     NON_GNU_CPP="/lib/cpp"
1265   ;;
1266   dnl Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
1267   m68k-harris-cxux* ) machine=nh3000 opsys=cxux ;;
1268   dnl Harris power pc NightHawk running Power UNIX (Series 6000)
1269   powerpc-harris-powerunix ) machine=nh6000 opsys=powerunix NON_GNU_CPP="cc -Xo -E -P" ;;
1270
1271   dnl Honeywell XPS100
1272   xps*-honeywell-sysv* ) machine=xps100 opsys=usg5-2 ;;
1273
1274   dnl HP 9000 series 200 or 300
1275   m68*-hp-bsd* ) machine=hp9000s300 opsys=bsd4-3 ;;
1276
1277   dnl HP-UX
1278   *-hp-hpux* )
1279     dnl Figure out machine and opsys orthogonally
1280     case "$canonical" in
1281       m68*  ) machine=hp9000s300 ;;
1282       hppa* ) machine=hp800      ;;
1283     esac
1284
1285     case "$canonical" in
1286       *-hp-hpux7*  )  opsys=hpux   ;;
1287       *-hp-hpux8*  )  opsys=hpux8  ;;
1288       *-hp-hpux9*  )  opsys=hpux9  ;;
1289       *-hp-hpux10* )  opsys=hpux10 ;;
1290       *-hp-hpux11* )  opsys=hpux11 ;;
1291       *            )  opsys=hpux   ;;
1292     esac
1293
1294     dnl HP has a broken "strcat"
1295     case "$opsys" in hpux9 | hpux10 ) XE_ADD_OBJS(strcat.o) ;; esac
1296
1297     if test "$opsys" = "hpux10" -o "$opsys" = "hpux11"; then \
1298         ansi_flag="-Ae"; else ansi_flag="-Aa"; fi
1299     NON_GNU_CC="cc $ansi_flag" NON_GNU_CPP="cc $ansi_flag -E"
1300
1301     case "$canonical" in *-hp-hpux*shr* ) opsys="${opsys}-shr" ;; esac
1302   ;;
1303
1304   dnl Orion machines
1305   orion-orion-bsd*   ) machine=orion    opsys=bsd4-2 ;;
1306   clipper-orion-bsd* ) machine=orion105 opsys=bsd4-2 ;;
1307
1308   dnl IBM machines
1309   i[[3-9]]86-ibm-aix1.1* ) machine=ibmps2-aix opsys=usg5-2-2 ;;
1310   i[[3-9]]86-ibm-aix1.[[23]]* | i[[3-9]]86-ibm-aix* ) machine=ibmps2-aix opsys=usg5-3 ;;
1311   i370-ibm-aix*) machine=ibm370aix opsys=usg5-3 ;;
1312   romp-ibm-aos*    ) opsys=bsd4-3 ;;
1313   romp-ibm-bsd*    ) opsys=bsd4-3 ;;
1314   romp-ibm-mach*   ) opsys=mach-bsd4-3 ;;
1315
1316   dnl Integrated Solutions "Optimum V"
1317   m68*-isi-bsd4.2* ) machine=isi-ov opsys=bsd4-2 ;;
1318   m68*-isi-bsd4.3* ) machine=isi-ov opsys=bsd4-3 ;;
1319
1320   dnl Intel 386 machines where we do care about the manufacturer
1321   i[[3-9]]86-intsys-sysv* ) machine=is386 opsys=usg5-2-2 ;;
1322
1323   dnl Prime EXL
1324   i[[3-9]]86-prime-sysv* ) machine=i386 opsys=usg5-3 ;;
1325
1326   dnl Sequent Symmetry running Dynix
1327   i[[3-9]]86-sequent-bsd* ) machine=symmetry opsys=bsd4-3 ;;
1328
1329   dnl Sequent Symmetry running DYNIX/ptx
1330   i[[3-9]]86-sequent-ptx* ) machine=sequent-ptx opsys=ptx NON_GNU_CPP="/lib/cpp" ;;
1331
1332   dnl Unspecified sysv on an ncr machine defaults to svr4.2.
1333   dnl (Plain usg5-4 does not turn on POSIX signals, which we need.)
1334   i[[3-9]]86-ncr-sysv* ) machine=ncr386 opsys=usg5-4-2 ;;
1335
1336   dnl Intel Paragon OSF/1
1337   i860-intel-osf1* ) machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp ;;
1338
1339   dnl Intel 860
1340   i860-*-sysv4* ) machine=i860 opsys=usg5-4 NON_GNU_CC="/bin/cc" NON_GNU_CPP="/usr/ccs/lib/cpp" ;;
1341
1342   dnl Masscomp machines
1343   m68*-masscomp-rtu* ) machine=masscomp opsys=rtu ;;
1344
1345   dnl Megatest machines
1346   m68*-megatest-bsd* ) machine=mega68 opsys=bsd4-2 ;;
1347
1348   dnl Workstations sold by MIPS
1349   dnl This is not necessarily all workstations using the MIPS processor -
1350   dnl Irises are produced by SGI, and DECstations by DEC.
1351   mips-mips-usg* ) machine=mips4 ;;
1352   mips-mips-riscos4 )
1353     machine=mips4
1354     NON_GNU_CC="cc -systype bsd43"
1355     NON_GNU_CPP="cc -systype bsd43 -E"
1356     case "$canonical" in
1357       mips-mips-riscos4* ) opsys=bsd4-3  ;;
1358       mips-mips-riscos5* ) opsys=riscos5 ;;
1359     esac
1360   ;;
1361   mips-mips-bsd* ) machine=mips opsys=bsd4-3 ;;
1362   mips-mips-*    ) machine=mips opsys=usg5-2-2 ;;
1363
1364   dnl NeXT
1365   m68*-next-* | m68k-*-nextstep* ) machine=m68k opsys=nextstep ;;
1366
1367   dnl The complete machine from National Semiconductor
1368   ns32k-ns-genix* ) machine=ns32000 opsys=usg5-2 ;;
1369
1370   dnl NCR machines
1371   m68*-ncr-sysv2* | m68*-ncr-sysvr2* ) machine=tower32   opsys=usg5-2-2 ;;
1372   m68*-ncr-sysv3* | m68*-ncr-sysvr3* ) machine=tower32v3 opsys=usg5-3 ;;
1373
1374   dnl Nixdorf Targon 31
1375   m68*-nixdorf-sysv* ) machine=targon31 opsys=usg5-2-2 ;;
1376
1377   dnl Nu (TI or LMI)
1378   m68*-nu-sysv* ) machine=nu opsys=usg5-2 ;;
1379
1380   dnl Plexus
1381   m68*-plexus-sysv* ) machine=plexus opsys=usg5-2 ;;
1382
1383   dnl Pyramid machines
1384   pyramid-pyramid-bsd* ) machine=pyramid opsys=bsd4-2 ;;
1385
1386   dnl Sequent Balance
1387   ns32k-sequent-bsd4.2* ) machine=sequent opsys=bsd4-2 ;;
1388   ns32k-sequent-bsd4.3* ) machine=sequent opsys=bsd4-3 ;;
1389
1390   dnl Siemens Nixdorf
1391   mips-siemens-sysv* | mips-sni-sysv*)
1392     machine=mips-siemens opsys=usg5-4
1393     NON_GNU_CC=/usr/ccs/bin/cc
1394     NON_GNU_CPP=/usr/ccs/lib/cpp
1395   ;;
1396
1397   dnl NEC
1398   mips-nec-sysv*)
1399     machine=mips-nec
1400     NON_GNU_CC=/usr/ccs/bin/cc
1401     NON_GNU_CPP=/usr/ccs/lib/cpp
1402   ;;
1403
1404   dnl Silicon Graphics machines
1405   dnl Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
1406   m68*-sgi-iris3.5* ) machine=irist opsys=iris3-5 ;;
1407   m68*-sgi-iris3.6* | m68*-sgi-iris*) machine=irist opsys=iris3-6 ;;
1408   dnl Iris 4D
1409   mips-sgi-irix3.*    ) opsys=irix3-3 ;;
1410   mips-sgi-irix4.*    ) opsys=irix4-0 ;;
1411   mips-sgi-irix6*     ) opsys=irix6-0 ;;
1412   mips-sgi-irix5.1*   ) opsys=irix5-1 ;;
1413   mips-sgi-irix5.2*   ) opsys=irix5-2 ;;
1414   mips-sgi-irix5.*    ) opsys=irix5-3 ;;
1415   mips-sgi-irix*      ) opsys=irix5-0 ;;
1416
1417   dnl SONY machines
1418   *-sony-newsos[[34]]* | *-sony-news[[34]]* ) opsys=bsd4-3 ;;
1419   *-sony-news* ) opsys=newsos5 ;;
1420
1421   dnl Stride
1422   m68*-stride-sysv* ) machine=stride opsys=usg5-2 ;;
1423
1424   dnl Suns
1425   *-*-solaris* | *-*-sunos* | *-sun-mach* | *-sun-bsd* )
1426     dnl Hardware type
1427     case "$canonical" in
1428       m68*-sunos1* )             machine=sun1     ;;
1429       m68*-sunos2* )             machine=sun2     ;;
1430       m68* )                     machine=sun3     ;;
1431       i*86*-sun-sunos[[34]]* )   machine=sun386   ;;
1432       i*86-*-* )                 machine=intel386 ;;
1433       rs6000* )                  machine=rs6000   ;;
1434     esac
1435
1436     dnl Make $canonical even more so.
1437     case "$canonical" in *-sunos5*)
1438       canonical=`echo $canonical | sed -e s/sunos5/solaris2/`;;
1439     esac
1440
1441     dnl On SunOS 4, use /usr/lib/cpp, sans dynodump, /bin/ranlib
1442     dnl On SunOS 5, use cc -E,        need dynodump, RANLIB not needed
1443     dnl But, SunOS 5.6 no longer needs dynodump because it has a similar
1444     dnl function integrated.
1445     case "$canonical" in
1446       *-sunos4* )
1447         #test -f /usr/lib/cpp     && NON_GNU_CPP=/usr/lib/cpp ;;
1448         : ;;
1449       *-solaris2* )
1450         #test -f /usr/ccs/lib/cpp && NON_GNU_CPP=/usr/ccs/lib/cpp
1451         RANLIB=':' ;;
1452     esac
1453
1454     case "$canonical" in
1455       *-solaris* )
1456         opsys=sol2
1457         os_release_major=`uname -r | sed -e 's/^\([[0-9]]\{1,\}\)\.\([[0-9]]\{1,\}\).*/\1/'`
1458         os_release_minor=`uname -r | sed -e 's/^\([[0-9]]\{1,\}\)\.\([[0-9]]\{1,\}\).*/\2/'`
1459         case "$os_release_minor" in [[0-9]])
1460           os_release_minor="0${os_release_minor}";;
1461         esac
1462         os_release="${os_release_major}${os_release_minor}"
1463         AC_DEFINE_UNQUOTED(OS_RELEASE, $os_release) ;;
1464
1465       dnl The last Sun386 ran 4.0.
1466       i*86-*-sunos4*      ) opsys=sunos4-0      ;;
1467       *-sunos4.0*         ) opsys=sunos4-0      ;;
1468       *-sunos4.1.2*       ) opsys=sunos4-1-2    ;;
1469       *-sunos4.1.3*       ) opsys=sunos4-1-3    ;;
1470       *-sunos4.1.[[4-9]]* ) opsys=sunos4-1-4    ;;
1471       *-sunos4* | *-sunos ) opsys=sunos4-1      ;;
1472       *-mach*             ) opsys=mach-bsd4-3   ;;
1473       *                   ) opsys=bsd4-2        ;;
1474     esac
1475
1476     case "$canonical" in *-sunos4*shr* ) opsys="${opsys}-shr" ;; esac
1477
1478     dnl Watch out for a compiler guaranteed not to work.
1479     test "$opsys $CC" = "sol2 /usr/ucb/cc" && CC=""
1480   ;;
1481
1482   dnl Tadpole 68k
1483   m68*-tadpole-sysv* ) machine=tad68k opsys=usg5-3 ;;
1484
1485   dnl Tahoe machines
1486   tahoe-tahoe-bsd4.2* ) machine=tahoe opsys=bsd4-2 ;;
1487   tahoe-tahoe-bsd4.3* ) machine=tahoe opsys=bsd4-3 ;;
1488
1489   dnl Tandem Integrity S2
1490   mips-tandem-sysv* ) machine=tandem-s2 opsys=usg5-3 ;;
1491
1492   dnl Tektronix XD88
1493   m88k-tektronix-sysv3* ) machine=tekxd88 opsys=usg5-3 ;;
1494
1495   dnl Tektronix 16000 box (6130?)
1496   ns16k-tektronix-bsd* ) machine=ns16000 opsys=bsd4-2 ;;
1497   dnl Tektronix 4300
1498   dnl src/m/tek4300.h hints that this is a m68k machine.
1499   m68*-tektronix-bsd* ) machine=tek4300 opsys=bsd4-3 ;;
1500
1501   dnl Titan P2 or P3
1502   titan-titan-sysv* ) machine=titan opsys=usg5-3 ;;
1503
1504   dnl Ustation E30 (SS5E)
1505   m68*-unisys-uniplus* ) machine=ustation opsystem=unipl5-2 ;;
1506
1507   dnl Vaxen.
1508   vax-dec-* )
1509     case "$canonical" in
1510       *-sysv[[01]]* | *-sysvr[[01]]* )  opsys=usg5-0 ;;
1511       *-sysv2* | *-sysvr2* )            opsys=usg5-2 ;;
1512       *-mach* )                         opsys=mach-bsd4-3 ;;
1513     esac
1514   ;;
1515
1516   dnl Whitechapel MG1
1517   ns16k-whitechapel-* ) machine=mg1 ;;
1518
1519   dnl Wicat
1520   m68*-wicat-sysv* ) machine=wicat opsys=usg5-2 ;;
1521
1522   dnl Intel 386 machines where we do not care about the manufacturer
1523   i[[3-9]]86-*-* )
1524     machine=intel386
1525     case "$canonical" in
1526       *-isc1.* | *-isc2.[[01]]* ) opsys=386-ix ;;
1527       *-isc2.2* )               opsys=isc2-2 ;;
1528       *-isc4.0* )               opsys=isc4-0 ;;
1529       *-isc4.* )                opsys=isc4-1
1530                                 GCC_TEST_OPTIONS=-posix
1531                                 NON_GCC_TEST_OPTIONS=-Xp
1532                                 ;;
1533       *-isc* )                  opsys=isc3-0 ;;
1534       *-esix5* )                opsys=esix5r4 NON_GNU_CPP=/usr/lib/cpp ;;
1535       *-esix* )                 opsys=esix ;;
1536       *-mach* )                 opsys=mach-bsd4-3 ;;
1537       *-xenix* )                opsys=xenix ;;
1538       *-sco3.2v4* )             opsys=sco4 NON_GNU_CPP=/lib/cpp  ;;
1539       *-bsd386* | *-bsdi1* )    opsys=bsd386 ;;
1540       *-bsdi4* )                opsys=bsdos4 ;;
1541       *-bsdi3* )                opsys=bsdos3 ;;
1542       *-bsdi2.1* )              opsys=bsdos2-1 ;;
1543       *-bsdi2* )                opsys=bsdos2 ;;
1544       *-sco3.2v5* )             opsys=sco5 ;;
1545       *-sysv5* )                opsys=sco7 ;;
1546       *-386bsd* )               opsys=386bsd ;;
1547       *-freebsd* )              opsys=freebsd ;;
1548       *-nextstep* )             opsys=nextstep ;;
1549       *-pc-cygwin* )            opsys=cygwin32 ;;
1550       *-pc-mingw* )             opsys=mingw32 ;
1551                                 test -z "$with_tty" && with_tty="no";;
1552       dnl Otherwise, we fall through to the generic opsys code at the bottom.
1553     esac
1554   ;;
1555
1556   dnl Linux/68k
1557   m68k-*-linux* ) machine=m68k opsys=linux ;;
1558
1559 esac
1560
1561 dnl Initialize machine from $canonical if not in our database above.
1562 test -z "$machine" && machine=`echo $canonical | sed 's/-.*$//'`
1563
1564 dnl Initialize opsys from `uname -s` if not in our database above.
1565 test -z "$opsys"   && opsys=`uname -s | tr ABCDEFGHIJKLMNOPQRSTUVWXYZ abcdefghijklmnopqrstuvwxyz`
1566
1567 dnl Use configure-time autodetection if s&m not available
1568 if test -r "${srcdir}/src/m/${machine}.h"; then
1569   machfile="m/${machine}.h"
1570   AC_DEFINE_UNQUOTED(config_machfile, "$machfile")
1571 else
1572   echo "XEmacs has no builtin knowledge of \`$machine' machines."
1573   echo "Using configure-time autodetection only."
1574 fi
1575
1576 if test -r "${srcdir}/src/s/${opsys}.h"; then
1577   opsysfile="s/${opsys}.h"
1578   AC_DEFINE_UNQUOTED(config_opsysfile, "$opsysfile")
1579 else
1580   echo "XEmacs has no builtin knowledge of \`$opsys' operating systems."
1581   echo "Using configure-time autodetection only."
1582 fi
1583
1584 dnl --------------------------------------------------------------
1585 dnl $opsys detection complete; defaults depending on $opsys follow
1586 dnl --------------------------------------------------------------
1587
1588 if test -z "$pdump"; then
1589   case "$opsys" in
1590     linux* )  pdump=yes ;;    dnl glibc 2.3.1 seems to hose unexec
1591     darwin )  pdump=yes ;;    dnl No "native" working dumper available
1592     cygwin* ) pdump=yes ;;    dnl unexec is broken
1593     *)        pdump=no ;;
1594   esac
1595 fi
1596
1597 if test -z "$dynamic"; then
1598   case "$opsys" in
1599     hpux* | sunos4* ) dynamic=no ;;
1600     *) dynamic=yes ;;
1601   esac
1602 fi
1603 if test "$dynamic" = "yes"; then
1604   case "$opsys" in
1605     hpux* | sunos4* | sco5 ) opsys="${opsys}-shr" ;;
1606     decosf* ) ld_call_shared="-call_shared" ;;
1607     darwin ) AC_DEFINE(DLSYM_NEEDS_UNDERSCORE) ;;
1608   esac
1609 else dnl "$dynamic" = "no"
1610   case "$opsys" in
1611     sol2 )
1612       echo "Static linking is not supported on Solaris 2."
1613       echo "Rerun configure without specifying --dynamic=no."
1614       exit 1 ;;
1615     linux   ) ld_call_shared="-Bstatic" ;;
1616     decosf* ) ld_call_shared="-non_shared" ;;
1617   esac
1618 fi
1619
1620 dnl Use xlc by default on AIX
1621 case "$opsys" in aix*) NON_GNU_CC=xlc ;; esac
1622
1623 stack_trace_eye_catcher=`echo ${PROGNAME}_${version}_${canonical} | sed 'y/.-/__/'`
1624 AC_DEFINE_UNQUOTED(STACK_TRACE_EYE_CATCHER, $stack_trace_eye_catcher)
1625
1626 dnl --------------------------------------------------
1627 dnl Determine the compiler, set up for feature testing
1628 dnl --------------------------------------------------
1629
1630 dnl Sun Development environment support
1631 test "$with_sparcworks" = "yes" && with_workshop=yes # compatibility alias
1632 XE_CHECK_FEATURE_DEPENDENCY(workshop, tooltalk)
1633 if test "$with_workshop" = "yes"; then
1634   AC_DEFINE(SUNPRO)
1635   XE_ADD_OBJS(sunpro.o)
1636 fi
1637
1638 if test "$with_clash_detection" != "no"; then
1639   AC_DEFINE(CLASH_DETECTION)
1640   XE_ADD_OBJS(filelock.o)
1641 fi
1642
1643 dnl Choose a compiler from (in order)
1644 dnl --compiler, env var CC, with_gcc=no && ${NON_GNU_CC:-cc}, AC_PROG_CC
1645 test -n "$compiler" && CC="$compiler"
1646 if test "$with_gcc" = "no"; then dnl Try to find a non-gcc compiler
1647   case "$CC" in "" | *gcc* ) CC="${NON_GNU_CC-cc}" ;; esac
1648 fi
1649
1650 dnl If we don't set CFLAGS here, AC_PROG_CC will set it.
1651 dnl But we know better what's good for us, so we do our own
1652 dnl computation of real CFLAGS later.
1653 dnl --cflags overrides environment variable CFLAGS
1654 test "${cflags-unset}" != unset && CFLAGS="$cflags"
1655 if test "${CFLAGS-unset}" != unset
1656   then cflags_specified=yes;
1657   else cflags_specified=no;
1658 fi
1659
1660 xe_save_CFLAGS="$CFLAGS"
1661
1662 AC_PROG_CC dnl Autoconf has its own magic for compiler autodetection
1663
1664 dnl Retry using random guesswork if AC_PROG_CC got it wrong...
1665 if   test "$with_gcc" = "no"  -a "$GCC" = "yes"; then
1666   CC=${NON_GNU_CC-cc}
1667   AC_PROG_CC
1668 elif test "$with_gcc" = "yes" -a "$GCC" != "yes" ; then
1669   CC=gcc
1670   AC_PROG_CC
1671 fi
1672 CFLAGS="$xe_save_CFLAGS"
1673
1674 dnl Figure out what C preprocessor to use.
1675
1676 dnl On Sun systems, people sometimes set up the variable CPP
1677 dnl with a value that is a directory, not an executable at all.
1678 dnl Detect that case, and ignore that value.
1679 test -n "$CPP" -a -d "$CPP" && CPP=
1680
1681 test -n "$NON_GNU_CPP" -a "$GCC" != "yes" -a -z "$CPP" && CPP="$NON_GNU_CPP"
1682
1683 AC_PROG_CPP
1684
1685 dnl --------------------------------------------------------------------
1686 dnl Compiler feature macros
1687 dnl --------------------------------------------------------------------
1688
1689 AC_AIX dnl Defines _ALL_SOURCE on AIX.
1690
1691 dnl We want feature macros defined here *and* in config.h.in, so that
1692 dnl the compilation environment at configure time and compile time agree.
1693
1694 AC_MSG_CHECKING(for GNU libc)
1695 AC_TRY_COMPILE([#include <features.h>],[
1696 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
1697 #error Not a GNU libc system :-(
1698 ******* ======= ******** &&&&&&&&
1699 #endif
1700 ], have_glibc=yes, have_glibc=no)
1701 AC_MSG_RESULT($have_glibc)
1702 dnl I'm tired of pop being broken with GLIBC -slb
1703 dnl Well. then why not fix fucking pop?
1704 test "$have_glibc" = "yes" && AC_DEFINE(_GNU_SOURCE)
1705
1706 dnl We'd like to use vendor extensions, where available.
1707 dnl We'd like to use functions from the latest Unix98 standards.
1708 dnl See http://www.opengroup.org/onlinepubs/007908799/xsh/compilation.html
1709 case "$opsys" in
1710   sol2)
1711    AC_DEFINE(__EXTENSIONS__)
1712    dnl Solaris 2 before 2.5 had some bugs with feature test macro interaction.
1713    if test "$os_release" -ge 505; then
1714      AC_DEFINE(_XOPEN_SOURCE,500)
1715      AC_DEFINE(_XOPEN_SOURCE_EXTENDED)
1716    fi ;;
1717   linux)
1718     AC_DEFINE(_POSIX_C_SOURCE,199506L)
1719     AC_DEFINE(_XOPEN_SOURCE,500)
1720     AC_DEFINE(_XOPEN_SOURCE_EXTENDED)
1721     ;;
1722 esac
1723
1724 dnl Identify compilers to enable compiler-specific hacks.
1725 dnl Add support for other compilers HERE!
1726 dnl GCC is already identified elsewhere.
1727 AC_TRY_RUN([int main () {
1728 #if defined __SUNPRO_C
1729 return 11;
1730 #elif defined __DECC
1731 return 12;
1732 #elif defined __USLC__ && defined __SCO_VERSION__
1733 return 13;
1734 #elif defined __INTEL_COMPILER
1735 return 14;
1736 #else
1737 return 0;
1738 #endif
1739 }], [],
1740 [case "$conftest_rc" in
1741   11) echo "You appear to be using the SunPro C compiler." ; __SUNPRO_C=yes ;;
1742   12) echo "You appear to be using the DEC C compiler."    ; __DECC=yes ;;
1743   13) echo "You appear to be using the SCO C compiler."    ; __USLC__=yes ;;
1744   14) echo "You appear to be using the Intel C++ compiler."; __ICC=yes
1745       dnl Newer versions of icc claim to be GCC
1746       GCC=no ;;
1747 esac])
1748
1749
1750 dnl case "$canonical" in
1751 dnl   *-sun-sunos* ) test "$CPP" = "acc -E" && CPP="acc -E -Xs" ;;
1752 dnl esac
1753
1754 dnl --------------------------------------------------------------------
1755 dnl Extract some information from the operating system and machine files
1756 dnl --------------------------------------------------------------------
1757
1758 echo "Extracting information from the machine- and system-dependent headers..."
1759
1760 dnl It is not important that this name contain the PID; you cannot run
1761 dnl two configures in the same directory and have anything work
1762 dnl anyway.
1763 tempcname="conftest.c"
1764
1765 dnl CPP_to_sh(CPP_SYMBOL, SH_VAR, DEFAULT_VALUE)
1766 define([CPP_to_sh],
1767 [[#]ifndef [$1]
1768 [#]define [$1]ifelse([$3],,, [ "$3"])
1769 [#]endif
1770 configure___ [$2]=[$1]
1771 ])dnl CPP_to_sh
1772
1773 dnl CPP_boolean_to_sh(CPP_SYMBOL, SH_VAR)
1774 define([CPP_boolean_to_sh],
1775 [[#]ifdef [$1]
1776 configure___ [$2]=yes
1777 [#]else
1778 configure___ [$2]=no
1779 [#]endif
1780 ])dnl CPP_boolean_to_sh
1781
1782 cat > $tempcname < confdefs.h
1783 cat >> $tempcname <<EOF
1784 #define NOT_C_CODE
1785 #define C_SWITCH_SITE
1786 #define C_SWITCH_X_SITE
1787 #define LD_SWITCH_SITE
1788 #define LD_SWITCH_X_SITE
1789 #define LD_SWITCH_X_SITE_AUX
1790 #define OS_RELEASE $os_release
1791
1792 #ifdef config_opsysfile
1793 #include "$srcdir/src/$opsysfile"
1794 #endif
1795
1796 #ifdef config_machfile
1797 #include "$srcdir/src/$machfile"
1798 #endif
1799
1800 CPP_to_sh(LIBS_MACHINE, libs_machine)
1801 CPP_to_sh(LIBS_SYSTEM,  libs_system)
1802 CPP_to_sh(LIBS_TERMCAP, libs_termcap)
1803 CPP_to_sh(LIB_STANDARD, libs_standard)
1804
1805 CPP_to_sh(OBJECTS_MACHINE, objects_machine)
1806 CPP_to_sh(OBJECTS_SYSTEM,  objects_system)
1807
1808 CPP_to_sh(C_SWITCH_MACHINE,   c_switch_machine)
1809 CPP_to_sh(C_SWITCH_SYSTEM,    c_switch_system)
1810
1811 CPP_to_sh(LD_SWITCH_MACHINE,  ld_switch_machine)
1812 CPP_to_sh(LD_SWITCH_SYSTEM,   ld_switch_system)
1813
1814 CPP_to_sh(UNEXEC, unexec, unexec.o)
1815
1816 CPP_to_sh(LD_SWITCH_SHARED, ld_switch_shared, -c)
1817
1818 #define ORDINARY_LD "\$(CC) \$(CFLAGS)"
1819 configure___ ordinary_ld=ORDINARY_LD
1820
1821 #ifdef ORDINARY_LINK
1822 #define LD ORDINARY_LD
1823 #else /* no ORDINARY LINK */
1824 #ifdef COFF_ENCAPSULATE
1825 #define LD "\$(CC) -nostdlib"
1826 #else /* not COFF_ENCAPSULATE */
1827 #ifdef LINKER
1828 #define LD LINKER
1829 #else /* ! defined (LINKER) */
1830 #define LD "ld"
1831 #endif /* ! defined (LINKER) */
1832 #endif /* ! defined (COFF_ENCAPSULATE) */
1833 #endif /* not ORDINARY_LINK */
1834 configure___ ld=LD
1835
1836 CPP_to_sh(LIB_GCC, lib_gcc)
1837 CPP_to_sh(LD_TEXT_START_ADDR, ld_text_start_addr)
1838
1839 #if ! defined (ORDINARY_LINK) && !defined (START_FILES)
1840 #ifdef NO_REMAP
1841 #ifdef COFF_ENCAPSULATE
1842 #define START_FILES "pre-crt0.o /usr/local/lib/gcc-crt0.o"
1843 #else /* ! defined (COFF_ENCAPSULATE) */
1844 #define START_FILES "pre-crt0.o /lib/crt0.o"
1845 #endif /* ! defined (COFF_ENCAPSULATE) */
1846 #else /* ! defined (NO_REMAP) */
1847 #define START_FILES "ecrt0.o"
1848 #endif /* ! defined (NO_REMAP) */
1849 #endif /* no ORDINARY_LINK */
1850 #ifndef START_FILES
1851 #define START_FILES
1852 #endif
1853 configure___ start_files=START_FILES
1854
1855 CPP_boolean_to_sh(ORDINARY_LINK, ordinary_link)
1856 CPP_boolean_to_sh(SYSTEM_MALLOC, system_malloc)
1857 CPP_boolean_to_sh(TERMINFO, have_terminfo)
1858 dnl The MAIL_USE_xxx variables come from the s&m headers
1859 CPP_boolean_to_sh(MAIL_USE_FLOCK, mail_use_flock)
1860 CPP_boolean_to_sh(MAIL_USE_LOCKF, mail_use_lockf)
1861 CPP_boolean_to_sh(MAIL_USE_LOCKING, mail_use_locking)
1862 CPP_boolean_to_sh(HAVE_WIN32_PROCESSES, win32_processes)
1863 EOF
1864
1865 dnl The value of CPP is a quoted variable reference, so we need to do this
1866 dnl to get its actual value...
1867 CPP=`eval "echo $CPP $CPPFLAGS"`
1868 define(TAB, [   ])dnl
1869 changequote(, )dnl
1870 eval `$CPP -Isrc $tempcname \
1871         | sed -n -e "s/[ TAB]*=[ TAB\"]*/='/" -e "s/[ TAB\"]*\$/'/" -e "s/^configure___//p"`
1872 changequote([, ])dnl
1873
1874 rm $tempcname
1875
1876 if test "$pdump" = "yes"; then
1877   ordinary_link="yes"
1878   ld="${ordinary_ld}"
1879   start_files=
1880   libs_standard=
1881   unexec=
1882   lib_gcc=
1883 fi
1884
1885 dnl For debugging...
1886 test "$extra_verbose" = "yes" && \
1887   PRINT_VAR(libs_machine libs_system libs_termcap libs_standard
1888   objects_machine objects_system c_switch_machine c_switch_system
1889   ld_switch_machine ld_switch_system unexec ld_switch_shared
1890   ld lib_gcc ld_text_start_addr start_files ordinary_link
1891   have_terminfo mail_use_flock mail_use_lockf) && echo ""
1892
1893 dnl Pick up mingw include path
1894 dnl We only cope with headers in mingw, not mingw32: no previous version of
1895 dnl XEmacs supported mingw and cygnus have made this incompatible change
1896 dnl so we just go with the flow.
1897 case "$opsys" in mingw* | cygwin*)
1898   cygwin_include=`eval "gcc -print-file-name=libc.a"` ;
1899   cygwin_include=`eval "dirname $cygwin_include"` ;
1900   cygwin_include="-I$cygwin_include/../include" ;
1901   extra_includes="$cygwin_include/mingw $cygwin_include" ;
1902   case "$opsys" in mingw*)
1903     XE_APPEND($extra_includes, c_switch_system) ;;
1904   esac
1905   ;;
1906 esac
1907
1908 dnl Non-ordinary link usually requires -lc
1909 test "$ordinary_link" = "no" -a -z "$libs_standard" && libs_standard="-lc"
1910
1911 dnl -----------------------
1912 dnl Compiler-specific hacks
1913 dnl -----------------------
1914
1915 dnl DEC C `-std1' means ANSI C mode
1916 test "$__DECC" = "yes" && XE_APPEND(-std1, c_switch_site)
1917
1918 dnl Some versions of SCO native compiler need -Kalloca
1919 if test "$__USLC__" = yes; then
1920   AC_MSG_CHECKING(for whether the -Kalloca compiler flag is needed)
1921   need_kalloca=no
1922   AC_TRY_LINK([], [void *x = alloca(4);], [:], [
1923     xe_save_c_switch_system="$c_switch_system"
1924     c_switch_system="$c_switch_system -Kalloca"
1925     AC_TRY_LINK([], [void *x = alloca(4);], [ need_kalloca=yes ])
1926     c_switch_system="$xe_save_c_switch_system"])
1927   AC_MSG_RESULT($need_kalloca)
1928   test "$need_kalloca" = "yes" && XE_APPEND(-Kalloca,c_switch_system)
1929 fi
1930
1931 dnl Calculate value of CFLAGS:
1932 dnl Use either command line flag, environment var, or autodetection
1933 if test "$cflags_specified" = "no"; then
1934   dnl Following values of CFLAGS are known to work well.
1935   dnl Should we take debugging options into consideration?
1936   if   test "$GCC" = "yes"; then
1937     CFLAGS="-g -O3 -Wall -Wno-switch -Winline -Wmissing-prototypes"
1938     dnl Yuck, bad compares have been worth at least 3 crashes!
1939     CFLAGS="$CFLAGS -Wsign-compare"
1940     dnl XEmacs is known not to be strict-aliasing-safe.
1941     case "`gcc -v --help 2>&1`" in
1942       *-fstrict-aliasing* ) CFLAGS="$CFLAGS -fno-strict-aliasing" ;;
1943     esac
1944     dnl You get five zillion shadowing warnings with g++.
1945     dnl Even with gcc, -Wshadow is questionable because of its complaints
1946     dnl about parameters with the same names as global functions.
1947     if test "$xemacs_compiler" != "g++"; then
1948       CFLAGS="$CFLAGS -Wshadow"
1949     fi
1950     dnl glibc is intentionally not `-Wpointer-arith'-clean.
1951     dnl Ulrich Drepper has rejected patches to fix the glibc header files.
1952     test "$have_glibc" != "yes" && CFLAGS="$CFLAGS -Wpointer-arith"
1953     dnl I'm not convinced this is a good idea any more. -sb
1954     dnl test "$opsys $machine" = "linux intel386" && \
1955     dnl CFLAGS="$CFLAGS -fno-strength-reduce -malign-loops=2 -malign-jumps=2 -malign-functions=2"
1956   elif test "$__SUNPRO_C" = "yes"; then
1957     case "$opsys" in
1958       sol2    ) CFLAGS="-v -xO4" ;;
1959       sunos4* ) CFLAGS="-xO2";;
1960     esac
1961   elif test "$__DECC" = "yes"; then
1962     CFLAGS="-O3"
1963   elif test "$CC" = "xlc"; then
1964     CFLAGS="-g -O3 -qstrict -qnoansialias -qlibansi -qinfo -qro -qmaxmem=20000"
1965   elif test "$__ICC" = "yes"; then
1966     CFLAGS="-g -O3 -Ob2 -Wall -W1"
1967   dnl ### Add optimal CFLAGS support for other compilers HERE!
1968   else
1969     CFLAGS="-O" ;dnl The only POSIX-approved flag
1970   fi
1971 fi
1972
1973 dnl Search for GCC specific build problems we know about
1974 if test "$GCC" = "yes"; then
1975 AC_MSG_CHECKING(for buggy gcc versions)
1976 GCC_VERSION=`$CC --version`
1977 case `uname -s`:`uname -m`:$GCC_VERSION in
1978         dnl egcs 2.90.21 (egcs-1.00 release)
1979         dnl egcs 2.90.29 (egcs-1.0.3 release)
1980     *:sun4*:2.8.1|*:sun4*:egcs-2.90.*)
1981         dnl Don't use -O2 with gcc 2.8.1 and egcs 1.0 under SPARC architectures
1982         dnl without also using `-fno-schedule-insns'.
1983         case "$CFLAGS" in
1984             *-O2*|*-O3*)
1985                 case "$CFLAGS" in
1986                     *-fno-schedule-insns*) ;;
1987                     *)
1988                         AC_MSG_RESULT(yes)
1989                         AC_MSG_WARN(Don't use -O2 with gcc 2.8.1 and egcs 1.0 under SPARC architectures)
1990                         AC_MSG_WARN(without also using -fno-schedule-insns.)
1991                         AC_MSG_ERROR(Aborting due to known problem)
1992                         ;;
1993                 esac
1994                 ;;
1995         esac
1996         ;;
1997         dnl egcs-2.91.57 (egcs-1.1 release)
1998         dnl egcs-2.91.66 (egcs-1.1.2 release)
1999     Linux:alpha:egcs-2.91.*)
2000         AC_MSG_RESULT(yes)
2001         AC_MSG_WARN(There have been reports of egcs-1.1 not compiling XEmacs correctly on)
2002         AC_MSG_WARN(Alpha Linux.  There have also been reports that egcs-1.0.3a is O.K.)
2003         AC_MSG_ERROR(Aborting due to known problem)
2004         ;;
2005     *:i*86*:2.7.2*)
2006         case "$CFLAGS" in
2007             *-O2*|*-O3*)
2008                 case "$GCC_VERSION" in
2009                     2.7.2)
2010                         case "$CFLAGS" in
2011                             *-fno-strength-reduce*) ;;
2012                             *)
2013                                 AC_MSG_RESULT(yes)
2014                                 AC_MSG_WARN(Don't use -O2 with gcc 2.7.2 under Intel/XXX without also using)
2015                                 AC_MSG_WARN(-fno-strength-reduce.)
2016                                 AC_MSG_ERROR(Aborting due to known problem)
2017                                 ;;
2018                         esac
2019                         ;;
2020                 esac
2021                 case "$CFLAGS" in
2022                  *-fno-caller-saves*) ;;
2023                  *)
2024                     AC_MSG_RESULT(yes)
2025                     AC_MSG_WARN(Don't use -O2 with gcc 2.7.2 under Intel/XXX without also using)
2026                     AC_MSG_WARN(-fno-caller-saves.)
2027                     AC_MSG_ERROR(Aborting due to known problem)
2028                     ;;
2029                 esac
2030                 ;;
2031         esac
2032         ;;
2033 esac
2034 AC_MSG_RESULT(no)
2035 fi
2036
2037 dnl GNU ld now defaults to combreloc, which screws up unexec, but not pdump.
2038 dnl Note that it's OK if the GNU style long option causes non-GNU ld to barf
2039 dnl a usage message, that's often good enough.  Please report it, though.
2040 dnl #### Should make this Solaris-friendly.
2041 dnl Link with -z nocombreloc for now.
2042 if test "$pdump" != "yes"; then
2043   AC_MSG_CHECKING(for \"-z nocombreloc\" linker flag)
2044   case "`ld --help 2>&1`" in
2045     *-z\ nocombreloc* ) AC_MSG_RESULT(yes)
2046       XE_PREPEND(-z nocombreloc, ld_switch_site) ;;
2047     *) AC_MSG_RESULT(no) ;;
2048   esac
2049 fi
2050
2051
2052 dnl Inform compiler that certain flags are meant for the linker
2053 dnl XE_PROTECT_LINKER_FLAGS(shell_var)
2054 define([XE_PROTECT_LINKER_FLAGS], [
2055 if test "$GCC" = "yes"; then
2056   set x $[$1]; shift; [$1]=""
2057   while test -n "[$]1"; do
2058     case [$]1 in
2059       -L  | -l  | -u               ) [$1]="$[$1] [$]1 [$]2"; shift ;;
2060       -L* | -l* | -u* | -Wl* | -pg ) [$1]="$[$1] [$]1" ;;
2061       -Xlinker* ) ;;
2062       * ) [$1]="$[$1] -Xlinker [$]1" ;;
2063     esac
2064     shift
2065   done
2066 fi])dnl
2067 XE_PROTECT_LINKER_FLAGS(ld_switch_system)
2068 XE_PROTECT_LINKER_FLAGS(ld_switch_machine)
2069 XE_PROTECT_LINKER_FLAGS(ld_switch_site)
2070 XE_PROTECT_LINKER_FLAGS(LDFLAGS)
2071 XE_PROTECT_LINKER_FLAGS(ld_call_shared)
2072
2073 dnl Add s&m-determined objects (including unexec) to link line
2074 test -n "$objects_machine" && XE_ADD_OBJS($objects_machine)
2075 test -n "$objects_system"  && XE_ADD_OBJS($objects_system)
2076 test -n "$unexec"          && test ! "$pdump" = "yes" && XE_ADD_OBJS($unexec)
2077 test "$pdump" = "yes" && XE_ADD_OBJS(dumper.o)
2078
2079 dnl Dynodump (Solaris 2.x, x<6)
2080 AC_MSG_CHECKING(for dynodump)
2081 if test "$unexec" != "unexsol2.o"; then
2082   AC_MSG_RESULT(no)
2083 else
2084   AC_MSG_RESULT(yes)
2085   AC_DEFINE(DYNODUMP)
2086   XE_APPEND(dynodump, MAKE_SUBDIR)
2087   XE_APPEND(dynodump, SRC_SUBDIR_DEPS)
2088   case "$machine" in
2089     sparc   ) dynodump_arch=sparc ;;
2090     *86*    ) dynodump_arch=i386  ;;
2091     powerpc ) dynodump_arch=ppc   ;;
2092   esac
2093 fi
2094
2095 dnl Feed s&m crud to src/Makefile
2096
2097 dnl Linux/powerpc needs the following magic for some reason
2098 dnl [Not needed with YellowDog 2.3 and causes link problems with YellowDog 3.0,
2099 dnl the two most popular PowerPC distributions.]
2100 dnl test "$machine$opsys" = "powerpclinux" && start_flags="-T $srcdir/src/ppc.ldscript"
2101
2102 if test "$unexec" = "unexaix.o"; then
2103 dnl AIX needs various hacks to make static linking work.
2104   if   test "$dynamic" = "no"; then
2105   start_flags="-Wl,-bnso,-bnodelcsect"
2106   test "$GCC" = "yes" && start_flags="-B/bin/ ${start_flags}"
2107   for f in "/lib/syscalls.exp" "/lib/threads.exp"; do
2108     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; fi
2109   done
2110   for f in "/usr/lpp/X11/bin/smt.exp" "/usr/bin/X11/smt.exp"; do
2111     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; break; fi
2112   done
2113   AC_CHECK_LIB(C, terminateAndUnload, XE_APPEND(-lC, libs_system))
2114   fi
2115 elif test -n "$ld_text_start_addr"; then
2116   start_flags="-T $ld_text_start_addr -e __start"
2117 fi
2118 AC_SUBST(start_flags)
2119
2120 AC_SUBST(ld_switch_shared)
2121 AC_SUBST(start_files)
2122 if test "$ordinary_link" = "no" -a "$GCC" = "yes"; then
2123  test -z "$linker" &&  linker='$(CC) -nostdlib'
2124  test -z "$lib_gcc" && lib_gcc='`$(CC) -print-libgcc-file-name`'
2125 fi
2126 test "$GCC" != "yes" && lib_gcc=
2127 AC_SUBST(ld)
2128 AC_SUBST(lib_gcc)
2129
2130 dnl ---------------------------------------------------------------
2131 dnl Add site and system specific flags to compile and link commands
2132 dnl ---------------------------------------------------------------
2133
2134 dnl Allow use of either ":" or spaces for lists of directories
2135 define(COLON_TO_SPACE,
2136   [case "$[$1]" in *:* [)] [$1]="`echo '' $[$1] | sed -e 's/^ //' -e 's/:/ /g'`";; esac])dnl
2137
2138 dnl --site-libraries (multiple dirs)
2139 COLON_TO_SPACE(site_libraries)
2140 if test -n "$site_libraries"; then
2141   for arg in $site_libraries; do
2142     case "$arg" in
2143      -* ) ;;
2144      * ) test -d "$arg" || \
2145            XE_DIE("Invalid site library \`$arg': no such directory")
2146        arg="-L${arg}" ;;
2147     esac
2148     XE_APPEND($arg, ld_switch_site)
2149   done
2150 fi
2151
2152 dnl --site-includes (multiple dirs)
2153 COLON_TO_SPACE(site_includes)
2154 if test -n "$site_includes"; then
2155   for arg in $site_includes; do
2156     case "$arg" in
2157       -* ) ;;
2158       * ) test -d "$arg" || \
2159            XE_DIE("Invalid site include \`$arg': no such directory")
2160       arg="-I${arg}" ;;
2161     esac
2162     XE_APPEND($arg, c_switch_site)
2163   done
2164 fi
2165
2166 dnl --site-prefixes (multiple dirs)
2167 dnl --site-prefixes=dir1:dir2 is a convenient shorthand for
2168 dnl --site-libraries=dir1/lib:dir2/lib --site-includes=dir1/include:dir2/include
2169 dnl Site prefixes take precedence over the standard places, but not over
2170 dnl site-includes and site-libraries.
2171 COLON_TO_SPACE(site_prefixes)
2172 if test -n "$site_prefixes"; then
2173   for dir in $site_prefixes; do
2174     lib_dir="${dir}/lib"
2175     inc_dir="${dir}/include"
2176     if test ! -d "$dir"; then
2177       XE_DIE("Invalid site prefix \`$dir': no such directory")
2178     elif test ! -d "$lib_dir"; then
2179       XE_DIE("Invalid site prefix \`$dir': no such directory \`$lib_dir'")
2180     else
2181       if test -d "$inc_dir"; then
2182         XE_APPEND("-I$inc_dir", c_switch_site)
2183       fi
2184       XE_APPEND("-L$lib_dir", ld_switch_site)
2185     fi
2186   done
2187 fi
2188
2189 dnl GNU software installs by default into /usr/local/{include,lib}
2190 dnl if test -d "/usr/local/include" -a -d "/usr/local/lib"; then
2191 dnl   XE_APPEND("-L/usr/local/lib",    ld_switch_site)
2192 dnl   XE_APPEND("-I/usr/local/include", c_switch_site)
2193 dnl fi
2194
2195 dnl Extra system-specific library directories - please add to list
2196 for dir in "/usr/ccs/lib"; do
2197   test -d "$dir" && XE_APPEND(-L${dir}, ld_switch_system)
2198 done
2199
2200 dnl --site-runtime-libraries (multiple dirs)
2201 COLON_TO_SPACE(site_runtime_libraries)
2202 if test -n "$site_runtime_libraries"; then
2203   LD_RUN_PATH="`echo $site_runtime_libraries | sed -e 's/  */:/g'`"
2204   export LD_RUN_PATH
2205 fi
2206
2207 dnl Linux systems have dynamic runtime library directories listed in
2208 dnl /etc/ld.so.conf.  Since those are used at run time, it seems pretty
2209 dnl safe to use them at link time, and less controversial than forcing
2210 dnl the run-time to use the link-time libraries.  This also helps avoid
2211 dnl mismatches between the link-time and run-time libraries.
2212
2213 dnl #### Unfortunately, there are horrible libc4 and libc5 libraries
2214 dnl listed in /etc/ld.so.conf on some systems, and including them on
2215 dnl the link path leads to linking in utterly broken libc's.
2216 dnl There are many clever ways of approaching this problem,
2217 dnl but finding one that actually works...
2218
2219 dnl if test -z "$LD_RUN_PATH" -a -r "/etc/ld.so.conf"; then
2220 dnl   for dir in `cat /etc/ld.so.conf`; do
2221 dnl     test -d "$dir" && XE_APPEND(-L${dir}, ld_switch_system)
2222 dnl   done
2223 dnl   add_runtime_path=no
2224 dnl fi
2225
2226 dnl -------------------------------------
2227 dnl Compute runtime library path
2228 dnl -------------------------------------
2229
2230 if test -n "$add_runtime_path"; then :;
2231 elif test "$dynamic" = "no"; then add_runtime_path=no
2232 elif test -n "$LD_RUN_PATH"; then add_runtime_path=yes
2233 else case "$opsys" in
2234        sol2 | irix* | *bsd* | decosf* ) add_runtime_path=yes ;;
2235        * ) add_runtime_path=no ;;
2236      esac
2237 fi
2238
2239 if test "$add_runtime_path" = "yes"; then
2240   dnl Try to autodetect runtime library flag (usually -R),
2241   dnl and whether it works (or at least does no harm)
2242   AC_MSG_CHECKING("for runtime libraries flag")
2243   case "$opsys" in
2244     sol2 ) dash_r="-R" ;;
2245     decosf* | linux* | irix*) dash_r="-rpath " ;;
2246     *)
2247       dash_r=""
2248       for try_dash_r in "-R" "-R " "-rpath "; do
2249         xe_check_libs="${try_dash_r}/no/such/file-or-directory"
2250         XE_PROTECT_LINKER_FLAGS(xe_check_libs)
2251         AC_TRY_LINK(, , dash_r="$try_dash_r")
2252         xe_check_libs=""
2253         test -n "$dash_r" && break
2254       done ;;
2255   esac
2256   if test -n "$dash_r";
2257     then AC_MSG_RESULT("\"${dash_r}\"")
2258     else AC_MSG_RESULT(NONE)
2259   fi
2260 fi
2261
2262 xe_add_unique_runpath_dir='
2263   xe_add_p=yes
2264   for xe_dir in $runpath_dirs; do   dnl Uniquify
2265     test "$xe_dir" = "$xe_runpath_dir" && xe_add_p=no
2266   done
2267   if test "$xe_add_p" = "yes"; then
2268     test -n "$runpath" && runpath="${runpath}:"
2269     runpath="${runpath}${xe_runpath_dir}"
2270     runpath_dirs="$runpath_dirs $xe_runpath_dir"
2271   fi'
2272
2273
2274 dnl XE_ADD_RUNPATH_DIR(directory)
2275 define([XE_ADD_RUNPATH_DIR],[{
2276 xe_runpath_dir=$1
2277 dnl PRINT_VAR(ld_switch_site ld_switch_x_site runpath xe_runpath_dir LD_RUN_PATH xe_ldflags)
2278   test "$xe_runpath_dir" != "/lib"     -a \
2279         "$xe_runpath_dir" != "/usr/lib" -a \
2280         -n "`ls ${xe_runpath_dir}/*.s[[ol]] 2>/dev/null`" && \
2281   eval "$xe_add_unique_runpath_dir"
2282 }])dnl
2283
2284 dnl XE_COMPUTE_RUNPATH()
2285 define([XE_COMPUTE_RUNPATH],[
2286 if test "$add_runtime_path" = "yes" -a -n "$dash_r"; then
2287   dnl Remove runtime paths from current ld switches
2288   ld_switch_site=`echo   '' $ld_switch_site   | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
2289   ld_switch_x_site=`echo '' $ld_switch_x_site | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
2290   dnl PRINT_VAR(ld_switch_site ld_switch_x_site)
2291
2292   dnl Fix up Runtime path
2293   dnl If LD_RUN_PATH is set in environment, use that.
2294   dnl In this case, assume user has set the right value.
2295   runpath="" runpath_dirs=""
2296   if test -n "$LD_RUN_PATH"; then
2297     runpath="$LD_RUN_PATH"
2298   elif test "$GCC" = "yes"; then
2299     dnl Compute runpath from gcc's -v output
2300     ld_switch_run_save="$ld_switch_run"; ld_switch_run=""
2301     echo "int main(int argc, char *argv[[]]) {return 0;}" > conftest.c
2302     xe_runpath_link='${CC-cc} -o conftest -v $CFLAGS '"$xe_ldflags"' conftest.$ac_ext 2>&1 1>/dev/null'
2303     for arg in `eval "$xe_runpath_link" | grep ' -L'`; do
2304       case "$arg" in P,* | -L* | -R* )
2305         for dir in `echo '' "$arg" | sed -e 's:^ ::' -e 's/^..//' -e 'y/:/ /'`; do
2306           XE_ADD_RUNPATH_DIR("$dir")
2307         done ;;
2308       esac
2309     done
2310     ld_switch_run="$ld_switch_run_save"
2311     rm -f conftest*
2312   else
2313     dnl Add all directories with .so files to runpath
2314     for arg in $ld_switch_site $ld_switch_x_site; do
2315       case "$arg" in -L*) XE_ADD_RUNPATH_DIR(`echo '' "$arg" | sed -e 's:^ ::' -e 's/^-L//'`);; esac
2316     done
2317     dnl Sometimes /opt/SUNWdt/lib is the only installed Motif available
2318     dnl #### this test always fails here as need_motif is null
2319     if test "$opsys $need_motif" = "sol2 yes"; then
2320       xe_runpath_dir="/opt/SUNWdt/lib";
2321       eval "$xe_add_unique_runpath_dir";
2322     fi
2323   fi dnl Compute $runpath
2324
2325   if test -n "$runpath"; then
2326     ld_switch_run="${dash_r}${runpath}"
2327     XE_PROTECT_LINKER_FLAGS(ld_switch_run)
2328     test "$extra_verbose" = "yes" && echo "Setting runpath to $runpath"
2329   fi
2330 fi
2331 ])dnl
2332 XE_COMPUTE_RUNPATH()
2333
2334 dnl -----------------------------------
2335 dnl Do some misc autoconf-special tests
2336 dnl -----------------------------------
2337
2338 dnl Do the opsystem or machine files prohibit the use of the GNU malloc?
2339 dnl Assume not, until told otherwise.
2340 GNU_MALLOC=yes
2341 if test "$with_dlmalloc" != "no"; then
2342         doug_lea_malloc=yes
2343 else
2344         doug_lea_malloc=no
2345 fi
2346 after_morecore_hook_exists=yes
2347 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
2348 AC_MSG_CHECKING(whether __after_morecore_hook exists)
2349 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
2350   [AC_MSG_RESULT(yes)],
2351   [AC_MSG_RESULT(no)
2352    after_morecore_hook_exists=no])
2353 if test "$system_malloc" = "yes" ; then
2354   GNU_MALLOC=no
2355   GNU_MALLOC_reason="
2356     - The GNU allocators don't work with this system configuration."
2357 elif test "$with_system_malloc" = "yes" ; then
2358   GNU_MALLOC=no
2359   GNU_MALLOC_reason="
2360     - User chose not to use GNU allocators."
2361 elif test "$with_debug_malloc" = "yes" ; then
2362   GNU_MALLOC=no
2363   GNU_MALLOC_reason="
2364     - User chose to use Debugging Malloc."
2365 fi
2366
2367 if test "$doug_lea_malloc" = "yes" -a "$GNU_MALLOC" = "yes" ; then
2368   GNU_MALLOC_reason="
2369     - Using Doug Lea's new malloc from the GNU C Library."
2370   AC_DEFINE(DOUG_LEA_MALLOC)
2371   if test "$after_morecore_hook_exists" = "no" ; then
2372     GNU_MALLOC_reason="
2373     - Using Doug Lea's new malloc from the Linux C Library."
2374     AC_DEFINE(_NO_MALLOC_WARNING_)
2375   fi
2376 fi
2377
2378 dnl #### mcheck is broken in all versions of Linux libc and glibc.
2379 dnl Try this again when 2.1 hits the streets.
2380 dnl Avoid using free-hook.c if support exists for malloc debugging in libc
2381 dnl have_libmcheck=no
2382 dnl if test "$error_check_malloc" = "yes" -a \
2383 dnl    "$have_glibc" = "yes" -a \
2384 dnl    "$doug_lea_malloc" = "yes"; then
2385 dnl   AC_CHECK_HEADERS(mcheck.h)
2386 dnl   AC_CHECK_LIB(mcheck, mcheck, have_libmcheck=yes, have_libmcheck=no)
2387 dnl fi
2388
2389 dnl if test "$have_libmcheck" = "yes"; then
2390 dnl   AC_DEFINE(HAVE_LIBMCHECK)
2391 dnl   libmcheck=-lmcheck
2392 dnl   AC_SUBST(libmcheck)
2393 dnl fi
2394
2395 dnl Some other nice autoconf tests.  If you add a test here which
2396 dnl should make an entry in src/config.h, do not forget to add an
2397 dnl #undef clause to src/config.h.in for autoconf to modify.
2398
2399 AC_PROG_RANLIB
2400 AC_PROG_INSTALL
2401 AC_PROG_YACC
2402
2403 dnl checks for header files
2404 AC_CHECK_HEADERS(dnl
2405   a.out.h dnl
2406   elf.h dnl
2407   cygwin/version.h dnl
2408   fcntl.h dnl
2409   inttypes.h dnl
2410   libgen.h dnl
2411   locale.h dnl
2412   mach/mach.h dnl
2413   sys/param.h dnl
2414   sys/pstat.h dnl
2415   sys/time.h dnl
2416   sys/timeb.h dnl
2417   sys/un.h dnl
2418   ulimit.h dnl
2419   unistd.h dnl
2420 )
2421 AC_HEADER_SYS_WAIT
2422 AC_HEADER_STDC
2423 AC_HEADER_TIME
2424 AC_DECL_SYS_SIGLIST
2425
2426
2427 dnl ----------------------------------------------------------------
2428 dnl Checking for utime() or utimes().
2429 dnl We prefer utime, since it is more standard.
2430 dnl Some systems have utime.h but do not declare the struct anyplace,
2431 dnl so we use a more sophisticated test for utime than AC_CHECK_FUNCS.
2432 dnl ----------------------------------------------------------------
2433 AC_MSG_CHECKING(for utime)
2434 AC_TRY_COMPILE([#include <sys/types.h>
2435 #include <utime.h>],
2436 [struct utimbuf x; x.actime = x.modtime = 0; utime ("/", &x);],
2437   [AC_MSG_RESULT(yes)
2438    AC_DEFINE(HAVE_UTIME)],
2439   [AC_MSG_RESULT(no)
2440    dnl We don't have utime(); how about utimes()?
2441    AC_CHECK_FUNCS(utimes)])
2442
2443
2444 dnl checks for typedefs
2445 AC_TYPE_SIGNAL
2446 AC_TYPE_SIZE_T
2447 AC_TYPE_PID_T
2448 AC_TYPE_UID_T
2449 AC_TYPE_MODE_T
2450 AC_TYPE_OFF_T
2451 AC_CHECK_TYPE(ssize_t, int)
2452
2453 dnl check for Unix98 socklen_t
2454 AC_MSG_CHECKING(for socklen_t)
2455 AC_TRY_COMPILE([#include <sys/types.h>
2456 #include <sys/socket.h>
2457 socklen_t x;
2458 ],[],[AC_MSG_RESULT(yes)],[
2459 AC_TRY_COMPILE([#include <sys/types.h>
2460 #include <sys/socket.h>
2461 int accept (int, struct sockaddr *, size_t *);
2462 ],[],[
2463 AC_MSG_RESULT(size_t)
2464 AC_DEFINE(socklen_t,size_t)], [
2465 AC_MSG_RESULT(int)
2466 AC_DEFINE(socklen_t,int)])])
2467
2468 AC_MSG_CHECKING(for struct timeval)
2469 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
2470 #include <sys/time.h>
2471 #include <time.h>
2472 #else
2473 #ifdef HAVE_SYS_TIME_H
2474 #include <sys/time.h>
2475 #else
2476 #include <time.h>
2477 #endif
2478 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
2479   [AC_MSG_RESULT(yes)
2480   HAVE_TIMEVAL=yes
2481   AC_DEFINE(HAVE_TIMEVAL)],
2482   [AC_MSG_RESULT(no)
2483    HAVE_TIMEVAL=no])
2484
2485 dnl checks for structure members
2486 AC_STRUCT_TM
2487 AC_STRUCT_TIMEZONE
2488
2489 dnl checks for compiler characteristics
2490 AC_C_CONST
2491
2492 dnl check for Make feature
2493 AC_PROG_MAKE_SET
2494
2495 dnl check byte order
2496 AC_C_BIGENDIAN
2497
2498 dnl define SIZEOF_TYPE
2499 AC_CHECK_SIZEOF(short)
2500 if test "$ac_cv_sizeof_short" = 0; then
2501   echo ""
2502   echo "*** PANIC *** Configure tests are not working - compiler is broken."
2503   echo "*** PANIC *** Please examine config.log for compilation errors."
2504   exit 1
2505 fi
2506 AC_CHECK_SIZEOF(int)
2507 AC_CHECK_SIZEOF(long)
2508 AC_CHECK_SIZEOF(long long)
2509 AC_CHECK_SIZEOF(void *)
2510
2511 dnl Cygwin from 1003022 has intptr_t, uintptr_t in <cygwin/types.h>
2512 case $opsys in
2513   cygwin* ) AC_EGREP_HEADER([typedef.*intptr_t;], [cygwin/types.h],
2514                             [AC_MSG_RESULT(yes)
2515                              AC_DEFINE(INTPTR_T_IN_CYGWIN_TYPES_H,1)],
2516                             [AC_MSG_RESULT(no)]) ;;
2517 esac
2518
2519 dnl check for long file names
2520 AC_SYS_LONG_FILE_NAMES
2521
2522 dnl -lm is required by LISP_FLOAT_TYPE, among other things
2523 AC_CHECK_FUNC(sin, ,AC_CHECK_LIB(m, sin))
2524
2525 dnl Floating operation support is now unconditional
2526 AC_DEFINE(LISP_FLOAT_TYPE)
2527
2528 AC_TRY_LINK([#include <math.h>],
2529   [return atanh(1.0) + asinh(1.0) + acosh(1.0); ],
2530   AC_DEFINE(HAVE_INVERSE_HYPERBOLIC))
2531
2532 dnl Determine type of mail locking from configure args and s&m headers
2533 AC_CHECKING(type of mail spool file locking)
2534 AC_CHECK_FUNCS(lockf flock)
2535 dnl The mail_use_xxx variables are set according to the s&m headers.
2536 test -z "$mail_locking" -a "$mail_use_flock" = "yes" && mail_locking=flock
2537 test -z "$mail_locking" -a "$mail_use_lockf" = "yes" && mail_locking=lockf
2538 test -z "$mail_locking" -a "$mail_use_locking" = "yes" && mail_locking=locking
2539 if   test -z "$mail_locking"; then
2540   case "$opsys" in cygwin* | mingw*)
2541     mail_locking=pop ;;
2542   esac
2543 fi
2544
2545 if   test "$mail_locking" = "lockf"; then AC_DEFINE(MAIL_LOCK_LOCKF)
2546 elif test "$mail_locking" = "flock"; then AC_DEFINE(MAIL_LOCK_FLOCK)
2547 elif test "$mail_locking" = "locking"; then AC_DEFINE(MAIL_LOCK_LOCKING)
2548 elif test "$mail_locking" = "pop"; then
2549   with_pop=yes
2550   mail_locking=
2551 else mail_locking="dot-locking"; AC_DEFINE(MAIL_LOCK_DOT)
2552 fi
2553 test "$mail_locking" = "lockf" -a "$ac_cv_func_lockf" != "yes" && \
2554   XE_DIE("lockf mail locking requested but not available.")
2555 test "$mail_locking" = "flock" -a "$ac_cv_func_flock" != "yes" && \
2556   XE_DIE("flock mail locking requested but not available.")
2557 test "$mail_locking" = "locking" -a "$ac_cv_func_locking" != "yes" && \
2558   XE_DIE("locking mail locking requested but not available.")
2559
2560 case "$opsys" in decosf*)
2561   AC_CHECK_LIB(pthreads, cma_open)
2562   test "$ac_cv_lib_pthreads_cma_open" = "yes" && \
2563     c_switch_site="$c_switch_site -threads" ;;
2564 esac
2565
2566 dnl ----------------------------------------------------------------
2567 dnl Miscellaneous flags
2568 dnl ----------------------------------------------------------------
2569
2570 AC_MSG_CHECKING(whether the -xildoff compiler flag is required)
2571 if   ${CC-cc} '-###' -xildon  no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ; then
2572   if ${CC-cc} '-###' -xildoff no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ;
2573     then AC_MSG_RESULT(no);
2574     else AC_MSG_RESULT(yes); XE_APPEND(-xildoff, ld_switch_site)
2575   fi
2576   else AC_MSG_RESULT(no)
2577 fi
2578
2579 dnl Link with "-z ignore" on Solaris if supported
2580 if test "$opsys" = "sol2"; then
2581   if test "$os_release" -ge 506; then
2582     AC_MSG_CHECKING(for \"-z ignore\" linker flag)
2583     case "`ld -h 2>&1`" in
2584       *-z\ ignore\|record* ) AC_MSG_RESULT(yes)
2585         XE_PREPEND(-z ignore, ld_switch_site) ;;
2586       *) AC_MSG_RESULT(no) ;;
2587     esac
2588   fi
2589 fi
2590
2591 dnl ----------------------
2592 dnl Choose a window system
2593 dnl ----------------------
2594
2595 AC_CHECKING("for specified window system")
2596
2597 dnl Autodetection of Gdk libraries and includes
2598 dnl -------------------------------------------
2599 dnl On some systems (FreeBSD springs to mind), they use
2600 dnl versions on the utility routines, so instead of gtk-config
2601 dnl you must use gtk12-config, etc, etc.
2602
2603 GNOME_CONFIG=no
2604 GTK_CONFIG=no
2605
2606 if test "$with_gnome" != "no"; then
2607    AC_MSG_CHECKING(for GNOME configuration script)
2608    for possible in gnome-config
2609    do
2610       possible_version=`${possible} --version 2> /dev/null`
2611       if test "x${possible_version}" != "x"; then
2612               GNOME_CONFIG="${possible}"
2613               with_gnome=yes
2614               with_gtk=yes
2615               break
2616       fi
2617    done
2618    AC_MSG_RESULT([${GNOME_CONFIG}])
2619 fi
2620
2621 if test "${GNOME_CONFIG}" != "no"; then
2622       GNOME_LIBS=`${GNOME_CONFIG} --libs gnomeui`
2623       GNOME_CFLAGS=`${GNOME_CONFIG} --cflags gnomeui`
2624       AC_DEFINE(HAVE_GNOME)
2625       XE_APPEND(${GNOME_LIBS}, libs_gtk)
2626       XE_APPEND(${GNOME_CFLAGS}, c_switch_gtk)
2627 fi
2628
2629 if test "$with_gtk" != "no";then
2630    AC_MSG_CHECKING(for GTK configuration script)
2631    for possible in gtk12-config gtk14-config gtk-config
2632    do
2633       possible_version=`${possible} --version 2> /dev/null`
2634       if test "x${possible_version}" != "x"; then
2635               GTK_CONFIG="${possible}"
2636               case "${possible_version}" in
2637                 1.0.*) AC_MSG_WARN([GTK 1.2 is required, please upgrade your version of GTK.]); with_gtk=no;;
2638                 1.3.*) AC_MSG_WARN([GTK 1.3 is not supported right now]); with_gtk=no;;
2639                 1.2.*)
2640                         with_gtk=yes
2641                         break
2642                         ;;
2643                 *)     AC_MSG_WARN([Found unsupported version of GTK: $possible_version]);;
2644               esac
2645       fi
2646    done
2647    AC_MSG_RESULT([${GTK_CONFIG}])
2648 fi
2649
2650 if test "${GTK_CONFIG}" != "no"; then
2651       AC_MSG_CHECKING(gtk version)
2652       GTK_VERSION=`${GTK_CONFIG} --version`
2653       AC_MSG_RESULT(${GTK_VERSION})
2654
2655       AC_MSG_CHECKING(gtk libs)
2656       GTK_LIBS=`${GTK_CONFIG} --libs`
2657       XE_APPEND(${GTK_LIBS}, libs_gtk)
2658       AC_MSG_RESULT(${GTK_LIBS})
2659
2660       AC_MSG_CHECKING(gtk cflags)
2661       GTK_CFLAGS=`${GTK_CONFIG} --cflags`
2662       if test "$GCC" = "yes"; then
2663         GTK_CFLAGS="${GTK_CFLAGS} -Wno-shadow"
2664       fi
2665       XE_APPEND(${GTK_CFLAGS}, c_switch_gtk)
2666       AC_MSG_RESULT(${GTK_CFLAGS})
2667
2668       AC_CHECK_LIB(gdk_imlib, main, XE_PREPEND(-lgdk_imlib, libs_gtk))
2669       AC_CHECK_LIB(Imlib, Imlib_init, XE_APPEND(-lImlib, libs_gtk))
2670       AC_CHECK_FUNCS(gdk_imlib_init)
2671
2672       AC_DEFINE(HAVE_XPM)
2673       AC_DEFINE(HAVE_GTK)
2674       AC_SUBST(GTK_CONFIG)
2675
2676       window_system=gtk
2677       with_gtk=yes
2678       with_x11=no
2679
2680       test "${with_scrollbars}" != "no" && with_scrollbars=gtk
2681       test "${with_toolbars}" != no && with_toolbars=gtk
2682       test "${with_menubars}" != "no" && with_menubars=gtk
2683       test "${with_dialogs}" != "no" && with_dialogs=gtk
2684       test "${with_widgets}" != "no" && with_widgets=gtk
2685
2686       XE_ADD_OBJS(console-gtk.o device-gtk.o event-gtk.o frame-gtk.o)
2687       XE_ADD_OBJS(objects-gtk.o redisplay-gtk.o glyphs-gtk.o)
2688       XE_ADD_OBJS(select-gtk.o gccache-gtk.o)
2689       XE_ADD_OBJS(gtk-xemacs.o ui-gtk.o)
2690
2691       dnl Check for libglade support (it rocks)
2692       OLD_CFLAGS="${CFLAGS}"
2693       OLD_CPPFLAGS="${CPPFLAGS}"
2694       OLD_LDFLAGS="${LDFLAGS}"
2695       CFLAGS="${GTK_CFLAGS} ${CFLAGS}"
2696       CPPFLAGS="${GTK_CFLAGS} ${CFLAGS}"
2697       LDFLAGS="${LDFLAGS} ${GTK_LIBS}"
2698       AC_CHECK_HEADERS(glade/glade.h glade.h)
2699       AC_CHECK_LIB(xml, main, XE_PREPEND(-lxml, libs_gtk))
2700       AC_CHECK_LIB(glade, main, XE_PREPEND(-lglade, libs_gtk))
2701       AC_CHECK_LIB(glade-gnome, main, XE_PREPEND(-lglade-gnome, libs_gtk))
2702       AC_EGREP_HEADER([char \*txtdomain;], [glade/glade-xml.h],
2703                       [AC_MSG_RESULT(yes)
2704                        AC_DEFINE(LIBGLADE_XML_TXTDOMAIN,1)],
2705                       [AC_MSG_RESULT(no)])
2706       CFLAGS="${OLD_CFLAGS}"
2707       CPPFLAGS="${OLD_CPPFLAGS}"
2708       LDFLAGS="${OLD_LDFLAGS}"
2709 fi
2710
2711 dnl We may eventually prefer gtk/gdk over vanilla X11...
2712
2713 if test "$with_x11" != "no"; then
2714   dnl User-specified --x-includes or --x-libraries implies --with-x11.
2715   test "$x_includes $x_libraries" != "NONE NONE" && \
2716    window_system=x11 with_x11=yes
2717
2718   dnl Autodetection of X11 libraries and includes
2719   dnl -------------------------------------------
2720   dnl AC_PATH_XTRA thinks it can find our X headers and includes, but
2721   dnl it often gets it wrong, so we only use it as a last resort.
2722
2723   dnl $OPENWINHOME implies --x-includes and --x-libraries
2724   dnl Not (yet) handled by autoconf2
2725   if test "$x_includes $x_libraries" = "NONE NONE" \
2726     -a -n "$OPENWINHOME" \
2727     -a "$OPENWINHOME" != "/usr/openwin" \
2728     -a -d "$OPENWINHOME"; then
2729       test -d "$OPENWINHOME/lib"           && x_libraries="$OPENWINHOME/lib"
2730       test -d "$OPENWINHOME/include"       && x_includes="$OPENWINHOME/include"
2731       test -d "$OPENWINHOME/share/include" && x_includes="$OPENWINHOME/share/include"
2732   fi
2733
2734   if test "$x_includes" = "NONE"; then
2735     dnl AC_PATH_XTRA often guesses /usr/include, when some other
2736     dnl include directory is a MUCH better guess (Linux, HP-UX 10.20).
2737     dnl This is a workaround for idiot (esp. HP) system vendors, who
2738     dnl provide a /usr/include/X11, but DON'T FULLY POPULATE IT.
2739     for dir in "/usr/X11" "/usr/X11R6"; do
2740       if test -d "$dir/include/X11"; then x_includes="$dir/include"; break; fi
2741     done
2742   fi
2743
2744   if test "$x_libraries" = "NONE"; then
2745     for dir in "/usr/X11/lib" "/usr/X11R6/lib" "/usr/lib/X11R6"; do
2746       if test -r "$dir/libX11.a"; then x_libraries="$dir"; break; fi
2747     done
2748   fi
2749
2750   AC_PATH_XTRA # Autoconf claims to find X library and include dirs for us.
2751   if test "$no_x" = "yes"
2752   then with_x11=no  window_system=none HAVE_X_WINDOWS=no
2753   else with_x11=yes window_system=x11  HAVE_X_WINDOWS=yes
2754   fi
2755 fi
2756
2757 dnl #### wmperry:: !x11 != NONE
2758 dnl case "$with_x11" in
2759 dnl  yes ) window_system=x11  HAVE_X_WINDOWS=yes ;;
2760 dnl  no  ) window_system=none HAVE_X_WINDOWS=no  ;;
2761 dnl esac
2762
2763 if test "$with_x11" = "yes"; then
2764   AC_DEFINE(HAVE_X_WINDOWS)
2765   XE_APPEND(lwlib, MAKE_SUBDIR)
2766   XE_APPEND(lwlib, SRC_SUBDIR_DEPS)
2767
2768
2769   dnl Look for Motif, but only if not found in $x_includes and $x_libraries
2770   AC_CHECK_HEADER(Xm/Xm.h, [AC_CHECK_LIB(Xm, XmStringFree, got_motif=yes)])
2771
2772   if test "$got_motif" != "yes"; then
2773     dnl Try to find Motif/CDE/Tooltalk dirs
2774     dnl These take precedence over other X libs/includes, so PRE-pend
2775     for lib_dir in "/usr/dt/lib" "/usr/lib/Motif2.1" \
2776                    "/usr/lib/Motif1.2" "/usr/lib/Motif1.1"; do
2777       inc_dir=`echo $lib_dir | sed -e 's/lib/include/'`
2778       if test -d "$lib_dir" -a -d "$inc_dir"; then
2779         case "$x_libraries" in *"$lib_dir"* ) ;; *)
2780           x_libraries="$lib_dir $x_libraries"
2781           XE_PREPEND(-L${lib_dir}, X_LIBS) ;;
2782         esac
2783         case "$x_includes" in "$inc_dir"* ) ;; *)
2784           x_includes="$inc_dir $x_includes"
2785           XE_PREPEND(-I${inc_dir}, X_CFLAGS) ;;
2786         esac
2787         break; dnl only need ONE Motif implementation!
2788         fi
2789     done
2790   fi
2791
2792   dnl Contrib X libs/includes do NOT take precedence, so AP-pend
2793   for rel in "X11R6" "X11R5" "X11R4"; do
2794     lib_dir="/usr/contrib/$rel/lib" inc_dir="/usr/contrib/$rel/include"
2795     if test -d "$lib_dir" -a -d "$inc_dir"; then
2796       case "$x_libraries" in *"$lib_dir"* ) ;; *)
2797         x_libraries="$x_libraries $lib_dir"
2798         XE_APPEND(-L${lib_dir}, X_LIBS)
2799       esac
2800       case "$x_includes" in "$inc_dir"* ) ;; *)
2801         x_includes="$x_includes $inc_dir"
2802         XE_APPEND(-I${inc_dir}, X_CFLAGS)
2803       esac
2804       break; dnl Only need ONE X11 implementation !
2805     fi
2806   done
2807
2808   dnl Avoid version mismatch for shared library libXm.so on osf4
2809   case "$opsys" in
2810   decosf*) if test "$GCC" = yes -a -d /usr/shlib; then XE_APPEND(-L/usr/shlib, X_LIBS); fi ;;
2811   esac
2812
2813   ld_switch_x_site="$X_LIBS"
2814
2815   XE_COMPUTE_RUNPATH()
2816
2817   if test "$extra_verbose" = "yes"; then
2818     echo; echo "X11 compilation variables:"
2819     PRINT_VAR(x_libraries x_includes X_CFLAGS X_LIBS X_PRE_LIBS X_EXTRA_LIBS)
2820     echo
2821   fi
2822
2823   dnl Set up bitmaps search path.
2824   dnl The original suggestion was to unconditionally to append X11/bitmaps
2825   dnl to each element of $x_includes, I'm pretty sure this is the wrong
2826   dnl thing to do.  We test for bitmaps and X11/bitmaps directories on each
2827   dnl element and add them to BITMAPDIR if they exist.
2828   bitmapdirs=
2829   if test "$x_includes" != NONE; then
2830     for i in $x_includes; do
2831       if test -d "$i/bitmaps"; then
2832         bitmapdirs="$i/bitmaps:$bitmapdirs"
2833       fi
2834       if test -d "$i/X11/bitmaps"; then
2835         bitmapdirs="$i/X11/bitmaps:$bitmapdirs"
2836       fi
2837     done
2838     bitmapdirs=`echo "$bitmapdirs" | sed s/.$//`
2839   fi
2840   test ! -z "$bitmapdirs" && AC_DEFINE_UNQUOTED(BITMAPDIR, "$bitmapdirs")
2841
2842   dnl Autodetect defines extracted from X config by xmkmf, e.g. NARROWPROTO
2843   AC_CHECKING(for X defines extracted by xmkmf)
2844   rm -fr conftestdir
2845   if mkdir conftestdir; then
2846     cd conftestdir
2847     cat > Imakefile <<'EOF'
2848 xetest:
2849         @echo ${PROTO_DEFINES} ${STD_DEFINES}
2850 EOF
2851     if (xmkmf) >/dev/null 2>/dev/null && test -f Makefile; then
2852       # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
2853       xmkmf_defines=`${MAKE-make} xetest 2>/dev/null | grep -v make`
2854     fi
2855     cd ..
2856     rm -fr conftestdir
2857     for word in $xmkmf_defines; do
2858       case "$word" in 
2859       -D__STDC__*) ;;
2860       -D* )
2861         sym=`echo '' $word | sed -e 's:^ *-D::' -e 's:=.*::'`
2862         case "$word" in
2863           -D*=* ) val=`echo '' $word | sed -e 's:^.*=::'` ;;
2864           *     ) val=1 ;;
2865         esac
2866 dnl Avoid re-AC_DEFINE-ing xmkmf symbols we've already defined above.
2867         if grep "^#define $sym " confdefs.h >/dev/null; then :; else
2868           if test "$val" = "1"
2869             then AC_DEFINE_UNQUOTED($sym)
2870             else AC_DEFINE_UNQUOTED($sym,$val)
2871           fi
2872         fi  ;;
2873       esac
2874     done
2875   fi
2876
2877   dnl make sure we can find Intrinsic.h
2878   AC_CHECK_HEADER(X11/Intrinsic.h, ,
2879    [AC_MSG_ERROR("Unable to find X11 header files.")])
2880
2881   dnl -lXt and -lX11 are required
2882   dnl Some broken systems require the magic "-b i486-linuxaout" flag
2883   AC_CHECK_LIB(X11, XOpenDisplay, have_lib_x11=yes)
2884   if test "$have_lib_x11" != "yes"; then
2885     AC_CHECK_LIB(X11, XGetFontProperty,
2886       ld_switch_x_site="-b i486-linuxaout $ld_switch_x_site",
2887       [AC_MSG_ERROR("Unable to find X11 libraries.")],
2888       -b i486-linuxaout)
2889   fi
2890   libs_x="-lX11"
2891   test "$extra_verbose" = "yes" && echo "    Setting libs_x to \"-lX11\""
2892
2893   dnl Autodetect -lXext
2894   AC_CHECK_LIB(Xext, XShapeSelectInput, XE_PREPEND(-lXext, libs_x))
2895
2896   dnl Require -lXt
2897   AC_CHECK_LIB(Xt, XtOpenDisplay, XE_PREPEND(-lXt, libs_x),
2898     AC_MSG_ERROR("Unable to find X11 libraries."))
2899
2900   AC_MSG_CHECKING(the version of X11 being used)
2901   AC_TRY_RUN([#include <X11/Intrinsic.h>
2902     int main(int c, char *v[]) { return c>1 ? XlibSpecificationRelease : 0; }],
2903     [./conftest foobar; x11_release=$?],[x11_release=4],[x11_release=4])
2904   AC_MSG_RESULT(R${x11_release})
2905   AC_DEFINE_UNQUOTED(THIS_IS_X11R${x11_release})
2906
2907   if test "${x11_release}" = "4"; then
2908     case "$with_widgets" in
2909       "" | "no") with_widgets=no ;;
2910       *) XE_DIE("Widget support requires X11R5 or greater") ;;
2911     esac
2912   fi
2913
2914   AC_CHECK_FUNCS(XConvertCase XtRegisterDrawable)
2915
2916   AC_CHECK_HEADERS(X11/Xlocale.h)
2917
2918   dnl XFree86 has a non-standard prototype for this X11R6 function
2919   AC_CHECK_FUNCS(XRegisterIMInstantiateCallback)
2920   AC_MSG_CHECKING(for standard XRegisterIMInstantiateCallback prototype)
2921   AC_TRY_COMPILE([
2922 #define NeedFunctionPrototypes 1
2923 #include <X11/Xlib.h>
2924 extern Bool XRegisterIMInstantiateCallback(
2925    Display*, struct _XrmHashBucketRec*, char*, char*, XIMProc, XPointer*);
2926 ], [], 
2927   [AC_MSG_RESULT(yes)],
2928   [AC_MSG_RESULT(no)
2929    AC_DEFINE(XREGISTERIMINSTANTIATECALLBACK_NONSTANDARD_PROTOTYPE)])
2930
2931   dnl autodetect -lXmu
2932   test -z "$with_xmu" && { AC_CHECK_LIB(Xmu, XmuReadBitmapDataFromFile,
2933                            with_xmu=yes, with_xmu=no) }
2934   if test "$with_xmu" = "no"; then
2935     XE_ADD_OBJS(xmu.o)
2936   else
2937     XE_PREPEND(-lXmu, libs_x)
2938     AC_DEFINE(HAVE_XMU)
2939   fi
2940
2941   dnl Autodetect -lXbsd
2942   dnl #### Someone, please add a better function than main
2943   AC_CHECK_LIB(Xbsd, main, XE_PREPEND(-lXbsd, libs_x))
2944
2945   dnl Problem with the MIT distribution of X on AIX
2946   if test "$unexec" = "unexaix.o" -a "$x11_release" = "6"; then
2947     dnl X11R6 requires thread-safe code on AIX for some reason
2948     if test "$GCC" = "yes"; then
2949       dnl gcc changed the name of the `-mthreads' option to `-pthread'
2950       dnl on 2000-06-12
2951       AC_MSG_CHECKING(for name of AIX gcc threads option)
2952       case `$CC -v --help 2>&1` in
2953         *-mthreads*) aix_threads=-mthreads ;;
2954                   *) aix_threads=-pthread  ;;
2955       esac
2956       AC_MSG_RESULT($aix_threads)
2957       XE_PREPEND($aix_threads, X_CFLAGS)
2958       XE_PREPEND($aix_threads, libs_x)
2959     else
2960       dnl Try to use the thread-safe "_r" versions of xlc
2961       case "$CC" in *_r) : ;;
2962         *)
2963          xe_save_CC="$CC"
2964          CC="${CC}_r"
2965          AC_CHECK_SIZEOF(short)
2966          test "$ac_cv_sizeof_short" = 0 && CC="$xe_save_CC" ;;
2967       esac
2968     fi
2969   fi
2970
2971 fi dnl $with_x11 = yes
2972
2973 if test "$with_msw" != "no"; then
2974   AC_CHECKING(for MS-Windows)
2975   AC_CHECK_LIB(gdi32,main,with_msw=yes)
2976   if test "$with_msw" = "yes"; then
2977     AC_DEFINE(HAVE_MS_WINDOWS)
2978
2979     dnl The net installer only works with MS-Windows currently
2980     if test "$with_netinstall" = "yes"; then
2981       XE_APPEND(netinstall, MAKE_SUBDIR)
2982       XE_APPEND(netinstall, SRC_SUBDIR_DEPS)
2983       XE_APPEND(netinstall, INSTALL_ARCH_DEP_SUBDIR)
2984     fi
2985
2986     install_pp="$srcdir/lib-src/installexe.sh"
2987     XE_APPEND(-lshell32 -lgdi32 -luser32 -lcomdlg32 -lcomctl32 -lkernel32 -lwinspool, libs_system)
2988     test "$with_dragndrop" != no && XE_APPEND(msw, dragndrop_proto)
2989     if test "$window_system" != x11; then
2990         window_system=msw
2991         test "$with_scrollbars" != "no" && with_scrollbars=msw \
2992             && XE_ADD_OBJS(scrollbar-msw.o)
2993         test "$with_menubars"   != "no" && with_menubars=msw \
2994             && XE_ADD_OBJS(menubar-msw.o)
2995         test "$with_toolbars"   != "no" && with_toolbars=msw \
2996             && XE_ADD_OBJS(toolbar-msw.o)
2997         test "$with_dialogs"   != "no" && with_dialogs=msw \
2998             && XE_ADD_OBJS(dialog-msw.o)
2999         test "$with_widgets"   != "no" && with_widgets=msw
3000     else
3001         test "$with_scrollbars" != "no" && XE_ADD_OBJS(scrollbar-msw.o)
3002         test "$with_menubars"   != "no" && XE_ADD_OBJS(menubar-msw.o)
3003         test "$with_toolbars"   != "no" && XE_ADD_OBJS(toolbar-msw.o)
3004         test "$with_dialogs"    != "no" && XE_ADD_OBJS(dialog-msw.o)
3005     fi
3006     dnl check for our special version of select
3007     AC_TRY_RUN([#include <fcntl.h>
3008     int main() { return (open("/dev/windows", O_RDONLY, 0) > 0)? 0 : 1; }],
3009     [need_event_unixoid=yes; AC_DEFINE(HAVE_MSG_SELECT)])
3010     with_file_coding=yes
3011     XE_ADD_OBJS(console-msw.o device-msw.o event-msw.o frame-msw.o objects-msw.o select-msw.o redisplay-msw.o glyphs-msw.o gui-msw.o)
3012   fi
3013 fi
3014
3015 AC_SUBST(install_pp)
3016
3017 test -z "$window_system" && window_system="none"
3018
3019 dnl Test for features that require a window system - ANY window system
3020 if test "$window_system" = "none"; then
3021   for feature in menubars scrollbars toolbars dialogs dragndrop xface
3022   do
3023     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
3024        AC_MSG_WARN([--with-$feature ignored:  Not valid without window system support])
3025     fi
3026     eval "with_${feature}=no"
3027   done
3028 else
3029   test -z "$with_toolbars" && with_toolbars=yes
3030 fi
3031
3032 dnl ### Test for features that require mswindows support - currently none
3033 dnl ### MS-Windows folks: add code here..... (martin)
3034 if test "$with_msw" != "yes"; then
3035   for feature in   MARTIN_IS_CLUELESS_ABOUT_MSW_FEATURES
3036   do
3037     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
3038        AC_MSG_WARN([--with-$feature ignored:  Not valid without MS-Windows support])
3039     fi
3040     eval "with_${feature}=no"
3041   done
3042 else
3043   :
3044 fi
3045
3046 dnl Test for features that require X11 support
3047 if test "$with_x11" != "yes"; then
3048   dnl It ought to be reasonable to have no output device at all, and only use
3049   dnl XEmacs in --batch mode.
3050   dnl if test "$with_tty" = "no" ; then
3051   dnl   AC_MSG_ERROR([No window system support and no TTY support - Unable to proceed.])
3052   dnl fi
3053   for feature in tooltalk cde offix wmcommand xim xmu nas_sound
3054   do
3055     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
3056        AC_MSG_WARN([--with-$feature ignored:  Not valid without X support])
3057     fi
3058     eval "with_${feature}=no"
3059   done
3060 fi
3061
3062 dnl Balloon Help requires the Shape extension, not available everywhere,
3063 dnl for example not on AIX 4.3.
3064 if test "$with_x11" = "yes"; then
3065   AC_CHECK_HEADER(X11/extensions/shape.h, [
3066    AC_DEFINE(HAVE_BALLOON_HELP)
3067    XE_ADD_OBJS(balloon_help.o balloon-x.o)])
3068 fi
3069
3070 dnl FSF 19.29 has some bitmapdir stuff here.
3071 bitmapdir=
3072
3073 case "$window_system" in
3074   x11  ) HAVE_X_WINDOWS=yes; echo "  Using X11." ;;
3075   msw  ) HAVE_X_WINDOWS=no ; echo "  Using MS-Windows." ;;
3076   gtk  )
3077        HAVE_X_WINDOWS=no
3078        test "$with_gnome" = "yes" && echo "  Using GNOME."
3079        test "$with_gnome" = "no" && echo "  Using GTK."
3080        ;;
3081   none ) HAVE_X_WINDOWS=no ; echo "  Using no window system." ;;
3082 esac
3083
3084 case "$x_libraries" in *X11R4* )
3085   test "$opsys" = "hpux9"     && opsysfile="s/hpux9-x11r4.h"
3086   test "$opsys" = "hpux9-shr" && opsysfile="s/hpux9shxr4.h"
3087 esac
3088
3089 dnl Enable or disable proper handling of WM_COMMAND
3090 AC_CHECKING(for WM_COMMAND option);
3091 dnl if test "$with_wmcommand" = "yes"; then
3092 if test "$with_wmcommand" != "no"; then
3093   AC_DEFINE(HAVE_WMCOMMAND)
3094 fi
3095
3096 dnl Autodetect Xauth
3097 dnl -lXau is only used by gnuclient, so use a special variable for Xauth X libs
3098 test -z "$with_xauth" && test "$window_system" = "none" && with_xauth=no
3099 test -z "$with_xauth" && { AC_CHECK_HEADER(X11/Xauth.h,          ,with_xauth=no) }
3100 test -z "$with_xauth" && { AC_CHECK_LIB(Xau, XauGetAuthByAddr,[:],with_xauth=no) }
3101 test -z "$with_xauth" && with_xauth=yes
3102 if test "$with_xauth" = "yes"; then
3103   AC_DEFINE(HAVE_XAUTH)
3104   XE_SPACE(libs_xauth, $GTK_LIBS $X_EXTRA_LIBS -lXau $libs_x $X_PRE_LIBS)
3105 fi
3106 AC_SUBST(libs_xauth)
3107
3108 dnl This one is for the static initializeds variables in
3109 dnl offix.c, so that the thing is dumped after lastfile.o
3110 AC_SUBST(dnd_objs)
3111
3112 dnl Autodetect tooltalk
3113 if test "$with_tooltalk" != "no" ; then
3114   dnl autodetect the location of tt_c.h
3115   dnl tt_c.h might be in Tt or desktop include directories
3116   for dir in "" "Tt/" "desktop/" ; do
3117     AC_CHECK_HEADER(${dir}tt_c.h, tt_c_h_file="${dir}tt_c.h"; break)
3118   done
3119   if test -z "$tt_c_h_file"; then
3120     if test "$with_tooltalk" = "yes"; then
3121       USAGE_ERROR("Unable to find required tooltalk header files.")
3122     fi
3123     with_tooltalk=no
3124   fi
3125 fi
3126 if test "$with_tooltalk" != "no" ; then
3127   for extra_libs in "" "-lI18N -lce" "-lcxx"; do
3128     AC_CHECK_LIB(tt, tt_message_create,
3129       tt_libs="-ltt $extra_libs"; break, [:],$extra_libs)
3130   done
3131   if test -z "$tt_libs"; then
3132     if test "$with_tooltalk" = "yes"; then
3133       USAGE_ERROR("Unable to find required tooltalk libraries.")
3134     fi
3135     with_tooltalk=no
3136   fi
3137 fi
3138 test -z "$with_tooltalk" && with_tooltalk=yes
3139 if test "$with_tooltalk" = "yes"; then
3140   AC_DEFINE(TOOLTALK)
3141   AC_DEFINE_UNQUOTED(TT_C_H_FILE, "$tt_c_h_file")
3142   XE_PREPEND($tt_libs, libs_x)
3143   XE_ADD_OBJS(tooltalk.o)
3144 fi
3145
3146 dnl Autodetect CDE
3147 test -z "$with_cde" && { AC_CHECK_HEADER(Dt/Dt.h,               , with_cde=no) }
3148 test -z "$with_cde" && { AC_CHECK_LIB(DtSvc, DtDndDragStart, [:], with_cde=no) }
3149 test -z "$with_cde" && with_cde=yes
3150 if test "$with_dragndrop" = no; then
3151   AC_MSG_WARN([No CDE without generic Drag'n'Drop support])
3152   with_cde=no
3153 fi
3154 if test "$with_cde" = "yes" ; then
3155   AC_DEFINE(HAVE_CDE)
3156   XE_PREPEND(-lDtSvc, libs_x)
3157   XE_APPEND(CDE, dragndrop_proto)
3158   with_tooltalk=yes # CDE requires Tooltalk
3159   need_motif=yes    # CDE requires Motif
3160 fi
3161
3162 dnl Always compile OffiX unless --without-offix is given, no
3163 dnl X11 support is compiled in, no standard Xmu is available,
3164 dnl or dragndrop support is disabled
3165 dnl Because OffiX support currently loses when more than one display
3166 dnl is in use, we now disable it by default -slb 07/10/1998.
3167 test "$window_system" != "x11" && with_offix=no
3168 if test "$with_xmu" != yes -a "$with_x11" = yes; then
3169   AC_MSG_WARN([No OffiX without real Xmu support])
3170   with_offix=no
3171 fi
3172 if test "$with_dragndrop" = no; then
3173   AC_MSG_WARN([No OffiX without generic Drag'n'Drop support])
3174   with_offix=no
3175 fi
3176 if test "$with_cde" = yes; then
3177   AC_MSG_WARN([CDE already found, disabling OffiX support])
3178   with_offix=no
3179 fi
3180 test -z "$with_offix" && with_offix=no
3181 if test "$with_offix" = "yes"; then
3182   AC_DEFINE(HAVE_OFFIX_DND)
3183   XE_APPEND(offix.o, dnd_objs)
3184   XE_APPEND(OffiX, dragndrop_proto)
3185 fi
3186 if test "$with_gtk" = "yes"; then
3187    XE_APPEND(GTK, dragndrop_proto)
3188 fi
3189
3190 dnl Autodetect Drag'n'Drop support
3191 dnl always included if CDE, Offix, or MSWindows are defined
3192 if test "$with_dragndrop" != "no" ; then
3193   AC_MSG_CHECKING(if drag and drop API is needed)
3194   if test -n "$dragndrop_proto" ; then
3195     with_dragndrop=yes
3196     AC_MSG_RESULT([yes (${dragndrop_proto} )])
3197     AC_DEFINE(HAVE_DRAGNDROP)
3198     XE_APPEND(dragdrop.o, extra_objs)
3199   else
3200     with_dragndrop=no
3201     AC_MSG_RESULT(no)
3202   fi
3203 fi
3204
3205 dnl Autodetect LDAP
3206 AC_CHECKING(for LDAP)
3207 test -z "$with_ldap" && { AC_CHECK_HEADER(ldap.h, ,with_ldap=no) }
3208 test -z "$with_ldap" && { AC_CHECK_HEADER(lber.h, ,with_ldap=no) }
3209 if test no != "$with_ldap";then
3210   if test . != "${ldap_libs+.}";then
3211     ldap_libs=
3212     AC_CHECK_FUNC(ldap_open,dnl Allow it to be in generic "$LIBS"
3213       [with_ldap=yes
3214       test yes = "$extra_verbose" &&
3215         echo "Setting ldap_libs to $ldap_libs"],dnl
3216       [AC_CHECK_LIB(ldap, ldap_open,dnl
3217         [with_ldap=yes],dnl
3218         [ldap_needs_lber=yes ldap_other_libs=-llber
3219 dnl This requires `AC_CACHE_VAL' (which is called by `AC_CHECK_LIB')
3220 dnl to be redefined to ignore cached (shell variable) value, as it is
3221 dnl done above, because the same variable is used in all
3222 dnl `AC_CHECK_LIB' expansions in macro invocation below.  Worse, if it
3223 dnl is not done, there is no portable way to compensate for this
3224 dnl locally since `unset' command is not supported by all shells.  The
3225 dnl other solution would be changing `AC_CHECK_LIB' so that cache
3226 dnl variable name depends on the macro OTHER-LIBRARIES argument.
3227         AC_CHECK_LIB(ldap, ldap_open,dnl
3228           [with_ldap=yes],dnl
3229           [ldap_needs_krb=yes ldap_other_libs="$ldap_other_libs -lkrb"
3230           AC_CHECK_LIB(ldap, ldap_open,dnl
3231             [with_ldap=yes],dnl
3232             [ldap_needs_des=yes ldap_other_libs="$ldap_other_libs -ldes"
3233             AC_CHECK_LIB(ldap, ldap_open,dnl
3234               [with_ldap=yes],dnl
3235               [with_ldap=no],dnl
3236               $ldap_other_libs)],dnl
3237             $ldap_other_libs)],dnl
3238           $ldap_other_libs)])
3239       if test yes = "$with_ldap";then
3240         if test yes = "$ldap_needs_des";then
3241           XE_PREPEND(-ldes, ldap_libs)
3242         fi
3243         if test yes = "$ldap_needs_krb";then
3244           XE_PREPEND(-lkrb, ldap_libs)
3245         fi
3246         if test yes = "$ldap_needs_lber";then
3247           XE_PREPEND(-llber, ldap_libs)
3248         fi
3249         XE_PREPEND(-lldap, ldap_libs)
3250       fi])
3251   else
3252 dnl Allow builder to override "$ldap_libs".
3253     save_LIBS="$LIBS" LIBS="$ldap_libs $LIBS"
3254     AC_CHECK_FUNC(ldap_open,dnl
3255       [with_ldap=yes
3256       test yes = "$extra_verbose" &&
3257         echo "Setting ldap_libs to $ldap_libs"],dnl
3258       [with_ldap=no])
3259     LIBS="$save_LIBS"
3260   fi
3261 fi
3262 if test "$with_ldap" = "yes"; then
3263   AC_DEFINE(HAVE_LDAP)
3264   XE_ADD_OBJS(eldap.o)
3265   LIBS="$ldap_libs $LIBS"
3266   AC_CHECK_FUNCS(ldap_set_option ldap_get_lderrno ldap_result2error ldap_parse_result)
3267 fi
3268
3269 dnl Autodetect PostgreSQL
3270 dnl On many Linux systems, PostgreSQL is packaged to be installed in /usr;
3271 dnl in this case, configure will easily detect it there.
3272 dnl
3273 dnl If PostgreSQL is installed into a different prefix,
3274 dnl (such as the default /usr/local/pgsql when building from source),
3275 dnl that prefix must be specified using the --site-prefixes flag.
3276 if test "$with_postgresql" != "no"; then
3277   AC_CHECKING(for PostgreSQL)
3278
3279 dnl Look for these standard header file locations, known to be used on Linux
3280   for header_dir in "" "pgsql/" "postgresql/"; do
3281     AC_CHECK_HEADER(${header_dir}libpq-fe.h,
3282                     libpq_fe_h_file=${header_dir}libpq-fe.h; break)
3283   done
3284
3285   test -n "$libpq_fe_h_file" && { AC_CHECK_LIB(pq,PQconnectdb,have_libpq=yes) }
3286
3287   if test -n "$libpq_fe_h_file" -a "$have_libpq" = "yes"; then
3288     with_postgresql=yes
3289     AC_DEFINE(HAVE_POSTGRESQL)
3290     AC_CHECK_LIB(pq,PQconnectStart, [
3291                  with_postgresqlv7=yes;
3292                  AC_DEFINE(HAVE_POSTGRESQLV7)])
3293     AC_DEFINE_UNQUOTED(LIBPQ_FE_H_FILE, "$libpq_fe_h_file")
3294     XE_PREPEND(-lpq, LIBS)
3295     XE_ADD_OBJS(postgresql.o)
3296   elif test "$with_postgresql" = "yes"; then
3297     XE_DIE("Required PostgreSQL support cannot be provided.  Check --site-prefixes.")
3298   fi
3299 fi
3300
3301 dnl ----------------------
3302 dnl Graphics libraries
3303 dnl ----------------------
3304
3305 if test "$window_system" != "none"; then
3306   AC_CHECKING(for graphics libraries)
3307
3308   dnl add special code to handle xpm-nox on Cygwin (csw)
3309   dnl   -- should only happen if CYGWIN && WITH_XPM && WITH_MSW && !WITH_X
3310   libpath_xpm=
3311   incpath_xpm=
3312   case "$opsys" in 
3313     cygwin*)
3314       cygwin_top=`eval "gcc -print-file-name=libc.a"` ;
3315       cygwin_top=`eval "dirname ${cygwin_top}"`;
3316       cygwin_top="${cygwin_top}/..";
3317       case "$window_system" in
3318         dnl use "standard" search pattern
3319         x11)  ;;
3320         dnl hardcode "standard" non-X11 xpm lib/inc dirs
3321         msw) libpath_xpm="-L${cygwin_top}/lib/noX"
3322              incpath_xpm="-I${cygwin_top}/include/noX"
3323               ;;
3324         dnl not supported on cygwin (yet?)
3325         gtk)  ;;
3326         dnl probably not reached...
3327         none) ;;
3328         dnl ditto
3329         *)    ;;
3330       esac
3331       ;;
3332     dnl use "standard" search pattern for all other OS's
3333     *) ;;
3334   esac
3335   dnl Autodetect Xpm
3336   xpm_problem=""
3337   if test -z "$with_xpm"; then
3338     XE_PREPEND("$incpath_xpm", CFLAGS)
3339     XE_PREPEND("$libpath_xpm", LDFLAGS)
3340     AC_MSG_CHECKING(for Xpm - no older than 3.4f)
3341     xe_check_libs=-lXpm
3342     AC_TRY_RUN([#define XPM_NUMBERS
3343 #include <X11/xpm.h>
3344     int main(int c, char **v) {
3345     return c == 1 ? 0 :
3346       XpmIncludeVersion != XpmLibraryVersion() ? 1 :
3347       XpmIncludeVersion < 30406 ? 2 : 0 ;}],
3348     [./conftest dummy_arg; xpm_status=$?;
3349       if test "$xpm_status" = "0"; then
3350         with_xpm=yes;
3351       else
3352         with_xpm=no;
3353         if test "$xpm_status" = "1"; then
3354           xpm_problem="Xpm library version and header file version don't match!"
3355         elif test "$xpm_status" = "2"; then
3356           xpm_problem="Xpm library version is too old!"
3357         else
3358           xpm_problem="Internal xpm detection logic error!"
3359         fi
3360         echo "
3361 *** WARNING *** $xpm_problem
3362   I'm not touching that with a 10-foot pole!
3363   If you really want to use the installed version of Xpm, rerun
3364   configure and add '--with-xpm=yes', but don't blame me if XEmacs crashes!"
3365     fi],
3366     [with_xpm=no])
3367     xe_check_libs=
3368     AC_MSG_RESULT($with_xpm)
3369   fi
3370   if test "$with_xpm" = "yes"; then
3371     dnl #### This code assumes that if AC_CHECK_LIB fails,
3372     dnl #### then it will succeed if FOR_MSW is defined,
3373     dnl #### but doesn't actually verify this assumption.
3374     AC_DEFINE(HAVE_XPM)
3375     XE_PREPEND("$libpath_xpm", LDFLAGS)
3376     XE_PREPEND(-lXpm, libs_x)
3377     XE_PREPEND("$incpath_xpm", CFLAGS)
3378     AC_MSG_CHECKING(for \"FOR_MSW\" xpm)
3379     xe_check_libs=-lXpm
3380     AC_TRY_LINK(, [XpmCreatePixmapFromData()],
3381     [xpm_for_msw=no],
3382     [xpm_for_msw=yes])
3383     xe_check_libs=
3384     AC_MSG_RESULT($xpm_for_msw)
3385     if test "$xpm_for_msw" = "yes"; then
3386       AC_DEFINE(FOR_MSW)
3387     fi
3388   fi
3389
3390   dnl Autodetect XFACE
3391   test -z "$with_xface" && { AC_CHECK_HEADER(compface.h,          ,with_xface=no) }
3392   test -z "$with_xface" && { AC_CHECK_LIB(compface, UnGenFace,[:] ,with_xface=no) }
3393   test -z "$with_xface" && with_xface=yes
3394   if test "$with_xface" = "yes"; then
3395     AC_DEFINE(HAVE_XFACE)
3396     XE_PREPEND(-lcompface, libs_x)
3397   fi
3398
3399   dnl For a brief period we had the GIF code split out into a separate library,
3400   dnl but patent problems, etc. sort of squashed that idea.
3401   dnl We default to building with builtin GIF decoding
3402   if test "$with_gif" != "no"; then
3403     with_gif="yes"
3404     AC_DEFINE(HAVE_GIF)
3405     XE_ADD_OBJS(dgif_lib.o gif_io.o)
3406   fi
3407
3408   dnl Too many stupid linkers can't detect cascaded lib dependencies until runtime
3409   dnl So we always search for libz compression support.
3410   if test "$with_png $with_tiff" != "no no"; then
3411     AC_CHECK_LIB(c,  inflate, [:], [
3412     AC_CHECK_LIB(z,  inflate, [XE_PREPEND(-lz,  libs_x)],[
3413     AC_CHECK_LIB(gz, inflate, [XE_PREPEND(-lgz, libs_x)])])])
3414   fi
3415
3416   dnl autodetect JPEG
3417   test -z "$with_jpeg" && { AC_CHECK_HEADER(jpeglib.h,                    ,with_jpeg=no) }
3418   test -z "$with_jpeg" && { AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,[:],with_jpeg=no) }
3419   test -z "$with_jpeg" && with_jpeg=yes
3420   if test "$with_jpeg" = "yes"; then
3421     AC_DEFINE(HAVE_JPEG)
3422     XE_PREPEND(-ljpeg, libs_x)
3423   fi
3424
3425   dnl autodetect PNG
3426   png_problem=""
3427   test -z "$with_png" && { AC_CHECK_FUNC(pow,                  ,with_png=no) }
3428   test -z "$with_png" && { AC_CHECK_HEADER(png.h,              ,with_png=no) }
3429   test -z "$with_png" && { AC_CHECK_LIB(png, png_read_image,[:],with_png=no) }
3430   if test -z "$with_png"; then
3431     AC_MSG_CHECKING(for workable png version information)
3432     xe_check_libs="-lpng -lz"
3433     AC_TRY_RUN([#include <png.h>
3434     int main(int c, char **v) {
3435     if (c == 1) return 0;
3436     if (strcmp(png_libpng_ver, PNG_LIBPNG_VER_STRING) != 0) return 1;
3437     return (PNG_LIBPNG_VER < 10002) ? 2 : 0 ;}],
3438     [./conftest dummy_arg; png_status=$?;
3439       if test "$png_status" = "0"; then
3440         with_png=yes;
3441       else
3442         with_png=no;
3443         if test "$png_status" = "1"; then
3444           png_problem="PNG library version and header file don't match!"
3445         elif test "$png_status" = "2"; then
3446           png_problem="PNG library version too old (pre 1.0.2)!"
3447         fi
3448         echo "
3449 *** WARNING *** $png_problem
3450   I'm not touching that with a 10-foot pole!
3451   If you really want to use the installed version of libPNG, rerun
3452   configure and add '--with-png=yes', but don't blame me if XEmacs crashes!"
3453     fi],
3454     [with_png=no])
3455     xe_check_libs=
3456     AC_MSG_RESULT($with_png)
3457   fi
3458   if test "$with_png" = "yes"; then
3459     AC_DEFINE(HAVE_PNG)
3460     XE_PREPEND(-lpng, libs_x)
3461   fi
3462
3463   dnl autodetect TIFF
3464   test -z "$with_tiff" && { AC_CHECK_HEADER(tiffio.h,            ,with_tiff=no) }
3465   test -z "$with_tiff" && { AC_CHECK_LIB(tiff, TIFFClientOpen,[:],with_tiff=no) }
3466   test -z "$with_tiff" && with_tiff=yes
3467   if test "$with_tiff" = "yes"; then
3468     AC_DEFINE(HAVE_TIFF)
3469     XE_PREPEND(-ltiff, libs_x)
3470   fi
3471 fi
3472
3473 dnl ----------------------
3474 dnl GTK-Specific Graphics libraries
3475 dnl ----------------------
3476
3477 if test "$with_gtk" = "yes"; then
3478   dnl Autodetect XFACE
3479   test -z "$with_xface" && { AC_CHECK_HEADER(compface.h,          ,with_xface=no) }
3480   test -z "$with_xface" && { AC_CHECK_LIB(compface, UnGenFace,[:] ,with_xface=no) }
3481   test -z "$with_xface" && with_xface=yes
3482   if test "$with_xface" = "yes"; then
3483     AC_DEFINE(HAVE_XFACE)
3484     XE_PREPEND(-lcompface, libs_gtk)
3485   fi
3486 fi
3487
3488
3489 dnl ----------------------
3490 dnl X-Specific Graphics libraries
3491 dnl ----------------------
3492
3493 if test "$with_x11" = "yes"; then
3494   AC_CHECKING(for X11 graphics libraries)
3495 fi
3496
3497 if test "$with_x11" = "yes"; then
3498   AC_CHECKING(for the Athena widgets)
3499
3500   dnl What in heck did the user actually want?
3501   case "$with_athena" in
3502     dnl This is the default, old fashioned flat Athena.
3503     "xaw" | "") athena_variant=Xaw      athena_3d=no  ;;
3504     "3d")       athena_variant=Xaw3d    athena_3d=yes ;;
3505     "next")     athena_variant=neXtaw   athena_3d=yes ;;
3506     "95")       athena_variant=Xaw95    athena_3d=yes ;;
3507     "xpm")      athena_variant=XawXpm   athena_3d=yes ;;
3508     *)          XE_DIE("Unknown Athena widget set \`$with_athena'. This should not happen.") ;;
3509   esac
3510
3511   athena_3d_function=Xaw3dComputeBottomShadowRGB
3512
3513   dnl Search for the Athena library...
3514   if test "$athena_3d" = "no"; then
3515     AC_CHECK_LIB($athena_variant, XawScrollbarSetThumb,
3516       [
3517         dnl Must not be a 3d library...
3518         AC_CHECK_LIB($athena_variant, $athena_3d_function,
3519           AC_MSG_WARN("Could not find a non-3d Athena widget library."),
3520           athena_lib=$athena_variant)
3521       ],
3522       AC_MSG_WARN("Could not find an Athena widget library."))
3523   else
3524     dnl The real configuration, need 3d library
3525     AC_CHECK_LIB($athena_variant, $athena_3d_function, athena_lib=$athena_variant,
3526       dnl OK, couldn't find it with a proper name, try the standard Athena lib
3527       dnl If that is 3d, presume the user asked for what they have installed.
3528       AC_CHECK_LIB(Xaw, $athena_3d_function,
3529         [
3530           athena_lib=Xaw;
3531           AC_MSG_WARN("Assuming that libXaw is actually $athena_variant.");
3532         ],
3533         AC_MSG_WARN("Could not find a 3d Athena widget library that looked like $athena_variant.")))
3534   fi
3535
3536   dnl Now we locate the Athena headers that we need.
3537   if test "$athena_3d" = "no"; then
3538     AC_CHECK_HEADER(X11/Xaw/ThreeD.h,
3539       AC_MSG_WARN("Could not find a non-3d Athena header set."),
3540       AC_CHECK_HEADER(X11/Xaw/XawInit.h,
3541         athena_h_path=X11/Xaw,
3542         AC_MSG_WARN("Could not find a non-3d Athena header set.")))
3543   else
3544     dnl The three-d Athena headers are so much more slippery.
3545     dnl Curse this `Lets replace standard libraries' thing that they did. :/
3546     AC_CHECK_HEADER(X11/$athena_variant/XawInit.h,
3547       AC_CHECK_HEADER(X11/$athena_variant/ThreeD.h,
3548         athena_h_path=X11/$athena_variant,))
3549
3550     dnl Is the variant specific header directory directly under include?
3551     if test -z "$athena_h_path"; then
3552       AC_CHECK_HEADER($athena_variant/XawInit.h,
3553         AC_CHECK_HEADER($athena_variant/ThreeD.h,
3554           athena_h_path=$athena_variant,))
3555     fi
3556
3557     dnl If we couldn't find the specific variant, try the generic Athena 3d headers
3558     if test -z "$athena_h_path" -a "$athena_variant" != "Xaw3d"; then
3559       AC_CHECK_HEADER(X11/Xaw3d/XawInit.h,
3560         AC_CHECK_HEADER(X11/Xaw3d/ThreeD.h,
3561           [
3562             AC_MSG_WARN("Assuming that X11/Xaw3d headers are suitable for $athena_variant.")
3563             athena_h_path=X11/Xaw3d
3564           ],))
3565     fi
3566
3567     dnl Also generic 3d headers directly under include dir
3568     if test -z "$athena_h_path" -a "$athena_variant" != "Xaw3d"; then
3569       AC_CHECK_HEADER(Xaw3d/XawInit.h,
3570         AC_CHECK_HEADER(Xaw3d/ThreeD.h,
3571           [
3572             AC_MSG_WARN("Assuming that Xaw3d headers are suitable for $athena_variant.")
3573             athena_h_path=Xaw3d
3574           ],))
3575     fi
3576
3577     dnl If nothing yet found, see if Xaw is a 3d header set...
3578     dnl We AC_MSG_WARN if we fail because I am all out of ideas...
3579     if test -z "$athena_h_path"; then
3580       AC_CHECK_HEADER(X11/Xaw/ThreeD.h,
3581         [
3582           AC_MSG_WARN("Assuming that X11/Xaw headers are suitable for $athena_variant.")
3583           athena_h_path=X11/Xaw
3584         ],
3585         AC_MSG_WARN("Could not find a suitable 3d Athena header set."))
3586     fi
3587   fi
3588
3589   dnl Do we actually have a usable Athena widget set? Please?
3590   if test -n "$athena_lib" -a -n "$athena_h_path"; then
3591     have_xaw=yes
3592   else
3593     have_xaw=no
3594   fi
3595
3596 else
3597   have_xaw=no
3598 fi dnl "$with_x11" = "yes"
3599
3600 if test "$with_x11" = "yes"; then
3601   dnl autodetect Motif - but only add to libs_x later (if necessary)
3602   AC_CHECK_HEADER(Xm/Xm.h,
3603    [AC_CHECK_LIB(Xm, XmStringFree, have_motif=yes, have_motif=no)],
3604    have_motif=no)
3605
3606   if test "$have_motif" = "yes"; then
3607     dnl autodetect lesstif
3608     AC_MSG_CHECKING(for Lesstif)
3609     AC_EGREP_CPP(yes,
3610 [#include <Xm/Xm.h>
3611 #ifdef LESSTIF_VERSION
3612 yes
3613 #endif
3614 ], have_lesstif=yes, have_lesstif=no)
3615   AC_MSG_RESULT($have_lesstif)
3616   fi
3617
3618 fi dnl "$with_x11" = "yes"
3619
3620 dnl Finish ensuring that we have values for the various toolkit items.
3621 dnl Not all toolkits support all widgets
3622
3623 dnl Avoid using Motif :-(
3624 case "$opsys" in
3625   *linux* | cygwin* )  lucid_prefers_motif="no"  ;;
3626   * )        lucid_prefers_motif="yes" ;;
3627 esac
3628
3629 case "$with_menubars" in "" | "yes" | "athena" )
3630   with_menubars="lucid" ;;
3631 esac
3632 case "$with_dialogs" in "" | "yes" | "lucid" )
3633   if test "$lucid_prefers_motif" = "yes"; then
3634     if   test "$have_motif"     = "yes"; then with_dialogs="motif"
3635     elif test "$have_xaw"       = "yes"; then with_dialogs="athena"
3636     else with_dialogs=no
3637     fi
3638   else
3639     if   test "$have_xaw"       = "yes"; then with_dialogs="athena"
3640     elif test "$have_motif"     = "yes"; then with_dialogs="motif"
3641     else with_dialogs=no
3642     fi
3643   fi ;;
3644 esac
3645 case "$with_scrollbars" in "" | "yes" )
3646   with_scrollbars="lucid" ;;
3647 esac
3648 case "$with_widgets" in
3649   "yes" | "lucid")
3650     if test "$lucid_prefers_motif" = "yes"; then
3651       if   test "$have_motif" = "yes"; then with_widgets="motif"
3652       elif test "$have_xaw"   = "yes"; then with_widgets="athena"
3653       else with_widgets=no
3654       fi
3655     else
3656       if   test "$have_xaw"   = "yes"; then with_widgets="athena"
3657       elif test "$have_motif" = "yes"; then with_widgets="motif"
3658       else with_widgets=no
3659       fi
3660     fi ;;
3661   "" )
3662     with_widgets=no ;;
3663 esac
3664
3665 all_widgets="$with_menubars $with_scrollbars $with_dialogs $with_toolbars $with_widgets"
3666
3667 case "$all_widgets" in
3668   *athena* )
3669     if test "$have_xaw" != "yes"; then
3670       XE_DIE("Could not find a suitable Athena library to build with.")
3671     fi
3672
3673     dnl Add the Lucid widget Athena code
3674     XE_APPEND(lwlib-Xaw.o, lwlib_objs)
3675
3676     dnl Add the Athena widget library we located earlier
3677     XE_PREPEND(-l$athena_lib, libs_x)
3678
3679     dnl Tell lwlib where to find the Athena header files.
3680     dnl Many people have tried to create a `smart' way of doing this,
3681     dnl but all have failed.  Before changing the following ugly definitions,
3682     dnl consult the veterans of many a battle.
3683     AC_DEFINE_UNQUOTED(ATHENA_Scrollbar_h_,"$athena_h_path/Scrollbar.h")
3684     AC_DEFINE_UNQUOTED(ATHENA_Dialog_h_,"$athena_h_path/Dialog.h")
3685     AC_DEFINE_UNQUOTED(ATHENA_Form_h_,"$athena_h_path/Form.h")
3686     AC_DEFINE_UNQUOTED(ATHENA_Command_h_,"$athena_h_path/Command.h")
3687     AC_DEFINE_UNQUOTED(ATHENA_Label_h_,"$athena_h_path/Label.h")
3688     AC_DEFINE_UNQUOTED(ATHENA_LabelP_h_,"$athena_h_path/LabelP.h")
3689     AC_DEFINE_UNQUOTED(ATHENA_Toggle_h_,"$athena_h_path/Toggle.h")
3690     AC_DEFINE_UNQUOTED(ATHENA_ToggleP_h_,"$athena_h_path/ToggleP.h")
3691     AC_DEFINE_UNQUOTED(ATHENA_AsciiText_h_,"$athena_h_path/AsciiText.h")
3692     AC_DEFINE_UNQUOTED(ATHENA_XawInit_h_,"$athena_h_path/XawInit.h")
3693
3694     AC_DEFINE(LWLIB_USES_ATHENA)
3695     AC_DEFINE(NEED_ATHENA)
3696     need_athena="yes"
3697
3698     if test "$athena_3d" = "yes"; then
3699       AC_DEFINE(HAVE_ATHENA_3D)
3700     fi
3701   ;;
3702 esac
3703
3704 case "$all_widgets" in *motif* )
3705   AC_DEFINE(LWLIB_USES_MOTIF)
3706   AC_DEFINE(NEED_MOTIF)
3707   XE_APPEND(lwlib-Xm.o, lwlib_objs)
3708   need_motif=yes ;;
3709 esac
3710
3711 test "$with_menubars"   = "lucid" && XE_APPEND(xlwmenu.o, lwlib_objs)
3712 test "$with_menubars"   = "motif" && XE_APPEND(xlwmenu.o, lwlib_objs)
3713 test "$with_scrollbars" = "lucid" && XE_APPEND(xlwscrollbar.o, lwlib_objs)
3714 test "$with_widgets"   != "no" && test "$with_widgets" != "msw" && \
3715         XE_APPEND(xlwtabs.o xlwgcs.o, lwlib_objs)
3716 case "$with_widgets" in athena* )
3717         XE_APPEND(xlwradio.o xlwcheckbox.o xlwgauge.o, lwlib_objs);;
3718 esac
3719 case "$all_widgets" in *lucid* )
3720   AC_DEFINE(NEED_LUCID)
3721   XE_APPEND(lwlib-Xlw.o, lwlib_objs) ;;
3722 esac
3723
3724 AC_SUBST(lwlib_objs)
3725
3726 test "$with_scrollbars" = "athena" && AC_DEFINE(LWLIB_SCROLLBARS_ATHENA)
3727 test "$with_dialogs"    = "athena" && AC_DEFINE(LWLIB_DIALOGS_ATHENA)
3728
3729 if test "$athena_3d" = "yes"; then
3730   test "$with_scrollbars" = "athena" && AC_DEFINE(LWLIB_SCROLLBARS_ATHENA3D)
3731   test "$with_dialogs"    = "athena" && AC_DEFINE(LWLIB_DIALOGS_ATHENA3D)
3732 fi
3733
3734 case "$with_widgets" in athena* ) AC_DEFINE(LWLIB_WIDGETS_ATHENA);; esac
3735 test "$with_widgets" != "no" && test "$with_widgets" != "msw" && \
3736         AC_DEFINE(LWLIB_TABS_LUCID)
3737
3738 test "$with_menubars"   != "no"    && AC_DEFINE(HAVE_MENUBARS)
3739 test "$with_scrollbars" != "no"    && AC_DEFINE(HAVE_SCROLLBARS)
3740 test "$with_dialogs"    != "no"    && AC_DEFINE(HAVE_DIALOGS)
3741 test "$with_toolbars"   != "no"    && AC_DEFINE(HAVE_TOOLBARS)
3742 test "$with_widgets"    != "no"    && AC_DEFINE(HAVE_WIDGETS)
3743
3744 test "$with_menubars"   = "lucid"  && AC_DEFINE(LWLIB_MENUBARS_LUCID)
3745 test "$with_scrollbars" = "lucid"  && AC_DEFINE(LWLIB_SCROLLBARS_LUCID)
3746
3747 test "$with_menubars"   = "motif"  && AC_DEFINE(LWLIB_MENUBARS_MOTIF)
3748 test "$with_scrollbars" = "motif"  && AC_DEFINE(LWLIB_SCROLLBARS_MOTIF)
3749 test "$with_dialogs"    = "motif"  && AC_DEFINE(LWLIB_DIALOGS_MOTIF)
3750 test "$with_widgets"    = "motif"  && AC_DEFINE(LWLIB_WIDGETS_MOTIF)
3751
3752 test "$with_menubars"   != "no"    && XE_ADD_OBJS(menubar.o)
3753 test "$with_scrollbars" != "no"    && XE_ADD_OBJS(scrollbar.o)
3754 test "$with_dialogs"    != "no"    && XE_ADD_OBJS(dialog.o)
3755 test "$with_toolbars"   != "no"    && XE_ADD_OBJS(toolbar.o)
3756
3757 if test "$with_gtk" = "yes"; then
3758   test "$with_menubars"   != "no"      && XE_ADD_OBJS(menubar-gtk.o)
3759   test "$with_scrollbars" != "no"      && XE_ADD_OBJS(scrollbar-gtk.o)
3760   test "$with_dialogs"    != "no"      && XE_ADD_OBJS(dialog-gtk.o)
3761   test "$with_toolbars"   != "no"      && XE_ADD_OBJS(toolbar-gtk.o)
3762   test "$all_widgets" != "no no no no no" && XE_ADD_OBJS(gui-gtk.o)
3763 fi
3764
3765 if test "$with_x11" = "yes"; then
3766   test "$with_menubars"   != "no"  && XE_ADD_OBJS(menubar-x.o)
3767   test "$with_scrollbars" != "no"  && XE_ADD_OBJS(scrollbar-x.o)
3768   test "$with_dialogs"    != "no"  && XE_ADD_OBJS(dialog-x.o)
3769   test "$with_toolbars"   != "no"  && XE_ADD_OBJS(toolbar-x.o)
3770   test "$all_widgets" != "no no no no no" && XE_ADD_OBJS(gui-x.o)
3771 fi
3772
3773 dnl ----------------------
3774 dnl Mule-dependent options
3775 dnl ----------------------
3776
3777 test -z "$with_mule" && with_mule=no
3778 test -z "$with_file_coding" && with_file_coding=no
3779
3780 dnl if test "$with_mule" = "yes" && test ! -d "$srcdir/lisp/mule"; then
3781 dnl     echo "Attempt to Build with Mule without Mule/Lisp"
3782 dnl     echo "Please install the XEmacs/Mule tarball or"
3783 dnl     echo "rerun configure with --with-mule=no"
3784 dnl     exit 1
3785 dnl fi
3786
3787 if test "$with_file_coding" = "yes" && test "$with_mule" = "no"; then
3788   AC_DEFINE(FILE_CODING)
3789   XE_ADD_OBJS(file-coding.o)
3790 fi
3791
3792 if test "$with_mule" = "yes" ; then
3793   AC_CHECKING(for Mule-related features)
3794   AC_DEFINE(MULE)
3795   AC_DEFINE(FILE_CODING)
3796   XE_ADD_OBJS(mule.o mule-ccl.o mule-charset.o file-coding.o)
3797
3798   dnl Use -lintl to get internationalized strerror for Mule
3799   AC_CHECK_HEADERS(libintl.h)
3800   AC_CHECK_LIB(intl, strerror)
3801
3802   AC_CHECKING(for Mule input methods)
3803   dnl Do we have the XmIm* routines?  And if so, do we want to use them?
3804   dnl XIM seems to be flaky except on Solaris...
3805   dnl test -z "$with_xim" -a "$opsys" != "sol2" && with_xim=no
3806   case "$with_xim" in "" | "yes" )
3807     AC_CHECKING(for XIM)
3808     AC_CHECK_LIB(X11, XOpenIM, with_xim=xlib, with_xim=no)
3809     dnl XIM + Lesstif is not (yet?) usable
3810     dnl Only use Motif if linking Motif anyway, or don't have xlib XIM
3811     if test "$need_motif $have_lesstif" = "yes no"; then
3812       AC_CHECK_LIB(Xm, XmImMbLookupString, with_xim=motif)
3813     elif test "$have_motif $have_lesstif $with_xim" = "yes no no"; then
3814       AC_CHECK_LIB(Xm, XmImMbLookupString, with_xim=motif)
3815     fi ;;
3816   esac
3817   if test "$with_xim" != "no"; then
3818     AC_DEFINE(HAVE_XIM)
3819     if test "$with_xim" = "xlib"; then
3820       AC_DEFINE(XIM_XLIB)
3821       XE_ADD_OBJS(input-method-xlib.o)
3822     fi
3823     if test "$with_xim" = "motif"; then
3824       AC_DEFINE(XIM_MOTIF)
3825       need_motif=yes
3826       XE_ADD_OBJS(input-method-motif.o)
3827     fi
3828     if test "$with_xim" = "motif"; then
3829       with_xfs=no
3830     fi
3831   fi
3832
3833   dnl "with_xfs" = "yes"
3834   if test "$with_xfs" = "yes" ; then
3835     AC_CHECKING(for XFontSet)
3836     AC_CHECK_LIB(X11, XmbDrawString, [:], with_xfs=no)
3837     if test "$with_xfs" = "yes" && test "$with_menubars" = "lucid"; then
3838       AC_DEFINE(USE_XFONTSET)
3839       if test "$with_xim" = "no" ; then
3840         XE_ADD_OBJS(input-method-xlib.o)
3841       fi
3842     fi
3843   fi dnl with_xfs
3844
3845   dnl Autodetect WNN
3846   test "$with_wnn6" = "yes" && with_wnn=yes # wnn6 implies wnn support
3847   test -z "$with_wnn" && { AC_CHECK_HEADER(wnn/jllib.h, ,with_wnn=no) }
3848   dnl gcc 2.97 fixincludes breaks inclusion of wnn/commonhd.h
3849   test -z "$with_wnn" && { AC_CHECK_HEADER(wnn/commonhd.h, ,with_wnn=no) }
3850   dnl Detour to find crypt
3851   if test "$with_wnn" != "no"; then
3852     AC_CHECK_FUNCS(crypt)
3853     test "$ac_cv_func_crypt" != "yes" && { AC_CHECK_LIB(crypt, crypt) }
3854   fi
3855   dnl Back to our regularly scheduled wnn hunting
3856   if test -z "$with_wnn" -o "$with_wnn" = "yes"; then
3857     AC_CHECK_LIB(wnn,jl_dic_list_e,libwnn=wnn,
3858       AC_CHECK_LIB(wnn4,jl_dic_list_e,libwnn=wnn4,
3859         AC_CHECK_LIB(wnn6,jl_dic_list_e,libwnn=wnn6,
3860           AC_CHECK_LIB(wnn6_fromsrc,dic_list_e,libwnn=wnn6_fromsrc,with_wnn=no))))
3861   fi
3862   test -z "$with_wnn" && with_wnn=yes
3863   if test "$with_wnn" = "yes"; then
3864     AC_DEFINE(HAVE_WNN)
3865     XE_PREPEND(-l$libwnn, libs_x)
3866     XE_ADD_OBJS(mule-wnnfns.o)
3867     if test "$with_wnn6" != "no"; then
3868       AC_CHECK_LIB($libwnn, jl_fi_dic_list, with_wnn6=yes)
3869       test "$with_wnn6" = "yes" && AC_DEFINE(WNN6)
3870     fi
3871   fi
3872
3873   dnl Autodetect canna
3874   canna_includes_found=no
3875   if test "$with_canna" != "no"; then
3876     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3877   fi
3878   if test "$canna_includes_found" = "no" -a "$with_canna" != "no" -a \
3879       -d "/usr/local/canna/include"; then
3880     save_c_switch_site="$c_switch_site"
3881     c_switch_site="$c_switch_site -I/usr/local/canna/include"
3882     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3883     if test "$canna_includes_found" != "yes"; then
3884       c_switch_site="$save_c_switch_site"
3885       with_canna="no"
3886     fi
3887   fi
3888
3889   test -z "$with_canna" && { AC_CHECK_HEADER(canna/RK.h,         , with_canna=no) }
3890   test -z "$with_canna" && { AC_CHECK_LIB(RKC, RkBgnBun,       [:],with_canna=no) }
3891   test -z "$with_canna" && { AC_CHECK_LIB(canna,jrKanjiControl,[:],with_canna=no) }
3892   test -z "$with_canna" && with_canna=yes
3893   if test "$with_canna" = "yes"; then
3894     AC_DEFINE(HAVE_CANNA)
3895     XE_PREPEND(-lcanna -lRKC, libs_x)
3896     XE_ADD_OBJS(mule-canna.o)
3897   fi
3898
3899 else dnl "$with_mule" = "no"
3900   for feature in xim canna wnn; do
3901     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
3902       AC_MSG_WARN("--with-${feature} ignored:  Not valid without Mule support")
3903     fi
3904     eval "with_${feature}=no"
3905   done
3906 fi dnl with_mule
3907
3908
3909 dnl At this point, we know whether we need the motif lib or not.
3910 if test "$need_motif" = "yes" ; then
3911   XE_PREPEND(-lXm, libs_x)
3912   dnl AIX needs the following library for use with Motif
3913   AC_CHECK_LIB(i18n, layout_object_getvalue, [XE_PREPEND(-li18n, libs_x)])
3914   XE_COMPUTE_RUNPATH()
3915 fi
3916
3917 dnl ----------------------------------------------------------------
3918 dnl Check for POSIX functions.
3919 dnl ----------------------------------------------------------------
3920
3921 AC_CHECK_FUNCS(cbrt closedir dup2 eaccess fmod fpathconf frexp ftime getaddrinfo gethostname getnameinfo getpagesize gettimeofday getcwd getwd logb lrand48 matherr mkdir mktime perror poll random rename res_init rint rmdir select setitimer setpgid setlocale setsid sigblock sighold sigprocmask snprintf stpcpy strerror tzset ulimit usleep waitpid vsnprintf fsync ftruncate umask)
3922
3923 dnl getaddrinfo() is borked under hpux11
3924 if test "$ac_cv_func_getaddrinfo" != "no" ; then
3925   case "$opsys" in
3926     hpux11* )
3927       AC_MSG_WARN([Use of getaddrinfo is disabled for HP-UX 11.XX.])
3928       ac_cv_func_getaddrinfo=no
3929       ;;
3930   esac
3931 fi
3932
3933 dnl ----------------------------------------------------------------
3934 dnl Check for PTY support functions.
3935 dnl ----------------------------------------------------------------
3936
3937 dnl There is no "standard" pty allocation method.  Every system is different.
3938 dnl  getpt()  is the preferred pty allocation method on glibc systems.
3939 dnl _getpty() is the preferred pty allocation method on SGI systems.
3940 dnl grantpt(), unlockpt(), ptsname() are defined by Unix98.
3941 AC_CHECK_FUNCS(getpt _getpty grantpt unlockpt ptsname killpg tcgetpgrp)
3942
3943 dnl openpty() is the preferred pty allocation method on BSD and Tru64 systems.
3944 dnl openpty() might be declared in:
3945 dnl - pty.h (Tru64 or Linux)
3946 dnl - libutil.h (FreeBSD)
3947 dnl - util.h (NetBSD)
3948 AC_CHECK_FUNC(openpty, have_openpty=yes, [
3949   AC_CHECK_LIB(util, openpty, have_openpty=yes need_libutil=yes)])
3950 if test "$have_openpty" = "yes"; then
3951   AC_DEFINE(HAVE_OPENPTY)
3952   AC_CHECK_HEADERS(pty.h libutil.h util.h, break)
3953   test "$need_libutil" = "yes" && XE_APPEND(-lutil, libs_system)
3954 fi
3955
3956 dnl Check for STREAM support functions.
3957 dnl Confusingly, "str" means both "string" and "SysV Streams".
3958 AC_CHECK_HEADERS(stropts.h)
3959 if test "$ac_cv_header_stropts_h" = "yes"; then
3960   AC_CHECK_FUNCS(isastream)
3961   AC_CHECK_HEADERS(strtio.h) dnl TIOCSIGNAL
3962 fi
3963
3964 dnl Use our own realpath always.
3965 XE_ADD_OBJS(realpath.o)
3966
3967 dnl Check whether the system provides getloadavg().
3968 AC_CHECK_FUNCS(getloadavg)
3969
3970 if test "$ac_cv_func_getloadavg" = "yes"; then
3971   dnl Solaris 8 declares getloadavg() in <sys/loadavg.h>.
3972   dnl glibc 2.2 declares getloadavg() in <stdlib.h>...
3973   dnl   ...if we #define _GNU_SOURCE, which we do.
3974   AC_CHECK_HEADERS(sys/loadavg.h)
3975 else
3976   dnl We define our own getloadavg() using lower level functions.
3977   XE_ADD_OBJS(getloadavg.o)
3978
3979   dnl Used by getloadavg() - does not require root priveleges
3980   AC_CHECK_LIB(kstat, kstat_open)
3981   AC_CHECK_HEADERS(kstat.h)
3982
3983   dnl Another way to get the load average
3984   AC_CHECK_LIB(kvm, kvm_read)
3985 fi
3986
3987 dnl If netdb.h does not declare h_errno, we must declare it by hand.
3988 AC_MSG_CHECKING(whether netdb declares h_errno)
3989 AC_TRY_LINK([#include <netdb.h>],
3990   [return h_errno;],
3991   [AC_MSG_RESULT(yes)
3992    AC_DEFINE(HAVE_H_ERRNO)],
3993   [AC_MSG_RESULT(no)])
3994
3995 AC_MSG_CHECKING(for sigsetjmp)
3996 AC_TRY_COMPILE([#include <setjmp.h>],
3997         [sigjmp_buf bar; sigsetjmp (bar, 0);],
3998   [AC_MSG_RESULT(yes)
3999    AC_DEFINE(HAVE_SIGSETJMP)],
4000   [AC_MSG_RESULT(no)])
4001
4002 AC_MSG_CHECKING(whether localtime caches TZ)
4003 AC_CACHE_VAL(emacs_cv_localtime_cache,
4004 [if test "$ac_cv_func_tzset" = "yes"; then
4005 AC_TRY_RUN([#include <time.h>
4006 #if STDC_HEADERS
4007 # include <stdlib.h>
4008 #endif
4009 extern char **environ;
4010 unset_TZ ()
4011 {
4012   char **from, **to;
4013   for (to = from = environ; (*to = *from); from++)
4014     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
4015       to++;
4016 }
4017 char TZ_GMT0[] = "TZ=GMT0";
4018 char TZ_PST8[] = "TZ=PST8";
4019 main()
4020 {
4021   time_t now = time ((time_t *) 0);
4022   int hour_GMT0, hour_unset;
4023   if (putenv (TZ_GMT0) != 0)
4024     exit (1);
4025   hour_GMT0 = localtime (&now)->tm_hour;
4026   unset_TZ ();
4027   hour_unset = localtime (&now)->tm_hour;
4028   if (putenv (TZ_PST8) != 0)
4029     exit (1);
4030   if (localtime (&now)->tm_hour == hour_GMT0)
4031     exit (1);
4032   unset_TZ ();
4033   if (localtime (&now)->tm_hour != hour_unset)
4034     exit (1);
4035   exit (0);
4036 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
4037 [# If we have tzset, assume the worst when cross-compiling.
4038 emacs_cv_localtime_cache=yes])
4039 else
4040         # If we lack tzset, report that localtime does not cache TZ,
4041         # since we can't invalidate the cache if we don't have tzset.
4042         emacs_cv_localtime_cache=no
4043 fi],[:])dnl
4044 AC_MSG_RESULT($emacs_cv_localtime_cache)
4045 if test $emacs_cv_localtime_cache = yes; then
4046   AC_DEFINE(LOCALTIME_CACHE)
4047 fi
4048
4049 if test "$HAVE_TIMEVAL" = "yes"; then
4050 AC_MSG_CHECKING(whether gettimeofday accepts one or two arguments)
4051 AC_TRY_LINK([
4052 #ifdef TIME_WITH_SYS_TIME
4053 #include <sys/time.h>
4054 #include <time.h>
4055 #else
4056 #ifdef HAVE_SYS_TIME_H
4057 #include <sys/time.h>
4058 #else
4059 #include <time.h>
4060 #endif
4061 #endif
4062   ],
4063   [
4064   struct timeval time;
4065   gettimeofday (&time, 0);
4066 ],
4067   [AC_MSG_RESULT(two)],
4068   [AC_MSG_RESULT(one)
4069    AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
4070 fi
4071
4072
4073 AC_C_INLINE
4074 test "$ac_cv_c_inline" != "no" -a "$GCC" = "yes" && XE_ADD_OBJS(inline.o)
4075
4076 dnl HP-UX has a working alloca in libPW.
4077 dnl case "${GCC}${opsys}" in hpux* )
4078 dnl  AC_CHECK_FUNC(alloca, [:], [AC_CHECK_LIB(PW, alloca)])
4079 dnl esac
4080
4081 dnl AC_FUNC_ALLOCA doesn't know about DEC C's #pragma intrinsic(alloca)
4082 if test "$__DECC" != "yes"; then
4083   AC_FUNC_ALLOCA
4084   test -n "$ALLOCA" && XE_ADD_OBJS($ALLOCA)
4085 fi
4086
4087 dnl Check whether vfork exists and works correctly. (This does more
4088 dnl than just check for its existence.) If so, it defines HAVE_VFORK_H.
4089 dnl If not, it defines vfork to be fork.
4090 AC_FUNC_VFORK
4091
4092 dnl Check whether strcoll exists and works correctly. (This does more
4093 dnl than just check for its existence.) If so, it defines HAVE_STRCOLL.
4094 AC_FUNC_STRCOLL
4095
4096 dnl If `getpgrp' takes no argument (the POSIX.1 version), define
4097 dnl `GETPGRP_VOID'.  Otherwise, it is the BSD version, which takes a
4098 dnl process ID as an argument.
4099 AC_CHECK_FUNCS(getpgrp)
4100 AC_FUNC_GETPGRP
4101
4102 dnl We used to call AC_FUNC_MMAP here
4103 dnl Instead we now use following, suggested by Neal Becker
4104 AC_MSG_CHECKING(for working mmap)
4105 case "$opsys" in ultrix* ) have_mmap=no ;; *)
4106 AC_TRY_RUN([#include <stdio.h>
4107 #include <unistd.h>
4108 #include <fcntl.h>
4109 #include <sys/mman.h>
4110
4111 #ifndef MAP_VARIABLE
4112 #define MAP_VARIABLE 0
4113 #endif
4114
4115 #ifndef MAP_FAILED
4116 #define MAP_FAILED -1
4117 #endif
4118
4119 int main (int argc, char *argv[])
4120 {
4121   int fd = -1;
4122   caddr_t p;
4123 #ifndef MAP_ANONYMOUS
4124   fd = open ("/dev/zero", O_RDWR);
4125   if (fd < 0)
4126     return 1;
4127 #define MAP_ANONYMOUS 0
4128 #endif
4129   if (mmap(0, 1024, PROT_READ | PROT_WRITE,
4130            MAP_PRIVATE | MAP_VARIABLE | MAP_ANONYMOUS,
4131            fd, 0) != (void *) MAP_FAILED)
4132     return 0;
4133   perror ("conftest: mmap failed");
4134   return 1;
4135 }], have_mmap=yes, have_mmap=no) ;;
4136 esac
4137 AC_MSG_RESULT($have_mmap)
4138 test "$have_mmap" = "yes" && AC_DEFINE(HAVE_MMAP)
4139
4140 dnl By default we switch off rel-alloc on cygwin as it generally causes us grief
4141 case "$opsys" in cygwin*) 
4142         test "$rel_alloc" = "default" && rel_alloc=no ;;
4143 esac
4144 dnl rel_alloc requires either GNU malloc or system malloc with mmap
4145 dnl We only turn rel_alloc on by default if mmap is available.
4146 test "$GNU_MALLOC" != "yes" -a "$have_mmap" != "yes" && rel_alloc=no
4147 if test "$rel_alloc $have_mmap" = "default yes"; then
4148   if test "$doug_lea_malloc" = "yes"; then
4149     dnl Check if malloc() calls mmap(), making rel_alloc pointless.
4150     AC_MSG_CHECKING(for M_MMAP_THRESHOLD)
4151     AC_TRY_COMPILE([#include <malloc.h>],[
4152 #ifndef M_MMAP_THRESHOLD
4153 #error No M_MMAP_THRESHOLD :-(
4154 !@+$%^&*_)(_ - unlikely to compile...
4155 #endif
4156 ], [rel_alloc=no; AC_MSG_RESULT(yes);], [rel_alloc=yes; AC_MSG_RESULT(no);])
4157   else
4158     rel_alloc=yes
4159   fi
4160 fi
4161 test "$rel_alloc" = "yes" && AC_DEFINE(REL_ALLOC)
4162
4163 dnl Check for terminal I/O variants
4164 dnl TERMIOS systems may have termio.h, but not vice-versa, I think.
4165 AC_CHECK_HEADER(termios.h,
4166   AC_DEFINE(HAVE_TERMIOS)
4167   AC_DEFINE(SIGNALS_VIA_CHARACTERS)
4168   AC_DEFINE(NO_TERMIO),
4169   [AC_CHECK_HEADER(termio.h, [AC_DEFINE(HAVE_TERMIO)])])
4170
4171
4172 dnl Check for Internet sockets.
4173 AC_CHECK_FUNC(socket,
4174  [AC_CHECK_HEADER(netinet/in.h,
4175    [AC_CHECK_HEADER(arpa/inet.h, [
4176   AC_DEFINE(HAVE_SOCKETS)
4177       AC_MSG_CHECKING("for sun_len member in struct sockaddr_un")
4178       AC_TRY_LINK([
4179 #include <sys/types.h>
4180 #include <sys/socket.h>
4181 #include <sys/un.h>
4182       ],
4183       [static struct sockaddr_un x; x.sun_len = 1;],
4184       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)],
4185       [AC_MSG_RESULT(no)])
4186       AC_MSG_CHECKING("for ip_mreq struct in netinet/in.h")
4187       AC_TRY_LINK([
4188 #include <sys/types.h>
4189 #include <netinet/in.h>
4190       ],
4191       [static struct ip_mreq x;],
4192       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MULTICAST)],
4193       [AC_MSG_RESULT(no)])])])])
4194
4195 dnl Check for SYS V IPC. (Inferior to sockets.)
4196 AC_CHECK_FUNC(msgget,
4197   [AC_CHECK_HEADER(sys/ipc.h,
4198     [AC_CHECK_HEADER(sys/msg.h,
4199       [AC_DEFINE(HAVE_SYSVIPC)])])])
4200
4201 dnl Check for directory variants
4202 AC_CHECK_HEADER(dirent.h, [AC_DEFINE(SYSV_SYSTEM_DIR)],
4203   [AC_CHECK_HEADER(sys/dir.h, , [AC_DEFINE(NONSYSTEM_DIR_LIBRARY)])])
4204
4205 dnl Check for nlist.h
4206 AC_CHECK_HEADER(nlist.h, AC_DEFINE(NLIST_STRUCT), )
4207
4208 dnl Check for sound of various sorts.
4209
4210 dnl Autodetect native sound
4211 AC_CHECKING("for sound support")
4212 test -z "$with_native_sound" -a -n "$native_sound_lib" && with_native_sound=yes
4213
4214 if test "$with_native_sound" != "no"; then
4215   dnl Maybe sound is already on include path...
4216   if test -n "$native_sound_lib"; then
4217     AC_CHECK_HEADER(multimedia/audio_device.h,
4218       [sound_found=yes sound_cflags=""
4219       XE_ADD_OBJS(sunplay.o)])
4220   fi
4221
4222   dnl Autodetect Sun native sound from SUNWaudmo package
4223   if test -z "$sound_found" -a -d "/usr/demo/SOUND"; then
4224     if test -d "/usr/demo/SOUND/include/multimedia"; then
4225       sun_sound_cflags="-I/usr/demo/SOUND/include"
4226     elif test -d "/usr/demo/SOUND/multimedia"; then
4227       sun_sound_cflags="-I/usr/demo/SOUND"
4228     fi
4229
4230     if test -n "$native_sound_lib"; then
4231       sun_sound_lib="$native_sound_lib"
4232     elif test -r "/usr/demo/SOUND/lib/libaudio.a"; then
4233       sun_sound_lib="/usr/demo/SOUND/lib/libaudio.a"
4234     elif test -r "/usr/demo/SOUND/libaudio.a"; then
4235       sun_sound_lib="/usr/demo/SOUND/libaudio.a"
4236     fi
4237
4238     if test -n "$sun_sound_cflags" -a -n "$sun_sound_lib"; then
4239       native_sound_lib="$sun_sound_lib"
4240       sound_cflags="$sun_sound_cflags"
4241       sound_found=yes
4242       XE_ADD_OBJS(sunplay.o)
4243     fi
4244   fi
4245
4246   dnl Check for SGI and HP native sound libs
4247   if test -z "$sound_found"; then
4248     case "$canonical" in
4249     *-sgi-* )
4250       if test -z "$native_sound_lib"; then
4251         AC_CHECK_LIB(audio, ALopenport, native_sound_lib="-laudio")
4252       fi
4253       if test -n "$native_sound_lib"; then
4254         sound_found=yes sound_cflags=""
4255         XE_ADD_OBJS(sgiplay.o)
4256       fi ;;
4257     hppa*-hp-hpux* )
4258       if test -z "$native_sound_lib"; then
4259         AC_CHECK_LIB(Alib, AOpenAudio, native_sound_lib="-lAlib")
4260       fi
4261       if test -n "$native_sound_lib"; then
4262         sound_found=yes
4263         XE_ADD_OBJS(hpplay.o)
4264         if test "$GCC" = "yes" # Kludge city
4265           then sound_cflags="-Dconst= -Dvolatile= -I/usr/audio/examples"
4266           else sound_cflags="+e -I/usr/audio/examples"
4267         fi
4268       fi ;;
4269     esac
4270   fi
4271
4272   dnl Win32 Native uses native sound
4273   if test -z "$sound_found"; then
4274     if test "$with_msw" = "yes"; then
4275     sound_found=yes
4276     native_sound_lib=
4277     fi
4278   fi
4279
4280   dnl Check for Linux/BSD native sound
4281   if test -z "$sound_found"; then
4282     for dir in "machine" "sys" "linux"; do
4283       AC_CHECK_HEADER(${dir}/soundcard.h,
4284         sound_found=yes
4285        need_miscplay=yes
4286         XE_ADD_OBJS(linuxplay.o)
4287         [AC_DEFINE_UNQUOTED(SOUNDCARD_H_FILE, "${dir}/soundcard.h")]
4288         break)
4289     done
4290   fi
4291
4292   test "$sound_found" = "yes" && with_native_sound=yes
4293 fi
4294
4295 if test "$with_native_sound" = "yes"; then
4296   AC_DEFINE(HAVE_NATIVE_SOUND)
4297   test -n "$native_sound_lib" && XE_PREPEND($native_sound_lib, LIBS)
4298 fi
4299
4300 dnl NAS Sound support
4301 if test "$with_nas_sound" != "no"; then
4302   AC_CHECK_HEADER(audio/audiolib.h, [
4303     AC_CHECK_LIB(audio, AuOpenServer, have_nas_sound=yes)])
4304   if test "$have_nas_sound" = "yes"; then
4305     with_nas_sound=yes
4306     AC_DEFINE(HAVE_NAS_SOUND)
4307     XE_ADD_OBJS(nas.o)
4308     XE_PREPEND(-laudio, libs_x)
4309     dnl If the nas library does not contain the error jump point,
4310     dnl then we force safer behavior.
4311     AC_EGREP_HEADER(AuXtErrorJump,audio/Xtutil.h,,[old_nas=yes; AC_DEFINE(NAS_NO_ERROR_JUMP)])
4312   else
4313     test "$with_nas_sound" = "yes" && \
4314       XE_DIE("Required NAS sound support cannot be provided.")
4315     with_nas_sound=no
4316   fi
4317 fi
4318
4319 dnl ESD Sound support
4320 if test "$with_esd_sound" != "no"; then
4321   AC_CHECK_PROG(have_esd_config, esd-config, yes, no)
4322   if test "$have_esd_config" = "yes"; then
4323     save_c_switch_site="$c_switch_site" save_LIBS="$LIBS"
4324     XE_APPEND(`esd-config --cflags`, c_switch_site)
4325     XE_PREPEND(`esd-config --libs`, LIBS)
4326     AC_CHECK_FUNC(esd_play_stream,
4327       have_esd_sound=yes,
4328       c_switch_site="$save_c_switch_site" LIBS="$save_LIBS")
4329   fi
4330
4331   if test "$have_esd_sound" = "yes"; then
4332     with_esd_sound=yes
4333     need_miscplay=yes
4334     XE_ADD_OBJS(esd.o)
4335     AC_DEFINE(HAVE_ESD_SOUND)
4336   else
4337     test "$with_esd_sound" = "yes" && \
4338       XE_DIE("Required ESD sound support cannot be provided.")
4339     with_esd_sound=no
4340   fi
4341 fi
4342
4343 test "$need_miscplay" = "yes" && XE_ADD_OBJS(miscplay.o)
4344
4345 dnl ---------------------
4346 dnl TTY-dependent options
4347 dnl ---------------------
4348
4349 test -z "$with_tty" && with_tty=yes
4350
4351 if test "$with_tty" = "yes"  ; then
4352   AC_CHECKING(for TTY-related features)
4353   AC_DEFINE(HAVE_TTY)
4354   XE_ADD_OBJS(console-tty.o device-tty.o event-tty.o frame-tty.o objects-tty.o redisplay-tty.o cm.o)
4355
4356   dnl Autodetect ncurses.
4357   if test -z "$with_ncurses"; then
4358     AC_CHECK_LIB(ncurses, tgetent, with_ncurses=yes, with_ncurses=no)
4359   fi
4360   if test "$with_ncurses" = "yes"; then
4361     AC_DEFINE(HAVE_NCURSES)
4362     AC_CHECK_HEADER(ncurses/curses.h, curses_h_file=ncurses/curses.h)
4363     AC_CHECK_HEADER(ncurses/term.h, term_h_file=ncurses/term.h)
4364     XE_ADD_OBJS(terminfo.o)
4365     XE_PREPEND(-lncurses, LIBS)
4366
4367     if test "$ac_cv_header_ncurses_curses_h" != "yes" ; then
4368       dnl Try again, and check for the bogus ncurses/ include bug.
4369       dnl (i.e. ncurses/curses.h bogusly includes <unctrl.h> instead of
4370       dnl <ncurses/unctrl.h>)
4371       save_c_switch_site="$c_switch_site"
4372       c_switch_site="$c_switch_site -I/usr/include/ncurses"
4373       AC_CHECK_HEADER(ncurses/curses.h, curses_h_file=ncurses/curses.h)
4374       if test "$ac_cv_header_ncurses_curses_h" = "yes"
4375         then AC_MSG_WARN("Your system has the bogus ncurses include bug.")
4376         else c_switch_site="$save_c_switch_site"
4377       fi
4378     fi
4379   else dnl "$with_ncurses" = "no"
4380     dnl Autodetect terminfo/-lcurses/-ltermlib/-ltermcap
4381     if test "$have_terminfo" = "yes"; then
4382       XE_ADD_OBJS(terminfo.o)
4383       if test -n "$libs_termcap"; then
4384         XE_PREPEND($libs_termcap, LIBS)
4385       else
4386         for lib in curses termlib termcap; do
4387           AC_CHECK_LIB($lib, tgetent, XE_PREPEND(-l${lib}, LIBS); break)
4388         done
4389       fi
4390     else dnl "$have_terminfo" = "no" && "with_ncurses" = "no"
4391       if test -n "$libs_termcap" -a "$opsys" = "openbsd"; then
4392         dnl We need to check if tgoto does not exist in termcap yet
4393         dnl because on OpenBSD libtermcap is another name for libcurses
4394         dnl which provides the same tgoto as ncurses
4395         AC_CHECK_LIB(termcap, tgoto, , XE_ADD_OBJS(tparam.o))
4396       else
4397         XE_ADD_OBJS(tparam.o)
4398       fi
4399       dnl The HP-UX curses library seems to have a badly broken version of select(2)
4400       dnl that makes "poll: interrupted system call" messages to appear and
4401       dnl Emacs subprocesses to hang (e.g. TeX compilation w/ AUCTeX) */
4402       case "$opsys" in *-hp-hpux* ) libs_termcap="-ltermcap" ;; esac
4403       if test -n "$libs_termcap"; then
4404         XE_PREPEND($libs_termcap, LIBS)
4405       else
4406         AC_CHECK_LIB(curses, tgetent, XE_PREPEND(-lcurses, LIBS),
4407           AC_CHECK_LIB(termcap, tgetent, XE_PREPEND(-ltermcap, LIBS),
4408             XE_ADD_OBJS(termcap.o)))
4409       fi
4410     fi
4411   fi
4412   AC_DEFINE_UNQUOTED(CURSES_H_FILE, "${curses_h_file-curses.h}")
4413   AC_DEFINE_UNQUOTED(TERM_H_FILE, "${term_h_file-term.h}")
4414
4415   dnl General Purpose Mouse (libgpm) support
4416   if test "$with_gpm" != "no"; then
4417     AC_CHECK_HEADER(gpm.h, [
4418       AC_CHECK_LIB(gpm, Gpm_Open, have_gpm=yes)])
4419     if test "$have_gpm" = "yes"; then
4420       with_gpm=yes
4421       AC_DEFINE(HAVE_GPM)
4422       XE_ADD_OBJS(gpmevent.o)
4423       XE_PREPEND(-lgpm, LIBS)
4424     elif test "$with_gpm" = "yes"; then
4425       XE_DIE(["GPM requested, but gpm.h or libgpm seems to be missing."])
4426     else
4427       with_gpm=no
4428     fi
4429   fi
4430
4431 else dnl "$with_tty" = "no"
4432   for feature in ncurses gpm; do
4433     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
4434       AC_MSG_WARN("--with-${feature} ignored:  Not valid without TTY support")
4435     fi
4436     eval "with_${feature}=no"
4437   done
4438 fi dnl with_tty
4439
4440 dnl Do we need event-unixoid.o ?
4441 dnl This is needed for X, or for TTY, or for MSWIN w/Cygwin select()
4442 dnl [but not Mingw MSWIN]
4443 test "$with_x11" = "yes" -o "$with_tty" = "yes" -o "$need_event_unixoid" = "yes" && XE_ADD_OBJS(event-unixoid.o)
4444
4445 dnl Database support
4446 dnl We do not necessarily have to have libdb/lib(g)dbm for DB/(G)DBM support.
4447 dnl On FreeBSD, both DB and DBM are part of libc.
4448 dnl By default, we check for DBM support in libgdbm, then libc, then libdbm.
4449
4450 test "$with_database_gdbm $with_database_dbm $with_database_berkdb" \
4451   != "no no no" && AC_CHECKING(for database support)
4452
4453 dnl Check for ndbm.h, required for either kind of DBM support.
4454 if test "$with_database_gdbm $with_database_dbm" != "no no"; then
4455   AC_CHECK_HEADER(ndbm.h, [:], [
4456     test "$with_database_gdbm" = "yes" -o \
4457          "$with_database_dbm"  = "yes" && \
4458       XE_DIE("Required DBM support cannot be provided.")
4459     with_database_gdbm=no with_database_dbm=no])
4460 fi
4461
4462 dnl Check for DBM support in libgdbm.
4463 if test "$with_database_gdbm" != "no"; then
4464   AC_CHECK_LIB(gdbm, dbm_open, [
4465    with_database_gdbm=yes with_database_dbm=no libdbm=-lgdbm], [
4466    if test "$with_database_gdbm" = "yes"; then
4467      XE_DIE("Required GNU DBM support cannot be provided.")
4468    fi
4469    with_database_gdbm=no])
4470 fi
4471
4472 dnl Check for DBM support in libc and libdbm.
4473 if test "$with_database_dbm" != "no"; then
4474   AC_CHECK_FUNC(dbm_open, [with_database_dbm=yes libdbm=], [
4475     AC_CHECK_LIB(dbm, dbm_open, [with_database_dbm=yes libdbm=-ldbm], [
4476       test "$with_database_dbm" = "yes" && \
4477         XE_DIE("Required DBM support cannot be provided.")
4478       with_database_dbm=no])])
4479 fi
4480
4481 dnl Tell make about the DBM support we detected.
4482 test -n "$libdbm" && XE_PREPEND("$libdbm", LIBS)
4483 test "$with_database_gdbm" = "yes" -o \
4484      "$with_database_dbm"  = "yes" && \
4485   AC_DEFINE(HAVE_DBM)
4486
4487 dnl Check for u_int*_t typedefs.
4488 AC_CHECK_TYPE(u_int8_t, uint8_t)
4489 if test $ac_cv_type_u_int8_t = yes; then
4490 AC_DEFINE(HAVE_U_INT8_T,1)
4491 fi
4492 AC_CHECK_TYPE(u_int16_t, uint16_t)
4493 if test $ac_cv_type_u_int16_t = yes; then
4494 AC_DEFINE(HAVE_U_INT16_T,1)
4495 fi
4496 AC_CHECK_TYPE(u_int32_t, uint32_t)
4497 if test $ac_cv_type_u_int32_t = yes; then
4498 AC_DEFINE(HAVE_U_INT32_T,1)
4499 fi
4500 AC_CHECK_TYPE(u_int64_t, uint64_t)
4501 if test $ac_cv_type_u_int64_t = yes; then
4502 AC_DEFINE(HAVE_U_INT64_T,1)
4503 fi
4504
4505 dnl Check for Berkeley DB.
4506 if test "$with_database_berkdb" != "no"; then
4507   AC_MSG_CHECKING(for Berkeley db.h)
4508   for header in "db/db.h" "db.h"; do
4509     case "$opsys" in
4510         *freebsd*)
4511     AC_TRY_COMPILE([
4512 #include <stdlib.h>
4513 #if !(defined __GLIBC__ && __GLIBC_MINOR__ >= 1)
4514 #ifdef HAVE_INTTYPES_H
4515 #define __BIT_TYPES_DEFINED__
4516 #include <inttypes.h>
4517 #endif
4518 #endif
4519 #include <$header>
4520 ],[], db_h_file="$header"; break)
4521         ;;
4522         *)
4523     AC_TRY_COMPILE([
4524 #include <stdlib.h>
4525 #if !(defined __GLIBC__ && __GLIBC_MINOR__ >= 1)
4526 #ifdef HAVE_INTTYPES_H
4527 #define __BIT_TYPES_DEFINED__
4528 #include <inttypes.h>
4529 #if !HAVE_U_INT8_T
4530 typedef uint8_t  u_int8_t;
4531 #endif
4532 #if !HAVE_U_INT16_T
4533 typedef uint16_t u_int16_t;
4534 #endif
4535 #if !HAVE_U_INT32_T
4536 typedef uint32_t u_int32_t;
4537 #endif
4538 #ifdef WE_DONT_NEED_QUADS
4539 #if !HAVE_U_INT64_T
4540 typedef uint64_t u_int64_t;
4541 #endif
4542 #endif
4543 #endif
4544 #endif
4545 #include <$header>
4546 ],[], db_h_file="$header"; break)
4547         ;;
4548         esac
4549   done
4550   if test -z "$db_h_file"
4551   then AC_MSG_RESULT(no); with_database_berkdb=no
4552   else AC_MSG_RESULT($db_h_file)
4553   fi
4554
4555   if test "$with_database_berkdb" != "no"; then
4556     AC_MSG_CHECKING(for Berkeley DB version)
4557     AC_EGREP_CPP(yes,
4558 [#include <$db_h_file>
4559 #if DB_VERSION_MAJOR > 1
4560 yes
4561 #endif
4562 ], [AC_EGREP_CPP(yes,
4563 [#include <$db_h_file>
4564 #if DB_VERSION_MAJOR > 2
4565 yes
4566 #endif
4567 ], [AC_MSG_RESULT(3); dbfunc=db_create],[
4568     AC_MSG_RESULT(2); dbfunc=db_open])],[
4569     AC_MSG_RESULT(1); dbfunc=dbopen])
4570     AC_CHECK_FUNC($dbfunc,     with_database_berkdb=yes need_libdb=no, [
4571     AC_CHECK_LIB(db, $dbfunc,  with_database_berkdb=yes need_libdb=yes)])
4572   fi
4573
4574   if test "$with_database_berkdb" = "yes"; then
4575     AC_DEFINE_UNQUOTED(DB_H_FILE, "$db_h_file")
4576     AC_DEFINE(HAVE_BERKELEY_DB)
4577     test "$need_libdb" = "yes" && XE_PREPEND(-ldb, LIBS)
4578   else with_database_berkdb=no
4579   fi
4580 fi
4581
4582 if test "$with_database_gdbm $with_database_dbm $with_database_berkdb" \
4583      != "no no no"; then
4584   AC_DEFINE(HAVE_DATABASE)
4585   XE_ADD_OBJS(database.o)
4586 fi
4587
4588 dnl Socks support
4589 if test "$with_socks" = "yes"; then
4590   AC_CHECK_LIB(socks, SOCKSinit)
4591   test -n "$ac_cv_lib_socks_SOCKSinit" && AC_DEFINE(HAVE_SOCKS)
4592 fi
4593
4594 dnl Usage tracking (undocumented and likely unused option)
4595 if test "$usage_tracking" = "yes"; then
4596   AC_DEFINE(USAGE_TRACKING)
4597   XE_PREPEND(-Bstatic -lut -Bdynamic, LIBS)
4598 fi
4599
4600 dnl autodetect dll support
4601 if test "$with_modules" != "no"; then
4602   AC_CHECKING(for module support)
4603
4604   dnl Check for MS-Windows
4605   if test "$with_msw" = "yes"; then
4606     have_dl=yes;
4607   else
4608     dnl Check for Darwin
4609     case "$opsys" in
4610       darwin) have_dl=yes; AC_DEFINE(HAVE_DYLD) ;;
4611       *) dnl Find headers and libraries
4612          AC_CHECK_HEADER(dlfcn.h, [
4613            AC_MSG_CHECKING([for dlopen in -lc])
4614            AC_TRY_LINK([#include <dlfcn.h>],dnl
4615               [dlopen ("", 0);], [ have_dl=yes ], [
4616                AC_MSG_CHECKING([for dlopen in -ldl])
4617                ac_save_LIBS="$LIBS"
4618                LIBS="-ldl $LIBS"
4619                AC_TRY_LINK([#include <dlfcn.h>],dnl
4620                  [dlopen ("", 0);], [ have_dl=yes ],
4621                  [LIBS="$ac_save_LIBS"])
4622                ac_save_LIBS=])])
4623         if test -n "$have_dl"; then
4624            AC_DEFINE(HAVE_DLOPEN)
4625         else
4626            AC_CHECK_LIB(dld, shl_load, [
4627            libdl=dld have_dl=yes;
4628            AC_DEFINE(HAVE_SHL_LOAD)], [
4629            AC_CHECK_LIB(dld, dld_init, [
4630            libdl=dld have_dl=yes;
4631            AC_DEFINE(HAVE_DLD_INIT)])])
4632         fi
4633     ;;
4634     esac
4635   fi dnl end !MS-Windows
4636
4637   if test -n "$have_dl"; then
4638     dnl XE_SHLIB_STUFF (in aclocal.m4) defines $can_build_shared
4639     XE_SHLIB_STUFF
4640   fi
4641
4642   if test "$can_build_shared" = "yes"; then
4643     AC_DEFINE(HAVE_SHLIB)
4644     XE_ADD_OBJS(sysdll.o emodules.o)
4645     XE_APPEND(src, INSTALL_ARCH_DEP_SUBDIR)
4646     test -n "$libdl" && XE_PREPEND(-l${libdl}, LIBS)
4647     AC_CHECK_FUNCS(dlerror _dlerror)
4648     with_modules=yes
4649   else
4650     if test "$with_modules" = "yes"; then
4651       XE_DIE("Required module support cannot be provided.")
4652     else
4653       AC_MSG_WARN("Module support cannot be provided.")
4654     fi
4655     with_modules=no
4656   fi
4657 fi
4658
4659 dnl Unfortunately, just because we can link doesn't mean we can run.
4660 dnl One of the above link tests may have succeeded but caused resulting
4661 dnl executables to fail to run.  Also any tests using AC_TRY_RUN will
4662 dnl have reported incorrect results.
4663 AC_TRY_RUN([int main(int c,char *v[]){return 0;}],[:],[
4664   echo ""
4665   echo "*** PANIC *** configure forgot how to build working executables!"
4666   echo ""
4667   echo "*** This is most commonly due to an unforeseen environment, causing"
4668   echo "*** configure to incorrectly compute the sequence of libraries to link."
4669   echo "*** Please examine the tail of config.log for runtime errors."
4670   echo "*** Pay special attention to the -l flags, and perhaps -I and -L."
4671   echo "*** Often adding or removing explicit options in the configure"
4672   echo "*** invocation can work around this kind of problem.  If so, please"
4673   echo "*** report it as a bug to xemacs-beta@xemacs.org."
4674   echo "***"
4675   echo "*** Other possible causes are inability to write to the file system"
4676   echo "*** (bogus permissions or disk full) or a misconfiguration of the dynamic"
4677   echo "*** linker.  On Linux, check /etc/ld.conf and rerun ldconfig if"
4678   echo "*** necessary.  On other systems, try telling configure where to find"
4679   echo "*** the shared libraries using the --site-runtime-libraries option."
4680   echo "***"
4681   echo "*** Another way to shoot yourself in the foot is to specify"
4682   echo "*** --with-FEATURE when FEATURE is not actually installed on your"
4683   echo "*** system.  Don't do that."
4684   exit 1])
4685
4686 dnl Process support
4687 if test "$win32_processes" = "yes"; then
4688   XE_ADD_OBJS(process-nt.o)
4689 else
4690   AC_DEFINE(HAVE_UNIX_PROCESSES)
4691   XE_ADD_OBJS(process-unix.o)
4692 fi
4693
4694 dnl --------------------------------
4695 dnl Compute SUBST-itutable variables
4696 dnl --------------------------------
4697
4698 dnl We ignore (C|LD)_SWITCH_X_(MACHINE|SYSTEM)
4699 dnl Use XE_SPACE instead of plain assignment statements to remove extraneous blanks
4700 XE_SPACE(CFLAGS, $CFLAGS)
4701 XE_SPACE(extra_objs, $extra_objs)
4702 XE_SPACE(c_switch_general, -DHAVE_CONFIG_H $c_switch_site $c_switch_machine $c_switch_system)
4703 XE_SPACE(c_switch_window_system, $c_switch_x_site $c_switch_gtk $X_CFLAGS)
4704 XE_SPACE(c_switch_all, $c_switch_general $c_switch_window_system)
4705 XE_SPACE(ld_switch_general, $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_run)
4706 XE_SPACE(ld_switch_window_system, $ld_switch_x_site)
4707 XE_SPACE(ld_switch_all, $ld_switch_general $ld_switch_window_system)
4708 XE_SPACE(ld_libs_general, $LIBS $libs_machine $libs_system $libs_standard)
4709 XE_SPACE(ld_libs_window_system, $X_EXTRA_LIBS $libs_x $libs_gtk $X_PRE_LIBS)
4710 XE_SPACE(ld_libs_all, $ld_libs_window_system $ld_libs_general)
4711
4712 dnl Compute lists of Makefiles and subdirs
4713 AC_SUBST(SRC_SUBDIR_DEPS)
4714 XE_APPEND(src, MAKE_SUBDIR)
4715 internal_makefile_list="Makefile.in"
4716 SUBDIR_MAKEFILES=''
4717 test -d lock || mkdir lock
4718 for dir in $MAKE_SUBDIR; do
4719   case "$dir" in */* ) dnl Implement mkdir -p
4720     ( for d in `echo $dir | sed 's:/: :g'` ; do
4721         test -d "$d" || mkdir "$d"; cd "$d"
4722       done ) ;;
4723    * ) test -d "$dir" || mkdir "$dir" ;;
4724   esac
4725   XE_SPACE(SUBDIR_MAKEFILES, $SUBDIR_MAKEFILES $dir/Makefile $dir/GNUmakefile)
4726   XE_SPACE(internal_makefile_list, $internal_makefile_list $dir/Makefile.in)
4727 done
4728 AC_SUBST(INSTALL_ARCH_DEP_SUBDIR)
4729 AC_SUBST(MAKE_SUBDIR)
4730 AC_SUBST(SUBDIR_MAKEFILES)
4731
4732 dnl Make s&m symlinks in the src directory, for config.h
4733 for dir in src/s src/m; do
4734   if test ! -d "$dir" ; then
4735     echo Making symbolic link to "$srcdir/$dir"
4736     ${LN_S} "$srcdir/$dir" "$dir"
4737   fi
4738 done
4739
4740 if test "$extra_verbose" = "yes"; then
4741   echo ""
4742   PRINT_VAR(extra_objs
4743    c_switch_general  c_switch_window_system  c_switch_all
4744   ld_switch_general ld_switch_window_system ld_switch_all
4745     ld_libs_general   ld_libs_window_system   ld_libs_all)
4746   echo ""
4747 fi
4748
4749 dnl ----------------------------------------------
4750 dnl Create some auxiliary files for developers.
4751 dnl ----------------------------------------------
4752
4753 dnl Create a .gdbinit useful for debugging XEmacs
4754 if test -f "$srcdir/src/.gdbinit" -a ! -f "src/.gdbinit"; then
4755   test "$extra_verbose" = "yes" && echo "creating src/.gdbinit"
4756   echo "source $srcdir/src/.gdbinit" > "src/.gdbinit"
4757 fi
4758
4759 dnl Create a .dbxrc useful for debugging XEmacs
4760 if test -f "$srcdir/src/.dbxrc" -a ! -f "src/.dbxrc"; then
4761   test "$extra_verbose" = "yes" && echo "creating src/.dbxrc"
4762   echo ". $srcdir/src/.dbxrc" > "src/.dbxrc"
4763 fi
4764
4765 dnl Create a useful TAGS file
4766 if test -f "$srcdir/TAGS" -a ! -f "TAGS"; then
4767   test "$extra_verbose" = "yes" && echo "creating TAGS"
4768   echo "\f
4769 $srcdir/TAGS,include" > "TAGS"
4770 fi
4771
4772 dnl Create top level .sbinit for Sun compilers
4773 if test "$__SUNPRO_C" = "yes"; then
4774   test "$extra_verbose" = "yes" && echo "creating .sbinit"
4775   ( echo "# For use with Sun WorkShop's Source browser."
4776     echo "# See sbquery(1) and sbinit(4) for more information"
4777     for dir in $MAKE_SUBDIR; do echo "import $dir"; done
4778   ) > .sbinit
4779 fi
4780
4781 dnl There are no more compile tests; remove the core they created.
4782 rm -f core
4783
4784 dnl ----------------------------------------------
4785 dnl Substitute into Makefile, config.h and paths.h
4786 dnl ----------------------------------------------
4787
4788 dnl what sort of things to edit into Makefile, config.h and paths.h
4789 dnl configuration here uncanonicalized to avoid exceeding size limits.
4790
4791 AC_SUBST(PROGNAME)
4792 AC_SUBST(version)
4793 AC_SUBST(configuration)
4794 AC_SUBST(canonical)
4795 AC_SUBST(inststaticdir)
4796 AC_SUBST(instvardir)
4797 AC_SUBST(srcdir)
4798 AC_SUBST(bindir)
4799 AC_SUBST(datadir)
4800 AC_SUBST(pkgdir)
4801 AC_SUBST(statedir)
4802 AC_SUBST(libdir)
4803 AC_SUBST(mandir)
4804 AC_SUBST(extra_includes)
4805
4806 AC_SUBST(prefix)
4807 AC_SUBST(PREFIX_USER_DEFINED)
4808 dnl Yo, Stephen Bourne!  I want to marry you!
4809 PREFIX=$prefix
4810 while true; do
4811   case "$PREFIX" in
4812     *\$* ) eval "PREFIX=$PREFIX" ;;
4813     *) break ;;
4814   esac
4815 done
4816 AC_SUBST(PREFIX)
4817
4818 AC_SUBST(exec_prefix)
4819 AC_SUBST(EXEC_PREFIX_USER_DEFINED)
4820 EXEC_PREFIX=$exec_prefix
4821 while true; do
4822   case "$EXEC_PREFIX" in
4823     *\$* ) eval "EXEC_PREFIX=$EXEC_PREFIX" ;;
4824     *) break ;;
4825   esac
4826 done
4827 AC_SUBST(EXEC_PREFIX)
4828
4829 AC_SUBST(infodir)
4830 AC_SUBST(INFODIR_USER_DEFINED)
4831 INFODIR=$infodir
4832 while true; do
4833   case "$INFODIR" in
4834     *\$* ) eval "INFODIR=$INFODIR" ;;
4835     *) break ;;
4836   esac
4837 done
4838 AC_SUBST(INFODIR)
4839
4840 AC_SUBST(infopath)
4841 AC_SUBST(INFOPATH_USER_DEFINED)
4842 INFOPATH=$infopath
4843 while true; do
4844   case "$INFOPATH" in
4845     *\$* ) eval "INFOPATH=$INFOPATH" ;;
4846     *) break ;;
4847   esac
4848 done
4849 AC_SUBST(INFOPATH)
4850
4851 AC_SUBST(package_path)
4852 AC_SUBST(PACKAGE_PATH_USER_DEFINED)
4853 PACKAGE_PATH=$package_path
4854 while true; do
4855   case "$PACKAGE_PATH" in
4856     *\$* ) eval "PACKAGE_PATH=$PACKAGE_PATH" ;;
4857     *) break ;;
4858   esac
4859 done
4860 AC_SUBST(PACKAGE_PATH)
4861
4862 AC_SUBST(lispdir)
4863 AC_SUBST(LISPDIR_USER_DEFINED)
4864 LISPDIR=$lispdir
4865 while true; do
4866   case "$LISPDIR" in
4867     *\$* ) eval "LISPDIR=$LISPDIR" ;;
4868     *) break ;;
4869   esac
4870 done
4871 AC_SUBST(LISPDIR)
4872
4873 AC_SUBST(moduledir)
4874 AC_SUBST(MODULEDIR_USER_DEFINED)
4875 MODULEDIR=$moduledir
4876 while true; do
4877   case "$MODULEDIR" in
4878     *\$* ) eval "MODULEDIR=$MODULEDIR" ;;
4879     *) break ;;
4880   esac
4881 done
4882 AC_SUBST(MODULEDIR)
4883
4884 AC_SUBST(sitelispdir)
4885 AC_SUBST(SITELISPDIR_USER_DEFINED)
4886 SITELISPDIR=$sitelispdir
4887 while true; do
4888   case "$SITELISPDIR" in
4889     *\$* ) eval "SITELISPDIR=$SITELISPDIR" ;;
4890     *) break ;;
4891   esac
4892 done
4893 AC_SUBST(SITELISPDIR)
4894
4895 AC_SUBST(sitemoduledir)
4896 AC_SUBST(SITEMODULEDIR_USER_DEFINED)
4897 SITEMODULEDIR=$sitemoduledir
4898 while true; do
4899   case "$SITEMODULEDIR" in
4900     *\$* ) eval "SITEMODULEDIR=$SITEMODULEDIR" ;;
4901     *) break ;;
4902   esac
4903 done
4904 AC_SUBST(SITEMODULEDIR)
4905
4906 AC_SUBST(etcdir)
4907 AC_SUBST(ETCDIR_USER_DEFINED)
4908 ETCDIR=$etcdir
4909 while true; do
4910   case "$ETCDIR" in
4911     *\$* ) eval "ETCDIR=$ETCDIR" ;;
4912     *) break ;;
4913   esac
4914 done
4915 AC_SUBST(ETCDIR)
4916
4917 AC_SUBST(docdir)
4918 AC_SUBST(DOCDIR_USER_DEFINED)
4919 DOCDIR=$docdir
4920 while true; do
4921   case "$DOCDIR" in
4922     *\$* ) eval "DOCDIR=$DOCDIR" ;;
4923     *) break ;;
4924   esac
4925 done
4926 AC_SUBST(DOCDIR)
4927
4928 AC_SUBST(archlibdir)
4929 AC_SUBST(ARCHLIBDIR_USER_DEFINED)
4930 ARCHLIBDIR=$archlibdir
4931 while true; do
4932   case "$ARCHLIBDIR" in
4933     *\$* ) eval "ARCHLIBDIR=$ARCHLIBDIR" ;;
4934     *) break ;;
4935   esac
4936 done
4937 AC_SUBST(ARCHLIBDIR)
4938
4939 AC_SUBST(docdir)
4940 AC_SUBST(bitmapdir)
4941 AC_SUBST(extra_objs)
4942
4943 dnl The following flags combine all the information from:
4944 dnl - command line options (user always gets priority)
4945 dnl - user environment variables
4946 dnl - determined by configure
4947 dnl - the s&m header files (required for ellcc)
4948 AC_SUBST(machfile)
4949 AC_SUBST(opsysfile)
4950 AC_SUBST(c_switch_general)
4951 AC_SUBST(c_switch_window_system)
4952 AC_SUBST(c_switch_all)
4953 AC_SUBST(ld_switch_general)
4954 AC_SUBST(ld_switch_window_system)
4955 AC_SUBST(ld_switch_all)
4956 AC_SUBST(ld_libs_general)
4957 AC_SUBST(ld_libs_window_system)
4958 AC_SUBST(ld_libs_all)
4959 AC_SUBST(CFLAGS)
4960 AC_SUBST(CPPFLAGS)
4961 AC_SUBST(LDFLAGS)
4962 RECURSIVE_MAKE_ARGS="\$(MFLAGS) CC='\$(CC)' CFLAGS='\$(CFLAGS)' LDFLAGS='\$(LDFLAGS)' CPPFLAGS='\$(CPPFLAGS)'"
4963 AC_SUBST(RECURSIVE_MAKE_ARGS)
4964
4965 AC_SUBST(native_sound_lib)
4966 AC_SUBST(sound_cflags)
4967 AC_SUBST(RANLIB)
4968 AC_SUBST(dynodump_arch)
4969
4970 dnl Preliminary support for using a different compiler for xemacs itself.
4971 dnl Useful for building XEmacs with a C++ or 64-bit compiler.
4972 : ${XEMACS_CC:=$CC}
4973 AC_SUBST(XEMACS_CC)
4974
4975 dnl The default is yes
4976 if test "$with_prefix" = "yes"; then
4977   AC_DEFINE(PREFIX_USER_DEFINED)
4978 fi
4979
4980 dnl The default is no
4981 if test "$with_site_lisp" = "no"; then
4982   AC_DEFINE(INHIBIT_SITE_LISP)
4983 fi
4984 dnl The default is yes
4985 if test "$with_site_modules" = "no"; then
4986   AC_DEFINE(INHIBIT_SITE_MODULES)
4987 fi
4988
4989 XE_SPACE(ac_configure_args, $ac_configure_args)
4990 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "$configuration")
4991 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "$ac_configure_args")
4992
4993 dnl Following are deprecated
4994
4995 null_string=""
4996 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE,     $null_string)
4997 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, $null_string)
4998 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,      $null_string)
4999 AC_DEFINE_UNQUOTED(LD_SWITCH_SITE,       $null_string)
5000 AC_DEFINE_UNQUOTED(C_SWITCH_SITE,        $null_string)
5001
5002 dnl Note: as a general rule, *only* define things here that are not
5003 dnl autodetected.  For things that are autodetected, define them
5004 dnl at the point where the autodetection occurs or would occur,
5005 dnl so that the user gets immediate feedback on the results of the
5006 dnl autodetection.
5007
5008 if   test "$GNU_MALLOC"         = "yes"; then AC_DEFINE(GNU_MALLOC)
5009 elif test "$with_system_malloc" = "yes"; then AC_DEFINE(USE_SYSTEM_MALLOC)
5010 elif test "$with_debug_malloc"  = "yes"; then AC_DEFINE(USE_DEBUG_MALLOC)
5011                                               AC_DEFINE(USE_SYSTEM_MALLOC)
5012 fi
5013 test "$with_i18n3"         = "yes" && AC_DEFINE(I18N3)
5014 test "$GCC"                = "yes" && AC_DEFINE(USE_GCC)
5015 test "$external_widget"    = "yes" && AC_DEFINE(EXTERNAL_WIDGET)
5016 test "$quick_build"        = "yes" && AC_DEFINE(QUICK_BUILD)
5017 test "$with_purify"        = "yes" && AC_DEFINE(PURIFY)
5018 test "$with_quantify"      = "yes" && AC_DEFINE(QUANTIFY)
5019 test "$with_pop"           = "yes" && AC_DEFINE(MAIL_USE_POP)
5020 test "$with_kerberos"      = "yes" && AC_DEFINE(KERBEROS)
5021 test "$with_hesiod"        = "yes" && AC_DEFINE(HESIOD)
5022 test "$use_union_type"     = "yes" && AC_DEFINE(USE_UNION_TYPE)
5023 test "$use_regex_malloc"   = "yes" && AC_DEFINE(REGEX_MALLOC)
5024 test "$pdump"              = "yes" && AC_DEFINE(PDUMP)
5025 test "$with_ipv6_cname"    = "yes" && AC_DEFINE(IPV6_CANONICALIZE)
5026
5027 dnl -------------------------------
5028 dnl Report on what we decided to do
5029 dnl -------------------------------
5030
5031 (
5032 dnl /etc/osversion is on SONY NEWS-OS
5033 if test -f /etc/osversion; then dnl SONY NEWS-OS
5034   echo "osversion: `cat /etc/osversion`"
5035 else
5036   echo "uname -a: `uname -a`"
5037 fi
5038 echo ""
5039 echo "$0 $quoted_arguments"
5040 ) > Installation
5041
5042 if test ! -z ${emacs_beta_version} ; then
5043   if test -z "${emacs_is_beta}" ; then
5044         xemacs_betaname=".${emacs_beta_version}"
5045   else
5046         xemacs_betaname="-b${emacs_beta_version}"
5047   fi
5048 else
5049   xemacs_betaname=""
5050 fi
5051
5052 dnl Start stdout redirection to '| tee -a Installation'
5053 (
5054 echo "
5055
5056 XEmacs ${emacs_major_version}.${emacs_minor_version}${xemacs_betaname} \"$xemacs_codename\" configured for \`$canonical'.
5057 "
5058 echo "
5059 Compilation / Installation:"
5060 echo "  Source code location:              $srcdir"
5061 echo "  Installation prefix:               $prefix"
5062 if test -n "$site_includes"; then
5063   echo "  Additional header files:           $site_includes"
5064 fi
5065 if test -n "$site_libraries"; then
5066   echo "  Additional libraries:              $site_libraries"
5067 fi
5068 if test -n "$site_prefixes"; then
5069   echo "  Additional prefixes:               $site_prefixes"
5070 fi
5071 if test -n "$runpath"; then
5072   echo "  Runtime library search path:       $runpath"
5073 fi
5074
5075 if test -n "$opsysfile"
5076 then echo "  Operating system description file: \`$opsysfile'"
5077 else echo "  Not using any operating system description file"
5078 fi
5079 if test -n "$machfile"
5080 then echo "  Machine description file:          \`$machfile'"
5081 else echo "  Not using any machine description file"
5082 fi
5083
5084 echo "  Compiler:                          $CC $CFLAGS"
5085 dnl Let's save some helpful-for-debugging info like compiler and libc versions..
5086 dnl First, see if it's gcc - the same check works everyplace...
5087 case "$CC" in
5088   gcc*) echo "  Compiler version:                  `$CC --version | sed 1q`"
5089         echo "  Compiler specs file:               `$CC -v 2>&1 | sed 's/.* \([[^ ]]\)/\1/' | sed 1q`"
5090         ;;
5091 dnl non-gcc machine-specific magic - contributions welcome
5092   *) case "$canonical" in
5093         *-*-aix*   ) 
5094           dnl Yes, it's this ugly for AIX...
5095           realcc=`which $CC`
5096           dnl Might be a symlink created by replaceCset command
5097           if test -L $realcc ; then
5098             ccdir=`dirname $realcc`
5099             ccprog=`/bin/ls -l $realcc | sed 's/.* \([[^ ]]\)/\1/'`
5100             dnl This doesn't handle ../../xlc type stuff, but I've not seen one...
5101             case $ccprog in
5102                 */*) realcc=$ccprog;;
5103                 *) realcc=$ccdir/$ccprog;;
5104             esac
5105           fi
5106           lpp=`lslpp -wqc $realcc | cut -f2 -d:`
5107           if test ! -z "$lpp" ; then
5108             lppstr=`lslpp -Lqc $lpp`
5109             lpplev=`echo "$lppstr" | cut -f3 -d:`
5110             lppdesc=`echo "$lppstr" | cut -f8 -d:`
5111           fi
5112           if test ! -z "$lpplev" ; then
5113             echo "  Compiler version:                  $lpp $lpplev - $lppdesc"
5114           else
5115             echo "  Compiler version:                  (unknown version)"
5116           fi
5117         ;;
5118         
5119         *-*-solaris*)
5120           ccvers=`$CC -V 2>&1 | sed 1q`
5121           if test ! -z "$ccvers" ; then
5122             echo "  Compiler version:                  $ccvers"
5123           fi
5124         ;;
5125
5126         alpha*-dec-osf*)
5127           ccvers=`$CC -V | tr '\n' ' '`
5128           if test ! -z "$ccvers" ; then
5129             echo "  Compiler version:                  $ccvers"
5130           fi
5131         ;;
5132
5133         mips-sgi-irix*)
5134           ccvers=`$CC -version`
5135           if test ! -z "$ccvers" ; then
5136             echo "  Compiler version:                  $ccvers"
5137           fi
5138         ;;
5139
5140         dnl Intel C++ Compiler on Linux
5141         i[[3-9]]86-pc-linux)
5142           ccvers=`$CC -V 2>&1 | sed -n 's@^Intel.*Version @@'p`
5143           if test ! -z "$ccvers" ; then
5144             echo "  Compiler version:                  $ccvers"
5145           fi
5146         ;;
5147           
5148         *) echo "  Compiler version:                  $CC on $canonical";;
5149   esac
5150 esac
5151
5152 echo "  Relocating allocator for buffers:  $rel_alloc"
5153 echo "  GNU version of malloc:             ${GNU_MALLOC}${GNU_MALLOC_reason}"
5154 case "$ld_switch_site" in
5155   *nocombreloc*) echo "  Linking with \`-z nocombreloc'.
5156     - Consider configuring with --pdump." ;;
5157 esac
5158
5159 dnl Now get the libc version - contributions welcome
5160 case "$canonical" in
5161         *-*-linux*) 
5162           if test -f /etc/redhat-release ; then
5163             echo "  libc:                              `rpm -q glibc`";
5164 dnl need a Debian and Suse check here...
5165           else
5166             echo "Need to guess glibc1/2/etc here";
5167           fi
5168         ;;
5169
5170         *-*-aix*) 
5171           echo "  libc:                              bos.rte.libc `lslpp -Lqc bos.rte.libc | cut -f3 -d:`" 
5172         ;;
5173
5174         *-*-solaris*)
5175           libc=`pkginfo -l SUNWcsl | grep VERSION: | awk '{print $2}'`
5176           echo "  libc:                              SUNWcsl $libc"
5177
5178         ;;
5179
5180         mips-sgi-irix*)
5181           echo "  IRIX version:                      `uname -sRm`'"
5182         ;;
5183           
5184
5185         alpha*-dec-osf*)
5186         dnl Another ugly case
5187           (cd /usr/.smdb.;
5188                 libc=` grep -h libc.so *.inv | awk '$9 == "f" {print $12}' | tr '\n' ','`
5189                 echo "  libc:                              $libc"
5190                 
5191           )
5192         ;;
5193
5194         *) echo "  libc:                              system-provided libc on $canonical" ;;
5195 esac
5196
5197
5198 echo "
5199 Window System:"
5200 if test "$with_msw" = "yes"; then
5201   echo "  Compiling in support for the Microsoft window system."
5202 fi
5203 if test "$with_x11" = "yes"; then
5204   echo "  Compiling in support for the X window system:"
5205   echo "    - X Windows headers location:                 $x_includes"
5206   echo "    - X Windows libraries location:               $x_libraries"
5207   if test "$with_xauth" != yes; then
5208     echo "    - Xau (X authority) not available."
5209   fi
5210   if test "$with_xmu" != yes; then
5211     echo "    - Xmu library not available; substituting equivalent routines."
5212   fi
5213   if test "$with_wmcommand" != no; then
5214     echo "    - Handling WM_COMMAND properly."
5215   fi
5216 fi
5217 if test "$need_motif" = "yes" ; then
5218   echo "  Compiling in support for Motif."
5219   if test "$have_lesstif" = "yes"; then
5220     echo "    - Using LessTif implementation."
5221   fi
5222   echo "  *WARNING*  Many versions of Motif are buggy, requiring workarounds."
5223   echo "             You are likely to experience slow redisplay."
5224   echo "             You may need to install vendor patches to Motif."
5225   echo "             See PROBLEMS for more information."
5226 fi
5227 if test "$need_athena" = "yes"; then
5228   echo "  Compiling in support for the Athena widget set:"
5229   echo "    - Athena headers location:                    $athena_h_path"
5230   echo "    - Athena library to link:                     $athena_lib"
5231 fi
5232 case "$with_menubars" in
5233   gtk   ) echo "  Using GTK menubars."   ;;
5234   lucid ) echo "  Using Lucid menubars." ;;
5235   motif ) echo "  Using Motif menubars."
5236           echo "  *WARNING*  The Motif menubar implementation is currently buggy."
5237           echo "             We recommend using the Lucid menubar instead."
5238           echo "             Re-run configure with --with-menubars='lucid'." ;;
5239     msw ) echo "  Using MS-Windows menubars." ;;
5240 esac
5241 case "$with_scrollbars" in
5242   gtk    ) echo "  Using GTK scrollbars."        ;;
5243   lucid  ) echo "  Using Lucid scrollbars."      ;;
5244   motif  ) echo "  Using Motif scrollbars."      ;;
5245   athena ) echo "  Using Athena scrollbars."     ;;
5246      msw ) echo "  Using MS-Windows scrollbars." ;;
5247 esac
5248 case "$with_dialogs" in
5249   gtk    ) echo "  Using GTK dialog boxes." ;;
5250   motif  ) echo "  Using Motif dialog boxes."
5251            if test "$unexec" = "unexaix.o"; then if test "`uname -v`" = 4 -a "`uname -r`" -ge 3; then
5252              echo "  *WARNING*  The Motif dialog boxes cause problems on AIX 4.3 and higher."
5253              echo "             We recommend using the Athena dialog boxes instead."
5254              echo "             Install libXaw and re-run configure with --with-dialogs='athena'."
5255              echo "             Read the PROBLEMS file for more information."
5256            fi; fi ;;
5257   athena ) echo "  Using Athena dialog boxes."     ;;
5258      msw ) echo "  Using MS-Windows dialog boxes." ;;
5259 esac
5260 case "$with_widgets" in
5261   gtk    ) echo "  Using GTK native widgets."        ;;
5262   motif  ) echo "  Using Motif native widgets."      ;;
5263   athena ) echo "  Using Athena native widgets."     ;;
5264      msw ) echo "  Using MS-Windows native widgets." ;;
5265 esac
5266 if test "$with_dragndrop" = yes; then
5267   echo "  Compiling in support for Drag'n'Drop (EXPERIMENTAL)."
5268   echo "    -  Drag'n'Drop prototype:                             $dragndrop_proto."
5269 fi
5270
5271 echo "
5272 TTY:"
5273 test "$with_ncurses" = yes && echo "  Compiling in support for ncurses."
5274 test "$with_gpm" = yes && echo "  Compiling in support for GPM (General Purpose Mouse)."
5275
5276 echo "
5277 Images:"
5278 test "$with_gif" = yes && echo "  Compiling in support for GIF  images (builtin)."
5279 if test "$with_xpm" = yes; then
5280   echo "  Compiling in support for XPM  images."
5281 elif test "$with_x11" = yes; then
5282   echo "  WARNING: -----------------------------------------------------------"
5283   echo "  WARNING: Compiling without XPM image support."
5284   if test "$xpm_problem" != ""; then
5285     echo "  Reason: $xpm_problem"
5286   fi
5287   echo "  WARNING: You should strongly consider installing XPM."
5288   echo "  WARNING: Otherwise toolbars and other graphics will look suboptimal."
5289   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
5290   echo "  WARNING: -----------------------------------------------------------"
5291 fi
5292 if test "$with_png" = yes; then
5293   echo "  Compiling in support for PNG  images."
5294 elif test "$window_system" != "none"; then
5295   echo "  WARNING: -----------------------------------------------------------"
5296   echo "  WARNING: Compiling without PNG image support."
5297   if test "$png_problem" != ""; then
5298     echo "  Reason: $png_problem"
5299   fi
5300   echo "  WARNING: You should strongly consider installing the PNG libraries."
5301   echo "  WARNING: Otherwise certain images and glyphs may not display."
5302   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
5303   echo "  WARNING: -----------------------------------------------------------"
5304 fi
5305 test "$with_jpeg" = yes && echo "  Compiling in support for JPEG images."
5306 test "$with_tiff" = yes && echo "  Compiling in support for TIFF images."
5307 test "$with_xface" = yes && echo "  Compiling in support for X-Face message headers."
5308
5309 echo "
5310 Sound:"
5311 test "$with_native_sound" = yes && echo "  Compiling in support for sound (native)."
5312 test "$with_nas_sound" = yes && echo "  Compiling in support for NAS (network audio system)."
5313 test "$old_nas" = yes && echo "    - NAS library lacks error trapping; will play synchronously."
5314 test "$with_esd_sound" = yes && echo "  Compiling in support for ESD (Enlightened Sound Daemon)."
5315
5316 echo "
5317 Databases:"
5318 test "$with_database_berkdb" = yes && echo "  Compiling in support for Berkeley database."
5319 test "$with_database_dbm"    = yes && echo "  Compiling in support for DBM."
5320 test "$with_database_gdbm"   = yes && echo "  Compiling in support for GNU DBM."
5321 test "$with_ldap" = yes && echo "  Compiling in support for LDAP."
5322 if test "$with_postgresql" = yes; then
5323   echo "  Compiling in support for PostgreSQL."
5324   echo "    - Using PostgreSQL header file:  $libpq_fe_h_file"
5325   test "$with_postgresqlv7" = yes && echo "    - Using PostgreSQL V7 bindings."
5326 fi
5327
5328 echo "
5329 Internationalization:"
5330 test "$with_mule" = yes && echo "  Compiling in support for Mule (multi-lingual Emacs)."
5331 test "$with_file_coding" = yes && echo "  Compiling in support for file coding."
5332 test "$with_xim" != no && echo "  Compiling in support for XIM (X11R5+ I18N input method)."
5333 test "$with_xim" = motif && echo "    - Using Motif to provide XIM support."
5334 test "$with_xim" = xlib && echo "    - Using raw Xlib to provide XIM support."
5335 test "$with_xfs" = yes && echo "    - Using XFontSet to provide bilingual menubar."
5336 test "$with_canna" = yes && echo "  Compiling in support for Canna on Mule."
5337 if test "$with_wnn" = yes; then
5338   echo "  Compiling in support for the WNN input method on Mule."
5339   test "$with_wnn6" = yes && echo "    - Using WNN version 6."
5340 fi
5341 test "$with_i18n3" = yes && echo "  Compiling in support for I18N level 3 (doesn't currently work)."
5342
5343 echo "
5344 Mail:"
5345 test "$with_pop" = yes && echo "  Compiling in support for POP mail retrieval."
5346 test "$with_kerberos" = yes && echo "  Compiling in support for Kerberos POP authentication."
5347 test "$with_hesiod" = yes && echo "  Compiling in support for Hesiod POP server access."
5348 test -n "$mail_locking" && echo "  Compiling in support for \"$mail_locking\" mail spool file locking method."
5349
5350 echo "
5351 Other Features:"
5352 test "$with_ipv6_cname" = no && echo "  Inhibiting IPv6 canonicalization at startup."
5353 test "$with_tooltalk" = yes && echo "  Compiling in support for ToolTalk."
5354 test "$with_workshop" = yes && echo "  Compiling in support for Sun WorkShop."
5355 test "$with_socks" = yes && echo "  Compiling in support for SOCKS."
5356 test "$with_dnet" = yes && echo "  Compiling in support for DNET."
5357 test "$with_modules" = "yes" && echo "  Compiling in support for dynamic shared object modules."
5358 if test "$use_union_type" = yes; then
5359   echo "  WARNING: ---------------------------------------------------------"
5360   echo "  Using the union type for Lisp_Objects."
5361   echo "  Union type has been implicated in hard-to-debug runtime crashes."
5362   echo "  Do NOT use this build of XEmacs for ordinary work.  See PROBLEMS."
5363   echo "  WARNING: ---------------------------------------------------------"
5364 fi
5365 if test "$use_regex_malloc" = no; then
5366   echo "  WARNING: -----------------------------------------------------------"
5367   echo "  Using alloca to allocate the failure stack."
5368   echo "  It may be impossible to detect stack exhaustion, and you will crash."
5369   echo "  Do NOT use this build of XEmacs for ordinary work."
5370   echo "  WARNING: -----------------------------------------------------------"
5371 fi
5372 test "$pdump" = yes && echo "  Using the new portable dumper."
5373 test "$debug" = yes && echo "  Compiling in support for extra debugging code."
5374 test "$usage_tracking" = yes && echo "  Compiling in support for active usage tracking (Sun internal)."
5375 if test "$error_check_extents $error_check_typecheck $error_check_bufpos $error_check_gc $error_check_malloc $error_check_glyphs" \
5376   != "no no no no no no"; then
5377   echo "  WARNING: ---------------------------------------------------------"
5378   echo "  WARNING: Compiling in support for runtime error checking."
5379   echo "  WARNING: XEmacs will run noticeably more slowly as a result."
5380   echo "  WARNING: Error checking is on by default for XEmacs beta releases."
5381   echo "  WARNING: ---------------------------------------------------------"
5382 fi
5383 echo ""
5384 ) | tee -a Installation
5385 dnl echo "The above configure report is appended to \"Installation\" file."
5386 echo ""
5387
5388 dnl -----------------------------------
5389 dnl Now generate config.h and Makefiles
5390 dnl -----------------------------------
5391 dnl This has to be called in order for this variable to get into config.status
5392 AC_SUBST(internal_makefile_list)
5393 # Remove any trailing slashes in these variables.
5394 test -n "$prefix" &&
5395   prefix=`echo '' "$prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
5396 test -n "$exec_prefix" &&
5397   exec_prefix=`echo '' "$exec_prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
5398
5399 dnl Build Makefile.in's from Makefile.in.in's
5400 dnl except ./Makefile from $srcdir/Makefile.in
5401
5402 for file in $internal_makefile_list; do
5403   test "$file" = src/Makefile.in && \
5404     file="src/Makefile.in:src/Makefile.in.in:src/depend"
5405   XE_APPEND($file, ac_output_files)
5406 done
5407 ac_output_files="$ac_output_files src/paths.h lib-src/config.values"
5408 test "$with_modules" = "yes" && XE_APPEND(lib-src/ellcc.h, ac_output_files)
5409
5410 AC_OUTPUT($ac_output_files,
5411 [for dir in . $MAKE_SUBDIR; do
5412   (
5413     cd $dir
5414     rm -f junk.c
5415     < Makefile.in \
5416       sed -e '/^# Generated/d' \
5417           -e 's%/\*\*/#.*%%' \
5418           -e 's/^ *# */#/' \
5419 dnl Delete Makefile.in.in comment lines
5420           -e '/^##/d' \
5421 dnl Pass through CPP directives unchanged
5422           -e '/^#/ {
5423 p
5424 d
5425 }'        \
5426 dnl Quote other lines to protect from CPP substitution
5427           -e '/./ {
5428 s/\([[\"]]\)/\\\1/g
5429 s/^/"/
5430 s/$/"/
5431 }'  > junk.c;
5432
5433 dnl Create a GNUmakefile and Makefile from Makefile.in.
5434
5435 changequote(<<,>>)dnl
5436 dnl CPP_MAKEFILE(CPPFLAGS,filename)
5437 define(<<CPP_MAKEFILE>>,
5438 echo creating $dir/<<$2>>
5439 $CPP -I. -I${top_srcdir}/src <<$1>> junk.c \
5440 dnl Delete line directives inserted by $CPP
5441   | sed -e 's/^\#.*//'          \
5442 dnl Delete spurious blanks inserted by $CPP
5443         -e 's/^[ TAB][ TAB]*$//'\
5444         -e 's/^ /TAB/'          \
5445 dnl Delete blank lines
5446         -e '/^[ \f]*$/d' \
5447 dnl Restore lines quoted above to original contents.
5448         -e '/^\"/ {
5449         s/\\\([\"]\)/\1/g
5450         s/^[ TAB]*\"//
5451         s/\"[ TAB]*$//
5452 }' > Makefile.new
5453     chmod 444 Makefile.new
5454     mv -f Makefile.new <<$2>>
5455 )dnl CPP_MAKEFILE
5456
5457     CPP_MAKEFILE(,Makefile)
5458     CPP_MAKEFILE(-DUSE_GNU_MAKE,GNUmakefile)
5459 changequote([,])dnl
5460     rm -f junk.c
5461   )
5462 done
5463
5464 dnl Append AC_DEFINE information to lib-src/config.values
5465 dnl (AC_SUBST information is already there (see config.values.sh).
5466 sed < config.status >> lib-src/config.values \
5467   -e '/{ac_dA}.*{ac_dB}.*{ac_dC}.*{ac_dD}$/!d' \
5468   -e 's/\${ac_dA}\(.*\)\${ac_dB}.*\${ac_dC}\(.*\)\${ac_dD}/\1 \2/' \
5469   -e 's/^\([[^ ]]*\) $/\1 ""/' \
5470   -e 's/ 1$/ t/'
5471
5472 ],
5473 [CPP="$CPP"
5474  top_srcdir="$srcdir"
5475  MAKE_SUBDIR="$MAKE_SUBDIR"
5476 ])dnl