git.chise.org Git - chise/xemacs-chise.git.1/blob - configure.in

   1 dnl Define our own header notice with own copyright
   2 define([AC_INIT_NOTICE],
   3 [#### Configuration script for XEmacs.  Largely divergent from FSF.
   4 #### Guess values for system-dependent variables and create Makefiles.
   5 #### Generated automatically using autoconf version] AC_ACVERSION [
   6 #### Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000 Free Software Foundation, Inc.
   7 #### Copyright (C) 1993-1995 Board of Trustees, University of Illinois.
   8 #### Copyright (C) 1996, 1997 Sun Microsystems, Inc.
   9 #### Copyright (C) 1995, 1996 Ben Wing.
  10 #### Copyright (C) 2000, 2001 Martin Buchholz.
  11 #### Copyright (C) 1998, 1999 J. Kean Johnston.
  12
  13 ### Don't edit this script!
  14 ### This script was automatically generated by the `autoconf' program
  15 ### from the file `./configure.in'.
  16 ### To rebuild it, execute the command
  17 ###     autoconf
  18 ### in the this directory.  You must have autoconf version 2.13 or later.
  19 ### Note: this script has not yet been ported to autoconf version 2.5x.
  20
  21 ### This file is part of XEmacs.
  22
  23 ### XEmacs is free software; you can redistribute it and/or modify it
  24 ### under the terms of the GNU General Public License as published by
  25 ### the Free Software Foundation; either version 2, or (at your
  26 ### option) any later version.
  27
  28 ### XEmacs is distributed in the hope that it will be useful, but
  29 ### WITHOUT ANY WARRANTY; without even the implied warranty of
  30 ### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  31 ### General Public License for more details.
  32
  33 ### You should have received a copy of the GNU General Public License
  34 ### along with XEmacs; see the file COPYING.  If not, write to the Free
  35 ### Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  36 ### 02111-1307, USA.
  37
  38 ### For usage, run `./configure --help'
  39 ### For more detailed information on building and installing XEmacs,
  40 ### read the file `INSTALL'.
  41 ###
  42 ### If configure succeeds, it leaves its status in config.status.
  43 ### A log of configuration tests can be found in config.log.
  44 ### If configure fails after disturbing the status quo,
  45 ###     config.status is removed.
  46 ])
  47
  48 dnl Since XEmacs has configuration requirements that autoconf cannot
  49 dnl meet, this file is an unholy marriage of custom-baked
  50 dnl configuration code and autoconf macros.
  51
  52 dnl We use the m4 quoting characters [ ] (as established by the
  53 dnl autoconf system), so quote them like this: [[foo]]
  54
  55 AC_PREREQ(2.13)dnl
  56 dnl Redefine some standard autoconf macros
  57 dnl here is how XEmacs is different:
  58 dnl - no cache file
  59 dnl - non-standard options
  60 dnl - support for extra-verbosity
  61 dnl - ordinary libs are handled separately from X libs (might be a mistake)
  62 dnl - various random kludges (e.g. -with-dnet=no)
  63
  64 dnl PRINT_VAR(var var ...)  prints values of shell variables
  65 define([PRINT_VAR],[for var in patsubst([$1],[[
  66 ]+],[ ]); do eval "echo \"$var = '\$$var'\""; done])
  67
  68 dnl Disable cache files:
  69 dnl This is controversial, but I am convinced this is the right way to go,
  70 dnl at least by default.  Otherwise there are too many surprises.
  71 define([AC_CACHE_LOAD], )dnl
  72 define([AC_CACHE_SAVE], )dnl
  73 define([AC_CACHE_VAL], [
  74 $2
  75 ])dnl
  76
  77 dnl Redefine AC_TRY_RUN_NATIVE to not throw away stderr while running
  78 dnl AC_TRY_RUN_NATIVE(PROGRAM, [ACTION-IF-TRUE [, ACTION-IF-FALSE]])
  79 define([AC_TRY_RUN_NATIVE],
  80 [cat > conftest.$ac_ext <<EOF
  81 [#]line __oline__ "configure"
  82 #include "confdefs.h"
  83 [$1]
  84 EOF
  85 if AC_TRY_EVAL(ac_link) && test -s conftest && (./conftest; exit $?) 2>&AC_FD_CC
  86 then
  87 dnl Do not remove the temporary files here, so they can be examined.
  88   ifelse([$2], , :, [$2])
  89 else
  90   conftest_rc="$?"
  91   echo "configure: failed program was:" >&AC_FD_CC
  92   cat conftest.$ac_ext >&AC_FD_CC
  93 ifelse([$3], , , [  rm -fr conftest*
  94   $3
  95 ])dnl
  96 fi
  97 rm -fr conftest*])dnl AC_TRY_RUN_NATIVE
  98
  99
 100 dnl Avoid spurious cross-compiling warnings from AC_TRY_RUN
 101 dnl XEmacs is unlikely to ever cross-compile
 102 define([AC_TRY_RUN],[AC_TRY_RUN_NATIVE([$1], [$2], [$3])])dnl
 103
 104 dnl Redefine AC_DEFINE* to provide more output if extra_verbose
 105 dnl Set VARIABLE to VALUE, verbatim, or 1.
 106 dnl AC_DEFINE(VARIABLE [, VALUE])
 107 define([AC_DEFINE],
 108 [{ test "$extra_verbose" = "yes" && cat << \EOF
 109     Defining $1[]ifelse($#, 2, [ = $2],)
 110 EOF
 111 cat >> confdefs.h <<\EOF
 112 [#define] $1 ifelse($#, 2, [$2], 1)
 113 EOF
 114 }
 115 ])dnl AC_DEFINE
 116
 117 define([AC_DEFINE_UNQUOTED],
 118 [{ test "$extra_verbose" = "yes" && cat << EOF
 119     Defining $1[]ifelse($#, 2, [ = $2],)
 120 EOF
 121 cat >> confdefs.h <<EOF
 122 [#define] $1 ifelse($#, 2, [$2], 1)
 123 EOF
 124 }
 125 ])dnl AC_DEFINE_UNQUOTED
 126
 127 dnl redefine AC_CHECK_LIB in accordance with our own value of ac_link
 128 dnl Add in extra kludgy check to support with_dnet=no
 129 dnl Add in extra LDFLAGS arg, which PRECEDES libs
 130 dnl Support --with-dnet=no
 131
 132 dnl AC_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND
 133 dnl             [, OTHER-LIBRARIES] [, LDFLAGS]]]])
 134 define([AC_CHECK_LIB],
 135 [ifelse([$1],dnet, [if test "$with_dnet" = "no" ; then
 136 ac_cv_lib_dnet_dnet_ntoa=no
 137 ifelse([$4], , , [$4]
 138 )dnl
 139 else
 140 ])]
 141 AC_CHECK_LIB_ORIG_HACKED([$1],[$2],[$3],[$4],[$5], [$6])
 142 [ifelse([$1],dnet,[fi
 143 ])]dnl
 144 )dnl AC_CHECK_LIB
 145
 146 define([AC_CHECK_LIB_ORIG_HACKED],
 147 [ifelse([$5],,AC_MSG_CHECKING([for $2 in -l$1]),
 148 xe_msg_checking="for [$2] in -l[$1]"
 149 test -n "[$5]" && xe_msg_checking="$xe_msg_checking using extra libs [$5]"
 150 AC_MSG_CHECKING("$xe_msg_checking"))
 151 dnl Use a cache variable name containing both the library and function name,
 152 dnl because the test really is for library $1 defining function $2, not
 153 dnl just for library $1.  Separate tests with the same $1 and different $2s
 154 dnl may have different results.
 155 ac_lib_var=`echo $1['_']$2 | sed 'y%./+-%__p_%'`
 156 AC_CACHE_VAL(ac_cv_lib_$ac_lib_var,
 157 [xe_check_libs="$6 -l$1 $5"
 158 AC_TRY_LINK(dnl
 159 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
 160 [/* Override any gcc2 internal prototype to avoid an error.  */
 161 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
 162 extern "C"
 163 #endif
 164 ])dnl
 165 [/* We use char because int might match the return type of a gcc2
 166     builtin and then its argument prototype would still apply.  */
 167 char $2();
 168 ]),
 169             [$2()],
 170             eval "ac_cv_lib_$ac_lib_var=yes",
 171             eval "ac_cv_lib_$ac_lib_var=no")
 172 xe_check_libs=""
 173 ])dnl
 174 if eval "test \"`echo '$ac_cv_lib_'$ac_lib_var`\" = yes" ; then
 175   AC_MSG_RESULT(yes)
 176   ifelse([$3], ,
 177 [changequote(, )dnl
 178   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
 179     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
 180 changequote([, ])dnl
 181   AC_DEFINE_UNQUOTED($ac_tr_lib)
 182   XE_PREPEND([-l$1], LIBS)
 183 ], [$3])
 184 else
 185   AC_MSG_RESULT(no)
 186 ifelse([$4], , , [$4
 187 ])dnl
 188 fi
 189 ])dnl AC_CHECK_LIB_ORIG_HACKED
 190
 191
 192 dnl AC_LANG_C()
 193 define([AC_LANG_C],
 194 [define([AC_LANG], [C])dnl
 195 ac_ext=c
 196 dnl CFLAGS is not in ac_cpp because -g, -O, etc. are not valid cpp options.
 197 dnl ac_cpp='$CPP $CPPFLAGS'
 198 dnl ac_compile='${CC-cc} -c $CFLAGS $CPPFLAGS conftest.$ac_ext 1>&AC_FD_CC'
 199 dnl ac_link='${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS conftest.$ac_ext $LIBS 1>&AC_FD_CC'
 200 xe_cppflags='$CPPFLAGS $c_switch_site $c_switch_machine $c_switch_system $c_switch_x_site $X_CFLAGS'
 201 xe_ldflags='$LDFLAGS $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_x_site $ld_switch_run'
 202 xe_libs='$ld_call_shared $xe_check_libs $X_EXTRA_LIBS $libs_x $libs_gtk $X_PRE_LIBS $LIBS $libs_machine $libs_system $libs_standard'
 203 ac_cpp='$CPP '"$xe_cppflags"
 204 ac_compile='${CC-cc} -c $CFLAGS '"$xe_cppflags"' conftest.$ac_ext 1>&AC_FD_CC'
 205 ac_link='${CC-cc} -o conftest $CFLAGS '"$xe_cppflags $xe_ldflags"' conftest.$ac_ext '"$xe_libs"' 1>&AC_FD_CC'
 206 cross_compiling=no
 207 ]) dnl AC_LANG_C
 208
 209 dnl The construct foo=`echo $w1 $w2 $w3` fails on some systems if $w1 = -e or -n
 210 dnl So we use the following instead.
 211 dnl XE_SPACE(var, words)
 212 define([XE_SPACE],[
 213 T=""
 214 for W in $2; do if test -z "$T"; then T="$W"; else T="$T $W"; fi; done
 215 $1="$T"
 216 ])dnl XE_SPACE
 217
 218 dnl XE_ADD_OBJS(foo.o ...)
 219 define([XE_ADD_OBJS],
 220 [extra_objs="$extra_objs [$1]" && dnl
 221  if test "$extra_verbose" = "yes"; then
 222    echo "    xemacs will be linked with \"[$1]\""
 223  fi])dnl XE_ADD_OBJS
 224
 225 dnl XE_APPEND(value, varname)
 226 define([XE_APPEND],
 227 [[$2]="$[$2] [$1]" && dnl
 228  if test "$extra_verbose" = "yes"; then echo "    Appending \"[$1]\" to \$[$2]"; fi])
 229
 230 dnl XE_PREPEND(value, varname)
 231 define([XE_PREPEND],
 232 [[$2]="[$1] $[$2]" && dnl
 233  if test "$extra_verbose" = "yes"; then echo "    Prepending \"[$1]\" to \$[$2]"; fi])
 234
 235 dnl XE_DIE(message)
 236 define([XE_DIE], [{ echo "Error:" $1 >&2; exit 1; }])
 237
 238 dnl XE_STRIP_4TH_COMPONENT(var)
 239 dnl Changes i986-pc-linux-gnu to i986-pc-linux, as God (not RMS) intended.
 240 define([XE_STRIP_4TH_COMPONENT],
 241 [$1=`echo "$$1" | sed '[s/^\([^-][^-]*-[^-][^-]*-[^-][^-]*\)-.*$/\1/]'`])
 242
 243 dnl Initialize some variables set by options.
 244 dnl The variables have the same names as the options, with
 245 dnl dashes changed to underlines.
 246
 247 define([AC_INIT_PARSE_ARGS],[
 248
 249 dnl Get sane consistent behavior from various shells
 250 dnl Avoid losing with weird user CDPATHs
 251
 252 if test -n "$ZSH_VERSION"; then
 253   dnl zsh's Bourne shell emulation options
 254   setopt NO_BAD_PATTERN NO_BANG_HIST NO_BG_NICE NO_EQUALS NO_FUNCTION_ARGZERO
 255   setopt GLOB_SUBST NO_HUP INTERACTIVE_COMMENTS KSH_ARRAYS NO_MULTIOS NO_NOMATCH
 256   setopt RM_STAR_SILENT POSIX_BUILTINS SH_FILE_EXPANSION SH_GLOB SH_OPTION_LETTERS
 257   setopt SH_WORD_SPLIT BSD_ECHO IGNORE_BRACES
 258   dnl zsh-3.1-beta drops core on the following
 259   dnl unset CDPATH
 260   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
 261 elif test -n "$BASH_VERSION"; then
 262   dnl Use Posix mode with bash
 263   set -o posix
 264   unset CDPATH
 265 else
 266   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
 267 fi
 268
 269 dnl Initialize some variables set by options.
 270 dnl The variables have the same names as the options, with
 271 dnl dashes changed to underlines.
 272 exec_prefix=NONE
 273 host=NONE
 274 no_create=
 275 nonopt=NONE
 276 no_recursion=
 277 prefix=NONE
 278 program_prefix=NONE
 279 program_suffix=NONE
 280 program_transform_name=s,x,x,
 281 silent=
 282 site=
 283 srcdir=
 284 target=NONE
 285 verbose=
 286 x_includes=NONE
 287 x_libraries=NONE
 288
 289 dnl Initialize some other variables.
 290 subdirs=
 291 MFLAGS= MAKEFLAGS=
 292 SHELL=${CONFIG_SHELL-/bin/sh}
 293 dnl Maximum number of lines to put in a shell here document.
 294 ac_max_here_lines=12
 295 ])dnl AC_INIT_PARSE_ARGS
 296
 297 AC_INIT(src/lisp.h)dnl
 298 AC_CONFIG_HEADER(src/config.h lwlib/config.h)
 299 dnl Remove any more than one leading "." element from the path name.
 300 dnl If we do not remove them, then another "./" will be prepended to
 301 dnl the file name each time we use config.status, and the program name
 302 dnl will get larger and larger.  This would not be a problem, except
 303 dnl that since progname gets recorded in all the Makefiles this script
 304 dnl produces, move-if-change thinks they're different when they're
 305 dnl not.
 306 dnl
 307 dnl It would be nice if we could put the ./ in a \( \) group and then
 308 dnl apply the * operator to that, so we remove as many leading './././'s
 309 dnl as are present, but some seds (like Ultrix's sed) don't allow you to
 310 dnl apply * to a \( \) group.  Bleah.
 311 progname="`echo $0 | sed 's:^\./\./:\./:'`"
 312
 313 dnl -----------------------------
 314 dnl Establish some default values
 315 dnl -----------------------------
 316
 317 XE_APPEND(lib-src, MAKE_SUBDIR)
 318 XE_APPEND(lib-src, INSTALL_ARCH_DEP_SUBDIR)
 319
 320 prefix='/usr/local'
 321 exec_prefix='${prefix}'
 322 bindir='${exec_prefix}/bin'
 323 dnl FSF 19.29 changes to:
 324 dnl datadir='${prefix}/share'
 325 dnl sharedstatedir='${prefix}/com'
 326 dnl libexecdir='${exec_prefix}/libexec'
 327 datadir='${prefix}/lib'
 328 statedir='${prefix}/lib'
 329 libdir='${exec_prefix}/lib'
 330 mandir='${prefix}/man/man1'
 331 inststaticdir='${PROGNAME}'
 332 instvardir='${PROGNAME}-${version}'
 333 infodir='${datadir}/${instvardir}/info'
 334 infopath=''
 335 install_pp=''
 336 lispdir='${datadir}/${instvardir}/lisp'
 337 moduledir='${libdir}/${instvardir}/${configuration}/modules'
 338 sitelispdir='${datadir}/${inststaticdir}/site-lisp'
 339 sitemoduledir='${libdir}/${inststaticdir}/site-modules'
 340 pkgdir='${datadir}/${instvardir}/lisp'
 341 package_path=''
 342 etcdir='${datadir}/${instvardir}/etc'
 343 archlibdir='${libdir}/${instvardir}/${configuration}'
 344 docdir='${archlibdir}'
 345 with_netinstall="no"
 346 with_prefix='yes'
 347 with_site_lisp='no'
 348 with_site_modules='yes'
 349 with_menubars=''
 350 with_scrollbars=''
 351 with_widgets=''
 352 with_dialogs=''
 353 with_file_coding=''
 354 cpp='' cppflags='' libs='' ldflags=''
 355 extra_includes=''
 356 dynamic=''
 357 with_x11=''
 358 with_msw=''
 359 rel_alloc='default'
 360 with_system_malloc='default'
 361 with_dlmalloc='default'
 362 dnl ESD is associated with crashes and lockups due to incorrect signal use.
 363 with_esd_sound='no'
 364 native_sound_lib=''
 365 dnl These should be set to the empty string when we want gtk / gnome to
 366 dnl be auto-detected instead of manually specified.
 367 with_gtk='no'
 368 with_gnome='no'
 369 dnl use_assertions should be 'yes' by default.  Too many people in this
 370 dnl world have core dumps turned off by default or \"cannot find where the
 371 dnl core file went\".  At least we should get some useful output ...
 372 use_assertions="yes"
 373 dnl the following is set to yes or no later.
 374 with_toolbars=""
 375 with_tty=""
 376 use_union_type="no"
 377 with_dnet=""
 378 pdump="no"
 379 dnl dragndrop is still experimental.  When it is stable, comment out the following line:
 380 with_dragndrop="no"
 381 dnl Too annoying, even if mandated by IPv6 (and I'm not even sure of that)
 382 with_ipv6_cname="no"
 383
 384 dnl ------------------
 385 dnl Options Processing
 386 dnl ------------------
 387
 388 define([USAGE_ERROR],
 389 [(echo "$progname: Usage error:"
 390 echo " " $1
 391 echo "  Use \`$progname --help' to show usage.") >&2 && exit 1])
 392
 393 dnl Record all the arguments, so we can save them in config.status.
 394 arguments="$@"
 395
 396 dnl Shell Magic: Quote the quoted arguments in ARGUMENTS.  At a later date,
 397 dnl in order to get the arguments back in $@, we have to do an
 398 dnl 'eval set x "$quoted_arguments"; shift'
 399 dnl # We use sed to turn embedded ' into '"'"'.  I truly hate sh quoting.
 400 quoted_sed_magic=s/"'"/"'"'"'"'"'"'"'"/g
 401 quoted_arguments=
 402 for i in "$@"; do
 403    case "$i" in
 404    -no-create | --no-create | --no-creat | --no-crea | --no-cre \
 405    | --no-cr | --no-c) ;;
 406    -no-recursion | --no-recursion | --no-recursio | --no-recursi \
 407    | --no-recurs | --no-recur | --no-recu | --no-rec | --no-re | --no-r) ;;
 408    *)
 409    quoted_i="`echo '' $i | sed -e 's:^ ::' -e $quoted_sed_magic`"
 410    quoted_arguments="$quoted_arguments '$quoted_i'" ;;
 411    esac
 412 done
 413
 414 dnl Do not use shift -- that destroys the argument list, which autoconf needs
 415 dnl to produce config.status.  It turns out that "set - $arguments" does not
 416 dnl work portably.
 417 dnl However, it also turns out that many shells cannot expand ${10} at all.
 418 dnl So using an index variable does not work either.  It is possible to use
 419 dnl some shell magic to make 'set x "$arguments"; shift' work portably.
 420 while test $# != 0; do
 421   arg="$1"; shift
 422   case "$arg" in
 423     --no-create|--no-recursion) ;;
 424     dnl Anything starting with a hyphen we assume is an option.
 425     -* )
 426       dnl Separate the switch name from the value it is being given.
 427       case "$arg" in
 428         -*=*)
 429           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\([[^=]]*\)=.*$:\1:'`
 430           val=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*[[^=]]*=\(.*\)$:\1:'`
 431           valomitted=no
 432         ;;
 433            dnl special case these strings since echo may silently eat them:
 434            dnl --help ) opt=help val=yes valomitted=yes ;;
 435            dnl --version ) opt=version val=yes valomitted=yes ;;
 436            dnl -e ) opt=e val=yes valomitted=yes ;;
 437            dnl -E ) opt=E val=yes valomitted=yes ;;
 438            dnl -n ) opt=n val=yes valomitted=yes ;;
 439         -*)
 440            dnl If FOO is a boolean argument, --FOO is equivalent to
 441            dnl --FOO=yes.  Otherwise, the value comes from the next
 442            dnl argument - see below.
 443           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\(.*\)$:\1:'`
 444           val="yes" valomitted=yes
 445         ;;
 446       esac
 447
 448       dnl translate "-" in option string to "_"
 449       optname="$opt"
 450       opt="`echo '' $opt | sed -e 's:^ ::' | tr - _`"
 451
 452       dnl Support --without-FOO as a synonym for --with-FOO=no
 453       case "${valomitted}-${opt}" in yes-without_* )
 454         opt=`echo $opt | sed 's/without/with/'`
 455         valomitted="no" val="no" ;;
 456       esac
 457
 458       dnl Process the option.
 459       case "$opt" in
 460
 461       dnl Process (many) boolean options
 462         with_site_lisp  | \
 463         with_prefix     | \
 464         with_site_modules | \
 465         with_x          | \
 466         with_x11        | \
 467         with_gtk        | \
 468         with_gnome      | \
 469         with_msw        | \
 470         with_gcc        | \
 471         dynamic         | \
 472         with_ncurses    | \
 473         with_dnet       | \
 474         with_socks      | \
 475         with_dragndrop  | \
 476         with_cde        | \
 477         with_offix      | \
 478         with_gpm        | \
 479         with_xpm        | \
 480         with_xface      | \
 481         with_gif        | \
 482         with_jpeg       | \
 483         with_png        | \
 484         with_tiff       | \
 485         with_wmcommand  | \
 486         with_xmu        | \
 487         with_purify     | \
 488         with_quantify   | \
 489         with_toolbars   | \
 490         with_tty        | \
 491         with_xfs        | \
 492         with_i18n3      | \
 493         with_mule       | \
 494         with_file_coding| \
 495         with_canna      | \
 496         with_wnn        | \
 497         with_wnn6       | \
 498         with_workshop   | \
 499         with_sparcworks | \
 500         with_tooltalk   | \
 501         with_ldap       | \
 502         with_postgresql | \
 503         with_pop        | \
 504         with_kerberos   | \
 505         with_hesiod     | \
 506         with_dnet       | \
 507         with_infodock   | \
 508         with_netinstall | \
 509         with_ipv6_cname | \
 510         external_widget | \
 511         verbose         | \
 512         extra_verbose   | \
 513         usage_tracking  | \
 514         use_union_type  | \
 515         pdump           | \
 516         debug           | \
 517         use_assertions  | \
 518         memory_usage_stats | \
 519         with_clash_detection | \
 520         with_modules | \
 521         quick_build )
 522           dnl Make sure the value given was either "yes" or "no".
 523           case "$val" in
 524             y | ye | yes )      val=yes ;;
 525             n | no )            val=no  ;;
 526             * ) USAGE_ERROR("The \`--$optname' option requires a boolean value: \`yes' or \`no'.") ;;
 527           esac
 528           eval "$opt=\"$val\"" ;;
 529
 530
 531         dnl Options that take a user-supplied value, as in --x-includes=/usr/X11R6/include
 532         dnl The cache-file option is ignored (for compatibility with other configures)
 533         srcdir          | \
 534         compiler        | \
 535         cflags          | \
 536         cpp             | \
 537         cppflags        | \
 538         libs            | \
 539         ldflags         | \
 540         cache_file      | \
 541         native_sound_lib| \
 542         site_lisp       | \
 543         x_includes      | \
 544         x_libraries     | \
 545         site_includes   | \
 546         site_libraries  | \
 547         site_prefixes   | \
 548         site_runtime_libraries )
 549           dnl If the value was omitted, get it from the next argument.
 550           if test "$valomitted" = "yes" ; then
 551             dnl Get the next argument from the argument list, if there is one.
 552             if test "$#" = 0 ; then
 553               USAGE_ERROR("The \`--$optname' option requires a value.");
 554             fi
 555             val="$1"; shift
 556           fi
 557           eval "$opt=\"$val\""
 558         ;;
 559
 560         dnl Options that take "yes", "no", or "default" values
 561         rel_alloc | \
 562         with_dlmalloc | \
 563         with_debug_malloc  | use_debug_malloc | \
 564         with_system_malloc | use_system_malloc )
 565           case "$val" in
 566             y | ye | yes )      val=yes ;;
 567             n | no )            val=no  ;;
 568             d | de | def | defa | defau | defaul | default ) val=default ;;
 569             * ) USAGE_ERROR(["The \`--$optname' option requires one of these values:
 570   \`yes', \`no', or \`default'."]) ;;
 571           esac
 572           case "$opt" in use_* ) opt="`echo $opt | sed s/use/with/`" ;; esac
 573           eval "$opt=\"$val\""
 574         ;;
 575
 576         dnl Has the user requested database support?
 577         "with_database" )
 578           with_database_berkdb=no
 579           with_database_dbm=no
 580           with_database_gdbm=no
 581           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 582             case "$x" in
 583               no ) ;;
 584               b | be | ber | berk | berkd | berkdb )       with_database_berkdb=yes ;;
 585               d | db | dbm )                               with_database_dbm=yes    ;;
 586               g | gn | gnu | gnud | gnudb | gnudbm | gdbm) with_database_gdbm=yes   ;;
 587               * ) USAGE_ERROR(["The \`--$optname' option value
 588   must be either \`no' or a comma-separated list
 589   of one or more of \`berkdb' and either \`dbm' or \`gnudbm'."]) ;;
 590             esac
 591           done
 592           if test "$with_database_dbm"  = "yes" -a \
 593                   "$with_database_gdbm" = "yes"; then
 594           USAGE_ERROR("Only one of \`dbm' and \`gnudbm' may be specified
 595   with the \`--$optname' option.")
 596           fi
 597         ;;
 598
 599         dnl Has the user requested sound support?
 600         "with_sound" )
 601         dnl values is a subset of all,native,nas,esd
 602         dnl or their negatives: none,nonative,nonas,noesd
 603           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 604             case "$x" in
 605               dnl all and none are only permitted as the first in the list.
 606               n | no | non | none ) new_sdefault=no ;;
 607               a | al | all | both ) new_sdefault=yes ;;
 608
 609               native )       with_native_sound=yes ;;
 610               nonative )     with_native_sound=no ;;
 611
 612               nas )          with_nas_sound=yes ;;
 613               nonas )        with_nas_sound=no ;;
 614
 615               esd )          with_esd_sound=yes ;;
 616               noesd )        with_esd_sound=no ;;
 617
 618               * ) bogus_sound=yes ;;
 619             esac
 620             if test "$bogus_sound" -o \
 621                  \( -n "$new_sdefault" -a -n "$sound_notfirst" \) ; then
 622                 types="\`all', \`none', \`(no)native', \`no(nas)', \`(no)esd'."
 623                 USAGE_ERROR(["Valid types for the \`--$optname' option are:
 624   $types.
 625 Option \`all' or \`none' must be first in the list.
 626 The default is to autodetect native and NAS sound support."])
 627             elif test -n "$new_sdefault" ; then
 628                 with_native_sound=$new_sdefault
 629                 with_nas_sound=$new_sdefault
 630                 with_esd_sound=$new_sdefault
 631                 new_sdefault=   # reset this
 632             fi
 633             sound_notfirst=true
 634           done
 635         ;;
 636
 637         dnl Has the user specified a preferred Athena widget set?
 638         dnl This bit expands any alias names out for us...
 639         "with_athena" )
 640           case "$val" in
 641             xa | xaw )                    val=xaw    ;;
 642             3 | 3d | xaw3d )              val=3d     ;;
 643             dnl No `n' for next, someone may try `no'
 644             ne | nex | next | naxtaw)     val=next   ;;
 645             dnl Have not tested the next two...
 646             9 | 95 | xaw95 )              val=95     ;;
 647             xp | xpm | xawxpm )           val=xpm    ;;
 648             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 649   \`xaw', \`3d', \`next', \`95', or \`xpm'."]) ;;
 650           esac
 651           eval "$opt=\"$val\""
 652         ;;
 653
 654         dnl Has the user requested XIM support?
 655         "with_xim" )
 656           case "$val" in
 657             y | ye | yes )                val=yes   ;;
 658             n | no | non | none )         val=no    ;;
 659             x | xl | xli | xlib )         val=xlib  ;;
 660             m | mo | mot | moti | motif ) val=motif ;;
 661             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 662   \`motif', \`xlib', \`yes', or \`no'."]) ;;
 663           esac
 664           eval "$opt=\"$val\""
 665         ;;
 666
 667         dnl Mail locking specification
 668         "mail_locking" )
 669           case "$val" in
 670             lockf )     val=lockf ;;
 671             flock )     val=flock ;;
 672             file | dot ) val=file  ;;
 673             locking )   val=locking  ;;
 674             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 675   \`lockf', \`flock', \`file', \`locking', or \`mmdf'."]) ;;
 676           esac
 677           eval "$opt=\"$val\""
 678         ;;
 679
 680         dnl Has the user requested error-checking?
 681         "error_checking" )
 682           dnl value can be all, none, and/or a list of categories to check.
 683           dnl Example: --error-checking=all,noextents,nobufpos
 684           dnl Example: --error-checking=none,malloc,gc
 685
 686           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 687             case "$x" in
 688               dnl all and none are only permitted as the first in the list.
 689               n | no | non | none ) new_default=no ;;
 690               a | al | all )        new_default=yes ;;
 691
 692               extents )       error_check_extents=yes ;;
 693               noextents )     error_check_extents=no ;;
 694
 695               typecheck )     error_check_typecheck=yes ;;
 696               notypecheck )   error_check_typecheck=no ;;
 697
 698               bufpos )        error_check_bufpos=yes ;;
 699               nobufpos )      error_check_bufpos=no ;;
 700
 701               gc )            error_check_gc=yes ;;
 702               nogc )          error_check_gc=no ;;
 703
 704               malloc )        error_check_malloc=yes ;;
 705               nomalloc )      error_check_malloc=no ;;
 706
 707               byte_code )     error_check_byte_code=yes ;;
 708               nobyte_code )   error_check_byte_code=no ;;
 709
 710               glyphs )     error_check_glyphs=yes ;;
 711               noglyphs )   error_check_glyphs=no ;;
 712
 713               * ) bogus_error_check=yes ;;
 714             esac
 715             if test "$bogus_error_check" -o \
 716                  \( -n "$new_default" -a -n "$echeck_notfirst" \) ; then
 717                 if test "$error_check_default" = yes ; then
 718                   types="\`all' (default), \`none', \`noextents', \`notypecheck', \`nobufpos', \`nogc', \`nomalloc', \`noglyphs' and \`nobyte-code'."
 719                 else
 720                   types="\`all', \`none' (default), \`extents', \`typecheck', \`bufpos', \`gc', \`malloc', \`glyphs' and \`byte-code'."
 721                 fi
 722                 USAGE_ERROR(["Valid types for the \`--$optname' option are:
 723   $types."])
 724             elif test -n "$new_default" ; then
 725                 error_check_extents=$new_default
 726                 error_check_typecheck=$new_default
 727                 error_check_bufpos=$new_default
 728                 error_check_gc=$new_default
 729                 error_check_malloc=$new_default
 730                 error_check_byte_code=$new_default
 731                 error_check_glyphs=$new_default
 732                 new_default=    # reset this
 733             fi
 734             echeck_notfirst=true
 735           done
 736         ;;
 737
 738         dnl Has the user tried to tell us where the X files are?
 739         dnl I think these are dopey, but no less than three alpha
 740         dnl testers, at large sites, have said they have their X files
 741         dnl installed in odd places.
 742
 743         dnl Has the user specified one of the path options?
 744         prefix | exec_prefix | bindir | datadir | statedir | libdir | \
 745         mandir | infodir | infopath | lispdir | etcdir | pkgdir | \
 746         archlibdir | docdir | package_path )
 747            dnl If the value was omitted, get it from the next argument.
 748            if test "$valomitted" = "yes"; then
 749              if test "$#" = 0; then
 750                  USAGE_ERROR("The \`--$optname' option requires a value.");
 751              fi
 752              val="$1"; shift
 753            fi
 754            eval "$opt=\"$val\""
 755
 756            dnl You need to synchronize this with the way the
 757            dnl default values are built.
 758            case "$opt" in
 759              dnl prefix is taken care of by --with-prefix
 760              exec_prefix ) AC_DEFINE(EXEC_PREFIX_USER_DEFINED) ;;
 761              lispdir ) AC_DEFINE(LISPDIR_USER_DEFINED) ;;
 762              sitelispdir ) AC_DEFINE(SITELISPDIR_USER_DEFINED) ;;
 763              moduledir ) AC_DEFINE(MODULEDIR_USER_DEFINED) ;;
 764              etcdir  )  AC_DEFINE(ETCDIR_USER_DEFINED) ;;
 765              infodir ) AC_DEFINE(INFODIR_USER_DEFINED) ;;
 766              infopath ) AC_DEFINE(INFOPATH_USER_DEFINED) ;;
 767              package_path ) AC_DEFINE(PACKAGE_PATH_USER_DEFINED) ;;
 768              datadir )
 769                 AC_DEFINE(INFODIR_USER_DEFINED)
 770                 AC_DEFINE(LISPDIR_USER_DEFINED)
 771                 AC_DEFINE(MODULEDIR_USER_DEFINED)
 772                 AC_DEFINE(ETCDIR_USER_DEFINED)
 773                 AC_DEFINE(DOCDIR_USER_DEFINED)
 774                 AC_DEFINE(ARCHLIBDIR_USER_DEFINED) ;;
 775              docdir ) AC_DEFINE(DOCDIR_USER_DEFINED) ;;
 776              exec_prefix | libdir | archlibdir ) AC_DEFINE(ARCHLIBDIR_USER_DEFINED) ;;
 777            esac
 778         ;;
 779
 780         dnl --no-create added by autoconf for use by config.status
 781         "no_create" ) ;;
 782
 783         dnl Has the user asked for some help?
 784         "usage" | "help" ) ${PAGER-more} ${srcdir}/configure.usage; exit 0 ;;
 785
 786         dnl Has the user specified the toolkit(s) to use for GUI elements?
 787         "with_menubars"   | \
 788         "with_scrollbars" | \
 789         "with_dialogs"    | \
 790         "with_widgets" )
 791           case "$val" in
 792             l | lu | luc | luci | lucid )               val=lucid  ;;
 793             mo | mot | moti | motif )                   val=motif  ;;
 794             a | at | ath | athe | athen | athena )      val=athena ;;
 795             n | no | non | none )                       val=no     ;;
 796             y | ye | yes )                              val=yes    ;;
 797             g | gt | gtk )                              val=gtk    ;;
 798             ms | msw )                                  val=msw    ;;
 799             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 800   \`gtk', \`lucid', \`motif', \`athena', \`yes', or \`no'."]) ;;
 801           esac
 802           eval "$opt=\"$val\""
 803         ;;
 804
 805         dnl Obsolete legacy argument?  Warn, but otherwise ignore.
 806         "use_minimal_tagbits" | \
 807         "use_indexed_lrecord_implementation" | \
 808         "run_in_place"  | \
 809         "const_is_losing" | \
 810         "with_gnu_make" )
 811           AC_MSG_WARN([Obsolete option \`--$optname' ignored.])
 812         ;;
 813
 814         dnl Unrecognized option?  No mercy for user errors.
 815         * ) USAGE_ERROR("Unrecognized option: $arg") ;;
 816
 817       esac
 818     ;;
 819
 820     dnl Assume anything with multiple hyphens is a configuration name.
 821     *-*-*) configuration="$arg" ;;
 822
 823     dnl Unrecognized argument?  No mercy for user errors.
 824     *) USAGE_ERROR("Unrecognized argument: $arg") ;;
 825
 826   esac
 827 done
 828
 829 dnl -------------------------
 830 dnl Finish options processing
 831 dnl -------------------------
 832
 833 dnl Several options are equivalent to, and override, environment variables.
 834 test -n "$cpp"      && CPP="$cpp"
 835 test -n "$cppflags" && CPPFLAGS="$cppflags"
 836 test -n "$libs"     && LIBS="$libs"
 837 test -n "$ldflags"  && LDFLAGS="$ldflags"
 838
 839 dnl Get the arguments back.  See the diatribe on Shell Magic above.
 840 eval set x "$quoted_arguments"; shift
 841
 842 dnl --extra-verbose implies --verbose
 843 test "$extra_verbose" = "yes" && verbose=yes
 844
 845 dnl with_x is an obsolete synonym for with_x11
 846 test -n "$with_x" && with_x11="$with_x"
 847
 848 dnl --with-quantify or --with-purify imply --use-system-malloc
 849 if test "$with_purify" = "yes" -o "$with_quantify" = "yes"; then
 850   test "$with_system_malloc" = "default" && with_system_malloc=yes
 851 fi
 852
 853 dnl XE_CHECK_FEATURE_DEPENDENCY(feature1, feature2)
 854 define([XE_CHECK_FEATURE_DEPENDENCY],
 855 [if test "$with_$1 $with_$2" = "yes no"; then
 856   USAGE_ERROR("--with-$1 requires --with-$2")
 857 elif test "$with_$2" = "no" ; then with_$1=no
 858 elif test "$with_$1" = "yes"; then with_$2=yes
 859 fi
 860 ])
 861
 862 dnl CDE requires tooltalk
 863 XE_CHECK_FEATURE_DEPENDENCY(cde, tooltalk)
 864
 865 dnl Find the source directory.
 866 case "$srcdir" in
 867
 868   dnl If srcdir is not specified, see if  "." or ".." might work.
 869   "" )
 870     for dir in "`echo $0 | sed 's|//|/|' | sed 's|/[[^/]]*$||'`" "." ".." ; do
 871       if test -f "$dir/src/lisp.h" -a \
 872               -f "$dir/lisp/version.el" ; then
 873         srcdir="$dir"
 874         break
 875       fi
 876     done
 877     if test -z "$srcdir" ; then
 878       USAGE_ERROR(["Neither the current directory nor its parent seem to
 879   contain the XEmacs sources.  If you do not want to build XEmacs in its
 880   source tree, you should run \`$progname' in the directory in which
 881   you wish to build XEmacs, using the \`--srcdir' option to say where the
 882   sources may be found."])
 883     fi
 884   ;;
 885
 886   dnl Otherwise, check if the directory they specified is okay.
 887   * )
 888     if test ! -f "$srcdir/src/lisp.h" -o \
 889             ! -f "$srcdir/lisp/version.el" ; then
 890       USAGE_ERROR(["The directory specified with the \`--srcdir' option,
 891   \`$srcdir', doesn't seem to contain the XEmacs sources.  You should
 892   either run the \`$progname' script at the top of the XEmacs source
 893   tree, or use the \`--srcdir' option to specify the XEmacs source directory."])
 894     fi
 895   ;;
 896 esac
 897
 898 dnl ###########################################################################
 899 if test -z "$configuration"; then
 900   dnl Guess the configuration
 901   configuration=`${CONFIG_SHELL-/bin/sh} $srcdir/config.guess`
 902   if test -z "$configuration"; then
 903     USAGE_ERROR(["XEmacs has not been ported to this host type.
 904 Try explicitly specifying the CONFIGURATION when rerunning configure."])
 905   fi
 906 fi
 907
 908 AC_PROG_LN_S
 909
 910 dnl Make symlinks for etc, lisp, and info directories while the path
 911 dnl is still relative.  We do not symlink lock because someone may
 912 dnl have stuck the source on a read-only partition.  Instead we
 913 dnl create it as an actual directory later on if it does not already
 914 dnl exist.
 915 for dir in lisp etc man info tests; do
 916   if test ! -d "$dir" ; then
 917     echo Making symbolic link to "$srcdir/$dir"
 918     ${LN_S} "$srcdir/$dir" "$dir"
 919   fi
 920 done
 921
 922 dnl Do our best to deal with automounter brokenness
 923 dnl CANONICALIZE_PATH(varname)
 924 define([CANONICALIZE_PATH],
 925 [if test -d "/net"; then
 926   if test -d "/tmp_mnt/net"; then tdir="tmp_mnt/net"; else tdir="tmp_mnt"; fi
 927   $1=`echo "[$]$1" | \
 928    sed -e "s|^${tdir}/|/net/|" -e "s|^/a/|/net/|" -e "s|^/amd/|/net/|"`
 929 fi])dnl
 930
 931 dnl Calculate canonical name for blddir (i.e. current directory).
 932 dnl PWD may already be the preferable absolute name for ".",
 933 dnl but we can't trust it - it is sometimes inaccurate.
 934 absolute_pwd="`pwd`";
 935 if test -n "$PWD" -a "`cd $PWD && pwd`" = "$absolute_pwd"
 936 then blddir="$PWD"
 937 else blddir="$absolute_pwd"; CANONICALIZE_PATH(blddir)
 938 fi
 939 AC_SUBST(blddir)
 940
 941 dnl Make srcdir absolute, if not already.  It is important to
 942 dnl avoid running the path through pwd unnecessary, since pwd can
 943 dnl give you automounter prefixes, which can go away.
 944 case "$srcdir" in
 945   /* ) ;;
 946   .  ) srcdir="$blddir" ;;
 947   *  ) srcdir="`cd $srcdir && pwd`"; CANONICALIZE_PATH(srcdir) ;;
 948 esac
 949
 950 dnl Check if the source directory already has a configured system in it.
 951 if test `pwd` != `sh -c cd $srcdir && pwd`  \
 952    && test -f "$srcdir/src/config.h"; then
 953   (echo "$progname: WARNING: The directory tree \`$srcdir' is being used"
 954    echo "   as a build directory right now; it has been configured in its own"
 955    echo "   right.  To configure in another directory as well, you MUST"
 956    echo "   use GNU make.  If you do not have GNU make, then you must"
 957    echo "   now do \`make distclean' in $srcdir,"
 958    echo "   and then run $progname again.") >&2
 959   extrasub='/^VPATH[[    ]]*=/c\
 960 vpath %.c $(srcdir)\
 961 vpath %.h $(srcdir)\
 962 vpath %.y $(srcdir)\
 963 vpath %.l $(srcdir)\
 964 vpath %.s $(srcdir)\
 965 vpath %.in $(srcdir)'
 966 fi
 967
 968 dnl ----------------------------------------
 969 dnl Find out which version of XEmacs this is
 970 dnl ----------------------------------------
 971 . "$srcdir/version.sh" || exit 1;
 972 dnl Must do the following first to determine verbosity for AC_DEFINE
 973 if test -n "$emacs_is_beta"; then beta=yes; else beta=no; fi
 974 : "${extra_verbose=$beta}"
 975 version="${emacs_major_version}.${emacs_minor_version}"
 976 AC_DEFINE_UNQUOTED(EMACS_MAJOR_VERSION, $emacs_major_version)
 977 AC_DEFINE_UNQUOTED(EMACS_MINOR_VERSION, $emacs_minor_version)
 978 if test -n "$emacs_beta_version" ; then
 979   if test "$beta" = "yes"; then
 980         version="${version}-b${emacs_beta_version}"
 981         AC_DEFINE_UNQUOTED(EMACS_BETA_VERSION, $emacs_beta_version)
 982   else
 983         version="${version}.${emacs_beta_version}"
 984         AC_DEFINE_UNQUOTED(EMACS_PATCH_LEVEL, $emacs_beta_version)
 985   fi
 986 fi
 987 AC_DEFINE_UNQUOTED(XEMACS_CODENAME, "$xemacs_codename")
 988 AC_DEFINE_UNQUOTED(EMACS_VERSION, "$version")
 989
 990 if test "$with_infodock" = "yes"; then
 991   if test ! -f ../../ID-INSTALL; then
 992     echo "Cannot build InfoDock without InfoDock sources"
 993     with_infodock=no
 994   fi
 995 fi
 996
 997 if test "$with_infodock" = "yes"; then
 998   dnl InfoDock version numbers.  XEmacs will use the same style of numbering
 999   dnl after the release of XEmacs 21.0.
1000   AC_DEFINE_UNQUOTED(INFODOCK_MAJOR_VERSION, $infodock_major_version)
1001   AC_DEFINE_UNQUOTED(INFODOCK_MINOR_VERSION, $infodock_minor_version)
1002   AC_DEFINE_UNQUOTED(INFODOCK_BUILD_VERSION, $infodock_build_version)
1003   version=${infodock_major_version}.${infodock_minor_version}.${infodock_build_version}
1004   PROGNAME=infodock
1005   CPPFLAGS="$CPPFLAGS -DINFODOCK"
1006 else
1007   PROGNAME=xemacs
1008 fi
1009
1010 AC_DEFINE_UNQUOTED(EMACS_PROGNAME, "$PROGNAME")
1011
1012 dnl ----------------------------------
1013 dnl Error checking and debugging flags
1014 dnl ----------------------------------
1015 dnl Error checking default to "yes" in beta versions, to "no" in releases.
1016 dnl Same goes for --debug and --extra-verbosity.
1017 if test -n "$emacs_is_beta"; then beta=yes; else beta=no; fi
1018 test "${error_check_extents=$beta}"   = yes && AC_DEFINE(ERROR_CHECK_EXTENTS)
1019 test "${error_check_typecheck=$beta}" = yes && AC_DEFINE(ERROR_CHECK_TYPECHECK)
1020 test "${error_check_bufpos=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_BUFPOS)
1021 test "${error_check_gc=$beta}"        = yes && AC_DEFINE(ERROR_CHECK_GC)
1022 test "${error_check_malloc=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_MALLOC)
1023 test "${error_check_byte_code=$beta}" = yes && AC_DEFINE(ERROR_CHECK_BYTE_CODE)
1024 test "${error_check_glyphs=$beta}" = yes && AC_DEFINE(ERROR_CHECK_GLYPHS)
1025 dnl debug=yes must be set when error checking is present.  This should be
1026 dnl fixed up.
1027 dnl debug implies other options
1028 if test "${debug:=$beta}" = "yes"; then
1029   use_assertions=yes memory_usage_stats=yes
1030   XE_ADD_OBJS(debug.o)
1031   XE_ADD_OBJS(tests.o)
1032   AC_DEFINE(DEBUG_XEMACS)
1033 fi
1034 test "$use_assertions"     = "yes" && AC_DEFINE(USE_ASSERTIONS)
1035 test "$memory_usage_stats" = "yes" && AC_DEFINE(MEMORY_USAGE_STATS)
1036
1037 dnl ------------------------------
1038 dnl Determine the s&m files to use
1039 dnl ------------------------------
1040 dnl Given the configuration name, set machfile and opsysfile to the
1041 dnl names of the m/*.h and s/*.h files we should use.
1042
1043 dnl Canonicalize the configuration name.
1044 AC_MSG_CHECKING("host system type")
1045 dnl allow -workshop suffix on configuration name
1046 internal_configuration=`echo $configuration | sed 's/-\(workshop\)//'`
1047 canonical=`${CONFIG_SHELL-/bin/sh} $srcdir/config.sub "$internal_configuration"`
1048 XE_STRIP_4TH_COMPONENT(configuration)
1049 XE_STRIP_4TH_COMPONENT(canonical)
1050 AC_MSG_RESULT($configuration)
1051
1052 dnl If you add support for a new configuration, add code to this
1053 dnl switch statement to recognize your configuration name and select
1054 dnl the appropriate operating system and machine description files.
1055
1056 dnl You would hope that you could choose an m/*.h file pretty much
1057 dnl based on the machine portion of the configuration name, and an s-
1058 dnl file based on the operating system portion.  However, it turns out
1059 dnl that each m/*.h file is pretty manufacturer-specific - for
1060 dnl example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
1061 dnl all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
1062 dnl machines.  So we basically have to have a special case for each
1063 dnl configuration name.
1064
1065 dnl As far as handling version numbers on operating systems is
1066 dnl concerned, make sure things will fail in a fixable way.  If
1067 dnl /etc/MACHINES says nothing about version numbers, be
1068 dnl prepared to handle anything reasonably.  If version numbers
1069 dnl matter, be sure /etc/MACHINES says something about it.
1070
1071 dnl Eric Raymond says we should accept strings like "sysvr4" to mean
1072 dnl "System V Release 4"; he writes, "The old convention encouraged"
1073 dnl "confusion between `system' and `release' levels'."
1074
1075 machine='' opsys=''
1076
1077 dnl Straightforward machine determination
1078 case "$canonical" in
1079   sparc-*-*        ) machine=sparc ;;
1080   alpha*-*-*       ) machine=alpha ;;
1081   vax-*-*          ) machine=vax ;;
1082   mips-dec-*       ) machine=pmax ;;
1083   mips-sgi-irix6*  ) machine=iris6d ;;
1084   mips-sgi-*       ) machine=iris4d ;;
1085   mips*-linux      ) machine=mips ;;
1086   romp-ibm-*       ) machine=ibmrt ;;
1087   rs6000-ibm-aix*  ) machine=ibmrs6000 ;;
1088   powerpc-ibm-aix* ) machine=ibmrs6000 ;;
1089   powerpc*-*       ) machine=powerpc ;;
1090   hppa-*-*         ) machine=hp800 ;;
1091   m88k-dg-*        ) machine=aviion ;;
1092   m68*-sony-*      ) machine=news ;;
1093   mips-sony-*      ) machine=news-risc ;;
1094   clipper-*        ) machine=clipper ;;
1095   arm*             ) machine=arm ;;
1096   ns32k-*          ) machine=ns32000 ;;
1097 esac
1098
1099 dnl Straightforward OS determination
1100 case "$canonical" in
1101   *-*-linux*    ) opsys=linux ;;
1102   *-*-netbsd*   ) opsys=netbsd ;;
1103   *-*-openbsd*  ) opsys=openbsd ;;
1104   *-*-nextstep* ) opsys=nextstep ;;
1105   *-*-vms       ) opsys=vms ;;
1106
1107   dnl DEC OSF
1108   *-dec-osf1.3 | *-dec-osf2* ) opsys=decosf1-3 ;;
1109   *-dec-osf1.2 | *-dec-osf1* ) opsys=decosf1-2 ;;
1110   *-dec-osf3.[[2-9]]         ) opsys=decosf3-2 ;;
1111   *-dec-osf3*                ) opsys=decosf3-1 ;;
1112   *-dec-osf[[4-9]]*          ) opsys=decosf4-0 ;;
1113
1114   dnl DEC Ultrix
1115   *-*-ultrix[[0-3]].* | *-*-ultrix4.0* ) opsys=bsd4-2 ;;
1116   *-*-ultrix4.[[12]]* ) opsys=bsd4-3 ;;
1117   *-*-ultrix* )         opsys=ultrix4-3 ;;
1118
1119   dnl AIX
1120   *-*-aix3.1*  ) opsys=aix3-1   ;;
1121   *-*-aix3.2.5 ) opsys=aix3-2-5 ;;
1122   *-*-aix3*    ) opsys=aix3-2   ;;
1123   *-*-aix4.0*  ) opsys=aix4     ;;
1124   *-*-aix4.1*  ) opsys=aix4-1   ;;
1125   *-*-aix4*    ) opsys=aix4-2   ;;
1126
1127   dnl Other generic OSes
1128   *-gnu* )                      opsys=gnu    ;;
1129   *-*-bsd4.[[01]] )             opsys=bsd4-1 ;;
1130   *-*-bsd4.2 )                  opsys=bsd4-2 ;;
1131   *-*-bsd4.3 )                  opsys=bsd4-3 ;;
1132   *-*-aos4.2 )                  opsys=bsd4-2 ;;
1133   *-*-aos*   )                  opsys=bsd4-3 ;;
1134   *-*-sysv0    | *-*-sysvr0 )   opsys=usg5-0 ;;
1135   *-*-sysv2    | *-*-sysvr2 )   opsys=usg5-2 ;;
1136   *-*-sysv2.2  | *-*-sysvr2.2 ) opsys=usg5-2-2 ;;
1137   *-*-sysv3*   | *-*-sysvr3* )  opsys=usg5-3 ;;
1138   *-*-sysv4.1* | *-*-sysvr4.1* )opsys=usg5-4 NON_GNU_CPP=/usr/lib/cpp ;;
1139   *-*-sysv4.[[2-9]]* | *-sysvr4.[[2-9]]* )
1140         if test -z "$NON_GNU_CPP" ; then
1141           for prog in "/usr/ccs/lib/cpp" "/lib/cpp"; do
1142             if test -f "$prog"; then NON_GNU_CPP="$prog"; break; fi
1143           done
1144         fi
1145         opsys=usg5-4-2 ;;
1146     *-sysv4* | *-sysvr4* )      opsys=usg5-4 ;;
1147     *-*-mach_bsd4.3* )          opsys=mach-bsd4-3 ;;
1148 esac
1149
1150 case "$canonical" in
1151
1152   dnl NetBSD ports
1153   *-*-netbsd* )
1154     case "$canonical" in
1155       i[[3-9]]86-*-netbsd*) machine=intel386 ;;
1156       hp300-*-netbsd* | amiga-*-netbsd* | sun3-*-netbsd* | mac68k-*-netbsd* | da30-*-netbsd* | m68k-*-netbsd* )
1157                       dnl Yes, this is somewhat bogus.
1158                       machine=hp9000s300 ;;
1159       pc532-*-netbsd* | ns32k-*-netbsd* )  machine=ns32000 ;;
1160       pmax-*-netbsd*  | mips-*-netbsd*  )  machine=pmax ;;
1161     esac
1162   ;;
1163
1164   dnl OpenBSD ports
1165   *-*-openbsd* )
1166     case "${canonical}" in
1167       i386-*-openbsd*)          machine=intel386 ;;
1168       m68k-*-openbsd*)          machine=hp9000s300 ;;
1169       mipsel-*-openbsd*)        machine=pmax ;;
1170      esac
1171    ;;
1172
1173   dnl Acorn RISCiX:
1174   arm-acorn-riscix1.1* ) machine=acorn opsys=riscix1-1 ;;
1175   arm-acorn-riscix1.2* | arm-acorn-riscix ) machine=acorn opsys=riscix1-2 ;;
1176
1177   dnl Alliant machines
1178   fx80-alliant-* ) machine=alliant4     opsys=bsd4-2 ;;
1179   i860-alliant-* ) machine=alliant-2800 opsys=bsd4-3 ;;
1180
1181   dnl Altos 3068
1182   m68*-altos-sysv* ) machine=altos opsys=usg5-2 ;;
1183
1184   dnl Amdahl UTS
1185   580-amdahl-sysv* ) machine=amdahl opsys=usg5-2-2 ;;
1186
1187   dnl Apollo, Domain/OS
1188   m68*-apollo-* ) machine=apollo opsys=bsd4-3 ;;
1189
1190   dnl AT&T 3b2, 3b5, 3b15, 3b20
1191   we32k-att-sysv* ) machine=att3b opsys=usg5-2-2 ;;
1192
1193   dnl AT&T 3b1 - The Mighty Unix PC!
1194   m68*-att-sysv* ) machine=7300 opsys=usg5-2-2 ;;
1195
1196   dnl Bull machines
1197   rs6000-bull-bosx* ) machine=ibmrs6000 opsys=aix3-2 ;; # dpx20
1198   m68*-bull-sysv3*  ) machine=dpx2      opsys=usg5-3 ;; # dpx2
1199   m68*-bull-sysv2*  ) machine=sps7      opsys=usg5-2 ;; # sps7
1200
1201   dnl CCI 5/32, 6/32 -- see "Tahoe".
1202
1203   dnl Celerity
1204   celerity-celerity-bsd* ) machine=celerity opsys=bsd4-2 ;;
1205
1206   dnl Convex
1207   *-convex-bsd* | *-convex-convexos* )
1208     machine=convex opsys=bsd4-3
1209     NON_GNU_CPP="cc -E -P"
1210   ;;
1211
1212   dnl Cubix QBx/386
1213   i[[3-9]]86-cubix-sysv* ) machine=intel386 opsys=usg5-3 ;;
1214
1215   dnl Data General AViiON Machines
1216   i586-dg-dgux*R4*   | i586-dg-dgux5.4.4* ) machine=aviion opsys=dgux5-4r4 ;;
1217   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* ) opsys=dgux5-4r3 ;;
1218   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* ) opsys=dgux5-4r2 ;;
1219   m88k-dg-dgux*                           ) opsys=dgux     ;;
1220
1221   dnl Motorola Delta machines
1222   m68k-motorola-sysv* | m68000-motorola-sysv* ) machine=delta opsys=usg5-3 ;;
1223   m88k-motorola-sysv4* )
1224     dnl jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
1225     dnl needs POSIX_SIGNALS and therefore needs usg5-4-2.
1226     dnl I hope there are not other 4.0 versions for this machine
1227     dnl which really need usg5-4 instead.
1228     machine=delta88k opsys=usg5-4-2
1229   ;;
1230   m88k-motorola-sysv* | m88k-motorola-m88kbcs* ) machine=delta88k opsys=usg5-3 ;;
1231
1232   dnl Dual machines
1233   m68*-dual-sysv*    ) machine=dual opsys=usg5-2   ;;
1234   m68*-dual-uniplus* ) machine=dual opsys=unipl5-2 ;;
1235
1236   dnl Encore machines
1237   ns16k-encore-bsd* ) machine=ns16000 opsys=umax ;;
1238
1239   dnl Gould Power Node and NP1
1240   pn-gould-bsd4.2* ) machine=gould     opsys=bsd4-2 ;;
1241   pn-gould-bsd4.3* ) machine=gould     opsys=bsd4-3 ;;
1242   np1-gould-bsd* )   machine=gould-np1 opsys=bsd4-3 ;;
1243
1244   dnl Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
1245   dnl as far as XEmacs is concerned).
1246   m88k-harris-cxux* )
1247     dnl Build needs to be different on 7.0 and later releases
1248     case "`uname -r`" in
1249        [[56]].[[0-9]] ) machine=nh4000 opsys=cxux  ;;
1250        [[7]].[[0-9]]  ) machine=nh4000 opsys=cxux7 ;;
1251     esac
1252     NON_GNU_CPP="/lib/cpp"
1253   ;;
1254   dnl Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
1255   m68k-harris-cxux* ) machine=nh3000 opsys=cxux ;;
1256   dnl Harris power pc NightHawk running Power UNIX (Series 6000)
1257   powerpc-harris-powerunix ) machine=nh6000 opsys=powerunix NON_GNU_CPP="cc -Xo -E -P" ;;
1258
1259   dnl Honeywell XPS100
1260   xps*-honeywell-sysv* ) machine=xps100 opsys=usg5-2 ;;
1261
1262   dnl HP 9000 series 200 or 300
1263   m68*-hp-bsd* ) machine=hp9000s300 opsys=bsd4-3 ;;
1264
1265   dnl HP-UX
1266   *-hp-hpux* )
1267     dnl Figure out machine and opsys orthogonally
1268     case "$canonical" in
1269       m68*  ) machine=hp9000s300 ;;
1270       hppa* ) machine=hp800      ;;
1271     esac
1272
1273     case "$canonical" in
1274       *-hp-hpux7*  )  opsys=hpux   ;;
1275       *-hp-hpux8*  )  opsys=hpux8  ;;
1276       *-hp-hpux9*  )  opsys=hpux9  ;;
1277       *-hp-hpux10* )  opsys=hpux10 ;;
1278       *-hp-hpux11* )  opsys=hpux11 ;;
1279       *            )  opsys=hpux   ;;
1280     esac
1281
1282     dnl HP has a broken "strcat"
1283     case "$opsys" in hpux9 | hpux10 ) XE_ADD_OBJS(strcat.o) ;; esac
1284
1285     if test "$opsys" = "hpux10" -o "$opsys" = "hpux11"; then \
1286         ansi_flag="-Ae"; else ansi_flag="-Aa"; fi
1287     NON_GNU_CC="cc $ansi_flag" NON_GNU_CPP="cc $ansi_flag -E"
1288
1289     case "$canonical" in *-hp-hpux*shr* ) opsys="${opsys}-shr" ;; esac
1290   ;;
1291
1292   dnl Orion machines
1293   orion-orion-bsd*   ) machine=orion    opsys=bsd4-2 ;;
1294   clipper-orion-bsd* ) machine=orion105 opsys=bsd4-2 ;;
1295
1296   dnl IBM machines
1297   i[[3-9]]86-ibm-aix1.1* ) machine=ibmps2-aix opsys=usg5-2-2 ;;
1298   i[[3-9]]86-ibm-aix1.[[23]]* | i[[3-9]]86-ibm-aix* ) machine=ibmps2-aix opsys=usg5-3 ;;
1299   i370-ibm-aix*) machine=ibm370aix opsys=usg5-3 ;;
1300   romp-ibm-aos*    ) opsys=bsd4-3 ;;
1301   romp-ibm-bsd*    ) opsys=bsd4-3 ;;
1302   romp-ibm-mach*   ) opsys=mach-bsd4-3 ;;
1303
1304   dnl Integrated Solutions "Optimum V"
1305   m68*-isi-bsd4.2* ) machine=isi-ov opsys=bsd4-2 ;;
1306   m68*-isi-bsd4.3* ) machine=isi-ov opsys=bsd4-3 ;;
1307
1308   dnl Intel 386 machines where we do care about the manufacturer
1309   i[[3-9]]86-intsys-sysv* ) machine=is386 opsys=usg5-2-2 ;;
1310
1311   dnl Prime EXL
1312   i[[3-9]]86-prime-sysv* ) machine=i386 opsys=usg5-3 ;;
1313
1314   dnl Sequent Symmetry running Dynix
1315   i[[3-9]]86-sequent-bsd* ) machine=symmetry opsys=bsd4-3 ;;
1316
1317   dnl Sequent Symmetry running DYNIX/ptx
1318   i[[3-9]]86-sequent-ptx* ) machine=sequent-ptx opsys=ptx NON_GNU_CPP="/lib/cpp" ;;
1319
1320   dnl Unspecified sysv on an ncr machine defaults to svr4.2.
1321   dnl (Plain usg5-4 does not turn on POSIX signals, which we need.)
1322   i[[3-9]]86-ncr-sysv* ) machine=ncr386 opsys=usg5-4-2 ;;
1323
1324   dnl Intel Paragon OSF/1
1325   i860-intel-osf1* ) machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp ;;
1326
1327   dnl Intel 860
1328   i860-*-sysv4* ) machine=i860 opsys=usg5-4 NON_GNU_CC="/bin/cc" NON_GNU_CPP="/usr/ccs/lib/cpp" ;;
1329
1330   dnl Masscomp machines
1331   m68*-masscomp-rtu* ) machine=masscomp opsys=rtu ;;
1332
1333   dnl Megatest machines
1334   m68*-megatest-bsd* ) machine=mega68 opsys=bsd4-2 ;;
1335
1336   dnl Workstations sold by MIPS
1337   dnl This is not necessarily all workstations using the MIPS processor -
1338   dnl Irises are produced by SGI, and DECstations by DEC.
1339   mips-mips-usg* ) machine=mips4 ;;
1340   mips-mips-riscos4 )
1341     machine=mips4
1342     NON_GNU_CC="cc -systype bsd43"
1343     NON_GNU_CPP="cc -systype bsd43 -E"
1344     case "$canonical" in
1345       mips-mips-riscos4* ) opsys=bsd4-3  ;;
1346       mips-mips-riscos5* ) opsys=riscos5 ;;
1347     esac
1348   ;;
1349   mips-mips-bsd* ) machine=mips opsys=bsd4-3 ;;
1350   mips-mips-*    ) machine=mips opsys=usg5-2-2 ;;
1351
1352   dnl NeXT
1353   m68*-next-* | m68k-*-nextstep* ) machine=m68k opsys=nextstep ;;
1354
1355   dnl The complete machine from National Semiconductor
1356   ns32k-ns-genix* ) machine=ns32000 opsys=usg5-2 ;;
1357
1358   dnl NCR machines
1359   m68*-ncr-sysv2* | m68*-ncr-sysvr2* ) machine=tower32   opsys=usg5-2-2 ;;
1360   m68*-ncr-sysv3* | m68*-ncr-sysvr3* ) machine=tower32v3 opsys=usg5-3 ;;
1361
1362   dnl Nixdorf Targon 31
1363   m68*-nixdorf-sysv* ) machine=targon31 opsys=usg5-2-2 ;;
1364
1365   dnl Nu (TI or LMI)
1366   m68*-nu-sysv* ) machine=nu opsys=usg5-2 ;;
1367
1368   dnl Plexus
1369   m68*-plexus-sysv* ) machine=plexus opsys=usg5-2 ;;
1370
1371   dnl Pyramid machines
1372   pyramid-pyramid-bsd* ) machine=pyramid opsys=bsd4-2 ;;
1373
1374   dnl Sequent Balance
1375   ns32k-sequent-bsd4.2* ) machine=sequent opsys=bsd4-2 ;;
1376   ns32k-sequent-bsd4.3* ) machine=sequent opsys=bsd4-3 ;;
1377
1378   dnl Siemens Nixdorf
1379   mips-siemens-sysv* | mips-sni-sysv*)
1380     machine=mips-siemens opsys=usg5-4
1381     NON_GNU_CC=/usr/ccs/bin/cc
1382     NON_GNU_CPP=/usr/ccs/lib/cpp
1383   ;;
1384
1385   dnl NEC
1386   mips-nec-sysv*)
1387     machine=mips-nec
1388     NON_GNU_CC=/usr/ccs/bin/cc
1389     NON_GNU_CPP=/usr/ccs/lib/cpp
1390   ;;
1391
1392   dnl Silicon Graphics machines
1393   dnl Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
1394   m68*-sgi-iris3.5* ) machine=irist opsys=iris3-5 ;;
1395   m68*-sgi-iris3.6* | m68*-sgi-iris*) machine=irist opsys=iris3-6 ;;
1396   dnl Iris 4D
1397   mips-sgi-irix3.*    ) opsys=irix3-3 ;;
1398   mips-sgi-irix4.*    ) opsys=irix4-0 ;;
1399   mips-sgi-irix6*     ) opsys=irix6-0 ;;
1400   mips-sgi-irix5.1*   ) opsys=irix5-1 ;;
1401   mips-sgi-irix5.2*   ) opsys=irix5-2 ;;
1402   mips-sgi-irix5.*    ) opsys=irix5-3 ;;
1403   mips-sgi-irix*      ) opsys=irix5-0 ;;
1404
1405   dnl SONY machines
1406   *-sony-newsos[[34]]* | *-sony-news[[34]]* ) opsys=bsd4-3 ;;
1407   *-sony-news* ) opsys=newsos5 ;;
1408
1409   dnl Stride
1410   m68*-stride-sysv* ) machine=stride opsys=usg5-2 ;;
1411
1412   dnl Suns
1413   *-*-solaris* | *-*-sunos* | *-sun-mach* | *-sun-bsd* )
1414     dnl Hardware type
1415     case "$canonical" in
1416       m68*-sunos1* )             machine=sun1     ;;
1417       m68*-sunos2* )             machine=sun2     ;;
1418       m68* )                     machine=sun3     ;;
1419       i*86*-sun-sunos[[34]]* )   machine=sun386   ;;
1420       i*86-*-* )                 machine=intel386 ;;
1421       rs6000* )                  machine=rs6000   ;;
1422     esac
1423
1424     dnl Make $canonical even more so.
1425     case "$canonical" in *-sunos5*)
1426       canonical=`echo $canonical | sed -e s/sunos5/solaris2/`;;
1427     esac
1428
1429     dnl On SunOS 4, use /usr/lib/cpp, sans dynodump, /bin/ranlib
1430     dnl On SunOS 5, use cc -E,        need dynodump, RANLIB not needed
1431     dnl But, SunOS 5.6 no longer needs dynodump because it has a similar
1432     dnl function integrated.
1433     case "$canonical" in
1434       *-sunos4* )
1435         #test -f /usr/lib/cpp     && NON_GNU_CPP=/usr/lib/cpp ;;
1436         : ;;
1437       *-solaris2* )
1438         #test -f /usr/ccs/lib/cpp && NON_GNU_CPP=/usr/ccs/lib/cpp
1439         RANLIB=':' ;;
1440     esac
1441
1442     case "$canonical" in
1443       *-solaris*          )
1444         opsys=sol2
1445         os_release=`uname -r | sed -e 's/^\([[0-9]]\)\.\([[0-9]]\).*/\1\2/'`
1446         AC_DEFINE_UNQUOTED(OS_RELEASE, $os_release) ;;
1447
1448       dnl The last Sun386 ran 4.0.
1449       i*86-*-sunos4*      ) opsys=sunos4-0      ;;
1450       *-sunos4.0*         ) opsys=sunos4-0      ;;
1451       *-sunos4.1.2*       ) opsys=sunos4-1-2    ;;
1452       *-sunos4.1.3*       ) opsys=sunos4-1-3    ;;
1453       *-sunos4.1.[[4-9]]* ) opsys=sunos4-1-4    ;;
1454       *-sunos4* | *-sunos ) opsys=sunos4-1      ;;
1455       *-mach*             ) opsys=mach-bsd4-3   ;;
1456       *                   ) opsys=bsd4-2        ;;
1457     esac
1458
1459     case "$canonical" in *-sunos4*shr* ) opsys="${opsys}-shr" ;; esac
1460
1461     dnl Watch out for a compiler guaranteed not to work.
1462     test "$opsys $CC" = "sol2 /usr/ucb/cc" && CC=""
1463   ;;
1464
1465   dnl Tadpole 68k
1466   m68*-tadpole-sysv* ) machine=tad68k opsys=usg5-3 ;;
1467
1468   dnl Tahoe machines
1469   tahoe-tahoe-bsd4.2* ) machine=tahoe opsys=bsd4-2 ;;
1470   tahoe-tahoe-bsd4.3* ) machine=tahoe opsys=bsd4-3 ;;
1471
1472   dnl Tandem Integrity S2
1473   mips-tandem-sysv* ) machine=tandem-s2 opsys=usg5-3 ;;
1474
1475   dnl Tektronix XD88
1476   m88k-tektronix-sysv3* ) machine=tekxd88 opsys=usg5-3 ;;
1477
1478   dnl Tektronix 16000 box (6130?)
1479   ns16k-tektronix-bsd* ) machine=ns16000 opsys=bsd4-2 ;;
1480   dnl Tektronix 4300
1481   dnl src/m/tek4300.h hints that this is a m68k machine.
1482   m68*-tektronix-bsd* ) machine=tek4300 opsys=bsd4-3 ;;
1483
1484   dnl Titan P2 or P3
1485   titan-titan-sysv* ) machine=titan opsys=usg5-3 ;;
1486
1487   dnl Ustation E30 (SS5E)
1488   m68*-unisys-uniplus* ) machine=ustation opsystem=unipl5-2 ;;
1489
1490   dnl Vaxen.
1491   vax-dec-* )
1492     case "$canonical" in
1493       *-sysv[[01]]* | *-sysvr[[01]]* )  opsys=usg5-0 ;;
1494       *-sysv2* | *-sysvr2* )            opsys=usg5-2 ;;
1495       *-mach* )                         opsys=mach-bsd4-3 ;;
1496     esac
1497   ;;
1498
1499   dnl Whitechapel MG1
1500   ns16k-whitechapel-* ) machine=mg1 ;;
1501
1502   dnl Wicat
1503   m68*-wicat-sysv* ) machine=wicat opsys=usg5-2 ;;
1504
1505   dnl Intel 386 machines where we do not care about the manufacturer
1506   i[[3-9]]86-*-* )
1507     machine=intel386
1508     case "$canonical" in
1509       *-isc1.* | *-isc2.[[01]]* ) opsys=386-ix ;;
1510       *-isc2.2* )               opsys=isc2-2 ;;
1511       *-isc4.0* )               opsys=isc4-0 ;;
1512       *-isc4.* )                opsys=isc4-1
1513                                 GCC_TEST_OPTIONS=-posix
1514                                 NON_GCC_TEST_OPTIONS=-Xp
1515                                 ;;
1516       *-isc* )                  opsys=isc3-0 ;;
1517       *-esix5* )                opsys=esix5r4 NON_GNU_CPP=/usr/lib/cpp ;;
1518       *-esix* )                 opsys=esix ;;
1519       *-mach* )                 opsys=mach-bsd4-3 ;;
1520       *-xenix* )                opsys=xenix ;;
1521       *-sco3.2v4* )             opsys=sco4 NON_GNU_CPP=/lib/cpp  ;;
1522       *-bsd386* | *-bsdi1* )    opsys=bsd386 ;;
1523       *-bsdi4* )                opsys=bsdos4 ;;
1524       *-bsdi3* )                opsys=bsdos3 ;;
1525       *-bsdi2.1* )              opsys=bsdos2-1 ;;
1526       *-bsdi2* )                opsys=bsdos2 ;;
1527       *-sco3.2v5* )             opsys=sco5 ;;
1528       *-sysv5* )                opsys=sco7 ;;
1529       *-386bsd* )               opsys=386bsd ;;
1530       *-freebsd* )              opsys=freebsd ;;
1531       *-nextstep* )             opsys=nextstep ;;
1532       *-pc-cygwin* )            opsys=cygwin32 ;;
1533       *-pc-mingw* )             opsys=mingw32 ;
1534                                 test -z "$with_tty" && with_tty="no";;
1535       dnl Otherwise, we fall through to the generic opsys code at the bottom.
1536     esac
1537   ;;
1538
1539   dnl Linux/68k
1540   m68k-*-linux* ) machine=m68k opsys=linux ;;
1541
1542 esac
1543
1544 dnl Initialize machine from $canonical if not in our database above.
1545 test -z "$machine" && machine=`echo $canonical | sed 's/-.*$//'`
1546
1547 dnl Initialize opsys from `uname -s` if not in our database above.
1548 test -z "$opsys"   && opsys=`uname -s | tr ABCDEFGHIJKLMNOPQRSTUVWXYZ abcdefghijklmnopqrstuvwxyz`
1549
1550 dnl Use configure-time autodetection if s&m not available
1551 if test -r "${srcdir}/src/m/${machine}.h"; then
1552   machfile="m/${machine}.h"
1553   AC_DEFINE_UNQUOTED(config_machfile, "$machfile")
1554 else
1555   echo "XEmacs has no builtin knowledge of \`$machine' machines."
1556   echo "Using configure-time autodetection only."
1557 fi
1558
1559 if test -r "${srcdir}/src/s/${opsys}.h"; then
1560   opsysfile="s/${opsys}.h"
1561   AC_DEFINE_UNQUOTED(config_opsysfile, "$opsysfile")
1562 else
1563   echo "XEmacs has no builtin knowledge of \`$opsys' operating systems."
1564   echo "Using configure-time autodetection only."
1565 fi
1566
1567
1568 if test -z "$dynamic"; then
1569   case "$opsys" in
1570     hpux* | sunos4* ) dynamic=no ;;
1571     *) dynamic=yes ;;
1572   esac
1573 fi
1574 if test "$dynamic" = "yes"; then
1575   case "$opsys" in
1576     hpux* | sunos4* | sco5 ) opsys="${opsys}-shr" ;;
1577     decosf* ) ld_call_shared="-call_shared" ;;
1578   esac
1579 else dnl "$dynamic" = "no"
1580   case "$opsys" in
1581     sol2 )
1582       echo "Static linking is not supported on Solaris 2."
1583       echo "Rerun configure without specifying --dynamic=no."
1584       exit 1 ;;
1585     linux   ) ld_call_shared="-Bstatic" ;;
1586     decosf* ) ld_call_shared="-non_shared" ;;
1587   esac
1588 fi
1589
1590 dnl Use xlc by default on AIX
1591 case "$opsys" in aix*) NON_GNU_CC=xlc ;; esac
1592
1593 stack_trace_eye_catcher=`echo ${PROGNAME}_${version}_${canonical} | sed 'y/.-/__/'`
1594 AC_DEFINE_UNQUOTED(STACK_TRACE_EYE_CATCHER, $stack_trace_eye_catcher)
1595
1596 dnl --------------------------------------------------
1597 dnl Determine the compiler, set up for feature testing
1598 dnl --------------------------------------------------
1599
1600 dnl Sun Development environment support
1601 test "$with_sparcworks" = "yes" && with_workshop=yes # compatibility alias
1602 XE_CHECK_FEATURE_DEPENDENCY(workshop, tooltalk)
1603 if test "$with_workshop" = "yes"; then
1604   AC_DEFINE(SUNPRO)
1605   XE_ADD_OBJS(sunpro.o)
1606 fi
1607
1608 if test "$with_clash_detection" != "no"; then
1609   AC_DEFINE(CLASH_DETECTION)
1610   XE_ADD_OBJS(filelock.o)
1611 fi
1612
1613 dnl Choose a compiler from (in order)
1614 dnl --compiler, env var CC, with_gcc=no && ${NON_GNU_CC:-cc}, AC_PROG_CC
1615 test -n "$compiler" && CC="$compiler"
1616 if test "$with_gcc" = "no"; then dnl Try to find a non-gcc compiler
1617   case "$CC" in "" | *gcc* ) CC="${NON_GNU_CC-cc}" ;; esac
1618 fi
1619
1620 dnl If we don't set CFLAGS here, AC_PROG_CC will set it.
1621 dnl But we know better what's good for us, so we do our own
1622 dnl computation of real CFLAGS later.
1623 dnl --cflags overrides environment variable CFLAGS
1624 test "${cflags-unset}" != unset && CFLAGS="$cflags"
1625 if test "${CFLAGS-unset}" != unset
1626   then cflags_specified=yes;
1627   else cflags_specified=no;
1628 fi
1629
1630 xe_save_CFLAGS="$CFLAGS"
1631
1632 AC_PROG_CC dnl Autoconf has its own magic for compiler autodetection
1633
1634 dnl Retry using random guesswork if AC_PROG_CC got it wrong...
1635 if   test "$with_gcc" = "no"  -a "$GCC" = "yes"; then
1636   CC=${NON_GNU_CC-cc}
1637   AC_PROG_CC
1638 elif test "$with_gcc" = "yes" -a "$GCC" != "yes" ; then
1639   CC=gcc
1640   AC_PROG_CC
1641 fi
1642 CFLAGS="$xe_save_CFLAGS"
1643
1644 dnl Figure out what C preprocessor to use.
1645
1646 dnl On Sun systems, people sometimes set up the variable CPP
1647 dnl with a value that is a directory, not an executable at all.
1648 dnl Detect that case, and ignore that value.
1649 test -n "$CPP" -a -d "$CPP" && CPP=
1650
1651 test -n "$NON_GNU_CPP" -a "$GCC" != "yes" -a -z "$CPP" && CPP="$NON_GNU_CPP"
1652
1653 AC_PROG_CPP
1654
1655 dnl --------------------------------------------------------------------
1656 dnl Compiler feature macros
1657 dnl --------------------------------------------------------------------
1658
1659 AC_AIX dnl Defines _ALL_SOURCE on AIX.
1660
1661 dnl We want feature macros defined here *and* in config.h.in, so that
1662 dnl the compilation environment at configure time and compile time agree.
1663
1664 AC_MSG_CHECKING(for GNU libc)
1665 AC_TRY_COMPILE([#include <features.h>],[
1666 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
1667 #error Not a GNU libc system :-(
1668 ******* ======= ******** &&&&&&&&
1669 #endif
1670 ], have_glibc=yes, have_glibc=no)
1671 AC_MSG_RESULT($have_glibc)
1672 dnl I'm tired of pop being broken with GLIBC -slb
1673 dnl Well. then why not fix fucking pop?
1674 test "$have_glibc" = "yes" && AC_DEFINE(_GNU_SOURCE)
1675
1676 dnl We'd like to use vendor extensions, where available.
1677 dnl We'd like to use functions from the latest Unix98 standards.
1678 dnl See http://www.opengroup.org/onlinepubs/007908799/xsh/compilation.html
1679 case "$opsys" in
1680   sol2)
1681    AC_DEFINE(__EXTENSIONS__)
1682    dnl Solaris 2 before 2.5 had some bugs with feature test macro interaction.
1683    if test "$os_release" -ge 55; then
1684      AC_DEFINE(_XOPEN_SOURCE,500)
1685      AC_DEFINE(_XOPEN_SOURCE_EXTENDED)
1686    fi ;;
1687   linux)
1688     AC_DEFINE(_POSIX_C_SOURCE,199506L)
1689     AC_DEFINE(_XOPEN_SOURCE,500)
1690     AC_DEFINE(_XOPEN_SOURCE_EXTENDED)
1691     ;;
1692 esac
1693
1694 dnl Identify compilers to enable compiler-specific hacks.
1695 dnl Add support for other compilers HERE!
1696 dnl GCC is already identified elsewhere.
1697 AC_TRY_RUN([int main () {
1698 #if defined __SUNPRO_C
1699 return 11;
1700 #elif defined __DECC
1701 return 12;
1702 #elif defined __USLC__ && defined __SCO_VERSION__
1703 return 13;
1704 #else
1705 return 0;
1706 #endif
1707 }], [],
1708 [case "$conftest_rc" in
1709   11) echo "You appear to be using the SunPro C compiler."; __SUNPRO_C=yes ;;
1710   12) echo "You appear to be using the DEC C compiler."   ; __DECC=yes ;;
1711   13) echo "You appear to be using the SCO C compiler."   ; __USLC__=yes ;;
1712 esac])
1713
1714
1715 dnl case "$canonical" in
1716 dnl   *-sun-sunos* ) test "$CPP" = "acc -E" && CPP="acc -E -Xs" ;;
1717 dnl esac
1718
1719 dnl --------------------------------------------------------------------
1720 dnl Extract some information from the operating system and machine files
1721 dnl --------------------------------------------------------------------
1722
1723 echo "Extracting information from the machine- and system-dependent headers..."
1724
1725 dnl It is not important that this name contain the PID; you cannot run
1726 dnl two configures in the same directory and have anything work
1727 dnl anyway.
1728 tempcname="conftest.c"
1729
1730 dnl CPP_to_sh(CPP_SYMBOL, SH_VAR, DEFAULT_VALUE)
1731 define([CPP_to_sh],
1732 [[#]ifndef [$1]
1733 [#]define [$1]ifelse([$3],,, [ "$3"])
1734 [#]endif
1735 configure___ [$2]=[$1]
1736 ])dnl CPP_to_sh
1737
1738 dnl CPP_boolean_to_sh(CPP_SYMBOL, SH_VAR)
1739 define([CPP_boolean_to_sh],
1740 [[#]ifdef [$1]
1741 configure___ [$2]=yes
1742 [#]else
1743 configure___ [$2]=no
1744 [#]endif
1745 ])dnl CPP_boolean_to_sh
1746
1747 cat > $tempcname < confdefs.h
1748 cat >> $tempcname <<EOF
1749 #define NOT_C_CODE
1750 #define C_SWITCH_SITE
1751 #define C_SWITCH_X_SITE
1752 #define LD_SWITCH_SITE
1753 #define LD_SWITCH_X_SITE
1754 #define LD_SWITCH_X_SITE_AUX
1755 #define OS_RELEASE $os_release
1756
1757 #ifdef config_opsysfile
1758 #include "$srcdir/src/$opsysfile"
1759 #endif
1760
1761 #ifdef config_machfile
1762 #include "$srcdir/src/$machfile"
1763 #endif
1764
1765 CPP_to_sh(LIBS_MACHINE, libs_machine)
1766 CPP_to_sh(LIBS_SYSTEM,  libs_system)
1767 CPP_to_sh(LIBS_TERMCAP, libs_termcap)
1768 CPP_to_sh(LIB_STANDARD, libs_standard)
1769
1770 CPP_to_sh(OBJECTS_MACHINE, objects_machine)
1771 CPP_to_sh(OBJECTS_SYSTEM,  objects_system)
1772
1773 CPP_to_sh(C_SWITCH_MACHINE,   c_switch_machine)
1774 CPP_to_sh(C_SWITCH_SYSTEM,    c_switch_system)
1775
1776 CPP_to_sh(LD_SWITCH_MACHINE,  ld_switch_machine)
1777 CPP_to_sh(LD_SWITCH_SYSTEM,   ld_switch_system)
1778
1779 CPP_to_sh(UNEXEC, unexec, unexec.o)
1780
1781 CPP_to_sh(LD_SWITCH_SHARED, ld_switch_shared, -c)
1782
1783 #define ORDINARY_LD "\$(CC) \$(CFLAGS)"
1784 configure___ ordinary_ld=ORDINARY_LD
1785
1786 #ifdef ORDINARY_LINK
1787 #define LD ORDINARY_LD
1788 #else /* no ORDINARY LINK */
1789 #ifdef COFF_ENCAPSULATE
1790 #define LD "\$(CC) -nostdlib"
1791 #else /* not COFF_ENCAPSULATE */
1792 #ifdef LINKER
1793 #define LD LINKER
1794 #else /* ! defined (LINKER) */
1795 #define LD "ld"
1796 #endif /* ! defined (LINKER) */
1797 #endif /* ! defined (COFF_ENCAPSULATE) */
1798 #endif /* not ORDINARY_LINK */
1799 configure___ ld=LD
1800
1801 CPP_to_sh(LIB_GCC, lib_gcc)
1802 CPP_to_sh(LD_TEXT_START_ADDR, ld_text_start_addr)
1803
1804 #if ! defined (ORDINARY_LINK) && !defined (START_FILES)
1805 #ifdef NO_REMAP
1806 #ifdef COFF_ENCAPSULATE
1807 #define START_FILES "pre-crt0.o /usr/local/lib/gcc-crt0.o"
1808 #else /* ! defined (COFF_ENCAPSULATE) */
1809 #define START_FILES "pre-crt0.o /lib/crt0.o"
1810 #endif /* ! defined (COFF_ENCAPSULATE) */
1811 #else /* ! defined (NO_REMAP) */
1812 #define START_FILES "ecrt0.o"
1813 #endif /* ! defined (NO_REMAP) */
1814 #endif /* no ORDINARY_LINK */
1815 #ifndef START_FILES
1816 #define START_FILES
1817 #endif
1818 configure___ start_files=START_FILES
1819
1820 CPP_boolean_to_sh(ORDINARY_LINK, ordinary_link)
1821 CPP_boolean_to_sh(SYSTEM_MALLOC, system_malloc)
1822 CPP_boolean_to_sh(TERMINFO, have_terminfo)
1823 dnl The MAIL_USE_xxx variables come from the s&m headers
1824 CPP_boolean_to_sh(MAIL_USE_FLOCK, mail_use_flock)
1825 CPP_boolean_to_sh(MAIL_USE_LOCKF, mail_use_lockf)
1826 CPP_boolean_to_sh(MAIL_USE_LOCKING, mail_use_locking)
1827 CPP_boolean_to_sh(HAVE_WIN32_PROCESSES, win32_processes)
1828 EOF
1829
1830 dnl The value of CPP is a quoted variable reference, so we need to do this
1831 dnl to get its actual value...
1832 CPP=`eval "echo $CPP $CPPFLAGS"`
1833 define(TAB, [   ])dnl
1834 changequote(, )dnl
1835 eval `$CPP -Isrc $tempcname \
1836         | sed -n -e "s/[ TAB]*=[ TAB\"]*/='/" -e "s/[ TAB\"]*\$/'/" -e "s/^configure___//p"`
1837 changequote([, ])dnl
1838
1839 rm $tempcname
1840
1841 if test "$pdump" = "yes"; then
1842   ordinary_link="yes"
1843   ld="${ordinary_ld}"
1844   start_files=
1845   libs_standard=
1846   unexec=
1847   lib_gcc=
1848 fi
1849
1850 dnl For debugging...
1851 test "$extra_verbose" = "yes" && \
1852   PRINT_VAR(libs_machine libs_system libs_termcap libs_standard
1853   objects_machine objects_system c_switch_machine c_switch_system
1854   ld_switch_machine ld_switch_system unexec ld_switch_shared
1855   ld lib_gcc ld_text_start_addr start_files ordinary_link
1856   have_terminfo mail_use_flock mail_use_lockf) && echo ""
1857
1858 dnl Pick up mingw include path
1859 dnl We only cope with headers in mingw, not mingw32: no previous version of
1860 dnl XEmacs supported mingw and cygnus have made this incompatible change
1861 dnl so we just go with the flow.
1862 case "$opsys" in mingw* | cygwin*)
1863   cygwin_include=`eval "gcc -print-file-name=libc.a"` ;
1864   cygwin_include=`eval "dirname $cygwin_include"` ;
1865   cygwin_include="-I$cygwin_include/../include" ;
1866   extra_includes="$cygwin_include/mingw $cygwin_include" ;
1867   case "$opsys" in mingw*)
1868     XE_APPEND($extra_includes, c_switch_system) ;;
1869   esac
1870   ;;
1871 esac
1872
1873 dnl Non-ordinary link usually requires -lc
1874 test "$ordinary_link" = "no" -a -z "$libs_standard" && libs_standard="-lc"
1875
1876 dnl -----------------------
1877 dnl Compiler-specific hacks
1878 dnl -----------------------
1879
1880 dnl DEC C `-std1' means ANSI C mode
1881 test "$__DECC" = "yes" && XE_APPEND(-std1, c_switch_site)
1882
1883 dnl Some versions of SCO native compiler need -Kalloca
1884 if test "$__USLC__" = yes; then
1885   AC_MSG_CHECKING(for whether the -Kalloca compiler flag is needed)
1886   need_kalloca=no
1887   AC_TRY_LINK([], [void *x = alloca(4);], [:], [
1888     xe_save_c_switch_system="$c_switch_system"
1889     c_switch_system="$c_switch_system -Kalloca"
1890     AC_TRY_LINK([], [void *x = alloca(4);], [ need_kalloca=yes ])
1891     c_switch_system="$xe_save_c_switch_system"])
1892   AC_MSG_RESULT($need_kalloca)
1893   test "$need_kalloca" = "yes" && XE_APPEND(-Kalloca,c_switch_system)
1894 fi
1895
1896 dnl Calculate value of CFLAGS:
1897 dnl Use either command line flag, environment var, or autodetection
1898 if test "$cflags_specified" = "no"; then
1899   dnl Following values of CFLAGS are known to work well.
1900   dnl Should we take debugging options into consideration?
1901   if   test "$GCC" = "yes"; then
1902     CFLAGS="-g -O3 -Wall -Wno-switch -Winline -Wmissing-prototypes"
1903     dnl Yuck, bad compares have been worth at least 3 crashes!
1904     CFLAGS="$CFLAGS -Wsign-compare"
1905     dnl You get five zillion shadowing warnings with g++.
1906     dnl Even with gcc, -Wshadow is questionable because of its complaints
1907     dnl about parameters with the same names as global functions.
1908     if test "$xemacs_compiler" != "g++"; then
1909       CFLAGS="$CFLAGS -Wshadow"
1910     fi
1911     dnl glibc is intentionally not `-Wpointer-arith'-clean.
1912     dnl Ulrich Drepper has rejected patches to fix the glibc header files.
1913     test "$have_glibc" != "yes" && CFLAGS="$CFLAGS -Wpointer-arith"
1914     dnl I'm not convinced this is a good idea any more. -sb
1915     dnl test "$opsys $machine" = "linux intel386" && \
1916     dnl CFLAGS="$CFLAGS -fno-strength-reduce -malign-loops=2 -malign-jumps=2 -malign-functions=2"
1917   elif test "$__SUNPRO_C" = "yes"; then
1918     case "$opsys" in
1919       sol2    ) CFLAGS="-v -xO4" ;;
1920       sunos4* ) CFLAGS="-xO2";;
1921     esac
1922   elif test "$__DECC" = "yes"; then
1923     CFLAGS="-O3"
1924   elif test "$CC" = "xlc"; then
1925     CFLAGS="-g -O3 -qstrict -qnoansialias -qlibansi -qinfo -qro -qmaxmem=20000"
1926   dnl ### Add optimal CFLAGS support for other compilers HERE!
1927   else
1928     CFLAGS="-O" ;dnl The only POSIX-approved flag
1929   fi
1930 fi
1931
1932 dnl Search for GCC specific build problems we know about
1933 if test "$GCC" = "yes"; then
1934 AC_MSG_CHECKING(for buggy gcc versions)
1935 GCC_VERSION=`$CC --version`
1936 case `uname -s`:`uname -m`:$GCC_VERSION in
1937         dnl egcs 2.90.21 (egcs-1.00 release)
1938         dnl egcs 2.90.29 (egcs-1.0.3 release)
1939     *:sun4*:2.8.1|*:sun4*:egcs-2.90.*)
1940         dnl Don't use -O2 with gcc 2.8.1 and egcs 1.0 under SPARC architectures
1941         dnl without also using `-fno-schedule-insns'.
1942         case "$CFLAGS" in
1943             *-O2*|*-O3*)
1944                 case "$CFLAGS" in
1945                     *-fno-schedule-insns*) ;;
1946                     *)
1947                         AC_MSG_RESULT(yes)
1948                         AC_MSG_WARN(Don't use -O2 with gcc 2.8.1 and egcs 1.0 under SPARC architectures)
1949                         AC_MSG_WARN(without also using -fno-schedule-insns.)
1950                         AC_MSG_ERROR(Aborting due to known problem)
1951                         ;;
1952                 esac
1953                 ;;
1954         esac
1955         ;;
1956         dnl egcs-2.91.57 (egcs-1.1 release)
1957         dnl egcs-2.91.66 (egcs-1.1.2 release)
1958     Linux:alpha:egcs-2.91.*)
1959         AC_MSG_RESULT(yes)
1960         AC_MSG_WARN(There have been reports of egcs-1.1 not compiling XEmacs correctly on)
1961         AC_MSG_WARN(Alpha Linux.  There have also been reports that egcs-1.0.3a is O.K.)
1962         AC_MSG_ERROR(Aborting due to known problem)
1963         ;;
1964     *:i*86*:2.7.2*)
1965         case "$CFLAGS" in
1966             *-O2*|*-O3*)
1967                 case "$GCC_VERSION" in
1968                     2.7.2)
1969                         case "$CFLAGS" in
1970                             *-fno-strength-reduce*) ;;
1971                             *)
1972                                 AC_MSG_RESULT(yes)
1973                                 AC_MSG_WARN(Don't use -O2 with gcc 2.7.2 under Intel/XXX without also using)
1974                                 AC_MSG_WARN(-fno-strength-reduce.)
1975                                 AC_MSG_ERROR(Aborting due to known problem)
1976                                 ;;
1977                         esac
1978                         ;;
1979                 esac
1980                 case "$CFLAGS" in
1981                  *-fno-caller-saves*) ;;
1982                  *)
1983                     AC_MSG_RESULT(yes)
1984                     AC_MSG_WARN(Don't use -O2 with gcc 2.7.2 under Intel/XXX without also using)
1985                     AC_MSG_WARN(-fno-caller-saves.)
1986                     AC_MSG_ERROR(Aborting due to known problem)
1987                     ;;
1988                 esac
1989                 ;;
1990         esac
1991         ;;
1992 esac
1993 AC_MSG_RESULT(no)
1994 fi
1995
1996 dnl Inform compiler that certain flags are meant for the linker
1997 dnl XE_PROTECT_LINKER_FLAGS(shell_var)
1998 define([XE_PROTECT_LINKER_FLAGS], [
1999 if test "$GCC" = "yes"; then
2000   set x $[$1]; shift; [$1]=""
2001   while test -n "[$]1"; do
2002     case [$]1 in
2003       -L  | -l  | -u               ) [$1]="$[$1] [$]1 [$]2"; shift ;;
2004       -L* | -l* | -u* | -Wl* | -pg ) [$1]="$[$1] [$]1" ;;
2005       -Xlinker* ) ;;
2006       * ) [$1]="$[$1] -Xlinker [$]1" ;;
2007     esac
2008     shift
2009   done
2010 fi])dnl
2011 XE_PROTECT_LINKER_FLAGS(ld_switch_system)
2012 XE_PROTECT_LINKER_FLAGS(ld_switch_machine)
2013 XE_PROTECT_LINKER_FLAGS(LDFLAGS)
2014 XE_PROTECT_LINKER_FLAGS(ld_call_shared)
2015
2016 dnl Add s&m-determined objects (including unexec) to link line
2017 test -n "$objects_machine" && XE_ADD_OBJS($objects_machine)
2018 test -n "$objects_system"  && XE_ADD_OBJS($objects_system)
2019 test -n "$unexec"          && test ! "$pdump" = "yes" && XE_ADD_OBJS($unexec)
2020 test "$pdump" = "yes" && XE_ADD_OBJS(dumper.o)
2021
2022 dnl Dynodump (Solaris 2.x, x<6)
2023 AC_MSG_CHECKING(for dynodump)
2024 if test "$unexec" != "unexsol2.o"; then
2025   AC_MSG_RESULT(no)
2026 else
2027   AC_MSG_RESULT(yes)
2028   AC_DEFINE(DYNODUMP)
2029   XE_APPEND(dynodump, MAKE_SUBDIR)
2030   XE_APPEND(dynodump, SRC_SUBDIR_DEPS)
2031   case "$machine" in
2032     sparc   ) dynodump_arch=sparc ;;
2033     *86*    ) dynodump_arch=i386  ;;
2034     powerpc ) dynodump_arch=ppc   ;;
2035   esac
2036   dnl Dynodump requires the system linker
2037   test "$GCC" = "yes" && XE_APPEND(-fno-gnu-linker, ld_switch_site)
2038 fi
2039
2040 dnl Feed s&m crud to src/Makefile
2041
2042 dnl Linux/powerpc needs the following magic for some reason
2043 test "$machine$opsys" = "powerpclinux" && start_flags="-T $srcdir/src/ppc.ldscript"
2044
2045 if test "$unexec" = "unexaix.o"; then
2046 dnl AIX needs various hacks to make static linking work.
2047   if   test "$dynamic" = "no"; then
2048   start_flags="-Wl,-bnso,-bnodelcsect"
2049   test "$GCC" = "yes" && start_flags="-B/bin/ ${start_flags}"
2050   for f in "/lib/syscalls.exp" "/lib/threads.exp"; do
2051     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; fi
2052   done
2053   for f in "/usr/lpp/X11/bin/smt.exp" "/usr/bin/X11/smt.exp"; do
2054     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; break; fi
2055   done
2056   AC_CHECK_LIB(C, terminateAndUnload, XE_APPEND(-lC, libs_system))
2057   fi
2058 elif test -n "$ld_text_start_addr"; then
2059   start_flags="-T $ld_text_start_addr -e __start"
2060 fi
2061 AC_SUBST(start_flags)
2062
2063 AC_SUBST(ld_switch_shared)
2064 AC_SUBST(start_files)
2065 if test "$ordinary_link" = "no" -a "$GCC" = "yes"; then
2066  test -z "$linker" &&  linker='$(CC) -nostdlib'
2067  test -z "$lib_gcc" && lib_gcc='`$(CC) -print-libgcc-file-name`'
2068 fi
2069 test "$GCC" != "yes" && lib_gcc=
2070 AC_SUBST(ld)
2071 AC_SUBST(lib_gcc)
2072
2073 dnl ---------------------------------------------------------------
2074 dnl Add site and system specific flags to compile and link commands
2075 dnl ---------------------------------------------------------------
2076
2077 dnl Allow use of either ":" or spaces for lists of directories
2078 define(COLON_TO_SPACE,
2079   [case "$[$1]" in *:* [)] [$1]="`echo '' $[$1] | sed -e 's/^ //' -e 's/:/ /g'`";; esac])dnl
2080
2081 dnl --site-libraries (multiple dirs)
2082 COLON_TO_SPACE(site_libraries)
2083 if test -n "$site_libraries"; then
2084   for arg in $site_libraries; do
2085     case "$arg" in
2086      -* ) ;;
2087      * ) test -d "$arg" || \
2088            XE_DIE("Invalid site library \`$arg': no such directory")
2089        arg="-L${arg}" ;;
2090     esac
2091     XE_APPEND($arg, ld_switch_site)
2092   done
2093 fi
2094
2095 dnl --site-includes (multiple dirs)
2096 COLON_TO_SPACE(site_includes)
2097 if test -n "$site_includes"; then
2098   for arg in $site_includes; do
2099     case "$arg" in
2100       -* ) ;;
2101       * ) test -d "$arg" || \
2102            XE_DIE("Invalid site include \`$arg': no such directory")
2103       arg="-I${arg}" ;;
2104     esac
2105     XE_APPEND($arg, c_switch_site)
2106   done
2107 fi
2108
2109 dnl --site-prefixes (multiple dirs)
2110 dnl --site-prefixes=dir1:dir2 is a convenient shorthand for
2111 dnl --site-libraries=dir1/lib:dir2/lib --site-includes=dir1/include:dir2/include
2112 dnl Site prefixes take precedence over the standard places, but not over
2113 dnl site-includes and site-libraries.
2114 COLON_TO_SPACE(site_prefixes)
2115 if test -n "$site_prefixes"; then
2116   for dir in $site_prefixes; do
2117     lib_dir="${dir}/lib"
2118     inc_dir="${dir}/include"
2119     if test ! -d "$dir"; then
2120       XE_DIE("Invalid site prefix \`$dir': no such directory")
2121     elif test ! -d "$lib_dir"; then
2122       XE_DIE("Invalid site prefix \`$dir': no such directory \`$lib_dir'")
2123     else
2124       if test -d "$inc_dir"; then
2125         XE_APPEND("-I$inc_dir", c_switch_site)
2126       fi
2127       XE_APPEND("-L$lib_dir", ld_switch_site)
2128     fi
2129   done
2130 fi
2131
2132 dnl GNU software installs by default into /usr/local/{include,lib}
2133 dnl if test -d "/usr/local/include" -a -d "/usr/local/lib"; then
2134 dnl   XE_APPEND("-L/usr/local/lib",    ld_switch_site)
2135 dnl   XE_APPEND("-I/usr/local/include", c_switch_site)
2136 dnl fi
2137
2138 dnl Extra system-specific library directories - please add to list
2139 for dir in "/usr/ccs/lib"; do
2140   test -d "$dir" && XE_APPEND(-L${dir}, ld_switch_system)
2141 done
2142
2143 dnl --site-runtime-libraries (multiple dirs)
2144 COLON_TO_SPACE(site_runtime_libraries)
2145 if test -n "$site_runtime_libraries"; then
2146   LD_RUN_PATH="`echo $site_runtime_libraries | sed -e 's/  */:/g'`"
2147   export LD_RUN_PATH
2148 fi
2149
2150 dnl Linux systems have dynamic runtime library directories listed in
2151 dnl /etc/ld.so.conf.  Since those are used at run time, it seems pretty
2152 dnl safe to use them at link time, and less controversial than forcing
2153 dnl the run-time to use the link-time libraries.  This also helps avoid
2154 dnl mismatches between the link-time and run-time libraries.
2155
2156 dnl #### Unfortunately, there are horrible libc4 and libc5 libraries
2157 dnl listed in /etc/ld.so.conf on some systems, and including them on
2158 dnl the link path leads to linking in utterly broken libc's.
2159 dnl There are many clever ways of approaching this problem,
2160 dnl but finding one that actually works...
2161
2162 dnl if test -z "$LD_RUN_PATH" -a -r "/etc/ld.so.conf"; then
2163 dnl   for dir in `cat /etc/ld.so.conf`; do
2164 dnl     test -d "$dir" && XE_APPEND(-L${dir}, ld_switch_system)
2165 dnl   done
2166 dnl   add_runtime_path=no
2167 dnl fi
2168
2169 dnl -------------------------------------
2170 dnl Compute runtime library path
2171 dnl -------------------------------------
2172
2173 if test -n "$add_runtime_path"; then :;
2174 elif test "$dynamic" = "no"; then add_runtime_path=no
2175 elif test -n "$LD_RUN_PATH"; then add_runtime_path=yes
2176 else case "$opsys" in
2177        sol2 | irix* | *bsd* | decosf* ) add_runtime_path=yes ;;
2178        * ) add_runtime_path=no ;;
2179      esac
2180 fi
2181
2182 if test "$add_runtime_path" = "yes"; then
2183   dnl Try to autodetect runtime library flag (usually -R),
2184   dnl and whether it works (or at least does no harm)
2185   AC_MSG_CHECKING("for runtime libraries flag")
2186   case "$opsys" in
2187     sol2 ) dash_r="-R" ;;
2188     decosf* | linux* | irix*) dash_r="-rpath " ;;
2189     *)
2190       dash_r=""
2191       for try_dash_r in "-R" "-R " "-rpath "; do
2192         xe_check_libs="${try_dash_r}/no/such/file-or-directory"
2193         XE_PROTECT_LINKER_FLAGS(xe_check_libs)
2194         AC_TRY_LINK(, , dash_r="$try_dash_r")
2195         xe_check_libs=""
2196         test -n "$dash_r" && break
2197       done ;;
2198   esac
2199   if test -n "$dash_r";
2200     then AC_MSG_RESULT("\"${dash_r}\"")
2201     else AC_MSG_RESULT(NONE)
2202   fi
2203 fi
2204
2205 xe_add_unique_runpath_dir='
2206   xe_add_p=yes
2207   for xe_dir in $runpath_dirs; do   dnl Uniquify
2208     test "$xe_dir" = "$xe_runpath_dir" && xe_add_p=no
2209   done
2210   if test "$xe_add_p" = "yes"; then
2211     test -n "$runpath" && runpath="${runpath}:"
2212     runpath="${runpath}${xe_runpath_dir}"
2213     runpath_dirs="$runpath_dirs $xe_runpath_dir"
2214   fi'
2215
2216
2217 dnl XE_ADD_RUNPATH_DIR(directory)
2218 define([XE_ADD_RUNPATH_DIR],[{
2219 xe_runpath_dir=$1
2220 dnl PRINT_VAR(ld_switch_site ld_switch_x_site runpath xe_runpath_dir LD_RUN_PATH xe_ldflags)
2221   test "$xe_runpath_dir" != "/lib"     -a \
2222         "$xe_runpath_dir" != "/usr/lib" -a \
2223         -n "`ls ${xe_runpath_dir}/*.s[[ol]] 2>/dev/null`" && \
2224   eval "$xe_add_unique_runpath_dir"
2225 }])dnl
2226
2227 dnl XE_COMPUTE_RUNPATH()
2228 define([XE_COMPUTE_RUNPATH],[
2229 if test "$add_runtime_path" = "yes" -a -n "$dash_r"; then
2230   dnl Remove runtime paths from current ld switches
2231   ld_switch_site=`echo   '' $ld_switch_site   | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
2232   ld_switch_x_site=`echo '' $ld_switch_x_site | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
2233   dnl PRINT_VAR(ld_switch_site ld_switch_x_site)
2234
2235   dnl Fix up Runtime path
2236   dnl If LD_RUN_PATH is set in environment, use that.
2237   dnl In this case, assume user has set the right value.
2238   runpath="" runpath_dirs=""
2239   if test -n "$LD_RUN_PATH"; then
2240     runpath="$LD_RUN_PATH"
2241   elif test "$GCC" = "yes"; then
2242     dnl Compute runpath from gcc's -v output
2243     ld_switch_run_save="$ld_switch_run"; ld_switch_run=""
2244     echo "int main(int argc, char *argv[[]]) {return 0;}" > conftest.c
2245     xe_runpath_link='${CC-cc} -o conftest -v $CFLAGS '"$xe_ldflags"' conftest.$ac_ext 2>&1 1>/dev/null'
2246     for arg in `eval "$xe_runpath_link" | grep ' -L'`; do
2247       case "$arg" in P,* | -L* | -R* )
2248         for dir in `echo '' "$arg" | sed -e 's:^ ::' -e 's/^..//' -e 'y/:/ /'`; do
2249           XE_ADD_RUNPATH_DIR("$dir")
2250         done ;;
2251       esac
2252     done
2253     ld_switch_run="$ld_switch_run_save"
2254     rm -f conftest*
2255   else
2256     dnl Add all directories with .so files to runpath
2257     for arg in $ld_switch_site $ld_switch_x_site; do
2258       case "$arg" in -L*) XE_ADD_RUNPATH_DIR(`echo '' "$arg" | sed -e 's:^ ::' -e 's/^-L//'`);; esac
2259     done
2260     dnl Sometimes /opt/SUNWdt/lib is the only installed Motif available
2261     if test "$opsys $need_motif" = "sol2 yes"; then
2262       xe_runpath_dir="/opt/SUNWdt/lib";
2263       eval "$xe_add_unique_runpath_dir";
2264     fi
2265   fi dnl Compute $runpath
2266
2267   if test -n "$runpath"; then
2268     ld_switch_run="${dash_r}${runpath}"
2269     XE_PROTECT_LINKER_FLAGS(ld_switch_run)
2270     test "$extra_verbose" = "yes" && echo "Setting runpath to $runpath"
2271   fi
2272 fi
2273 ])dnl
2274 XE_COMPUTE_RUNPATH()
2275
2276 dnl -----------------------------------
2277 dnl Do some misc autoconf-special tests
2278 dnl -----------------------------------
2279
2280 dnl Do the opsystem or machine files prohibit the use of the GNU malloc?
2281 dnl Assume not, until told otherwise.
2282 GNU_MALLOC=yes
2283 if test "$with_dlmalloc" != "no"; then
2284         doug_lea_malloc=yes
2285 else
2286         doug_lea_malloc=no
2287 fi
2288 after_morecore_hook_exists=yes
2289 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
2290 AC_MSG_CHECKING(whether __after_morecore_hook exists)
2291 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
2292   [AC_MSG_RESULT(yes)],
2293   [AC_MSG_RESULT(no)
2294    after_morecore_hook_exists=no])
2295 if test "$system_malloc" = "yes" ; then
2296   GNU_MALLOC=no
2297   GNU_MALLOC_reason="
2298     - The GNU allocators don't work with this system configuration."
2299 elif test "$with_system_malloc" = "yes" ; then
2300   GNU_MALLOC=no
2301   GNU_MALLOC_reason="
2302     - User chose not to use GNU allocators."
2303 elif test "$with_debug_malloc" = "yes" ; then
2304   GNU_MALLOC=no
2305   GNU_MALLOC_reason="
2306     - User chose to use Debugging Malloc."
2307 fi
2308
2309 if test "$doug_lea_malloc" = "yes" -a "$GNU_MALLOC" = "yes" ; then
2310   GNU_MALLOC_reason="
2311     - Using Doug Lea's new malloc from the GNU C Library."
2312   AC_DEFINE(DOUG_LEA_MALLOC)
2313   if test "$after_morecore_hook_exists" = "no" ; then
2314     GNU_MALLOC_reason="
2315     - Using Doug Lea's new malloc from the Linux C Library."
2316     AC_DEFINE(_NO_MALLOC_WARNING_)
2317   fi
2318 fi
2319
2320 dnl #### mcheck is broken in all versions of Linux libc and glibc.
2321 dnl Try this again when 2.1 hits the streets.
2322 dnl Avoid using free-hook.c if support exists for malloc debugging in libc
2323 dnl have_libmcheck=no
2324 dnl if test "$error_check_malloc" = "yes" -a \
2325 dnl    "$have_glibc" = "yes" -a \
2326 dnl    "$doug_lea_malloc" = "yes"; then
2327 dnl   AC_CHECK_HEADERS(mcheck.h)
2328 dnl   AC_CHECK_LIB(mcheck, mcheck, have_libmcheck=yes, have_libmcheck=no)
2329 dnl fi
2330
2331 dnl if test "$have_libmcheck" = "yes"; then
2332 dnl   AC_DEFINE(HAVE_LIBMCHECK)
2333 dnl   libmcheck=-lmcheck
2334 dnl   AC_SUBST(libmcheck)
2335 dnl fi
2336
2337 dnl Some other nice autoconf tests.  If you add a test here which
2338 dnl should make an entry in src/config.h, do not forget to add an
2339 dnl #undef clause to src/config.h.in for autoconf to modify.
2340
2341 AC_PROG_RANLIB
2342 AC_PROG_INSTALL
2343 AC_PROG_YACC
2344
2345 dnl checks for header files
2346 AC_CHECK_HEADERS(dnl
2347   a.out.h dnl
2348   elf.h dnl
2349   cygwin/version.h dnl
2350   fcntl.h dnl
2351   inttypes.h dnl
2352   libgen.h dnl
2353   locale.h dnl
2354   mach/mach.h dnl
2355   sys/param.h dnl
2356   sys/pstat.h dnl
2357   sys/time.h dnl
2358   sys/timeb.h dnl
2359   sys/un.h dnl
2360   ulimit.h dnl
2361   unistd.h dnl
2362 )
2363 AC_HEADER_SYS_WAIT
2364 AC_HEADER_STDC
2365 AC_HEADER_TIME
2366 AC_DECL_SYS_SIGLIST
2367
2368
2369 dnl ----------------------------------------------------------------
2370 dnl Checking for utime() or utimes().
2371 dnl We prefer utime, since it is more standard.
2372 dnl Some systems have utime.h but do not declare the struct anyplace,
2373 dnl so we use a more sophisticated test for utime than AC_CHECK_FUNCS.
2374 dnl ----------------------------------------------------------------
2375 AC_MSG_CHECKING(for utime)
2376 AC_TRY_COMPILE([#include <sys/types.h>
2377 #include <utime.h>],
2378 [struct utimbuf x; x.actime = x.modtime = 0; utime ("/", &x);],
2379   [AC_MSG_RESULT(yes)
2380    AC_DEFINE(HAVE_UTIME)],
2381   [AC_MSG_RESULT(no)
2382    dnl We don't have utime(); how about utimes()?
2383    AC_CHECK_FUNCS(utimes)])
2384
2385
2386 dnl checks for typedefs
2387 AC_TYPE_SIGNAL
2388 AC_TYPE_SIZE_T
2389 AC_TYPE_PID_T
2390 AC_TYPE_UID_T
2391 AC_TYPE_MODE_T
2392 AC_TYPE_OFF_T
2393 AC_CHECK_TYPE(ssize_t, int)
2394
2395 dnl check for Unix98 socklen_t
2396 AC_MSG_CHECKING(for socklen_t)
2397 AC_TRY_COMPILE([#include <sys/socket.h>
2398 socklen_t x;
2399 ],[],[AC_MSG_RESULT(yes)],[
2400 AC_TRY_COMPILE([#include <sys/socket.h>
2401 int accept (int, struct sockaddr *, size_t *);
2402 ],[],[
2403 AC_MSG_RESULT(size_t)
2404 AC_DEFINE(socklen_t,size_t)], [
2405 AC_MSG_RESULT(int)
2406 AC_DEFINE(socklen_t,int)])])
2407
2408 AC_MSG_CHECKING(for struct timeval)
2409 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
2410 #include <sys/time.h>
2411 #include <time.h>
2412 #else
2413 #ifdef HAVE_SYS_TIME_H
2414 #include <sys/time.h>
2415 #else
2416 #include <time.h>
2417 #endif
2418 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
2419   [AC_MSG_RESULT(yes)
2420   HAVE_TIMEVAL=yes
2421   AC_DEFINE(HAVE_TIMEVAL)],
2422   [AC_MSG_RESULT(no)
2423    HAVE_TIMEVAL=no])
2424
2425 dnl checks for structure members
2426 AC_STRUCT_TM
2427 AC_STRUCT_TIMEZONE
2428
2429 dnl checks for compiler characteristics
2430 AC_C_CONST
2431
2432 dnl check for Make feature
2433 AC_PROG_MAKE_SET
2434
2435 dnl check byte order
2436 AC_C_BIGENDIAN
2437
2438 dnl define SIZEOF_TYPE
2439 AC_CHECK_SIZEOF(short)
2440 if test "$ac_cv_sizeof_short" = 0; then
2441   echo ""
2442   echo "*** PANIC *** Configure tests are not working - compiler is broken."
2443   echo "*** PANIC *** Please examine config.log for compilation errors."
2444   exit 1
2445 fi
2446 AC_CHECK_SIZEOF(int)
2447 AC_CHECK_SIZEOF(long)
2448 AC_CHECK_SIZEOF(long long)
2449 AC_CHECK_SIZEOF(void *)
2450
2451 dnl check for long file names
2452 AC_SYS_LONG_FILE_NAMES
2453
2454 dnl -lm is required by LISP_FLOAT_TYPE, among other things
2455 AC_CHECK_FUNC(sin, ,AC_CHECK_LIB(m, sin))
2456
2457 dnl Floating operation support is now unconditional
2458 AC_DEFINE(LISP_FLOAT_TYPE)
2459
2460 AC_TRY_LINK([#include <math.h>],
2461   [return atanh(1.0) + asinh(1.0) + acosh(1.0); ],
2462   AC_DEFINE(HAVE_INVERSE_HYPERBOLIC))
2463
2464 dnl Determine type of mail locking from configure args and s&m headers
2465 AC_CHECKING(type of mail spool file locking)
2466 AC_CHECK_FUNCS(lockf flock)
2467 dnl The mail_use_xxx variables are set according to the s&m headers.
2468 test -z "$mail_locking" -a "$mail_use_flock" = "yes" && mail_locking=flock
2469 test -z "$mail_locking" -a "$mail_use_lockf" = "yes" && mail_locking=lockf
2470 test -z "$mail_locking" -a "$mail_use_locking" = "yes" && mail_locking=locking
2471 if   test -z "$mail_locking"; then
2472   case "$opsys" in cygwin* | mingw*)
2473     mail_locking=pop ;;
2474   esac
2475 fi
2476
2477 if   test "$mail_locking" = "lockf"; then AC_DEFINE(MAIL_LOCK_LOCKF)
2478 elif test "$mail_locking" = "flock"; then AC_DEFINE(MAIL_LOCK_FLOCK)
2479 elif test "$mail_locking" = "locking"; then AC_DEFINE(MAIL_LOCK_LOCKING)
2480 elif test "$mail_locking" = "pop"; then
2481   with_pop=yes
2482   mail_locking=
2483 else mail_locking="dot-locking"; AC_DEFINE(MAIL_LOCK_DOT)
2484 fi
2485 test "$mail_locking" = "lockf" -a "$ac_cv_func_lockf" != "yes" && \
2486   XE_DIE("lockf mail locking requested but not available.")
2487 test "$mail_locking" = "flock" -a "$ac_cv_func_flock" != "yes" && \
2488   XE_DIE("flock mail locking requested but not available.")
2489 test "$mail_locking" = "locking" -a "$ac_cv_func_locking" != "yes" && \
2490   XE_DIE("locking mail locking requested but not available.")
2491
2492 case "$opsys" in decosf*)
2493   AC_CHECK_LIB(pthreads, cma_open)
2494   test "$ac_cv_lib_pthreads_cma_open" = "yes" && \
2495     c_switch_site="$c_switch_site -threads" ;;
2496 esac
2497
2498 dnl ----------------------------------------------------------------
2499 dnl Miscellaneous flags
2500 dnl ----------------------------------------------------------------
2501
2502 AC_MSG_CHECKING(whether the -xildoff compiler flag is required)
2503 if   ${CC-cc} '-###' -xildon  no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ; then
2504   if ${CC-cc} '-###' -xildoff no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ;
2505     then AC_MSG_RESULT(no);
2506     else AC_MSG_RESULT(yes); XE_APPEND(-xildoff, ld_switch_site)
2507   fi
2508   else AC_MSG_RESULT(no)
2509 fi
2510
2511 dnl Link with "-z ignore" on Solaris if supported
2512 if test "$opsys" = "sol2"; then
2513   if test "$os_release" -ge 56; then
2514     AC_MSG_CHECKING(for \"-z ignore\" linker flag)
2515     case "`ld -h 2>&1`" in
2516       *-z\ ignore\|record* ) AC_MSG_RESULT(yes)
2517         XE_PREPEND(-z ignore, ld_switch_site) ;;
2518       *) AC_MSG_RESULT(no) ;;
2519     esac
2520   fi
2521 fi
2522
2523 dnl GNU ld now defaults to combreloc, which screws up unexec, but not pdump.
2524 dnl Note that it's OK if the GNU style long option causes non-GNU ld to barf
2525 dnl a usage message, that's often good enough.  Please report it, though.
2526 dnl #### Should make this Solaris-friendly.
2527 dnl Link with -z nocombreloc for now.
2528 if test "$pdump" != "yes"; then
2529   AC_MSG_CHECKING(for \"-z nocombreloc\" linker flag)
2530   case "`ld --help 2>&1`" in
2531     *-z\ nocombreloc* ) AC_MSG_RESULT(yes)
2532       XE_PREPEND(-z nocombreloc, ld_switch_site) ;;
2533     *) AC_MSG_RESULT(no) ;;
2534   esac
2535 fi
2536
2537 dnl ----------------------
2538 dnl Choose a window system
2539 dnl ----------------------
2540
2541 AC_CHECKING("for specified window system")
2542
2543 dnl Autodetection of Gdk libraries and includes
2544 dnl -------------------------------------------
2545 dnl On some systems (FreeBSD springs to mind), they use
2546 dnl versions on the utility routines, so instead of gtk-config
2547 dnl you must use gtk12-config, etc, etc.
2548
2549 GNOME_CONFIG=no
2550 GTK_CONFIG=no
2551
2552 if test "$with_gnome" != "no"; then
2553    AC_MSG_CHECKING(for GNOME configuration script)
2554    for possible in gnome-config
2555    do
2556       possible_version=`${possible} --version 2> /dev/null`
2557       if test "x${possible_version}" != "x"; then
2558               GNOME_CONFIG="${possible}"
2559               with_gnome=yes
2560               with_gtk=yes
2561               break
2562       fi
2563    done
2564    AC_MSG_RESULT([${GNOME_CONFIG}])
2565 fi
2566
2567 if test "${GNOME_CONFIG}" != "no"; then
2568       GNOME_LIBS=`${GNOME_CONFIG} --libs gnomeui`
2569       GNOME_CFLAGS=`${GNOME_CONFIG} --cflags gnomeui`
2570       AC_DEFINE(HAVE_GNOME)
2571       XE_APPEND(${GNOME_LIBS}, libs_gtk)
2572       XE_APPEND(${GNOME_CFLAGS}, c_switch_gtk)
2573 fi
2574
2575 if test "$with_gtk" != "no";then
2576    AC_MSG_CHECKING(for GTK configuration script)
2577    for possible in gtk12-config gtk14-config gtk-config
2578    do
2579       possible_version=`${possible} --version 2> /dev/null`
2580       if test "x${possible_version}" != "x"; then
2581               GTK_CONFIG="${possible}"
2582       fi
2583       case "${possible_version}" in
2584         1.0.*) AC_MSG_WARN([GTK 1.2 is required, please upgrade your version of GTK.]); with_gtk=no;;
2585         1.3.*) AC_MSG_WARN([GTK 1.3 is not supported right now]); with_gtk=no;;
2586         1.2.*)
2587                 with_gtk=yes
2588                 break
2589                 ;;
2590         *)     AC_MSG_WARN([Found unsupported version of GTK: $possible_version]);;
2591       esac
2592    done
2593    AC_MSG_RESULT([${GTK_CONFIG}])
2594 fi
2595
2596 if test "${GTK_CONFIG}" != "no"; then
2597       AC_MSG_CHECKING(gtk version)
2598       GTK_VERSION=`${GTK_CONFIG} --version`
2599       AC_MSG_RESULT(${GTK_VERSION})
2600
2601       AC_MSG_CHECKING(gtk libs)
2602       GTK_LIBS=`${GTK_CONFIG} --libs`
2603       XE_APPEND(${GTK_LIBS}, libs_gtk)
2604       AC_MSG_RESULT(${GTK_LIBS})
2605
2606       AC_MSG_CHECKING(gtk cflags)
2607       GTK_CFLAGS=`${GTK_CONFIG} --cflags`
2608       XE_APPEND(${GTK_CFLAGS}, c_switch_gtk)
2609       AC_MSG_RESULT(${GTK_CFLAGS})
2610
2611       AC_CHECK_LIB(gdk_imlib, main, XE_PREPEND(-lgdk_imlib, libs_gtk))
2612       AC_CHECK_LIB(Imlib, Imlib_init, XE_APPEND(-lImlib, libs_gtk))
2613       AC_CHECK_FUNCS(gdk_imlib_init)
2614
2615       AC_DEFINE(HAVE_XPM)
2616       AC_DEFINE(HAVE_GTK)
2617       AC_SUBST(GTK_CONFIG)
2618
2619       window_system=gtk
2620       with_gtk=yes
2621       with_x11=no
2622
2623       test "${with_scrollbars}" != "no" && with_scrollbars=gtk
2624       test "${with_toolbars}" != no && with_toolbars=gtk
2625       test "${with_menubars}" != "no" && with_menubars=gtk
2626       test "${with_dialogs}" != "no" && with_dialogs=gtk
2627       test "${with_widgets}" != "no" && with_widgets=gtk
2628
2629       XE_ADD_OBJS(console-gtk.o device-gtk.o event-gtk.o frame-gtk.o)
2630       XE_ADD_OBJS(objects-gtk.o redisplay-gtk.o glyphs-gtk.o)
2631       XE_ADD_OBJS(select-gtk.o gccache-gtk.o)
2632       XE_ADD_OBJS(gtk-xemacs.o ui-gtk.o)
2633
2634       dnl Check for libglade support (it rocks)
2635       OLD_CFLAGS="${CFLAGS}"
2636       OLD_CPPFLAGS="${CPPFLAGS}"
2637       OLD_LDFLAGS="${LDFLAGS}"
2638       CFLAGS="${GTK_CFLAGS} ${CFLAGS}"
2639       CPPFLAGS="${GTK_CFLAGS} ${CFLAGS}"
2640       LDFLAGS="${LDFLAGS} ${GTK_LIBS}"
2641       AC_CHECK_HEADERS(glade/glade.h glade.h)
2642       AC_CHECK_LIB(xml, main, XE_PREPEND(-lxml, libs_gtk))
2643       AC_CHECK_LIB(glade, main, XE_PREPEND(-lglade, libs_gtk))
2644       AC_CHECK_LIB(glade-gnome, main, XE_PREPEND(-lglade-gnome, libs_gtk))
2645       AC_EGREP_HEADER([char \*txtdomain;], [glade/glade-xml.h],
2646                       [AC_MSG_RESULT(yes)
2647                        AC_DEFINE(LIBGLADE_XML_TXTDOMAIN,1)],
2648                       [AC_MSG_RESULT(no)])
2649       CFLAGS="${OLD_CFLAGS}"
2650       CPPFLAGS="${OLD_CPPFLAGS}"
2651       LDFLAGS="${OLD_LDFLAGS}"
2652 fi
2653
2654 dnl We may eventually prefer gtk/gdk over vanilla X11...
2655
2656 if test "$with_x11" != "no"; then
2657   dnl User-specified --x-includes or --x-libraries implies --with-x11.
2658   test "$x_includes $x_libraries" != "NONE NONE" && \
2659    window_system=x11 with_x11=yes
2660
2661   dnl Autodetection of X11 libraries and includes
2662   dnl -------------------------------------------
2663   dnl AC_PATH_XTRA thinks it can find our X headers and includes, but
2664   dnl it often gets it wrong, so we only use it as a last resort.
2665
2666   dnl $OPENWINHOME implies --x-includes and --x-libraries
2667   dnl Not (yet) handled by autoconf2
2668   if test "$x_includes $x_libraries" = "NONE NONE" \
2669     -a -n "$OPENWINHOME" \
2670     -a "$OPENWINHOME" != "/usr/openwin" \
2671     -a -d "$OPENWINHOME"; then
2672       test -d "$OPENWINHOME/lib"           && x_libraries="$OPENWINHOME/lib"
2673       test -d "$OPENWINHOME/include"       && x_includes="$OPENWINHOME/include"
2674       test -d "$OPENWINHOME/share/include" && x_includes="$OPENWINHOME/share/include"
2675   fi
2676
2677   if test "$x_includes" = "NONE"; then
2678     dnl AC_PATH_XTRA often guesses /usr/include, when some other
2679     dnl include directory is a MUCH better guess (Linux, HP-UX 10.20).
2680     dnl This is a workaround for idiot (esp. HP) system vendors, who
2681     dnl provide a /usr/include/X11, but DON'T FULLY POPULATE IT.
2682     for dir in "/usr/X11" "/usr/X11R6"; do
2683       if test -d "$dir/include/X11"; then x_includes="$dir/include"; break; fi
2684     done
2685   fi
2686
2687   if test "$x_libraries" = "NONE"; then
2688     for dir in "/usr/X11/lib" "/usr/X11R6/lib" "/usr/lib/X11R6"; do
2689       if test -r "$dir/libX11.a"; then x_libraries="$dir"; break; fi
2690     done
2691   fi
2692
2693   AC_PATH_XTRA # Autoconf claims to find X library and include dirs for us.
2694   if test "$no_x" = "yes"
2695   then with_x11=no  window_system=none HAVE_X_WINDOWS=no
2696   else with_x11=yes window_system=x11  HAVE_X_WINDOWS=yes
2697   fi
2698 fi
2699
2700 dnl #### wmperry:: !x11 != NONE
2701 dnl case "$with_x11" in
2702 dnl  yes ) window_system=x11  HAVE_X_WINDOWS=yes ;;
2703 dnl  no  ) window_system=none HAVE_X_WINDOWS=no  ;;
2704 dnl esac
2705
2706 if test "$with_x11" = "yes"; then
2707   AC_DEFINE(HAVE_X_WINDOWS)
2708   XE_APPEND(lwlib, MAKE_SUBDIR)
2709   XE_APPEND(lwlib, SRC_SUBDIR_DEPS)
2710
2711   dnl Try to find Motif/CDE/Tooltalk dirs
2712   dnl These take precedence over other X libs/includes, so PRE-pend
2713   for lib_dir in "/usr/dt/lib" "/usr/lib/Motif2.1" "/usr/lib/Motif1.2" "/usr/lib/Motif1.1"; do
2714     inc_dir=`echo $lib_dir | sed -e 's/lib/include/'`
2715     if test -d "$lib_dir" -a -d "$inc_dir"; then
2716       case "$x_libraries" in *"$lib_dir"* ) ;; *)
2717         x_libraries="$lib_dir $x_libraries"
2718         XE_PREPEND(-L${lib_dir}, X_LIBS) ;;
2719       esac
2720       case "$x_includes" in "$inc_dir"* ) ;; *)
2721         x_includes="$inc_dir $x_includes"
2722         XE_PREPEND(-I${inc_dir}, X_CFLAGS) ;;
2723       esac
2724       break; dnl only need ONE Motif implementation!
2725       fi
2726   done
2727
2728   dnl Contrib X libs/includes do NOT take precedence, so AP-pend
2729   for rel in "X11R6" "X11R5" "X11R4"; do
2730     lib_dir="/usr/contrib/$rel/lib" inc_dir="/usr/contrib/$rel/include"
2731     if test -d "$lib_dir" -a -d "$inc_dir"; then
2732       case "$x_libraries" in *"$lib_dir"* ) ;; *)
2733         x_libraries="$x_libraries $lib_dir"
2734         XE_APPEND(-L${lib_dir}, X_LIBS)
2735       esac
2736       case "$x_includes" in "$inc_dir"* ) ;; *)
2737         x_includes="$x_includes $inc_dir"
2738         XE_APPEND(-I${inc_dir}, X_CFLAGS)
2739       esac
2740       break; dnl Only need ONE X11 implementation !
2741     fi
2742   done
2743
2744   dnl Avoid version mismatch for shared library libXm.so on osf4
2745   case "$opsys" in
2746   decosf*) if test "$GCC" = yes -a -d /usr/shlib; then XE_APPEND(-L/usr/shlib, X_LIBS); fi ;;
2747   esac
2748
2749   ld_switch_x_site="$X_LIBS"
2750
2751   XE_COMPUTE_RUNPATH()
2752
2753   if test "$extra_verbose" = "yes"; then
2754     echo; echo "X11 compilation variables:"
2755     PRINT_VAR(x_libraries x_includes X_CFLAGS X_LIBS X_PRE_LIBS X_EXTRA_LIBS)
2756     echo
2757   fi
2758
2759   dnl Set up bitmaps search path.
2760   dnl The original suggestion was to unconditionally to append X11/bitmaps
2761   dnl to each element of $x_includes, I'm pretty sure this is the wrong
2762   dnl thing to do.  We test for bitmaps and X11/bitmaps directories on each
2763   dnl element and add them to BITMAPDIR if they exist.
2764   bitmapdirs=
2765   if test "$x_includes" != NONE; then
2766     for i in $x_includes; do
2767       if test -d "$i/bitmaps"; then
2768         bitmapdirs="$i/bitmaps:$bitmapdirs"
2769       fi
2770       if test -d "$i/X11/bitmaps"; then
2771         bitmapdirs="$i/X11/bitmaps:$bitmapdirs"
2772       fi
2773     done
2774     bitmapdirs=`echo "$bitmapdirs" | sed s/.$//`
2775   fi
2776   test ! -z "$bitmapdirs" && AC_DEFINE_UNQUOTED(BITMAPDIR, "$bitmapdirs")
2777
2778   dnl Autodetect defines extracted from X config by xmkmf, e.g. NARROWPROTO
2779   AC_CHECKING(for X defines extracted by xmkmf)
2780   rm -fr conftestdir
2781   if mkdir conftestdir; then
2782     cd conftestdir
2783     cat > Imakefile <<'EOF'
2784 xetest:
2785         @echo ${PROTO_DEFINES} ${STD_DEFINES}
2786 EOF
2787     if (xmkmf) >/dev/null 2>/dev/null && test -f Makefile; then
2788       # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
2789       xmkmf_defines=`${MAKE-make} xetest 2>/dev/null | grep -v make`
2790     fi
2791     cd ..
2792     rm -fr conftestdir
2793     for word in $xmkmf_defines; do
2794       case "$word" in
2795       -D__STDC__*) ;;
2796       -D* )
2797         sym=`echo '' $word | sed -e 's:^ *-D::' -e 's:=.*::'`
2798         case "$word" in
2799           -D*=* ) val=`echo '' $word | sed -e 's:^.*=::'` ;;
2800           *     ) val=1 ;;
2801         esac
2802 dnl Avoid re-AC_DEFINE-ing xmkmf symbols we've already defined above.
2803         if grep "^#define $sym " confdefs.h >/dev/null; then :; else
2804           if test "$val" = "1"
2805             then AC_DEFINE_UNQUOTED($sym)
2806             else AC_DEFINE_UNQUOTED($sym,$val)
2807           fi
2808         fi  ;;
2809       esac
2810     done
2811   fi
2812
2813   dnl make sure we can find Intrinsic.h
2814   AC_CHECK_HEADER(X11/Intrinsic.h, ,
2815    [AC_MSG_ERROR("Unable to find X11 header files.")])
2816
2817   dnl -lXt and -lX11 are required
2818   dnl Some broken systems require the magic "-b i486-linuxaout" flag
2819   AC_CHECK_LIB(X11, XOpenDisplay, have_lib_x11=yes)
2820   if test "$have_lib_x11" != "yes"; then
2821     AC_CHECK_LIB(X11, XGetFontProperty,
2822       ld_switch_x_site="-b i486-linuxaout $ld_switch_x_site",
2823       [AC_MSG_ERROR("Unable to find X11 libraries.")],
2824       -b i486-linuxaout)
2825   fi
2826   libs_x="-lX11"
2827   test "$extra_verbose" = "yes" && echo "    Setting libs_x to \"-lX11\""
2828
2829   dnl Autodetect -lXext
2830   AC_CHECK_LIB(Xext, XShapeSelectInput, XE_PREPEND(-lXext, libs_x))
2831
2832   dnl Require -lXt
2833   AC_CHECK_LIB(Xt, XtOpenDisplay, XE_PREPEND(-lXt, libs_x),
2834     AC_MSG_ERROR("Unable to find X11 libraries."))
2835
2836   AC_MSG_CHECKING(the version of X11 being used)
2837   AC_TRY_RUN([#include <X11/Intrinsic.h>
2838     int main(int c, char *v[]) { return c>1 ? XlibSpecificationRelease : 0; }],
2839     [./conftest foobar; x11_release=$?],[x11_release=4],[x11_release=4])
2840   AC_MSG_RESULT(R${x11_release})
2841   AC_DEFINE_UNQUOTED(THIS_IS_X11R${x11_release})
2842
2843   if test "${x11_release}" = "4"; then
2844     case "$with_widgets" in
2845       "" | "no") with_widgets=no ;;
2846       *) XE_DIE("Widget support requires X11R5 or greater") ;;
2847     esac
2848   fi
2849
2850   AC_CHECK_FUNCS(XConvertCase)
2851
2852   AC_CHECK_HEADERS(X11/Xlocale.h)
2853
2854   dnl XFree86 has a non-standard prototype for this X11R6 function
2855   AC_CHECK_FUNCS(XRegisterIMInstantiateCallback)
2856   AC_MSG_CHECKING(for standard XRegisterIMInstantiateCallback prototype)
2857   AC_TRY_COMPILE([
2858 #define NeedFunctionPrototypes 1
2859 #include <X11/Xlib.h>
2860 extern Bool XRegisterIMInstantiateCallback(
2861    Display*, struct _XrmHashBucketRec*, char*, char*, XIMProc, XPointer*);
2862 ], [],
2863   [AC_MSG_RESULT(yes)],
2864   [AC_MSG_RESULT(no)
2865    AC_DEFINE(XREGISTERIMINSTANTIATECALLBACK_NONSTANDARD_PROTOTYPE)])
2866
2867   dnl autodetect -lXmu
2868   test -z "$with_xmu" && { AC_CHECK_LIB(Xmu, XmuReadBitmapDataFromFile,
2869                            with_xmu=yes, with_xmu=no) }
2870   if test "$with_xmu" = "no"; then
2871     XE_ADD_OBJS(xmu.o)
2872   else
2873     XE_PREPEND(-lXmu, libs_x)
2874     AC_DEFINE(HAVE_XMU)
2875   fi
2876
2877   dnl Autodetect -lXbsd
2878   dnl #### Someone, please add a better function than main
2879   AC_CHECK_LIB(Xbsd, main, XE_PREPEND(-lXbsd, libs_x))
2880
2881   dnl Problem with the MIT distribution of X on AIX
2882   if test "$unexec" = "unexaix.o" -a "$x11_release" = "6"; then
2883     dnl X11R6 requires thread-safe code on AIX for some reason
2884     if test "$GCC" = "yes"; then
2885       XE_PREPEND(-mthreads, X_CFLAGS)
2886       XE_PREPEND(-mthreads, libs_x)
2887     else
2888       case "$CC" in
2889         "xlc" ) CC="xlc_r" ;;
2890         "xlC" ) CC="xlC_r" ;;
2891         "cc"  ) CC="cc_r" ;;
2892       esac
2893     fi
2894   fi
2895
2896 fi dnl $with_x11 = yes
2897
2898 if test "$with_msw" != "no"; then
2899   AC_CHECKING(for MS-Windows)
2900   AC_CHECK_LIB(gdi32,main,with_msw=yes)
2901   if test "$with_msw" = "yes"; then
2902     AC_DEFINE(HAVE_MS_WINDOWS)
2903
2904     dnl The net installer only works with MS-Windows currently
2905     if test "$with_netinstall" = "yes"; then
2906       XE_APPEND(netinstall, MAKE_SUBDIR)
2907       XE_APPEND(netinstall, SRC_SUBDIR_DEPS)
2908       XE_APPEND(netinstall, INSTALL_ARCH_DEP_SUBDIR)
2909     fi
2910
2911     install_pp="$blddir/lib-src/installexe.sh"
2912     XE_APPEND(-lshell32 -lgdi32 -luser32 -lcomdlg32 -lcomctl32 -lwinspool, libs_system)
2913     test "$with_dragndrop" != no && XE_APPEND(msw, dragndrop_proto)
2914     if test "$window_system" != x11; then
2915         window_system=msw
2916         test "$with_scrollbars" != "no" && with_scrollbars=msw \
2917             && XE_ADD_OBJS(scrollbar-msw.o)
2918         test "$with_menubars"   != "no" && with_menubars=msw \
2919             && XE_ADD_OBJS(menubar-msw.o)
2920         test "$with_toolbars"   != "no" && with_toolbars=msw \
2921             && XE_ADD_OBJS(toolbar-msw.o)
2922         test "$with_dialogs"   != "no" && with_dialogs=msw \
2923             && XE_ADD_OBJS(dialog-msw.o)
2924         test "$with_widgets"   != "no" && with_widgets=msw
2925     else
2926         test "$with_scrollbars" != "no" && XE_ADD_OBJS(scrollbar-msw.o)
2927         test "$with_menubars"   != "no" && XE_ADD_OBJS(menubar-msw.o)
2928         test "$with_toolbars"   != "no" && XE_ADD_OBJS(toolbar-msw.o)
2929         test "$with_dialogs"    != "no" && XE_ADD_OBJS(dialog-msw.o)
2930     fi
2931     dnl check for our special version of select
2932     AC_TRY_RUN([#include <fcntl.h>
2933     int main() { return (open("/dev/windows", O_RDONLY, 0) > 0)? 0 : 1; }],
2934     [need_event_unixoid=yes; AC_DEFINE(HAVE_MSG_SELECT)])
2935     with_file_coding=yes
2936     XE_ADD_OBJS(console-msw.o device-msw.o event-msw.o frame-msw.o objects-msw.o select-msw.o redisplay-msw.o glyphs-msw.o gui-msw.o)
2937   fi
2938 fi
2939
2940 AC_SUBST(install_pp)
2941
2942 test -z "$window_system" && window_system="none"
2943
2944 dnl Test for features that require a window system - ANY window system
2945 if test "$window_system" = "none"; then
2946   for feature in menubars scrollbars toolbars dialogs dragndrop xface
2947   do
2948     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2949        AC_MSG_WARN([--with-$feature ignored:  Not valid without window system support])
2950     fi
2951     eval "with_${feature}=no"
2952   done
2953 else
2954   test -z "$with_toolbars" && with_toolbars=yes
2955 fi
2956
2957 dnl ### Test for features that require mswindows support - currently none
2958 dnl ### MS-Windows folks: add code here..... (martin)
2959 if test "$with_msw" != "yes"; then
2960   for feature in   MARTIN_IS_CLUELESS_ABOUT_MSW_FEATURES
2961   do
2962     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2963        AC_MSG_WARN([--with-$feature ignored:  Not valid without MS-Windows support])
2964     fi
2965     eval "with_${feature}=no"
2966   done
2967 else
2968   :
2969 fi
2970
2971 dnl Test for features that require X11 support
2972 if test "$with_x11" != "yes"; then
2973   dnl It ought to be reasonable to have no output device at all, and only use
2974   dnl XEmacs in --batch mode.
2975   dnl if test "$with_tty" = "no" ; then
2976   dnl   AC_MSG_ERROR([No window system support and no TTY support - Unable to proceed.])
2977   dnl fi
2978   for feature in tooltalk cde offix wmcommand xim xmu nas_sound
2979   do
2980     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2981        AC_MSG_WARN([--with-$feature ignored:  Not valid without X support])
2982     fi
2983     eval "with_${feature}=no"
2984   done
2985 fi
2986
2987 dnl Balloon Help requires the Shape extension, not available everywhere,
2988 dnl for example not on AIX 4.3.
2989 if test "$with_x11" = "yes"; then
2990   AC_CHECK_HEADER(X11/extensions/shape.h, [
2991    AC_DEFINE(HAVE_BALLOON_HELP)
2992    XE_ADD_OBJS(balloon_help.o balloon-x.o)])
2993 fi
2994
2995 dnl FSF 19.29 has some bitmapdir stuff here.
2996 bitmapdir=
2997
2998 case "$window_system" in
2999   x11  ) HAVE_X_WINDOWS=yes; echo "  Using X11." ;;
3000   msw  ) HAVE_X_WINDOWS=no ; echo "  Using MS-Windows." ;;
3001   gtk  )
3002        HAVE_X_WINDOWS=no
3003        test "$with_gnome" = "yes" && echo "  Using GNOME."
3004        test "$with_gnome" = "no" && echo "  Using GTK."
3005        ;;
3006   none ) HAVE_X_WINDOWS=no ; echo "  Using no window system." ;;
3007 esac
3008
3009 case "$x_libraries" in *X11R4* )
3010   test "$opsys" = "hpux9"     && opsysfile="s/hpux9-x11r4.h"
3011   test "$opsys" = "hpux9-shr" && opsysfile="s/hpux9shxr4.h"
3012 esac
3013
3014 dnl Enable or disable proper handling of WM_COMMAND
3015 AC_CHECKING(for WM_COMMAND option);
3016 dnl if test "$with_wmcommand" = "yes"; then
3017 if test "$with_wmcommand" != "no"; then
3018   AC_DEFINE(HAVE_WMCOMMAND)
3019 fi
3020
3021 dnl Autodetect Xauth
3022 dnl -lXau is only used by gnuclient, so use a special variable for Xauth X libs
3023 test -z "$with_xauth" && test "$window_system" = "none" && with_xauth=no
3024 test -z "$with_xauth" && { AC_CHECK_HEADER(X11/Xauth.h,          ,with_xauth=no) }
3025 test -z "$with_xauth" && { AC_CHECK_LIB(Xau, XauGetAuthByAddr,[:],with_xauth=no) }
3026 test -z "$with_xauth" && with_xauth=yes
3027 if test "$with_xauth" = "yes"; then
3028   AC_DEFINE(HAVE_XAUTH)
3029   XE_SPACE(libs_xauth, $GTK_LIBS $X_EXTRA_LIBS -lXau $libs_x $X_PRE_LIBS)
3030 fi
3031 AC_SUBST(libs_xauth)
3032
3033 dnl This one is for the static initializeds variables in
3034 dnl offix.c, so that the thing is dumped after lastfile.o
3035 AC_SUBST(dnd_objs)
3036
3037 dnl Autodetect tooltalk
3038 if test "$with_tooltalk" != "no" ; then
3039   dnl autodetect the location of tt_c.h
3040   dnl tt_c.h might be in Tt or desktop include directories
3041   for dir in "" "Tt/" "desktop/" ; do
3042     AC_CHECK_HEADER(${dir}tt_c.h, tt_c_h_file="${dir}tt_c.h"; break)
3043   done
3044   if test -z "$tt_c_h_file"; then
3045     if test "$with_tooltalk" = "yes"; then
3046       USAGE_ERROR("Unable to find required tooltalk header files.")
3047     fi
3048     with_tooltalk=no
3049   fi
3050 fi
3051 if test "$with_tooltalk" != "no" ; then
3052   for extra_libs in "" "-lI18N -lce" "-lcxx"; do
3053     AC_CHECK_LIB(tt, tt_message_create,
3054       tt_libs="-ltt $extra_libs"; break, [:],$extra_libs)
3055   done
3056   if test -z "$tt_libs"; then
3057     if test "$with_tooltalk" = "yes"; then
3058       USAGE_ERROR("Unable to find required tooltalk libraries.")
3059     fi
3060     with_tooltalk=no
3061   fi
3062 fi
3063 test -z "$with_tooltalk" && with_tooltalk=yes
3064 if test "$with_tooltalk" = "yes"; then
3065   AC_DEFINE(TOOLTALK)
3066   AC_DEFINE_UNQUOTED(TT_C_H_FILE, "$tt_c_h_file")
3067   XE_PREPEND($tt_libs, libs_x)
3068   XE_ADD_OBJS(tooltalk.o)
3069 fi
3070
3071 dnl Autodetect CDE
3072 test -z "$with_cde" && { AC_CHECK_HEADER(Dt/Dt.h,               , with_cde=no) }
3073 test -z "$with_cde" && { AC_CHECK_LIB(DtSvc, DtDndDragStart, [:], with_cde=no) }
3074 test -z "$with_cde" && with_cde=yes
3075 if test "$with_dragndrop" = no; then
3076   AC_MSG_WARN([No CDE without generic Drag'n'Drop support])
3077   with_cde=no
3078 fi
3079 if test "$with_cde" = "yes" ; then
3080   AC_DEFINE(HAVE_CDE)
3081   XE_PREPEND(-lDtSvc, libs_x)
3082   XE_APPEND(CDE, dragndrop_proto)
3083   with_tooltalk=yes # CDE requires Tooltalk
3084   need_motif=yes    # CDE requires Motif
3085 fi
3086
3087 dnl Always compile OffiX unless --without-offix is given, no
3088 dnl X11 support is compiled in, no standard Xmu is available,
3089 dnl or dragndrop support is disabled
3090 dnl Because OffiX support currently loses when more than one display
3091 dnl is in use, we now disable it by default -slb 07/10/1998.
3092 test "$window_system" != "x11" && with_offix=no
3093 if test "$with_xmu" != yes -a "$with_x11" = yes; then
3094   AC_MSG_WARN([No OffiX without real Xmu support])
3095   with_offix=no
3096 fi
3097 if test "$with_dragndrop" = no; then
3098   AC_MSG_WARN([No OffiX without generic Drag'n'Drop support])
3099   with_offix=no
3100 fi
3101 if test "$with_cde" = yes; then
3102   AC_MSG_WARN([CDE already found, disabling OffiX support])
3103   with_offix=no
3104 fi
3105 test -z "$with_offix" && with_offix=no
3106 if test "$with_offix" = "yes"; then
3107   AC_DEFINE(HAVE_OFFIX_DND)
3108   XE_APPEND(offix.o, dnd_objs)
3109   XE_APPEND(OffiX, dragndrop_proto)
3110 fi
3111 if test "$with_gtk" = "yes"; then
3112    XE_APPEND(GTK, dragndrop_proto)
3113 fi
3114
3115 dnl Autodetect Drag'n'Drop support
3116 dnl always included if CDE, Offix, or MSWindows are defined
3117 if test "$with_dragndrop" != "no" ; then
3118   AC_MSG_CHECKING(if drag and drop API is needed)
3119   if test -n "$dragndrop_proto" ; then
3120     with_dragndrop=yes
3121     AC_MSG_RESULT([yes (${dragndrop_proto} )])
3122     AC_DEFINE(HAVE_DRAGNDROP)
3123     XE_APPEND(dragdrop.o, extra_objs)
3124   else
3125     with_dragndrop=no
3126     AC_MSG_RESULT(no)
3127   fi
3128 fi
3129
3130 dnl Autodetect LDAP
3131 AC_CHECKING(for LDAP)
3132 test -z "$with_ldap" && { AC_CHECK_HEADER(ldap.h, ,with_ldap=no) }
3133 test -z "$with_ldap" && { AC_CHECK_HEADER(lber.h, ,with_ldap=no) }
3134 if test "$with_ldap" != "no"; then
3135   AC_CHECK_LIB(ldap, ldap_search, with_ldap_nolber=yes, with_ldap_nolber=no)
3136   test "$with_ldap_nolber" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_lber=yes, with_ldap_lber=no, -llber) }
3137   test "$with_ldap_nolber" = "no" -a "$with_ldap_lber" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_krb=yes, with_ldap_krb=no, -llber -lkrb) }
3138   test "$with_ldap_nolber" = "no" -a "$with_ldap_lber" = "no" -a "$with_ldap_krb" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_krbdes=yes, with_ldap_krbdes=no, -llber -lkrb -ldes) }
3139   test -z "$with_ldap" -a \( "$with_ldap_lber" = "yes" -o "$with_ldap_nolber" = "yes" -o "$with_ldap_krb" = "yes" -o "$with_ldap_krbdes" = "yes" \) && with_ldap=yes
3140 fi
3141 if test "$with_ldap" = "yes"; then
3142   AC_DEFINE(HAVE_LDAP)
3143   XE_ADD_OBJS(eldap.o)
3144   if test "$with_ldap_nolber" = "yes" ; then
3145     XE_PREPEND(-lldap, LIBS)
3146   else
3147     if test "$with_ldap_krb" = "yes" ; then
3148       XE_PREPEND(-lkrb, LIBS)
3149     fi
3150     if test "$with_ldap_krbdes" = "yes" ; then
3151       XE_PREPEND(-ldes, LIBS)
3152       XE_PREPEND(-lkrb, LIBS)
3153     fi
3154     XE_PREPEND(-llber, LIBS)
3155     XE_PREPEND(-lldap, LIBS)
3156   fi
3157   AC_CHECK_FUNCS(ldap_set_option ldap_get_lderrno ldap_result2error ldap_parse_result)
3158 fi
3159
3160 dnl Autodetect PostgreSQL
3161 dnl On many Linux systems, PostgreSQL is packaged to be installed in /usr;
3162 dnl in this case, configure will easily detect it there.
3163 dnl
3164 dnl If PostgreSQL is installed into a different prefix,
3165 dnl (such as the default /usr/local/pgsql when building from source),
3166 dnl that prefix must be specified using the --site-prefixes flag.
3167 if test "$with_postgresql" != "no"; then
3168   AC_CHECKING(for PostgreSQL)
3169
3170 dnl Look for these standard header file locations, known to be used on Linux
3171   for header_dir in "" "pgsql/" "postgresql/"; do
3172     AC_CHECK_HEADER(${header_dir}libpq-fe.h,
3173                     libpq_fe_h_file=${header_dir}libpq-fe.h; break)
3174   done
3175
3176   test -n "$libpq_fe_h_file" && { AC_CHECK_LIB(pq,PQconnectdb,have_libpq=yes) }
3177
3178   if test -n "$libpq_fe_h_file" -a "$have_libpq" = "yes"; then
3179     with_postgresql=yes
3180     AC_DEFINE(HAVE_POSTGRESQL)
3181     AC_CHECK_LIB(pq,PQconnectStart, [
3182                  with_postgresqlv7=yes;
3183                  AC_DEFINE(HAVE_POSTGRESQLV7)])
3184     AC_DEFINE_UNQUOTED(LIBPQ_FE_H_FILE, "$libpq_fe_h_file")
3185     XE_PREPEND(-lpq, LIBS)
3186     XE_ADD_OBJS(postgresql.o)
3187   elif test "$with_postgresql" = "yes"; then
3188     XE_DIE("Required PostgreSQL support cannot be provided.  Check --site-prefixes.")
3189   fi
3190 fi
3191
3192 dnl ----------------------
3193 dnl Graphics libraries
3194 dnl ----------------------
3195
3196 if test "$window_system" != "none"; then
3197   AC_CHECKING(for graphics libraries)
3198
3199   dnl add special code to handle xpm-nox on Cygwin (csw)
3200   dnl   -- should only happen if CYGWIN && WITH_XPM && WITH_MSW && !WITH_X
3201   libpath_xpm=
3202   incpath_xpm=
3203   case "$opsys" in
3204     cygwin*)
3205       cygwin_top=`eval "gcc -print-file-name=libc.a"` ;
3206       cygwin_top=`eval "dirname ${cygwin_top}"`;
3207       cygwin_top="${cygwin_top}/..";
3208       case "$window_system" in
3209         dnl use "standard" search pattern
3210         x11)  ;;
3211         dnl hardcode "standard" non-X11 xpm lib/inc dirs
3212         msw) libpath_xpm="-L${cygwin_top}/lib/noX"
3213              incpath_xpm="-I${cygwin_top}/include/noX"
3214               ;;
3215         dnl not supported on cygwin (yet?)
3216         gtk)  ;;
3217         dnl probably not reached...
3218         none) ;;
3219         dnl ditto
3220         *)    ;;
3221       esac
3222       ;;
3223     dnl use "standard" search pattern for all other OS's
3224     *) ;;
3225   esac
3226   dnl Autodetect Xpm
3227   xpm_problem=""
3228   if test -z "$with_xpm"; then
3229     XE_PREPEND("$incpath_xpm", CFLAGS)
3230     XE_PREPEND("$libpath_xpm", LDFLAGS)
3231     AC_MSG_CHECKING(for Xpm - no older than 3.4f)
3232     xe_check_libs=-lXpm
3233     AC_TRY_RUN([#define XPM_NUMBERS
3234 #include <X11/xpm.h>
3235     int main(int c, char **v) {
3236     return c == 1 ? 0 :
3237       XpmIncludeVersion != XpmLibraryVersion() ? 1 :
3238       XpmIncludeVersion < 30406 ? 2 : 0 ;}],
3239     [./conftest dummy_arg; xpm_status=$?;
3240       if test "$xpm_status" = "0"; then
3241         with_xpm=yes;
3242       else
3243         with_xpm=no;
3244         if test "$xpm_status" = "1"; then
3245           xpm_problem="Xpm library version and header file version don't match!"
3246         elif test "$xpm_status" = "2"; then
3247           xpm_problem="Xpm library version is too old!"
3248         else
3249           xpm_problem="Internal xpm detection logic error!"
3250         fi
3251         echo "
3252 *** WARNING *** $xpm_problem
3253   I'm not touching that with a 10-foot pole!
3254   If you really want to use the installed version of Xpm, rerun
3255   configure and add '--with-xpm=yes', but don't blame me if XEmacs crashes!"
3256     fi],
3257     [with_xpm=no])
3258     xe_check_libs=
3259     AC_MSG_RESULT($with_xpm)
3260   fi
3261   if test "$with_xpm" = "yes"; then
3262     dnl #### This code assumes that if AC_CHECK_LIB fails,
3263     dnl #### then it will succeed if FOR_MSW is defined,
3264     dnl #### but doesn't actually verify this assumption.
3265     AC_DEFINE(HAVE_XPM)
3266     XE_PREPEND("$libpath_xpm", LDFLAGS)
3267     XE_PREPEND(-lXpm, libs_x)
3268     XE_PREPEND("$incpath_xpm", CFLAGS)
3269     AC_MSG_CHECKING(for \"FOR_MSW\" xpm)
3270     xe_check_libs=-lXpm
3271     AC_TRY_LINK(, [XpmCreatePixmapFromData()],
3272     [xpm_for_msw=no],
3273     [xpm_for_msw=yes])
3274     xe_check_libs=
3275     AC_MSG_RESULT($xpm_for_msw)
3276     if test "$xpm_for_msw" = "yes"; then
3277       AC_DEFINE(FOR_MSW)
3278     fi
3279   fi
3280
3281   dnl Autodetect XFACE
3282   test -z "$with_xface" && { AC_CHECK_HEADER(compface.h,          ,with_xface=no) }
3283   test -z "$with_xface" && { AC_CHECK_LIB(compface, UnGenFace,[:] ,with_xface=no) }
3284   test -z "$with_xface" && with_xface=yes
3285   if test "$with_xface" = "yes"; then
3286     AC_DEFINE(HAVE_XFACE)
3287     XE_PREPEND(-lcompface, libs_x)
3288   fi
3289
3290   dnl For a brief period we had the GIF code split out into a separate library,
3291   dnl but patent problems, etc. sort of squashed that idea.
3292   dnl We default to building with builtin GIF decoding
3293   if test "$with_gif" != "no"; then
3294     with_gif="yes"
3295     AC_DEFINE(HAVE_GIF)
3296     XE_ADD_OBJS(dgif_lib.o gif_io.o)
3297   fi
3298
3299   dnl Too many stupid linkers can't detect cascaded lib dependencies until runtime
3300   dnl So we always search for libz compression support.
3301   if test "$with_png $with_tiff" != "no no"; then
3302     AC_CHECK_LIB(c,  inflate, [:], [
3303     AC_CHECK_LIB(z,  inflate, [XE_PREPEND(-lz,  libs_x)],[
3304     AC_CHECK_LIB(gz, inflate, [XE_PREPEND(-lgz, libs_x)])])])
3305   fi
3306
3307   dnl autodetect JPEG
3308   test -z "$with_jpeg" && { AC_CHECK_HEADER(jpeglib.h,                    ,with_jpeg=no) }
3309   test -z "$with_jpeg" && { AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,[:],with_jpeg=no) }
3310   test -z "$with_jpeg" && with_jpeg=yes
3311   if test "$with_jpeg" = "yes"; then
3312     AC_DEFINE(HAVE_JPEG)
3313     XE_PREPEND(-ljpeg, libs_x)
3314   fi
3315
3316   dnl autodetect PNG
3317   png_problem=""
3318   test -z "$with_png" && { AC_CHECK_FUNC(pow,                  ,with_png=no) }
3319   test -z "$with_png" && { AC_CHECK_HEADER(png.h,              ,with_png=no) }
3320   test -z "$with_png" && { AC_CHECK_LIB(png, png_read_image,[:],with_png=no) }
3321   if test -z "$with_png"; then
3322     AC_MSG_CHECKING(for workable png version information)
3323     xe_check_libs="-lpng -lz"
3324     AC_TRY_RUN([#include <png.h>
3325     int main(int c, char **v) {
3326     if (c == 1) return 0;
3327     if (strcmp(png_libpng_ver, PNG_LIBPNG_VER_STRING) != 0) return 1;
3328     return (PNG_LIBPNG_VER < 10002) ? 2 : 0 ;}],
3329     [./conftest dummy_arg; png_status=$?;
3330       if test "$png_status" = "0"; then
3331         with_png=yes;
3332       else
3333         with_png=no;
3334         if test "$png_status" = "1"; then
3335           png_problem="PNG library version and header file don't match!"
3336         elif test "$png_status" = "2"; then
3337           png_problem="PNG library version too old (pre 1.0.2)!"
3338         fi
3339         echo "
3340 *** WARNING *** $png_problem
3341   I'm not touching that with a 10-foot pole!
3342   If you really want to use the installed version of libPNG, rerun
3343   configure and add '--with-png=yes', but don't blame me if XEmacs crashes!"
3344     fi],
3345     [with_png=no])
3346     xe_check_libs=
3347     AC_MSG_RESULT($with_png)
3348   fi
3349   if test "$with_png" = "yes"; then
3350     AC_DEFINE(HAVE_PNG)
3351     XE_PREPEND(-lpng, libs_x)
3352   fi
3353
3354   dnl autodetect TIFF
3355   test -z "$with_tiff" && { AC_CHECK_HEADER(tiffio.h,            ,with_tiff=no) }
3356   test -z "$with_tiff" && { AC_CHECK_LIB(tiff, TIFFClientOpen,[:],with_tiff=no) }
3357   test -z "$with_tiff" && with_tiff=yes
3358   if test "$with_tiff" = "yes"; then
3359     AC_DEFINE(HAVE_TIFF)
3360     XE_PREPEND(-ltiff, libs_x)
3361   fi
3362 fi
3363
3364 dnl ----------------------
3365 dnl GTK-Specific Graphics libraries
3366 dnl ----------------------
3367
3368 if test "$with_gtk" = "yes"; then
3369   dnl Autodetect XFACE
3370   test -z "$with_xface" && { AC_CHECK_HEADER(compface.h,          ,with_xface=no) }
3371   test -z "$with_xface" && { AC_CHECK_LIB(compface, UnGenFace,[:] ,with_xface=no) }
3372   test -z "$with_xface" && with_xface=yes
3373   if test "$with_xface" = "yes"; then
3374     AC_DEFINE(HAVE_XFACE)
3375     XE_PREPEND(-lcompface, libs_gtk)
3376   fi
3377 fi
3378
3379
3380 dnl ----------------------
3381 dnl X-Specific Graphics libraries
3382 dnl ----------------------
3383
3384 if test "$with_x11" = "yes"; then
3385   AC_CHECKING(for X11 graphics libraries)
3386 fi
3387
3388 if test "$with_x11" = "yes" -a "$with_widgets" = "athena"; then
3389   AC_CHECKING(for the Athena widgets)
3390
3391   dnl What in heck did the user actually want?
3392   case "$with_athena" in
3393     dnl This is the default, old fashioned flat Athena.
3394     "xaw" | "") athena_variant=Xaw      athena_3d=no  ;;
3395     "3d")       athena_variant=Xaw3d    athena_3d=yes ;;
3396     "next")     athena_variant=neXtaw   athena_3d=yes ;;
3397     "95")       athena_variant=Xaw95    athena_3d=yes ;;
3398     "xpm")      athena_variant=XawXpm   athena_3d=yes ;;
3399     *)          XE_DIE("Unknown Athena widget set \`$with_athena'. This should not happen.") ;;
3400   esac
3401
3402   dnl Search for the Athena library...
3403   if test "$athena_3d" = "no"; then
3404     AC_CHECK_LIB($athena_variant, XawScrollbarSetThumb,
3405       [
3406         dnl Must not be a 3d library...
3407         AC_CHECK_LIB($athena_variant, threeDClassRec,
3408           AC_MSG_WARN("Could not find a non-3d Athena widget library."),
3409           athena_lib=$athena_variant)
3410       ],
3411       AC_MSG_WARN("Could not find an Athena widget library."))
3412   else
3413     dnl The real configuration, need 3d library
3414     AC_CHECK_LIB($athena_variant, threeDClassRec, athena_lib=$athena_variant,
3415       dnl OK, couldn't find it with a proper name, try the standard Athena lib
3416       dnl If that is 3d, presume the user asked for what they have installed.
3417       AC_CHECK_LIB(Xaw, threeDClassRec,
3418         [
3419           athena_lib=Xaw;
3420           AC_MSG_WARN("Assuming that libXaw is actually $athena_variant.");
3421         ],
3422         AC_MSG_WARN("Could not find a 3d Athena widget library that looked like $athena_variant.")))
3423   fi
3424
3425   dnl Now we locate the Athena headers that we need.
3426   if test "$athena_3d" = "no"; then
3427     AC_CHECK_HEADER(X11/Xaw/ThreeD.h,
3428       AC_MSG_WARN("Could not find a non-3d Athena header set."),
3429       AC_CHECK_HEADER(X11/Xaw/XawInit.h,
3430         athena_h_path=X11/Xaw,
3431         AC_MSG_WARN("Could not find a non-3d Athena header set.")))
3432   else
3433     dnl The three-d Athena headers are so much more slippery.
3434     dnl Curse this `Lets replace standard libraries' thing that they did. :/
3435     AC_CHECK_HEADER(X11/$athena_variant/XawInit.h,
3436       AC_CHECK_HEADER(X11/$athena_variant/ThreeD.h,
3437         athena_h_path=X11/$athena_variant,))
3438
3439     dnl Is the variant specific header directory directly under include?
3440     if test -z "$athena_h_path"; then
3441       AC_CHECK_HEADER($athena_variant/XawInit.h,
3442         AC_CHECK_HEADER($athena_variant/ThreeD.h,
3443           athena_h_path=$athena_variant,))
3444     fi
3445
3446     dnl If we couldn't find the specific variant, try the generic Athena 3d headers
3447     if test -z "$athena_h_path" -a "$athena_variant" != "Xaw3d"; then
3448       AC_CHECK_HEADER(X11/Xaw3d/XawInit.h,
3449         AC_CHECK_HEADER(X11/Xaw3d/ThreeD.h,
3450           [
3451             AC_MSG_WARN("Assuming that X11/Xaw3d headers are suitable for $athena_variant.")
3452             athena_h_path=X11/Xaw3d
3453           ],))
3454     fi
3455
3456     dnl Also generic 3d headers directly under include dir
3457     if test -z "$athena_h_path" -a "$athena_variant" != "Xaw3d"; then
3458       AC_CHECK_HEADER(Xaw3d/XawInit.h,
3459         AC_CHECK_HEADER(Xaw3d/ThreeD.h,
3460           [
3461             AC_MSG_WARN("Assuming that Xaw3d headers are suitable for $athena_variant.")
3462             athena_h_path=Xaw3d
3463           ],))
3464     fi
3465
3466     dnl If nothing yet found, see if Xaw is a 3d header set...
3467     dnl We AC_MSG_WARN if we fail because I am all out of ideas...
3468     if test -z "$athena_h_path"; then
3469       AC_CHECK_HEADER(X11/Xaw/ThreeD.h,
3470         [
3471           AC_MSG_WARN("Assuming that X11/Xaw headers are suitable for $athena_variant.")
3472           athena_h_path=X11/Xaw
3473         ],
3474         AC_MSG_WARN("Could not find a suitable 3d Athena header set."))
3475     fi
3476   fi
3477
3478   dnl Do we actually have a usable Athena widget set? Please?
3479   if test -n "$athena_lib" -a -n "$athena_h_path"; then
3480     have_xaw=yes
3481   else
3482     have_xaw=no
3483   fi
3484
3485 else
3486   have_xaw=no
3487 fi dnl "$with_x11" = "yes" -a "$with_widgets" = "athena"
3488
3489 if test "$with_x11" = "yes"; then
3490   dnl autodetect Motif - but only add to libs_x later (if necessary)
3491   AC_CHECK_HEADER(Xm/Xm.h,
3492    [AC_CHECK_LIB(Xm, XmStringFree, have_motif=yes, have_motif=no)],
3493    have_motif=no)
3494
3495   if test "$have_motif" = "yes"; then
3496     dnl autodetect lesstif
3497     AC_MSG_CHECKING(for Lesstif)
3498     AC_EGREP_CPP(yes,
3499 [#include <Xm/Xm.h>
3500 #ifdef LESSTIF_VERSION
3501 yes
3502 #endif
3503 ], have_lesstif=yes, have_lesstif=no)
3504   AC_MSG_RESULT($have_lesstif)
3505   fi
3506
3507 fi dnl "$with_x11" = "yes"
3508
3509 dnl Finish ensuring that we have values for the various toolkit items.
3510 dnl Not all toolkits support all widgets
3511 dnl if Motif is available we use it for the dialog boxes.
3512
3513 case "$with_menubars" in "" | "yes" | "athena" )
3514   with_menubars="lucid" ;;
3515 esac
3516 case "$with_dialogs" in "" | "yes" | "lucid" )
3517   if   test "$have_motif"     = "yes"; then with_dialogs="motif"
3518   elif test "$have_xaw"       = "yes"; then with_dialogs="athena"
3519   else with_dialogs=no
3520   fi ;;
3521 esac
3522 case "$with_scrollbars" in "" | "yes" )
3523   with_scrollbars="lucid" ;;
3524 esac
3525 case "$with_widgets" in "" | "yes" | "lucid")
3526   if   test "$have_motif" = "yes"; then with_widgets="motif"
3527   elif test "$have_xaw"   = "yes"; then with_widgets="athena"
3528   else with_widgets=no
3529   fi ;;
3530 esac
3531
3532 all_widgets="$with_menubars $with_scrollbars $with_dialogs $with_toolbars $with_widgets"
3533
3534 case "$all_widgets" in
3535   *athena* )
3536     if test "$have_xaw" != "yes"; then
3537       XE_DIE("Could not find a suitable Athena library to build with.")
3538     fi
3539
3540     dnl Add the Lucid widget Athena code
3541     XE_APPEND(lwlib-Xaw.o, lwlib_objs)
3542
3543     dnl Add the Athena widget library we located earlier
3544     XE_PREPEND(-l$athena_lib, libs_x)
3545
3546     dnl Tell lwlib where to find the Athena header files.
3547     dnl Many people have tried to create a `smart' way of doing this,
3548     dnl but all have failed.  Before changing the following ugly definitions,
3549     dnl consult the veterans of many a battle.
3550     AC_DEFINE_UNQUOTED(ATHENA_Scrollbar_h_,"$athena_h_path/Scrollbar.h")
3551     AC_DEFINE_UNQUOTED(ATHENA_Dialog_h_,"$athena_h_path/Dialog.h")
3552     AC_DEFINE_UNQUOTED(ATHENA_Form_h_,"$athena_h_path/Form.h")
3553     AC_DEFINE_UNQUOTED(ATHENA_Command_h_,"$athena_h_path/Command.h")
3554     AC_DEFINE_UNQUOTED(ATHENA_Label_h_,"$athena_h_path/Label.h")
3555     AC_DEFINE_UNQUOTED(ATHENA_LabelP_h_,"$athena_h_path/LabelP.h")
3556     AC_DEFINE_UNQUOTED(ATHENA_Toggle_h_,"$athena_h_path/Toggle.h")
3557     AC_DEFINE_UNQUOTED(ATHENA_ToggleP_h_,"$athena_h_path/ToggleP.h")
3558     AC_DEFINE_UNQUOTED(ATHENA_AsciiText_h_,"$athena_h_path/AsciiText.h")
3559     AC_DEFINE_UNQUOTED(ATHENA_XawInit_h_,"$athena_h_path/XawInit.h")
3560
3561     AC_DEFINE(LWLIB_USES_ATHENA)
3562     AC_DEFINE(NEED_ATHENA)
3563     need_athena="yes"
3564
3565     if test "$athena_3d" = "yes"; then
3566       AC_DEFINE(HAVE_ATHENA_3D)
3567     fi
3568   ;;
3569 esac
3570
3571 case "$all_widgets" in *motif* )
3572   AC_DEFINE(LWLIB_USES_MOTIF)
3573   AC_DEFINE(NEED_MOTIF)
3574   XE_APPEND(lwlib-Xm.o, lwlib_objs)
3575   need_motif=yes ;;
3576 esac
3577
3578 test "$with_menubars"   = "lucid" && XE_APPEND(xlwmenu.o, lwlib_objs)
3579 test "$with_menubars"   = "motif" && XE_APPEND(xlwmenu.o, lwlib_objs)
3580 test "$with_scrollbars" = "lucid" && XE_APPEND(xlwscrollbar.o, lwlib_objs)
3581 test "$with_widgets"   != "no" && test "$with_widgets" != "msw" && \
3582         XE_APPEND(xlwtabs.o xlwgcs.o, lwlib_objs)
3583 case "$with_widgets" in athena* )
3584         XE_APPEND(xlwradio.o xlwcheckbox.o xlwgauge.o, lwlib_objs);;
3585 esac
3586 case "$all_widgets" in *lucid* )
3587   AC_DEFINE(NEED_LUCID)
3588   XE_APPEND(lwlib-Xlw.o, lwlib_objs) ;;
3589 esac
3590
3591 AC_SUBST(lwlib_objs)
3592
3593 test "$with_scrollbars" = "athena" && AC_DEFINE(LWLIB_SCROLLBARS_ATHENA)
3594 test "$with_dialogs"    = "athena" && AC_DEFINE(LWLIB_DIALOGS_ATHENA)
3595
3596 if test "$athena_3d" = "yes"; then
3597   test "$with_scrollbars" = "athena" && AC_DEFINE(LWLIB_SCROLLBARS_ATHENA3D)
3598   test "$with_dialogs"    = "athena" && AC_DEFINE(LWLIB_DIALOGS_ATHENA3D)
3599 fi
3600
3601 case "$with_widgets" in athena* ) AC_DEFINE(LWLIB_WIDGETS_ATHENA);; esac
3602 test "$with_widgets" != "no" && test "$with_widgets" != "msw" && \
3603         AC_DEFINE(LWLIB_TABS_LUCID)
3604
3605 test "$with_menubars"   != "no"    && AC_DEFINE(HAVE_MENUBARS)
3606 test "$with_scrollbars" != "no"    && AC_DEFINE(HAVE_SCROLLBARS)
3607 test "$with_dialogs"    != "no"    && AC_DEFINE(HAVE_DIALOGS)
3608 test "$with_toolbars"   != "no"    && AC_DEFINE(HAVE_TOOLBARS)
3609 test "$with_widgets"    != "no"    && AC_DEFINE(HAVE_WIDGETS)
3610
3611 test "$with_menubars"   = "lucid"  && AC_DEFINE(LWLIB_MENUBARS_LUCID)
3612 test "$with_scrollbars" = "lucid"  && AC_DEFINE(LWLIB_SCROLLBARS_LUCID)
3613
3614 test "$with_menubars"   = "motif"  && AC_DEFINE(LWLIB_MENUBARS_MOTIF)
3615 test "$with_scrollbars" = "motif"  && AC_DEFINE(LWLIB_SCROLLBARS_MOTIF)
3616 test "$with_dialogs"    = "motif"  && AC_DEFINE(LWLIB_DIALOGS_MOTIF)
3617 test "$with_widgets"    = "motif"  && AC_DEFINE(LWLIB_WIDGETS_MOTIF)
3618
3619 test "$with_menubars"   != "no"    && XE_ADD_OBJS(menubar.o)
3620 test "$with_scrollbars" != "no"    && XE_ADD_OBJS(scrollbar.o)
3621 test "$with_dialogs"    != "no"    && XE_ADD_OBJS(dialog.o)
3622 test "$with_toolbars"   != "no"    && XE_ADD_OBJS(toolbar.o)
3623
3624 if test "$with_gtk" = "yes"; then
3625   test "$with_menubars"   != "no"      && XE_ADD_OBJS(menubar-gtk.o)
3626   test "$with_scrollbars" != "no"      && XE_ADD_OBJS(scrollbar-gtk.o)
3627   test "$with_dialogs"    != "no"      && XE_ADD_OBJS(dialog-gtk.o)
3628   test "$with_toolbars"   != "no"      && XE_ADD_OBJS(toolbar-gtk.o)
3629   test "$all_widgets" != "no no no no no" && XE_ADD_OBJS(gui-gtk.o)
3630 fi
3631
3632 if test "$with_x11" = "yes"; then
3633   test "$with_menubars"   != "no"  && XE_ADD_OBJS(menubar-x.o)
3634   test "$with_scrollbars" != "no"  && XE_ADD_OBJS(scrollbar-x.o)
3635   test "$with_dialogs"    != "no"  && XE_ADD_OBJS(dialog-x.o)
3636   test "$with_toolbars"   != "no"  && XE_ADD_OBJS(toolbar-x.o)
3637   test "$all_widgets" != "no no no no no" && XE_ADD_OBJS(gui-x.o)
3638 fi
3639
3640 dnl ----------------------
3641 dnl Mule-dependent options
3642 dnl ----------------------
3643
3644 test -z "$with_mule" && with_mule=no
3645 test -z "$with_file_coding" && with_file_coding=no
3646
3647 dnl if test "$with_mule" = "yes" && test ! -d "$srcdir/lisp/mule"; then
3648 dnl     echo "Attempt to Build with Mule without Mule/Lisp"
3649 dnl     echo "Please install the XEmacs/Mule tarball or"
3650 dnl     echo "rerun configure with --with-mule=no"
3651 dnl     exit 1
3652 dnl fi
3653
3654 if test "$with_file_coding" = "yes" && test "$with_mule" = "no"; then
3655   AC_DEFINE(FILE_CODING)
3656   XE_ADD_OBJS(file-coding.o)
3657 fi
3658
3659 if test "$with_mule" = "yes" ; then
3660   AC_CHECKING(for Mule-related features)
3661   AC_DEFINE(MULE)
3662   AC_DEFINE(FILE_CODING)
3663   XE_ADD_OBJS(mule.o mule-ccl.o mule-charset.o file-coding.o)
3664
3665   dnl Use -lintl to get internationalized strerror for Mule
3666   AC_CHECK_HEADERS(libintl.h)
3667   AC_CHECK_LIB(intl, strerror)
3668
3669   AC_CHECKING(for Mule input methods)
3670   dnl Do we have the XmIm* routines?  And if so, do we want to use them?
3671   dnl XIM seems to be flaky except on Solaris...
3672   dnl test -z "$with_xim" -a "$opsys" != "sol2" && with_xim=no
3673   case "$with_xim" in "" | "yes" )
3674     AC_CHECKING(for XIM)
3675     AC_CHECK_LIB(X11, XOpenIM, with_xim=xlib, with_xim=no)
3676     dnl XIM + Lesstif is not (yet?) usable
3677     if test "$have_motif $have_lesstif" = "yes no"; then
3678       AC_CHECK_LIB(Xm, XmImMbLookupString, with_xim=motif)
3679     fi ;;
3680   esac
3681   if test "$with_xim" != "no"; then
3682     AC_DEFINE(HAVE_XIM)
3683     if test "$with_xim" = "xlib"; then
3684       AC_DEFINE(XIM_XLIB)
3685       XE_ADD_OBJS(input-method-xlib.o)
3686     fi
3687     if test "$with_xim" = "motif"; then
3688       AC_DEFINE(XIM_MOTIF)
3689       need_motif=yes
3690       XE_ADD_OBJS(input-method-motif.o)
3691     fi
3692     if test "$with_xim" = "motif"; then
3693       with_xfs=no
3694     fi
3695   fi
3696
3697   dnl "with_xfs" = "yes"
3698   if test "$with_xfs" = "yes" ; then
3699     AC_CHECKING(for XFontSet)
3700     AC_CHECK_LIB(X11, XmbDrawString, [:], with_xfs=no)
3701     if test "$with_xfs" = "yes" && test "$with_menubars" = "lucid"; then
3702       AC_DEFINE(USE_XFONTSET)
3703       if test "$with_xim" = "no" ; then
3704         XE_ADD_OBJS(input-method-xlib.o)
3705       fi
3706     fi
3707   fi dnl with_xfs
3708
3709   dnl Autodetect WNN
3710   test "$with_wnn6" = "yes" && with_wnn=yes # wnn6 implies wnn support
3711   test -z "$with_wnn" && { AC_CHECK_HEADER(wnn/jllib.h, ,with_wnn=no) }
3712   dnl gcc 2.97 fixincludes breaks inclusion of wnn/commonhd.h
3713   test -z "$with_wnn" && { AC_CHECK_HEADER(wnn/commonhd.h, ,with_wnn=no) }
3714   dnl Detour to find crypt
3715   if test "$with_wnn" != "no"; then
3716     AC_CHECK_FUNCS(crypt)
3717     test "$ac_cv_func_crypt" != "yes" && { AC_CHECK_LIB(crypt, crypt) }
3718   fi
3719   dnl Back to our regularly scheduled wnn hunting
3720   if test -z "$with_wnn" -o "$with_wnn" = "yes"; then
3721     AC_CHECK_LIB(wnn,jl_dic_list_e,libwnn=wnn,
3722       AC_CHECK_LIB(wnn4,jl_dic_list_e,libwnn=wnn4,
3723         AC_CHECK_LIB(wnn6,jl_dic_list_e,libwnn=wnn6,
3724           AC_CHECK_LIB(wnn6_fromsrc,dic_list_e,libwnn=wnn6_fromsrc,with_wnn=no))))
3725   fi
3726   test -z "$with_wnn" && with_wnn=yes
3727   if test "$with_wnn" = "yes"; then
3728     AC_DEFINE(HAVE_WNN)
3729     XE_PREPEND(-l$libwnn, libs_x)
3730     XE_ADD_OBJS(mule-wnnfns.o)
3731     if test "$with_wnn6" != "no"; then
3732       AC_CHECK_LIB($libwnn, jl_fi_dic_list, with_wnn6=yes)
3733       test "$with_wnn6" = "yes" && AC_DEFINE(WNN6)
3734     fi
3735   fi
3736
3737   dnl Autodetect canna
3738   canna_includes_found=no
3739   if test "$with_canna" != "no"; then
3740     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3741   fi
3742   if test "$canna_includes_found" = "no" -a "$with_canna" != "no" -a \
3743       -d "/usr/local/canna/include"; then
3744     save_c_switch_site="$c_switch_site"
3745     c_switch_site="$c_switch_site -I/usr/local/canna/include"
3746     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3747     if test "$canna_includes_found" != "yes"; then
3748       c_switch_site="$save_c_switch_site"
3749       with_canna="no"
3750     fi
3751   fi
3752
3753   test -z "$with_canna" && { AC_CHECK_HEADER(canna/RK.h,         , with_canna=no) }
3754   test -z "$with_canna" && { AC_CHECK_LIB(RKC, RkBgnBun,       [:],with_canna=no) }
3755   test -z "$with_canna" && { AC_CHECK_LIB(canna,jrKanjiControl,[:],with_canna=no) }
3756   test -z "$with_canna" && with_canna=yes
3757   if test "$with_canna" = "yes"; then
3758     AC_DEFINE(HAVE_CANNA)
3759     XE_PREPEND(-lcanna -lRKC, libs_x)
3760     XE_ADD_OBJS(mule-canna.o)
3761   fi
3762
3763 else dnl "$with_mule" = "no"
3764   for feature in xim canna wnn; do
3765     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
3766       AC_MSG_WARN("--with-${feature} ignored:  Not valid without Mule support")
3767     fi
3768     eval "with_${feature}=no"
3769   done
3770 fi dnl with_mule
3771
3772
3773 dnl At this point, we know whether we need the motif lib or not.
3774 if test "$need_motif" = "yes" ; then
3775   XE_PREPEND(-lXm, libs_x)
3776   dnl AIX needs the following library for use with Motif
3777   AC_CHECK_LIB(i18n, layout_object_getvalue, [XE_PREPEND(-li18n, libs_x)])
3778   XE_COMPUTE_RUNPATH()
3779 fi
3780
3781 AC_CHECK_FUNCS(cbrt closedir dup2 eaccess fmod fpathconf frexp ftime getaddrinfo gethostname getnameinfo getpagesize gettimeofday getcwd getwd logb lrand48 matherr mkdir mktime perror poll random rename res_init rint rmdir select setitimer setpgid setlocale setsid sigblock sighold sigprocmask snprintf stpcpy strerror tzset ulimit usleep waitpid vsnprintf fsync ftruncate umask)
3782
3783 dnl ----------------------------------------------------------------
3784 dnl Check for PTY support functions.
3785 dnl ----------------------------------------------------------------
3786
3787 dnl There is no "standard" pty allocation method.  Every system is different.
3788 dnl  getpt()  is the preferred pty allocation method on glibc systems.
3789 dnl _getpty() is the preferred pty allocation method on SGI systems.
3790 dnl grantpt(), unlockpt(), ptsname() are defined by Unix98.
3791 AC_CHECK_FUNCS(getpt _getpty grantpt unlockpt ptsname killpg tcgetpgrp)
3792
3793 dnl openpty() is the preferred pty allocation method on BSD and Tru64 systems.
3794 dnl openpty() might be declared in:
3795 dnl - pty.h (Tru64 or Linux)
3796 dnl - libutil.h (FreeBSD)
3797 dnl - util.h (NetBSD)
3798 AC_CHECK_FUNC(openpty, have_openpty=yes, [
3799   AC_CHECK_LIB(util, openpty, have_openpty=yes need_libutil=yes)])
3800 if test "$have_openpty" = "yes"; then
3801   AC_DEFINE(HAVE_OPENPTY)
3802   AC_CHECK_HEADERS(pty.h libutil.h util.h, break)
3803   test "$need_libutil" = "yes" && XE_APPEND(-lutil, libs_system)
3804 fi
3805
3806 dnl Check for STREAM support functions.
3807 dnl Confusingly, "str" means both "string" and "SysV Streams".
3808 AC_CHECK_HEADERS(stropts.h)
3809 if test "$ac_cv_header_stropts_h" = "yes"; then
3810   AC_CHECK_FUNCS(isastream)
3811   AC_CHECK_HEADERS(strtio.h) dnl TIOCSIGNAL
3812 fi
3813
3814 dnl Use our own realpath always.
3815 XE_ADD_OBJS(realpath.o)
3816
3817 dnl Check whether the system provides getloadavg().
3818 AC_CHECK_FUNCS(getloadavg)
3819
3820 if test "$ac_cv_func_getloadavg" = "yes"; then
3821   dnl Solaris 8 declares getloadavg() in <sys/loadavg.h>.
3822   dnl glibc 2.2 declares getloadavg() in <stdlib.h>...
3823   dnl   ...if we #define _GNU_SOURCE, which we do.
3824   AC_CHECK_HEADERS(sys/loadavg.h)
3825 else
3826   dnl We define our own getloadavg() using lower level functions.
3827   XE_ADD_OBJS(getloadavg.o)
3828
3829   dnl Used by getloadavg() - does not require root priveleges
3830   AC_CHECK_LIB(kstat, kstat_open)
3831   AC_CHECK_HEADERS(kstat.h)
3832
3833   dnl Another way to get the load average
3834   AC_CHECK_LIB(kvm, kvm_read)
3835 fi
3836
3837 dnl If netdb.h does not declare h_errno, we must declare it by hand.
3838 AC_MSG_CHECKING(whether netdb declares h_errno)
3839 AC_TRY_LINK([#include <netdb.h>],
3840   [return h_errno;],
3841   [AC_MSG_RESULT(yes)
3842    AC_DEFINE(HAVE_H_ERRNO)],
3843   [AC_MSG_RESULT(no)])
3844
3845 AC_MSG_CHECKING(for sigsetjmp)
3846 AC_TRY_COMPILE([#include <setjmp.h>],
3847         [sigjmp_buf bar; sigsetjmp (bar, 0);],
3848   [AC_MSG_RESULT(yes)
3849    AC_DEFINE(HAVE_SIGSETJMP)],
3850   [AC_MSG_RESULT(no)])
3851
3852 AC_MSG_CHECKING(whether localtime caches TZ)
3853 AC_CACHE_VAL(emacs_cv_localtime_cache,
3854 [if test "$ac_cv_func_tzset" = "yes"; then
3855 AC_TRY_RUN([#include <time.h>
3856 #if STDC_HEADERS
3857 # include <stdlib.h>
3858 #endif
3859 extern char **environ;
3860 unset_TZ ()
3861 {
3862   char **from, **to;
3863   for (to = from = environ; (*to = *from); from++)
3864     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
3865       to++;
3866 }
3867 char TZ_GMT0[] = "TZ=GMT0";
3868 char TZ_PST8[] = "TZ=PST8";
3869 main()
3870 {
3871   time_t now = time ((time_t *) 0);
3872   int hour_GMT0, hour_unset;
3873   if (putenv (TZ_GMT0) != 0)
3874     exit (1);
3875   hour_GMT0 = localtime (&now)->tm_hour;
3876   unset_TZ ();
3877   hour_unset = localtime (&now)->tm_hour;
3878   if (putenv (TZ_PST8) != 0)
3879     exit (1);
3880   if (localtime (&now)->tm_hour == hour_GMT0)
3881     exit (1);
3882   unset_TZ ();
3883   if (localtime (&now)->tm_hour != hour_unset)
3884     exit (1);
3885   exit (0);
3886 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3887 [# If we have tzset, assume the worst when cross-compiling.
3888 emacs_cv_localtime_cache=yes])
3889 else
3890         # If we lack tzset, report that localtime does not cache TZ,
3891         # since we can't invalidate the cache if we don't have tzset.
3892         emacs_cv_localtime_cache=no
3893 fi],[:])dnl
3894 AC_MSG_RESULT($emacs_cv_localtime_cache)
3895 if test $emacs_cv_localtime_cache = yes; then
3896   AC_DEFINE(LOCALTIME_CACHE)
3897 fi
3898
3899 if test "$HAVE_TIMEVAL" = "yes"; then
3900 AC_MSG_CHECKING(whether gettimeofday accepts one or two arguments)
3901 AC_TRY_LINK([
3902 #ifdef TIME_WITH_SYS_TIME
3903 #include <sys/time.h>
3904 #include <time.h>
3905 #else
3906 #ifdef HAVE_SYS_TIME_H
3907 #include <sys/time.h>
3908 #else
3909 #include <time.h>
3910 #endif
3911 #endif
3912   ],
3913   [
3914   struct timeval time;
3915   gettimeofday (&time, 0);
3916 ],
3917   [AC_MSG_RESULT(two)],
3918   [AC_MSG_RESULT(one)
3919    AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
3920 fi
3921
3922
3923 AC_C_INLINE
3924 test "$ac_cv_c_inline" != "no" -a "$GCC" = "yes" && XE_ADD_OBJS(inline.o)
3925
3926 dnl HP-UX has a working alloca in libPW.
3927 dnl case "${GCC}${opsys}" in hpux* )
3928 dnl  AC_CHECK_FUNC(alloca, [:], [AC_CHECK_LIB(PW, alloca)])
3929 dnl esac
3930
3931 dnl AC_FUNC_ALLOCA doesn't know about DEC C's #pragma intrinsic(alloca)
3932 if test "$__DECC" != "yes"; then
3933   AC_FUNC_ALLOCA
3934   test -n "$ALLOCA" && XE_ADD_OBJS($ALLOCA)
3935 fi
3936
3937 dnl Check whether vfork exists and works correctly. (This does more
3938 dnl than just check for its existence.) If so, it defines HAVE_VFORK_H.
3939 dnl If not, it defines vfork to be fork.
3940 AC_FUNC_VFORK
3941
3942 dnl Check whether strcoll exists and works correctly. (This does more
3943 dnl than just check for its existence.) If so, it defines HAVE_STRCOLL.
3944 AC_FUNC_STRCOLL
3945
3946 dnl If `getpgrp' takes no argument (the POSIX.1 version), define
3947 dnl `GETPGRP_VOID'.  Otherwise, it is the BSD version, which takes a
3948 dnl process ID as an argument.
3949 AC_CHECK_FUNCS(getpgrp)
3950 AC_FUNC_GETPGRP
3951
3952 dnl We used to call AC_FUNC_MMAP here
3953 dnl Instead we now use following, suggested by Neal Becker
3954 AC_MSG_CHECKING(for working mmap)
3955 case "$opsys" in ultrix* ) have_mmap=no ;; *)
3956 AC_TRY_RUN([#include <stdio.h>
3957 #include <unistd.h>
3958 #include <fcntl.h>
3959 #include <sys/mman.h>
3960
3961 #ifndef MAP_VARIABLE
3962 #define MAP_VARIABLE 0
3963 #endif
3964
3965 #ifndef MAP_FAILED
3966 #define MAP_FAILED -1
3967 #endif
3968
3969 int main (int argc, char *argv[])
3970 {
3971   int fd = -1;
3972   caddr_t p;
3973 #ifndef MAP_ANONYMOUS
3974   fd = open ("/dev/zero", O_RDWR);
3975   if (fd < 0)
3976     return 1;
3977 #define MAP_ANONYMOUS 0
3978 #endif
3979   if (mmap(0, 1024, PROT_READ | PROT_WRITE,
3980            MAP_PRIVATE | MAP_VARIABLE | MAP_ANONYMOUS,
3981            fd, 0) != (void *) MAP_FAILED)
3982     return 0;
3983   perror ("conftest: mmap failed");
3984   return 1;
3985 }], have_mmap=yes, have_mmap=no) ;;
3986 esac
3987 AC_MSG_RESULT($have_mmap)
3988 test "$have_mmap" = "yes" && AC_DEFINE(HAVE_MMAP)
3989
3990 dnl By default we switch off rel-alloc on cygwin as it generally causes us grief
3991 case "$opsys" in cygwin*)
3992         test "$rel_alloc" = "default" && rel_alloc=no ;;
3993 esac
3994 dnl rel_alloc requires either GNU malloc or system malloc with mmap
3995 dnl We only turn rel_alloc on by default if mmap is available.
3996 test "$GNU_MALLOC" != "yes" -a "$have_mmap" != "yes" && rel_alloc=no
3997 if test "$rel_alloc $have_mmap" = "default yes"; then
3998   if test "$doug_lea_malloc" = "yes"; then
3999     dnl Check if malloc() calls mmap(), making rel_alloc pointless.
4000     AC_MSG_CHECKING(for M_MMAP_THRESHOLD)
4001     AC_TRY_COMPILE([#include <malloc.h>],[
4002 #ifndef M_MMAP_THRESHOLD
4003 #error No M_MMAP_THRESHOLD :-(
4004 !@+$%^&*_)(_ - unlikely to compile...
4005 #endif
4006 ], [rel_alloc=no; AC_MSG_RESULT(yes);], [rel_alloc=yes; AC_MSG_RESULT(no);])
4007   else
4008     rel_alloc=yes
4009   fi
4010 fi
4011 test "$rel_alloc" = "yes" && AC_DEFINE(REL_ALLOC)
4012
4013 dnl Check for terminal I/O variants
4014 dnl TERMIOS systems may have termio.h, but not vice-versa, I think.
4015 AC_CHECK_HEADER(termios.h,
4016   AC_DEFINE(HAVE_TERMIOS)
4017   AC_DEFINE(SIGNALS_VIA_CHARACTERS)
4018   AC_DEFINE(NO_TERMIO),
4019   [AC_CHECK_HEADER(termio.h, [AC_DEFINE(HAVE_TERMIO)])])
4020
4021
4022 dnl Check for Internet sockets.
4023 AC_CHECK_FUNC(socket,
4024  [AC_CHECK_HEADER(netinet/in.h,
4025    [AC_CHECK_HEADER(arpa/inet.h, [
4026   AC_DEFINE(HAVE_SOCKETS)
4027       AC_MSG_CHECKING("for sun_len member in struct sockaddr_un")
4028       AC_TRY_LINK([
4029 #include <sys/types.h>
4030 #include <sys/socket.h>
4031 #include <sys/un.h>
4032       ],
4033       [static struct sockaddr_un x; x.sun_len = 1;],
4034       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)],
4035       [AC_MSG_RESULT(no)])
4036       AC_MSG_CHECKING("for ip_mreq struct in netinet/in.h")
4037       AC_TRY_LINK([
4038 #include <sys/types.h>
4039 #include <netinet/in.h>
4040       ],
4041       [static struct ip_mreq x;],
4042       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MULTICAST)],
4043       [AC_MSG_RESULT(no)])])])])
4044
4045 dnl Check for SYS V IPC. (Inferior to sockets.)
4046 AC_CHECK_FUNC(msgget,
4047   [AC_CHECK_HEADER(sys/ipc.h,
4048     [AC_CHECK_HEADER(sys/msg.h,
4049       [AC_DEFINE(HAVE_SYSVIPC)])])])
4050
4051 dnl Check for directory variants
4052 AC_CHECK_HEADER(dirent.h, [AC_DEFINE(SYSV_SYSTEM_DIR)],
4053   [AC_CHECK_HEADER(sys/dir.h, , [AC_DEFINE(NONSYSTEM_DIR_LIBRARY)])])
4054
4055 dnl Check for nlist.h
4056 AC_CHECK_HEADER(nlist.h, AC_DEFINE(NLIST_STRUCT), )
4057
4058 dnl Check for sound of various sorts.
4059
4060 dnl Autodetect native sound
4061 AC_CHECKING("for sound support")
4062 test -z "$with_native_sound" -a -n "$native_sound_lib" && with_native_sound=yes
4063
4064 if test "$with_native_sound" != "no"; then
4065   dnl Maybe sound is already on include path...
4066   if test -n "$native_sound_lib"; then
4067     AC_CHECK_HEADER(multimedia/audio_device.h,
4068       [sound_found=yes sound_cflags=""
4069       XE_ADD_OBJS(sunplay.o)])
4070   fi
4071
4072   dnl Autodetect Sun native sound from SUNWaudmo package
4073   if test -z "$sound_found" -a -d "/usr/demo/SOUND"; then
4074     sound_found=yes
4075     XE_ADD_OBJS(sunplay.o)
4076     if test -d "/usr/demo/SOUND/include"
4077       then sound_cflags="-I/usr/demo/SOUND/include"
4078       else sound_cflags="-I/usr/demo/SOUND"
4079     fi
4080     if test -z "$native_sound_lib" ; then
4081       if test -r "/usr/demo/SOUND/lib/libaudio.a"
4082         then native_sound_lib="/usr/demo/SOUND/lib/libaudio.a"
4083         else native_sound_lib="/usr/demo/SOUND/libaudio.a"
4084       fi
4085     fi
4086   fi
4087
4088   dnl Check for SGI and HP native sound libs
4089   if test -z "$sound_found"; then
4090     case "$canonical" in
4091     *-sgi-* )
4092       if test -z "$native_sound_lib"; then
4093         AC_CHECK_LIB(audio, ALopenport, native_sound_lib="-laudio")
4094       fi
4095       if test -n "$native_sound_lib"; then
4096         sound_found=yes sound_cflags=""
4097         XE_ADD_OBJS(sgiplay.o)
4098       fi ;;
4099     hppa*-hp-hpux* )
4100       if test -z "$native_sound_lib"; then
4101         AC_CHECK_LIB(Alib, AOpenAudio, native_sound_lib="-lAlib")
4102       fi
4103       if test -n "$native_sound_lib"; then
4104         sound_found=yes
4105         XE_ADD_OBJS(hpplay.o)
4106         if test "$GCC" = "yes" # Kludge city
4107           then sound_cflags="-Dconst= -Dvolatile= -I/usr/audio/examples"
4108           else sound_cflags="+e -I/usr/audio/examples"
4109         fi
4110       fi ;;
4111     esac
4112   fi
4113
4114   dnl Win32 Native uses native sound
4115   if test -z "$sound_found"; then
4116     if test "$with_msw" = "yes"; then
4117     sound_found=yes
4118     native_sound_lib=
4119     fi
4120   fi
4121
4122   dnl Check for Linux/BSD native sound
4123   if test -z "$sound_found"; then
4124     for dir in "machine" "sys" "linux"; do
4125       AC_CHECK_HEADER(${dir}/soundcard.h,
4126         sound_found=yes
4127        need_miscplay=yes
4128         XE_ADD_OBJS(linuxplay.o)
4129         [AC_DEFINE_UNQUOTED(SOUNDCARD_H_FILE, "${dir}/soundcard.h")]
4130         break)
4131     done
4132   fi
4133
4134   test "$sound_found" = "yes" && with_native_sound=yes
4135 fi
4136
4137 if test "$with_native_sound" = "yes"; then
4138   AC_DEFINE(HAVE_NATIVE_SOUND)
4139   test -n "$native_sound_lib" && XE_PREPEND($native_sound_lib, LIBS)
4140 fi
4141
4142 dnl NAS Sound support
4143 if test "$with_nas_sound" != "no"; then
4144   AC_CHECK_HEADER(audio/audiolib.h, [
4145     AC_CHECK_LIB(audio, AuOpenServer, have_nas_sound=yes)])
4146   if test "$have_nas_sound" = "yes"; then
4147     with_nas_sound=yes
4148     AC_DEFINE(HAVE_NAS_SOUND)
4149     XE_ADD_OBJS(nas.o)
4150     XE_PREPEND(-laudio, libs_x)
4151     dnl If the nas library does not contain the error jump point,
4152     dnl then we force safer behavior.
4153     AC_EGREP_HEADER(AuXtErrorJump,audio/Xtutil.h,,[old_nas=yes; AC_DEFINE(NAS_NO_ERROR_JUMP)])
4154   else
4155     test "$with_nas_sound" = "yes" && \
4156       XE_DIE("Required NAS sound support cannot be provided.")
4157     with_nas_sound=no
4158   fi
4159 fi
4160
4161 dnl ESD Sound support
4162 if test "$with_esd_sound" != "no"; then
4163   AC_CHECK_PROG(have_esd_config, esd-config, yes, no)
4164   if test "$have_esd_config" = "yes"; then
4165     save_c_switch_site="$c_switch_site" save_LIBS="$LIBS"
4166     XE_APPEND(`esd-config --cflags`, c_switch_site)
4167     XE_PREPEND(`esd-config --libs`, LIBS)
4168     AC_CHECK_FUNC(esd_play_stream,
4169       have_esd_sound=yes,
4170       c_switch_site="$save_c_switch_site" LIBS="$save_LIBS")
4171   fi
4172
4173   if test "$have_esd_sound" = "yes"; then
4174     with_esd_sound=yes
4175     need_miscplay=yes
4176     XE_ADD_OBJS(esd.o)
4177     AC_DEFINE(HAVE_ESD_SOUND)
4178   else
4179     test "$with_esd_sound" = "yes" && \
4180       XE_DIE("Required ESD sound support cannot be provided.")
4181     with_esd_sound=no
4182   fi
4183 fi
4184
4185 test "$need_miscplay" = "yes" && XE_ADD_OBJS(miscplay.o)
4186
4187 dnl ---------------------
4188 dnl TTY-dependent options
4189 dnl ---------------------
4190
4191 test -z "$with_tty" && with_tty=yes
4192
4193 if test "$with_tty" = "yes"  ; then
4194   AC_CHECKING(for TTY-related features)
4195   AC_DEFINE(HAVE_TTY)
4196   XE_ADD_OBJS(console-tty.o device-tty.o event-tty.o frame-tty.o objects-tty.o redisplay-tty.o cm.o)
4197
4198   dnl Autodetect ncurses.
4199   if test -z "$with_ncurses"; then
4200     AC_CHECK_LIB(ncurses, tgetent, with_ncurses=yes, with_ncurses=no)
4201   fi
4202   if test "$with_ncurses" = "yes"; then
4203     AC_DEFINE(HAVE_NCURSES)
4204     AC_CHECK_HEADER(ncurses/curses.h, curses_h_file=ncurses/curses.h)
4205     AC_CHECK_HEADER(ncurses/term.h, term_h_file=ncurses/term.h)
4206     XE_ADD_OBJS(terminfo.o)
4207     XE_PREPEND(-lncurses, LIBS)
4208
4209     if test "$ac_cv_header_ncurses_curses_h" != "yes" ; then
4210       dnl Try again, and check for the bogus ncurses/ include bug.
4211       dnl (i.e. ncurses/curses.h bogusly includes <unctrl.h> instead of
4212       dnl <ncurses/unctrl.h>)
4213       save_c_switch_site="$c_switch_site"
4214       c_switch_site="$c_switch_site -I/usr/include/ncurses"
4215       AC_CHECK_HEADER(ncurses/curses.h, curses_h_file=ncurses/curses.h)
4216       if test "$ac_cv_header_ncurses_curses_h" = "yes"
4217         then AC_MSG_WARN("Your system has the bogus ncurses include bug.")
4218         else c_switch_site="$save_c_switch_site"
4219       fi
4220     fi
4221   else dnl "$with_ncurses" = "no"
4222     dnl Autodetect terminfo/-lcurses/-ltermlib/-ltermcap
4223     if test "$have_terminfo" = "yes"; then
4224       XE_ADD_OBJS(terminfo.o)
4225       if test -n "$libs_termcap"; then
4226         XE_PREPEND($libs_termcap, LIBS)
4227       else
4228         for lib in curses termlib termcap; do
4229           AC_CHECK_LIB($lib, tgetent, XE_PREPEND(-l${lib}, LIBS); break)
4230         done
4231       fi
4232     else dnl "$have_terminfo" = "no" && "with_ncurses" = "no"
4233       XE_ADD_OBJS(tparam.o)
4234       dnl The HP-UX curses library seems to have a badly broken version of select(2)
4235       dnl that makes "poll: interrupted system call" messages to appear and
4236       dnl Emacs subprocesses to hang (e.g. TeX compilation w/ AUCTeX) */
4237       case "$opsys" in *-hp-hpux* ) libs_termcap="-ltermcap" ;; esac
4238       if test -n "$libs_termcap"; then
4239         XE_PREPEND($libs_termcap, LIBS)
4240       else
4241         AC_CHECK_LIB(curses, tgetent, XE_PREPEND(-lcurses, LIBS),
4242           AC_CHECK_LIB(termcap, tgetent, XE_PREPEND(-ltermcap, LIBS),
4243             XE_ADD_OBJS(termcap.o)))
4244       fi
4245     fi
4246   fi
4247   AC_DEFINE_UNQUOTED(CURSES_H_FILE, "${curses_h_file-curses.h}")
4248   AC_DEFINE_UNQUOTED(TERM_H_FILE, "${term_h_file-term.h}")
4249
4250   dnl Autodetect gpm
4251   test -z "$with_gpm" && { AC_CHECK_HEADER(gpm.h, , with_gpm=no) }
4252   test -z "$with_gpm" && { AC_CHECK_LIB(gpm, Gpm_Open, with_gpm=yes, with_gpm=no) }
4253   if test "$with_gpm" = "yes"; then
4254     AC_DEFINE(HAVE_GPM)
4255     XE_ADD_OBJS(gpmevent.o)
4256     XE_PREPEND(-lgpm, LIBS)
4257   fi
4258
4259 else dnl "$with_tty" = "no"
4260   for feature in ncurses gpm; do
4261     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
4262       AC_MSG_WARN("--with-${feature} ignored:  Not valid without TTY support")
4263     fi
4264     eval "with_${feature}=no"
4265   done
4266 fi dnl with_tty
4267
4268 dnl Do we need event-unixoid.o ?
4269 dnl This is needed for X, or for TTY, or for MSWIN w/Cygwin select()
4270 dnl [but not Mingw MSWIN]
4271 test "$with_x11" = "yes" -o "$with_tty" = "yes" -o "$need_event_unixoid" = "yes" && XE_ADD_OBJS(event-unixoid.o)
4272
4273 dnl Database support
4274 dnl We do not necessarily have to have libdb/lib(g)dbm for DB/(G)DBM support.
4275 dnl On FreeBSD, both DB and DBM are part of libc.
4276 dnl By default, we check for DBM support in libgdbm, then libc, then libdbm.
4277
4278 test "$with_database_gdbm $with_database_dbm $with_database_berkdb" \
4279   != "no no no" && AC_CHECKING(for database support)
4280
4281 dnl Check for ndbm.h, required for either kind of DBM support.
4282 if test "$with_database_gdbm $with_database_dbm" != "no no"; then
4283   AC_CHECK_HEADER(ndbm.h, [:], [
4284     test "$with_database_gdbm" = "yes" -o \
4285          "$with_database_dbm"  = "yes" && \
4286       XE_DIE("Required DBM support cannot be provided.")
4287     with_database_gdbm=no with_database_dbm=no])
4288 fi
4289
4290 dnl Check for DBM support in libgdbm.
4291 if test "$with_database_gdbm" != "no"; then
4292   AC_CHECK_LIB(gdbm, dbm_open, [
4293    with_database_gdbm=yes with_database_dbm=no libdbm=-lgdbm], [
4294    if test "$with_database_gdbm" = "yes"; then
4295      XE_DIE("Required GNU DBM support cannot be provided.")
4296    fi
4297    with_database_gdbm=no])
4298 fi
4299
4300 dnl Check for DBM support in libc and libdbm.
4301 if test "$with_database_dbm" != "no"; then
4302   AC_CHECK_FUNC(dbm_open, [with_database_dbm=yes libdbm=], [
4303     AC_CHECK_LIB(dbm, dbm_open, [with_database_dbm=yes libdbm=-ldbm], [
4304       test "$with_database_dbm" = "yes" && \
4305         XE_DIE("Required DBM support cannot be provided.")
4306       with_database_dbm=no])])
4307 fi
4308
4309 dnl Tell make about the DBM support we detected.
4310 test -n "$libdbm" && XE_PREPEND("$libdbm", LIBS)
4311 test "$with_database_gdbm" = "yes" -o \
4312      "$with_database_dbm"  = "yes" && \
4313   AC_DEFINE(HAVE_DBM)
4314
4315 dnl Check for Berkeley DB.
4316 if test "$with_database_berkdb" != "no"; then
4317   AC_MSG_CHECKING(for Berkeley db.h)
4318   for header in "db/db.h" "db.h"; do
4319     AC_TRY_COMPILE([
4320 #include <stdlib.h>
4321 #if !(defined __GLIBC__ && __GLIBC_MINOR__ >= 1)
4322 #ifdef HAVE_INTTYPES_H
4323 #define __BIT_TYPES_DEFINED__
4324 #include <inttypes.h>
4325 typedef uint8_t  u_int8_t;
4326 typedef uint16_t u_int16_t;
4327 typedef uint32_t u_int32_t;
4328 #ifdef WE_DONT_NEED_QUADS
4329 typedef uint64_t u_int64_t;
4330 #endif
4331 #endif
4332 #endif
4333 #include <$header>
4334 ],[], db_h_file="$header"; break)
4335   done
4336   if test -z "$db_h_file"
4337   then AC_MSG_RESULT(no); with_database_berkdb=no
4338   else AC_MSG_RESULT($db_h_file)
4339   fi
4340
4341   if test "$with_database_berkdb" != "no"; then
4342     AC_MSG_CHECKING(for Berkeley DB version)
4343     AC_EGREP_CPP(yes,
4344 [#include <$db_h_file>
4345 #if DB_VERSION_MAJOR > 1
4346 yes
4347 #endif
4348 ], [AC_EGREP_CPP(yes,
4349 [#include <$db_h_file>
4350 #if DB_VERSION_MAJOR > 2
4351 yes
4352 #endif
4353 ], [AC_MSG_RESULT(3); dbfunc=db_create],[
4354     AC_MSG_RESULT(2); dbfunc=db_open])],[
4355     AC_MSG_RESULT(1); dbfunc=dbopen])
4356     AC_CHECK_FUNC($dbfunc,     with_database_berkdb=yes need_libdb=no, [
4357     AC_CHECK_LIB(db, $dbfunc,  with_database_berkdb=yes need_libdb=yes)])
4358   fi
4359
4360   if test "$with_database_berkdb" = "yes"; then
4361     AC_DEFINE_UNQUOTED(DB_H_FILE, "$db_h_file")
4362     AC_DEFINE(HAVE_BERKELEY_DB)
4363     test "$need_libdb" = "yes" && XE_PREPEND(-ldb, LIBS)
4364   else with_database_berkdb=no
4365   fi
4366 fi
4367
4368 if test "$with_database_gdbm $with_database_dbm $with_database_berkdb" \
4369      != "no no no"; then
4370   AC_DEFINE(HAVE_DATABASE)
4371   XE_ADD_OBJS(database.o)
4372 fi
4373
4374 dnl Socks support
4375 if test "$with_socks" = "yes"; then
4376   AC_CHECK_LIB(socks, SOCKSinit)
4377   test -n "$ac_cv_lib_socks_SOCKSinit" && AC_DEFINE(HAVE_SOCKS)
4378 fi
4379
4380 dnl Usage tracking (undocumented and likely unused option)
4381 if test "$usage_tracking" = "yes"; then
4382   AC_DEFINE(USAGE_TRACKING)
4383   XE_PREPEND(-Bstatic -lut -Bdynamic, LIBS)
4384 fi
4385
4386 dnl autodetect dll support
4387 if test "$with_modules" != "no"; then
4388   AC_CHECKING(for module support)
4389
4390   dnl Check for MS-Windows
4391   if test "$with_msw" = "yes"; then
4392     have_dl=yes;
4393   else
4394     dnl Find headers and libraries
4395     AC_CHECK_HEADER(dlfcn.h, [
4396       AC_MSG_CHECKING([for dlopen in -lc])
4397       AC_TRY_LINK([#include <dlfcn.h>],dnl
4398         [dlopen ("", 0);], [ have_dl=yes ], [
4399       AC_MSG_CHECKING([for dlopen in -ldl])
4400       ac_save_LIBS="$LIBS"
4401       LIBS="-ldl $LIBS"
4402       AC_TRY_LINK([#include <dlfcn.h>],dnl
4403         [dlopen ("", 0);], [ have_dl=yes ],
4404         [LIBS="$ac_save_LIBS"])
4405       ac_save_LIBS=])])
4406     if test -n "$have_dl"; then
4407       AC_DEFINE(HAVE_DLOPEN)
4408     else
4409       AC_CHECK_LIB(dld, shl_load, [
4410         libdl=dld have_dl=yes;
4411         AC_DEFINE(HAVE_SHL_LOAD)], [
4412         AC_CHECK_LIB(dld, dld_init, [
4413         libdl=dld have_dl=yes;
4414         AC_DEFINE(HAVE_DLD_INIT)])])
4415     fi
4416   fi dnl end !MS-Windows
4417
4418   if test -n "$have_dl"; then
4419     dnl XE_SHLIB_STUFF (in aclocal.m4) defines $can_build_shared
4420     XE_SHLIB_STUFF
4421   fi
4422
4423   if test "$can_build_shared" = "yes"; then
4424     AC_DEFINE(HAVE_SHLIB)
4425     XE_ADD_OBJS(sysdll.o emodules.o)
4426     XE_APPEND(src, INSTALL_ARCH_DEP_SUBDIR)
4427     test -n "$libdl" && XE_PREPEND(-l${libdl}, LIBS)
4428     AC_CHECK_FUNCS(dlerror _dlerror)
4429     with_modules=yes
4430   else
4431     if test "$with_modules" = "yes"; then
4432       XE_DIE("Required module support cannot be provided.")
4433     else
4434       AC_MSG_WARN("Module support cannot be provided.")
4435     fi
4436     with_modules=no
4437   fi
4438 fi
4439
4440 dnl Unfortunately, just because we can link doesn't mean we can run.
4441 dnl One of the above link tests may have succeeded but caused resulting
4442 dnl executables to fail to run.  Also any tests using AC_TRY_RUN will
4443 dnl have reported incorrect results.
4444 AC_TRY_RUN([int main(int c,char *v[]){return 0;}],[:],[
4445   echo ""
4446   echo "*** PANIC *** The C compiler can no longer build working executables."
4447   echo "*** PANIC *** Please examine the tail of config.log for runtime errors."
4448   echo "*** PANIC *** The most likely reason for this problem is that configure"
4449   echo "*** PANIC *** links with shared libraries, but those libraries cannot be"
4450   echo "*** PANIC *** found at run time."
4451   echo "*** PANIC ***"
4452   echo "*** PANIC *** On a Linux system, edit /etc/ld.so.conf and re-run ldconfig."
4453   echo "*** PANIC *** On other systems, try telling configure where to find the"
4454   echo "*** PANIC *** shared libraries using the --site-runtime-libraries option"
4455   echo "*** PANIC ***"
4456   echo "*** PANIC *** Another way to shoot yourself in the foot is to specify"
4457   echo "*** PANIC *** --with-FEATURE when FEATURE is not actually installed"
4458   echo "*** PANIC *** on your system.  Don't do that."
4459   exit 1])
4460
4461 dnl Process support
4462 if test "$win32_processes" = "yes"; then
4463   XE_ADD_OBJS(process-nt.o)
4464 else
4465   AC_DEFINE(HAVE_UNIX_PROCESSES)
4466   XE_ADD_OBJS(process-unix.o)
4467 fi
4468
4469 dnl --------------------------------
4470 dnl Compute SUBST-itutable variables
4471 dnl --------------------------------
4472
4473 dnl We ignore (C|LD)_SWITCH_X_(MACHINE|SYSTEM)
4474 dnl Use XE_SPACE instead of plain assignment statements to remove extraneous blanks
4475 XE_SPACE(CFLAGS, $CFLAGS)
4476 XE_SPACE(extra_objs, $extra_objs)
4477 XE_SPACE(c_switch_general, -DHAVE_CONFIG_H $c_switch_site $c_switch_machine $c_switch_system)
4478 XE_SPACE(c_switch_window_system, $c_switch_x_site $c_switch_gtk $X_CFLAGS)
4479 XE_SPACE(c_switch_all, $c_switch_general $c_switch_window_system)
4480 XE_SPACE(ld_switch_general, $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_run)
4481 XE_SPACE(ld_switch_window_system, $ld_switch_x_site)
4482 XE_SPACE(ld_switch_all, $ld_switch_general $ld_switch_window_system)
4483 XE_SPACE(ld_libs_general, $LIBS $libs_machine $libs_system $libs_standard)
4484 XE_SPACE(ld_libs_window_system, $X_EXTRA_LIBS $libs_x $libs_gtk $X_PRE_LIBS)
4485 XE_SPACE(ld_libs_all, $ld_libs_window_system $ld_libs_general)
4486
4487 dnl Compute lists of Makefiles and subdirs
4488 AC_SUBST(SRC_SUBDIR_DEPS)
4489 XE_APPEND(src, MAKE_SUBDIR)
4490 internal_makefile_list="Makefile.in"
4491 SUBDIR_MAKEFILES=''
4492 test -d lock || mkdir lock
4493 for dir in $MAKE_SUBDIR; do
4494   case "$dir" in */* ) dnl Implement mkdir -p
4495     ( for d in `echo $dir | sed 's:/: :g'` ; do
4496         test -d "$d" || mkdir "$d"; cd "$d"
4497       done ) ;;
4498    * ) test -d "$dir" || mkdir "$dir" ;;
4499   esac
4500   XE_SPACE(SUBDIR_MAKEFILES, $SUBDIR_MAKEFILES $dir/Makefile $dir/GNUmakefile)
4501   XE_SPACE(internal_makefile_list, $internal_makefile_list $dir/Makefile.in)
4502 done
4503 AC_SUBST(INSTALL_ARCH_DEP_SUBDIR)
4504 AC_SUBST(MAKE_SUBDIR)
4505 AC_SUBST(SUBDIR_MAKEFILES)
4506
4507 dnl Make s&m symlinks in the src directory, for config.h
4508 for dir in src/s src/m; do
4509   if test ! -d "$dir" ; then
4510     echo Making symbolic link to "$srcdir/$dir"
4511     ${LN_S} "$srcdir/$dir" "$dir"
4512   fi
4513 done
4514
4515 if test "$extra_verbose" = "yes"; then
4516   echo ""
4517   PRINT_VAR(extra_objs
4518    c_switch_general  c_switch_window_system  c_switch_all
4519   ld_switch_general ld_switch_window_system ld_switch_all
4520     ld_libs_general   ld_libs_window_system   ld_libs_all)
4521   echo ""
4522 fi
4523
4524 dnl ----------------------------------------------
4525 dnl Create some auxiliary files for developers.
4526 dnl ----------------------------------------------
4527
4528 dnl Create a .gdbinit useful for debugging XEmacs
4529 if test -f "$srcdir/src/.gdbinit" -a ! -f "src/.gdbinit"; then
4530   test "$extra_verbose" = "yes" && echo "creating src/.gdbinit"
4531   echo "source $srcdir/src/.gdbinit" > "src/.gdbinit"
4532 fi
4533
4534 dnl Create a .dbxrc useful for debugging XEmacs
4535 if test -f "$srcdir/src/.dbxrc" -a ! -f "src/.dbxrc"; then
4536   test "$extra_verbose" = "yes" && echo "creating src/.dbxrc"
4537   echo ". $srcdir/src/.dbxrc" > "src/.dbxrc"
4538 fi
4539
4540 dnl Create a useful TAGS file
4541 if test -f "$srcdir/TAGS" -a ! -f "TAGS"; then
4542   test "$extra_verbose" = "yes" && echo "creating TAGS"
4543   echo "\f
4544 $srcdir/TAGS,include" > "TAGS"
4545 fi
4546
4547 dnl Create top level .sbinit for Sun compilers
4548 if test "$__SUNPRO_C" = "yes"; then
4549   test "$extra_verbose" = "yes" && echo "creating .sbinit"
4550   ( echo "# For use with Sun WorkShop's Source browser."
4551     echo "# See sbquery(1) and sbinit(4) for more information"
4552     for dir in $MAKE_SUBDIR; do echo "import $dir"; done
4553   ) > .sbinit
4554 fi
4555
4556 dnl There are no more compile tests; remove the core they created.
4557 rm -f core
4558
4559 dnl ----------------------------------------------
4560 dnl Substitute into Makefile, config.h and paths.h
4561 dnl ----------------------------------------------
4562
4563 dnl what sort of things to edit into Makefile, config.h and paths.h
4564 dnl configuration here uncanonicalized to avoid exceeding size limits.
4565
4566 AC_SUBST(PROGNAME)
4567 AC_SUBST(version)
4568 AC_SUBST(configuration)
4569 AC_SUBST(canonical)
4570 AC_SUBST(inststaticdir)
4571 AC_SUBST(instvardir)
4572 AC_SUBST(srcdir)
4573 AC_SUBST(bindir)
4574 AC_SUBST(datadir)
4575 AC_SUBST(pkgdir)
4576 AC_SUBST(statedir)
4577 AC_SUBST(libdir)
4578 AC_SUBST(mandir)
4579 AC_SUBST(extra_includes)
4580
4581 AC_SUBST(prefix)
4582 AC_SUBST(PREFIX_USER_DEFINED)
4583 dnl Yo, Stephen Bourne!  I want to marry you!
4584 PREFIX=$prefix
4585 while true; do
4586   case "$PREFIX" in
4587     *\$* ) eval "PREFIX=$PREFIX" ;;
4588     *) break ;;
4589   esac
4590 done
4591 AC_SUBST(PREFIX)
4592
4593 AC_SUBST(exec_prefix)
4594 AC_SUBST(EXEC_PREFIX_USER_DEFINED)
4595 EXEC_PREFIX=$exec_prefix
4596 while true; do
4597   case "$EXEC_PREFIX" in
4598     *\$* ) eval "EXEC_PREFIX=$EXEC_PREFIX" ;;
4599     *) break ;;
4600   esac
4601 done
4602 AC_SUBST(EXEC_PREFIX)
4603
4604 AC_SUBST(infodir)
4605 AC_SUBST(INFODIR_USER_DEFINED)
4606 INFODIR=$infodir
4607 while true; do
4608   case "$INFODIR" in
4609     *\$* ) eval "INFODIR=$INFODIR" ;;
4610     *) break ;;
4611   esac
4612 done
4613 AC_SUBST(INFODIR)
4614
4615 AC_SUBST(infopath)
4616 AC_SUBST(INFOPATH_USER_DEFINED)
4617 INFOPATH=$infopath
4618 while true; do
4619   case "$INFOPATH" in
4620     *\$* ) eval "INFOPATH=$INFOPATH" ;;
4621     *) break ;;
4622   esac
4623 done
4624 AC_SUBST(INFOPATH)
4625
4626 AC_SUBST(package_path)
4627 AC_SUBST(PACKAGE_PATH_USER_DEFINED)
4628 PACKAGE_PATH=$package_path
4629 while true; do
4630   case "$PACKAGE_PATH" in
4631     *\$* ) eval "PACKAGE_PATH=$PACKAGE_PATH" ;;
4632     *) break ;;
4633   esac
4634 done
4635 AC_SUBST(PACKAGE_PATH)
4636
4637 AC_SUBST(lispdir)
4638 AC_SUBST(LISPDIR_USER_DEFINED)
4639 LISPDIR=$lispdir
4640 while true; do
4641   case "$LISPDIR" in
4642     *\$* ) eval "LISPDIR=$LISPDIR" ;;
4643     *) break ;;
4644   esac
4645 done
4646 AC_SUBST(LISPDIR)
4647
4648 AC_SUBST(moduledir)
4649 AC_SUBST(MODULEDIR_USER_DEFINED)
4650 MODULEDIR=$moduledir
4651 while true; do
4652   case "$MODULEDIR" in
4653     *\$* ) eval "MODULEDIR=$MODULEDIR" ;;
4654     *) break ;;
4655   esac
4656 done
4657 AC_SUBST(MODULEDIR)
4658
4659 AC_SUBST(sitelispdir)
4660 AC_SUBST(SITELISPDIR_USER_DEFINED)
4661 SITELISPDIR=$sitelispdir
4662 while true; do
4663   case "$SITELISPDIR" in
4664     *\$* ) eval "SITELISPDIR=$SITELISPDIR" ;;
4665     *) break ;;
4666   esac
4667 done
4668 AC_SUBST(SITELISPDIR)
4669
4670 AC_SUBST(sitemoduledir)
4671 AC_SUBST(SITEMODULEDIR_USER_DEFINED)
4672 SITEMODULEDIR=$sitemoduledir
4673 while true; do
4674   case "$SITEMODULEDIR" in
4675     *\$* ) eval "SITEMODULEDIR=$SITEMODULEDIR" ;;
4676     *) break ;;
4677   esac
4678 done
4679 AC_SUBST(SITEMODULEDIR)
4680
4681 AC_SUBST(etcdir)
4682 AC_SUBST(ETCDIR_USER_DEFINED)
4683 ETCDIR=$etcdir
4684 while true; do
4685   case "$ETCDIR" in
4686     *\$* ) eval "ETCDIR=$ETCDIR" ;;
4687     *) break ;;
4688   esac
4689 done
4690 AC_SUBST(ETCDIR)
4691
4692 AC_SUBST(docdir)
4693 AC_SUBST(DOCDIR_USER_DEFINED)
4694 DOCDIR=$docdir
4695 while true; do
4696   case "$DOCDIR" in
4697     *\$* ) eval "DOCDIR=$DOCDIR" ;;
4698     *) break ;;
4699   esac
4700 done
4701 AC_SUBST(DOCDIR)
4702
4703 AC_SUBST(archlibdir)
4704 AC_SUBST(ARCHLIBDIR_USER_DEFINED)
4705 ARCHLIBDIR=$archlibdir
4706 while true; do
4707   case "$ARCHLIBDIR" in
4708     *\$* ) eval "ARCHLIBDIR=$ARCHLIBDIR" ;;
4709     *) break ;;
4710   esac
4711 done
4712 AC_SUBST(ARCHLIBDIR)
4713
4714 AC_SUBST(docdir)
4715 AC_SUBST(bitmapdir)
4716 AC_SUBST(extra_objs)
4717
4718 dnl The following flags combine all the information from:
4719 dnl - command line options (user always gets priority)
4720 dnl - user environment variables
4721 dnl - determined by configure
4722 dnl - the s&m header files (required for ellcc)
4723 AC_SUBST(machfile)
4724 AC_SUBST(opsysfile)
4725 AC_SUBST(c_switch_general)
4726 AC_SUBST(c_switch_window_system)
4727 AC_SUBST(c_switch_all)
4728 AC_SUBST(ld_switch_general)
4729 AC_SUBST(ld_switch_window_system)
4730 AC_SUBST(ld_switch_all)
4731 AC_SUBST(ld_libs_general)
4732 AC_SUBST(ld_libs_window_system)
4733 AC_SUBST(ld_libs_all)
4734 AC_SUBST(CFLAGS)
4735 AC_SUBST(CPPFLAGS)
4736 AC_SUBST(LDFLAGS)
4737 RECURSIVE_MAKE="\$(MAKE) \$(MFLAGS) CC='\$(CC)' CFLAGS='\$(CFLAGS)' LDFLAGS='\$(LDFLAGS)' CPPFLAGS='\$(CPPFLAGS)'"
4738 AC_SUBST(RECURSIVE_MAKE)
4739
4740 AC_SUBST(native_sound_lib)
4741 AC_SUBST(sound_cflags)
4742 AC_SUBST(RANLIB)
4743 AC_SUBST(dynodump_arch)
4744
4745 dnl Preliminary support for using a different compiler for xemacs itself.
4746 dnl Useful for building XEmacs with a C++ or 64-bit compiler.
4747 : ${XEMACS_CC:=$CC}
4748 AC_SUBST(XEMACS_CC)
4749
4750 dnl The default is yes
4751 if test "$with_prefix" = "yes"; then
4752   AC_DEFINE(PREFIX_USER_DEFINED)
4753 fi
4754
4755 dnl The default is no
4756 if test "$with_site_lisp" = "no"; then
4757   AC_DEFINE(INHIBIT_SITE_LISP)
4758 fi
4759 dnl The default is yes
4760 if test "$with_site_modules" = "no"; then
4761   AC_DEFINE(INHIBIT_SITE_MODULES)
4762 fi
4763
4764 XE_SPACE(ac_configure_args, $ac_configure_args)
4765 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "$configuration")
4766 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "$ac_configure_args")
4767
4768 dnl Following are deprecated
4769
4770 null_string=""
4771 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE,     $null_string)
4772 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, $null_string)
4773 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,      $null_string)
4774 AC_DEFINE_UNQUOTED(LD_SWITCH_SITE,       $null_string)
4775 AC_DEFINE_UNQUOTED(C_SWITCH_SITE,        $null_string)
4776
4777 dnl Note: as a general rule, *only* define things here that are not
4778 dnl autodetected.  For things that are autodetected, define them
4779 dnl at the point where the autodetection occurs or would occur,
4780 dnl so that the user gets immediate feedback on the results of the
4781 dnl autodetection.
4782
4783 if   test "$GNU_MALLOC"         = "yes"; then AC_DEFINE(GNU_MALLOC)
4784 elif test "$with_system_malloc" = "yes"; then AC_DEFINE(USE_SYSTEM_MALLOC)
4785 elif test "$with_debug_malloc"  = "yes"; then AC_DEFINE(USE_DEBUG_MALLOC)
4786                                               AC_DEFINE(USE_SYSTEM_MALLOC)
4787 fi
4788 test "$with_i18n3"         = "yes" && AC_DEFINE(I18N3)
4789 test "$GCC"                = "yes" && AC_DEFINE(USE_GCC)
4790 test "$external_widget"    = "yes" && AC_DEFINE(EXTERNAL_WIDGET)
4791 test "$quick_build"        = "yes" && AC_DEFINE(QUICK_BUILD)
4792 test "$with_purify"        = "yes" && AC_DEFINE(PURIFY)
4793 test "$with_quantify"      = "yes" && AC_DEFINE(QUANTIFY)
4794 test "$with_pop"           = "yes" && AC_DEFINE(MAIL_USE_POP)
4795 test "$with_kerberos"      = "yes" && AC_DEFINE(KERBEROS)
4796 test "$with_hesiod"        = "yes" && AC_DEFINE(HESIOD)
4797 test "$use_union_type"     = "yes" && AC_DEFINE(USE_UNION_TYPE)
4798 test "$pdump"              = "yes" && AC_DEFINE(PDUMP)
4799 test "$with_ipv6_cname"    = "yes" && AC_DEFINE(IPV6_CANONICALIZE)
4800
4801 dnl -------------------------------
4802 dnl Report on what we decided to do
4803 dnl -------------------------------
4804
4805 (
4806 dnl /etc/osversion is on SONY NEWS-OS
4807 if test -f /etc/osversion; then dnl SONY NEWS-OS
4808   echo "osversion: `cat /etc/osversion`"
4809 else
4810   echo "uname -a: `uname -a`"
4811 fi
4812 echo ""
4813 echo "$0 $quoted_arguments"
4814 ) > Installation
4815
4816 if test ! -z ${emacs_beta_version} ; then
4817   if test -z "${emacs_is_beta}" ; then
4818         xemacs_betaname=".${emacs_beta_version}"
4819   else
4820         xemacs_betaname="-b${emacs_beta_version}"
4821   fi
4822 else
4823   xemacs_betaname=""
4824 fi
4825
4826 dnl Start stdout redirection to '| tee -a Installation'
4827 (
4828 echo "
4829
4830 XEmacs ${emacs_major_version}.${emacs_minor_version}${xemacs_betaname} \"$xemacs_codename\" configured for \`$canonical'.
4831 "
4832 echo "
4833 Compilation / Installation:"
4834 echo "  Source code location:              $srcdir"
4835 echo "  Installation prefix:               $prefix"
4836 if test -n "$site_includes"; then
4837   echo "  Additional header files:           $site_includes"
4838 fi
4839 if test -n "$site_libraries"; then
4840   echo "  Additional libraries:              $site_libraries"
4841 fi
4842 if test -n "$site_prefixes"; then
4843   echo "  Additional prefixes:               $site_prefixes"
4844 fi
4845 if test -n "$runpath"; then
4846   echo "  Runtime library search path:       $runpath"
4847 fi
4848
4849 if test -n "$opsysfile"
4850 then echo "  Operating system description file: \`$opsysfile'"
4851 else echo "  Not using any operating system description file"
4852 fi
4853 if test -n "$machfile"
4854 then echo "  Machine description file:          \`$machfile'"
4855 else echo "  Not using any machine description file"
4856 fi
4857
4858 echo "  Compiler:                          $CC $CFLAGS"
4859 echo "  Relocating allocator for buffers:  $rel_alloc"
4860 echo "  GNU version of malloc:             ${GNU_MALLOC}${GNU_MALLOC_reason}"
4861 case "$ld_switch_site" in
4862   *nocombreloc*) echo "  Linking with \`-z nocombreloc'.
4863     - Consider configuring with --pdump." ;;
4864 esac
4865
4866 echo "
4867 Window System:"
4868 if test "$with_msw" = "yes"; then
4869   echo "  Compiling in support for the Microsoft window system."
4870 fi
4871 if test "$with_x11" = "yes"; then
4872   echo "  Compiling in support for the X window system:"
4873   echo "    - X Windows headers location:                 $x_includes"
4874   echo "    - X Windows libraries location:               $x_libraries"
4875   if test "$with_xauth" != yes; then
4876     echo "    - Xau (X authority) not available."
4877   fi
4878   if test "$with_xmu" != yes; then
4879     echo "    - Xmu library not available; substituting equivalent routines."
4880   fi
4881   if test "$with_wmcommand" != no; then
4882     echo "    - Handling WM_COMMAND properly."
4883   fi
4884 fi
4885 if test "$need_athena" = "yes"; then
4886   echo "  Compiling in support for the Athena widget set:"
4887   echo "    - Athena headers location:                    $athena_h_path"
4888   echo "    - Athena library to link:                     $athena_lib"
4889 fi
4890 case "$with_menubars" in
4891   gtk   ) echo "  Using GTK menubars."   ;;
4892   lucid ) echo "  Using Lucid menubars." ;;
4893   motif ) echo "  Using Motif menubars."
4894           echo "  *WARNING*  The Motif menubar implementation is currently buggy."
4895           echo "             We recommend using the Lucid menubar instead."
4896           echo "             Re-run configure with --with-menubars='lucid'." ;;
4897     msw ) echo "  Using MS-Windows menubars." ;;
4898 esac
4899 case "$with_scrollbars" in
4900   gtk    ) echo "  Using GTK scrollbars."        ;;
4901   lucid  ) echo "  Using Lucid scrollbars."      ;;
4902   motif  ) echo "  Using Motif scrollbars."      ;;
4903   athena ) echo "  Using Athena scrollbars."     ;;
4904      msw ) echo "  Using MS-Windows scrollbars." ;;
4905 esac
4906 case "$with_dialogs" in
4907   gtk    ) echo "  Using GTK dialog boxes." ;;
4908   motif  ) echo "  Using Motif dialog boxes."
4909            if test "$unexec" = "unexaix.o"; then if test "`uname -v`" = 4 -a "`uname -r`" -ge 3; then
4910              echo "  *WARNING*  The Motif dialog boxes cause problems on AIX 4.3 and higher."
4911              echo "             We recommend using the Athena dialog boxes instead."
4912              echo "             Install libXaw and re-run configure with --with-dialogs='athena'."
4913              echo "             Read the PROBLEMS file for more information."
4914            fi; fi ;;
4915   athena ) echo "  Using Athena dialog boxes."     ;;
4916      msw ) echo "  Using MS-Windows dialog boxes." ;;
4917 esac
4918 case "$with_widgets" in
4919   gtk    ) echo "  Using GTK native widgets."        ;;
4920   motif  ) echo "  Using Motif native widgets."      ;;
4921   athena ) echo "  Using Athena native widgets."     ;;
4922      msw ) echo "  Using MS-Windows native widgets." ;;
4923 esac
4924 if test "$with_dragndrop" = yes; then
4925   echo "  Compiling in support for Drag'n'Drop (EXPERIMENTAL)."
4926   echo "    -  Drag'n'Drop prototype:                             $dragndrop_proto."
4927 fi
4928
4929 echo "
4930 TTY:"
4931 test "$with_ncurses" = yes && echo "  Compiling in support for ncurses."
4932 test "$with_gpm" = yes && echo "  Compiling in support for GPM (General Purpose Mouse)."
4933
4934 echo "
4935 Images:"
4936 test "$with_gif" = yes && echo "  Compiling in support for GIF  images (builtin)."
4937 if test "$with_xpm" = yes; then
4938   echo "  Compiling in support for XPM  images."
4939 elif test "$with_x11" = yes; then
4940   echo "  WARNING: -----------------------------------------------------------"
4941   echo "  WARNING: Compiling without XPM image support."
4942   if test "$xpm_problem" != ""; then
4943     echo "  Reason: $xpm_problem"
4944   fi
4945   echo "  WARNING: You should strongly consider installing XPM."
4946   echo "  WARNING: Otherwise toolbars and other graphics will look suboptimal."
4947   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
4948   echo "  WARNING: -----------------------------------------------------------"
4949 fi
4950 if test "$with_png" = yes; then
4951   echo "  Compiling in support for PNG  images."
4952 elif test "$window_system" != "none"; then
4953   echo "  WARNING: -----------------------------------------------------------"
4954   echo "  WARNING: Compiling without PNG image support."
4955   if test "$png_problem" != ""; then
4956     echo "  Reason: $png_problem"
4957   fi
4958   echo "  WARNING: You should strongly consider installing the PNG libraries."
4959   echo "  WARNING: Otherwise certain images and glyphs may not display."
4960   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
4961   echo "  WARNING: -----------------------------------------------------------"
4962 fi
4963 test "$with_jpeg" = yes && echo "  Compiling in support for JPEG images."
4964 test "$with_tiff" = yes && echo "  Compiling in support for TIFF images."
4965 test "$with_xface" = yes && echo "  Compiling in support for X-Face message headers."
4966
4967 echo "
4968 Sound:"
4969 test "$with_native_sound" = yes && echo "  Compiling in support for sound (native)."
4970 test "$with_nas_sound" = yes && echo "  Compiling in support for NAS (network audio system)."
4971 test "$old_nas" = yes && echo "    - NAS library lacks error trapping; will play synchronously."
4972 test "$with_esd_sound" = yes && echo "  Compiling in support for ESD (Enlightened Sound Daemon)."
4973
4974 echo "
4975 Databases:"
4976 test "$with_database_berkdb" = yes && echo "  Compiling in support for Berkeley database."
4977 test "$with_database_dbm"    = yes && echo "  Compiling in support for DBM."
4978 test "$with_database_gdbm"   = yes && echo "  Compiling in support for GNU DBM."
4979 test "$with_ldap" = yes && echo "  Compiling in support for LDAP."
4980 if test "$with_postgresql" = yes; then
4981   echo "  Compiling in support for PostgreSQL."
4982   echo "    - Using PostgreSQL header file:  $libpq_fe_h_file"
4983   test "$with_postgresqlv7" = yes && echo "    - Using PostgreSQL V7 bindings."
4984 fi
4985
4986 echo "
4987 Internationalization:"
4988 test "$with_mule" = yes && echo "  Compiling in support for Mule (multi-lingual Emacs)."
4989 test "$with_file_coding" = yes && echo "  Compiling in support for file coding."
4990 test "$with_xim" != no && echo "  Compiling in support for XIM (X11R5+ I18N input method)."
4991 test "$with_xim" = motif && echo "    - Using Motif to provide XIM support."
4992 test "$with_xim" = xlib && echo "    - Using raw Xlib to provide XIM support."
4993 test "$with_xfs" = yes && echo "    - Using XFontSet to provide bilingual menubar."
4994 test "$with_canna" = yes && echo "  Compiling in support for Canna on Mule."
4995 if test "$with_wnn" = yes; then
4996   echo "  Compiling in support for the WNN input method on Mule."
4997   test "$with_wnn6" = yes && echo "    - Using WNN version 6."
4998 fi
4999 test "$with_i18n3" = yes && echo "  Compiling in support for I18N level 3 (doesn't currently work)."
5000
5001 echo "
5002 Mail:"
5003 test "$with_pop" = yes && echo "  Compiling in support for POP mail retrieval."
5004 test "$with_kerberos" = yes && echo "  Compiling in support for Kerberos POP authentication."
5005 test "$with_hesiod" = yes && echo "  Compiling in support for Hesiod POP server access."
5006 test -n "$mail_locking" && echo "  Compiling in support for \"$mail_locking\" mail spool file locking method."
5007
5008 echo "
5009 Other Features:"
5010 test "$with_ipv6_cname" = no && echo "  Inhibiting IPv6 canonicalization at startup."
5011 test "$with_tooltalk" = yes && echo "  Compiling in support for ToolTalk."
5012 test "$with_workshop" = yes && echo "  Compiling in support for Sun WorkShop."
5013 test "$with_socks" = yes && echo "  Compiling in support for SOCKS."
5014 test "$with_dnet" = yes && echo "  Compiling in support for DNET."
5015 test "$with_modules" = "yes" && echo "  Compiling in support for dynamic shared object modules."
5016 test "$use_union_type" = yes && echo "  Using the union type for Lisp_Objects."
5017 test "$pdump" = yes && echo "  Using the new portable dumper."
5018 test "$debug" = yes && echo "  Compiling in support for extra debugging code."
5019 test "$usage_tracking" = yes && echo "  Compiling in support for active usage tracking (Sun internal)."
5020 if test "$error_check_extents $error_check_typecheck $error_check_bufpos $error_check_gc $error_check_malloc $error_check_glyphs" \
5021   != "no no no no no no"; then
5022   echo "  WARNING: ---------------------------------------------------------"
5023   echo "  WARNING: Compiling in support for runtime error checking."
5024   echo "  WARNING: XEmacs will run noticeably more slowly as a result."
5025   echo "  WARNING: Error checking is on by default for XEmacs beta releases."
5026   echo "  WARNING: ---------------------------------------------------------"
5027 fi
5028 echo ""
5029 ) | tee -a Installation
5030 dnl echo "The above configure report is appended to \"Installation\" file."
5031 echo ""
5032
5033 dnl -----------------------------------
5034 dnl Now generate config.h and Makefiles
5035 dnl -----------------------------------
5036 dnl This has to be called in order for this variable to get into config.status
5037 AC_SUBST(internal_makefile_list)
5038 # Remove any trailing slashes in these variables.
5039 test -n "$prefix" &&
5040   prefix=`echo '' "$prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
5041 test -n "$exec_prefix" &&
5042   exec_prefix=`echo '' "$exec_prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
5043
5044 dnl Build Makefile.in's from Makefile.in.in's
5045 dnl except ./Makefile from $srcdir/Makefile.in
5046
5047 for file in $internal_makefile_list; do
5048   test "$file" = src/Makefile.in && \
5049     file="src/Makefile.in:src/Makefile.in.in:src/depend"
5050   XE_APPEND($file, ac_output_files)
5051 done
5052 ac_output_files="$ac_output_files src/paths.h lib-src/config.values"
5053 test "$with_modules" = "yes" && XE_APPEND(lib-src/ellcc.h, ac_output_files)
5054
5055 AC_OUTPUT($ac_output_files,
5056 [for dir in . $MAKE_SUBDIR; do
5057   (
5058     cd $dir
5059     rm -f junk.c
5060     < Makefile.in \
5061       sed -e '/^# Generated/d' \
5062           -e 's%/\*\*/#.*%%' \
5063           -e 's/^ *# */#/' \
5064 dnl Delete Makefile.in.in comment lines
5065           -e '/^##/d' \
5066 dnl Pass through CPP directives unchanged
5067           -e '/^#/ {
5068 p
5069 d
5070 }'        \
5071 dnl Quote other lines to protect from CPP substitution
5072           -e '/./ {
5073 s/\([[\"]]\)/\\\1/g
5074 s/^/"/
5075 s/$/"/
5076 }'  > junk.c;
5077
5078 dnl Create a GNUmakefile and Makefile from Makefile.in.
5079
5080 changequote(<<,>>)dnl
5081 dnl CPP_MAKEFILE(CPPFLAGS,filename)
5082 define(<<CPP_MAKEFILE>>,
5083 echo creating $dir/<<$2>>
5084 $CPP -I. -I${top_srcdir}/src <<$1>> junk.c \
5085 dnl Delete line directives inserted by $CPP
5086   | sed -e 's/^\#.*//'          \
5087 dnl Delete spurious blanks inserted by $CPP
5088         -e 's/^[ TAB][ TAB]*$//'\
5089         -e 's/^ /TAB/'          \
5090 dnl Delete blank lines
5091         -e '/^[ \f]*$/d' \
5092 dnl Restore lines quoted above to original contents.
5093         -e '/^\"/ {
5094         s/\\\([\"]\)/\1/g
5095         s/^[ TAB]*\"//
5096         s/\"[ TAB]*$//
5097 }' > Makefile.new
5098     chmod 444 Makefile.new
5099     mv -f Makefile.new <<$2>>
5100 )dnl CPP_MAKEFILE
5101
5102     CPP_MAKEFILE(,Makefile)
5103     CPP_MAKEFILE(-DUSE_GNU_MAKE,GNUmakefile)
5104 changequote([,])dnl
5105     rm -f junk.c
5106   )
5107 done
5108
5109 dnl Append AC_DEFINE information to lib-src/config.values
5110 dnl (AC_SUBST information is already there (see config.values.sh).
5111 sed < config.status >> lib-src/config.values \
5112   -e '/{ac_dA}.*{ac_dB}.*{ac_dC}.*{ac_dD}$/!d' \
5113   -e 's/\${ac_dA}\(.*\)\${ac_dB}.*\${ac_dC}\(.*\)\${ac_dD}/\1 \2/' \
5114   -e 's/^\([[^ ]]*\) $/\1 ""/' \
5115   -e 's/ 1$/ t/'
5116
5117 ],
5118 [CPP="$CPP"
5119  top_srcdir="$srcdir"
5120  MAKE_SUBDIR="$MAKE_SUBDIR"
5121 ])dnl