git.chise.org Git - chise/xemacs-chise.git.1/blob - configure.in

   1 dnl Define our own header notice with own copyright
   2 define([AC_INIT_NOTICE],
   3 [#### Configuration script for XEmacs.  Largely divergent from FSF.
   4 #### Guess values for system-dependent variables and create Makefiles.
   5 #### Generated automatically using autoconf version] AC_ACVERSION [
   6 #### Copyright (C) 1992, 93, 94, 95, 96 Free Software Foundation, Inc.
   7 #### Copyright (C) 1993-1995 Board of Trustees, University of Illinois.
   8 #### Copyright (C) 1996, 1997 Sun Microsystems, Inc.
   9 #### Copyright (C) 1995, 1996 Ben Wing.
  10 #### Copyright (C) 1998, 1999 J. Kean Johnston.
  11
  12 ### Don't edit this script!
  13 ### This script was automatically generated by the `autoconf' program
  14 ### from the file `./configure.in'.
  15 ### To rebuild it, execute the command
  16 ###     autoconf
  17 ### in the this directory.  You must have autoconf version 2.12 or later.
  18
  19 ### This file is part of XEmacs.
  20
  21 ### XEmacs is free software; you can redistribute it and/or modify it
  22 ### under the terms of the GNU General Public License as published by
  23 ### the Free Software Foundation; either version 2, or (at your
  24 ### option) any later version.
  25
  26 ### XEmacs is distributed in the hope that it will be useful, but
  27 ### WITHOUT ANY WARRANTY; without even the implied warranty of
  28 ### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  29 ### General Public License for more details.
  30
  31 ### You should have received a copy of the GNU General Public License
  32 ### along with XEmacs; see the file COPYING.  If not, write to the Free
  33 ### Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  34 ### 02111-1307, USA.
  35
  36 ### For usage, run `./configure --help'
  37 ### For more detailed information on building and installing XEmacs,
  38 ### read the file `INSTALL'.
  39 ###
  40 ### If configure succeeds, it leaves its status in config.status.
  41 ### A log of configuration tests can be found in config.log.
  42 ### If configure fails after disturbing the status quo,
  43 ###     config.status is removed.
  44 ])
  45
  46 dnl Since XEmacs has configuration requirements that autoconf cannot
  47 dnl meet, this file is an unholy marriage of custom-baked
  48 dnl configuration code and autoconf macros.
  49
  50 dnl We use the m4 quoting characters [ ] (as established by the
  51 dnl autoconf system), so quote them like this: [[foo]]
  52
  53 AC_PREREQ(2.12)dnl
  54 dnl Redefine some standard autoconf macros
  55 dnl here is how XEmacs is different:
  56 dnl - no cache file
  57 dnl - non-standard options
  58 dnl - suport for extra-verbosity
  59 dnl - ordinary libs are handled separately from X libs (might be a mistake)
  60 dnl - various random kludges (e.g. -with-dnet=no
  61
  62 dnl PRINT_VAR(var var ...)  prints values of shell variables
  63 define([PRINT_VAR],[for var in patsubst([$1],[[
  64 ]+],[ ]); do eval "echo \"$var = '\$$var'\""; done])
  65
  66 dnl Disable cache files:
  67 dnl This is controversial, but I am convinced this is the right way to go,
  68 dnl at least by default.  Otherwise there are too many surprises.
  69 define([AC_CACHE_LOAD], )dnl
  70 define([AC_CACHE_SAVE], )dnl
  71 define([AC_CACHE_VAL], [
  72 $2
  73 ])dnl
  74
  75 dnl Redefine AC_TRY_RUN_NATIVE to not throw away stderr while running
  76 dnl AC_TRY_RUN_NATIVE(PROGRAM, [ACTION-IF-TRUE [, ACTION-IF-FALSE]])
  77 define([AC_TRY_RUN_NATIVE],
  78 [cat > conftest.$ac_ext <<EOF
  79 [#]line __oline__ "configure"
  80 #include "confdefs.h"
  81 [$1]
  82 EOF
  83 if AC_TRY_EVAL(ac_link) && test -s conftest && (./conftest; exit $?) 2>&AC_FD_CC
  84 then
  85 dnl Do not remove the temporary files here, so they can be examined.
  86   ifelse([$2], , :, [$2])
  87 else
  88   conftest_rc="$?"
  89   echo "configure: failed program was:" >&AC_FD_CC
  90   cat conftest.$ac_ext >&AC_FD_CC
  91 ifelse([$3], , , [  rm -fr conftest*
  92   $3
  93 ])dnl
  94 fi
  95 rm -fr conftest*])dnl AC_TRY_RUN_NATIVE
  96
  97
  98 dnl Avoid spurious cross-compiling warnings from AC_TRY_RUN
  99 dnl XEmacs is unlikely to ever cross-compile
 100 define([AC_TRY_RUN],[AC_TRY_RUN_NATIVE([$1], [$2], [$3])])dnl
 101
 102 dnl Redefine AC_DEFINE* to provide more output if extra_verbose
 103 dnl Set VARIABLE to VALUE, verbatim, or 1.
 104 dnl AC_DEFINE(VARIABLE [, VALUE])
 105 define([AC_DEFINE],
 106 [{ test "$extra_verbose" = "yes" && cat << \EOF
 107     Defining $1[]ifelse($#, 2, [ = $2],)
 108 EOF
 109 cat >> confdefs.h <<\EOF
 110 [#define] $1 ifelse($#, 2, [$2], 1)
 111 EOF
 112 }
 113 ])dnl AC_DEFINE
 114
 115 define([AC_DEFINE_UNQUOTED],
 116 [{ test "$extra_verbose" = "yes" && cat << EOF
 117     Defining $1[]ifelse($#, 2, [ = $2],)
 118 EOF
 119 cat >> confdefs.h <<EOF
 120 [#define] $1 ifelse($#, 2, [$2], 1)
 121 EOF
 122 }
 123 ])dnl AC_DEFINE_UNQUOTED
 124
 125 dnl redefine AC_CHECK_LIB in accordance with our own value of ac_link
 126 dnl Add in extra kludgy check to support with_dnet=no
 127 dnl Add in extra LDFLAGS arg, which PRECEDE libs
 128 dnl Support --with-dnet=no
 129
 130 dnl AC_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND
 131 dnl             [, OTHER-LIBRARIES] [, LDFLAGS]]]])
 132 define([AC_CHECK_LIB],
 133 [ifelse([$1],dnet, [if test "$with_dnet" = "no" ; then
 134 ac_cv_lib_dnet_dnet_ntoa=no
 135 ifelse([$4], , , [$4]
 136 )dnl
 137 else
 138 ])]
 139 AC_CHECK_LIB_ORIG_HACKED([$1],[$2],[$3],[$4],[$5], [$6])
 140 [ifelse([$1],dnet,[fi
 141 ])]dnl
 142 )dnl AC_CHECK_LIB
 143
 144 define([AC_CHECK_LIB_ORIG_HACKED],
 145 [ifelse([$5],,AC_MSG_CHECKING([for $2 in -l$1]),
 146 xe_msg_checking="for [$2] in -l[$1]"
 147 test -n "[$5]" && xe_msg_checking="$xe_msg_checking using extra libs [$5]"
 148 AC_MSG_CHECKING("$xe_msg_checking"))
 149 dnl Use a cache variable name containing both the library and function name,
 150 dnl because the test really is for library $1 defining function $2, not
 151 dnl just for library $1.  Separate tests with the same $1 and different $2s
 152 dnl may have different results.
 153 ac_lib_var=`echo $1['_']$2 | sed 'y%./+-%__p_%'`
 154 AC_CACHE_VAL(ac_cv_lib_$ac_lib_var,
 155 [xe_check_libs="$6 -l$1 $5"
 156 AC_TRY_LINK(dnl
 157 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
 158 [/* Override any gcc2 internal prototype to avoid an error.  */
 159 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
 160 extern "C"
 161 #endif
 162 ])dnl
 163 [/* We use char because int might match the return type of a gcc2
 164     builtin and then its argument prototype would still apply.  */
 165 char $2();
 166 ]),
 167             [$2()],
 168             eval "ac_cv_lib_$ac_lib_var=yes",
 169             eval "ac_cv_lib_$ac_lib_var=no")
 170 xe_check_libs=""
 171 ])dnl
 172 if eval "test \"`echo '$ac_cv_lib_'$ac_lib_var`\" = yes" ; then
 173   AC_MSG_RESULT(yes)
 174   ifelse([$3], ,
 175 [changequote(, )dnl
 176   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
 177     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
 178 changequote([, ])dnl
 179   AC_DEFINE_UNQUOTED($ac_tr_lib)
 180   XE_PREPEND([-l$1], LIBS)
 181 ], [$3])
 182 else
 183   AC_MSG_RESULT(no)
 184 ifelse([$4], , , [$4
 185 ])dnl
 186 fi
 187 ])dnl AC_CHECK_LIB_ORIG_HACKED
 188
 189
 190 dnl AC_LANG_C()
 191 define([AC_LANG_C],
 192 [define([AC_LANG], [C])dnl
 193 ac_ext=c
 194 dnl CFLAGS is not in ac_cpp because -g, -O, etc. are not valid cpp options.
 195 dnl ac_cpp='$CPP $CPPFLAGS'
 196 dnl ac_compile='${CC-cc} -c $CFLAGS $CPPFLAGS conftest.$ac_ext 1>&AC_FD_CC'
 197 dnl ac_link='${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS conftest.$ac_ext $LIBS 1>&AC_FD_CC'
 198 xe_cppflags='$CPPFLAGS $c_switch_site $c_switch_machine $c_switch_system $c_switch_x_site $X_CFLAGS'
 199 xe_ldflags='$LDFLAGS $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_x_site $ld_switch_run'
 200 xe_libs='$ld_call_shared $xe_check_libs $X_EXTRA_LIBS $libs_x $X_PRE_LIBS $LIBS $libs_machine $libs_system $libs_standard'
 201 ac_cpp='$CPP '"$xe_cppflags"
 202 ac_compile='${CC-cc} -c $CFLAGS '"$xe_cppflags"' conftest.$ac_ext 1>&AC_FD_CC'
 203 ac_link='${CC-cc} -o conftest $CFLAGS '"$xe_cppflags $xe_ldflags"' conftest.$ac_ext '"$xe_libs"' 1>&AC_FD_CC'
 204 cross_compiling=no
 205 ]) dnl AC_LANG_C
 206
 207 dnl The construct foo=`echo $w1 $w2 $w3` fails on some systems if $w1 = -e or -n
 208 dnl So we use the following instead.
 209 dnl XE_SPACE(var, words)
 210 define([XE_SPACE],[
 211 T=""
 212 for W in $2; do if test -z "$T"; then T="$W"; else T="$T $W"; fi; done
 213 $1="$T"
 214 ])dnl XE_SPACE
 215
 216 dnl XE_ADD_OBJS(foo.o ...)
 217 define([XE_ADD_OBJS],
 218 [extra_objs="$extra_objs [$1]" && dnl
 219  if test "$extra_verbose" = "yes"; then
 220    echo "    xemacs will be linked with \"[$1]\""
 221  fi])dnl XE_ADD_OBJS
 222
 223 dnl XE_APPEND(value, varname)
 224 define([XE_APPEND],
 225 [[$2]="$[$2] [$1]" && dnl
 226  if test "$extra_verbose" = "yes"; then echo "    Appending \"[$1]\" to \$[$2]"; fi])
 227
 228 dnl XE_PREPEND(value, varname)
 229 define([XE_PREPEND],
 230 [[$2]="[$1] $[$2]" && dnl
 231  if test "$extra_verbose" = "yes"; then echo "    Prepending \"[$1]\" to \$[$2]"; fi])
 232
 233 dnl XE_DIE(message)
 234 define([XE_DIE], [{ echo "Error:" $1 >&2; exit 1; }])
 235
 236 dnl XE_STRIP_4TH_COMPONENT(var)
 237 dnl Changes i986-pc-linux-gnu to i986-pc-linux, as God (not RMS) intended.
 238 define([XE_STRIP_4TH_COMPONENT],
 239 [$1=`echo "$$1" | sed '[s/^\([^-][^-]*-[^-][^-]*-[^-][^-]*\)-.*$/\1/]'`])
 240
 241 dnl Initialize some variables set by options.
 242 dnl The variables have the same names as the options, with
 243 dnl dashes changed to underlines.
 244
 245 define([AC_INIT_PARSE_ARGS],[
 246
 247 dnl Get sane consistent behavior from various shells
 248 dnl Avoid losing with weird user CDPATHs
 249
 250 if test -n "$ZSH_VERSION"; then
 251   dnl zsh's Bourne shell emulation options
 252   setopt NO_BAD_PATTERN NO_BANG_HIST NO_BG_NICE NO_EQUALS NO_FUNCTION_ARGZERO
 253   setopt GLOB_SUBST NO_HUP INTERACTIVE_COMMENTS KSH_ARRAYS NO_MULTIOS NO_NOMATCH
 254   setopt RM_STAR_SILENT POSIX_BUILTINS SH_FILE_EXPANSION SH_GLOB SH_OPTION_LETTERS
 255   setopt SH_WORD_SPLIT BSD_ECHO IGNORE_BRACES
 256   dnl zsh-3.1-beta drops core on the following
 257   dnl unset CDPATH
 258   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
 259 elif test -n "$BASH_VERSION"; then
 260   dnl Use Posix mode with bash
 261   set -o posix
 262   unset CDPATH
 263 else
 264   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
 265 fi
 266
 267 dnl Initialize some variables set by options.
 268 dnl The variables have the same names as the options, with
 269 dnl dashes changed to underlines.
 270 exec_prefix=NONE
 271 host=NONE
 272 no_create=
 273 nonopt=NONE
 274 no_recursion=
 275 prefix=NONE
 276 program_prefix=NONE
 277 program_suffix=NONE
 278 program_transform_name=s,x,x,
 279 silent=
 280 site=
 281 srcdir=
 282 target=NONE
 283 verbose=
 284 x_includes=NONE
 285 x_libraries=NONE
 286
 287 dnl Installation directory options.
 288 dnl These are left unexpanded so users can "make install exec_prefix=/foo"
 289 dnl and all the variables that are supposed to be based on exec_prefix
 290 dnl by default will actually change.
 291 dnl Use braces instead of parens because sh, perl, etc. also accept them.
 292 dnl If you change these, you need to synchronize with the settings of the
 293 dnl various ..._USER_DEFINED variables further down.
 294 bindir='${exec_prefix}/bin'
 295 sbindir='${exec_prefix}/sbin'
 296 libexecdir='${exec_prefix}/libexec'
 297 datadir='${prefix}/share'
 298 sysconfdir='${prefix}/etc'
 299 sharedstatedir='${prefix}/com'
 300 localstatedir='${prefix}/var'
 301 libdir='${{exec_prefix}}/lib'
 302 includedir='${prefix}/include'
 303 oldincludedir='/usr/include'
 304 infodir='${prefix}/info'
 305 mandir='${prefix}/man'
 306
 307 dnl Initialize some other variables.
 308 subdirs=
 309 MFLAGS= MAKEFLAGS=
 310 dnl Maximum number of lines to put in a shell here document.
 311 ac_max_here_lines=12
 312 ])dnl AC_INIT_PARSE_ARGS
 313
 314 AC_INIT(src/lisp.h)dnl
 315 AC_CONFIG_HEADER(src/config.h lwlib/config.h)
 316 dnl Remove any more than one leading "." element from the path name.
 317 dnl If we do not remove them, then another "./" will be prepended to
 318 dnl the file name each time we use config.status, and the program name
 319 dnl will get larger and larger.  This would not be a problem, except
 320 dnl that since progname gets recorded in all the Makefiles this script
 321 dnl produces, move-if-change thinks they're different when they're
 322 dnl not.
 323 dnl
 324 dnl It would be nice if we could put the ./ in a \( \) group and then
 325 dnl apply the * operator to that, so we remove as many leading './././'s
 326 dnl as are present, but some seds (like Ultrix's sed) don't allow you to
 327 dnl apply * to a \( \) group.  Bleah.
 328 progname="`echo $0 | sed 's:^\./\./:\./:'`"
 329
 330 dnl -----------------------------
 331 dnl Establish some default values
 332 dnl -----------------------------
 333
 334 XE_APPEND(lib-src, MAKE_SUBDIR)
 335 XE_APPEND(lib-src, INSTALL_ARCH_DEP_SUBDIR)
 336
 337 prefix='/usr/local'
 338 exec_prefix='${prefix}'
 339 bindir='${exec_prefix}/bin'
 340 dnl FSF 19.29 changes to:
 341 dnl datadir='${prefix}/share'
 342 dnl sharedstatedir='${prefix}/com'
 343 dnl libexecdir='${exec_prefix}/libexec'
 344 datadir='${prefix}/lib'
 345 statedir='${prefix}/lib'
 346 libdir='${exec_prefix}/lib'
 347 mandir='${prefix}/man/man1'
 348 inststaticdir='${PROGNAME}'
 349 instvardir='${PROGNAME}-${version}'
 350 infodir='${datadir}/${instvardir}/info'
 351 infopath=''
 352 install_pp=''
 353 lispdir='${datadir}/${instvardir}/lisp'
 354 moduledir='${datadir}/${instvardir}/${configuration}/modules'
 355 sitelispdir='${datadir}/${inststaticdir}/site-lisp'
 356 sitemoduledir='${datadir}/${inststaticdir}/site-modules'
 357 pkgdir='${datadir}/${instvardir}/lisp'
 358 package_path=''
 359 etcdir='${datadir}/${instvardir}/etc'
 360 lockdir='${statedir}/${inststaticdir}/lock'
 361 archlibdir='${datadir}/${instvardir}/${configuration}'
 362 docdir='${archlibdir}'
 363 with_prefix='yes'
 364 with_site_lisp='no'
 365 with_site_modules='yes'
 366 with_menubars=''
 367 with_scrollbars=''
 368 with_widgets=''
 369 with_dialogs=''
 370 with_file_coding=''
 371 dnl const_is_losing is removed - we rely on AC_C_CONST instead.
 372 dnl We accept (and ignore) the --const-is-losing option for compatibility.
 373 dnl const_is_losing='yes'
 374 cpp='' cppflags='' libs='' ldflags=''
 375 dynamic=''
 376 with_x11=''
 377 with_msw=''
 378 rel_alloc='default'
 379 with_system_malloc='default'
 380 with_dlmalloc='default'
 381 native_sound_lib=''
 382 dnl use_assertions should be 'yes' by default.  Too many people in this
 383 dnl world have core dumps turned off by default or \"cannot find where the
 384 dnl core file went\".  At least we should get some useful output ...
 385 use_assertions="yes"
 386 dnl the following is set to yes or no later.
 387 with_toolbars=""
 388 with_tty=""
 389 use_union_type="no"
 390 with_dnet=""
 391
 392 dnl ------------------
 393 dnl Options Processing
 394 dnl ------------------
 395
 396 define([USAGE_ERROR],
 397 [(echo "$progname: Usage error:"
 398 echo " " $1
 399 echo "  Use \`$progname --help' to show usage.") >&2 && exit 1])
 400
 401 dnl Record all the arguments, so we can save them in config.status.
 402 arguments="$@"
 403
 404 dnl Shell Magic: Quote the quoted arguments in ARGUMENTS.  At a later date,
 405 dnl in order to get the arguments back in $@, we have to do an
 406 dnl 'eval set x "$quoted_arguments"; shift'
 407 dnl # We use sed to turn embedded ' into '"'"'.  I truly hate sh quoting.
 408 quoted_sed_magic=s/"'"/"'"'"'"'"'"'"'"/g
 409 quoted_arguments=
 410 for i in "$@"; do
 411    case "$i" in
 412    -no-create | --no-create | --no-creat | --no-crea | --no-cre \
 413    | --no-cr | --no-c) ;;
 414    -no-recursion | --no-recursion | --no-recursio | --no-recursi \
 415    | --no-recurs | --no-recur | --no-recu | --no-rec | --no-re | --no-r) ;;
 416    *)
 417    quoted_i="`echo '' $i | sed -e 's:^ ::' -e $quoted_sed_magic`"
 418    quoted_arguments="$quoted_arguments '$quoted_i'" ;;
 419    esac
 420 done
 421
 422 dnl Do not use shift -- that destroys the argument list, which autoconf needs
 423 dnl to produce config.status.  It turns out that "set - $arguments" does not
 424 dnl work portably.
 425 dnl However, it also turns out that many shells cannot expand ${10} at all.
 426 dnl So using an index variable does not work either.  It is possible to use
 427 dnl some shell magic to make 'set x "$arguments"; shift' work portably.
 428 while test $# != 0; do
 429   arg="$1"; shift
 430   case "$arg" in
 431     --no-create|--no-recursion) ;;
 432     dnl Anything starting with a hyphen we assume is an option.
 433     -* )
 434       dnl Separate the switch name from the value it is being given.
 435       case "$arg" in
 436         -*=*)
 437           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\([[^=]]*\)=.*$:\1:'`
 438           val=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*[[^=]]*=\(.*\)$:\1:'`
 439           valomitted=no
 440         ;;
 441            dnl special case these strings since echo may silently eat them:
 442            dnl --help ) opt=help val=yes valomitted=yes ;;
 443            dnl --version ) opt=version val=yes valomitted=yes ;;
 444            dnl -e ) opt=e val=yes valomitted=yes ;;
 445            dnl -E ) opt=E val=yes valomitted=yes ;;
 446            dnl -n ) opt=n val=yes valomitted=yes ;;
 447         -*)
 448            dnl If FOO is a boolean argument, --FOO is equivalent to
 449            dnl --FOO=yes.  Otherwise, the value comes from the next
 450            dnl argument - see below.
 451           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\(.*\)$:\1:'`
 452           val="yes" valomitted=yes
 453         ;;
 454       esac
 455
 456       dnl translate "-" in option string to "_"
 457       optname="$opt"
 458       opt="`echo '' $opt | sed -e 's:^ ::' | tr - _`"
 459
 460       dnl Support --without-FOO as a synonym for --with-FOO=no
 461       case "${valomitted}-${opt}" in yes-without_* )
 462         opt=`echo $opt | sed 's/without/with/'`
 463         valomitted="no" val="no" ;;
 464       esac
 465
 466       dnl Process the option.
 467       case "$opt" in
 468
 469       dnl Process (many) boolean options
 470         with_site_lisp  | \
 471         with_prefix     | \
 472         with_site_modules | \
 473         with_x          | \
 474         with_x11        | \
 475         with_msw        | \
 476         with_gcc        | \
 477         dynamic         | \
 478         with_ncurses    | \
 479         with_dnet       | \
 480         with_socks      | \
 481         with_dragndrop  | \
 482         with_cde        | \
 483         with_offix      | \
 484         with_gpm        | \
 485         with_xpm        | \
 486         with_xface      | \
 487         with_gif        | \
 488         with_jpeg       | \
 489         with_png        | \
 490         with_tiff       | \
 491         with_wmcommand  | \
 492         with_xmu        | \
 493         with_purify     | \
 494         with_quantify   | \
 495         with_toolbars   | \
 496         with_tty        | \
 497         with_xfs        | \
 498         with_i18n3      | \
 499         with_mule       | \
 500         with_file_coding| \
 501         with_canna      | \
 502         with_wnn        | \
 503         with_wnn6       | \
 504         with_workshop   | \
 505         with_sparcworks | \
 506         with_tooltalk   | \
 507         with_ldap       | \
 508         with_pop        | \
 509         with_kerberos   | \
 510         with_hesiod     | \
 511         with_dnet       | \
 512         with_infodock   | \
 513         external_widget | \
 514         verbose         | \
 515         extra_verbose   | \
 516         const_is_losing | \
 517         usage_tracking  | \
 518         use_union_type  | \
 519         debug           | \
 520         use_assertions  | \
 521         memory_usage_stats | \
 522         with_clash_detection | \
 523         with_modules | \
 524         no_doc_file )
 525           dnl Make sure the value given was either "yes" or "no".
 526           case "$val" in
 527             y | ye | yes )      val=yes ;;
 528             n | no )            val=no  ;;
 529             * ) USAGE_ERROR("The \`--$optname' option requires a boolean value: \`yes' or \`no'.") ;;
 530           esac
 531           eval "$opt=\"$val\"" ;;
 532
 533
 534         dnl Options that take a user-supplied value, as in --x-includes=/usr/X11R6/include
 535         dnl The cache-file option is ignored (for compatibility with other configures)
 536         srcdir          | \
 537         compiler        | \
 538         cflags          | \
 539         cpp             | \
 540         cppflags        | \
 541         libs            | \
 542         ldflags         | \
 543         cache_file      | \
 544         native_sound_lib| \
 545         site_lisp       | \
 546         x_includes      | \
 547         x_libraries     | \
 548         site_includes   | \
 549         site_libraries  | \
 550         site_prefixes   | \
 551         site_runtime_libraries )
 552           dnl If the value was omitted, get it from the next argument.
 553           if test "$valomitted" = "yes" ; then
 554             dnl Get the next argument from the argument list, if there is one.
 555             if test "$#" = 0 ; then
 556               USAGE_ERROR("The \`--$optname' option requires a value.");
 557             fi
 558             val="$1"; shift
 559           fi
 560           eval "$opt=\"$val\""
 561         ;;
 562
 563         dnl Options that take "yes", "no", or "default" values
 564         rel_alloc | \
 565         with_dlmalloc | \
 566         with_debug_malloc  | use_debug_malloc | \
 567         with_system_malloc | use_system_malloc )
 568           case "$val" in
 569             y | ye | yes )      val=yes ;;
 570             n | no )            val=no  ;;
 571             d | de | def | defa | defau | defaul | default ) val=default ;;
 572             * ) USAGE_ERROR(["The \`--$optname' option requires one of these values:
 573   \`yes', \`no', or \`default'."]) ;;
 574           esac
 575           case "$opt" in use_* ) opt="`echo $opt | sed s/use/with/`" ;; esac
 576           eval "$opt=\"$val\""
 577         ;;
 578
 579         dnl Has the user requested database support?
 580         "with_database" )
 581           with_database_berkdb=no
 582           with_database_dbm=no
 583           with_database_gnudbm=no
 584           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 585             case "$x" in
 586                 no ) ;;
 587                 b | be | ber | berk | berkd | berkdb )  with_database_berkdb=yes ;;
 588                 d | db | dbm )                          with_database_dbm=yes    ;;
 589                 g | gn | gnu | gnud | gnudb | gnudbm )  with_database_gnudbm=yes ;;
 590                 * ) USAGE_ERROR(["The \`--$optname' option value
 591   must be either \`no' or a comma-separated list
 592   of one or more of \`berkdb' and either \`dbm' or \`gnudbm'."]) ;;
 593             esac
 594           done
 595           if test "$with_database_dbm"    = "yes" -a \
 596                   "$with_database_gnudbm" = "yes"; then
 597           USAGE_ERROR("Only one of \`dbm' and \`gnudbm' may be specified
 598   with the \`--$optname' option.")
 599           fi
 600         ;;
 601
 602         dnl Has the user requested sound support?
 603         "with_sound" )
 604           dnl value can be native, nas or both. yes is allowed
 605           dnl as a backwards compatible synonym for native
 606           case "$val" in
 607             y | ye | yes )                      val=native ;;
 608             n | no | non | none )               val=no;;
 609             na | nat | nati | nativ | native )  val=native  ;;
 610             ne | net | neta | netau | netaud | netaudi | netaudio | nas ) val=nas  ;;
 611             b | bo | bot | both )               val=both;;
 612             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 613   \`native', \`nas', \`both', or \`none'."]) ;;
 614           esac
 615           eval "$opt=\"$val\""
 616         ;;
 617
 618         dnl Has the user requested XIM support?
 619         "with_xim" )
 620           case "$val" in
 621             y | ye | yes )                val=yes   ;;
 622             n | no | non | none )         val=no    ;;
 623             x | xl | xli | xlib )         val=xlib  ;;
 624             m | mo | mot | moti | motif ) val=motif ;;
 625             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 626   \`motif', \`xlib', \`yes', or \`no'."]) ;;
 627           esac
 628           eval "$opt=\"$val\""
 629         ;;
 630
 631         dnl Mail locking specification
 632         "mail_locking" )
 633           case "$val" in
 634             lockf )     val=lockf ;;
 635             flock )     val=flock ;;
 636             file )      val=file  ;;
 637             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 638   \`lockf', \`flock', or \`file'."]) ;;
 639           esac
 640           eval "$opt=\"$val\""
 641         ;;
 642
 643         dnl Has the user requested error-checking?
 644         "error_checking" )
 645           dnl value can be all, none, and/or a list of categories to check.
 646           dnl Example: --error-checking=all,noextents,nobufpos
 647           dnl Example: --error-checking=none,malloc,gc
 648
 649           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 650             case "$x" in
 651               dnl all and none are only permitted as the first in the list.
 652               n | no | non | none ) new_default=no ;;
 653               a | al | all )        new_default=yes ;;
 654
 655               extents )       error_check_extents=yes ;;
 656               noextents )     error_check_extents=no ;;
 657
 658               typecheck )     error_check_typecheck=yes ;;
 659               notypecheck )   error_check_typecheck=no ;;
 660
 661               bufpos )        error_check_bufpos=yes ;;
 662               nobufpos )      error_check_bufpos=no ;;
 663
 664               gc )            error_check_gc=yes ;;
 665               nogc )          error_check_gc=no ;;
 666
 667               malloc )        error_check_malloc=yes ;;
 668               nomalloc )      error_check_malloc=no ;;
 669
 670               byte_code )     error_check_byte_code=yes ;;
 671               nobyte_code )   error_check_byte_code=no ;;
 672
 673               * ) bogus_error_check=yes ;;
 674             esac
 675             if test "$bogus_error_check" -o \
 676                  \( -n "$new_default" -a -n "$echeck_notfirst" \) ; then
 677                 if test "$error_check_default" = yes ; then
 678                   types="\`all' (default), \`none', \`noextents', \`notypecheck', \`nobufpos', \`nogc', \`nomalloc', and \`nobyte-code'."
 679                 else
 680                   types="\`all', \`none' (default), \`extents', \`typecheck', \`bufpos', \`gc', \`malloc', and \`byte-code'."
 681                 fi
 682                 USAGE_ERROR(["Valid types for the \`--$optname' option are:
 683   $types."])
 684             elif test -n "$new_default" ; then
 685                 error_check_extents=$new_default
 686                 error_check_typecheck=$new_default
 687                 error_check_bufpos=$new_default
 688                 error_check_gc=$new_default
 689                 error_check_malloc=$new_default
 690                 error_check_byte_code=$new_default
 691                 new_default=    # reset this
 692             fi
 693             echeck_notfirst=true
 694           done
 695         ;;
 696
 697         dnl Has the user tried to tell us where the X files are?
 698         dnl I think these are dopey, but no less than three alpha
 699         dnl testers, at large sites, have said they have their X files
 700         dnl installed in odd places.
 701
 702         dnl Has the user specified one of the path options?
 703         prefix | exec_prefix | bindir | datadir | statedir | libdir | \
 704         mandir | infodir | infopath | lispdir | etcdir | lockdir | pkgdir | \
 705         archlibdir | docdir | package_path )
 706            dnl If the value was omitted, get it from the next argument.
 707            if test "$valomitted" = "yes"; then
 708              if test "$#" = 0; then
 709                  USAGE_ERROR("The \`--$optname' option requires a value.");
 710              fi
 711              val="$1"; shift
 712            fi
 713            eval "$opt=\"$val\""
 714
 715            dnl You need to synchronize this with the way the
 716            dnl default values are built.
 717            case "$opt" in
 718              dnl prefix is taken care of by --with-prefix
 719              exec_prefix ) AC_DEFINE(EXEC_PREFIX_USER_DEFINED) ;;
 720              lispdir ) AC_DEFINE(LISPDIR_USER_DEFINED) ;;
 721              sitelispdir ) AC_DEFINE(SITELISPDIR_USER_DEFINED) ;;
 722              moduledir ) AC_DEFINE(MODULEDIR_USER_DEFINED) ;;
 723              etcdir  )  AC_DEFINE(ETCDIR_USER_DEFINED) ;;
 724              infodir ) AC_DEFINE(INFODIR_USER_DEFINED) ;;
 725              infopath ) AC_DEFINE(INFOPATH_USER_DEFINED) ;;
 726              package_path ) AC_DEFINE(PACKAGE_PATH_USER_DEFINED) ;;
 727              datadir )
 728                 AC_DEFINE(INFODIR_USER_DEFINED)
 729                 AC_DEFINE(LISPDIR_USER_DEFINED)
 730             AC_DEFINE(MODULEDIR_USER_DEFINED)
 731                 AC_DEFINE(ETCDIR_USER_DEFINED) ;;
 732              statedir | lockdir ) AC_DEFINE(LOCKDIR_USER_DEFINED) ;;
 733              docdir ) AC_DEFINE(DOCDIR_USER_DEFINED) ;;
 734              exec_prefix | libdir | archlibdir ) AC_DEFINE(ARCHLIBDIR_USER_DEFINED) ;;
 735            esac
 736         ;;
 737
 738         dnl --no-create added by autoconf for use by config.status
 739         "no_create" ) ;;
 740
 741         dnl Has the user asked for some help?
 742         "usage" | "help" ) ${PAGER-more} ${srcdir}/configure.usage; exit 0 ;;
 743
 744         dnl Has the user specified the toolkit(s) to use for GUI elements?
 745         "with_menubars"   | \
 746         "with_scrollbars" | \
 747         "with_dialogs" | \
 748         "with_widgets" )
 749           case "$val" in
 750             l | lu | luc | luci | lucid )               val=lucid  ;;
 751             m | mo | mot | moti | motif )               val=motif  ;;
 752             athena3d | athena-3d )                      val=athena3d ;;
 753             a | at | ath | athe | athen | athena )      val=athena ;;
 754             n | no | non | none )                       val=no ;;
 755             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 756   \`lucid', \`motif', \`athena', \`athena3d', or \`no'."]) ;;
 757           esac
 758           eval "$opt=\"$val\""
 759         ;;
 760
 761         dnl Obsolete legacy argument?  Warn, but otherwise ignore.
 762         "run_in_place"  | \
 763         "with_gnu_make" )
 764           AC_MSG_WARN([Obsolete option \`--$optname' ignored.])
 765         ;;
 766
 767         dnl Unrecognized option?  No mercy for user errors.
 768         * ) USAGE_ERROR("Unrecognized option: $arg") ;;
 769
 770       esac
 771     ;;
 772
 773     dnl Assume anything with multiple hyphens is a configuration name.
 774     *-*-*) configuration="$arg" ;;
 775
 776     dnl Unrecognized argument?  No mercy for user errors.
 777     *) USAGE_ERROR("Unrecognized argument: $arg") ;;
 778
 779   esac
 780 done
 781
 782 dnl -------------------------
 783 dnl Finish options processing
 784 dnl -------------------------
 785
 786 dnl Several options are equivalent to, and override, environment variables.
 787 test -n "$cpp"      && CPP="$cpp"
 788 test -n "$cppflags" && CPPFLAGS="$cppflags"
 789 test -n "$libs"     && LIBS="$libs"
 790 test -n "$ldflags"  && LDFLAGS="$ldflags"
 791
 792 dnl Get the arguments back.  See the diatribe on Shell Magic above.
 793 eval set x "$quoted_arguments"; shift
 794
 795 dnl --extra-verbose implies --verbose
 796 test "$extra_verbose" = "yes" && verbose=yes
 797
 798 dnl with_x is an obsolete synonym for with_x11
 799 test -n "$with_x" && with_x11="$with_x"
 800
 801 dnl --with-quantify or --with-purify imply --use-system-malloc
 802 if test "$with_purify" = "yes" -o "$with_quantify" = "yes"; then
 803   test "$with_system_malloc" = "default" && with_system_malloc=yes
 804 fi
 805
 806 dnl XE_CHECK_FEATURE_DEPENDENCY(feature1, feature2)
 807 define([XE_CHECK_FEATURE_DEPENDENCY],
 808 [if test "$with_$1 $with_$2" = "yes no"; then
 809   USAGE_ERROR("--with-$1 requires --with-$2")
 810 elif test "$with_$2" = "no" ; then with_$1=no
 811 elif test "$with_$1" = "yes"; then with_$2=yes
 812 fi
 813 ])
 814
 815 dnl CDE requires tooltalk
 816 XE_CHECK_FEATURE_DEPENDENCY(cde, tooltalk)
 817
 818 dnl Find the source directory.
 819 case "$srcdir" in
 820
 821   dnl If srcdir is not specified, see if  "." or ".." might work.
 822   "" )
 823     for dir in "`echo $0 | sed 's|//|/|' | sed 's|/[[^/]]*$||'`" "." ".." ; do
 824       if test -f "$dir/src/lisp.h" -a \
 825               -f "$dir/lisp/version.el" ; then
 826         srcdir="$dir"
 827         break
 828       fi
 829     done
 830     if test -z "$srcdir" ; then
 831       USAGE_ERROR(["Neither the current directory nor its parent seem to
 832   contain the XEmacs sources.  If you do not want to build XEmacs in its
 833   source tree, you should run \`$progname' in the directory in which
 834   you wish to build XEmacs, using the \`--srcdir' option to say where the
 835   sources may be found."])
 836     fi
 837   ;;
 838
 839   dnl Otherwise, check if the directory they specified is okay.
 840   * )
 841     if test ! -f "$srcdir/src/lisp.h" -o \
 842             ! -f "$srcdir/lisp/version.el" ; then
 843       USAGE_ERROR(["The directory specified with the \`--srcdir' option,
 844   \`$srcdir', doesn't seem to contain the XEmacs sources.  You should
 845   either run the \`$progname' script at the top of the XEmacs source
 846   tree, or use the \`--srcdir' option to specify the XEmacs source directory."])
 847     fi
 848   ;;
 849 esac
 850
 851 dnl ###########################################################################
 852 if test -z "$configuration"; then
 853   dnl Guess the configuration
 854   configuration=`${CONFIG_SHELL-/bin/sh} $srcdir/config.guess`
 855   if test -z "$configuration"; then
 856     USAGE_ERROR(["XEmacs has not been ported to this host type.
 857 Try explicitly specifying the CONFIGURATION when rerunning configure."])
 858   fi
 859 fi
 860
 861 AC_PROG_LN_S
 862
 863 dnl Make symlinks for etc, lisp, and info directories while the path
 864 dnl is still relative.  We do not symlink lock because someone may
 865 dnl have stuck the source on a read-only partition.  Instead we
 866 dnl create it as an actual directory later on if it does not already
 867 dnl exist.
 868 for dir in lisp etc man info; do
 869   if test ! -d "$dir" ; then
 870     echo Making symbolic link to "$srcdir/$dir"
 871     ${LN_S} "$srcdir/$dir" "$dir"
 872   fi
 873 done
 874
 875 dnl Do our best to deal with automounter brokenness
 876 dnl CANONICALIZE_PATH(varname)
 877 define([CANONICALIZE_PATH],
 878 [if test -d "/net"; then
 879   if test -d "/tmp_mnt/net"; then tdir="tmp_mnt/net"; else tdir="tmp_mnt"; fi
 880   $1=`echo "[$]$1" | \
 881    sed -e "s|^${tdir}/|/net/|" -e "s|^/a/|/net/|" -e "s|^/amd/|/net/|"`
 882 fi])dnl
 883
 884 dnl Calculate canonical name for blddir (i.e. current directory).
 885 dnl PWD may already be the preferable absolute name for ".",
 886 dnl but we can't trust it - it is sometimes inaccurate.
 887 absolute_pwd="`pwd`";
 888 if test -n "$PWD" -a "`cd $PWD && pwd`" = "$absolute_pwd"
 889 then blddir="$PWD"
 890 else blddir="$absolute_pwd"; CANONICALIZE_PATH(blddir)
 891 fi
 892 AC_SUBST(blddir)
 893
 894 dnl Make srcdir absolute, if not already.  It is important to
 895 dnl avoid running the path through pwd unnecessary, since pwd can
 896 dnl give you automounter prefixes, which can go away.
 897 case "$srcdir" in
 898   /* ) ;;
 899   .  ) srcdir="$blddir" ;;
 900   *  ) srcdir="`cd $srcdir && pwd`"; CANONICALIZE_PATH(srcdir) ;;
 901 esac
 902
 903 dnl Check if the source directory already has a configured system in it.
 904 if test `pwd` != `sh -c cd $srcdir && pwd`  \
 905    && test -f "$srcdir/src/config.h"; then
 906   (echo "$progname: WARNING: The directory tree \`$srcdir' is being used"
 907    echo "   as a build directory right now; it has been configured in its own"
 908    echo "   right.  To configure in another directory as well, you MUST"
 909    echo "   use GNU make.  If you do not have GNU make, then you must"
 910    echo "   now do \`make distclean' in $srcdir,"
 911    echo "   and then run $progname again.") >&2
 912   extrasub='/^VPATH[[    ]]*=/c\
 913 vpath %.c $(srcdir)\
 914 vpath %.h $(srcdir)\
 915 vpath %.y $(srcdir)\
 916 vpath %.l $(srcdir)\
 917 vpath %.s $(srcdir)\
 918 vpath %.in $(srcdir)'
 919 fi
 920
 921 dnl ----------------------------------------
 922 dnl Find out which version of XEmacs this is
 923 dnl ----------------------------------------
 924 . "$srcdir/version.sh" || exit 1;
 925 dnl Must do the following first to determine verbosity for AC_DEFINE
 926 if test -n "$emacs_is_beta"; then beta=yes; else beta=no; fi
 927 : "${extra_verbose=$beta}"
 928 version="${emacs_major_version}.${emacs_minor_version}"
 929 AC_DEFINE_UNQUOTED(EMACS_MAJOR_VERSION, $emacs_major_version)
 930 AC_DEFINE_UNQUOTED(EMACS_MINOR_VERSION, $emacs_minor_version)
 931 if test -n "$emacs_beta_version" ; then
 932   if test "$beta" = "yes"; then
 933         version="${version}-b${emacs_beta_version}"
 934         AC_DEFINE_UNQUOTED(EMACS_BETA_VERSION, $emacs_beta_version)
 935   else
 936         version="${version}.${emacs_beta_version}"
 937         AC_DEFINE_UNQUOTED(EMACS_PATCH_LEVEL, $emacs_beta_version)
 938   fi
 939 fi
 940 AC_DEFINE_UNQUOTED(XEMACS_CODENAME, "$xemacs_codename")
 941 AC_DEFINE_UNQUOTED(EMACS_VERSION, "$version")
 942
 943 if test "$with_infodock" = "yes"; then
 944   if test ! -f ../../ID-INSTALL; then
 945     echo "Cannot build InfoDock without InfoDock sources"
 946     with_infodock=no
 947   fi
 948 fi
 949
 950 if test "$with_infodock" = "yes"; then
 951   dnl InfoDock version numbers.  XEmacs will use the same style of numbering
 952   dnl after the release of XEmacs 21.0.
 953   AC_DEFINE_UNQUOTED(INFODOCK_MAJOR_VERSION, $infodock_major_version)
 954   AC_DEFINE_UNQUOTED(INFODOCK_MINOR_VERSION, $infodock_minor_version)
 955   AC_DEFINE_UNQUOTED(INFODOCK_BUILD_VERSION, $infodock_build_version)
 956   version=${infodock_major_version}.${infodock_minor_version}.${infodock_build_version}
 957   PROGNAME=infodock
 958   CPPFLAGS="$CPPFLAGS -DINFODOCK"
 959 else
 960   PROGNAME=xemacs
 961 fi
 962
 963 dnl ----------------------------------
 964 dnl Error checking and debugging flags
 965 dnl ----------------------------------
 966 dnl Error checking default to "yes" in beta versions, to "no" in releases.
 967 dnl Same goes for --debug and --extra-verbosity.
 968 if test -n "$emacs_is_beta"; then beta=yes; else beta=no; fi
 969 test "${error_check_extents=$beta}"   = yes && AC_DEFINE(ERROR_CHECK_EXTENTS)
 970 test "${error_check_typecheck=$beta}" = yes && AC_DEFINE(ERROR_CHECK_TYPECHECK)
 971 test "${error_check_bufpos=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_BUFPOS)
 972 test "${error_check_gc=$beta}"        = yes && AC_DEFINE(ERROR_CHECK_GC)
 973 test "${error_check_malloc=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_MALLOC)
 974 test "${error_check_byte_code=$beta}" = yes && AC_DEFINE(ERROR_CHECK_BYTE_CODE)
 975 dnl debug=yes must be set when error checking is present.  This should be
 976 dnl fixed up.
 977 dnl debug implies other options
 978 if test "${debug:=$beta}" = "yes"; then
 979   use_assertions=yes memory_usage_stats=yes
 980   XE_ADD_OBJS(debug.o)
 981   AC_DEFINE(DEBUG_XEMACS)
 982 fi
 983 test "$use_assertions"     = "yes" && AC_DEFINE(USE_ASSERTIONS)
 984 test "$memory_usage_stats" = "yes" && AC_DEFINE(MEMORY_USAGE_STATS)
 985
 986 dnl ------------------------------
 987 dnl Determine the s&m files to use
 988 dnl ------------------------------
 989 dnl Given the configuration name, set machfile and opsysfile to the
 990 dnl names of the m/*.h and s/*.h files we should use.
 991
 992 dnl Canonicalize the configuration name.
 993 AC_MSG_CHECKING("host system type")
 994 dnl allow -workshop suffix on configuration name
 995 internal_configuration=`echo $configuration | sed 's/-\(workshop\)//'`
 996 canonical=`${CONFIG_SHELL-/bin/sh} $srcdir/config.sub "$internal_configuration"`
 997 XE_STRIP_4TH_COMPONENT(configuration)
 998 XE_STRIP_4TH_COMPONENT(canonical)
 999 AC_MSG_RESULT($configuration)
1000
1001 dnl If you add support for a new configuration, add code to this
1002 dnl switch statement to recognize your configuration name and select
1003 dnl the appropriate operating system and machine description files.
1004
1005 dnl You would hope that you could choose an m/*.h file pretty much
1006 dnl based on the machine portion of the configuration name, and an s-
1007 dnl file based on the operating system portion.  However, it turns out
1008 dnl that each m/*.h file is pretty manufacturer-specific - for
1009 dnl example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
1010 dnl all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
1011 dnl machines.  So we basically have to have a special case for each
1012 dnl configuration name.
1013
1014 dnl As far as handling version numbers on operating systems is
1015 dnl concerned, make sure things will fail in a fixable way.  If
1016 dnl /etc/MACHINES says nothing about version numbers, be
1017 dnl prepared to handle anything reasonably.  If version numbers
1018 dnl matter, be sure /etc/MACHINES says something about it.
1019
1020 dnl Eric Raymond says we should accept strings like "sysvr4" to mean
1021 dnl "System V Release 4"; he writes, "The old convention encouraged"
1022 dnl "confusion between `system' and `release' levels'."
1023
1024 machine='' opsys=''
1025
1026 dnl Straightforward machine determination
1027 case "$canonical" in
1028   sparc-*-*        ) machine=sparc ;;
1029   alpha*-*-*       ) machine=alpha ;;
1030   vax-*-*          ) machine=vax ;;
1031   mips-dec-*       ) machine=pmax ;;
1032   mips-sgi-*       ) machine=iris4d ;;
1033   romp-ibm-*       ) machine=ibmrt ;;
1034   rs6000-ibm-aix*  ) machine=ibmrs6000 ;;
1035   powerpc-ibm-aix* ) machine=ibmrs6000 ;;
1036   powerpc*-*       ) machine=powerpc ;;
1037   hppa-*-*         ) machine=hp800 ;;
1038   m88k-dg-*        ) machine=aviion ;;
1039   m68*-sony-*      ) machine=news ;;
1040   mips-sony-*      ) machine=news-risc ;;
1041   clipper-*        ) machine=clipper ;;
1042   arm-*            ) machine=arm ;;
1043   ns32k-*          ) machine=ns32000 ;;
1044 esac
1045
1046 dnl Straightforward OS determination
1047 case "$canonical" in
1048   *-*-linux*    ) opsys=linux ;;
1049   *-*-netbsd*   ) opsys=netbsd ;;
1050   *-*-openbsd*  ) opsys=openbsd ;;
1051   *-*-nextstep* ) opsys=nextstep ;;
1052   *-*-vms       ) opsys=vms ;;
1053
1054   dnl DEC OSF
1055   *-dec-osf1.3 | *-dec-osf2* ) opsys=decosf1-3 ;;
1056   *-dec-osf1.2 | *-dec-osf1* ) opsys=decosf1-2 ;;
1057   *-dec-osf3.[[2-9]]         ) opsys=decosf3-2 ;;
1058   *-dec-osf3*                ) opsys=decosf3-1 ;;
1059   *-dec-osf4*                ) opsys=decosf4-0 ;;
1060
1061   dnl DEC Ultrix
1062   *-*-ultrix[[0-3]].* | *-*-ultrix4.0* ) opsys=bsd4-2 ;;
1063   *-*-ultrix4.[[12]]* ) opsys=bsd4-3 ;;
1064   *-*-ultrix* )         opsys=ultrix4-3 ;;
1065
1066   dnl AIX
1067   *-*-aix3.1*  ) opsys=aix3-1   ;;
1068   *-*-aix3.2.5 ) opsys=aix3-2-5 ;;
1069   *-*-aix3*    ) opsys=aix3-2   ;;
1070   *-*-aix4.0*  ) opsys=aix4     ;;
1071   *-*-aix4.1*  ) opsys=aix4-1   ;;
1072   *-*-aix4*    ) opsys=aix4-2   ;;
1073
1074   dnl Other generic OSes
1075   *-gnu* )                      opsys=gnu    ;;
1076   *-*-bsd4.[[01]] )             opsys=bsd4-1 ;;
1077   *-*-bsd4.2 )                  opsys=bsd4-2 ;;
1078   *-*-bsd4.3 )                  opsys=bsd4-3 ;;
1079   *-*-aos4.2 )                  opsys=bsd4-2 ;;
1080   *-*-aos*   )                  opsys=bsd4-3 ;;
1081   *-*-sysv0    | *-*-sysvr0 )   opsys=usg5-0 ;;
1082   *-*-sysv2    | *-*-sysvr2 )   opsys=usg5-2 ;;
1083   *-*-sysv2.2  | *-*-sysvr2.2 ) opsys=usg5-2-2 ;;
1084   *-*-sysv3*   | *-*-sysvr3* )  opsys=usg5-3 ;;
1085   *-*-sysv4.1* | *-*-sysvr4.1* )opsys=usg5-4 NON_GNU_CPP=/usr/lib/cpp ;;
1086   *-*-sysv4.[[2-9]]* | *-sysvr4.[[2-9]]* )
1087         if test -z "$NON_GNU_CPP" ; then
1088           for prog in "/usr/ccs/lib/cpp" "/lib/cpp"; do
1089             if test -f "$prog"; then NON_GNU_CPP="$prog"; break; fi
1090           done
1091         fi
1092         opsys=usg5-4-2 ;;
1093     *-sysv4* | *-sysvr4* )      opsys=usg5-4 ;;
1094     *-*-mach_bsd4.3* )          opsys=mach-bsd4-3 ;;
1095 esac
1096
1097 case "$canonical" in
1098
1099   dnl NetBSD ports
1100   *-*-netbsd* )
1101     case "$canonical" in
1102       i[[3-9]]86-*-netbsd*) machine=intel386 ;;
1103       hp300-*-netbsd* | amiga-*-netbsd* | sun3-*-netbsd* | mac68k-*-netbsd* | da30-*-netbsd* | m68k-*-netbsd* )
1104                       dnl Yes, this is somewhat bogus.
1105                       machine=hp9000s300 ;;
1106       pc532-*-netbsd* | ns32k-*-netbsd* )  machine=ns32000 ;;
1107       pmax-*-netbsd*  | mips-*-netbsd*  )  machine=pmax ;;
1108     esac
1109   ;;
1110
1111   dnl OpenBSD ports
1112   *-*-openbsd* )
1113     case "${canonical}" in
1114       i386-*-openbsd*)          machine=intel386 ;;
1115       m68k-*-openbsd*)          machine=hp9000s300 ;;
1116       mipsel-*-openbsd*)        machine=pmax ;;
1117      esac
1118    ;;
1119
1120   dnl Acorn RISCiX:
1121   arm-acorn-riscix1.1* ) machine=acorn opsys=riscix1-1 ;;
1122   arm-acorn-riscix1.2* | arm-acorn-riscix ) machine=acorn opsys=riscix1-2 ;;
1123
1124   dnl Alliant machines
1125   fx80-alliant-* ) machine=alliant4     opsys=bsd4-2 ;;
1126   i860-alliant-* ) machine=alliant-2800 opsys=bsd4-3 ;;
1127
1128   dnl Altos 3068
1129   m68*-altos-sysv* ) machine=altos opsys=usg5-2 ;;
1130
1131   dnl Amdahl UTS
1132   580-amdahl-sysv* ) machine=amdahl opsys=usg5-2-2 ;;
1133
1134   dnl Apollo, Domain/OS
1135   m68*-apollo-* ) machine=apollo opsys=bsd4-3 ;;
1136
1137   dnl AT&T 3b2, 3b5, 3b15, 3b20
1138   we32k-att-sysv* ) machine=att3b opsys=usg5-2-2 ;;
1139
1140   dnl AT&T 3b1 - The Mighty Unix PC!
1141   m68*-att-sysv* ) machine=7300 opsys=usg5-2-2 ;;
1142
1143   dnl Bull machines
1144   rs6000-bull-bosx* ) machine=ibmrs6000 opsys=aix3-2 ;; # dpx20
1145   m68*-bull-sysv3*  ) machine=dpx2      opsys=usg5-3 ;; # dpx2
1146   m68*-bull-sysv2*  ) machine=sps7      opsys=usg5-2 ;; # sps7
1147
1148   dnl CCI 5/32, 6/32 -- see "Tahoe".
1149
1150   dnl Celerity
1151   celerity-celerity-bsd* ) machine=celerity opsys=bsd4-2 ;;
1152
1153   dnl Convex
1154   *-convex-bsd* | *-convex-convexos* )
1155     machine=convex opsys=bsd4-3
1156     NON_GNU_CPP="cc -E -P"
1157   ;;
1158
1159   dnl Cubix QBx/386
1160   i[[3-9]]86-cubix-sysv* ) machine=intel386 opsys=usg5-3 ;;
1161
1162   dnl Data General AViiON Machines
1163   i586-dg-dgux*R4*   | i586-dg-dgux5.4.4* ) machine=aviion opsys=dgux5-4r4 ;;
1164   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* ) opsys=dgux5-4r3 ;;
1165   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* ) opsys=dgux5-4r2 ;;
1166   m88k-dg-dgux*                           ) opsys=dgux     ;;
1167
1168   dnl Motorola Delta machines
1169   m68k-motorola-sysv* | m68000-motorola-sysv* ) machine=delta opsys=usg5-3 ;;
1170   m88k-motorola-sysv4* )
1171     dnl jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
1172     dnl needs POSIX_SIGNALS and therefore needs usg5-4-2.
1173     dnl I hope there are not other 4.0 versions for this machine
1174     dnl which really need usg5-4 instead.
1175     machine=delta88k opsys=usg5-4-2
1176   ;;
1177   m88k-motorola-sysv* | m88k-motorola-m88kbcs* ) machine=delta88k opsys=usg5-3 ;;
1178
1179   dnl Dual machines
1180   m68*-dual-sysv*    ) machine=dual opsys=usg5-2   ;;
1181   m68*-dual-uniplus* ) machine=dual opsys=unipl5-2 ;;
1182
1183   dnl Encore machines
1184   ns16k-encore-bsd* ) machine=ns16000 opsys=umax ;;
1185
1186   dnl Gould Power Node and NP1
1187   pn-gould-bsd4.2* ) machine=gould     opsys=bsd4-2 ;;
1188   pn-gould-bsd4.3* ) machine=gould     opsys=bsd4-3 ;;
1189   np1-gould-bsd* )   machine=gould-np1 opsys=bsd4-3 ;;
1190
1191   dnl Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
1192   dnl as far as XEmacs is concerned).
1193   m88k-harris-cxux* )
1194     dnl Build needs to be different on 7.0 and later releases
1195     case "`uname -r`" in
1196        [[56]].[[0-9]] ) machine=nh4000 opsys=cxux  ;;
1197        [[7]].[[0-9]]  ) machine=nh4000 opsys=cxux7 ;;
1198     esac
1199     NON_GNU_CPP="/lib/cpp"
1200   ;;
1201   dnl Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
1202   m68k-harris-cxux* ) machine=nh3000 opsys=cxux ;;
1203   dnl Harris power pc NightHawk running Power UNIX (Series 6000)
1204   powerpc-harris-powerunix ) machine=nh6000 opsys=powerunix NON_GNU_CPP="cc -Xo -E -P" ;;
1205
1206   dnl Honeywell XPS100
1207   xps*-honeywell-sysv* ) machine=xps100 opsys=usg5-2 ;;
1208
1209   dnl HP 9000 series 200 or 300
1210   m68*-hp-bsd* ) machine=hp9000s300 opsys=bsd4-3 ;;
1211
1212   dnl HP-UX
1213   *-hp-hpux* )
1214     dnl Figure out machine and opsys orthogonally
1215     case "$canonical" in
1216       m68*  ) machine=hp9000s300 ;;
1217       hppa* ) machine=hp800      ;;
1218     esac
1219
1220     case "$canonical" in
1221       *-hp-hpux7*  )  opsys=hpux   ;;
1222       *-hp-hpux8*  )  opsys=hpux8  ;;
1223       *-hp-hpux9*  )  opsys=hpux9  ;;
1224       *-hp-hpux10* )  opsys=hpux10 ;;
1225       *-hp-hpux11* )  opsys=hpux11 ;;
1226       *            )  opsys=hpux   ;;
1227     esac
1228
1229     dnl HP has a broken "strcat"
1230     case "$opsys" in hpux9 | hpux10 ) XE_ADD_OBJS(strcat.o) ;; esac
1231
1232     if test "$opsys" = "hpux10" -o "$opsys" = "hpux11"; then \
1233         ansi_flag="-Ae"; else ansi_flag="-Aa"; fi
1234     NON_GNU_CC="cc $ansi_flag" NON_GNU_CPP="cc $ansi_flag -E"
1235
1236     case "$canonical" in *-hp-hpux*shr* ) opsys="${opsys}-shr" ;; esac
1237   ;;
1238
1239   dnl Orion machines
1240   orion-orion-bsd*   ) machine=orion    opsys=bsd4-2 ;;
1241   clipper-orion-bsd* ) machine=orion105 opsys=bsd4-2 ;;
1242
1243   dnl IBM machines
1244   i[[3-9]]86-ibm-aix1.1* ) machine=ibmps2-aix opsys=usg5-2-2 ;;
1245   i[[3-9]]86-ibm-aix1.[[23]]* | i[[3-9]]86-ibm-aix* ) machine=ibmps2-aix opsys=usg5-3 ;;
1246   i370-ibm-aix*) machine=ibm370aix opsys=usg5-3 ;;
1247   romp-ibm-aos*    ) opsys=bsd4-3 ;;
1248   romp-ibm-bsd*    ) opsys=bsd4-3 ;;
1249   romp-ibm-mach*   ) opsys=mach-bsd4-3 ;;
1250
1251   dnl Integrated Solutions "Optimum V"
1252   m68*-isi-bsd4.2* ) machine=isi-ov opsys=bsd4-2 ;;
1253   m68*-isi-bsd4.3* ) machine=isi-ov opsys=bsd4-3 ;;
1254
1255   dnl Intel 386 machines where we do care about the manufacturer
1256   i[[3-9]]86-intsys-sysv* ) machine=is386 opsys=usg5-2-2 ;;
1257
1258   dnl Prime EXL
1259   i[[3-9]]86-prime-sysv* ) machine=i386 opsys=usg5-3 ;;
1260
1261   dnl Sequent Symmetry running Dynix
1262   i[[3-9]]86-sequent-bsd* ) machine=symmetry opsys=bsd4-3 ;;
1263
1264   dnl Sequent Symmetry running DYNIX/ptx
1265   i[[3-9]]86-sequent-ptx* ) machine=sequent-ptx opsys=ptx NON_GNU_CPP="/lib/cpp" ;;
1266
1267   dnl Unspecified sysv on an ncr machine defaults to svr4.2.
1268   dnl (Plain usg5-4 does not turn on POSIX signals, which we need.)
1269   i[[3-9]]86-ncr-sysv* ) machine=ncr386 opsys=usg5-4-2 ;;
1270
1271   dnl Intel Paragon OSF/1
1272   i860-intel-osf1* ) machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp ;;
1273
1274   dnl Intel 860
1275   i860-*-sysv4* ) machine=i860 opsys=usg5-4 NON_GNU_CC="/bin/cc" NON_GNU_CPP="/usr/ccs/lib/cpp" ;;
1276
1277   dnl Masscomp machines
1278   m68*-masscomp-rtu* ) machine=masscomp opsys=rtu ;;
1279
1280   dnl Megatest machines
1281   m68*-megatest-bsd* ) machine=mega68 opsys=bsd4-2 ;;
1282
1283   dnl Workstations sold by MIPS
1284   dnl This is not necessarily all workstations using the MIPS processor -
1285   dnl Irises are produced by SGI, and DECstations by DEC.
1286   mips-mips-usg* ) machine=mips4 ;;
1287   mips-mips-riscos4 )
1288     machine=mips4
1289     NON_GNU_CC="cc -systype bsd43"
1290     NON_GNU_CPP="cc -systype bsd43 -E"
1291     case "$canonical" in
1292       mips-mips-riscos4* ) opsys=bsd4-3  ;;
1293       mips-mips-riscos5* ) opsys=riscos5 ;;
1294     esac
1295   ;;
1296   mips-mips-bsd* ) machine=mips opsys=bsd4-3 ;;
1297   mips-mips-*    ) machine=mips opsys=usg5-2-2 ;;
1298
1299   dnl NeXT
1300   m68*-next-* | m68k-*-nextstep* ) machine=m68k opsys=nextstep ;;
1301
1302   dnl The complete machine from National Semiconductor
1303   ns32k-ns-genix* ) machine=ns32000 opsys=usg5-2 ;;
1304
1305   dnl NCR machines
1306   m68*-ncr-sysv2* | m68*-ncr-sysvr2* ) machine=tower32   opsys=usg5-2-2 ;;
1307   m68*-ncr-sysv3* | m68*-ncr-sysvr3* ) machine=tower32v3 opsys=usg5-3 ;;
1308
1309   dnl Nixdorf Targon 31
1310   m68*-nixdorf-sysv* ) machine=targon31 opsys=usg5-2-2 ;;
1311
1312   dnl Nu (TI or LMI)
1313   m68*-nu-sysv* ) machine=nu opsys=usg5-2 ;;
1314
1315   dnl Plexus
1316   m68*-plexus-sysv* ) machine=plexus opsys=usg5-2 ;;
1317
1318   dnl Pyramid machines
1319   pyramid-pyramid-bsd* ) machine=pyramid opsys=bsd4-2 ;;
1320
1321   dnl Sequent Balance
1322   ns32k-sequent-bsd4.2* ) machine=sequent opsys=bsd4-2 ;;
1323   ns32k-sequent-bsd4.3* ) machine=sequent opsys=bsd4-3 ;;
1324
1325   dnl Siemens Nixdorf
1326   mips-siemens-sysv* | mips-sni-sysv*)
1327     machine=mips-siemens opsys=usg5-4
1328     NON_GNU_CC=/usr/ccs/bin/cc
1329     NON_GNU_CPP=/usr/ccs/lib/cpp
1330   ;;
1331
1332   dnl NEC
1333   mips-nec-sysv*)
1334     machine=mips-nec
1335     NON_GNU_CC=/usr/ccs/bin/cc
1336     NON_GNU_CPP=/usr/ccs/lib/cpp
1337   ;;
1338
1339   dnl Silicon Graphics machines
1340   dnl Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
1341   m68*-sgi-iris3.5* ) machine=irist opsys=iris3-5 ;;
1342   m68*-sgi-iris3.6* | m68*-sgi-iris*) machine=irist opsys=iris3-6 ;;
1343   dnl Iris 4D
1344   mips-sgi-irix3.*    ) opsys=irix3-3 ;;
1345   mips-sgi-irix4.*    ) opsys=irix4-0 ;;
1346   mips-sgi-irix6*     ) opsys=irix6-0 ;;
1347   mips-sgi-irix5.1*   ) opsys=irix5-1 ;;
1348   mips-sgi-irix5.2*   ) opsys=irix5-2 ;;
1349   mips-sgi-irix5.*    ) opsys=irix5-3 ;;
1350   mips-sgi-irix*      ) opsys=irix5-0 ;;
1351
1352   dnl SONY machines
1353   *-sony-newsos[[34]]* | *-sony-news[[34]]* ) opsys=bsd4-3 ;;
1354   *-sony-news* ) opsys=newsos5 ;;
1355
1356   dnl Stride
1357   m68*-stride-sysv* ) machine=stride opsys=usg5-2 ;;
1358
1359   dnl Suns
1360   *-*-solaris* | *-*-sunos* | *-sun-mach* | *-sun-bsd* )
1361     dnl Hardware type
1362     case "$canonical" in
1363       m68*-sunos1* )             machine=sun1     ;;
1364       m68*-sunos2* )             machine=sun2     ;;
1365       m68* )                     machine=sun3     ;;
1366       i*86*-sun-sunos[[34]]* )   machine=sun386   ;;
1367       i*86-*-* )                 machine=intel386 ;;
1368       rs6000* )                  machine=rs6000   ;;
1369     esac
1370
1371     dnl Make $canonical even more so.
1372     case "$canonical" in *-sunos5*)
1373       canonical=`echo $canonical | sed -e s/sunos5/solaris2/`;;
1374     esac
1375
1376     dnl On SunOS 4, use /usr/lib/cpp, sans dynodump, /bin/ranlib
1377     dnl On SunOS 5, use cc -E,        need dynodump, RANLIB not needed
1378     dnl But, SunOS 5.6 no longer needs dynodump because it has a similar
1379     dnl function integrated.
1380     case "$canonical" in
1381       *-sunos4* )
1382         #test -f /usr/lib/cpp     && NON_GNU_CPP=/usr/lib/cpp ;;
1383         : ;;
1384       *-solaris2* )
1385         #test -f /usr/ccs/lib/cpp && NON_GNU_CPP=/usr/ccs/lib/cpp
1386         RANLIB=':' ;;
1387     esac
1388
1389     case "$canonical" in
1390       *-solaris*          )
1391         opsys=sol2
1392         os_release=`uname -r | sed -e 's/^\([[0-9]]\)\.\([[0-9]]\).*/\1\2/'`
1393         AC_DEFINE_UNQUOTED(OS_RELEASE, $os_release) ;;
1394
1395       dnl The last Sun386 ran 4.0.
1396       i*86-*-sunos4*      ) opsys=sunos4-0      ;;
1397       *-sunos4.0*         ) opsys=sunos4-0      ;;
1398       *-sunos4.1.2*       ) opsys=sunos4-1-2    ;;
1399       *-sunos4.1.3*       ) opsys=sunos4-1-3    ;;
1400       *-sunos4.1.[[4-9]]* ) opsys=sunos4-1-4    ;;
1401       *-sunos4* | *-sunos ) opsys=sunos4-1      ;;
1402       *-mach*             ) opsys=mach-bsd4-3   ;;
1403       *                   ) opsys=bsd4-2        ;;
1404     esac
1405
1406     case "$canonical" in *-sunos4*shr* ) opsys="${opsys}-shr" ;; esac
1407
1408     dnl Watch out for a compiler guaranteed not to work.
1409     test "$opsys $CC" = "sol2 /usr/ucb/cc" && CC=""
1410   ;;
1411
1412   dnl Tadpole 68k
1413   m68*-tadpole-sysv* ) machine=tad68k opsys=usg5-3 ;;
1414
1415   dnl Tahoe machines
1416   tahoe-tahoe-bsd4.2* ) machine=tahoe opsys=bsd4-2 ;;
1417   tahoe-tahoe-bsd4.3* ) machine=tahoe opsys=bsd4-3 ;;
1418
1419   dnl Tandem Integrity S2
1420   mips-tandem-sysv* ) machine=tandem-s2 opsys=usg5-3 ;;
1421
1422   dnl Tektronix XD88
1423   m88k-tektronix-sysv3* ) machine=tekxd88 opsys=usg5-3 ;;
1424
1425   dnl Tektronix 16000 box (6130?)
1426   ns16k-tektronix-bsd* ) machine=ns16000 opsys=bsd4-2 ;;
1427   dnl Tektronix 4300
1428   dnl src/m/tek4300.h hints that this is a m68k machine.
1429   m68*-tektronix-bsd* ) machine=tek4300 opsys=bsd4-3 ;;
1430
1431   dnl Titan P2 or P3
1432   titan-titan-sysv* ) machine=titan opsys=usg5-3 ;;
1433
1434   dnl Ustation E30 (SS5E)
1435   m68*-unisys-uniplus* ) machine=ustation opsystem=unipl5-2 ;;
1436
1437   dnl Vaxen.
1438   vax-dec-* )
1439     case "$canonical" in
1440       *-sysv[[01]]* | *-sysvr[[01]]* )  opsys=usg5-0 ;;
1441       *-sysv2* | *-sysvr2* )            opsys=usg5-2 ;;
1442       *-mach* )                         opsys=mach-bsd4-3 ;;
1443     esac
1444   ;;
1445
1446   dnl Whitechapel MG1
1447   ns16k-whitechapel-* ) machine=mg1 ;;
1448
1449   dnl Wicat
1450   m68*-wicat-sysv* ) machine=wicat opsys=usg5-2 ;;
1451
1452   dnl Intel 386 machines where we do not care about the manufacturer
1453   i[[3-9]]86-*-* )
1454     machine=intel386
1455     case "$canonical" in
1456       *-isc1.* | *-isc2.[[01]]* ) opsys=386-ix ;;
1457       *-isc2.2* )               opsys=isc2-2 ;;
1458       *-isc4.0* )               opsys=isc4-0 ;;
1459       *-isc4.* )                opsys=isc4-1
1460                                 GCC_TEST_OPTIONS=-posix
1461                                 NON_GCC_TEST_OPTIONS=-Xp
1462                                 ;;
1463       *-isc* )                  opsys=isc3-0 ;;
1464       *-esix5* )                opsys=esix5r4 NON_GNU_CPP=/usr/lib/cpp ;;
1465       *-esix* )                 opsys=esix ;;
1466       *-mach* )                 opsys=mach-bsd4-3 ;;
1467       *-xenix* )                opsys=xenix ;;
1468       *-sco3.2v4* )             opsys=sco4 NON_GNU_CPP=/lib/cpp  ;;
1469       *-bsd386* | *-bsdi1* )    opsys=bsd386 ;;
1470       *-bsdi4* )                opsys=bsdos4 ;;
1471       *-bsdi3* )                opsys=bsdos3 ;;
1472       *-bsdi2.1* )              opsys=bsdos2-1 ;;
1473       *-bsdi2* )                opsys=bsdos2 ;;
1474       *-sco3.2v5* )             opsys=sco5 ;
1475         dnl This is a pain.  Like the current USL cc, SCO cc -E
1476         dnl tokenizes as it preprocesses, making configure very
1477         dnl unhappy.  Unfortunately, /lib/cpp does not understand
1478         dnl flags like "-b elf", so we have to cheat in order to
1479         dnl pick up the right defines for UNEXEC from the s-file.
1480         dnl 01/05/95 robertl@dgii.com
1481         if test "$dynamic" = "yes" ; then
1482                 NON_GNU_CPP="/lib/cpp -D_XOPEN_SOURCE -D_SCO_ELF"  ;
1483         else
1484                 NON_GNU_CPP="/lib/cpp -D_XOPEN_SOURCE"  ;
1485         fi ;;
1486       *-sysv5* )                opsys=sco7 ;;
1487       *-386bsd* )               opsys=386bsd ;;
1488       *-freebsd* )              opsys=freebsd ;;
1489       *-nextstep* )             opsys=nextstep ;;
1490       *-pc-cygwin* )            opsys=cygwin32 ;;
1491       *-pc-mingw* )             opsys=mingw32 ;
1492                                 test -z "$with_tty" && with_tty="no";;
1493       dnl Otherwise, we fall through to the generic opsys code at the bottom.
1494     esac
1495   ;;
1496
1497   dnl Linux/68k
1498   m68k-*-linux* ) machine=m68k opsys=linux ;;
1499
1500 esac
1501
1502 if test -z "$machine" -o -z "$opsys"; then
1503   (echo "$progname: XEmacs hasn't been ported to \`$canonical' systems."
1504    echo "$progname: Check \`etc/MACHINES' for recognized configuration names."
1505   ) >&2
1506   exit 1
1507 fi
1508
1509 if test -z "$dynamic"; then
1510   case "$opsys" in
1511     hpux* | sunos4* ) dynamic=no ;;
1512     *) dynamic=yes ;;
1513   esac
1514 fi
1515 if test "$dynamic" = "yes"; then
1516   case "$opsys" in
1517     hpux* | sunos4* | sco5 ) opsys="${opsys}-shr" ;;
1518     decosf* ) ld_call_shared="-call_shared" ;;
1519   esac
1520 else dnl "$dynamic" = "no"
1521   case "$opsys" in
1522     sol2 )
1523       echo "Static linking is not supported on Solaris 2."
1524       echo "Rerun configure without specifying --dynamic=no."
1525       exit 1 ;;
1526     linux   ) ld_call_shared="-Bstatic" ;;
1527     decosf* ) ld_call_shared="-non_shared" ;;
1528   esac
1529 fi
1530
1531 dnl Use xlc by default on AIX
1532 case "$opsys" in aix*) NON_GNU_CC=xlc ;; esac
1533
1534 stack_trace_eye_catcher=`echo ${PROGNAME}_${version}_${canonical} | sed 'y/.-/__/'`
1535 AC_DEFINE_UNQUOTED(STACK_TRACE_EYE_CATCHER, $stack_trace_eye_catcher)
1536
1537 machfile="m/${machine}.h"
1538 opsysfile="s/${opsys}.h"
1539
1540 dnl --------------------------------------------------
1541 dnl Determine the compiler, set up for feature testing
1542 dnl --------------------------------------------------
1543
1544 dnl Sun Development environment support
1545 test "$with_sparcworks" = "yes" && with_workshop=yes # compatibility alias
1546 XE_CHECK_FEATURE_DEPENDENCY(workshop, tooltalk)
1547 if test "$with_workshop" = "yes"; then
1548   AC_DEFINE(SUNPRO)
1549   XE_ADD_OBJS(sunpro.o)
1550 fi
1551
1552 if test "$with_clash_detection" = "yes"; then
1553   AC_DEFINE(CLASH_DETECTION)
1554   XE_ADD_OBJS(filelock.o)
1555 fi
1556
1557 dnl Choose a compiler from (in order)
1558 dnl --compiler, env var CC, with_gcc=no && ${NON_GNU_CC:-cc}, AC_PROG_CC
1559 test -n "$compiler" && CC="$compiler"
1560 if test "$with_gcc" = "no"; then dnl Try to find a non-gcc compiler
1561   case "$CC" in "" | *gcc* ) CC="${NON_GNU_CC-cc}" ;; esac
1562 fi
1563
1564 dnl If we don't set CFLAGS here, AC_PROG_CC will set it.
1565 dnl But we know better what's good for us, so we do our own
1566 dnl computation of real CFLAGS later.
1567 dnl --cflags overrides environment variable CFLAGS
1568 test "${cflags-unset}" != unset && CFLAGS="$cflags"
1569 if test "${CFLAGS-unset}" != unset
1570   then cflags_specified=yes;
1571   else cflags_specified=no;
1572 fi
1573
1574 xe_save_CFLAGS="$CFLAGS"
1575
1576 AC_PROG_CC dnl Autoconf has its own magic for compiler autodetection
1577
1578 dnl Retry using random guesswork if AC_PROG_CC got it wrong...
1579 if   test "$with_gcc" = "no"  -a "$GCC" = "yes"; then
1580   CC=${NON_GNU_CC-cc}
1581   AC_PROG_CC
1582 elif test "$with_gcc" = "yes" -a "$GCC" != "yes" ; then
1583   CC=gcc
1584   AC_PROG_CC
1585 fi
1586 CFLAGS="$xe_save_CFLAGS"
1587
1588 dnl Figure out what C preprocessor to use.
1589
1590 dnl On Sun systems, people sometimes set up the variable CPP
1591 dnl with a value that is a directory, not an executable at all.
1592 dnl Detect that case, and ignore that value.
1593 test -n "$CPP" -a -d "$CPP" && CPP=
1594
1595 test -n "$NON_GNU_CPP" -a "$GCC" != "yes" -a -z "$CPP" && CPP="$NON_GNU_CPP"
1596
1597 AC_PROG_CPP
1598
1599 AC_AIX
1600
1601 AC_MSG_CHECKING(for GNU libc)
1602 AC_TRY_COMPILE([#include <features.h>],[
1603 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
1604 #error Not a GNU libc system :-(
1605 ******* ======= ******** &&&&&&&&
1606 #endif
1607 ], have_glibc=yes, have_glibc=no)
1608 AC_MSG_RESULT($have_glibc)
1609 dnl I'm tired of pop being broken with GLIBC -slb
1610 dnl Well. then why not fix fucking pop?
1611 test "$have_glibc" = "yes" && AC_DEFINE(_GNU_SOURCE)
1612
1613
1614 dnl Identify compilers to enable compiler-specific hacks.
1615 dnl Add support for other compilers HERE!
1616 dnl GCC is already identified elsewhere.
1617 AC_TRY_RUN([int main () {
1618 #if defined __SUNPRO_C
1619 return 11;
1620 #elif defined __DECC
1621 return 12;
1622 #else
1623 return 0;
1624 #endif
1625 }], [],
1626 [case "$conftest_rc" in
1627   11) echo "You appear to be using the SunPro C compiler."; __SUNPRO_C=yes ;;
1628   12) echo "You appear to be using the DEC C compiler."   ; __DECC=yes ;;
1629 esac])
1630
1631
1632 dnl case "$canonical" in
1633 dnl   *-sun-sunos* ) test "$CPP" = "acc -E" && CPP="acc -E -Xs" ;;
1634 dnl esac
1635
1636 dnl --------------------------------------------------------------------
1637 dnl Extract some information from the operating system and machine files
1638 dnl --------------------------------------------------------------------
1639
1640 echo "Extracting information from the machine- and system-dependent headers..."
1641
1642 dnl It is not important that this name contain the PID; you cannot run
1643 dnl two configures in the same directory and have anything work
1644 dnl anyway.
1645 tempcname="conftest.c"
1646
1647 dnl CPP_to_sh(CPP_SYMBOL, SH_VAR, DEFAULT_VALUE)
1648 define([CPP_to_sh],
1649 [[#]ifndef [$1]
1650 [#]define [$1]ifelse([$3],,, [ "$3"])
1651 [#]endif
1652 configure___ [$2]=[$1]
1653 ])dnl CPP_to_sh
1654
1655 dnl CPP_boolean_to_sh(CPP_SYMBOL, SH_VAR)
1656 define([CPP_boolean_to_sh],
1657 [[#]ifdef [$1]
1658 configure___ [$2]=yes
1659 [#]else
1660 configure___ [$2]=no
1661 [#]endif
1662 ])dnl CPP_boolean_to_sh
1663
1664 cat > $tempcname <<EOF
1665 #define NOT_C_CODE
1666 #define C_SWITCH_SITE
1667 #define C_SWITCH_X_SITE
1668 #define LD_SWITCH_SITE
1669 #define LD_SWITCH_X_SITE
1670 #define LD_SWITCH_X_SITE_AUX
1671 #define OS_RELEASE $os_release
1672 #include "$srcdir/src/$opsysfile"
1673 #include "$srcdir/src/$machfile"
1674
1675 CPP_to_sh(LIBS_MACHINE, libs_machine)
1676 CPP_to_sh(LIBS_SYSTEM,  libs_system)
1677 CPP_to_sh(LIBS_TERMCAP, libs_termcap)
1678 CPP_to_sh(LIB_STANDARD, libs_standard)
1679
1680 CPP_to_sh(OBJECTS_MACHINE, objects_machine)
1681 CPP_to_sh(OBJECTS_SYSTEM,  objects_system)
1682
1683 CPP_to_sh(C_SWITCH_MACHINE,   c_switch_machine)
1684 CPP_to_sh(C_SWITCH_SYSTEM,    c_switch_system)
1685
1686 CPP_to_sh(LD_SWITCH_MACHINE,  ld_switch_machine)
1687 CPP_to_sh(LD_SWITCH_SYSTEM,   ld_switch_system)
1688
1689 CPP_to_sh(UNEXEC, unexec, unexec.o)
1690
1691 CPP_to_sh(LD_SWITCH_SHARED, ld_switch_shared, -c)
1692
1693 #ifdef ORDINARY_LINK
1694 #define LD "\$(CC) \$(CFLAGS)"
1695 #else /* no ORDINARY LINK */
1696 #ifdef COFF_ENCAPSULATE
1697 #define LD "\$(CC) -nostdlib"
1698 #else /* not COFF_ENCAPSULATE */
1699 #ifdef LINKER
1700 #define LD LINKER
1701 #else /* ! defined (LINKER) */
1702 #define LD "ld"
1703 #endif /* ! defined (LINKER) */
1704 #endif /* ! defined (COFF_ENCAPSULATE) */
1705 #endif /* not ORDINARY_LINK */
1706 configure___ ld=LD
1707
1708 CPP_to_sh(LIB_GCC, lib_gcc)
1709 CPP_to_sh(LD_TEXT_START_ADDR, ld_text_start_addr)
1710
1711 #if ! defined (ORDINARY_LINK) && !defined (START_FILES)
1712 #ifdef NO_REMAP
1713 #ifdef COFF_ENCAPSULATE
1714 #define START_FILES "pre-crt0.o /usr/local/lib/gcc-crt0.o"
1715 #else /* ! defined (COFF_ENCAPSULATE) */
1716 #define START_FILES "pre-crt0.o /lib/crt0.o"
1717 #endif /* ! defined (COFF_ENCAPSULATE) */
1718 #else /* ! defined (NO_REMAP) */
1719 #define START_FILES "ecrt0.o"
1720 #endif /* ! defined (NO_REMAP) */
1721 #endif /* no ORDINARY_LINK */
1722 #ifndef START_FILES
1723 #define START_FILES
1724 #endif
1725 configure___ start_files=START_FILES
1726
1727 CPP_boolean_to_sh(ORDINARY_LINK, ordinary_link)
1728 CPP_boolean_to_sh(SYSTEM_MALLOC, system_malloc)
1729 CPP_boolean_to_sh(TERMINFO, have_terminfo)
1730 CPP_boolean_to_sh(MAIL_USE_FLOCK, mail_use_flock)
1731 CPP_boolean_to_sh(MAIL_USE_LOCKF, mail_use_lockf)
1732 CPP_boolean_to_sh(HAVE_WIN32_PROCESSES, win32_processes)
1733 EOF
1734
1735 dnl The value of CPP is a quoted variable reference, so we need to do this
1736 dnl to get its actual value...
1737 CPP=`eval "echo $CPP $CPPFLAGS"`
1738 define(TAB, [   ])dnl
1739 changequote(, )dnl
1740 eval `$CPP -Isrc $tempcname \
1741         | sed -n -e "s/[ TAB]*=[ TAB\"]*/='/" -e "s/[ TAB\"]*\$/'/" -e "s/^configure___//p"`
1742 changequote([, ])dnl
1743
1744 rm $tempcname
1745
1746 dnl For debugging...
1747 test "$extra_verbose" = "yes" && \
1748   PRINT_VAR(libs_machine libs_system libs_termcap libs_standard
1749   objects_machine objects_system c_switch_machine c_switch_system
1750   ld_switch_machine ld_switch_system unexec ld_switch_shared
1751   ld lib_gcc ld_text_start_addr start_files ordinary_link
1752   have_terminfo mail_use_flock mail_use_lockf) && echo ""
1753
1754 dnl Non-ordinary link usually requires -lc
1755 test "$ordinary_link" = "no" -a -z "$libs_standard" && libs_standard="-lc"
1756
1757 dnl Compiler-specific hacks
1758 dnl DEC C requires -std
1759 test "$__DECC" = "yes" && XE_APPEND(-std, c_switch_site)
1760
1761 dnl Calculalate value of CFLAGS:
1762 dnl Use either command line flag, environment var, or autodetection
1763 if test "$cflags_specified" = "no"; then
1764   dnl Following values of CFLAGS are known to work well.
1765   dnl Should we take debugging options into consideration?
1766   if   test "$GCC" = "yes"; then
1767     CFLAGS="-g -O3 -Wall -Wno-switch"
1768     dnl I'm not convinced this is a good idea any more. -sb
1769     dnl test "$opsys $machine" = "linux intel386" && \
1770     dnl CFLAGS="$CFLAGS -fno-strength-reduce -malign-loops=2 -malign-jumps=2 -malign-functions=2"
1771   elif test "$__SUNPRO_C" = "yes"; then
1772     case "$opsys" in
1773       sol2    ) CFLAGS="-v -xO4" ;;
1774       sunos4* ) CFLAGS="-xO2";;
1775     esac
1776   elif test "$__DECC" = "yes"; then
1777     CFLAGS="-O3"
1778   elif test "$CC" = "xlc"; then
1779     CFLAGS="-g -O3 -qstrict -qnoansialias -qlibansi -qinfo -qro -qmaxmem=20000"
1780   dnl ### Add optimal CFLAGS support for other compilers HERE!
1781   else
1782     CFLAGS="-O" ;dnl The only POSIX-approved flag
1783   fi
1784 fi
1785
1786 dnl Inform compiler that certain flags are meant for the linker
1787 dnl XE_PROTECT_LINKER_FLAGS(shell_var)
1788 define([XE_PROTECT_LINKER_FLAGS], [
1789 if test "$GCC" = "yes"; then
1790   set x $[$1]; shift; [$1]=""
1791   while test -n "[$]1"; do
1792     case [$]1 in
1793       -L  | -l  | -u               ) [$1]="$[$1] [$]1 [$]2"; shift ;;
1794       -L* | -l* | -u* | -Wl* | -pg ) [$1]="$[$1] [$]1" ;;
1795       -Xlinker* ) ;;
1796       * ) [$1]="$[$1] -Xlinker [$]1" ;;
1797     esac
1798     shift
1799   done
1800 fi])dnl
1801 XE_PROTECT_LINKER_FLAGS(ld_switch_system)
1802 XE_PROTECT_LINKER_FLAGS(ld_switch_machine)
1803 XE_PROTECT_LINKER_FLAGS(LDFLAGS)
1804 XE_PROTECT_LINKER_FLAGS(ld_call_shared)
1805
1806 dnl Add s&m-determined objects (including unexec) to link line
1807 test -n "$objects_machine" && XE_ADD_OBJS($objects_machine)
1808 test -n "$objects_system"  && XE_ADD_OBJS($objects_system)
1809 test -n "$unexec"          && XE_ADD_OBJS($unexec)
1810
1811 dnl Dynodump (Solaris 2.x, x<6)
1812 AC_MSG_CHECKING(for dynodump)
1813 if test "$unexec" != "unexsol2.o"; then
1814   AC_MSG_RESULT(no)
1815 else
1816   AC_MSG_RESULT(yes)
1817   AC_DEFINE(DYNODUMP)
1818   XE_APPEND(dynodump, MAKE_SUBDIR)
1819   XE_APPEND(dynodump, SRC_SUBDIR_DEPS)
1820   case "$machine" in
1821     sparc   ) dynodump_arch=sparc ;;
1822     *86*    ) dynodump_arch=i386  ;;
1823     powerpc ) dynodump_arch=ppc   ;;
1824   esac
1825   dnl Dynodump requires the system linker
1826   test "$GCC" = "yes" && XE_APPEND(-fno-gnu-linker, ld_switch_site)
1827 fi
1828
1829 dnl Feed s&m crud to src/Makefile
1830
1831 dnl Linux/powerpc needs the following magic for some reason
1832 test "$machine$opsys" = "powerpclinux" && start_flags="-T $srcdir/src/ppc.ldscript"
1833
1834 if test "$unexec" = "unexaix.o"; then
1835 dnl AIX needs various hacks to make static linking work.
1836   if   test "$dynamic" = "no"; then
1837   start_flags="-Wl,-bnso,-bnodelcsect"
1838   test "$GCC" = "yes" && start_flags="-B/bin/ ${start_flags}"
1839   for f in "/lib/syscalls.exp" "/lib/threads.exp"; do
1840     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; fi
1841   done
1842   for f in "/usr/lpp/X11/bin/smt.exp" "/usr/bin/X11/smt.exp"; do
1843     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; break; fi
1844   done
1845   AC_CHECK_LIB(C, terminateAndUnload, XE_APPEND(-lC, libs_system))
1846   fi
1847 elif test -n "$ld_text_start_addr"; then
1848   start_flags="-T $ld_text_start_addr -e __start"
1849 fi
1850 AC_SUBST(start_flags)
1851
1852 AC_SUBST(ld_switch_shared)
1853 AC_SUBST(start_files)
1854 if test "$ordinary_link" = "no" -a "$GCC" = "yes"; then
1855  test -z "$linker" &&  linker='$(CC) -nostdlib'
1856  test -z "$lib_gcc" && lib_gcc='`$(CC) -print-libgcc-file-name`'
1857 fi
1858 test "$GCC" != "yes" && lib_gcc=
1859 AC_SUBST(ld)
1860 AC_SUBST(lib_gcc)
1861
1862 dnl ---------------------------------------------------------------
1863 dnl Add site and system specific flags to compile and link commands
1864 dnl ---------------------------------------------------------------
1865
1866 dnl Allow use of either ":" or spaces for lists of directories
1867 define(COLON_TO_SPACE,
1868   [case "$[$1]" in *:* [)] [$1]="`echo '' $[$1] | sed -e 's/^ //' -e 's/:/ /g'`";; esac])dnl
1869
1870 dnl --site-libraries (multiple dirs)
1871 COLON_TO_SPACE(site_libraries)
1872 if test -n "$site_libraries"; then
1873   for arg in $site_libraries; do
1874     case "$arg" in
1875      -* ) ;;
1876      * ) test -d "$arg" || \
1877            XE_DIE("Invalid site library \`$arg': no such directory")
1878        arg="-L${arg}" ;;
1879     esac
1880     XE_APPEND($arg, ld_switch_site)
1881   done
1882 fi
1883
1884 dnl --site-includes (multiple dirs)
1885 COLON_TO_SPACE(site_includes)
1886 if test -n "$site_includes"; then
1887   for arg in $site_includes; do
1888     case "$arg" in
1889       -* ) ;;
1890       * ) test -d "$arg" || \
1891            XE_DIE("Invalid site include \`$arg': no such directory")
1892       arg="-I${arg}" ;;
1893     esac
1894     XE_APPEND($arg, c_switch_site)
1895   done
1896 fi
1897
1898 dnl --site-prefixes (multiple dirs)
1899 dnl --site-prefixes=dir1:dir2 is a convenient shorthand for
1900 dnl --site-libraries=dir1/lib:dir2/lib --site-includes=dir1/include:dir2/include
1901 dnl Site prefixes take precedence over the standard places, but not over
1902 dnl site-includes and site-libraries.
1903 COLON_TO_SPACE(site_prefixes)
1904 if test -n "$site_prefixes"; then
1905   for dir in $site_prefixes; do
1906     lib_dir="${dir}/lib"
1907     inc_dir="${dir}/include"
1908     if test ! -d "$dir"; then
1909       XE_DIE("Invalid site prefix \`$dir': no such directory")
1910     elif test ! -d "$lib_dir"; then
1911       XE_DIE("Invalid site prefix \`$dir': no such directory \`$lib_dir'")
1912     else
1913       if test -d "$inc_dir"; then
1914         XE_APPEND("-I$inc_dir", c_switch_site)
1915       fi
1916       XE_APPEND("-L$lib_dir", ld_switch_site)
1917     fi
1918   done
1919 fi
1920
1921 dnl GNU software installs by default into /usr/local/{include,lib}
1922 dnl if test -d "/usr/local/include" -a -d "/usr/local/lib"; then
1923 dnl   XE_APPEND("-L/usr/local/lib",    ld_switch_site)
1924 dnl   XE_APPEND("-I/usr/local/include", c_switch_site)
1925 dnl fi
1926
1927 dnl Extra system-specific library directories - please add to list
1928 for dir in "/usr/ccs/lib"; do
1929   test -d "$dir" && XE_APPEND(-L${dir}, ld_switch_site)
1930 done
1931
1932 dnl --site-runtime-libraries (multiple dirs)
1933 COLON_TO_SPACE(site_runtime_libraries)
1934 if test -n "$site_runtime_libraries"; then
1935   LD_RUN_PATH="`echo $site_runtime_libraries | sed -e 's/  */:/g'`"
1936   export LD_RUN_PATH
1937 fi
1938
1939 dnl -------------------------------------
1940 dnl Compute runtime library path
1941 dnl -------------------------------------
1942
1943 if   test "$dynamic" = "no"; then add_runtime_path=no
1944 elif test -n "$LD_RUN_PATH"; then add_runtime_path=yes
1945 else case "$opsys" in
1946        sol2 | irix* | *bsd* | decosf* ) add_runtime_path=yes ;;
1947        * ) add_runtime_path=no ;;
1948      esac
1949 fi
1950
1951 if test "$add_runtime_path" = "yes"; then
1952   dnl Try to autodetect runtime library flag (usually -R),
1953   dnl and whether it works (or at least does no harm)
1954   AC_MSG_CHECKING("for runtime libraries flag")
1955   case "$opsys" in
1956     sol2 ) dash_r="-R" ;;
1957     decosf* | linux* | irix*) dash_r="-rpath " ;;
1958     *)
1959       dash_r=""
1960       for try_dash_r in "-R" "-R " "-rpath "; do
1961         xe_check_libs="${try_dash_r}/no/such/file-or-directory"
1962         XE_PROTECT_LINKER_FLAGS(xe_check_libs)
1963         AC_TRY_LINK(, , dash_r="$try_dash_r")
1964         xe_check_libs=""
1965         test -n "$dash_r" && break
1966       done ;;
1967   esac
1968   if test -n "$dash_r";
1969     then AC_MSG_RESULT("\"${dash_r}\"")
1970     else AC_MSG_RESULT(NONE)
1971   fi
1972 fi
1973
1974 xe_add_unique_runpath_dir='
1975   xe_add_p=yes
1976   for xe_dir in $runpath_dirs; do   dnl Uniquify
1977     test "$xe_dir" = "$xe_runpath_dir" && xe_add_p=no
1978   done
1979   if test "$xe_add_p" = "yes"; then
1980     test -n "$runpath" && runpath="${runpath}:"
1981     runpath="${runpath}${xe_runpath_dir}"
1982     runpath_dirs="$runpath_dirs $xe_runpath_dir"
1983   fi'
1984
1985
1986 dnl XE_ADD_RUNPATH_DIR(directory)
1987 define([XE_ADD_RUNPATH_DIR],[{
1988 xe_runpath_dir=$1
1989 dnl PRINT_VAR(ld_switch_site ld_switch_x_site runpath xe_runpath_dir LD_RUN_PATH xe_ldflags)
1990   test "$xe_runpath_dir" != "/lib"     -a \
1991         "$xe_runpath_dir" != "/usr/lib" -a \
1992         -n "`ls ${xe_runpath_dir}/*.s[[ol]] 2>/dev/null`" && \
1993   eval "$xe_add_unique_runpath_dir"
1994 }])dnl
1995
1996 dnl XE_COMPUTE_RUNPATH()
1997 define([XE_COMPUTE_RUNPATH],[
1998 if test "$add_runtime_path" = "yes" -a -n "$dash_r"; then
1999   dnl Remove runtime paths from current ld switches
2000   ld_switch_site=`echo   '' $ld_switch_site   | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
2001   ld_switch_x_site=`echo '' $ld_switch_x_site | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
2002   dnl PRINT_VAR(ld_switch_site ld_switch_x_site)
2003
2004   dnl Fix up Runtime path
2005   dnl If LD_RUN_PATH is set in environment, use that.
2006   dnl In this case, assume user has set the right value.
2007   runpath="" runpath_dirs=""
2008   if test -n "$LD_RUN_PATH"; then
2009     runpath="$LD_RUN_PATH"
2010   elif test "$GCC" = "yes"; then
2011     dnl Compute runpath from gcc's -v output
2012     ld_switch_run_save="$ld_switch_run"; ld_switch_run=""
2013     echo "int main(int argc, char *argv[[]]) {return 0;}" > conftest.c
2014     xe_runpath_link='${CC-cc} -o conftest -v $CFLAGS '"$xe_ldflags"' conftest.$ac_ext 2>&1 1>/dev/null'
2015     for arg in `eval "$xe_runpath_link" | grep ' -L'`; do
2016       case "$arg" in P,* | -L* | -R* )
2017         for dir in `echo '' "$arg" | sed -e 's:^ ::' -e 's/^..//' -e 'y/:/ /'`; do
2018           XE_ADD_RUNPATH_DIR("$dir")
2019         done ;;
2020       esac
2021     done
2022     ld_switch_run="$ld_switch_run_save"
2023     rm -f conftest*
2024   else
2025     dnl Add all directories with .so files to runpath
2026     for arg in $ld_switch_site $ld_switch_x_site; do
2027       case "$arg" in -L*) XE_ADD_RUNPATH_DIR(`echo '' "$arg" | sed -e 's:^ ::' -e 's/^-L//'`);; esac
2028     done
2029     dnl Sometimes /opt/SUNWdt/lib is the only installed Motif available
2030     if test "$opsys $need_motif" = "sol2 yes"; then
2031       xe_runpath_dir="/opt/SUNWdt/lib";
2032       eval "$xe_add_unique_runpath_dir";
2033     fi
2034   fi dnl Compute $runpath
2035
2036   if test -n "$runpath"; then
2037     ld_switch_run="${dash_r}${runpath}"
2038     XE_PROTECT_LINKER_FLAGS(ld_switch_run)
2039     test "$extra_verbose" = "yes" && echo "Setting runpath to $runpath"
2040   fi
2041 fi
2042 ])dnl
2043 XE_COMPUTE_RUNPATH()
2044
2045 dnl JKJ REMOVEME
2046 dnl XE_SHLIB_STUFF
2047
2048 dnl -----------------------------------
2049 dnl Do some misc autoconf-special tests
2050 dnl -----------------------------------
2051
2052 dnl Do the opsystem or machine files prohibit the use of the GNU malloc?
2053 dnl Assume not, until told otherwise.
2054 GNU_MALLOC=yes
2055 if test "$with_dlmalloc" != "no"; then
2056         doug_lea_malloc=yes
2057 else
2058         doug_lea_malloc=no
2059 fi
2060 after_morecore_hook_exists=yes
2061 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
2062 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
2063 AC_MSG_CHECKING(whether __after_morecore_hook exists)
2064 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
2065   [AC_MSG_RESULT(yes)],
2066   [AC_MSG_RESULT(no)
2067    after_morecore_hook_exists=no])
2068 if test "$system_malloc" = "yes" ; then
2069   GNU_MALLOC=no
2070   GNU_MALLOC_reason="
2071   (The GNU allocators don't work with this system configuration)."
2072 elif test "$with_system_malloc" = "yes" ; then
2073   GNU_MALLOC=no
2074   GNU_MALLOC_reason="
2075   (User chose not to use GNU allocators)."
2076 elif test "$with_debug_malloc" = "yes" ; then
2077   GNU_MALLOC=no
2078   GNU_MALLOC_reason="
2079   (User chose to use Debugging Malloc)."
2080 fi
2081
2082 if test "$doug_lea_malloc" = "yes" ; then
2083   if test "$GNU_MALLOC" = yes ; then
2084     GNU_MALLOC_reason="
2085   (Using Doug Lea's new malloc from the GNU C Library.)"
2086   fi
2087   AC_DEFINE(DOUG_LEA_MALLOC)
2088   if test "$after_morecore_hook_exists" = "no" ; then
2089     GNU_MALLOC_reason="
2090   (Using Doug Lea's new malloc from the Linux C Library.)"
2091     AC_DEFINE(_NO_MALLOC_WARNING_)
2092   fi
2093   use_minimal_tagbits=yes
2094 fi
2095
2096 dnl #### mcheck is broken in all versions of Linux libc and glibc.
2097 dnl Try this again when 2.1 hits the streets.
2098 dnl Avoid using free-hook.c if support exists for malloc debugging in libc
2099 dnl have_libmcheck=no
2100 dnl if test "$error_check_malloc" = "yes" -a \
2101 dnl    "$have_glibc" = "yes" -a \
2102 dnl    "$doug_lea_malloc" = "yes"; then
2103 dnl   AC_CHECK_HEADERS(mcheck.h)
2104 dnl   AC_CHECK_LIB(mcheck, mcheck, have_libmcheck=yes, have_libmcheck=no)
2105 dnl fi
2106
2107 dnl if test "$have_libmcheck" = "yes"; then
2108 dnl   AC_DEFINE(HAVE_LIBMCHECK)
2109 dnl   libmcheck=-lmcheck
2110 dnl   AC_SUBST(libmcheck)
2111 dnl fi
2112
2113 dnl Some other nice autoconf tests.  If you add a test here which
2114 dnl should make an entry in src/config.h, do not forget to add an
2115 dnl #undef clause to src/config.h.in for autoconf to modify.
2116
2117 AC_PROG_RANLIB
2118 AC_PROG_INSTALL
2119 AC_PROG_YACC
2120
2121 dnl checks for header files
2122 AC_CHECK_HEADERS(mach/mach.h sys/stropts.h sys/timeb.h sys/time.h unistd.h)
2123 AC_CHECK_HEADERS(utime.h locale.h libgen.h fcntl.h ulimit.h cygwin/version.h)
2124 AC_CHECK_HEADERS(kstat.h sys/pstat.h inttypes.h sys/un.h a.out.h)
2125 AC_HEADER_SYS_WAIT
2126 AC_HEADER_STDC
2127 AC_HEADER_TIME
2128 AC_DECL_SYS_SIGLIST
2129
2130 dnl Some systems have utime.h but do not declare the struct anyplace.
2131 AC_MSG_CHECKING(for struct utimbuf)
2132 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
2133 #include <sys/time.h>
2134 #include <time.h>
2135 #else
2136 #ifdef HAVE_SYS_TIME_H
2137 #include <sys/time.h>
2138 #else
2139 #include <time.h>
2140 #endif
2141 #endif
2142 #ifdef HAVE_UTIME_H
2143 #include <utime.h>
2144 #endif], [static struct utimbuf x; x.actime = x.modtime;],
2145   [AC_MSG_RESULT(yes)
2146    AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
2147   AC_MSG_RESULT(no))
2148
2149 dnl checks for typedefs
2150 AC_TYPE_SIGNAL
2151 AC_TYPE_SIZE_T
2152 AC_TYPE_PID_T
2153 AC_TYPE_UID_T
2154 AC_TYPE_MODE_T
2155 AC_TYPE_OFF_T
2156
2157 AC_MSG_CHECKING(for struct timeval)
2158 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
2159 #include <sys/time.h>
2160 #include <time.h>
2161 #else
2162 #ifdef HAVE_SYS_TIME_H
2163 #include <sys/time.h>
2164 #else
2165 #include <time.h>
2166 #endif
2167 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
2168   [AC_MSG_RESULT(yes)
2169   HAVE_TIMEVAL=yes
2170   AC_DEFINE(HAVE_TIMEVAL)],
2171   [AC_MSG_RESULT(no)
2172    HAVE_TIMEVAL=no])
2173
2174 dnl checks for structure members
2175 AC_STRUCT_TM
2176 AC_STRUCT_TIMEZONE
2177
2178 dnl checks for compiler characteristics
2179 AC_C_CONST
2180
2181 dnl check for Make feature
2182 AC_PROG_MAKE_SET
2183
2184 dnl check byte order
2185 AC_C_BIGENDIAN
2186
2187 dnl define SIZEOF_TYPE
2188 AC_CHECK_SIZEOF(short)
2189 if test "$ac_cv_sizeof_short" = 0; then
2190   echo ""
2191   echo "*** PANIC *** Configure tests are not working - compiler is broken."
2192   echo "*** PANIC *** Please examine config.log for compilation errors."
2193   exit 1
2194 fi
2195 AC_CHECK_SIZEOF(int)
2196 AC_CHECK_SIZEOF(long)
2197 AC_CHECK_SIZEOF(long long)
2198 AC_CHECK_SIZEOF(void *)
2199
2200 dnl check for long file names
2201 AC_SYS_LONG_FILE_NAMES
2202
2203 dnl -lm is required by LISP_FLOAT_TYPE, among other things
2204 AC_CHECK_FUNC(sin, ,AC_CHECK_LIB(m, sin))
2205
2206 dnl Floating operation support is now unconditional
2207 AC_DEFINE(LISP_FLOAT_TYPE)
2208
2209 AC_TRY_LINK([#include <math.h>],
2210   [return atanh(1.0) + asinh(1.0) + acosh(1.0); ],
2211   AC_DEFINE(HAVE_INVERSE_HYPERBOLIC))
2212
2213 dnl Determine type of mail locking from configure args and s&m headers
2214 AC_CHECKING(type of mail spool file locking)
2215 test -z "$mail_locking" -a "$mail_use_flock" = "yes" && mail_locking=flock
2216 test -z "$mail_locking" -a "$mail_use_lockf" = "yes" && mail_locking=lockf
2217 if   test "$mail_locking" = "lockf"; then AC_DEFINE(REAL_MAIL_USE_LOCKF)
2218 elif test "$mail_locking" = "flock"; then AC_DEFINE(REAL_MAIL_USE_FLOCK)
2219 else mail_locking="dot-locking"
2220 fi
2221
2222 case "$opsys" in decosf*)
2223   AC_CHECK_LIB(pthreads, cma_open)
2224   test "$ac_cv_lib_pthreads_cma_open" = "yes" && \
2225     c_switch_site="$c_switch_site -threads" ;;
2226 esac
2227
2228 AC_MSG_CHECKING(whether the -xildoff compiler flag is required)
2229 if   ${CC-cc} '-###' -xildon  no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ; then
2230   if ${CC-cc} '-###' -xildoff no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ;
2231     then AC_MSG_RESULT(no);
2232     else AC_MSG_RESULT(yes); XE_APPEND(-xildoff, ld_switch_site)
2233   fi
2234   else AC_MSG_RESULT(no)
2235 fi
2236
2237 dnl Link with "-z ignore" on Solaris if supported
2238 if test "$opsys" = "sol2" && test "$OS_RELEASE" -ge 56; then
2239   AC_MSG_CHECKING(for \"-z ignore\" linker flag)
2240   case "`ld -h 2>&1`" in
2241     *-z\ ignore\|record* ) AC_MSG_RESULT(yes)
2242       XE_PREPEND(-z ignore, ld_switch_site) ;;
2243     *) AC_MSG_RESULT(no) ;;
2244   esac
2245 fi
2246
2247 dnl ----------------------
2248 dnl Choose a window system
2249 dnl ----------------------
2250
2251 AC_CHECKING("for specified window system")
2252
2253 if test "$with_x11" != "no"; then
2254   dnl User-specified --x-includes or --x-libraries implies --with-x11.
2255   test "$x_includes $x_libraries" != "NONE NONE" && \
2256    window_system=x11 with_x11=yes
2257
2258   dnl Autodetection of X11 libraries and includes
2259   dnl -------------------------------------------
2260   dnl AC_PATH_XTRA thinks it can find our X headers and includes, but
2261   dnl it often gets it wrong, so we only use it as a last resort.
2262
2263   dnl $OPENWINHOME implies --x-includes and --x-libraries
2264   dnl Not (yet) handled by autoconf2
2265   if test "$x_includes $x_libraries" = "NONE NONE" \
2266     -a -n "$OPENWINHOME" \
2267     -a "$OPENWINHOME" != "/usr/openwin" \
2268     -a -d "$OPENWINHOME"; then
2269       test -d "$OPENWINHOME/lib"           && x_libraries="$OPENWINHOME/lib"
2270       test -d "$OPENWINHOME/include"       && x_includes="$OPENWINHOME/include"
2271       test -d "$OPENWINHOME/share/include" && x_includes="$OPENWINHOME/share/include"
2272   fi
2273
2274   if test "$x_includes" = "NONE"; then
2275     dnl AC_PATH_XTRA often guesses /usr/include, when some other
2276     dnl include directory is a MUCH better guess (Linux, HP-UX 10.20).
2277     dnl This is a workaround for idiot (esp. HP) system vendors, who
2278     dnl provide a /usr/include/X11, but DON'T FULLY POPULATE IT.
2279     for dir in "/usr/X11" "/usr/X11R6"; do
2280       if test -d "$dir/include/X11"; then x_includes="$dir/include"; break; fi
2281     done
2282   fi
2283
2284   if test "$x_libraries" = "NONE"; then
2285     for dir in "/usr/X11/lib" "/usr/X11R6/lib" "/usr/lib/X11R6"; do
2286       if test -r "$dir/libX11.a"; then x_libraries="$dir"; break; fi
2287     done
2288   fi
2289
2290   AC_PATH_XTRA # Autoconf claims to find X library and include dirs for us.
2291   if test "$no_x" = "yes"
2292   then with_x11=no  window_system=none HAVE_X_WINDOWS=no
2293   else with_x11=yes window_system=x11  HAVE_X_WINDOWS=yes
2294   fi
2295 fi
2296
2297 case "$with_x11" in
2298   yes ) window_system=x11  HAVE_X_WINDOWS=yes ;;
2299   no  ) window_system=none HAVE_X_WINDOWS=no  ;;
2300 esac
2301
2302 if test "$with_x11" = "yes"; then
2303   AC_DEFINE(HAVE_X_WINDOWS)
2304   XE_APPEND(lwlib, MAKE_SUBDIR)
2305   XE_APPEND(lwlib, SRC_SUBDIR_DEPS)
2306
2307   dnl Try to find Motif/CDE/Tooltalk dirs
2308   dnl These take precedence over other X libs/includes, so PRE-pend
2309   for lib_dir in "/usr/dt/lib" "/usr/lib/Motif2.1" "/usr/lib/Motif1.2" "/usr/lib/Motif1.1"; do
2310     inc_dir=`echo $lib_dir | sed -e 's/lib/include/'`
2311     if test -d "$lib_dir" -a -d "$inc_dir"; then
2312       case "$x_libraries" in *"$lib_dir"* ) ;; *)
2313         x_libraries="$lib_dir $x_libraries"
2314         XE_PREPEND(-L${lib_dir}, X_LIBS) ;;
2315       esac
2316       case "$x_includes" in "$inc_dir"* ) ;; *)
2317         x_includes="$inc_dir $x_includes"
2318         XE_PREPEND(-I${inc_dir}, X_CFLAGS) ;;
2319       esac
2320       break; dnl only need ONE Motif implementation!
2321       fi
2322   done
2323
2324   dnl Contrib X libs/includes do NOT take precedence, so AP-pend
2325   for rel in "X11R6" "X11R5" "X11R4"; do
2326     lib_dir="/usr/contrib/$rel/lib" inc_dir="/usr/contrib/$rel/include"
2327     if test -d "$lib_dir" -a -d "$inc_dir"; then
2328       case "$x_libraries" in *"$lib_dir"* ) ;; *)
2329         x_libraries="$x_libraries $lib_dir"
2330         XE_APPEND(-L${lib_dir}, X_LIBS)
2331       esac
2332       case "$x_includes" in "$inc_dir"* ) ;; *)
2333         x_includes="$x_includes $inc_dir"
2334         XE_APPEND(-I${inc_dir}, X_CFLAGS)
2335       esac
2336       break; dnl Only need ONE X11 implementation !
2337     fi
2338   done
2339
2340   dnl Avoid version mismatch for shared library libXm.so on osf4
2341   if test "$GCC" = yes -a -d /usr/shlib; then XE_APPEND(-L/usr/shlib, X_LIBS); fi
2342
2343   ld_switch_x_site="$X_LIBS"
2344
2345   XE_COMPUTE_RUNPATH()
2346
2347   if test "$extra_verbose" = "yes"; then
2348     echo; echo "X11 compilation variables:"
2349     PRINT_VAR(x_libraries x_includes X_CFLAGS X_LIBS X_PRE_LIBS X_EXTRA_LIBS)
2350     echo
2351   fi
2352
2353   dnl Set up bitmaps search path.
2354   dnl The original suggestion was to unconditionally to append X11/bitmaps
2355   dnl to each element of $x_includes, I'm pretty sure this is the wrong
2356   dnl thing to do.  We test for bitmaps and X11/bitmaps directories on each
2357   dnl element and add them to BITMAPDIR if they exist.
2358   bitmapdirs=
2359   if test "$x_includes" != NONE; then
2360     for i in $x_includes; do
2361       if test -d "$i/bitmaps"; then
2362         bitmapdirs="$i/bitmaps:$bitmapdirs"
2363       fi
2364       if test -d "$i/X11/bitmaps"; then
2365         bitmapdirs="$i/X11/bitmaps:$bitmapdirs"
2366       fi
2367     done
2368     bitmapdirs=`echo "$bitmapdirs" | sed s/.$//`
2369   fi
2370   test ! -z "$bitmapdirs" && AC_DEFINE_UNQUOTED(BITMAPDIR, "$bitmapdirs")
2371
2372   dnl Autodetect defines extracted from X config by xmkmf, e.g. NARROWPROTO
2373   AC_CHECKING(for X defines extracted by xmkmf)
2374   rm -fr conftestdir
2375   if mkdir conftestdir; then
2376     cd conftestdir
2377     cat > Imakefile <<'EOF'
2378 xetest:
2379         @echo ${PROTO_DEFINES} ${STD_DEFINES}
2380 EOF
2381     if (xmkmf) >/dev/null 2>/dev/null && test -f Makefile; then
2382       # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
2383       xmkmf_defines=`${MAKE-make} xetest 2>/dev/null | grep -v make`
2384     fi
2385     cd ..
2386     rm -fr conftestdir
2387     for word in $xmkmf_defines; do
2388       case "$word" in
2389         -D*=* ) ;;
2390         -D* ) word=`echo '' $word | sed -e 's:^ *-D::'`
2391               AC_DEFINE_UNQUOTED($word) ;;
2392       esac
2393     done
2394   fi
2395
2396   dnl make sure we can find Intrinsic.h
2397   AC_CHECK_HEADER(X11/Intrinsic.h, ,
2398    [AC_MSG_ERROR("Unable to find X11 header files.")])
2399
2400   dnl -lXt and -lX11 are required
2401   dnl Some broken systems require the magic "-b i486-linuxaout" flag
2402   AC_CHECK_LIB(X11, XOpenDisplay, have_lib_x11=yes)
2403   if test "$have_lib_x11" != "yes"; then
2404     AC_CHECK_LIB(X11, XGetFontProperty,
2405       ld_switch_x_site="-b i486-linuxaout $ld_switch_x_site",
2406       [AC_MSG_ERROR("Unable to find X11 libraries.")],
2407       -b i486-linuxaout)
2408   fi
2409   libs_x="-lX11"
2410   test "$extra_verbose" = "yes" && echo "    Setting libs_x to \"-lX11\""
2411
2412   dnl Autodetect -lXext
2413   AC_CHECK_LIB(Xext, XShapeSelectInput, XE_PREPEND(-lXext, libs_x))
2414
2415   dnl Require -lXt
2416   AC_CHECK_LIB(Xt, XtOpenDisplay, XE_PREPEND(-lXt, libs_x),
2417     AC_MSG_ERROR("Unable to find X11 libraries."))
2418
2419   AC_MSG_CHECKING(the version of X11 being used)
2420   AC_TRY_RUN([#include <X11/Intrinsic.h>
2421     int main(int c, char *v[]) { return c>1 ? XlibSpecificationRelease : 0; }],
2422     [./conftest foobar; x11_release=$?],[x11_release=4],[x11_release=4])
2423   AC_MSG_RESULT(R${x11_release})
2424   AC_DEFINE_UNQUOTED(THIS_IS_X11R${x11_release})
2425
2426   AC_CHECK_HEADERS(X11/Xlocale.h)
2427
2428   dnl remove this - we should avoid checking for specific OS
2429   AC_MSG_CHECKING(for XFree86)
2430   if test -d "/usr/X386/include" -o \
2431           -f "/etc/XF86Config"    -o \
2432           -f "/etc/X11/XF86Config" -o \
2433           -f "/usr/X11R6/lib/X11/XF86Config"; then
2434     AC_MSG_RESULT(yes)
2435     AC_DEFINE(HAVE_XFREE386)
2436   else
2437     AC_MSG_RESULT(no)
2438   fi
2439
2440   dnl autodetect -lXmu
2441   test -z "$with_xmu" && { AC_CHECK_LIB(Xmu, XmuReadBitmapDataFromFile,
2442                            with_xmu=yes, with_xmu=no) }
2443   if test "$with_xmu" = "no"; then
2444     XE_ADD_OBJS(xmu.o)
2445   else
2446     XE_PREPEND(-lXmu, libs_x)
2447     AC_DEFINE(HAVE_XMU)
2448   fi
2449
2450   dnl Autodetect -lXbsd
2451   dnl #### Someone, please add a better function than main
2452   AC_CHECK_LIB(Xbsd, main, XE_PREPEND(-lXbsd, libs_x))
2453
2454   dnl Problem with the MIT distribution of X on AIX
2455   if test "$unexec" = "unexaix.o" -a "$x11_release" = "6"; then
2456     dnl X11R6 requires thread-safe code on AIX for some reason
2457     if test "$GCC" = "yes"; then
2458       XE_PREPEND(-mthreads, X_CFLAGS)
2459       XE_PREPEND(-mthreads, libs_x)
2460     else
2461       case "$CC" in
2462         "xlc" ) CC="xlc_r" ;;
2463         "xlC" ) CC="xlC_r" ;;
2464         "cc"  ) CC="cc_r" ;;
2465       esac
2466     fi
2467   fi
2468
2469 fi dnl $with_x11 = yes
2470
2471 if test "$with_msw" != "no"; then
2472   AC_CHECKING(for MS-Windows)
2473   AC_CHECK_LIB(gdi32,main,with_msw=yes)
2474   if test "$with_msw" = "yes"; then
2475     AC_DEFINE(HAVE_MS_WINDOWS)
2476     install_pp="$blddir/lib-src/installexe.sh"
2477     XE_APPEND(-lshell32 -lgdi32 -luser32 -lcomctl32, libs_system)
2478     test "$with_dragndrop" != no && XE_APPEND(msw, dragndrop_proto)
2479     if test "$window_system" != x11; then
2480         window_system=msw
2481         test "$with_scrollbars" != "no" && with_scrollbars=msw \
2482             && XE_ADD_OBJS(scrollbar-msw.o)
2483         test "$with_menubars"   != "no" && with_menubars=msw \
2484             && XE_ADD_OBJS(menubar-msw.o)
2485         test "$with_toolbars"   != "no" && with_toolbars=msw \
2486             && XE_ADD_OBJS(toolbar-msw.o)
2487         test "$with_dialogs"   != "no" && with_dialogs=msw \
2488             && XE_ADD_OBJS(dialog-msw.o)
2489         test "$with_widgets"   != "no" && with_widgets=msw
2490     else
2491         test "$with_scrollbars" != "no" && XE_ADD_OBJS(scrollbar-msw.o)
2492         test "$with_menubars"   != "no" && XE_ADD_OBJS(menubar-msw.o)
2493         test "$with_toolbars"   != "no" && XE_ADD_OBJS(toolbar-msw.o)
2494         test "$with_dialogs"    != "no" && XE_ADD_OBJS(dialog-msw.o)
2495     fi
2496     dnl check for our special version of select
2497     AC_TRY_RUN([#include <fcntl.h>
2498     int main() { return (open("/dev/windows", O_RDONLY, 0) > 0)? 0 : 1; }],
2499     [AC_DEFINE(HAVE_MSG_SELECT)])
2500     const_is_losing=no
2501     with_file_coding=yes
2502     XE_ADD_OBJS(console-msw.o device-msw.o event-msw.o frame-msw.o objects-msw.o select-msw.o redisplay-msw.o glyphs-msw.o gui-msw.o)
2503   fi
2504 fi
2505
2506 AC_SUBST(install_pp)
2507
2508 test -z "$window_system" && window_system="none"
2509
2510 dnl Test for features that require a window system - ANY window system
2511 if test "$window_system" = "none"; then
2512   for feature in menubars scrollbars toolbars dialogs dragndrop xface
2513   do
2514     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2515        AC_MSG_WARN([--with-$feature ignored:  Not valid without window system support])
2516     fi
2517     eval "with_${feature}=no"
2518   done
2519 else
2520   test -z "$with_toolbars" && with_toolbars=yes
2521 fi
2522
2523 dnl ### Test for features that require mswindows support - currently none
2524 dnl ### MS-Windows folks: add code here..... (martin)
2525 if test "$with_msw" != "yes"; then
2526   for feature in   MARTIN_IS_CLUELESS_ABOUT_MSW_FEATURES
2527   do
2528     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2529        AC_MSG_WARN([--with-$feature ignored:  Not valid without MS-Windows support])
2530     fi
2531     eval "with_${feature}=no"
2532   done
2533 else
2534   :
2535 fi
2536
2537 dnl Test for features that require X11 support
2538 if test "$with_x11" != "yes"; then
2539   dnl It ought to be reasonable to have no output device at all, and only use
2540   dnl XEmacs in --batch mode.
2541   dnl if test "$with_tty" = "no" ; then
2542   dnl   AC_MSG_ERROR([No window system support and no TTY support - Unable to proceed.])
2543   dnl fi
2544   for feature in tooltalk cde offix wmcommand xim xmu
2545   do
2546     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2547        AC_MSG_WARN([--with-$feature ignored:  Not valid without X support])
2548     fi
2549     eval "with_${feature}=no"
2550   done
2551 fi
2552
2553 dnl FSF 19.29 has some bitmapdir stuff here.
2554 bitmapdir=
2555
2556 case "$window_system" in
2557   x11  ) HAVE_X_WINDOWS=yes; echo "  Using X11." ;;
2558   msw  ) HAVE_X_WINDOWS=no ; echo "  Using MS-Windows." ;;
2559   none ) HAVE_X_WINDOWS=no ; echo "  Using no window system." ;;
2560 esac
2561
2562 case "$x_libraries" in *X11R4* )
2563   test "$opsys" = "hpux9"     && opsysfile="s/hpux9-x11r4.h"
2564   test "$opsys" = "hpux9-shr" && opsysfile="s/hpux9shxr4.h"
2565 esac
2566
2567 dnl Enable or disable proper handling of WM_COMMAND
2568 AC_CHECKING(for WM_COMMAND option);
2569 dnl if test "$with_wmcommand" = "yes"; then
2570 if test "$with_wmcommand" != "no"; then
2571   AC_DEFINE(HAVE_WMCOMMAND)
2572 fi
2573
2574 dnl Autodetect Xauth
2575 dnl -lXau is only used by gnuclient, so use a special variable for Xauth X libs
2576 test -z "$with_xauth" && test "$window_system" = "none" && with_xauth=no
2577 test -z "$with_xauth" && { AC_CHECK_HEADER(X11/Xauth.h,          ,with_xauth=no) }
2578 test -z "$with_xauth" && { AC_CHECK_LIB(Xau, XauGetAuthByAddr,[:],with_xauth=no) }
2579 test -z "$with_xauth" && with_xauth=yes
2580 if test "$with_xauth" = "yes"; then
2581   AC_DEFINE(HAVE_XAUTH)
2582   XE_SPACE(libs_xauth, $X_EXTRA_LIBS -lXau $libs_x $X_PRE_LIBS)
2583 fi
2584 AC_SUBST(libs_xauth)
2585
2586 dnl This one is for the static initializeds variables in
2587 dnl offix.c, so that the thing is dumped after lastfile.o
2588 AC_SUBST(dnd_objs)
2589
2590 dnl Autodetect tooltalk
2591 if test "$with_tooltalk" != "no" ; then
2592   dnl autodetect the location of tt_c.h
2593   dnl tt_c.h might be in Tt or desktop include directories
2594   for dir in "" "Tt/" "desktop/" ; do
2595     AC_CHECK_HEADER(${dir}tt_c.h, tt_c_h_path="${dir}tt_c.h"; break)
2596   done
2597   if test -z "$tt_c_h_path"; then
2598     if test "$with_tooltalk" = "yes"; then
2599       USAGE_ERROR("Unable to find required tooltalk header files.")
2600     fi
2601     with_tooltalk=no
2602   fi
2603 fi
2604 if test "$with_tooltalk" != "no" ; then
2605   for extra_libs in "" "-lI18N -lce" "-lcxx"; do
2606     AC_CHECK_LIB(tt, tt_message_create,
2607       tt_libs="-ltt $extra_libs"; break, [:],$extra_libs)
2608   done
2609   if test -z "$tt_libs"; then
2610     if test "$with_tooltalk" = "yes"; then
2611       USAGE_ERROR("Unable to find required tooltalk libraries.")
2612     fi
2613     with_tooltalk=no
2614   fi
2615 fi
2616 test -z "$with_tooltalk" && with_tooltalk=yes
2617 if test "$with_tooltalk" = "yes"; then
2618   AC_DEFINE(TOOLTALK)
2619   AC_DEFINE_UNQUOTED(TT_C_H_PATH, "$tt_c_h_path")
2620   XE_PREPEND($tt_libs, libs_x)
2621   XE_ADD_OBJS(tooltalk.o)
2622 fi
2623
2624 dnl Autodetect CDE
2625 test -z "$with_cde" && { AC_CHECK_HEADER(Dt/Dt.h,               , with_cde=no) }
2626 test -z "$with_cde" && { AC_CHECK_LIB(DtSvc, DtDndDragStart, [:], with_cde=no) }
2627 test -z "$with_cde" && with_cde=yes
2628 if test "$with_dragndrop" = no; then
2629   AC_MSG_WARN([No CDE without generic Drag'n'Drop support])
2630   with_cde=no
2631 fi
2632 if test "$with_cde" = "yes" ; then
2633   AC_DEFINE(HAVE_CDE)
2634   XE_PREPEND(-lDtSvc, libs_x)
2635   XE_APPEND(CDE, dragndrop_proto)
2636   with_tooltalk=yes # CDE requires Tooltalk
2637   need_motif=yes    # CDE requires Motif
2638 fi
2639
2640 dnl Always compile OffiX unless --without-offix is given, no
2641 dnl X11 support is compiled in, no standard Xmu is available,
2642 dnl or dragndrop support is disabled
2643 dnl Because OffiX support currently loses when more than one display
2644 dnl is in use, we now disable it by default -slb 07/10/1998.
2645 test "$window_system" != "x11" && with_offix=no
2646 if test "$with_xmu" != yes -a "$with_x11" = yes; then
2647   AC_MSG_WARN([No OffiX without real Xmu support])
2648   with_offix=no
2649 fi
2650 if test "$with_dragndrop" = no; then
2651   AC_MSG_WARN([No OffiX without generic Drag'n'Drop support])
2652   with_offix=no
2653 fi
2654 if test "$with_cde" = yes; then
2655   AC_MSG_WARN([CDE already found, disabling OffiX support])
2656   with_offix=no
2657 fi
2658 test -z "$with_offix" && with_offix=no
2659 if test "$with_offix" = "yes"; then
2660   AC_DEFINE(HAVE_OFFIX_DND)
2661   XE_APPEND(offix.o, dnd_objs)
2662   XE_APPEND(OffiX, dragndrop_proto)
2663 fi
2664
2665 dnl Autodetect Drag'n'Drop support
2666 dnl always included if CDE, Offix, or MSWindows are defined
2667 AC_MSG_CHECKING(if drag and drop API is needed)
2668 if test "$with_dragndrop" != "no" ; then
2669   if test -n "$dragndrop_proto" ; then
2670     with_dragndrop=yes
2671     AC_MSG_RESULT([yes (${dragndrop_proto} )])
2672     AC_DEFINE(HAVE_DRAGNDROP)
2673     XE_APPEND(dragdrop.o, extra_objs)
2674   else
2675     with_dragndrop=no
2676     AC_MSG_RESULT(no)
2677   fi
2678 fi
2679
2680 dnl Autodetect LDAP
2681 AC_CHECKING(for LDAP)
2682 test -z "$with_ldap" && { AC_CHECK_HEADER(ldap.h, ,with_ldap=no) }
2683 test -z "$with_ldap" && { AC_CHECK_HEADER(lber.h, ,with_ldap=no) }
2684 if test "$with_ldap" != "no"; then
2685   AC_CHECK_LIB(ldap, ldap_search, with_ldap_nolber=yes, with_ldap_nolber=no)
2686   test "$with_ldap_nolber" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_lber=yes, with_ldap_lber=no, -llber) }
2687   test "$with_ldap_nolber" = "no" -a "$with_ldap_lber" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_krb=yes, with_ldap_krb=no, -llber -lkrb) }
2688   test "$with_ldap_nolber" = "no" -a "$with_ldap_lber" = "no" -a "$with_ldap_krb" = "no" && { AC_CHECK_LIB(ldap, ldap_open, with_ldap_krbdes=yes, with_ldap_krbdes=no, -llber -lkrb -ldes) }
2689   test -z "$with_ldap" -a \( "$with_ldap_lber" = "yes" -o "$with_ldap_nolber" = "yes" -o "$with_ldap_krb" = "yes" -o "$with_ldap_krbdes" = "yes" \) && with_ldap=yes
2690 fi
2691 if test "$with_ldap" = "yes"; then
2692   AC_DEFINE(HAVE_LDAP)
2693   XE_ADD_OBJS(eldap.o)
2694   if test "$with_ldap_nolber" = "yes" ; then
2695     XE_PREPEND(-lldap, LIBS)
2696   else
2697     if test "$with_ldap_krb" = "yes" ; then
2698       XE_PREPEND(-lkrb, LIBS)
2699     fi
2700     if test "$with_ldap_krbdes" = "yes" ; then
2701       XE_PREPEND(-ldes, LIBS)
2702       XE_PREPEND(-lkrb, LIBS)
2703     fi
2704     XE_PREPEND(-llber, LIBS)
2705     XE_PREPEND(-lldap, LIBS)
2706   fi
2707   AC_CHECK_FUNCS(ldap_set_option ldap_get_lderrno ldap_result2error ldap_parse_result)
2708 fi
2709
2710 dnl ----------------------
2711 dnl Graphics libraries
2712 dnl ----------------------
2713
2714 if test "$window_system" != "none"; then
2715   AC_CHECKING(for graphics libraries)
2716
2717   dnl Autodetect Xpm
2718   xpm_problem=""
2719   if test -z "$with_xpm"; then
2720     AC_MSG_CHECKING(for Xpm - no older than 3.4f)
2721     xe_check_libs=-lXpm
2722     AC_TRY_RUN([#include <X11/xpm.h>
2723     int main(int c, char **v) {
2724     return c == 1 ? 0 :
2725       XpmIncludeVersion != XpmLibraryVersion() ? 1 :
2726       XpmIncludeVersion < 30406 ? 2 : 0 ;}],
2727     [./conftest dummy_arg; xpm_status=$?;
2728       if test "$xpm_status" = "0"; then
2729         with_xpm=yes;
2730       else
2731         with_xpm=no;
2732         if test "$xpm_status" = "1"; then
2733           xpm_problem="Xpm library version and header file version don't match!"
2734         elif test "$xpm_status" = "2"; then
2735           xpm_problem="Xpm library version is too old!"
2736         else
2737           xpm_problem="Internal xpm detection logic error!"
2738         fi
2739         echo "
2740 *** WARNING *** $xpm_problem
2741   I'm not touching that with a 10-foot pole!
2742   If you really want to use the installed version of Xpm, rerun
2743   configure and add '--with-xpm=yes', but don't blame me if XEmacs crashes!"
2744     fi],
2745     [with_xpm=no])
2746     xe_check_libs=
2747     AC_MSG_RESULT($with_xpm)
2748   fi
2749   if test "$with_xpm" = "yes"; then
2750     AC_DEFINE(HAVE_XPM)
2751     XE_PREPEND(-lXpm, libs_x)
2752     AC_MSG_CHECKING(for \"FOR_MSW\" xpm)
2753     xe_check_libs=-lXpm
2754     AC_TRY_LINK(, [XpmCreatePixmapFromData()],
2755     [xpm_for_msw=no],
2756     [xpm_for_msw=yes])
2757     xe_check_libs=
2758     AC_MSG_RESULT($xpm_for_msw)
2759     if test "$xpm_for_msw" = "yes"; then
2760       AC_DEFINE(FOR_MSW)
2761     fi
2762   fi
2763
2764   dnl Autodetect XFACE
2765   test -z "$with_xface" && { AC_CHECK_HEADER(compface.h,          ,with_xface=no) }
2766   test -z "$with_xface" && { AC_CHECK_LIB(compface, UnGenFace,[:] ,with_xface=no) }
2767   test -z "$with_xface" && with_xface=yes
2768   if test "$with_xface" = "yes"; then
2769     AC_DEFINE(HAVE_XFACE)
2770     XE_PREPEND(-lcompface, libs_x)
2771   fi
2772
2773   dnl For a brief period we had the GIF code split out into a separate library,
2774   dnl but patent problems, etc. sort of squashed that idea.
2775   dnl We default to building with builtin GIF decoding
2776   if test "$with_gif" != "no"; then
2777     with_gif="yes"
2778     AC_DEFINE(HAVE_GIF)
2779     XE_ADD_OBJS(dgif_lib.o gif_io.o)
2780   fi
2781
2782   dnl Too many stupid linkers can't detect cascaded lib dependencies until runtime
2783   dnl So we always search for libz compression support.
2784   if test "$with_png $with_tiff" != "no no"; then
2785     AC_CHECK_LIB(c,  inflate, [:], [
2786     AC_CHECK_LIB(z,  inflate, [XE_PREPEND(-lz,  libs_x)],[
2787     AC_CHECK_LIB(gz, inflate, [XE_PREPEND(-lgz, libs_x)])])])
2788   fi
2789
2790   dnl autodetect JPEG
2791   test -z "$with_jpeg" && { AC_CHECK_HEADER(jpeglib.h,                    ,with_jpeg=no) }
2792   test -z "$with_jpeg" && { AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,[:],with_jpeg=no) }
2793   test -z "$with_jpeg" && with_jpeg=yes
2794   if test "$with_jpeg" = "yes"; then
2795     AC_DEFINE(HAVE_JPEG)
2796     XE_PREPEND(-ljpeg, libs_x)
2797   fi
2798
2799   dnl autodetect PNG
2800   png_problem=""
2801   test -z "$with_png" && { AC_CHECK_FUNC(pow,                  ,with_png=no) }
2802   test -z "$with_png" && { AC_CHECK_HEADER(png.h,              ,with_png=no) }
2803   test -z "$with_png" && { AC_CHECK_LIB(png, png_read_image,[:],with_png=no) }
2804   if test -z "$with_png"; then
2805     AC_MSG_CHECKING(for workable png version information)
2806     xe_check_libs="-lpng -lz"
2807     AC_TRY_RUN([#include <png.h>
2808     int main(int c, char **v) {
2809     if (c == 1) return 0;
2810     if (strcmp(png_libpng_ver, PNG_LIBPNG_VER_STRING) != 0) return 1;
2811     return (PNG_LIBPNG_VER < 10002) ? 2 : 0 ;}],
2812     [./conftest dummy_arg; png_status=$?;
2813       if test "$png_status" = "0"; then
2814         with_png=yes;
2815       else
2816         with_png=no;
2817         if test "$png_status" = "1"; then
2818           png_problem="PNG library version and header file don't match!"
2819         elif test "$png_status" = "2"; then
2820           png_problem="PNG library version too old (pre 1.0.2)!"
2821         fi
2822         echo "
2823 *** WARNING *** $png_problem
2824   I'm not touching that with a 10-foot pole!
2825   If you really want to use the installed version of libPNG, rerun
2826   configure and add '--with-png=yes', but don't blame me if XEmacs crashes!"
2827     fi],
2828     [with_png=no])
2829     xe_check_libs=
2830     AC_MSG_RESULT($with_png)
2831   fi
2832   if test "$with_png" = "yes"; then
2833     AC_DEFINE(HAVE_PNG)
2834     XE_PREPEND(-lpng, libs_x)
2835   fi
2836
2837   dnl autodetect TIFF
2838   test -z "$with_tiff" && { AC_CHECK_HEADER(tiffio.h,            ,with_tiff=no) }
2839   test -z "$with_tiff" && { AC_CHECK_LIB(tiff, TIFFClientOpen,[:],with_tiff=no) }
2840   test -z "$with_tiff" && with_tiff=yes
2841   if test "$with_tiff" = "yes"; then
2842     AC_DEFINE(HAVE_TIFF)
2843     XE_PREPEND(-ltiff, libs_x)
2844   fi
2845 fi
2846
2847 dnl ----------------------
2848 dnl X-Specific Graphics libraries
2849 dnl ----------------------
2850
2851 if test "$with_x11" = "yes"; then
2852
2853   AC_CHECKING(for X11 graphics libraries)
2854
2855   dnl Autodetect -lXaw
2856   AC_CHECK_LIB(Xaw, XawScrollbarSetThumb, have_xaw=yes, have_xaw=no)
2857   dnl if test "$have_xaw" = "yes"; then
2858     dnl AC_CHECK_HEADER(X11/Xaw/Reports.h, [
2859       dnl XE_APPEND(pkg-src/tree-x, MAKE_SUBDIR)
2860       dnl XE_APPEND(pkg-src/tree-x, INSTALL_ARCH_DEP_SUBDIR)])
2861   dnl fi
2862
2863   dnl autodetect Motif - but only add to libs_x later (if necessary)
2864   AC_CHECK_HEADER(Xm/Xm.h,
2865    [AC_CHECK_LIB(Xm, XmStringFree, have_motif=yes, have_motif=no)],
2866    have_motif=no)
2867
2868   if test "$have_motif" = "yes"; then
2869     dnl autodetect lesstif
2870     AC_MSG_CHECKING(for Lesstif)
2871     AC_EGREP_CPP(yes,
2872 [#include <Xm/Xm.h>
2873 #ifdef LESSTIF_VERSION
2874 yes
2875 #endif
2876 ], have_lesstif=yes, have_lesstif=no)
2877   AC_MSG_RESULT($have_lesstif)
2878   fi
2879
2880 fi dnl "$with_x11" = "yes"
2881
2882 dnl Finish ensuring that we have values for the various toolkit items.
2883 dnl Not all toolkits support all widgets
2884 dnl if Motif is available we use it for the dialog boxes.
2885
2886 case "$with_menubars" in "" | "yes" | "athena" | "athena3d" )
2887   with_menubars="lucid" ;;
2888 esac
2889 case "$with_dialogs" in "" | "yes" | "lucid" )
2890   if   test "$have_motif" = "yes"; then with_dialogs="motif"
2891   elif test "$have_xaw"   = "yes"; then with_dialogs="athena"
2892   else with_dialogs=no
2893   fi ;;
2894 esac
2895 case "$with_scrollbars" in "" | "yes" )
2896   with_scrollbars="lucid" ;;
2897 esac
2898 case "$with_widgets" in "" | "yes" )
2899   if   test "$have_motif" = "yes"; then with_widgets="motif"
2900   else with_widgets=no
2901   fi ;;
2902 esac
2903
2904 all_widgets="$with_menubars $with_scrollbars $with_dialogs $with_toolbars $with_widgets"
2905
2906 case "$all_widgets" in *athena* )
2907   AC_DEFINE(LWLIB_USES_ATHENA)
2908   AC_DEFINE(NEED_ATHENA)
2909   XE_APPEND(lwlib-Xaw.o, lwlib_objs)
2910   XE_PREPEND(-lXaw, libs_x) ;;
2911 esac
2912
2913 case "$all_widgets" in *motif* )
2914   AC_DEFINE(LWLIB_USES_MOTIF)
2915   AC_DEFINE(NEED_MOTIF)
2916   XE_APPEND(lwlib-Xm.o, lwlib_objs)
2917   need_motif=yes ;;
2918 esac
2919
2920 test "$with_menubars"   = "lucid" && XE_APPEND(xlwmenu.o, lwlib_objs)
2921 test "$with_menubars"   = "motif" && XE_APPEND(xlwmenu.o, lwlib_objs)
2922 test "$with_scrollbars" = "lucid" && XE_APPEND(xlwscrollbar.o, lwlib_objs)
2923 case "$all_widgets" in *lucid* )
2924   AC_DEFINE(NEED_LUCID)
2925   XE_APPEND(lwlib-Xlw.o, lwlib_objs) ;;
2926 esac
2927
2928 AC_SUBST(lwlib_objs)
2929
2930 case "$with_scrollbars" in athena* ) AC_DEFINE(LWLIB_SCROLLBARS_ATHENA);; esac
2931 case "$with_dialogs"    in athena* ) AC_DEFINE(LWLIB_DIALOGS_ATHENA)   ;; esac
2932 test "$with_scrollbars" = "athena3d" && AC_DEFINE(LWLIB_SCROLLBARS_ATHENA3D)
2933 test "$with_dialogs"    = "athena3d" && AC_DEFINE(LWLIB_DIALOGS_ATHENA3D)
2934
2935 test "$with_menubars"   != "no"    && AC_DEFINE(HAVE_MENUBARS)
2936 test "$with_scrollbars" != "no"    && AC_DEFINE(HAVE_SCROLLBARS)
2937 test "$with_dialogs"    != "no"    && AC_DEFINE(HAVE_DIALOGS)
2938 test "$with_toolbars"   != "no"    && AC_DEFINE(HAVE_TOOLBARS)
2939
2940 test "$with_menubars"   = "lucid"  && AC_DEFINE(LWLIB_MENUBARS_LUCID)
2941 test "$with_scrollbars" = "lucid"  && AC_DEFINE(LWLIB_SCROLLBARS_LUCID)
2942
2943 test "$with_menubars"   = "motif"  && AC_DEFINE(LWLIB_MENUBARS_MOTIF)
2944 test "$with_scrollbars" = "motif"  && AC_DEFINE(LWLIB_SCROLLBARS_MOTIF)
2945 test "$with_dialogs"    = "motif"  && AC_DEFINE(LWLIB_DIALOGS_MOTIF)
2946
2947 test "$with_menubars"   != "no"      && XE_ADD_OBJS(menubar.o)
2948 test "$with_scrollbars" != "no"      && XE_ADD_OBJS(scrollbar.o)
2949 test "$with_dialogs"    != "no"      && XE_ADD_OBJS(dialog.o)
2950 test "$with_toolbars"   != "no"      && XE_ADD_OBJS(toolbar.o)
2951
2952 if test "$with_x11" = "yes"; then
2953   test "$with_menubars"   != "no"      && XE_ADD_OBJS(menubar-x.o)
2954   test "$with_scrollbars" != "no"      && XE_ADD_OBJS(scrollbar-x.o)
2955   test "$with_dialogs"    != "no"      && XE_ADD_OBJS(dialog-x.o)
2956   test "$with_toolbars"   != "no"      && XE_ADD_OBJS(toolbar-x.o)
2957   test "$all_widgets" != "no no no no no" && XE_ADD_OBJS(gui-x.o)
2958 else
2959   if test \( "$with_sound" = "nas" \) -o \( "$with_sound" = "both" \); then
2960     echo "Attempt to Build NAS sound without X"
2961     echo "Please remove NAS configuration or build with X"
2962     exit 1
2963   fi
2964 fi
2965
2966 dnl ----------------------
2967 dnl Mule-dependent options
2968 dnl ----------------------
2969
2970 test -z "$with_mule" && with_mule=no
2971 test -z "$with_file_coding" && with_file_coding=no
2972
2973 dnl if test "$with_mule" = "yes" && test ! -d "$srcdir/lisp/mule"; then
2974 dnl     echo "Attempt to Build with Mule without Mule/Lisp"
2975 dnl     echo "Please install the XEmacs/Mule tarball or"
2976 dnl     echo "rerun configure with --with-mule=no"
2977 dnl     exit 1
2978 dnl fi
2979
2980 if test "$with_file_coding" = "yes" && test "$with_mule" = "no"; then
2981   AC_DEFINE(FILE_CODING)
2982   XE_ADD_OBJS(file-coding.o)
2983 fi
2984
2985 if test "$with_mule" = "yes" ; then
2986   AC_CHECKING(for Mule-related features)
2987   AC_DEFINE(MULE)
2988   AC_DEFINE(FILE_CODING)
2989   XE_ADD_OBJS(mule.o mule-ccl.o mule-charset.o file-coding.o)
2990
2991   dnl Use -lintl to get internationalized strerror for Mule
2992   AC_CHECK_HEADERS(libintl.h)
2993   AC_CHECK_LIB(intl, strerror)
2994
2995   AC_CHECKING(for Mule input methods)
2996   dnl Do we have the XmIm* routines?  And if so, do we want to use them?
2997   dnl XIM seems to be flaky except on Solaris...
2998   dnl test -z "$with_xim" -a "$opsys" != "sol2" && with_xim=no
2999   case "$with_xim" in "" | "yes" )
3000     AC_CHECKING(for XIM)
3001     AC_CHECK_LIB(X11, XOpenIM, with_xim=xlib, with_xim=no)
3002     dnl XIM + Lesstif is not (yet?) usable
3003     if test "$have_motif $have_lesstif" = "yes no"; then
3004       AC_CHECK_LIB(Xm, XmImMbLookupString, with_xim=motif)
3005     fi ;;
3006   esac
3007   if test "$with_xim" != "no"; then
3008     AC_DEFINE(HAVE_XIM)
3009     if test "$with_xim" = "xlib"; then
3010       AC_DEFINE(XIM_XLIB)
3011       XE_ADD_OBJS(input-method-xlib.o)
3012     fi
3013     if test "$with_xim" = "motif"; then
3014       AC_DEFINE(XIM_MOTIF)
3015       need_motif=yes
3016       XE_ADD_OBJS(input-method-motif.o)
3017     fi
3018     if test "$with_xim" = "motif"; then
3019       with_xfs=no
3020     fi
3021   fi
3022
3023   dnl "with_xfs" = "yes"
3024   if test "$with_xfs" = "yes" ; then
3025     AC_CHECKING(for XFontSet)
3026     AC_CHECK_LIB(X11, XmbDrawString, [:], with_xfs=no)
3027     if test "$with_xfs" = "yes" && test "$with_menubars" = "lucid"; then
3028       AC_DEFINE(USE_XFONTSET)
3029       if test "$with_xim" = "no" ; then
3030         XE_ADD_OBJS(input-method-xfs.o)
3031       fi
3032     fi
3033   fi dnl with_xfs
3034
3035   dnl Autodetect WNN
3036   test "$with_wnn6" = "yes" && with_wnn=yes # wnn6 implies wnn support
3037   test -z "$with_wnn" && { AC_CHECK_HEADER(wnn/jllib.h, ,with_wnn=no) }
3038   dnl Detour to find crypt
3039   if test "$with_wnn" != "no"; then
3040     AC_CHECK_FUNCS(crypt)
3041     test "$ac_cv_func_crypt" != "yes" && { AC_CHECK_LIB(crypt, crypt) }
3042   fi
3043   dnl Back to our regularly scheduled wnn hunting
3044   if test -z "$with_wnn" -o "$with_wnn" = "yes"; then
3045     AC_CHECK_LIB(wnn,jl_dic_list_e,libwnn=wnn,
3046       AC_CHECK_LIB(wnn4,jl_dic_list_e,libwnn=wnn4,
3047         AC_CHECK_LIB(wnn6,jl_dic_list_e,libwnn=wnn6,
3048           AC_CHECK_LIB(wnn6_fromsrc,dic_list_e,libwnn=wnn6_fromsrc,with_wnn=no))))
3049   fi
3050   test -z "$with_wnn" && with_wnn=yes
3051   if test "$with_wnn" = "yes"; then
3052     AC_DEFINE(HAVE_WNN)
3053     XE_PREPEND(-l$libwnn, libs_x)
3054     XE_ADD_OBJS(mule-wnnfns.o)
3055     if test "$with_wnn6" != "no"; then
3056       AC_CHECK_LIB($libwnn, jl_fi_dic_list, with_wnn6=yes)
3057       test "$with_wnn6" = "yes" && AC_DEFINE(WNN6)
3058     fi
3059   fi
3060
3061   dnl Autodetect canna
3062   canna_includes_found=no
3063   if test "$with_canna" != "no"; then
3064     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3065   fi
3066   if test "$canna_includes_found" = "no" -a "$with_canna" != "no" -a \
3067       -d "/usr/local/canna/include"; then
3068     save_c_switch_site="$c_switch_site"
3069     c_switch_site="$c_switch_site -I/usr/local/canna/include"
3070     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3071     if test "$canna_includes_found" != "yes"; then
3072       c_switch_site="$save_c_switch_site"
3073       with_canna="no"
3074     fi
3075   fi
3076
3077   test -z "$with_canna" && { AC_CHECK_HEADER(canna/RK.h,         , with_canna=no) }
3078   test -z "$with_canna" && { AC_CHECK_LIB(RKC, RkBgnBun,       [:],with_canna=no) }
3079   test -z "$with_canna" && { AC_CHECK_LIB(canna,jrKanjiControl,[:],with_canna=no) }
3080   test -z "$with_canna" && with_canna=yes
3081   if test "$with_canna" = "yes"; then
3082     AC_DEFINE(HAVE_CANNA)
3083     XE_PREPEND(-lcanna -lRKC, libs_x)
3084     XE_ADD_OBJS(mule-canna.o)
3085   fi
3086
3087 else dnl "$with_mule" = "no"
3088   for feature in xim canna wnn; do
3089     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
3090       AC_MSG_WARN("--with-${feature} ignored:  Not valid without Mule support")
3091     fi
3092     eval "with_${feature}=no"
3093   done
3094 fi dnl with_mule
3095
3096
3097 dnl At this point, we know whether we need the motif lib or not.
3098 if test "$need_motif" = "yes" ; then
3099   XE_PREPEND(-lXm, libs_x)
3100   dnl AIX needs the following library for use with Motif
3101   AC_CHECK_LIB(i18n, layout_object_getvalue, [XE_PREPEND(-li18n, libs_x)])
3102   XE_COMPUTE_RUNPATH()
3103 fi
3104
3105 AC_CHECK_FUNCS(cbrt closedir dup2 eaccess fmod fpathconf frexp ftime gethostname getpagesize gettimeofday getcwd getwd logb lrand48 matherr mkdir mktime perror poll random rename res_init rint rmdir select setitimer setpgid setlocale setsid sigblock sighold sigprocmask snprintf strcasecmp strerror tzset ulimit usleep utimes waitpid vsnprintf)
3106
3107 dnl realpath is buggy on linux, decosf and aix4
3108
3109 dnl The realpath() in linux libc (4.6.27) sometimes fails with ELOOP.
3110 dnl The realpath in ELF linux libc's is O.K.
3111 dnl For example, call realpath on a file thirty-five or so directories deep
3112 dnl and you get ELOOP even if no symlinks at all are involved.
3113 dnl Reports as of 11/1997 indicate BSDi has problems too.
3114 dnl The realpath() in UnixWare2.1.3 could not get any pathname fragment in error condition.
3115 case "$opsys" in
3116   linuxaout* | bsdos3* | freebsd* | decosf4-0* | aix4* ) XE_ADD_OBJS(realpath.o) ;;
3117   * )
3118     case "$canonical" in
3119       *-*-sysv4.2uw2* ) XE_ADD_OBJS(realpath.o) ;;
3120       * ) AC_CHECK_FUNCS(realpath)
3121           test "$ac_cv_func_realpath" != "yes" && XE_ADD_OBJS(realpath.o) ;;
3122     esac ;;
3123 esac
3124
3125 dnl Check whether the system provides getloadavg (Solaris 7 has it)
3126 AC_CHECK_FUNCS(getloadavg)
3127
3128 if test "$ac_cv_func_getloadavg" != "yes"
3129 then
3130   XE_ADD_OBJS(getloadavg.o)
3131
3132   dnl Used by getloadavg() - does not require root priveleges
3133   AC_CHECK_LIB(kstat, kstat_open)
3134
3135   dnl Another way to get the load average
3136   AC_CHECK_LIB(kvm, kvm_read)
3137 fi
3138
3139 dnl If netdb.h does not declare h_errno, we must declare it by hand.
3140 AC_MSG_CHECKING(whether netdb declares h_errno)
3141 AC_TRY_LINK([#include <netdb.h>],
3142   [return h_errno;],
3143   [AC_MSG_RESULT(yes)
3144    AC_DEFINE(HAVE_H_ERRNO)],
3145   [AC_MSG_RESULT(no)])
3146
3147 AC_MSG_CHECKING(for sigsetjmp)
3148 AC_TRY_COMPILE([#include <setjmp.h>],
3149         [sigjmp_buf bar; sigsetjmp (bar, 0);],
3150   [AC_MSG_RESULT(yes)
3151    AC_DEFINE(HAVE_SIGSETJMP)],
3152   [AC_MSG_RESULT(no)])
3153
3154 AC_MSG_CHECKING(whether localtime caches TZ)
3155 AC_CACHE_VAL(emacs_cv_localtime_cache,
3156 [if test "$ac_cv_func_tzset" = "yes"; then
3157 AC_TRY_RUN([#include <time.h>
3158 #if STDC_HEADERS
3159 # include <stdlib.h>
3160 #endif
3161 extern char **environ;
3162 unset_TZ ()
3163 {
3164   char **from, **to;
3165   for (to = from = environ; (*to = *from); from++)
3166     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
3167       to++;
3168 }
3169 char TZ_GMT0[] = "TZ=GMT0";
3170 char TZ_PST8[] = "TZ=PST8";
3171 main()
3172 {
3173   time_t now = time ((time_t *) 0);
3174   int hour_GMT0, hour_unset;
3175   if (putenv (TZ_GMT0) != 0)
3176     exit (1);
3177   hour_GMT0 = localtime (&now)->tm_hour;
3178   unset_TZ ();
3179   hour_unset = localtime (&now)->tm_hour;
3180   if (putenv (TZ_PST8) != 0)
3181     exit (1);
3182   if (localtime (&now)->tm_hour == hour_GMT0)
3183     exit (1);
3184   unset_TZ ();
3185   if (localtime (&now)->tm_hour != hour_unset)
3186     exit (1);
3187   exit (0);
3188 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3189 [# If we have tzset, assume the worst when cross-compiling.
3190 emacs_cv_localtime_cache=yes])
3191 else
3192         # If we lack tzset, report that localtime does not cache TZ,
3193         # since we can't invalidate the cache if we don't have tzset.
3194         emacs_cv_localtime_cache=no
3195 fi],[:])dnl
3196 AC_MSG_RESULT($emacs_cv_localtime_cache)
3197 if test $emacs_cv_localtime_cache = yes; then
3198   AC_DEFINE(LOCALTIME_CACHE)
3199 fi
3200
3201 if test "$HAVE_TIMEVAL" = "yes"; then
3202 AC_MSG_CHECKING(whether gettimeofday accepts one or two arguments)
3203 AC_TRY_LINK([
3204 #ifdef TIME_WITH_SYS_TIME
3205 #include <sys/time.h>
3206 #include <time.h>
3207 #else
3208 #ifdef HAVE_SYS_TIME_H
3209 #include <sys/time.h>
3210 #else
3211 #include <time.h>
3212 #endif
3213 #endif
3214   ],
3215   [
3216   struct timeval time;
3217   struct timezone dummy;
3218   gettimeofday (&time, &dummy);
3219 ],
3220   [AC_MSG_RESULT(two)],
3221   [AC_MSG_RESULT(one)
3222    AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
3223 fi
3224
3225
3226 AC_C_INLINE
3227 if test "$ac_cv_c_inline" != "no"; then
3228   AC_DEFINE(HAVE_INLINE)
3229   test "$GCC" = "yes" && XE_ADD_OBJS(inline.o)
3230 fi
3231
3232 dnl HP-UX has a working alloca in libPW.
3233 dnl case "${GCC}${opsys}" in hpux* )
3234 dnl  AC_CHECK_FUNC(alloca, [:], [AC_CHECK_LIB(PW, alloca)])
3235 dnl esac
3236
3237 AC_FUNC_ALLOCA
3238 test -n "$ALLOCA" && XE_ADD_OBJS($ALLOCA)
3239
3240 dnl Check whether vfork exists and works correctly. (This does more
3241 dnl than just check for its existence.) If so, it defines HAVE_VFORK_H.
3242 dnl If not, it defines vfork to be fork.
3243 AC_FUNC_VFORK
3244
3245 dnl Check whether strcoll exists and works correctly. (This does more
3246 dnl than just check for its existence.) If so, it defines HAVE_STRCOLL.
3247 AC_FUNC_STRCOLL
3248
3249 dnl If `getpgrp' takes no argument (the POSIX.1 version), define
3250 dnl `GETPGRP_VOID'.  Otherwise, it is the BSD version, which takes a
3251 dnl process ID as an argument.
3252 AC_CHECK_FUNCS(getpgrp)
3253 AC_FUNC_GETPGRP
3254
3255 dnl We used to call AC_FUNC_MMAP here
3256 dnl Instead we now use following, suggested by Neal Becker
3257 AC_MSG_CHECKING(for working mmap)
3258 case "$opsys" in ultrix* ) have_mmap=no ;; *)
3259 AC_TRY_RUN([#include <stdio.h>
3260 #include <unistd.h>
3261 #include <fcntl.h>
3262 #include <sys/mman.h>
3263
3264 #ifndef MAP_VARIABLE
3265 #define MAP_VARIABLE 0
3266 #endif
3267
3268 #ifndef MAP_FAILED
3269 #define MAP_FAILED -1
3270 #endif
3271
3272 int main (int argc, char *argv[])
3273 {
3274   int fd = -1;
3275   caddr_t p;
3276 #ifndef MAP_ANONYMOUS
3277   fd = open ("/dev/zero", O_RDWR);
3278   if (fd < 0)
3279     return 1;
3280 #define MAP_ANONYMOUS 0
3281 #endif
3282   if (mmap(0, 1024, PROT_READ | PROT_WRITE,
3283            MAP_PRIVATE | MAP_VARIABLE | MAP_ANONYMOUS,
3284            fd, 0) != (void *) MAP_FAILED)
3285     return 0;
3286   perror ("conftest: mmap failed");
3287   return 1;
3288 }], have_mmap=yes, have_mmap=no) ;;
3289 esac
3290 AC_MSG_RESULT($have_mmap)
3291 test "$have_mmap" = "yes" && AC_DEFINE(HAVE_MMAP)
3292
3293 dnl rel_alloc requires either GNU malloc or system malloc with mmap
3294 dnl We only turn rel_alloc on by default if mmap is available.
3295 test "$GNU_MALLOC" != "yes"   -a "$have_mmap" != "yes" && rel_alloc=no
3296 test "$rel_alloc" = "default" -a "$have_mmap"  = "yes" && rel_alloc=yes
3297 test "$rel_alloc" = "yes" && AC_DEFINE(REL_ALLOC)
3298
3299 dnl Check for terminal I/O variants
3300 dnl TERMIOS systems may have termio.h, but not vice-versa, I think.
3301 AC_CHECK_HEADER(termios.h,
3302   AC_DEFINE(HAVE_TERMIOS)
3303   AC_DEFINE(SIGNALS_VIA_CHARACTERS)
3304   AC_DEFINE(NO_TERMIO),
3305   [AC_CHECK_HEADER(termio.h, [AC_DEFINE(HAVE_TERMIO)])])
3306
3307
3308 dnl Check for Internet sockets.
3309 AC_CHECK_FUNC(socket,
3310  [AC_CHECK_HEADER(netinet/in.h,
3311    [AC_CHECK_HEADER(arpa/inet.h, [
3312   AC_DEFINE(HAVE_SOCKETS)
3313       AC_MSG_CHECKING("for sun_len member in struct sockaddr_un")
3314       AC_TRY_LINK([
3315 #include <sys/types.h>
3316 #include <sys/socket.h>
3317 #include <sys/un.h>
3318       ],
3319       [static struct sockaddr_un x; x.sun_len = 1;],
3320       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)],
3321       [AC_MSG_RESULT(no)])
3322       AC_MSG_CHECKING("for ip_mreq struct in netinet/in.h")
3323       AC_TRY_LINK([
3324 #include <sys/types.h>
3325 #include <netinet/in.h>
3326       ],
3327       [static struct ip_mreq x;],
3328       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MULTICAST)],
3329       [AC_MSG_RESULT(no)])])])])
3330
3331 dnl Check for SYS V IPC. (Inferior to sockets.)
3332 AC_CHECK_FUNC(msgget,
3333   [AC_CHECK_HEADER(sys/ipc.h,
3334     [AC_CHECK_HEADER(sys/msg.h,
3335       [AC_DEFINE(HAVE_SYSVIPC)])])])
3336
3337 dnl Check for directory variants
3338 AC_CHECK_HEADER(dirent.h, [AC_DEFINE(SYSV_SYSTEM_DIR)],
3339   [AC_CHECK_HEADER(sys/dir.h, , [AC_DEFINE(NONSYSTEM_DIR_LIBRARY)])])
3340
3341 dnl Check for nlist.h
3342 AC_CHECK_HEADER(nlist.h, AC_DEFINE(NLIST_STRUCT), )
3343
3344 dnl Check for sound of various sorts.
3345
3346 dnl Autodetect native sound
3347 AC_CHECKING("for sound support")
3348 case "$with_sound" in
3349   native | both ) with_native_sound=yes;;
3350   nas    | no   ) with_native_sound=no;;
3351 esac
3352 test -z "$with_native_sound" -a -n "$native_sound_lib" && with_native_sound=yes
3353
3354 if test "$with_native_sound" != "no"; then
3355   dnl Maybe sound is already on include path...
3356   if test -n "$native_sound_lib"; then
3357     AC_CHECK_HEADER(multimedia/audio_device.h,
3358       [sound_found=yes sound_cflags=""
3359       XE_ADD_OBJS(sunplay.o)])
3360   fi
3361
3362   dnl Autodetect Sun native sound from SUNWaudmo package
3363   if test -z "$sound_found" -a -d "/usr/demo/SOUND"; then
3364     sound_found=yes
3365     XE_ADD_OBJS(sunplay.o)
3366     if test -d "/usr/demo/SOUND/include"
3367       then sound_cflags="-I/usr/demo/SOUND/include"
3368       else sound_cflags="-I/usr/demo/SOUND"
3369     fi
3370     if test -z "$native_sound_lib" ; then
3371       if test -r "/usr/demo/SOUND/lib/libaudio.a"
3372         then native_sound_lib="/usr/demo/SOUND/lib/libaudio.a"
3373         else native_sound_lib="/usr/demo/SOUND/libaudio.a"
3374       fi
3375     fi
3376   fi
3377
3378   dnl Check for SGI and HP native sound libs
3379   if test -z "$sound_found"; then
3380     case "$canonical" in
3381     *-sgi-* )
3382       if test -z "$native_sound_lib"; then
3383         AC_CHECK_LIB(audio, ALopenport, native_sound_lib="-laudio")
3384       fi
3385       if test -n "$native_sound_lib"; then
3386         sound_found=yes sound_cflags=""
3387         XE_ADD_OBJS(sgiplay.o)
3388       fi ;;
3389     hppa*-hp-hpux* )
3390       if test -z "$native_sound_lib"; then
3391         AC_CHECK_LIB(Alib, AOpenAudio, native_sound_lib="-lAlib")
3392       fi
3393       if test -n "$native_sound_lib"; then
3394         sound_found=yes
3395         XE_ADD_OBJS(hpplay.o)
3396         if test "$GCC" = "yes" # Kludge city
3397           then sound_cflags="-Dconst= -Dvolatile= -I/usr/audio/examples"
3398           else sound_cflags="+e -I/usr/audio/examples"
3399         fi
3400       fi ;;
3401     esac
3402   fi
3403
3404   dnl Check for Linux/BSD native sound
3405   if test -z "$sound_found"; then
3406     for dir in "machine" "sys" "linux"; do
3407       AC_CHECK_HEADER(${dir}/soundcard.h,
3408         sound_found=yes
3409         XE_ADD_OBJS(linuxplay.o)
3410         [AC_DEFINE_UNQUOTED(SOUNDCARD_H_PATH, "${dir}/soundcard.h")]
3411         break)
3412     done
3413   fi
3414
3415   test "$sound_found" = "yes" && with_native_sound=yes
3416 fi
3417
3418 if test -z "$with_sound"; then
3419   if test "$with_native_sound" = "yes" -o -n "$native_sound_lib"; then
3420     with_sound=native
3421   fi
3422 fi
3423
3424 if test "$with_native_sound" = "yes"; then
3425   AC_DEFINE(HAVE_NATIVE_SOUND)
3426   test -n "$native_sound_lib" && XE_PREPEND($native_sound_lib, LIBS)
3427 fi
3428
3429 case "$with_sound" in both | nas )
3430   AC_DEFINE(HAVE_NAS_SOUND)
3431   XE_ADD_OBJS(nas.o)
3432   XE_PREPEND(-laudio, libs_x)
3433   dnl If the nas library does not contain the error jump point,
3434   dnl then we force safer behavior.
3435   AC_EGREP_HEADER(AuXtErrorJump,audio/Xtutil.h,,[AC_DEFINE(NAS_NO_ERROR_JUMP)])
3436 esac
3437
3438 dnl ---------------------
3439 dnl TTY-dependent options
3440 dnl ---------------------
3441
3442 test -z "$with_tty" && with_tty=yes
3443
3444 if test "$with_tty" = "yes"  ; then
3445   AC_CHECKING(for TTY-related features)
3446   AC_DEFINE(HAVE_TTY)
3447   XE_ADD_OBJS(console-tty.o device-tty.o event-tty.o frame-tty.o objects-tty.o redisplay-tty.o cm.o)
3448
3449   dnl Autodetect ncurses.
3450   if test -z "$with_ncurses"; then
3451     AC_CHECK_LIB(ncurses, tgetent, with_ncurses=yes, with_ncurses=no)
3452   fi
3453   if test "$with_ncurses" = "yes"; then
3454     AC_DEFINE(HAVE_NCURSES)
3455     AC_CHECK_HEADER(ncurses/curses.h, curses_h_path=ncurses/curses.h)
3456     AC_CHECK_HEADER(ncurses/term.h, term_h_path=ncurses/term.h)
3457     XE_ADD_OBJS(terminfo.o)
3458     XE_PREPEND(-lncurses, LIBS)
3459
3460     if test "$ac_cv_header_ncurses_curses_h" != "yes" ; then
3461       dnl Try again, and check for the bogus ncurses/ include bug.
3462       dnl (i.e. ncurses/curses.h bogusly includes <unctrl.h> instead of
3463       dnl <ncurses/unctrl.h>)
3464       save_c_switch_site="$c_switch_site"
3465       c_switch_site="$c_switch_site -I/usr/include/ncurses"
3466       AC_CHECK_HEADER(ncurses/curses.h, curses_h_path=ncurses/curses.h)
3467       if test "$ac_cv_header_ncurses_curses_h" = "yes"
3468         then AC_MSG_WARN("Your system has the bogus ncurses include bug.")
3469         else c_switch_site="$save_c_switch_site"
3470       fi
3471     fi
3472   else dnl "$with_ncurses" = "no"
3473     dnl Autodetect terminfo/-lcurses/-ltermlib/-ltermcap
3474     if test "$have_terminfo" = "yes"; then
3475       XE_ADD_OBJS(terminfo.o)
3476       if test -n "$libs_termcap"; then
3477         XE_PREPEND($libs_termcap, LIBS)
3478       else
3479         for lib in curses termlib termcap; do
3480           AC_CHECK_LIB($lib, tgetent, XE_PREPEND(-l${lib}, LIBS); break)
3481         done
3482       fi
3483     else dnl "$have_terminfo" = "no" && "with_ncurses" = "no"
3484       XE_ADD_OBJS(tparam.o)
3485       dnl The HP-UX curses library seems to have a badly broken version of select(2)
3486       dnl that makes "poll: interrupted system call" messages to appear and
3487       dnl Emacs suprocesses to hang (e.g. TeX compilation w/ AUCTeX) */
3488       case "$opsys" in *-hp-hpux* ) libs_termcap="-ltermcap" ;; esac
3489       if test -n "$libs_termcap"; then
3490         XE_PREPEND($libs_termcap, LIBS)
3491       else
3492         AC_CHECK_LIB(curses, tgetent, XE_PREPEND(-lcurses, LIBS),
3493           AC_CHECK_LIB(termcap, tgetent, XE_PREPEND(-ltermcap, LIBS),
3494             XE_ADD_OBJS(termcap.o)))
3495       fi
3496     fi
3497   fi
3498   AC_DEFINE_UNQUOTED(CURSES_H_PATH, "${curses_h_path-curses.h}")
3499   AC_DEFINE_UNQUOTED(TERM_H_PATH, "${term_h_path-term.h}")
3500
3501   dnl Autodetect gpm
3502   test -z "$with_gpm" && { AC_CHECK_HEADER(gpm.h, , with_gpm=no) }
3503   test -z "$with_gpm" && { AC_CHECK_LIB(gpm, Gpm_Open, with_gpm=yes, with_gpm=no) }
3504   if test "$with_gpm" = "yes"; then
3505     AC_DEFINE(HAVE_GPM)
3506     XE_ADD_OBJS(gpmevent.o)
3507     XE_PREPEND(-lgpm, LIBS)
3508   fi
3509
3510 else dnl "$with_tty" = "no"
3511   for feature in ncurses gpm; do
3512     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
3513       AC_MSG_WARN("--with-${feature} ignored:  Not valid without TTY support")
3514     fi
3515     eval "with_${feature}=no"
3516   done
3517 fi dnl with_tty
3518
3519 dnl Do we need event-unixoid.o ?
3520 test "$with_x11" = "yes" -o "$with_tty" = "yes" && XE_ADD_OBJS(event-unixoid.o)
3521
3522 dnl Database support
3523 dnl We do not necessarily have to have libdb/lib(g)dbm for DB/(G)DBM support.
3524 dnl On FreeBSD, both DB and DBM are part of libc.
3525 dnl By default, we check for DBM support in libgdbm, then libc, then libdbm.
3526
3527 test "$with_database_gnudbm $with_database_dbm $with_database_berkdb" \
3528   != "no no no" && AC_CHECKING(for database support)
3529
3530 dnl Check for ndbm.h, required for either kind of DBM support.
3531 if test "$with_database_gnudbm $with_database_dbm" != "no no"; then
3532   AC_CHECK_HEADER(ndbm.h, [:], [
3533     test "$with_database_gnudbm" = "yes" -o \
3534          "$with_database_dbm"    = "yes" && \
3535       XE_DIE("Required DBM support cannot be provided.")
3536     with_database_gnudbm=no with_database_dbm=no])
3537 fi
3538
3539 dnl Check for DBM support in libgdbm.
3540 if test "$with_database_gnudbm" != "no"; then
3541   AC_CHECK_LIB(gdbm, dbm_open, [
3542    with_database_gnudbm=yes with_database_dbm=no libdbm=-lgdbm], [
3543    if test "$with_database_gnudbm" = "yes"; then
3544      XE_DIE("Required GNU DBM support cannot be provided.")
3545    fi
3546    with_database_gnudbm=no])
3547 fi
3548
3549 dnl Check for DBM support in libc and libdbm.
3550 if test "$with_database_dbm" != "no"; then
3551   AC_CHECK_FUNC(dbm_open, [with_database_dbm=yes libdbm=], [
3552     AC_CHECK_LIB(dbm, dbm_open, [with_database_dbm=yes libdbm=-ldbm], [
3553       test "$with_database_dbm" = "yes" && \
3554         XE_DIE("Required DBM support cannot be provided.")
3555       with_database_dbm=no])])
3556 fi
3557
3558 dnl Tell make about the DBM support we detected.
3559 test -n "$libdbm" && XE_PREPEND("$libdbm", LIBS)
3560 test "$with_database_gnudbm" = "yes" -o \
3561      "$with_database_dbm"    = "yes" && \
3562   AC_DEFINE(HAVE_DBM)
3563
3564 dnl Check for Berkeley DB.
3565 if test "$with_database_berkdb" != "no"; then
3566   AC_MSG_CHECKING(for Berkeley db.h)
3567   for path in "db/db.h" "db.h"; do
3568     AC_TRY_COMPILE([#ifdef HAVE_INTTYPES_H
3569 #define __BIT_TYPES_DEFINED__
3570 #include <inttypes.h>
3571 typedef uint8_t  u_int8_t;
3572 typedef uint16_t u_int16_t;
3573 typedef uint32_t u_int32_t;
3574 #ifdef WE_DONT_NEED_QUADS
3575 typedef uint64_t u_int64_t;
3576 #endif
3577 #endif
3578 #include <$path>
3579 ],[], db_h_path="$path"; break)
3580   done
3581   if test -z "$db_h_path"
3582   then AC_MSG_RESULT(no); with_database_berkdb=no
3583   else AC_MSG_RESULT($db_h_path)
3584   fi
3585
3586   if test "$with_database_berkdb" != "no"; then
3587     AC_MSG_CHECKING(for Berkeley DB version)
3588     AC_EGREP_CPP(yes,
3589 [#include <$db_h_path>
3590 #if DB_VERSION_MAJOR > 1
3591 yes
3592 #endif
3593 ], [AC_MSG_RESULT(2); dbfunc=db_open], [AC_MSG_RESULT(1); dbfunc=dbopen])
3594     AC_CHECK_FUNC($dbfunc,     with_database_berkdb=yes need_libdb=no, [
3595     AC_CHECK_LIB(db, $dbfunc,  with_database_berkdb=yes need_libdb=yes)])
3596   fi
3597
3598   if test "$with_database_berkdb" = "yes"; then
3599     AC_DEFINE_UNQUOTED(DB_H_PATH, "$db_h_path")
3600     AC_DEFINE(HAVE_BERKELEY_DB)
3601     test "$need_libdb" = "yes" && XE_PREPEND(-ldb, LIBS)
3602   else with_database_berkdb=no
3603   fi
3604 fi
3605
3606 if test "$with_database_gnudbm $with_database_dbm $with_database_berkdb" \
3607      != "no no no"; then
3608   AC_DEFINE(HAVE_DATABASE)
3609   XE_ADD_OBJS(database.o)
3610 fi
3611
3612 dnl Socks support
3613 if test "$with_socks" = "yes"; then
3614   AC_CHECK_LIB(socks, SOCKSinit)
3615   test -n "$ac_cv_lib_socks_SOCKSinit" && AC_DEFINE(HAVE_SOCKS)
3616 fi
3617
3618 dnl Usage tracking (undocumented and likely unused option)
3619 if test "$usage_tracking" = "yes"; then
3620   AC_DEFINE(USAGE_TRACKING)
3621   XE_PREPEND(-Bstatic -lut -Bdynamic, LIBS)
3622 fi
3623
3624 dnl autodetect dll support
3625 AC_CHECK_HEADERS(dlfcn.h, [have_dlfcn=yes
3626   AC_DEFINE(HAVE_DLFCN_H)])
3627 test -z "$with_modules" && test ! -z "$have_dlfcn" && { AC_CHECK_LIB(dl,  dlopen,   [ AC_DEFINE(HAVE_DLOPEN) DLL_LIB=dl;  with_modules=yes]) }
3628 test -z "$with_modules" && test ! -z "$have_dlfcn" && { AC_CHECK_LIB(c,   _dlopen,  [ AC_DEFINE(HAVE_DLOPEN) DLL_LIB=;   with_modules=yes]) }
3629 test -z "$with_modules" && test ! -z "$have_dlfcn" && { AC_CHECK_LIB(c,   dlopen,   [ AC_DEFINE(HAVE_DLOPEN) DLL_LIB=;   with_modules=yes]) }
3630 test -z "$with_modules" && { AC_CHECK_LIB(dld, shl_load, [ AC_DEFINE(HAVE_SHL_LOAD) DLL_LIB=dld; with_modules=yes]) }
3631 test -z "$with_modules" && { AC_CHECK_LIB(dld, dld_init, [ AC_DEFINE(HAVE_DLD_INIT) DLL_LIB=dld; with_modules=yes]) }
3632 if test "$with_modules" = "yes"; then
3633   XE_SHLIB_STUFF
3634   if test "$can_build_shared" = "yes"; then
3635     AC_DEFINE(HAVE_SHLIB)
3636     XE_ADD_OBJS(sysdll.o)
3637     XE_ADD_OBJS(emodules.o)
3638     XE_APPEND(src, INSTALL_ARCH_DEP_SUBDIR)
3639     test ! -z "$DLL_LIB" && XE_PREPEND(-l${DLL_LIB}, LIBS)
3640     AC_CHECK_FUNCS(dlerror _dlerror)
3641   else
3642     AC_MSG_WARN(disabling shared library support)
3643     with_modules=no
3644   fi
3645 fi
3646
3647 dnl Unfortunately, just because we can link doesn't mean we can run.
3648 dnl One of the above link tests may have succeeded but caused resulting
3649 dnl executables to fail to run.  Also any tests using AC_TRY_RUN will
3650 dnl have reported incorrect results.
3651 AC_TRY_RUN([int main(int c,char *v[]){return 0;}],[:],[
3652   echo ""
3653   echo "*** PANIC *** The C compiler can no longer build working executables."
3654   echo "*** PANIC *** Please examine the tail of config.log for runtime errors."
3655   echo "*** PANIC *** The most likely reason for this problem is that configure"
3656   echo "*** PANIC *** links with shared libraries, but those libraries cannot be"
3657   echo "*** PANIC *** found at run time."
3658   echo "*** PANIC ***"
3659   echo "*** PANIC *** On a Linux system, edit /etc/ld.so.conf and re-run ldconfig."
3660   echo "*** PANIC *** On other systems, try telling configure where to find the"
3661   echo "*** PANIC *** shared libraries using the --site-runtime-libraries option"
3662   echo "*** PANIC ***"
3663   echo "*** PANIC *** Another way to shoot yourself in the foot is to specify"
3664   echo "*** PANIC *** --with-FEATURE when FEATURE is not actually installed"
3665   echo "*** PANIC *** on your system.  Don't do that."
3666   exit 1])
3667
3668 dnl Process support
3669 if test "$win32_processes" = "yes"; then
3670   XE_ADD_OBJS(process-nt.o)
3671 else
3672   AC_DEFINE(HAVE_UNIX_PROCESSES)
3673   XE_ADD_OBJS(process-unix.o)
3674 fi
3675
3676 dnl --------------------------------
3677 dnl Compute SUBST-itutable variables
3678 dnl --------------------------------
3679
3680 dnl We ignore (C|LD)_SWITCH_X_(MACHINE|SYSTEM)
3681 dnl Use XE_SPACE instead of plain assignment statements to remove extraneous blanks
3682 XE_SPACE(CFLAGS, $CFLAGS)
3683 XE_SPACE(extra_objs, $extra_objs)
3684 XE_SPACE(c_switch_general, -DHAVE_CONFIG_H $c_switch_site $c_switch_machine $c_switch_system)
3685 XE_SPACE(c_switch_window_system, $c_switch_x_site $X_CFLAGS)
3686 XE_SPACE(c_switch_all, $c_switch_general $c_switch_window_system)
3687 XE_SPACE(ld_switch_general, $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_run)
3688 XE_SPACE(ld_switch_window_system, $ld_switch_x_site)
3689 XE_SPACE(ld_switch_all, $ld_switch_general $ld_switch_window_system)
3690 XE_SPACE(ld_libs_general, $LIBS $libs_machine $libs_system $libs_standard)
3691 XE_SPACE(ld_libs_window_system, $X_EXTRA_LIBS $libs_x $X_PRE_LIBS)
3692 XE_SPACE(ld_libs_all, $ld_libs_window_system $ld_libs_general)
3693
3694 dnl Compute lists of Makefiles and subdirs
3695 AC_SUBST(SRC_SUBDIR_DEPS)
3696 XE_APPEND(src, MAKE_SUBDIR)
3697 internal_makefile_list="Makefile.in"
3698 SUBDIR_MAKEFILES=''
3699 test -d lock || mkdir lock
3700 for dir in $MAKE_SUBDIR; do
3701   case "$dir" in */* ) dnl Implement mkdir -p
3702     ( for d in `echo $dir | sed 's:/: :g'` ; do
3703         test -d "$d" || mkdir "$d"; cd "$d"
3704       done ) ;;
3705    * ) test -d "$dir" || mkdir "$dir" ;;
3706   esac
3707   XE_SPACE(SUBDIR_MAKEFILES, $SUBDIR_MAKEFILES $dir/Makefile $dir/GNUmakefile)
3708   XE_SPACE(internal_makefile_list, $internal_makefile_list $dir/Makefile.in)
3709 done
3710 AC_SUBST(INSTALL_ARCH_DEP_SUBDIR)
3711 AC_SUBST(MAKE_SUBDIR)
3712 AC_SUBST(SUBDIR_MAKEFILES)
3713
3714 dnl Make s&m symlinks in the src directory, for config.h
3715 for dir in src/s src/m; do
3716   if test ! -d "$dir" ; then
3717     echo Making symbolic link to "$srcdir/$dir"
3718     ${LN_S} "$srcdir/$dir" "$dir"
3719   fi
3720 done
3721
3722 if test "$extra_verbose" = "yes"; then
3723   echo ""
3724   PRINT_VAR(extra_objs
3725    c_switch_general  c_switch_window_system  c_switch_all
3726   ld_switch_general ld_switch_window_system ld_switch_all
3727     ld_libs_general   ld_libs_window_system   ld_libs_all)
3728   echo ""
3729 fi
3730
3731 dnl Create some auxiliary files
3732 if test -f $srcdir/src/gdbinit -a ! -f src/gdbinit ; then
3733   echo "creating src/gdbinit"; echo ""
3734   echo "source $srcdir/src/gdbinit" > src/gdbinit
3735 fi
3736
3737 dnl Create top level .sbinit for Sun compilers
3738 if test "$__SUNPRO_C" = "yes"; then
3739   echo "creating .sbinit"; echo ""
3740   ( echo "# For use with Sun WorkShop's Source browser."
3741     echo "# See sbquery(1) and sbinit(4) for more information"
3742     for dir in $MAKE_SUBDIR; do echo "import $dir"; done
3743   ) > .sbinit
3744 fi
3745
3746 dnl There are no more compile tests; remove the core they created.
3747 rm -f core
3748
3749 dnl ----------------------------------------------
3750 dnl Substitute into Makefile, config.h and paths.h
3751 dnl ----------------------------------------------
3752
3753 dnl what sort of things to edit into Makefile, config.h and paths.h
3754 dnl configuration here uncanonicalized to avoid exceeding size limits.
3755
3756 AC_SUBST(PROGNAME)
3757 AC_SUBST(version)
3758 AC_SUBST(configuration)
3759 AC_SUBST(canonical)
3760 AC_SUBST(inststaticdir)
3761 AC_SUBST(instvardir)
3762 AC_SUBST(srcdir)
3763 AC_SUBST(bindir)
3764 AC_SUBST(datadir)
3765 AC_SUBST(pkgdir)
3766 AC_SUBST(statedir)
3767 AC_SUBST(libdir)
3768 AC_SUBST(mandir)
3769
3770 AC_SUBST(prefix)
3771 AC_SUBST(PREFIX_USER_DEFINED)
3772 dnl Yo, Stephen Bourne!  I want to marry you!
3773 PREFIX=$prefix
3774 while true; do
3775   case "$PREFIX" in
3776     *\$* ) eval "PREFIX=$PREFIX" ;;
3777     *) break ;;
3778   esac
3779 done
3780 AC_SUBST(PREFIX)
3781
3782 AC_SUBST(exec_prefix)
3783 AC_SUBST(EXEC_PREFIX_USER_DEFINED)
3784 EXEC_PREFIX=$exec_prefix
3785 while true; do
3786   case "$EXEC_PREFIX" in
3787     *\$* ) eval "EXEC_PREFIX=$EXEC_PREFIX" ;;
3788     *) break ;;
3789   esac
3790 done
3791 AC_SUBST(EXEC_PREFIX)
3792
3793 AC_SUBST(infodir)
3794 AC_SUBST(INFODIR_USER_DEFINED)
3795 INFODIR=$infodir
3796 while true; do
3797   case "$INFODIR" in
3798     *\$* ) eval "INFODIR=$INFODIR" ;;
3799     *) break ;;
3800   esac
3801 done
3802 AC_SUBST(INFODIR)
3803
3804 AC_SUBST(infopath)
3805 AC_SUBST(INFOPATH_USER_DEFINED)
3806 INFOPATH=$infopath
3807 while true; do
3808   case "$INFOPATH" in
3809     *\$* ) eval "INFOPATH=$INFOPATH" ;;
3810     *) break ;;
3811   esac
3812 done
3813 AC_SUBST(INFOPATH)
3814
3815 AC_SUBST(package_path)
3816 AC_SUBST(PACKAGE_PATH_USER_DEFINED)
3817 PACKAGE_PATH=$package_path
3818 while true; do
3819   case "$PACKAGE_PATH" in
3820     *\$* ) eval "PACKAGE_PATH=$PACKAGE_PATH" ;;
3821     *) break ;;
3822   esac
3823 done
3824 AC_SUBST(PACKAGE_PATH)
3825
3826 AC_SUBST(lispdir)
3827 AC_SUBST(LISPDIR_USER_DEFINED)
3828 LISPDIR=$lispdir
3829 while true; do
3830   case "$LISPDIR" in
3831     *\$* ) eval "LISPDIR=$LISPDIR" ;;
3832     *) break ;;
3833   esac
3834 done
3835 AC_SUBST(LISPDIR)
3836
3837 AC_SUBST(moduledir)
3838 AC_SUBST(MODULEDIR_USER_DEFINED)
3839 MODULEDIR=$moduledir
3840 while true; do
3841   case "$MODULEDIR" in
3842     *\$* ) eval "MODULEDIR=$MODULEDIR" ;;
3843     *) break ;;
3844   esac
3845 done
3846 AC_SUBST(MODULEDIR)
3847
3848 AC_SUBST(sitelispdir)
3849 AC_SUBST(SITELISPDIR_USER_DEFINED)
3850 SITELISPDIR=$sitelispdir
3851 while true; do
3852   case "$SITELISPDIR" in
3853     *\$* ) eval "SITELISPDIR=$SITELISPDIR" ;;
3854     *) break ;;
3855   esac
3856 done
3857 AC_SUBST(SITELISPDIR)
3858
3859 AC_SUBST(sitemoduledir)
3860 AC_SUBST(SITEMODULEDIR_USER_DEFINED)
3861 SITEMODULEDIR=$sitemoduledir
3862 while true; do
3863   case "$SITEMODULEDIR" in
3864     *\$* ) eval "SITEMODULEDIR=$SITEMODULEDIR" ;;
3865     *) break ;;
3866   esac
3867 done
3868 AC_SUBST(SITEMODULEDIR)
3869
3870 AC_SUBST(etcdir)
3871 AC_SUBST(ETCDIR_USER_DEFINED)
3872 ETCDIR=$etcdir
3873 while true; do
3874   case "$ETCDIR" in
3875     *\$* ) eval "ETCDIR=$ETCDIR" ;;
3876     *) break ;;
3877   esac
3878 done
3879 AC_SUBST(ETCDIR)
3880
3881 AC_SUBST(lockdir)
3882 AC_SUBST(LOCKDIR_USER_DEFINED)
3883 LOCKDIR=$lockdir
3884 while true; do
3885   case "$LOCKDIR" in
3886     *\$* ) eval "LOCKDIR=$LOCKDIR" ;;
3887     *) break ;;
3888   esac
3889 done
3890 AC_SUBST(LOCKDIR)
3891
3892 AC_SUBST(docdir)
3893 AC_SUBST(DOCDIR_USER_DEFINED)
3894 DOCDIR=$docdir
3895 while true; do
3896   case "$DOCDIR" in
3897     *\$* ) eval "DOCDIR=$DOCDIR" ;;
3898     *) break ;;
3899   esac
3900 done
3901 AC_SUBST(DOCDIR)
3902
3903 AC_SUBST(archlibdir)
3904 AC_SUBST(ARCHLIBDIR_USER_DEFINED)
3905 ARCHLIBDIR=$archlibdir
3906 while true; do
3907   case "$ARCHLIBDIR" in
3908     *\$* ) eval "ARCHLIBDIR=$ARCHLIBDIR" ;;
3909     *) break ;;
3910   esac
3911 done
3912 AC_SUBST(ARCHLIBDIR)
3913
3914 AC_SUBST(docdir)
3915 AC_SUBST(bitmapdir)
3916 AC_SUBST(extra_objs)
3917
3918 dnl The following flags combine all the information from:
3919 dnl - command line options (user always gets priority)
3920 dnl - user environment variables
3921 dnl - determined by configure
3922 dnl - the s&m header files (required for ellcc)
3923 AC_SUBST(machfile)
3924 AC_SUBST(opsysfile)
3925 AC_SUBST(c_switch_general)
3926 AC_SUBST(c_switch_window_system)
3927 AC_SUBST(c_switch_all)
3928 AC_SUBST(ld_switch_general)
3929 AC_SUBST(ld_switch_window_system)
3930 AC_SUBST(ld_switch_all)
3931 AC_SUBST(ld_libs_general)
3932 AC_SUBST(ld_libs_window_system)
3933 AC_SUBST(ld_libs_all)
3934 AC_SUBST(CFLAGS)
3935 AC_SUBST(CPPFLAGS)
3936 AC_SUBST(LDFLAGS)
3937 RECURSIVE_MAKE="\$(MAKE) \$(MFLAGS) CC='\$(CC)' CFLAGS='\$(CFLAGS)' LDFLAGS='\$(LDFLAGS)' CPPFLAGS='\$(CPPFLAGS)'"
3938 AC_SUBST(RECURSIVE_MAKE)
3939
3940 AC_SUBST(native_sound_lib)
3941 AC_SUBST(sound_cflags)
3942 AC_SUBST(RANLIB)
3943 AC_SUBST(dynodump_arch)
3944
3945 dnl Preliminary support for using a different compiler for xemacs itself.
3946 dnl Useful for building XEmacs with a C++ or 64-bit compiler.
3947 : ${XEMACS_CC:=$CC}
3948 AC_SUBST(XEMACS_CC)
3949
3950 dnl The default is yes
3951 if test "$with_prefix" = "yes"; then
3952   AC_DEFINE(PREFIX_USER_DEFINED)
3953 fi
3954
3955 dnl The default is no
3956 if test "$with_site_lisp" = "no"; then
3957   AC_DEFINE(INHIBIT_SITE_LISP)
3958 fi
3959 dnl The default is yes
3960 if test "$with_site_modules" = "no"; then
3961   AC_DEFINE(INHIBIT_SITE_MODULES)
3962 fi
3963
3964 XE_SPACE(ac_configure_args, $ac_configure_args)
3965 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "$canonical")
3966 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "$ac_configure_args")
3967 AC_DEFINE_UNQUOTED(config_machfile,  "$machfile")
3968 AC_DEFINE_UNQUOTED(config_opsysfile, "$opsysfile")
3969
3970 dnl Following are deprecated
3971
3972 null_string=""
3973 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE,     $null_string)
3974 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, $null_string)
3975 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,      $null_string)
3976 AC_DEFINE_UNQUOTED(LD_SWITCH_SITE,       $null_string)
3977 AC_DEFINE_UNQUOTED(C_SWITCH_SITE,        $null_string)
3978
3979 dnl Note: as a general rule, *only* define things here that are not
3980 dnl autodetected.  For things that are autodetected, define them
3981 dnl at the point where the autodetection occurs or would occur,
3982 dnl so that the user gets immediate feedback on the results of the
3983 dnl autodetection.
3984
3985 if   test "$GNU_MALLOC"         = "yes"; then AC_DEFINE(GNU_MALLOC)
3986 elif test "$with_system_malloc" = "yes"; then AC_DEFINE(USE_SYSTEM_MALLOC)
3987 elif test "$with_debug_malloc"  = "yes"; then AC_DEFINE(USE_DEBUG_MALLOC)
3988                                               AC_DEFINE(USE_SYSTEM_MALLOC)
3989 fi
3990 test "$with_i18n3"         = "yes" && AC_DEFINE(I18N3)
3991 test "$GCC"                = "yes" && AC_DEFINE(USE_GCC)
3992 test "$external_widget"    = "yes" && AC_DEFINE(EXTERNAL_WIDGET)
3993 test "$no_doc_file"        = "yes" && AC_DEFINE(NO_DOC_FILE)
3994 dnl test "$const_is_losing"    = "yes" && AC_DEFINE(CONST_IS_LOSING)
3995 test "$with_purify"        = "yes" && AC_DEFINE(PURIFY)
3996 test "$with_quantify"      = "yes" && AC_DEFINE(QUANTIFY)
3997 test "$with_pop"           = "yes" && AC_DEFINE(MAIL_USE_POP)
3998 test "$with_kerberos"      = "yes" && AC_DEFINE(KERBEROS)
3999 test "$with_hesiod"        = "yes" && AC_DEFINE(HESIOD)
4000 test "$use_union_type"     = "yes" && AC_DEFINE(USE_UNION_TYPE)
4001
4002 dnl -------------------------------
4003 dnl Report on what we decided to do
4004 dnl -------------------------------
4005
4006 (
4007 dnl /etc/osversion is on SONY NEWS-OS
4008 if test -f /etc/osversion; then dnl SONY NEWS-OS
4009   echo "osversion: `cat /etc/osversion`"
4010 else
4011   echo "uname -a: `uname -a`"
4012 fi
4013 echo ""
4014 echo "$0 $quoted_arguments"
4015 ) > Installation
4016
4017 if test ! -z ${emacs_beta_version} ; then
4018   if test -z "${emacs_is_beta}" ; then
4019         xemacs_betaname=".${emacs_beta_version}"
4020   else
4021         xemacs_betaname="-b${emacs_beta_version}"
4022   fi
4023 else
4024   xemacs_betaname=""
4025 fi
4026
4027 dnl Start stdout redirection to '| tee -a Installation'
4028 (
4029 echo "
4030
4031 XEmacs ${emacs_major_version}.${emacs_minor_version}${xemacs_betaname} \"$xemacs_codename\" configured for \`$canonical'.
4032
4033   Where should the build process find the source code?    $srcdir
4034   What installation prefix should install use?            $prefix
4035   What operating system and machine description files should XEmacs use?
4036         \`$opsysfile' and \`$machfile'
4037   What compiler should XEmacs be built with?              $CC $CFLAGS
4038   Should XEmacs use the GNU version of malloc?            ${GNU_MALLOC}${GNU_MALLOC_reason}
4039   Should XEmacs use the relocating allocator for buffers? $rel_alloc
4040   What window system should XEmacs use?                   ${window_system}"
4041 if test "$with_x11" = "yes"; then
4042   echo "  Where do we find X Windows header files?                $x_includes"
4043   echo "  Where do we find X Windows libraries?                   $x_libraries"
4044 fi
4045 if test -n "$site_includes"; then
4046   echo "  Additional header files:                                $site_includes"
4047 fi
4048 if test -n "$site_libraries"; then
4049   echo "  Additional libraries:                                   $site_libraries"
4050 fi
4051 if test -n "$site_prefixes"; then
4052   echo "  Additional prefixes:                                    $site_prefixes"
4053 fi
4054 if test -n "$runpath"; then
4055   echo "  Runtime library search path:                            $runpath"
4056 fi
4057 test "$with_dnet"  = yes && echo "  Compiling in support for DNET."
4058 test "$with_socks" = yes && echo "  Compiling in support for SOCKS."
4059 test "$with_xauth" = yes && echo "  Compiling in support for XAUTH."
4060 if test "$with_xmu" != yes -a "$with_x11" = yes; then
4061   echo "  No Xmu; substituting equivalent routines."
4062 fi
4063
4064 if test "$with_xpm" = yes; then
4065   echo "  Compiling in support for XPM images."
4066 elif test "$with_x11" = yes; then
4067   echo "  --------------------------------------------------------------------"
4068   echo "  WARNING: Compiling without XPM support."
4069   if test "$xpm_problem" != ""; then
4070     echo "  Reason: $xpm_problem"
4071   fi
4072   echo "  WARNING: You should strongly consider installing XPM."
4073   echo "  WARNING: Otherwise toolbars and other graphics will look suboptimal."
4074   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
4075   echo "  --------------------------------------------------------------------"
4076 fi
4077 if test "$with_png" = yes; then
4078   echo "  Compiling in support for PNG image handling."
4079 elif test "$window_system" != "none"; then
4080   echo "  --------------------------------------------------------------------"
4081   echo "  WARNING: Compiling without PNG image support."
4082   if test "$png_problem" != ""; then
4083     echo "  Reason: $png_problem"
4084   fi
4085   echo "  WARNING: You should strongly consider installing the PNG libraries."
4086   echo "  WARNING: Otherwise certain images and glyphs may not display."
4087   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
4088   echo "  --------------------------------------------------------------------"
4089 fi
4090 test "$with_gif"   = yes && echo "  Compiling in support for (builtin) GIF image handling."
4091 test "$with_jpeg"  = yes && echo "  Compiling in support for JPEG image handling."
4092 test "$with_tiff"  = yes && echo "  Compiling in support for TIFF image handling."
4093 test "$with_xface" = yes && echo "  Compiling in support for X-Face message headers."
4094 case "$with_sound" in
4095   nas    ) echo "  Compiling in network sound (NAS) support." ;;
4096   native ) echo "  Compiling in native sound support." ;;
4097   both   ) echo "  Compiling in both network and native sound support." ;;
4098 esac
4099 test "$old_nas" = yes && echo "        nas library lacks error trapping, will play synchronously."
4100
4101 test "$with_database_berkdb" = yes && echo "  Compiling in support for Berkeley DB."
4102 test "$with_database_dbm"    = yes && echo "  Compiling in support for DBM."
4103 test "$with_database_gnudbm" = yes && echo "  Compiling in support for GNU DBM."
4104
4105 test "$with_ldap"            = yes && echo "  Compiling in support for LDAP."
4106
4107 test "$with_ncurses"  = yes && echo "  Compiling in support for ncurses."
4108 test "$with_gpm"      = yes && echo "  Compiling in support for GPM (General Purpose Mouse)."
4109
4110 test "$with_mule"     = yes && echo "  Compiling in Mule (multi-lingual) support."
4111 test "$with_file_coding"     = yes && echo "  Compiling in File coding support."
4112 test "$with_xim"      != no && echo "  Compiling in XIM (X11R5+ I18N input method) support."
4113 test "$with_xim" = motif    && echo "    Using Motif to provide XIM support."
4114 test "$with_xim" = xlib     && echo "    Using raw Xlib to provide XIM support."
4115 test "$with_xfs" = yes      && echo "    Using XFontSet to provide bilingual menubar."
4116 test "$with_canna"    = yes && echo "  Compiling in support for Canna on Mule."
4117 if test "$with_wnn" = yes; then
4118   echo "  Compiling in support for the WNN input method on Mule."
4119   test "$with_wnn6" = yes && echo "    Using WNN version 6."
4120 fi
4121 test "$with_i18n3"    = yes && echo "  Compiling in I18N support, level 3 (doesn't currently work)."
4122
4123 test "$with_cde"      = yes && echo "  Compiling in support for CDE."
4124 test "$with_tooltalk" = yes && echo "  Compiling in support for ToolTalk."
4125 test "$with_offix"    = yes && echo "  Compiling in support for OffiX."
4126 test "$with_dragndrop" = yes && echo "  Compiling in EXPERIMENTAL support for Drag'n'Drop ($dragndrop_proto )."
4127 test "$with_workshop" = yes && echo "  Compiling in support for Sun WorkShop."
4128 test "$with_wmcommand"  != no && echo "  Compiling in support for proper WM_COMMAND handling."
4129 case "$with_menubars" in
4130   lucid ) echo "  Using Lucid menubars." ;;
4131   motif ) echo "  Using Motif menubars."
4132           echo "  *WARNING*  The Motif menubar implementation is currently buggy."
4133           echo "             We recommend using the Lucid menubar instead."
4134           echo "             Re-run configure with --with-menubars='lucid'." ;;
4135 esac
4136 case "$with_scrollbars" in
4137   lucid    ) echo "  Using Lucid scrollbars."     ;;
4138   motif    ) echo "  Using Motif scrollbars."     ;;
4139   athena   ) echo "  Using Athena scrollbars."    ;;
4140   athena3d ) echo "  Using Athena-3d scrollbars." ;;
4141 esac
4142 case "$with_widgets" in
4143   motif    ) echo "  Using Motif native widgets."     ;;
4144 esac
4145 case "$with_dialogs" in
4146   motif    )
4147     echo "  Using Motif dialog boxes."
4148     if test "$unexec" = "unexaix.o"; then if test "`uname -v`" = 4 -a "`uname -r`" -ge 3; then
4149       echo "  *WARNING*  The Motif dialog boxes cause problems on AIX 4.3 and higher."
4150       echo "             We recommend using the Athena dialog boxes instead."
4151       echo "             Install libXaw and re-run configure with --with-dialogs='athena'."
4152       echo "             Read the PROBLEMS file for more information."
4153     fi; fi
4154     ;;
4155   athena   ) echo "  Using Athena dialog boxes."    ;;
4156   athena3d ) echo "  Using Athena-3d dialog boxes." ;;
4157 esac
4158 test "$with_modules" = "yes" && echo "  Compiling in DSO module support."
4159 test "$with_clash_detection" = yes && \
4160   echo "  Clash detection will use \"$lockdir\" for locking files."
4161 echo "  movemail will use \"$mail_locking\" for locking mail spool files."
4162 test "$with_pop"        = yes && echo "  Using POP for mail access."
4163 test "$with_kerberos"   = yes && echo "  Using Kerberos for POP authentication."
4164 test "$with_hesiod"     = yes && echo "  Using Hesiod to get POP server host."
4165 test "$use_union_type"  = yes && echo "  Using the union type for Lisp_Objects."
4166 test "$debug"              = yes && echo "  Compiling in extra code for debugging."
4167 test "$usage_tracking"     = yes && echo "  Compiling with usage tracking active (Sun internal)."
4168 if test "$error_check_extents $error_check_typecheck $error_check_bufpos $error_check_gc $error_check_malloc" \
4169   != "no no no no no"; then
4170   echo "  WARNING: ---------------------------------------------------------"
4171   echo "  WARNING: Compiling in support for runtime error checking."
4172   echo "  WARNING: XEmacs will run noticeably more slowly as a result."
4173   echo "  WARNING: Error checking is on by default for XEmacs beta releases."
4174   echo "  WARNING: ---------------------------------------------------------"
4175 fi
4176 echo ""
4177 ) | tee -a Installation
4178 dnl echo "The above configure report is appended to \"Installation\" file."
4179 echo ""
4180
4181 dnl -----------------------------------
4182 dnl Now generate config.h and Makefiles
4183 dnl -----------------------------------
4184 dnl This has to be called in order for this variable to get into config.status
4185 AC_SUBST(internal_makefile_list)
4186 # Remove any trailing slashes in these variables.
4187 test -n "$prefix" &&
4188   prefix=`echo '' "$prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
4189 test -n "$exec_prefix" &&
4190   exec_prefix=`echo '' "$exec_prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
4191
4192 dnl Build Makefile.in's from Makefile.in.in's
4193 dnl except ./Makefile from $srcdir/Makefile.in
4194
4195 for file in $internal_makefile_list; do
4196   test "$file" = src/Makefile.in && \
4197     file="src/Makefile.in:src/Makefile.in.in:src/depend"
4198   ac_output_files="${ac_output_files+$ac_output_files }$file"
4199 done
4200 ac_output_files="$ac_output_files src/paths.h lib-src/config.values"
4201 if test "$with_modules" = "yes"; then
4202   ac_output_files="$ac_output_files lib-src/ellcc.h"
4203 fi
4204
4205 AC_OUTPUT($ac_output_files,
4206 [for dir in . $MAKE_SUBDIR; do
4207   (
4208     cd $dir
4209     rm -f junk.c
4210     < Makefile.in \
4211       sed -e '/^# Generated/d' \
4212           -e 's%/\*\*/#.*%%' \
4213           -e 's/^ *# */#/' \
4214 dnl Delete Makefile.in.in comment lines
4215           -e '/^##/d' \
4216 dnl Pass through CPP directives unchanged
4217           -e '/^#/ {
4218 p
4219 d
4220 }'        \
4221 dnl Quote other lines to protect from CPP substitution
4222           -e '/./ {
4223 s/\([[\"]]\)/\\\1/g
4224 s/^/"/
4225 s/$/"/
4226 }'  > junk.c;
4227
4228 dnl Create a GNUmakefile and Makefile from Makefile.in.
4229
4230 changequote(<<,>>)dnl
4231 dnl CPP_MAKEFILE(CPPFLAGS,filename)
4232 define(<<CPP_MAKEFILE>>,
4233 echo creating $dir/<<$2>>
4234 $CPP -I. -I${top_srcdir}/src <<$1>> junk.c \
4235 dnl Delete line directives inserted by $CPP
4236   | sed -e 's/^\#.*//'          \
4237 dnl Delete spurious blanks inserted by $CPP
4238         -e 's/^[ TAB][ TAB]*$//'\
4239         -e 's/^ /TAB/'          \
4240 dnl Delete blank lines
4241   | sed -n -e '/^..*$/p'        \
4242 dnl Restore lines quoted above to original contents.
4243   | sed '/^\"/ {
4244         s/\\\([\"]\)/\1/g
4245         s/^[ TAB]*\"//
4246         s/\"[ TAB]*$//
4247 }' > Makefile.new
4248     chmod 444 Makefile.new
4249     mv -f Makefile.new <<$2>>
4250 )dnl CPP_MAKEFILE
4251
4252     CPP_MAKEFILE(,Makefile)
4253     CPP_MAKEFILE(-DUSE_GNU_MAKE,GNUmakefile)
4254 changequote([,])dnl
4255     rm -f junk.c
4256   )
4257 done
4258
4259 dnl Append AC_DEFINE information to lib-src/config.values
4260 dnl (AC_SUBST information is already there (see config.values.sh).
4261 sed < config.status >> lib-src/config.values \
4262   -e '/{ac_dA}.*{ac_dB}.*{ac_dC}.*{ac_dD}$/!d' \
4263   -e 's/\${ac_dA}\(.*\)\${ac_dB}.*\${ac_dC}\(.*\)\${ac_dD}/\1 \2/' \
4264   -e 's/^\([[^ ]]*\) $/\1 ""/' \
4265   -e 's/ 1$/ t/'
4266
4267 ],
4268 [CPP="$CPP"
4269  top_srcdir="$srcdir"
4270  MAKE_SUBDIR="$MAKE_SUBDIR"
4271 ])dnl