git.chise.org Git - chise/xemacs-chise.git.1/blob - configure.in

   1 dnl Define our own header notice with own copyright
   2 define([AC_INIT_NOTICE],
   3 [#### Configuration script for XEmacs.  Largely divergent from FSF.
   4 #### Guess values for system-dependent variables and create Makefiles.
   5 #### Generated automatically using autoconf version] AC_ACVERSION [
   6 #### Copyright (C) 1992, 93, 94, 95, 96 Free Software Foundation, Inc.
   7 #### Copyright (C) 1993-1995 Board of Trustees, University of Illinois.
   8 #### Copyright (C) 1996, 1997 Sun Microsystems, Inc.
   9 #### Copyright (C) 1995, 1996 Ben Wing.
  10 #### Copyright (C) 1998, 1999 J. Kean Johnston.
  11
  12 ### Don't edit this script!
  13 ### This script was automatically generated by the `autoconf' program
  14 ### from the file `./configure.in'.
  15 ### To rebuild it, execute the command
  16 ###     autoconf
  17 ### in the this directory.  You must have autoconf version 2.12 or later.
  18
  19 ### This file is part of XEmacs.
  20
  21 ### XEmacs is free software; you can redistribute it and/or modify it
  22 ### under the terms of the GNU General Public License as published by
  23 ### the Free Software Foundation; either version 2, or (at your
  24 ### option) any later version.
  25
  26 ### XEmacs is distributed in the hope that it will be useful, but
  27 ### WITHOUT ANY WARRANTY; without even the implied warranty of
  28 ### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  29 ### General Public License for more details.
  30
  31 ### You should have received a copy of the GNU General Public License
  32 ### along with XEmacs; see the file COPYING.  If not, write to the Free
  33 ### Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  34 ### 02111-1307, USA.
  35
  36 ### For usage, run `./configure --help'
  37 ### For more detailed information on building and installing XEmacs,
  38 ### read the file `INSTALL'.
  39 ###
  40 ### If configure succeeds, it leaves its status in config.status.
  41 ### A log of configuration tests can be found in config.log.
  42 ### If configure fails after disturbing the status quo,
  43 ###     config.status is removed.
  44 ])
  45
  46 dnl Since XEmacs has configuration requirements that autoconf cannot
  47 dnl meet, this file is an unholy marriage of custom-baked
  48 dnl configuration code and autoconf macros.
  49
  50 dnl We use the m4 quoting characters [ ] (as established by the
  51 dnl autoconf system), so quote them like this: [[foo]]
  52
  53 AC_PREREQ(2.12)dnl
  54 dnl Redefine some standard autoconf macros
  55 dnl here is how XEmacs is different:
  56 dnl - no cache file
  57 dnl - non-standard options
  58 dnl - suport for extra-verbosity
  59 dnl - ordinary libs are handled separately from X libs (might be a mistake)
  60 dnl - various random kludges (e.g. -with-dnet=no
  61
  62 dnl PRINT_VAR(var var ...)  prints values of shell variables
  63 define([PRINT_VAR],[for var in patsubst([$1],[[
  64 ]+],[ ]); do eval "echo \"$var = '\$$var'\""; done])
  65
  66 dnl Disable cache files:
  67 dnl This is controversial, but I am convinced this is the right way to go,
  68 dnl at least by default.  Otherwise there are too many surprises.
  69 define([AC_CACHE_LOAD], )dnl
  70 define([AC_CACHE_SAVE], )dnl
  71 define([AC_CACHE_VAL], [
  72 $2
  73 ])dnl
  74
  75 dnl Redefine AC_TRY_RUN_NATIVE to not throw away stderr while running
  76 dnl AC_TRY_RUN_NATIVE(PROGRAM, [ACTION-IF-TRUE [, ACTION-IF-FALSE]])
  77 define([AC_TRY_RUN_NATIVE],
  78 [cat > conftest.$ac_ext <<EOF
  79 [#]line __oline__ "configure"
  80 #include "confdefs.h"
  81 [$1]
  82 EOF
  83 if AC_TRY_EVAL(ac_link) && test -s conftest && (./conftest; exit $?) 2>&AC_FD_CC
  84 then
  85 dnl Do not remove the temporary files here, so they can be examined.
  86   ifelse([$2], , :, [$2])
  87 else
  88   conftest_rc="$?"
  89   echo "configure: failed program was:" >&AC_FD_CC
  90   cat conftest.$ac_ext >&AC_FD_CC
  91 ifelse([$3], , , [  rm -fr conftest*
  92   $3
  93 ])dnl
  94 fi
  95 rm -fr conftest*])dnl AC_TRY_RUN_NATIVE
  96
  97
  98 dnl Avoid spurious cross-compiling warnings from AC_TRY_RUN
  99 dnl XEmacs is unlikely to ever cross-compile
 100 define([AC_TRY_RUN],[AC_TRY_RUN_NATIVE([$1], [$2], [$3])])dnl
 101
 102 dnl Redefine AC_DEFINE* to provide more output if extra_verbose
 103 dnl Set VARIABLE to VALUE, verbatim, or 1.
 104 dnl AC_DEFINE(VARIABLE [, VALUE])
 105 define([AC_DEFINE],
 106 [{ test "$extra_verbose" = "yes" && cat << \EOF
 107     Defining $1[]ifelse($#, 2, [ = $2],)
 108 EOF
 109 cat >> confdefs.h <<\EOF
 110 [#define] $1 ifelse($#, 2, [$2], 1)
 111 EOF
 112 }
 113 ])dnl AC_DEFINE
 114
 115 define([AC_DEFINE_UNQUOTED],
 116 [{ test "$extra_verbose" = "yes" && cat << EOF
 117     Defining $1[]ifelse($#, 2, [ = $2],)
 118 EOF
 119 cat >> confdefs.h <<EOF
 120 [#define] $1 ifelse($#, 2, [$2], 1)
 121 EOF
 122 }
 123 ])dnl AC_DEFINE_UNQUOTED
 124
 125 dnl redefine AC_CHECK_LIB in accordance with our own value of ac_link
 126 dnl Add in extra kludgy check to support with_dnet=no
 127 dnl Add in extra LDFLAGS arg, which PRECEDE libs
 128 dnl Support --with-dnet=no
 129
 130 dnl AC_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND
 131 dnl             [, OTHER-LIBRARIES] [, LDFLAGS]]]])
 132 define([AC_CHECK_LIB],
 133 [ifelse([$1],dnet, [if test "$with_dnet" = "no" ; then
 134 ac_cv_lib_dnet_dnet_ntoa=no
 135 ifelse([$4], , , [$4]
 136 )dnl
 137 else
 138 ])]
 139 AC_CHECK_LIB_ORIG_HACKED([$1],[$2],[$3],[$4],[$5], [$6])
 140 [ifelse([$1],dnet,[fi
 141 ])]dnl
 142 )dnl AC_CHECK_LIB
 143
 144 define([AC_CHECK_LIB_ORIG_HACKED],
 145 [ifelse([$5],,AC_MSG_CHECKING([for $2 in -l$1]),
 146 xe_msg_checking="for [$2] in -l[$1]"
 147 test -n "[$5]" && xe_msg_checking="$xe_msg_checking using extra libs [$5]"
 148 AC_MSG_CHECKING("$xe_msg_checking"))
 149 dnl Use a cache variable name containing both the library and function name,
 150 dnl because the test really is for library $1 defining function $2, not
 151 dnl just for library $1.  Separate tests with the same $1 and different $2s
 152 dnl may have different results.
 153 ac_lib_var=`echo $1['_']$2 | sed 'y%./+-%__p_%'`
 154 AC_CACHE_VAL(ac_cv_lib_$ac_lib_var,
 155 [xe_check_libs="$6 -l$1 $5"
 156 AC_TRY_LINK(dnl
 157 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
 158 [/* Override any gcc2 internal prototype to avoid an error.  */
 159 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
 160 extern "C"
 161 #endif
 162 ])dnl
 163 [/* We use char because int might match the return type of a gcc2
 164     builtin and then its argument prototype would still apply.  */
 165 char $2();
 166 ]),
 167             [$2()],
 168             eval "ac_cv_lib_$ac_lib_var=yes",
 169             eval "ac_cv_lib_$ac_lib_var=no")
 170 xe_check_libs=""
 171 ])dnl
 172 if eval "test \"`echo '$ac_cv_lib_'$ac_lib_var`\" = yes" ; then
 173   AC_MSG_RESULT(yes)
 174   ifelse([$3], ,
 175 [changequote(, )dnl
 176   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
 177     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
 178 changequote([, ])dnl
 179   AC_DEFINE_UNQUOTED($ac_tr_lib)
 180   XE_PREPEND([-l$1], LIBS)
 181 ], [$3])
 182 else
 183   AC_MSG_RESULT(no)
 184 ifelse([$4], , , [$4
 185 ])dnl
 186 fi
 187 ])dnl AC_CHECK_LIB_ORIG_HACKED
 188
 189
 190 dnl AC_LANG_C()
 191 define([AC_LANG_C],
 192 [define([AC_LANG], [C])dnl
 193 ac_ext=c
 194 dnl CFLAGS is not in ac_cpp because -g, -O, etc. are not valid cpp options.
 195 dnl ac_cpp='$CPP $CPPFLAGS'
 196 dnl ac_compile='${CC-cc} -c $CFLAGS $CPPFLAGS conftest.$ac_ext 1>&AC_FD_CC'
 197 dnl ac_link='${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS conftest.$ac_ext $LIBS 1>&AC_FD_CC'
 198 xe_cppflags='$CPPFLAGS $c_switch_site $c_switch_machine $c_switch_system $c_switch_x_site $X_CFLAGS'
 199 xe_ldflags='$LDFLAGS $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_x_site $ld_switch_run'
 200 xe_libs='$ld_call_shared $xe_check_libs $X_EXTRA_LIBS $libs_x $X_PRE_LIBS $LIBS $libs_machine $libs_system $libs_standard'
 201 ac_cpp='$CPP '"$xe_cppflags"
 202 ac_compile='${CC-cc} -c $CFLAGS '"$xe_cppflags"' conftest.$ac_ext 1>&AC_FD_CC'
 203 ac_link='${CC-cc} -o conftest $CFLAGS '"$xe_cppflags $xe_ldflags"' conftest.$ac_ext '"$xe_libs"' 1>&AC_FD_CC'
 204 cross_compiling=no
 205 ]) dnl AC_LANG_C
 206
 207 dnl The construct foo=`echo $w1 $w2 $w3` fails on some systems if $w1 = -e or -n
 208 dnl So we use the following instead.
 209 dnl XE_SPACE(var, words)
 210 define([XE_SPACE],[
 211 T=""
 212 for W in $2; do if test -z "$T"; then T="$W"; else T="$T $W"; fi; done
 213 $1="$T"
 214 ])dnl XE_SPACE
 215
 216 dnl XE_ADD_OBJS(foo.o ...)
 217 define([XE_ADD_OBJS],
 218 [extra_objs="$extra_objs [$1]" && dnl
 219  if test "$extra_verbose" = "yes"; then
 220    echo "    xemacs will be linked with \"[$1]\""
 221  fi])dnl XE_ADD_OBJS
 222
 223 dnl XE_APPEND(value, varname)
 224 define([XE_APPEND],
 225 [[$2]="$[$2] [$1]" && dnl
 226  if test "$extra_verbose" = "yes"; then echo "    Appending \"[$1]\" to \$[$2]"; fi])
 227
 228 dnl XE_PREPEND(value, varname)
 229 define([XE_PREPEND],
 230 [[$2]="[$1] $[$2]" && dnl
 231  if test "$extra_verbose" = "yes"; then echo "    Prepending \"[$1]\" to \$[$2]"; fi])
 232
 233 dnl XE_DIE(message)
 234 define([XE_DIE], [{ echo "Error:" $1 >&2; exit 1; }])
 235
 236 dnl XE_STRIP_4TH_COMPONENT(var)
 237 dnl Changes i986-pc-linux-gnu to i986-pc-linux, as God (not RMS) intended.
 238 define([XE_STRIP_4TH_COMPONENT],
 239 [$1=`echo "$$1" | sed '[s/^\([^-][^-]*-[^-][^-]*-[^-][^-]*\)-.*$/\1/]'`])
 240
 241 dnl Initialize some variables set by options.
 242 dnl The variables have the same names as the options, with
 243 dnl dashes changed to underlines.
 244
 245 define([AC_INIT_PARSE_ARGS],[
 246
 247 dnl Get sane consistent behavior from various shells
 248 dnl Avoid losing with weird user CDPATHs
 249
 250 if test -n "$ZSH_VERSION"; then
 251   dnl zsh's Bourne shell emulation options
 252   setopt NO_BAD_PATTERN NO_BANG_HIST NO_BG_NICE NO_EQUALS NO_FUNCTION_ARGZERO
 253   setopt GLOB_SUBST NO_HUP INTERACTIVE_COMMENTS KSH_ARRAYS NO_MULTIOS NO_NOMATCH
 254   setopt RM_STAR_SILENT POSIX_BUILTINS SH_FILE_EXPANSION SH_GLOB SH_OPTION_LETTERS
 255   setopt SH_WORD_SPLIT BSD_ECHO IGNORE_BRACES
 256   dnl zsh-3.1-beta drops core on the following
 257   dnl unset CDPATH
 258   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
 259 elif test -n "$BASH_VERSION"; then
 260   dnl Use Posix mode with bash
 261   set -o posix
 262   unset CDPATH
 263 else
 264   if test -n "$CDPATH"; then CDPATH="."; export CDPATH; fi
 265 fi
 266
 267 dnl Initialize some variables set by options.
 268 dnl The variables have the same names as the options, with
 269 dnl dashes changed to underlines.
 270 exec_prefix=NONE
 271 host=NONE
 272 no_create=
 273 nonopt=NONE
 274 no_recursion=
 275 prefix=NONE
 276 program_prefix=NONE
 277 program_suffix=NONE
 278 program_transform_name=s,x,x,
 279 silent=
 280 site=
 281 srcdir=
 282 target=NONE
 283 verbose=
 284 x_includes=NONE
 285 x_libraries=NONE
 286
 287 dnl Installation directory options.
 288 dnl These are left unexpanded so users can "make install exec_prefix=/foo"
 289 dnl and all the variables that are supposed to be based on exec_prefix
 290 dnl by default will actually change.
 291 dnl Use braces instead of parens because sh, perl, etc. also accept them.
 292 dnl If you change these, you need to synchronize with the settings of the
 293 dnl various ..._USER_DEFINED variables further down.
 294 bindir='${exec_prefix}/bin'
 295 sbindir='${exec_prefix}/sbin'
 296 libexecdir='${exec_prefix}/libexec'
 297 datadir='${prefix}/share'
 298 sysconfdir='${prefix}/etc'
 299 sharedstatedir='${prefix}/com'
 300 localstatedir='${prefix}/var'
 301 libdir='${{exec_prefix}}/lib'
 302 includedir='${prefix}/include'
 303 oldincludedir='/usr/include'
 304 infodir='${prefix}/info'
 305 mandir='${prefix}/man'
 306
 307 dnl Initialize some other variables.
 308 subdirs=
 309 MFLAGS= MAKEFLAGS=
 310 dnl Maximum number of lines to put in a shell here document.
 311 ac_max_here_lines=12
 312 ])dnl AC_INIT_PARSE_ARGS
 313
 314 AC_INIT(src/lisp.h)dnl
 315 AC_CONFIG_HEADER(src/config.h lwlib/config.h)
 316 dnl Remove any more than one leading "." element from the path name.
 317 dnl If we do not remove them, then another "./" will be prepended to
 318 dnl the file name each time we use config.status, and the program name
 319 dnl will get larger and larger.  This would not be a problem, except
 320 dnl that since progname gets recorded in all the Makefiles this script
 321 dnl produces, move-if-change thinks they're different when they're
 322 dnl not.
 323 dnl
 324 dnl It would be nice if we could put the ./ in a \( \) group and then
 325 dnl apply the * operator to that, so we remove as many leading './././'s
 326 dnl as are present, but some seds (like Ultrix's sed) don't allow you to
 327 dnl apply * to a \( \) group.  Bleah.
 328 progname="`echo $0 | sed 's:^\./\./:\./:'`"
 329
 330 dnl -----------------------------
 331 dnl Establish some default values
 332 dnl -----------------------------
 333
 334 XE_APPEND(lib-src, MAKE_SUBDIR)
 335 XE_APPEND(lib-src, INSTALL_ARCH_DEP_SUBDIR)
 336
 337 prefix='/usr/local'
 338 exec_prefix='${prefix}'
 339 bindir='${exec_prefix}/bin'
 340 dnl FSF 19.29 changes to:
 341 dnl datadir='${prefix}/share'
 342 dnl sharedstatedir='${prefix}/com'
 343 dnl libexecdir='${exec_prefix}/libexec'
 344 datadir='${prefix}/lib'
 345 statedir='${prefix}/lib'
 346 libdir='${exec_prefix}/lib'
 347 mandir='${prefix}/man/man1'
 348 infodir='${datadir}/${PROGNAME}-${version}/info'
 349 infopath=''
 350 install_pp=''
 351 lispdir='${datadir}/${PROGNAME}-${version}/lisp'
 352 moduledir='${datadir}/${PROGNAME}-${version}/${configuration}/modules'
 353 sitelispdir='${datadir}/xemacs/site-lisp'
 354 sitemoduledir='${datadir}/xemacs/site-modules'
 355 pkgdir='${datadir}/${PROGNAME}-${version}/lisp'
 356 package_path=''
 357 etcdir='${datadir}/${PROGNAME}-${version}/etc'
 358 lockdir='${statedir}/${PROGNAME}/lock'
 359 archlibdir='${datadir}/${PROGNAME}-${version}/${configuration}'
 360 with_site_lisp='no'
 361 with_site_modules='yes'
 362 with_menubars=''
 363 with_scrollbars=''
 364 with_dialogs=''
 365 with_file_coding=''
 366 dnl const_is_losing is removed - we rely on AC_C_CONST instead.
 367 dnl We accept (and ignore) the --const-is-losing option for compatibility.
 368 dnl const_is_losing='yes'
 369 cpp='' cppflags='' libs='' ldflags=''
 370 dynamic=''
 371 with_x11=''
 372 with_msw=''
 373 rel_alloc='default'
 374 with_system_malloc='default'
 375 with_dlmalloc='default'
 376 native_sound_lib=''
 377 dnl use_assertions should be 'yes' by default.  Too many people in this
 378 dnl world have core dumps turned off by default or \"cannot find where the
 379 dnl core file went\".  At least we should get some useful output ...
 380 use_assertions="yes"
 381 dnl the following is set to yes or no later.
 382 with_toolbars=""
 383 with_tty=""
 384 use_union_type="no"
 385 with_dnet=""
 386
 387 dnl ------------------
 388 dnl Options Processing
 389 dnl ------------------
 390
 391 define([USAGE_ERROR],
 392 [(echo "$progname: Usage error:"
 393 echo " " $1
 394 echo "  Use \`$progname --help' to show usage.") >&2 && exit 1])
 395
 396 dnl Record all the arguments, so we can save them in config.status.
 397 arguments="$@"
 398
 399 dnl Shell Magic: Quote the quoted arguments in ARGUMENTS.  At a later date,
 400 dnl in order to get the arguments back in $@, we have to do an
 401 dnl 'eval set x "$quoted_arguments"; shift'
 402 dnl # We use sed to turn embedded ' into '"'"'.  I truly hate sh quoting.
 403 quoted_sed_magic=s/"'"/"'"'"'"'"'"'"'"/g
 404 quoted_arguments=
 405 for i in "$@"; do
 406    case "$i" in
 407    -no-create | --no-create | --no-creat | --no-crea | --no-cre \
 408    | --no-cr | --no-c) ;;
 409    -no-recursion | --no-recursion | --no-recursio | --no-recursi \
 410    | --no-recurs | --no-recur | --no-recu | --no-rec | --no-re | --no-r) ;;
 411    *)
 412    quoted_i="`echo '' $i | sed -e 's:^ ::' -e $quoted_sed_magic`"
 413    quoted_arguments="$quoted_arguments '$quoted_i'" ;;
 414    esac
 415 done
 416
 417 dnl Do not use shift -- that destroys the argument list, which autoconf needs
 418 dnl to produce config.status.  It turns out that "set - $arguments" does not
 419 dnl work portably.
 420 dnl However, it also turns out that many shells cannot expand ${10} at all.
 421 dnl So using an index variable does not work either.  It is possible to use
 422 dnl some shell magic to make 'set x "$arguments"; shift' work portably.
 423 while test $# != 0; do
 424   arg="$1"; shift
 425   case "$arg" in
 426     --no-create|--no-recursion) ;;
 427     dnl Anything starting with a hyphen we assume is an option.
 428     -* )
 429       dnl Separate the switch name from the value it is being given.
 430       case "$arg" in
 431         -*=*)
 432           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\([[^=]]*\)=.*$:\1:'`
 433           val=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*[[^=]]*=\(.*\)$:\1:'`
 434           valomitted=no
 435         ;;
 436            dnl special case these strings since echo may silently eat them:
 437            dnl --help ) opt=help val=yes valomitted=yes ;;
 438            dnl --version ) opt=version val=yes valomitted=yes ;;
 439            dnl -e ) opt=e val=yes valomitted=yes ;;
 440            dnl -E ) opt=E val=yes valomitted=yes ;;
 441            dnl -n ) opt=n val=yes valomitted=yes ;;
 442         -*)
 443            dnl If FOO is a boolean argument, --FOO is equivalent to
 444            dnl --FOO=yes.  Otherwise, the value comes from the next
 445            dnl argument - see below.
 446           opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\(.*\)$:\1:'`
 447           val="yes" valomitted=yes
 448         ;;
 449       esac
 450
 451       dnl translate "-" in option string to "_"
 452       optname="$opt"
 453       opt="`echo '' $opt | sed -e 's:^ ::' | tr - _`"
 454
 455       dnl Support --without-FOO as a synonym for --with-FOO=no
 456       case "${valomitted}-${opt}" in yes-without_* )
 457         opt=`echo $opt | sed 's/without/with/'`
 458         valomitted="no" val="no" ;;
 459       esac
 460
 461       dnl Process the option.
 462       case "$opt" in
 463
 464       dnl Process (many) boolean options
 465         with_site_lisp  | \
 466     with_site_modules | \
 467         with_x          | \
 468         with_x11        | \
 469         with_msw        | \
 470         with_gcc        | \
 471         dynamic         | \
 472         with_ncurses    | \
 473         with_dnet       | \
 474         with_socks      | \
 475         with_dragndrop  | \
 476         with_cde        | \
 477         with_offix      | \
 478         with_gpm        | \
 479         with_xpm        | \
 480         with_xface      | \
 481         with_gif        | \
 482         with_jpeg       | \
 483         with_png        | \
 484         with_tiff       | \
 485         with_session    | \
 486         with_xmu        | \
 487         with_purify     | \
 488         with_quantify   | \
 489         with_toolbars   | \
 490         with_tty        | \
 491         with_xfs        | \
 492         with_i18n3      | \
 493         with_mule       | \
 494         with_file_coding| \
 495         with_canna      | \
 496         with_wnn        | \
 497         with_wnn6       | \
 498         with_workshop   | \
 499         with_sparcworks | \
 500         with_tooltalk   | \
 501         with_ldap       | \
 502         with_pop        | \
 503         with_kerberos   | \
 504         with_hesiod     | \
 505         with_dnet       | \
 506         with_infodock   | \
 507         external_widget | \
 508         verbose         | \
 509         extra_verbose   | \
 510         const_is_losing | \
 511         usage_tracking  | \
 512         use_union_type  | \
 513         debug           | \
 514         use_assertions  | \
 515         memory_usage_stats | \
 516         with_clash_detection | \
 517         with_shlib | \
 518         no_doc_file )
 519           dnl Make sure the value given was either "yes" or "no".
 520           case "$val" in
 521             y | ye | yes )      val=yes ;;
 522             n | no )            val=no  ;;
 523             * ) USAGE_ERROR("The \`--$optname' option requires a boolean value: \`yes' or \`no'.") ;;
 524           esac
 525           eval "$opt=\"$val\"" ;;
 526
 527
 528         dnl Options that take a user-supplied value, as in --x-includes=/usr/X11R6/include
 529         dnl The cache-file option is ignored (for compatibility with other configures)
 530         srcdir          | \
 531         compiler        | \
 532         cflags          | \
 533         cpp             | \
 534         cppflags        | \
 535         libs            | \
 536         ldflags         | \
 537         cache_file      | \
 538         native_sound_lib| \
 539         site_lisp       | \
 540         x_includes      | \
 541         x_libraries     | \
 542         site_includes   | \
 543         site_libraries  | \
 544         site_prefixes   | \
 545         site_runtime_libraries )
 546           dnl If the value was omitted, get it from the next argument.
 547           if test "$valomitted" = "yes" ; then
 548             dnl Get the next argument from the argument list, if there is one.
 549             if test "$#" = 0 ; then
 550               USAGE_ERROR("The \`--$optname' option requires a value.");
 551             fi
 552             val="$1"; shift
 553           fi
 554           eval "$opt=\"$val\""
 555         ;;
 556
 557         dnl Options that take "yes", "no", or "default" values
 558         rel_alloc | \
 559         with_dlmalloc | \
 560         with_debug_malloc  | use_debug_malloc | \
 561         with_system_malloc | use_system_malloc )
 562           case "$val" in
 563             y | ye | yes )      val=yes ;;
 564             n | no )            val=no  ;;
 565             d | de | def | defa | defau | defaul | default ) val=default ;;
 566             * ) USAGE_ERROR(["The \`--$optname' option requires one of these values:
 567   \`yes', \`no', or \`default'."]) ;;
 568           esac
 569           case "$opt" in use_* ) opt="`echo $opt | sed s/use/with/`" ;; esac
 570           eval "$opt=\"$val\""
 571         ;;
 572
 573         dnl Has the user requested database support?
 574         "with_database" )
 575           with_database_berkdb=no
 576           with_database_dbm=no
 577           with_database_gnudbm=no
 578           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 579             case "$x" in
 580                 no ) ;;
 581                 b | be | ber | berk | berkd | berkdb )  with_database_berkdb=yes ;;
 582                 d | db | dbm )                          with_database_dbm=yes    ;;
 583                 g | gn | gnu | gnud | gnudb | gnudbm )  with_database_gnudbm=yes ;;
 584                 * ) USAGE_ERROR(["The \`--$optname' option value
 585   must be either \`no' or a comma-separated list
 586   of one or more of \`berkdb' and either \`dbm' or \`gnudbm'."]) ;;
 587             esac
 588           done
 589           if test "$with_database_dbm"    = "yes" -a \
 590                   "$with_database_gnudbm" = "yes"; then
 591           USAGE_ERROR("Only one of \`dbm' and \`gnudbm' may be specified
 592   with the \`--$optname' option.")
 593           fi
 594         ;;
 595
 596         dnl Has the user requested sound support?
 597         "with_sound" )
 598           dnl value can be native, nas or both. yes is allowed
 599           dnl as a backwards compatible synonym for native
 600           case "$val" in
 601             y | ye | yes )                      val=native ;;
 602             n | no | non | none )               val=no;;
 603             na | nat | nati | nativ | native )  val=native  ;;
 604             ne | net | neta | netau | netaud | netaudi | netaudio | nas ) val=nas  ;;
 605             b | bo | bot | both )               val=both;;
 606             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 607   \`native', \`nas', \`both', or \`none'."]) ;;
 608           esac
 609           eval "$opt=\"$val\""
 610         ;;
 611
 612         dnl Has the user requested XIM support?
 613         "with_xim" )
 614           case "$val" in
 615             y | ye | yes )                val=yes   ;;
 616             n | no | non | none )         val=no    ;;
 617             x | xl | xli | xlib )         val=xlib  ;;
 618             m | mo | mot | moti | motif ) val=motif ;;
 619             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 620   \`motif', \`xlib', \`yes', or \`no'."]) ;;
 621           esac
 622           eval "$opt=\"$val\""
 623         ;;
 624
 625         dnl Mail locking specification
 626         "mail_locking" )
 627           case "$val" in
 628             lockf )     val=lockf ;;
 629             flock )     val=flock ;;
 630             file )      val=file  ;;
 631             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 632   \`lockf', \`flock', or \`file'."]) ;;
 633           esac
 634           eval "$opt=\"$val\""
 635         ;;
 636
 637         dnl Has the user requested error-checking?
 638         "error_checking" )
 639           dnl value can be all, none, and/or a list of categories to check.
 640           dnl Example: --error-checking=all,noextents,nobufpos
 641           dnl Example: --error-checking=none,malloc,gc
 642
 643           for x in `echo "$val" | sed -e 's/,/ /g'` ; do
 644             case "$x" in
 645               dnl all and none are only permitted as the first in the list.
 646               n | no | non | none ) new_default=no ;;
 647               a | al | all )        new_default=yes ;;
 648
 649               extents )       error_check_extents=yes ;;
 650               noextents )     error_check_extents=no ;;
 651
 652               typecheck )     error_check_typecheck=yes ;;
 653               notypecheck )   error_check_typecheck=no ;;
 654
 655               bufpos )        error_check_bufpos=yes ;;
 656               nobufpos )      error_check_bufpos=no ;;
 657
 658               gc )            error_check_gc=yes ;;
 659               nogc )          error_check_gc=no ;;
 660
 661               malloc )        error_check_malloc=yes ;;
 662               nomalloc )      error_check_malloc=no ;;
 663
 664               * ) bogus_error_check=yes ;;
 665             esac
 666             if test "$bogus_error_check" -o \
 667                  \( -n "$new_default" -a -n "$echeck_notfirst" \) ; then
 668                 if test "$error_check_default" = yes ; then
 669                   types="\`all' (default), \`none', \`noextents', \`notypecheck', \`nobufpos', \`nogc', and \`nomalloc'."
 670                 else
 671                   types="\`all', \`none' (default), \`extents', \`typecheck', \`bufpos', \`gc', and \`malloc'."
 672                 fi
 673                 USAGE_ERROR(["Valid types for the \`--$optname' option are:
 674   $types."])
 675             elif test -n "$new_default" ; then
 676                 error_check_extents=$new_default
 677                 error_check_typecheck=$new_default
 678                 error_check_bufpos=$new_default
 679                 error_check_gc=$new_default
 680                 error_check_malloc=$new_default
 681                 new_default=    # reset this
 682             fi
 683             echeck_notfirst=true
 684           done
 685         ;;
 686
 687         dnl Has the user tried to tell us where the X files are?
 688         dnl I think these are dopey, but no less than three alpha
 689         dnl testers, at large sites, have said they have their X files
 690         dnl installed in odd places.
 691
 692         dnl Has the user specified one of the path options?
 693         prefix | exec_prefix | bindir | datadir | statedir | libdir | \
 694         mandir | infodir | infopath | lispdir | etcdir | lockdir | pkgdir | \
 695         archlibdir | docdir | package_path )
 696            dnl If the value was omitted, get it from the next argument.
 697            if test "$valomitted" = "yes"; then
 698              if test "$#" = 0; then
 699                  USAGE_ERROR("The \`--$optname' option requires a value.");
 700              fi
 701              val="$1"; shift
 702            fi
 703            eval "$opt=\"$val\""
 704
 705            dnl You need to synchronize this with the way the
 706            dnl default values are built.
 707            case "$opt" in
 708              lispdir ) AC_DEFINE(LISPDIR_USER_DEFINED) ;;
 709              sitelispdir ) AC_DEFINE(SITELISPDIR_USER_DEFINED) ;;
 710              moduledir ) AC_DEFINE(MODULEDIR_USER_DEFINED) ;;
 711              etcdir  )  AC_DEFINE(ETCDIR_USER_DEFINED) ;;
 712              infodir ) AC_DEFINE(INFODIR_USER_DEFINED) ;;
 713              infopath ) AC_DEFINE(INFOPATH_USER_DEFINED) ;;
 714              package_path ) AC_DEFINE(PACKAGE_PATH_USER_DEFINED) ;;
 715              datadir )
 716                 AC_DEFINE(INFODIR_USER_DEFINED)
 717                 AC_DEFINE(LISPDIR_USER_DEFINED)
 718             AC_DEFINE(MODULEDIR_USER_DEFINED)
 719                 AC_DEFINE(ETCDIR_USER_DEFINED) ;;
 720              statedir | lockdir ) AC_DEFINE(LOCKDIR_USER_DEFINED) ;;
 721              exec_prefix | libdir | archlibdir ) AC_DEFINE(ARCHLIBDIR_USER_DEFINED) ;;
 722            esac
 723         ;;
 724
 725         dnl --no-create added by autoconf for use by config.status
 726         "no_create" ) ;;
 727
 728         dnl Has the user asked for some help?
 729         "usage" | "help" ) ${PAGER-more} ${srcdir}/configure.usage; exit 0 ;;
 730
 731         dnl Has the user specified the toolkit(s) to use for GUI elements?
 732         "with_menubars"   | \
 733         "with_scrollbars" | \
 734         "with_dialogs" )
 735           case "$val" in
 736             l | lu | luc | luci | lucid )               val=lucid  ;;
 737             m | mo | mot | moti | motif )               val=motif  ;;
 738             athena3d | athena-3d )                      val=athena3d ;;
 739             a | at | ath | athe | athen | athena )      val=athena ;;
 740             n | no | non | none )                       val=no ;;
 741             * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
 742   \`lucid', \`motif', \`athena', \`athena3d', or \`no'."]) ;;
 743           esac
 744           eval "$opt=\"$val\""
 745         ;;
 746
 747         dnl Obsolete legacy argument?  Warn, but otherwise ignore.
 748         "run_in_place"  | \
 749         "with_gnu_make" )
 750           AC_MSG_WARN([Obsolete option \`--$optname' ignored.])
 751         ;;
 752
 753         dnl Unrecognized option?  No mercy for user errors.
 754         * ) USAGE_ERROR("Unrecognized option: $arg") ;;
 755
 756       esac
 757     ;;
 758
 759     dnl Assume anything with multiple hyphens is a configuration name.
 760     *-*-*) configuration="$arg" ;;
 761
 762     dnl Unrecognized argument?  No mercy for user errors.
 763     *) USAGE_ERROR("Unrecognized argument: $arg") ;;
 764
 765   esac
 766 done
 767
 768 dnl -------------------------
 769 dnl Finish options processing
 770 dnl -------------------------
 771
 772 dnl Several options are equivalent to, and override, environment variables.
 773 test -n "$cpp"      && CPP="$cpp"
 774 test -n "$cppflags" && CPPFLAGS="$cppflags"
 775 test -n "$libs"     && LIBS="$libs"
 776 test -n "$ldflags"  && LDFLAGS="$ldflags"
 777
 778 dnl Get the arguments back.  See the diatribe on Shell Magic above.
 779 eval set x "$quoted_arguments"; shift
 780
 781 dnl --extra-verbose implies --verbose
 782 test "$extra_verbose" = "yes" && verbose=yes
 783
 784 dnl with_x is an obsolete synonym for with_x11
 785 test -n "$with_x" && with_x11="$with_x"
 786
 787 dnl --with-quantify or --with-purify imply --use-system-malloc
 788 if test "$with_purify" = "yes" -o "$with_quantify" = "yes"; then
 789   test "$with_system_malloc" = "default" && with_system_malloc=yes
 790 fi
 791
 792 dnl XE_CHECK_FEATURE_DEPENDENCY(feature1, feature2)
 793 define([XE_CHECK_FEATURE_DEPENDENCY],
 794 [if test "$with_$1 $with_$2" = "yes no"; then
 795   USAGE_ERROR("--with-$1 requires --with-$2")
 796 elif test "$with_$2" = "no" ; then with_$1=no
 797 elif test "$with_$1" = "yes"; then with_$2=yes
 798 fi
 799 ])
 800
 801 dnl CDE requires tooltalk
 802 XE_CHECK_FEATURE_DEPENDENCY(cde, tooltalk)
 803
 804 dnl Find the source directory.
 805 case "$srcdir" in
 806
 807   dnl If srcdir is not specified, see if  "." or ".." might work.
 808   "" )
 809     for dir in "`echo $0 | sed 's|//|/|' | sed 's|/[[^/]]*$||'`" "." ".." ; do
 810       if test -f "$dir/src/lisp.h" -a \
 811               -f "$dir/lisp/version.el" ; then
 812         srcdir="$dir"
 813         break
 814       fi
 815     done
 816     if test -z "$srcdir" ; then
 817       USAGE_ERROR(["Neither the current directory nor its parent seem to
 818   contain the XEmacs sources.  If you do not want to build XEmacs in its
 819   source tree, you should run \`$progname' in the directory in which
 820   you wish to build XEmacs, using the \`--srcdir' option to say where the
 821   sources may be found."])
 822     fi
 823   ;;
 824
 825   dnl Otherwise, check if the directory they specified is okay.
 826   * )
 827     if test ! -f "$srcdir/src/lisp.h" -o \
 828             ! -f "$srcdir/lisp/version.el" ; then
 829       USAGE_ERROR(["The directory specified with the \`--srcdir' option,
 830   \`$srcdir', doesn't seem to contain the XEmacs sources.  You should
 831   either run the \`$progname' script at the top of the XEmacs source
 832   tree, or use the \`--srcdir' option to specify the XEmacs source directory."])
 833     fi
 834   ;;
 835 esac
 836
 837 dnl ###########################################################################
 838 if test -z "$configuration"; then
 839   dnl Guess the configuration
 840   configuration=`${CONFIG_SHELL-/bin/sh} $srcdir/config.guess`
 841   if test -z "$configuration"; then
 842     USAGE_ERROR(["XEmacs has not been ported to this host type.
 843 Try explicitly specifying the CONFIGURATION when rerunning configure."])
 844   fi
 845 fi
 846
 847 AC_PROG_LN_S
 848
 849 dnl Make symlinks for etc, lisp, and info directories while the path
 850 dnl is still relative.  We do not symlink lock because someone may
 851 dnl have stuck the source on a read-only partition.  Instead we
 852 dnl create it as an actual directory later on if it does not already
 853 dnl exist.
 854 for dir in lisp etc man info; do
 855   if test ! -d "$dir" ; then
 856     echo Making symbolic link to "$srcdir/$dir"
 857     ${LN_S} "$srcdir/$dir" "$dir"
 858   fi
 859 done
 860
 861 dnl Do our best to deal with automounter brokenness
 862 dnl CANONICALIZE_PATH(varname)
 863 define([CANONICALIZE_PATH],
 864 [if test -d "/net"; then
 865   if test -d "/tmp_mnt/net"; then tdir="tmp_mnt/net"; else tdir="tmp_mnt"; fi
 866   $1=`echo "[$]$1" | \
 867    sed -e "s|^${tdir}/|/net/|" -e "s|^/a/|/net/|" -e "s|^/amd/|/net/|"`
 868 fi])dnl
 869
 870 dnl Calculate canonical name for blddir (i.e. current directory).
 871 dnl PWD may already be the preferable absolute name for ".",
 872 dnl but we can't trust it - it is sometimes inaccurate.
 873 absolute_pwd="`pwd`";
 874 if test -n "$PWD" -a "`cd $PWD && pwd`" = "$absolute_pwd"
 875 then blddir="$PWD"
 876 else blddir="$absolute_pwd"; CANONICALIZE_PATH(blddir)
 877 fi
 878 AC_SUBST(blddir)
 879
 880 dnl Make srcdir absolute, if not already.  It is important to
 881 dnl avoid running the path through pwd unnecessary, since pwd can
 882 dnl give you automounter prefixes, which can go away.
 883 case "$srcdir" in
 884   /* ) ;;
 885   .  ) srcdir="$blddir" ;;
 886   *  ) srcdir="`cd $srcdir && pwd`"; CANONICALIZE_PATH(srcdir) ;;
 887 esac
 888
 889 dnl Check if the source directory already has a configured system in it.
 890 if test `pwd` != `sh -c cd $srcdir && pwd`  \
 891    && test -f "$srcdir/src/config.h"; then
 892   (echo "$progname: WARNING: The directory tree \`$srcdir' is being used"
 893    echo "   as a build directory right now; it has been configured in its own"
 894    echo "   right.  To configure in another directory as well, you MUST"
 895    echo "   use GNU make.  If you do not have GNU make, then you must"
 896    echo "   now do \`make distclean' in $srcdir,"
 897    echo "   and then run $progname again.") >&2
 898   extrasub='/^VPATH[[    ]]*=/c\
 899 vpath %.c $(srcdir)\
 900 vpath %.h $(srcdir)\
 901 vpath %.y $(srcdir)\
 902 vpath %.l $(srcdir)\
 903 vpath %.s $(srcdir)\
 904 vpath %.in $(srcdir)'
 905 fi
 906
 907 dnl ----------------------------------------
 908 dnl Find out which version of XEmacs this is
 909 dnl ----------------------------------------
 910 . "$srcdir/version.sh" || exit 1;
 911 dnl Must do the following first to determine verbosity for AC_DEFINE
 912 if test -n "$emacs_beta_version"; then beta=yes; else beta=no; fi
 913 : "${extra_verbose=$beta}"
 914 version="${emacs_major_version}.${emacs_minor_version}"
 915 AC_DEFINE_UNQUOTED(EMACS_MAJOR_VERSION, $emacs_major_version)
 916 AC_DEFINE_UNQUOTED(EMACS_MINOR_VERSION, $emacs_minor_version)
 917 if test -n "$emacs_beta_version"; then
 918   version="${version}-b${emacs_beta_version}"
 919   AC_DEFINE_UNQUOTED(EMACS_BETA_VERSION, $emacs_beta_version)
 920 fi
 921 AC_DEFINE_UNQUOTED(XEMACS_CODENAME, "$xemacs_codename")
 922 AC_DEFINE_UNQUOTED(EMACS_VERSION, "$version")
 923
 924 if test "$with_infodock" = "yes"; then
 925   if test ! -f ../ID-INSTALL; then
 926     echo "Cannot build InfoDock without InfoDock sources"
 927     with_infodock=no
 928   fi
 929 fi
 930
 931 if test "$with_infodock" = "yes"; then
 932   dnl InfoDock version numbers.  XEmacs will use the same style of numbering
 933   dnl after the release of XEmacs 21.0.
 934   AC_DEFINE_UNQUOTED(INFODOCK_MAJOR_VERSION, $infodock_major_version)
 935   AC_DEFINE_UNQUOTED(INFODOCK_MINOR_VERSION, $infodock_minor_version)
 936   AC_DEFINE_UNQUOTED(INFODOCK_BUILD_VERSION, $infodock_build_version)
 937   version=${infodock_major_version}.${infodock_minor_version}.${infodock_build_version}
 938   PROGNAME=infodock
 939   CPPFLAGS="$CPPFLAGS -DINFODOCK"
 940 else
 941   PROGNAME=xemacs
 942 fi
 943
 944 dnl ----------------------------------
 945 dnl Error checking and debugging flags
 946 dnl ----------------------------------
 947 dnl Error checking default to "yes" in beta versions, to "no" in releases.
 948 dnl Same goes for --debug and --extra-verbosity.
 949 if test -n "$emacs_beta_version"; then beta=yes; else beta=no; fi
 950 test "${error_check_extents=$beta}"   = yes && AC_DEFINE(ERROR_CHECK_EXTENTS)
 951 test "${error_check_typecheck=$beta}" = yes && AC_DEFINE(ERROR_CHECK_TYPECHECK)
 952 test "${error_check_bufpos=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_BUFPOS)
 953 test "${error_check_gc=$beta}"        = yes && AC_DEFINE(ERROR_CHECK_GC)
 954 test "${error_check_malloc=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_MALLOC)
 955 dnl debug=yes must be set when error checking is present.  This should be
 956 dnl fixed up.
 957 dnl debug implies other options
 958 if test "${debug:=$beta}" = "yes"; then
 959   use_assertions=yes memory_usage_stats=yes
 960   XE_ADD_OBJS(debug.o)
 961   AC_DEFINE(DEBUG_XEMACS)
 962 fi
 963 test "$use_assertions"     = "yes" && AC_DEFINE(USE_ASSERTIONS)
 964 test "$memory_usage_stats" = "yes" && AC_DEFINE(MEMORY_USAGE_STATS)
 965
 966 dnl ------------------------------
 967 dnl Determine the s&m files to use
 968 dnl ------------------------------
 969 dnl Given the configuration name, set machfile and opsysfile to the
 970 dnl names of the m/*.h and s/*.h files we should use.
 971
 972 dnl Canonicalize the configuration name.
 973 AC_MSG_CHECKING("host system type")
 974 dnl allow -workshop suffix on configuration name
 975 internal_configuration=`echo $configuration | sed 's/-\(workshop\)//'`
 976 canonical=`${CONFIG_SHELL-/bin/sh} $srcdir/config.sub "$internal_configuration"`
 977 XE_STRIP_4TH_COMPONENT(configuration)
 978 XE_STRIP_4TH_COMPONENT(canonical)
 979 AC_MSG_RESULT($configuration)
 980
 981 dnl If you add support for a new configuration, add code to this
 982 dnl switch statement to recognize your configuration name and select
 983 dnl the appropriate operating system and machine description files.
 984
 985 dnl You would hope that you could choose an m/*.h file pretty much
 986 dnl based on the machine portion of the configuration name, and an s-
 987 dnl file based on the operating system portion.  However, it turns out
 988 dnl that each m/*.h file is pretty manufacturer-specific - for
 989 dnl example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 990 dnl all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 991 dnl machines.  So we basically have to have a special case for each
 992 dnl configuration name.
 993
 994 dnl As far as handling version numbers on operating systems is
 995 dnl concerned, make sure things will fail in a fixable way.  If
 996 dnl /etc/MACHINES says nothing about version numbers, be
 997 dnl prepared to handle anything reasonably.  If version numbers
 998 dnl matter, be sure /etc/MACHINES says something about it.
 999
1000 dnl Eric Raymond says we should accept strings like "sysvr4" to mean
1001 dnl "System V Release 4"; he writes, "The old convention encouraged"
1002 dnl "confusion between `system' and `release' levels'."
1003
1004 machine='' opsys=''
1005
1006 dnl Straightforward machine determination
1007 case "$canonical" in
1008   sparc-*-*        ) machine=sparc ;;
1009   alpha*-*-*       ) machine=alpha ;;
1010   vax-*-*          ) machine=vax ;;
1011   mips-dec-*       ) machine=pmax ;;
1012   mips-sgi-*       ) machine=iris4d ;;
1013   romp-ibm-*       ) machine=ibmrt ;;
1014   rs6000-ibm-aix*  ) machine=ibmrs6000 ;;
1015   powerpc-ibm-aix* ) machine=ibmrs6000 ;;
1016   powerpc*-*       ) machine=powerpc ;;
1017   hppa-*-*         ) machine=hp800 ;;
1018   m88k-dg-*        ) machine=aviion ;;
1019   m68*-sony-*      ) machine=news ;;
1020   mips-sony-*      ) machine=news-risc ;;
1021   clipper-*        ) machine=clipper ;;
1022   arm-*            ) machine=arm ;;
1023   ns32k-*          ) machine=ns32000 ;;
1024 esac
1025
1026 dnl Straightforward OS determination
1027 case "$canonical" in
1028   *-*-linux*    ) opsys=linux ;;
1029   *-*-netbsd*   ) opsys=netbsd ;;
1030   *-*-openbsd*  ) opsys=openbsd ;;
1031   *-*-nextstep* ) opsys=nextstep ;;
1032   *-*-vms       ) opsys=vms ;;
1033
1034   dnl DEC OSF
1035   *-dec-osf1.3 | *-dec-osf2* ) opsys=decosf1-3 ;;
1036   *-dec-osf1.2 | *-dec-osf1* ) opsys=decosf1-2 ;;
1037   *-dec-osf3.[[2-9]]         ) opsys=decosf3-2 ;;
1038   *-dec-osf3*                ) opsys=decosf3-1 ;;
1039   *-dec-osf4*                ) opsys=decosf4-0 ;;
1040
1041   dnl DEC Ultrix
1042   *-*-ultrix[[0-3]].* | *-*-ultrix4.0* ) opsys=bsd4-2 ;;
1043   *-*-ultrix4.[[12]]* ) opsys=bsd4-3 ;;
1044   *-*-ultrix* )         opsys=ultrix4-3 ;;
1045
1046   dnl AIX
1047   *-*-aix3.1*  ) opsys=aix3-1   ;;
1048   *-*-aix3.2.5 ) opsys=aix3-2-5 ;;
1049   *-*-aix3*    ) opsys=aix3-2   ;;
1050   *-*-aix4.0*  ) opsys=aix4     ;;
1051   *-*-aix4.1*  ) opsys=aix4-1   ;;
1052   *-*-aix4*    ) opsys=aix4-2   ;;
1053
1054   dnl Other generic OSes
1055   *-gnu* )                      opsys=gnu    ;;
1056   *-*-bsd4.[[01]] )             opsys=bsd4-1 ;;
1057   *-*-bsd4.2 )                  opsys=bsd4-2 ;;
1058   *-*-bsd4.3 )                  opsys=bsd4-3 ;;
1059   *-*-aos4.2 )                  opsys=bsd4-2 ;;
1060   *-*-aos*   )                  opsys=bsd4-3 ;;
1061   *-*-sysv0    | *-*-sysvr0 )   opsys=usg5-0 ;;
1062   *-*-sysv2    | *-*-sysvr2 )   opsys=usg5-2 ;;
1063   *-*-sysv2.2  | *-*-sysvr2.2 ) opsys=usg5-2-2 ;;
1064   *-*-sysv3*   | *-*-sysvr3* )  opsys=usg5-3 ;;
1065   *-*-sysv4.1* | *-*-sysvr4.1* )opsys=usg5-4 NON_GNU_CPP=/usr/lib/cpp ;;
1066   *-*-sysv4.[[2-9]]* | *-sysvr4.[[2-9]]* )
1067         if test -z "$NON_GNU_CPP" ; then
1068           for prog in "/usr/ccs/lib/cpp" "/lib/cpp"; do
1069             if test -f "$prog"; then NON_GNU_CPP="$prog"; break; fi
1070           done
1071         fi
1072         opsys=usg5-4-2 ;;
1073     *-sysv4* | *-sysvr4* )      opsys=usg5-4 ;;
1074     *-*-mach_bsd4.3* )          opsys=mach-bsd4-3 ;;
1075 esac
1076
1077 case "$canonical" in
1078
1079   dnl NetBSD ports
1080   *-*-netbsd* )
1081     case "$canonical" in
1082       i[[3-9]]86-*-netbsd*) machine=intel386 ;;
1083       hp300-*-netbsd* | amiga-*-netbsd* | sun3-*-netbsd* | mac68k-*-netbsd* | da30-*-netbsd* | m68k-*-netbsd* )
1084                       dnl Yes, this is somewhat bogus.
1085                       machine=hp9000s300 ;;
1086       pc532-*-netbsd* | ns32k-*-netbsd* )  machine=ns32000 ;;
1087       pmax-*-netbsd*  | mips-*-netbsd*  )  machine=pmax ;;
1088     esac
1089   ;;
1090
1091   dnl OpenBSD ports
1092   *-*-openbsd* )
1093     case "${canonical}" in
1094       i386-*-openbsd*)          machine=intel386 ;;
1095       m68k-*-openbsd*)          machine=hp9000s300 ;;
1096       mipsel-*-openbsd*)        machine=pmax ;;
1097      esac
1098    ;;
1099
1100   dnl Acorn RISCiX:
1101   arm-acorn-riscix1.1* ) machine=acorn opsys=riscix1-1 ;;
1102   arm-acorn-riscix1.2* | arm-acorn-riscix ) machine=acorn opsys=riscix1-2 ;;
1103
1104   dnl Alliant machines
1105   fx80-alliant-* ) machine=alliant4     opsys=bsd4-2 ;;
1106   i860-alliant-* ) machine=alliant-2800 opsys=bsd4-3 ;;
1107
1108   dnl Altos 3068
1109   m68*-altos-sysv* ) machine=altos opsys=usg5-2 ;;
1110
1111   dnl Amdahl UTS
1112   580-amdahl-sysv* ) machine=amdahl opsys=usg5-2-2 ;;
1113
1114   dnl Apollo, Domain/OS
1115   m68*-apollo-* ) machine=apollo opsys=bsd4-3 ;;
1116
1117   dnl AT&T 3b2, 3b5, 3b15, 3b20
1118   we32k-att-sysv* ) machine=att3b opsys=usg5-2-2 ;;
1119
1120   dnl AT&T 3b1 - The Mighty Unix PC!
1121   m68*-att-sysv* ) machine=7300 opsys=usg5-2-2 ;;
1122
1123   dnl Bull machines
1124   rs6000-bull-bosx* ) machine=ibmrs6000 opsys=aix3-2 ;; # dpx20
1125   m68*-bull-sysv3*  ) machine=dpx2      opsys=usg5-3 ;; # dpx2
1126   m68*-bull-sysv2*  ) machine=sps7      opsys=usg5-2 ;; # sps7
1127
1128   dnl CCI 5/32, 6/32 -- see "Tahoe".
1129
1130   dnl Celerity
1131   celerity-celerity-bsd* ) machine=celerity opsys=bsd4-2 ;;
1132
1133   dnl Convex
1134   *-convex-bsd* | *-convex-convexos* )
1135     machine=convex opsys=bsd4-3
1136     NON_GNU_CPP="cc -E -P"
1137   ;;
1138
1139   dnl Cubix QBx/386
1140   i[[3-9]]86-cubix-sysv* ) machine=intel386 opsys=usg5-3 ;;
1141
1142   dnl Data General AViiON Machines
1143   i586-dg-dgux*R4*   | i586-dg-dgux5.4.4* ) machine=aviion opsys=dgux5-4r4 ;;
1144   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* ) opsys=dgux5-4r3 ;;
1145   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* ) opsys=dgux5-4r2 ;;
1146   m88k-dg-dgux*                           ) opsys=dgux     ;;
1147
1148   dnl Motorola Delta machines
1149   m68k-motorola-sysv* | m68000-motorola-sysv* ) machine=delta opsys=usg5-3 ;;
1150   m88k-motorola-sysv4* )
1151     dnl jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
1152     dnl needs POSIX_SIGNALS and therefore needs usg5-4-2.
1153     dnl I hope there are not other 4.0 versions for this machine
1154     dnl which really need usg5-4 instead.
1155     machine=delta88k opsys=usg5-4-2
1156   ;;
1157   m88k-motorola-sysv* | m88k-motorola-m88kbcs* ) machine=delta88k opsys=usg5-3 ;;
1158
1159   dnl Dual machines
1160   m68*-dual-sysv*    ) machine=dual opsys=usg5-2   ;;
1161   m68*-dual-uniplus* ) machine=dual opsys=unipl5-2 ;;
1162
1163   dnl Encore machines
1164   ns16k-encore-bsd* ) machine=ns16000 opsys=umax ;;
1165
1166   dnl Gould Power Node and NP1
1167   pn-gould-bsd4.2* ) machine=gould     opsys=bsd4-2 ;;
1168   pn-gould-bsd4.3* ) machine=gould     opsys=bsd4-3 ;;
1169   np1-gould-bsd* )   machine=gould-np1 opsys=bsd4-3 ;;
1170
1171   dnl Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
1172   dnl as far as XEmacs is concerned).
1173   m88k-harris-cxux* )
1174     dnl Build needs to be different on 7.0 and later releases
1175     case "`uname -r`" in
1176        [[56]].[[0-9]] ) machine=nh4000 opsys=cxux  ;;
1177        [[7]].[[0-9]]  ) machine=nh4000 opsys=cxux7 ;;
1178     esac
1179     NON_GNU_CPP="/lib/cpp"
1180   ;;
1181   dnl Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
1182   m68k-harris-cxux* ) machine=nh3000 opsys=cxux ;;
1183   dnl Harris power pc NightHawk running Power UNIX (Series 6000)
1184   powerpc-harris-powerunix ) machine=nh6000 opsys=powerunix NON_GNU_CPP="cc -Xo -E -P" ;;
1185
1186   dnl Honeywell XPS100
1187   xps*-honeywell-sysv* ) machine=xps100 opsys=usg5-2 ;;
1188
1189   dnl HP 9000 series 200 or 300
1190   m68*-hp-bsd* ) machine=hp9000s300 opsys=bsd4-3 ;;
1191
1192   dnl HP-UX
1193   *-hp-hpux* )
1194     dnl Figure out machine and opsys orthogonally
1195     case "$canonical" in
1196       m68*  ) machine=hp9000s300 ;;
1197       hppa* ) machine=hp800      ;;
1198     esac
1199
1200     case "$canonical" in
1201       *-hp-hpux7*  )  opsys=hpux   ;;
1202       *-hp-hpux8*  )  opsys=hpux8  ;;
1203       *-hp-hpux9*  )  opsys=hpux9  ;;
1204       *-hp-hpux10* )  opsys=hpux10 ;;
1205       *-hp-hpux11* )  opsys=hpux11 ;;
1206       *            )  opsys=hpux   ;;
1207     esac
1208
1209     dnl HP has a broken "strcat"
1210     case "$opsys" in hpux9 | hpux10 ) XE_ADD_OBJS(strcat.o) ;; esac
1211
1212     if test "$opsys" = "hpux10" -o "$opsys" = "hpux11"; then \
1213         ansi_flag="-Ae"; else ansi_flag="-Aa"; fi
1214     NON_GNU_CC="cc $ansi_flag" NON_GNU_CPP="cc $ansi_flag -E"
1215
1216     case "$canonical" in *-hp-hpux*shr* ) opsys="${opsys}-shr" ;; esac
1217   ;;
1218
1219   dnl Orion machines
1220   orion-orion-bsd*   ) machine=orion    opsys=bsd4-2 ;;
1221   clipper-orion-bsd* ) machine=orion105 opsys=bsd4-2 ;;
1222
1223   dnl IBM machines
1224   i[[3-9]]86-ibm-aix1.1* ) machine=ibmps2-aix opsys=usg5-2-2 ;;
1225   i[[3-9]]86-ibm-aix1.[[23]]* | i[[3-9]]86-ibm-aix* ) machine=ibmps2-aix opsys=usg5-3 ;;
1226   i370-ibm-aix*) machine=ibm370aix opsys=usg5-3 ;;
1227   romp-ibm-aos*    ) opsys=bsd4-3 ;;
1228   romp-ibm-bsd*    ) opsys=bsd4-3 ;;
1229   romp-ibm-mach*   ) opsys=mach-bsd4-3 ;;
1230
1231   dnl Integrated Solutions "Optimum V"
1232   m68*-isi-bsd4.2* ) machine=isi-ov opsys=bsd4-2 ;;
1233   m68*-isi-bsd4.3* ) machine=isi-ov opsys=bsd4-3 ;;
1234
1235   dnl Intel 386 machines where we do care about the manufacturer
1236   i[[3-9]]86-intsys-sysv* ) machine=is386 opsys=usg5-2-2 ;;
1237
1238   dnl Prime EXL
1239   i[[3-9]]86-prime-sysv* ) machine=i386 opsys=usg5-3 ;;
1240
1241   dnl Sequent Symmetry running Dynix
1242   i[[3-9]]86-sequent-bsd* ) machine=symmetry opsys=bsd4-3 ;;
1243
1244   dnl Sequent Symmetry running DYNIX/ptx
1245   i[[3-9]]86-sequent-ptx* ) machine=sequent-ptx opsys=ptx NON_GNU_CPP="/lib/cpp" ;;
1246
1247   dnl Unspecified sysv on an ncr machine defaults to svr4.2.
1248   dnl (Plain usg5-4 does not turn on POSIX signals, which we need.)
1249   i[[3-9]]86-ncr-sysv* ) machine=ncr386 opsys=usg5-4-2 ;;
1250
1251   dnl Intel Paragon OSF/1
1252   i860-intel-osf1* ) machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp ;;
1253
1254   dnl Intel 860
1255   i860-*-sysv4* ) machine=i860 opsys=usg5-4 NON_GNU_CC="/bin/cc" NON_GNU_CPP="/usr/ccs/lib/cpp" ;;
1256
1257   dnl Masscomp machines
1258   m68*-masscomp-rtu* ) machine=masscomp opsys=rtu ;;
1259
1260   dnl Megatest machines
1261   m68*-megatest-bsd* ) machine=mega68 opsys=bsd4-2 ;;
1262
1263   dnl Workstations sold by MIPS
1264   dnl This is not necessarily all workstations using the MIPS processor -
1265   dnl Irises are produced by SGI, and DECstations by DEC.
1266   mips-mips-usg* ) machine=mips4 ;;
1267   mips-mips-riscos4 )
1268     machine=mips4
1269     NON_GNU_CC="cc -systype bsd43"
1270     NON_GNU_CPP="cc -systype bsd43 -E"
1271     case "$canonical" in
1272       mips-mips-riscos4* ) opsys=bsd4-3  ;;
1273       mips-mips-riscos5* ) opsys=riscos5 ;;
1274     esac
1275   ;;
1276   mips-mips-bsd* ) machine=mips opsys=bsd4-3 ;;
1277   mips-mips-*    ) machine=mips opsys=usg5-2-2 ;;
1278
1279   dnl NeXT
1280   m68*-next-* | m68k-*-nextstep* ) machine=m68k opsys=nextstep ;;
1281
1282   dnl The complete machine from National Semiconductor
1283   ns32k-ns-genix* ) machine=ns32000 opsys=usg5-2 ;;
1284
1285   dnl NCR machines
1286   m68*-ncr-sysv2* | m68*-ncr-sysvr2* ) machine=tower32   opsys=usg5-2-2 ;;
1287   m68*-ncr-sysv3* | m68*-ncr-sysvr3* ) machine=tower32v3 opsys=usg5-3 ;;
1288
1289   dnl Nixdorf Targon 31
1290   m68*-nixdorf-sysv* ) machine=targon31 opsys=usg5-2-2 ;;
1291
1292   dnl Nu (TI or LMI)
1293   m68*-nu-sysv* ) machine=nu opsys=usg5-2 ;;
1294
1295   dnl Plexus
1296   m68*-plexus-sysv* ) machine=plexus opsys=usg5-2 ;;
1297
1298   dnl Pyramid machines
1299   pyramid-pyramid-bsd* ) machine=pyramid opsys=bsd4-2 ;;
1300
1301   dnl Sequent Balance
1302   ns32k-sequent-bsd4.2* ) machine=sequent opsys=bsd4-2 ;;
1303   ns32k-sequent-bsd4.3* ) machine=sequent opsys=bsd4-3 ;;
1304
1305   dnl Siemens Nixdorf
1306   mips-siemens-sysv* | mips-sni-sysv*)
1307     machine=mips-siemens opsys=usg5-4
1308     NON_GNU_CC=/usr/ccs/bin/cc
1309     NON_GNU_CPP=/usr/ccs/lib/cpp
1310   ;;
1311
1312   dnl NEC
1313   mips-nec-sysv*)
1314     machine=mips-nec
1315     NON_GNU_CC=/usr/ccs/bin/cc
1316     NON_GNU_CPP=/usr/ccs/lib/cpp
1317   ;;
1318
1319   dnl Silicon Graphics machines
1320   dnl Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
1321   m68*-sgi-iris3.5* ) machine=irist opsys=iris3-5 ;;
1322   m68*-sgi-iris3.6* | m68*-sgi-iris*) machine=irist opsys=iris3-6 ;;
1323   dnl Iris 4D
1324   mips-sgi-irix3.*    ) opsys=irix3-3 ;;
1325   mips-sgi-irix4.*    ) opsys=irix4-0 ;;
1326   mips-sgi-irix6*     ) opsys=irix6-0 ;;
1327   mips-sgi-irix5.1*   ) opsys=irix5-1 ;;
1328   mips-sgi-irix5.2*   ) opsys=irix5-2 ;;
1329   mips-sgi-irix5.*    ) opsys=irix5-3 ;;
1330   mips-sgi-irix*      ) opsys=irix5-0 ;;
1331
1332   dnl SONY machines
1333   *-sony-newsos[[34]]* | *-sony-news[[34]]* ) opsys=bsd4-3 ;;
1334   *-sony-news* ) opsys=newsos5 ;;
1335
1336   dnl Stride
1337   m68*-stride-sysv* ) machine=stride opsys=usg5-2 ;;
1338
1339   dnl Suns
1340   *-*-solaris* | *-*-sunos* | *-sun-mach* | *-sun-bsd* )
1341     dnl Hardware type
1342     case "$canonical" in
1343       m68*-sunos1* )             machine=sun1     ;;
1344       m68*-sunos2* )             machine=sun2     ;;
1345       m68* )                     machine=sun3     ;;
1346       i*86*-sun-sunos[[34]]* )   machine=sun386   ;;
1347       i*86-*-* )                 machine=intel386 ;;
1348       rs6000* )                  machine=rs6000   ;;
1349     esac
1350
1351     dnl Make $canonical even more so.
1352     case "$canonical" in *-sunos5*)
1353       canonical=`echo $canonical | sed -e s/sunos5/solaris2/`;;
1354     esac
1355
1356     dnl On SunOS 4, use /usr/lib/cpp, sans dynodump, /bin/ranlib
1357     dnl On SunOS 5, use cc -E,        need dynodump, RANLIB not needed
1358     dnl But, SunOS 5.6 no longer needs dynodump because it has a similar
1359     dnl function integrated.
1360     case "$canonical" in
1361       *-sunos4* )
1362         #test -f /usr/lib/cpp     && NON_GNU_CPP=/usr/lib/cpp ;;
1363         : ;;
1364       *-solaris2* )
1365         #test -f /usr/ccs/lib/cpp && NON_GNU_CPP=/usr/ccs/lib/cpp
1366         RANLIB=':' ;;
1367     esac
1368
1369     case "$canonical" in
1370       *-solaris*          )
1371         opsys=sol2
1372         os_release=`uname -r | sed -e 's/^\([[0-9]]\)\.\([[0-9]]\).*/\1\2/'`
1373         AC_DEFINE_UNQUOTED(OS_RELEASE, $os_release) ;;
1374
1375       dnl The last Sun386 ran 4.0.
1376       i*86-*-sunos4*      ) opsys=sunos4-0      ;;
1377       *-sunos4.0*         ) opsys=sunos4-0      ;;
1378       *-sunos4.1.2*       ) opsys=sunos4-1-2    ;;
1379       *-sunos4.1.3*       ) opsys=sunos4-1-3    ;;
1380       *-sunos4.1.[[4-9]]* ) opsys=sunos4-1-4    ;;
1381       *-sunos4* | *-sunos ) opsys=sunos4-1      ;;
1382       *-mach*             ) opsys=mach-bsd4-3   ;;
1383       *                   ) opsys=bsd4-2        ;;
1384     esac
1385
1386     case "$canonical" in *-sunos4*shr* ) opsys="${opsys}-shr" ;; esac
1387
1388     dnl Watch out for a compiler guaranteed not to work.
1389     test "$opsys $CC" = "sol2 /usr/ucb/cc" && CC=""
1390   ;;
1391
1392   dnl Tadpole 68k
1393   m68*-tadpole-sysv* ) machine=tad68k opsys=usg5-3 ;;
1394
1395   dnl Tahoe machines
1396   tahoe-tahoe-bsd4.2* ) machine=tahoe opsys=bsd4-2 ;;
1397   tahoe-tahoe-bsd4.3* ) machine=tahoe opsys=bsd4-3 ;;
1398
1399   dnl Tandem Integrity S2
1400   mips-tandem-sysv* ) machine=tandem-s2 opsys=usg5-3 ;;
1401
1402   dnl Tektronix XD88
1403   m88k-tektronix-sysv3* ) machine=tekxd88 opsys=usg5-3 ;;
1404
1405   dnl Tektronix 16000 box (6130?)
1406   ns16k-tektronix-bsd* ) machine=ns16000 opsys=bsd4-2 ;;
1407   dnl Tektronix 4300
1408   dnl src/m/tek4300.h hints that this is a m68k machine.
1409   m68*-tektronix-bsd* ) machine=tek4300 opsys=bsd4-3 ;;
1410
1411   dnl Titan P2 or P3
1412   titan-titan-sysv* ) machine=titan opsys=usg5-3 ;;
1413
1414   dnl Ustation E30 (SS5E)
1415   m68*-unisys-uniplus* ) machine=ustation opsystem=unipl5-2 ;;
1416
1417   dnl Vaxen.
1418   vax-dec-* )
1419     case "$canonical" in
1420       *-sysv[[01]]* | *-sysvr[[01]]* )  opsys=usg5-0 ;;
1421       *-sysv2* | *-sysvr2* )            opsys=usg5-2 ;;
1422       *-mach* )                         opsys=mach-bsd4-3 ;;
1423     esac
1424   ;;
1425
1426   dnl Whitechapel MG1
1427   ns16k-whitechapel-* ) machine=mg1 ;;
1428
1429   dnl Wicat
1430   m68*-wicat-sysv* ) machine=wicat opsys=usg5-2 ;;
1431
1432   dnl Intel 386 machines where we do not care about the manufacturer
1433   i[[3-9]]86-*-* )
1434     machine=intel386
1435     case "$canonical" in
1436       *-isc1.* | *-isc2.[[01]]* ) opsys=386-ix ;;
1437       *-isc2.2* )               opsys=isc2-2 ;;
1438       *-isc4.0* )               opsys=isc4-0 ;;
1439       *-isc4.* )                opsys=isc4-1
1440                                 GCC_TEST_OPTIONS=-posix
1441                                 NON_GCC_TEST_OPTIONS=-Xp
1442                                 ;;
1443       *-isc* )                  opsys=isc3-0 ;;
1444       *-esix5* )                opsys=esix5r4 NON_GNU_CPP=/usr/lib/cpp ;;
1445       *-esix* )                 opsys=esix ;;
1446       *-mach* )                 opsys=mach-bsd4-3 ;;
1447       *-xenix* )                opsys=xenix ;;
1448       *-sco3.2v4* )             opsys=sco4 NON_GNU_CPP=/lib/cpp  ;;
1449       *-bsd386* | *-bsdi1* )    opsys=bsd386 ;;
1450       *-bsdi4* )                opsys=bsdos4 ;;
1451       *-bsdi3* )                opsys=bsdos3 ;;
1452       *-bsdi2.1* )              opsys=bsdos2-1 ;;
1453       *-bsdi2* )                opsys=bsdos2 ;;
1454       *-sco3.2v5* )             opsys=sco5 ;
1455         dnl This is a pain.  Like the current USL cc, SCO cc -E
1456         dnl tokenizes as it preprocesses, making configure very
1457         dnl unhappy.  Unfortunately, /lib/cpp does not understand
1458         dnl flags like "-b elf", so we have to cheat in order to
1459         dnl pick up the right defines for UNEXEC from the s-file.
1460         dnl 01/05/95 robertl@dgii.com
1461         if test "$dynamic" = "yes" ; then
1462                 NON_GNU_CPP="/lib/cpp -D_XOPEN_SOURCE -D_SCO_ELF"  ;
1463         else
1464                 NON_GNU_CPP="/lib/cpp -D_XOPEN_SOURCE"  ;
1465         fi ;;
1466       *-386bsd* )               opsys=386bsd ;;
1467       *-freebsd* )              opsys=freebsd ;;
1468       *-nextstep* )             opsys=nextstep ;;
1469       *-pc-cygwin* )            opsys=cygwin32 ;;
1470       *-pc-mingw* )             opsys=mingw32 ;
1471                                 test -z "$with_tty" && with_tty="no";;
1472       dnl Otherwise, we fall through to the generic opsys code at the bottom.
1473     esac
1474   ;;
1475
1476   dnl Linux/68k
1477   m68k-*-linux* ) machine=m68k opsys=linux ;;
1478
1479 esac
1480
1481 if test -z "$machine" -o -z "$opsys"; then
1482   (echo "$progname: XEmacs hasn't been ported to \`$canonical' systems."
1483    echo "$progname: Check \`etc/MACHINES' for recognized configuration names."
1484   ) >&2
1485   exit 1
1486 fi
1487
1488 if test -z "$dynamic"; then
1489   case "$opsys" in
1490     hpux* | sunos4* ) dynamic=no ;;
1491     *) dynamic=yes ;;
1492   esac
1493 fi
1494 if test "$dynamic" = "yes"; then
1495   case "$opsys" in
1496     hpux* | sunos4* | sco5 ) opsys="${opsys}-shr" ;;
1497     decosf* ) ld_call_shared="-call_shared" ;;
1498   esac
1499 else dnl "$dynamic" = "no"
1500   case "$opsys" in
1501     sol2 )
1502       echo "Static linking is not supported on Solaris 2."
1503       echo "Rerun configure without specifying --dynamic=no."
1504       exit 1 ;;
1505     linux   ) ld_call_shared="-Bstatic" ;;
1506     decosf* ) ld_call_shared="-non_shared" ;;
1507   esac
1508 fi
1509
1510 dnl Use xlc by default on AIX
1511 case "$opsys" in aix*) NON_GNU_CC=xlc ;; esac
1512
1513 stack_trace_eye_catcher=`echo ${PROGNAME}_${version}_${canonical} | sed 'y/.-/__/'`
1514 AC_DEFINE_UNQUOTED(STACK_TRACE_EYE_CATCHER, $stack_trace_eye_catcher)
1515
1516 machfile="m/${machine}.h"
1517 opsysfile="s/${opsys}.h"
1518
1519 dnl --------------------------------------------------
1520 dnl Determine the compiler, set up for feature testing
1521 dnl --------------------------------------------------
1522
1523 dnl Sun Development environment support
1524 test "$with_sparcworks" = "yes" && with_workshop=yes # compatibility alias
1525 XE_CHECK_FEATURE_DEPENDENCY(workshop, tooltalk)
1526 if test "$with_workshop" = "yes"; then
1527   AC_DEFINE(SUNPRO)
1528   XE_ADD_OBJS(sunpro.o)
1529 fi
1530
1531 if test "$with_clash_detection" = "yes"; then
1532   AC_DEFINE(CLASH_DETECTION)
1533   XE_ADD_OBJS(filelock.o)
1534 fi
1535
1536 dnl Choose a compiler from (in order)
1537 dnl --compiler, env var CC, with_gcc=no && ${NON_GNU_CC:-cc}, AC_PROG_CC
1538 test -n "$compiler" && CC="$compiler"
1539 if test "$with_gcc" = "no"; then dnl Try to find a non-gcc compiler
1540   case "$CC" in "" | *gcc* ) CC="${NON_GNU_CC-cc}" ;; esac
1541 fi
1542
1543 dnl If we don't set CFLAGS here, AC_PROG_CC will set it.
1544 dnl But we know better what's good for us, so we do our own
1545 dnl computation of real CFLAGS later.
1546 dnl --cflags overrides environment variable CFLAGS
1547 test "${cflags-unset}" != unset && CFLAGS="$cflags"
1548 if test "${CFLAGS-unset}" != unset
1549   then cflags_specified=yes;
1550   else cflags_specified=no;
1551 fi
1552
1553 xe_save_CFLAGS="$CFLAGS"
1554
1555 AC_PROG_CC dnl Autoconf has its own magic for compiler autodetection
1556
1557 dnl Retry using random guesswork if AC_PROG_CC got it wrong...
1558 if   test "$with_gcc" = "no"  -a "$GCC" = "yes"; then
1559   CC=${NON_GNU_CC-cc}
1560   AC_PROG_CC
1561 elif test "$with_gcc" = "yes" -a "$GCC" != "yes" ; then
1562   CC=gcc
1563   AC_PROG_CC
1564 fi
1565 CFLAGS="$xe_save_CFLAGS"
1566
1567 dnl Figure out what C preprocessor to use.
1568
1569 dnl On Sun systems, people sometimes set up the variable CPP
1570 dnl with a value that is a directory, not an executable at all.
1571 dnl Detect that case, and ignore that value.
1572 test -n "$CPP" -a -d "$CPP" && CPP=
1573
1574 test -n "$NON_GNU_CPP" -a "$GCC" != "yes" -a -z "$CPP" && CPP="$NON_GNU_CPP"
1575
1576 AC_PROG_CPP
1577
1578 AC_AIX
1579
1580 AC_MSG_CHECKING(for GNU libc)
1581 AC_TRY_COMPILE([#include <features.h>],[
1582 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
1583 #error Not a GNU libc system :-(
1584 ******* ======= ******** &&&&&&&&
1585 #endif
1586 ], have_glibc=yes, have_glibc=no)
1587 AC_MSG_RESULT($have_glibc)
1588 dnl I'm tired of pop being broken with GLIBC -slb
1589 dnl Well. then why not fix fucking pop?
1590 test "$have_glibc" = "yes" && AC_DEFINE(_GNU_SOURCE)
1591
1592
1593 dnl Identify compilers to enable compiler-specific hacks.
1594 dnl Add support for other compilers HERE!
1595 dnl GCC is already identified elsewhere.
1596 AC_TRY_RUN([int main () {
1597 #if defined __SUNPRO_C
1598 return 11;
1599 #elif defined __DECC
1600 return 12;
1601 #else
1602 return 0;
1603 #endif
1604 }], [],
1605 [case "$conftest_rc" in
1606   11) echo "You appear to be using the SunPro C compiler."; __SUNPRO_C=yes ;;
1607   12) echo "You appear to be using the DEC C compiler."   ; __DECC=yes ;;
1608 esac])
1609
1610
1611 dnl case "$canonical" in
1612 dnl   *-sun-sunos* ) test "$CPP" = "acc -E" && CPP="acc -E -Xs" ;;
1613 dnl esac
1614
1615 dnl --------------------------------------------------------------------
1616 dnl Extract some information from the operating system and machine files
1617 dnl --------------------------------------------------------------------
1618
1619 echo "Extracting information from the machine- and system-dependent headers..."
1620
1621 dnl It is not important that this name contain the PID; you cannot run
1622 dnl two configures in the same directory and have anything work
1623 dnl anyway.
1624 tempcname="conftest.c"
1625
1626 dnl CPP_to_sh(CPP_SYMBOL, SH_VAR, DEFAULT_VALUE)
1627 define([CPP_to_sh],
1628 [[#]ifndef [$1]
1629 [#]define [$1]ifelse([$3],,, [ "$3"])
1630 [#]endif
1631 configure___ [$2]=[$1]
1632 ])dnl CPP_to_sh
1633
1634 dnl CPP_boolean_to_sh(CPP_SYMBOL, SH_VAR)
1635 define([CPP_boolean_to_sh],
1636 [[#]ifdef [$1]
1637 configure___ [$2]=yes
1638 [#]else
1639 configure___ [$2]=no
1640 [#]endif
1641 ])dnl CPP_boolean_to_sh
1642
1643 cat > $tempcname <<EOF
1644 #define NOT_C_CODE
1645 #define C_SWITCH_SITE
1646 #define C_SWITCH_X_SITE
1647 #define LD_SWITCH_SITE
1648 #define LD_SWITCH_X_SITE
1649 #define LD_SWITCH_X_SITE_AUX
1650 #define OS_RELEASE $os_release
1651 #include "$srcdir/src/$opsysfile"
1652 #include "$srcdir/src/$machfile"
1653
1654 CPP_to_sh(LIBS_MACHINE, libs_machine)
1655 CPP_to_sh(LIBS_SYSTEM,  libs_system)
1656 CPP_to_sh(LIBS_TERMCAP, libs_termcap)
1657 CPP_to_sh(LIB_STANDARD, libs_standard)
1658
1659 CPP_to_sh(OBJECTS_MACHINE, objects_machine)
1660 CPP_to_sh(OBJECTS_SYSTEM,  objects_system)
1661
1662 CPP_to_sh(C_SWITCH_MACHINE,   c_switch_machine)
1663 CPP_to_sh(C_SWITCH_SYSTEM,    c_switch_system)
1664
1665 CPP_to_sh(LD_SWITCH_MACHINE,  ld_switch_machine)
1666 CPP_to_sh(LD_SWITCH_SYSTEM,   ld_switch_system)
1667
1668 CPP_to_sh(UNEXEC, unexec, unexec.o)
1669
1670 CPP_to_sh(LD_SWITCH_SHARED, ld_switch_shared, -c)
1671
1672 #ifdef ORDINARY_LINK
1673 #define LD "\$(CC) \$(CFLAGS)"
1674 #else /* no ORDINARY LINK */
1675 #ifdef COFF_ENCAPSULATE
1676 #define LD "\$(CC) -nostdlib"
1677 #else /* not COFF_ENCAPSULATE */
1678 #ifdef LINKER
1679 #define LD LINKER
1680 #else /* ! defined (LINKER) */
1681 #define LD "ld"
1682 #endif /* ! defined (LINKER) */
1683 #endif /* ! defined (COFF_ENCAPSULATE) */
1684 #endif /* not ORDINARY_LINK */
1685 configure___ ld=LD
1686
1687 CPP_to_sh(LIB_GCC, lib_gcc)
1688 CPP_to_sh(LD_TEXT_START_ADDR, ld_text_start_addr)
1689
1690 #if ! defined (ORDINARY_LINK) && !defined (START_FILES)
1691 #ifdef NO_REMAP
1692 #ifdef COFF_ENCAPSULATE
1693 #define START_FILES "pre-crt0.o /usr/local/lib/gcc-crt0.o"
1694 #else /* ! defined (COFF_ENCAPSULATE) */
1695 #define START_FILES "pre-crt0.o /lib/crt0.o"
1696 #endif /* ! defined (COFF_ENCAPSULATE) */
1697 #else /* ! defined (NO_REMAP) */
1698 #define START_FILES "ecrt0.o"
1699 #endif /* ! defined (NO_REMAP) */
1700 #endif /* no ORDINARY_LINK */
1701 #ifndef START_FILES
1702 #define START_FILES
1703 #endif
1704 configure___ start_files=START_FILES
1705
1706 CPP_boolean_to_sh(ORDINARY_LINK, ordinary_link)
1707 CPP_boolean_to_sh(SYSTEM_MALLOC, system_malloc)
1708 CPP_boolean_to_sh(TERMINFO, have_terminfo)
1709 CPP_boolean_to_sh(MAIL_USE_FLOCK, mail_use_flock)
1710 CPP_boolean_to_sh(MAIL_USE_LOCKF, mail_use_lockf)
1711 CPP_boolean_to_sh(HAVE_WIN32_PROCESSES, win32_processes)
1712 EOF
1713
1714 dnl The value of CPP is a quoted variable reference, so we need to do this
1715 dnl to get its actual value...
1716 CPP=`eval "echo $CPP $CPPFLAGS"`
1717 define(TAB, [   ])dnl
1718 changequote(, )dnl
1719 eval `$CPP -Isrc $tempcname \
1720         | sed -n -e "s/[ TAB]*=[ TAB\"]*/='/" -e "s/[ TAB\"]*\$/'/" -e "s/^configure___//p"`
1721 changequote([, ])dnl
1722
1723 rm $tempcname
1724
1725 dnl For debugging...
1726 test "$extra_verbose" = "yes" && \
1727   PRINT_VAR(libs_machine libs_system libs_termcap libs_standard
1728   objects_machine objects_system c_switch_machine c_switch_system
1729   ld_switch_machine ld_switch_system unexec ld_switch_shared
1730   ld lib_gcc ld_text_start_addr start_files ordinary_link
1731   have_terminfo mail_use_flock mail_use_lockf) && echo ""
1732
1733 dnl Non-ordinary link usually requires -lc
1734 test "$ordinary_link" = "no" -a -z "$libs_standard" && libs_standard="-lc"
1735
1736 dnl Compiler-specific hacks
1737 dnl DEC C requires -std
1738 test "$__DECC" = "yes" && XE_APPEND(-std, c_switch_site)
1739
1740 dnl Calculalate value of CFLAGS:
1741 dnl Use either command line flag, environment var, or autodetection
1742 if test "$cflags_specified" = "no"; then
1743   dnl Following values of CFLAGS are known to work well.
1744   dnl Should we take debugging options into consideration?
1745   if   test "$GCC" = "yes"; then
1746     CFLAGS="-g -O3 -Wall -Wno-switch"
1747     dnl I'm not convinced this is a good idea any more. -sb
1748     dnl test "$opsys $machine" = "linux intel386" && \
1749     dnl CFLAGS="$CFLAGS -fno-strength-reduce -malign-loops=2 -malign-jumps=2 -malign-functions=2"
1750   elif test "$__SUNPRO_C" = "yes"; then
1751     case "$opsys" in
1752       sol2    ) CFLAGS="-v -xO4" ;;
1753       sunos4* ) CFLAGS="-xO2";;
1754     esac
1755   elif test "$__DECC" = "yes"; then
1756     CFLAGS="-O3"
1757   elif test "$CC" = "xlc"; then
1758     CFLAGS="-g -O3 -qstrict -qnoansialias -qlibansi -qinfo -qro -qmaxmem=20000"
1759   dnl ### Add optimal CFLAGS support for other compilers HERE!
1760   else
1761     CFLAGS="-O" ;dnl The only POSIX-approved flag
1762   fi
1763 fi
1764
1765 dnl Inform compiler that certain flags are meant for the linker
1766 dnl XE_PROTECT_LINKER_FLAGS(shell_var)
1767 define([XE_PROTECT_LINKER_FLAGS], [
1768 if test "$GCC" = "yes"; then
1769   set x $[$1]; shift; [$1]=""
1770   while test -n "[$]1"; do
1771     case [$]1 in
1772       -L  | -l  | -u               ) [$1]="$[$1] [$]1 [$]2"; shift ;;
1773       -L* | -l* | -u* | -Wl* | -pg ) [$1]="$[$1] [$]1" ;;
1774       -Xlinker* ) ;;
1775       * ) [$1]="$[$1] -Xlinker [$]1" ;;
1776     esac
1777     shift
1778   done
1779 fi])dnl
1780 XE_PROTECT_LINKER_FLAGS(ld_switch_system)
1781 XE_PROTECT_LINKER_FLAGS(ld_switch_machine)
1782 XE_PROTECT_LINKER_FLAGS(LDFLAGS)
1783 XE_PROTECT_LINKER_FLAGS(ld_call_shared)
1784
1785 dnl Add s&m-determined objects (including unexec) to link line
1786 test -n "$objects_machine" && XE_ADD_OBJS($objects_machine)
1787 test -n "$objects_system"  && XE_ADD_OBJS($objects_system)
1788 test -n "$unexec"          && XE_ADD_OBJS($unexec)
1789
1790 dnl Dynodump (Solaris 2.x, x<6)
1791 AC_MSG_CHECKING(for dynodump)
1792 if test "$unexec" != "unexsol2.o"; then
1793   AC_MSG_RESULT(no)
1794 else
1795   AC_MSG_RESULT(yes)
1796   AC_DEFINE(DYNODUMP)
1797   XE_APPEND(dynodump, MAKE_SUBDIR)
1798   XE_APPEND(dynodump, SRC_SUBDIR_DEPS)
1799   case "$machine" in
1800     sparc   ) dynodump_arch=sparc ;;
1801     *86*    ) dynodump_arch=i386  ;;
1802     powerpc ) dynodump_arch=ppc   ;;
1803   esac
1804   dnl Dynodump requires the system linker
1805   test "$GCC" = "yes" && XE_APPEND(-fno-gnu-linker, ld_switch_site)
1806 fi
1807
1808 dnl Feed s&m crud to src/Makefile
1809
1810 dnl Linux/powerpc needs the following magic for some reason
1811 test "$machine$opsys" = "powerpclinux" && start_flags="-T $srcdir/src/ppc.ldscript"
1812
1813 if test "$unexec" = "unexaix.o"; then
1814 dnl AIX needs various hacks to make static linking work.
1815   if   test "$dynamic" = "no"; then
1816   start_flags="-Wl,-bnso,-bnodelcsect"
1817   test "$GCC" = "yes" && start_flags="-B/bin/ ${start_flags}"
1818   for f in "/lib/syscalls.exp" "/lib/threads.exp"; do
1819     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; fi
1820   done
1821   for f in "/usr/lpp/X11/bin/smt.exp" "/usr/bin/X11/smt.exp"; do
1822     if test -r "$f"; then start_flags="${start_flags},-bI:${f}"; break; fi
1823   done
1824   AC_CHECK_LIB(C, terminateAndUnload, XE_APPEND(-lC, libs_system))
1825   fi
1826 elif test -n "$ld_text_start_addr"; then
1827   start_flags="-T $ld_text_start_addr -e __start"
1828 fi
1829 AC_SUBST(start_flags)
1830
1831 AC_SUBST(ld_switch_shared)
1832 AC_SUBST(start_files)
1833 if test "$ordinary_link" = "no" -a "$GCC" = "yes"; then
1834  test -z "$linker" &&  linker='$(CC) -nostdlib'
1835  test -z "$lib_gcc" && lib_gcc='`$(CC) -print-libgcc-file-name`'
1836 fi
1837 test "$GCC" != "yes" && lib_gcc=
1838 AC_SUBST(ld)
1839 AC_SUBST(lib_gcc)
1840
1841 dnl ---------------------------------------------------------------
1842 dnl Add site and system specific flags to compile and link commands
1843 dnl ---------------------------------------------------------------
1844
1845 dnl Allow use of either ":" or spaces for lists of directories
1846 define(COLON_TO_SPACE,
1847   [case "$[$1]" in *:* [)] [$1]="`echo '' $[$1] | sed -e 's/^ //' -e 's/:/ /g'`";; esac])dnl
1848
1849 dnl --site-libraries (multiple dirs)
1850 COLON_TO_SPACE(site_libraries)
1851 if test -n "$site_libraries"; then
1852   for arg in $site_libraries; do
1853     case "$arg" in
1854      -* ) ;;
1855      * ) test -d "$arg" || \
1856            XE_DIE("Invalid site library \`$arg': no such directory")
1857        arg="-L${arg}" ;;
1858     esac
1859     XE_APPEND($arg, ld_switch_site)
1860   done
1861 fi
1862
1863 dnl --site-includes (multiple dirs)
1864 COLON_TO_SPACE(site_includes)
1865 if test -n "$site_includes"; then
1866   for arg in $site_includes; do
1867     case "$arg" in
1868       -* ) ;;
1869       * ) test -d "$arg" || \
1870            XE_DIE("Invalid site include \`$arg': no such directory")
1871       arg="-I${arg}" ;;
1872     esac
1873     XE_APPEND($arg, c_switch_site)
1874   done
1875 fi
1876
1877 dnl --site-prefixes (multiple dirs)
1878 dnl --site-prefixes=dir1:dir2 is a convenient shorthand for
1879 dnl --site-libraries=dir1/lib:dir2/lib --site-includes=dir1/include:dir2/include
1880 dnl Site prefixes take precedence over the standard places, but not over
1881 dnl site-includes and site-libraries.
1882 COLON_TO_SPACE(site_prefixes)
1883 if test -n "$site_prefixes"; then
1884   for dir in $site_prefixes; do
1885     inc_dir="${dir}/include"
1886     lib_dir="${dir}/lib"
1887     if test ! -d "$dir"; then
1888       XE_DIE("Invalid site prefix \`$dir': no such directory")
1889     elif test ! -d "$inc_dir"; then
1890       XE_DIE("Invalid site prefix \`$dir': no such directory \`$inc_dir'")
1891     elif test ! -d "$lib_dir"; then
1892       XE_DIE("Invalid site prefix \`$dir': no such directory \`$lib_dir'")
1893     else
1894       XE_APPEND("-I$inc_dir", c_switch_site)
1895       XE_APPEND("-L$lib_dir", ld_switch_site)
1896     fi
1897   done
1898 fi
1899
1900 dnl GNU software installs by default into /usr/local/{include,lib}
1901 dnl if test -d "/usr/local/include" -a -d "/usr/local/lib"; then
1902 dnl   XE_APPEND("-L/usr/local/lib",    ld_switch_site)
1903 dnl   XE_APPEND("-I/usr/local/include", c_switch_site)
1904 dnl fi
1905
1906 dnl Extra system-specific library directories - please add to list
1907 for dir in "/usr/ccs/lib"; do
1908   test -d "$dir" && XE_APPEND(-L${dir}, ld_switch_site)
1909 done
1910
1911 dnl --site-runtime-libraries (multiple dirs)
1912 COLON_TO_SPACE(site_runtime_libraries)
1913 if test -n "$site_runtime_libraries"; then
1914   LD_RUN_PATH="`echo $site_runtime_libraries | sed -e 's/  */:/g'`"
1915   export LD_RUN_PATH
1916 fi
1917
1918 dnl -------------------------------------
1919 dnl Compute runtime library path
1920 dnl -------------------------------------
1921
1922 if   test "$dynamic" = "no"; then add_runtime_path=no
1923 elif test -n "$LD_RUN_PATH"; then add_runtime_path=yes
1924 else case "$opsys" in
1925        sol2 | irix* | *bsd* | decosf* ) add_runtime_path=yes ;;
1926        * ) add_runtime_path=no ;;
1927      esac
1928 fi
1929
1930 if test "$add_runtime_path" = "yes"; then
1931   dnl Try to autodetect runtime library flag (usually -R),
1932   dnl and whether it works (or at least does no harm)
1933   AC_MSG_CHECKING("for runtime libraries flag")
1934   case "$opsys" in
1935     sol2 ) dash_r="-R" ;;
1936     decosf* | linux* | irix*) dash_r="-rpath " ;;
1937     *)
1938       dash_r=""
1939       for try_dash_r in "-R" "-R " "-rpath "; do
1940         xe_check_libs="${try_dash_r}/no/such/file-or-directory"
1941         XE_PROTECT_LINKER_FLAGS(xe_check_libs)
1942         AC_TRY_LINK(, , dash_r="$try_dash_r")
1943         xe_check_libs=""
1944         test -n "$dash_r" && break
1945       done ;;
1946   esac
1947   if test -n "$dash_r";
1948     then AC_MSG_RESULT("\"${dash_r}\"")
1949     else AC_MSG_RESULT(NONE)
1950   fi
1951 fi
1952
1953 xe_add_unique_runpath_dir='
1954   xe_add_p=yes
1955   for xe_dir in $runpath_dirs; do   dnl Uniquify
1956     test "$xe_dir" = "$xe_runpath_dir" && xe_add_p=no
1957   done
1958   if test "$xe_add_p" = "yes"; then
1959     test -n "$runpath" && runpath="${runpath}:"
1960     runpath="${runpath}${xe_runpath_dir}"
1961     runpath_dirs="$runpath_dirs $xe_runpath_dir"
1962   fi'
1963
1964
1965 dnl XE_ADD_RUNPATH_DIR(directory)
1966 define([XE_ADD_RUNPATH_DIR],[{
1967 xe_runpath_dir=$1
1968 dnl PRINT_VAR(ld_switch_site ld_switch_x_site runpath xe_runpath_dir LD_RUN_PATH xe_ldflags)
1969   test "$xe_runpath_dir" != "/lib"     -a \
1970         "$xe_runpath_dir" != "/usr/lib" -a \
1971         -n "`ls ${xe_runpath_dir}/*.s[[ol]] 2>/dev/null`" && \
1972   eval "$xe_add_unique_runpath_dir"
1973 }])dnl
1974
1975 dnl XE_COMPUTE_RUNPATH()
1976 define([XE_COMPUTE_RUNPATH],[
1977 if test "$add_runtime_path" = "yes" -a -n "$dash_r"; then
1978   dnl Remove runtime paths from current ld switches
1979   ld_switch_site=`echo   '' $ld_switch_site   | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
1980   ld_switch_x_site=`echo '' $ld_switch_x_site | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
1981   dnl PRINT_VAR(ld_switch_site ld_switch_x_site)
1982
1983   dnl Fix up Runtime path
1984   dnl If LD_RUN_PATH is set in environment, use that.
1985   dnl In this case, assume user has set the right value.
1986   runpath="" runpath_dirs=""
1987   if test -n "$LD_RUN_PATH"; then
1988     runpath="$LD_RUN_PATH"
1989   elif test "$GCC" = "yes"; then
1990     dnl Compute runpath from gcc's -v output
1991     ld_switch_run_save="$ld_switch_run"; ld_switch_run=""
1992     echo "int main(int argc, char *argv[[]]) {return 0;}" > conftest.c
1993     xe_runpath_link='${CC-cc} -o conftest -v $CFLAGS '"$xe_ldflags"' conftest.$ac_ext 2>&1 1>/dev/null'
1994     for arg in `eval "$xe_runpath_link" | grep ' -L'`; do
1995       case "$arg" in P,* | -L* | -R* )
1996         for dir in `echo '' "$arg" | sed -e 's:^ ::' -e 's/^..//' -e 'y/:/ /'`; do
1997           XE_ADD_RUNPATH_DIR("$dir")
1998         done ;;
1999       esac
2000     done
2001     ld_switch_run="$ld_switch_run_save"
2002     rm -f conftest*
2003   else
2004     dnl Add all directories with .so files to runpath
2005     for arg in $ld_switch_site $ld_switch_x_site; do
2006       case "$arg" in -L*) XE_ADD_RUNPATH_DIR(`echo '' "$arg" | sed -e 's:^ ::' -e 's/^-L//'`);; esac
2007     done
2008     dnl Sometimes /opt/SUNWdt/lib is the only installed Motif available
2009     if test "$opsys $need_motif" = "sol2 yes"; then
2010       xe_runpath_dir="/opt/SUNWdt/lib";
2011       eval "$xe_add_unique_runpath_dir";
2012     fi
2013   fi dnl Compute $runpath
2014
2015   if test -n "$runpath"; then
2016     ld_switch_run="${dash_r}${runpath}"
2017     XE_PROTECT_LINKER_FLAGS(ld_switch_run)
2018     test "$extra_verbose" = "yes" && echo "Setting runpath to $runpath"
2019   fi
2020 fi
2021 ])dnl
2022 XE_COMPUTE_RUNPATH()
2023
2024 dnl JKJ REMOVEME
2025 dnl XE_SHLIB_STUFF
2026
2027 dnl -----------------------------------
2028 dnl Do some misc autoconf-special tests
2029 dnl -----------------------------------
2030
2031 dnl Do the opsystem or machine files prohibit the use of the GNU malloc?
2032 dnl Assume not, until told otherwise.
2033 GNU_MALLOC=yes
2034 if test "$with_dlmalloc" != "no"; then
2035         doug_lea_malloc=yes
2036 else
2037         doug_lea_malloc=no
2038 fi
2039 after_morecore_hook_exists=yes
2040 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
2041 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
2042 AC_MSG_CHECKING(whether __after_morecore_hook exists)
2043 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
2044   [AC_MSG_RESULT(yes)],
2045   [AC_MSG_RESULT(no)
2046    after_morecore_hook_exists=no])
2047 if test "$system_malloc" = "yes" ; then
2048   GNU_MALLOC=no
2049   GNU_MALLOC_reason="
2050   (The GNU allocators don't work with this system configuration)."
2051 elif test "$with_system_malloc" = "yes" ; then
2052   GNU_MALLOC=no
2053   GNU_MALLOC_reason="
2054   (User chose not to use GNU allocators)."
2055 elif test "$with_debug_malloc" = "yes" ; then
2056   GNU_MALLOC=no
2057   GNU_MALLOC_reason="
2058   (User chose to use Debugging Malloc)."
2059 fi
2060
2061 if test "$doug_lea_malloc" = "yes" ; then
2062   if test "$GNU_MALLOC" = yes ; then
2063     GNU_MALLOC_reason="
2064   (Using Doug Lea's new malloc from the GNU C Library.)"
2065   fi
2066   AC_DEFINE(DOUG_LEA_MALLOC)
2067   if test "$after_morecore_hook_exists" = "no" ; then
2068     GNU_MALLOC_reason="
2069   (Using Doug Lea's new malloc from the Linux C Library.)"
2070     AC_DEFINE(_NO_MALLOC_WARNING_)
2071   fi
2072   use_minimal_tagbits=yes
2073 fi
2074
2075 dnl #### mcheck is broken in all versions of Linux libc and glibc.
2076 dnl Try this again when 2.1 hits the streets.
2077 dnl Avoid using free-hook.c if support exists for malloc debugging in libc
2078 dnl have_libmcheck=no
2079 dnl if test "$error_check_malloc" = "yes" -a \
2080 dnl    "$have_glibc" = "yes" -a \
2081 dnl    "$doug_lea_malloc" = "yes"; then
2082 dnl   AC_CHECK_HEADERS(mcheck.h)
2083 dnl   AC_CHECK_LIB(mcheck, mcheck, have_libmcheck=yes, have_libmcheck=no)
2084 dnl fi
2085
2086 dnl if test "$have_libmcheck" = "yes"; then
2087 dnl   AC_DEFINE(HAVE_LIBMCHECK)
2088 dnl   libmcheck=-lmcheck
2089 dnl   AC_SUBST(libmcheck)
2090 dnl fi
2091
2092 dnl Some other nice autoconf tests.  If you add a test here which
2093 dnl should make an entry in src/config.h, do not forget to add an
2094 dnl #undef clause to src/config.h.in for autoconf to modify.
2095
2096 AC_PROG_RANLIB
2097 AC_PROG_INSTALL
2098 AC_PROG_YACC
2099
2100 dnl checks for header files
2101 AC_CHECK_HEADERS(mach/mach.h sys/stropts.h sys/timeb.h sys/time.h unistd.h)
2102 AC_CHECK_HEADERS(utime.h locale.h libgen.h fcntl.h ulimit.h cygwin/version.h)
2103 AC_CHECK_HEADERS(kstat.h sys/pstat.h inttypes.h sys/un.h a.out.h)
2104 AC_HEADER_SYS_WAIT
2105 AC_HEADER_STDC
2106 AC_HEADER_TIME
2107 AC_DECL_SYS_SIGLIST
2108
2109 dnl Some systems have utime.h but do not declare the struct anyplace.
2110 AC_MSG_CHECKING(for struct utimbuf)
2111 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
2112 #include <sys/time.h>
2113 #include <time.h>
2114 #else
2115 #ifdef HAVE_SYS_TIME_H
2116 #include <sys/time.h>
2117 #else
2118 #include <time.h>
2119 #endif
2120 #endif
2121 #ifdef HAVE_UTIME_H
2122 #include <utime.h>
2123 #endif], [static struct utimbuf x; x.actime = x.modtime;],
2124   [AC_MSG_RESULT(yes)
2125    AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
2126   AC_MSG_RESULT(no))
2127
2128 dnl checks for typedefs
2129 AC_TYPE_SIGNAL
2130 AC_TYPE_SIZE_T
2131 AC_TYPE_PID_T
2132 AC_TYPE_UID_T
2133 AC_TYPE_MODE_T
2134 AC_TYPE_OFF_T
2135
2136 AC_MSG_CHECKING(for struct timeval)
2137 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
2138 #include <sys/time.h>
2139 #include <time.h>
2140 #else
2141 #ifdef HAVE_SYS_TIME_H
2142 #include <sys/time.h>
2143 #else
2144 #include <time.h>
2145 #endif
2146 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
2147   [AC_MSG_RESULT(yes)
2148   HAVE_TIMEVAL=yes
2149   AC_DEFINE(HAVE_TIMEVAL)],
2150   [AC_MSG_RESULT(no)
2151    HAVE_TIMEVAL=no])
2152
2153 dnl checks for structure members
2154 AC_STRUCT_TM
2155 AC_STRUCT_TIMEZONE
2156
2157 dnl checks for compiler characteristics
2158 AC_C_CONST
2159
2160 dnl check for Make feature
2161 AC_PROG_MAKE_SET
2162
2163 dnl check byte order
2164 AC_C_BIGENDIAN
2165
2166 dnl define SIZEOF_TYPE
2167 AC_CHECK_SIZEOF(short)
2168 if test "$ac_cv_sizeof_short" = 0; then
2169   echo ""
2170   echo "*** PANIC *** Configure tests are not working - compiler is broken."
2171   echo "*** PANIC *** Please examine config.log for compilation errors."
2172   exit 1
2173 fi
2174 AC_CHECK_SIZEOF(int)
2175 AC_CHECK_SIZEOF(long)
2176 AC_CHECK_SIZEOF(long long)
2177 AC_CHECK_SIZEOF(void *)
2178
2179 dnl check for long file names
2180 AC_SYS_LONG_FILE_NAMES
2181
2182 dnl -lm is required by LISP_FLOAT_TYPE, among other things
2183 AC_CHECK_FUNC(sin, ,AC_CHECK_LIB(m, sin))
2184
2185 dnl Floating operation support is now unconditional
2186 AC_DEFINE(LISP_FLOAT_TYPE)
2187
2188 AC_TRY_LINK([#include <math.h>],
2189   [return atanh(1.0) + asinh(1.0) + acosh(1.0); ],
2190   AC_DEFINE(HAVE_INVERSE_HYPERBOLIC))
2191
2192 dnl Determine type of mail locking from configure args and s&m headers
2193 AC_CHECKING(type of mail spool file locking)
2194 test -z "$mail_locking" -a "$mail_use_flock" = "yes" && mail_locking=flock
2195 test -z "$mail_locking" -a "$mail_use_lockf" = "yes" && mail_locking=lockf
2196 if   test "$mail_locking" = "lockf"; then AC_DEFINE(REAL_MAIL_USE_LOCKF)
2197 elif test "$mail_locking" = "flock"; then AC_DEFINE(REAL_MAIL_USE_FLOCK)
2198 else mail_locking="dot-locking"
2199 fi
2200
2201 case "$opsys" in decosf*)
2202   AC_CHECK_LIB(pthreads, cma_open)
2203   test "$ac_cv_lib_pthreads_cma_open" = "yes" && \
2204     c_switch_site="$c_switch_site -threads" ;;
2205 esac
2206
2207 AC_MSG_CHECKING(whether the -xildoff compiler flag is required)
2208 if   ${CC-cc} '-###' -xildon  no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ; then
2209   if ${CC-cc} '-###' -xildoff no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ;
2210     then AC_MSG_RESULT(no);
2211     else AC_MSG_RESULT(yes); XE_APPEND(-xildoff, ld_switch_site)
2212   fi
2213   else AC_MSG_RESULT(no)
2214 fi
2215
2216 dnl Link with "-z ignore" on Solaris if supported
2217 if test "$opsys" = "sol2" && test "$OS_RELEASE" -ge 56; then
2218   AC_MSG_CHECKING(for \"-z ignore\" linker flag)
2219   case "`ld -h 2>&1`" in
2220     *-z\ ignore\|record* ) AC_MSG_RESULT(yes)
2221       XE_PREPEND(-z ignore, ld_switch_site) ;;
2222     *) AC_MSG_RESULT(no) ;;
2223   esac
2224 fi
2225
2226 dnl ----------------------
2227 dnl Choose a window system
2228 dnl ----------------------
2229
2230 AC_CHECKING("for specified window system")
2231
2232 if test "$with_x11" != "no"; then
2233   dnl User-specified --x-includes or --x-libraries implies --with-x11.
2234   test "$x_includes $x_libraries" != "NONE NONE" && \
2235    window_system=x11 with_x11=yes
2236
2237   dnl Autodetection of X11 libraries and includes
2238   dnl -------------------------------------------
2239   dnl AC_PATH_XTRA thinks it can find our X headers and includes, but
2240   dnl it often gets it wrong, so we only use it as a last resort.
2241
2242   dnl $OPENWINHOME implies --x-includes and --x-libraries
2243   dnl Not (yet) handled by autoconf2
2244   if test "$x_includes $x_libraries" = "NONE NONE" \
2245     -a -n "$OPENWINHOME" \
2246     -a "$OPENWINHOME" != "/usr/openwin" \
2247     -a -d "$OPENWINHOME"; then
2248       test -d "$OPENWINHOME/lib"           && x_libraries="$OPENWINHOME/lib"
2249       test -d "$OPENWINHOME/include"       && x_includes="$OPENWINHOME/include"
2250       test -d "$OPENWINHOME/share/include" && x_includes="$OPENWINHOME/share/include"
2251   fi
2252
2253   if test "$x_includes" = "NONE"; then
2254     dnl AC_PATH_XTRA often guesses /usr/include, when some other
2255     dnl include directory is a MUCH better guess (Linux, HP-UX 10.20).
2256     dnl This is a workaround for idiot (esp. HP) system vendors, who
2257     dnl provide a /usr/include/X11, but DON'T FULLY POPULATE IT.
2258     for dir in "/usr/X11" "/usr/X11R6"; do
2259       if test -d "$dir/include/X11"; then x_includes="$dir/include"; break; fi
2260     done
2261   fi
2262
2263   if test "$x_libraries" = "NONE"; then
2264     for dir in "/usr/X11/lib" "/usr/X11R6/lib" "/usr/lib/X11R6"; do
2265       if test -r "$dir/libX11.a"; then x_libraries="$dir"; break; fi
2266     done
2267   fi
2268
2269   AC_PATH_XTRA # Autoconf claims to find X library and include dirs for us.
2270   if test "$no_x" = "yes"
2271   then with_x11=no  window_system=none HAVE_X_WINDOWS=no
2272   else with_x11=yes window_system=x11  HAVE_X_WINDOWS=yes
2273   fi
2274 fi
2275
2276 case "$with_x11" in
2277   yes ) window_system=x11  HAVE_X_WINDOWS=yes ;;
2278   no  ) window_system=none HAVE_X_WINDOWS=no  ;;
2279 esac
2280
2281 if test "$with_x11" = "yes"; then
2282   AC_DEFINE(HAVE_X_WINDOWS)
2283   XE_APPEND(lwlib, MAKE_SUBDIR)
2284   XE_APPEND(lwlib, SRC_SUBDIR_DEPS)
2285
2286   dnl Try to find Motif/CDE/Tooltalk dirs
2287   dnl These take precedence over other X libs/includes, so PRE-pend
2288   for lib_dir in "/usr/dt/lib" "/usr/lib/Motif2.1" "/usr/lib/Motif1.2" "/usr/lib/Motif1.1"; do
2289     inc_dir=`echo $lib_dir | sed -e 's/lib/include/'`
2290     if test -d "$lib_dir" -a -d "$inc_dir"; then
2291       case "$x_libraries" in *"$lib_dir"* ) ;; *)
2292         x_libraries="$lib_dir $x_libraries"
2293         XE_PREPEND(-L${lib_dir}, X_LIBS) ;;
2294       esac
2295       case "$x_includes" in "$inc_dir"* ) ;; *)
2296         x_includes="$inc_dir $x_includes"
2297         XE_PREPEND(-I${inc_dir}, X_CFLAGS) ;;
2298       esac
2299       break; dnl only need ONE Motif implementation!
2300       fi
2301   done
2302
2303   dnl Contrib X libs/includes do NOT take precedence, so AP-pend
2304   for rel in "X11R6" "X11R5" "X11R4"; do
2305     lib_dir="/usr/contrib/$rel/lib" inc_dir="/usr/contrib/$rel/include"
2306     if test -d "$lib_dir" -a -d "$inc_dir"; then
2307       case "$x_libraries" in *"$lib_dir"* ) ;; *)
2308         x_libraries="$x_libraries $lib_dir"
2309         XE_APPEND(-L${lib_dir}, X_LIBS)
2310       esac
2311       case "$x_includes" in "$inc_dir"* ) ;; *)
2312         x_includes="$x_includes $inc_dir"
2313         XE_APPEND(-I${inc_dir}, X_CFLAGS)
2314       esac
2315       break; dnl Only need ONE X11 implementation !
2316     fi
2317   done
2318
2319   dnl Avoid version mismatch for shared library libXm.so on osf4
2320   if test "$GCC" = yes -a -d /usr/shlib; then XE_APPEND(-L/usr/shlib, X_LIBS); fi
2321
2322   ld_switch_x_site="$X_LIBS"
2323
2324   XE_COMPUTE_RUNPATH()
2325
2326   if test "$extra_verbose" = "yes"; then
2327     echo; echo "X11 compilation variables:"
2328     PRINT_VAR(x_libraries x_includes X_CFLAGS X_LIBS X_PRE_LIBS X_EXTRA_LIBS)
2329     echo
2330   fi
2331
2332   dnl Set up bitmaps search path.
2333   dnl The original suggestion was to unconditionally to append X11/bitmaps
2334   dnl to each element of $x_includes, I'm pretty sure this is the wrong
2335   dnl thing to do.  We test for bitmaps and X11/bitmaps directories on each
2336   dnl element and add them to BITMAPDIR if they exist.
2337   bitmapdirs=
2338   if test "$x_includes" != NONE; then
2339     for i in $x_includes; do
2340       if test -d "$i/bitmaps"; then
2341         bitmapdirs="$i/bitmaps:$bitmapdirs"
2342       fi
2343       if test -d "$i/X11/bitmaps"; then
2344         bitmapdirs="$i/X11/bitmaps:$bitmapdirs"
2345       fi
2346     done
2347     bitmapdirs=`echo "$bitmapdirs" | sed s/.$//`
2348   fi
2349   test ! -z "$bitmapdirs" && AC_DEFINE_UNQUOTED(BITMAPDIR, "$bitmapdirs")
2350
2351   dnl Autodetect defines extracted from X config by xmkmf, e.g. NARROWPROTO
2352   AC_CHECKING(for X defines extracted by xmkmf)
2353   rm -fr conftestdir
2354   if mkdir conftestdir; then
2355     cd conftestdir
2356     cat > Imakefile <<'EOF'
2357 xetest:
2358         @echo ${PROTO_DEFINES} ${STD_DEFINES}
2359 EOF
2360     if (xmkmf) >/dev/null 2>/dev/null && test -f Makefile; then
2361       # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
2362       xmkmf_defines=`${MAKE-make} xetest 2>/dev/null | grep -v make`
2363     fi
2364     cd ..
2365     rm -fr conftestdir
2366     for word in $xmkmf_defines; do
2367       case "$word" in
2368         -D*=* ) ;;
2369         -D* ) word=`echo '' $word | sed -e 's:^ *-D::'`
2370               AC_DEFINE_UNQUOTED($word) ;;
2371       esac
2372     done
2373   fi
2374
2375   dnl make sure we can find Intrinsic.h
2376   AC_CHECK_HEADER(X11/Intrinsic.h, ,
2377    [AC_MSG_ERROR("Unable to find X11 header files.")])
2378
2379   dnl -lXt and -lX11 are required
2380   dnl Some broken systems require the magic "-b i486-linuxaout" flag
2381   AC_CHECK_LIB(X11, XOpenDisplay, have_lib_x11=yes)
2382   if test "$have_lib_x11" != "yes"; then
2383     AC_CHECK_LIB(X11, XGetFontProperty,
2384       ld_switch_x_site="-b i486-linuxaout $ld_switch_x_site",
2385       [AC_MSG_ERROR("Unable to find X11 libraries.")],
2386       -b i486-linuxaout)
2387   fi
2388   libs_x="-lX11"
2389   test "$extra_verbose" = "yes" && echo "    Setting libs_x to \"-lX11\""
2390
2391   dnl Autodetect -lXext
2392   AC_CHECK_LIB(Xext, XShapeSelectInput, XE_PREPEND(-lXext, libs_x))
2393
2394   dnl Require -lXt
2395   AC_CHECK_LIB(Xt, XtOpenDisplay, XE_PREPEND(-lXt, libs_x),
2396     AC_MSG_ERROR("Unable to find X11 libraries."))
2397
2398   AC_MSG_CHECKING(the version of X11 being used)
2399   AC_TRY_RUN([#include <X11/Intrinsic.h>
2400     int main(int c, char *v[]) { return c>1 ? XlibSpecificationRelease : 0; }],
2401     [./conftest foobar; x11_release=$?],[x11_release=4],[x11_release=4])
2402   AC_MSG_RESULT(R${x11_release})
2403   AC_DEFINE_UNQUOTED(THIS_IS_X11R${x11_release})
2404
2405   AC_CHECK_HEADERS(X11/Xlocale.h)
2406
2407   dnl remove this - we should avoid checking for specific OS
2408   AC_MSG_CHECKING(for XFree86)
2409   if test -d "/usr/X386/include" -o \
2410           -f "/etc/XF86Config"    -o \
2411           -f "/etc/X11/XF86Config" -o \
2412           -f "/usr/X11R6/lib/X11/XF86Config"; then
2413     AC_MSG_RESULT(yes)
2414     AC_DEFINE(HAVE_XFREE386)
2415   else
2416     AC_MSG_RESULT(no)
2417   fi
2418
2419   dnl autodetect -lXmu
2420   test -z "$with_xmu" && { AC_CHECK_LIB(Xmu, XmuReadBitmapDataFromFile,
2421                            with_xmu=yes, with_xmu=no) }
2422   if test "$with_xmu" = "no"; then
2423     XE_ADD_OBJS(xmu.o)
2424   else
2425     XE_PREPEND(-lXmu, libs_x)
2426     AC_DEFINE(HAVE_XMU)
2427   fi
2428
2429   dnl Autodetect -lXbsd
2430   dnl #### Someone, please add a better function than main
2431   AC_CHECK_LIB(Xbsd, main, XE_PREPEND(-lXbsd, libs_x))
2432
2433   dnl Problem with the MIT distribution of X on AIX
2434   if test "$unexec" = "unexaix.o" -a "$x11_release" = "6"; then
2435     dnl X11R6 requires thread-safe code on AIX for some reason
2436     if test "$GCC" = "yes"; then
2437       XE_PREPEND(-mthreads, X_CFLAGS)
2438       XE_PREPEND(-mthreads, libs_x)
2439     else
2440       case "$CC" in
2441         "xlc" ) CC="xlc_r" ;;
2442         "xlC" ) CC="xlC_r" ;;
2443         "cc"  ) CC="cc_r" ;;
2444       esac
2445     fi
2446   fi
2447
2448 fi dnl $with_x11 = yes
2449
2450 if test "$with_msw" != "no"; then
2451   AC_CHECKING(for MS-Windows)
2452   AC_CHECK_LIB(gdi32,main,with_msw=yes)
2453   if test "$with_msw" = "yes"; then
2454     AC_DEFINE(HAVE_MS_WINDOWS)
2455     install_pp="$blddir/lib-src/installexe.sh"
2456     XE_APPEND(-lshell32 -lgdi32 -luser32 -lcomctl32, libs_system)
2457     test "$with_dragndrop" != no && XE_APPEND(msw, dragndrop_proto)
2458     if test "$window_system" != x11; then
2459         window_system=msw
2460         test "$with_scrollbars" != "no" && with_scrollbars=msw \
2461             && XE_ADD_OBJS(scrollbar-msw.o)
2462         test "$with_menubars"   != "no" && with_menubars=msw \
2463             && XE_ADD_OBJS(menubar-msw.o)
2464         test "$with_toolbars"   != "no" && with_toolbars=msw \
2465             && XE_ADD_OBJS(toolbar-msw.o)
2466         test "$with_dialogs"   != "no" && with_dialogs=msw \
2467             && XE_ADD_OBJS(dialog-msw.o)
2468     else
2469         test "$with_scrollbars" != "no" && XE_ADD_OBJS(scrollbar-msw.o)
2470         test "$with_menubars"   != "no" && XE_ADD_OBJS(menubar-msw.o)
2471         test "$with_toolbars"   != "no" && XE_ADD_OBJS(toolbar-msw.o)
2472         test "$with_dialogs"    != "no" && XE_ADD_OBJS(dialog-msw.o)
2473     fi
2474     dnl check for our special version of select
2475     AC_TRY_RUN([#include <fcntl.h>
2476     int main() { return (open("/dev/windows", O_RDONLY, 0) > 0)? 0 : 1; }],
2477     [AC_DEFINE(HAVE_MSG_SELECT)])
2478     const_is_losing=no
2479     with_file_coding=yes
2480     XE_ADD_OBJS(console-msw.o device-msw.o event-msw.o frame-msw.o objects-msw.o select-msw.o redisplay-msw.o glyphs-msw.o gui-msw.o)
2481   fi
2482 fi
2483
2484 AC_SUBST(install_pp)
2485
2486 test -z "$window_system" && window_system="none"
2487
2488 dnl Test for features that require a window system - ANY window system
2489 if test "$window_system" = "none"; then
2490   for feature in menubars scrollbars toolbars dialogs dragndrop xface
2491   do
2492     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2493        AC_MSG_WARN([--with-$feature ignored:  Not valid without window system support])
2494     fi
2495     eval "with_${feature}=no"
2496   done
2497 else
2498   test -z "$with_toolbars" && with_toolbars=yes
2499 fi
2500
2501 dnl ### Test for features that require mswindows support - currently none
2502 dnl ### MS-Windows folks: add code here..... (martin)
2503 if test "$with_msw" != "yes"; then
2504   for feature in   MARTIN_IS_CLUELESS_ABOUT_MSW_FEATURES
2505   do
2506     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2507        AC_MSG_WARN([--with-$feature ignored:  Not valid without MS-Windows support])
2508     fi
2509     eval "with_${feature}=no"
2510   done
2511 else
2512   :
2513 fi
2514
2515 dnl Test for features that require X11 support
2516 if test "$with_x11" != "yes"; then
2517   dnl It ought to be reasonable to have no output device at all, and only use
2518   dnl XEmacs in --batch mode.
2519   dnl if test "$with_tty" = "no" ; then
2520   dnl   AC_MSG_ERROR([No window system support and no TTY support - Unable to proceed.])
2521   dnl fi
2522   for feature in tooltalk cde offix session xim xmu
2523   do
2524     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
2525        AC_MSG_WARN([--with-$feature ignored:  Not valid without X support])
2526     fi
2527     eval "with_${feature}=no"
2528   done
2529 fi
2530
2531 dnl FSF 19.29 has some bitmapdir stuff here.
2532 bitmapdir=
2533
2534 case "$window_system" in
2535   x11  ) HAVE_X_WINDOWS=yes; echo "  Using X11." ;;
2536   msw  ) HAVE_X_WINDOWS=no ; echo "  Using MS-Windows." ;;
2537   none ) HAVE_X_WINDOWS=no ; echo "  Using no window system." ;;
2538 esac
2539
2540 case "$x_libraries" in *X11R4* )
2541   test "$opsys" = "hpux9"     && opsysfile="s/hpux9-x11r4.h"
2542   test "$opsys" = "hpux9-shr" && opsysfile="s/hpux9shxr4.h"
2543 esac
2544
2545 dnl Enable or disable proper session-management
2546 AC_CHECKING(for session-management option);
2547 dnl if test "$with_session" = "yes"; then
2548 if test "$with_session" != "no"; then
2549   AC_DEFINE(HAVE_SESSION)
2550 fi
2551
2552 dnl Autodetect Xauth
2553 dnl -lXau is only used by gnuclient, so use a special variable for Xauth X libs
2554 test -z "$with_xauth" && test "$window_system" = "none" && with_xauth=no
2555 test -z "$with_xauth" && { AC_CHECK_HEADER(X11/Xauth.h,          ,with_xauth=no) }
2556 test -z "$with_xauth" && { AC_CHECK_LIB(Xau, XauGetAuthByAddr,[:],with_xauth=no) }
2557 test -z "$with_xauth" && with_xauth=yes
2558 if test "$with_xauth" = "yes"; then
2559   AC_DEFINE(HAVE_XAUTH)
2560   XE_SPACE(libs_xauth, $X_EXTRA_LIBS -lXau $libs_x $X_PRE_LIBS)
2561 fi
2562 AC_SUBST(libs_xauth)
2563
2564 dnl This one is for the static initializeds variables in
2565 dnl offix.c, so that the thing is dumped after lastfile.o
2566 AC_SUBST(dnd_objs)
2567
2568 dnl Autodetect tooltalk
2569 if test "$with_tooltalk" != "no" ; then
2570   dnl autodetect the location of tt_c.h
2571   dnl tt_c.h might be in Tt or desktop include directories
2572   for dir in "" "Tt/" "desktop/" ; do
2573     AC_CHECK_HEADER(${dir}tt_c.h, tt_c_h_path="${dir}tt_c.h"; break)
2574   done
2575   if test -z "$tt_c_h_path"; then
2576     if test "$with_tooltalk" = "yes"; then
2577       USAGE_ERROR("Unable to find required tooltalk header files.")
2578     fi
2579     with_tooltalk=no
2580   fi
2581 fi
2582 if test "$with_tooltalk" != "no" ; then
2583   for extra_libs in "" "-lI18N -lce" "-lcxx"; do
2584     AC_CHECK_LIB(tt, tt_message_create,
2585       tt_libs="-ltt $extra_libs"; break, [:],$extra_libs)
2586   done
2587   if test -z "$tt_libs"; then
2588     if test "$with_tooltalk" = "yes"; then
2589       USAGE_ERROR("Unable to find required tooltalk libraries.")
2590     fi
2591     with_tooltalk=no
2592   fi
2593 fi
2594 test -z "$with_tooltalk" && with_tooltalk=yes
2595 if test "$with_tooltalk" = "yes"; then
2596   AC_DEFINE(TOOLTALK)
2597   AC_DEFINE_UNQUOTED(TT_C_H_PATH, "$tt_c_h_path")
2598   XE_PREPEND($tt_libs, libs_x)
2599   XE_ADD_OBJS(tooltalk.o)
2600 fi
2601
2602 dnl Autodetect CDE
2603 test -z "$with_cde" && { AC_CHECK_HEADER(Dt/Dt.h,               , with_cde=no) }
2604 test -z "$with_cde" && { AC_CHECK_LIB(DtSvc, DtDndDragStart, [:], with_cde=no) }
2605 test -z "$with_cde" && with_cde=yes
2606 if test "$with_dragndrop" = no; then
2607   AC_MSG_WARN([No CDE without generic Drag'n'Drop support])
2608   with_cde=no
2609 fi
2610 if test "$with_cde" = "yes" ; then
2611   AC_DEFINE(HAVE_CDE)
2612   XE_PREPEND(-lDtSvc, libs_x)
2613   XE_APPEND(CDE, dragndrop_proto)
2614   with_tooltalk=yes # CDE requires Tooltalk
2615   need_motif=yes    # CDE requires Motif
2616 fi
2617
2618 dnl Always compile OffiX unless --without-offix is given, no
2619 dnl X11 support is compiled in, no standard Xmu is available,
2620 dnl or dragndrop support is disabled
2621 dnl Because OffiX support currently loses when more than one display
2622 dnl is in use, we now disable it by default -slb 07/10/1998.
2623 test "$window_system" != "x11" && with_offix=no
2624 if test "$with_xmu" != yes -a "$with_x11" = yes; then
2625   AC_MSG_WARN([No OffiX without real Xmu support])
2626   with_offix=no
2627 fi
2628 if test "$with_dragndrop" = no; then
2629   AC_MSG_WARN([No OffiX without generic Drag'n'Drop support])
2630   with_offix=no
2631 fi
2632 if test "$with_cde" = yes; then
2633   AC_MSG_WARN([CDE already found, disabling OffiX support])
2634   with_offix=no
2635 fi
2636 test -z "$with_offix" && with_offix=no
2637 if test "$with_offix" = "yes"; then
2638   AC_DEFINE(HAVE_OFFIX_DND)
2639   XE_APPEND(offix.o, dnd_objs)
2640   XE_APPEND(OffiX, dragndrop_proto)
2641 fi
2642
2643 dnl Autodetect Drag'n'Drop support
2644 dnl always included if CDE, Offix, or MSWindows are defined
2645 AC_MSG_CHECKING(if drag and drop API is needed)
2646 if test "$with_dragndrop" != "no" ; then
2647   if test -n "$dragndrop_proto" ; then
2648     with_dragndrop=yes
2649     AC_MSG_RESULT([yes (${dragndrop_proto} )])
2650     AC_DEFINE(HAVE_DRAGNDROP)
2651     XE_APPEND(dragdrop.o, extra_objs)
2652   else
2653     with_dragndrop=no
2654     AC_MSG_RESULT(no)
2655   fi
2656 fi
2657
2658 dnl Autodetect LDAP
2659 AC_CHECKING(for LDAP)
2660 test -z "$with_ldap" && { AC_CHECK_HEADER(ldap.h, ,with_ldap=no) }
2661 test -z "$with_ldap" && { AC_CHECK_HEADER(lber.h, ,with_ldap=no) }
2662 if test "$with_ldap" != "no"; then
2663   test -z "$with_umich_ldap" && { AC_CHECK_LIB(ldap, ldap_open, with_umich_ldap=yes, with_umich_ldap=no, -llber) }
2664   test "$with_umich_ldap" = "no" && { AC_CHECK_LIB(ldap10, ldap_set_option, with_ns_ldap=yes, with_ns_ldap=no) }
2665   test -z "$with_ldap" -a \( "$with_umich_ldap" = "yes" -o "$with_ns_ldap" = "yes" \) && with_ldap=yes
2666 fi
2667 if test "$with_ldap" = "yes"; then
2668   AC_DEFINE(HAVE_LDAP)
2669   XE_ADD_OBJS(eldap.o)
2670   if test "$with_umich_ldap" = "yes" ; then
2671     AC_DEFINE(HAVE_UMICH_LDAP)
2672     XE_PREPEND(-llber, LIBS)
2673     XE_PREPEND(-lldap, LIBS)
2674   elif test "$with_ldap" = "yes" -a "$with_ns_ldap" = "yes" ; then
2675     AC_DEFINE(HAVE_NS_LDAP)
2676     XE_PREPEND(-lldap10, LIBS)
2677   elif test "$with_ldap" = "yes" ; then
2678     XE_PREPEND(-lldap, LIBS)
2679   fi
2680 fi
2681
2682 dnl ----------------------
2683 dnl Graphics libraries
2684 dnl ----------------------
2685
2686 if test "$window_system" != "none"; then
2687   AC_CHECKING(for graphics libraries)
2688
2689   dnl Autodetect Xpm
2690   xpm_problem=""
2691   if test -z "$with_xpm"; then
2692     AC_MSG_CHECKING(for Xpm - no older than 3.4f)
2693     xe_check_libs=-lXpm
2694     AC_TRY_RUN([#include <X11/xpm.h>
2695     int main(int c, char **v) {
2696     return c == 1 ? 0 :
2697       XpmIncludeVersion != XpmLibraryVersion() ? 1 :
2698       XpmIncludeVersion < 30406 ? 2 : 0 ;}],
2699     [./conftest dummy_arg; xpm_status=$?;
2700       if test "$xpm_status" = "0"; then
2701         with_xpm=yes;
2702       else
2703         with_xpm=no;
2704         if test "$xpm_status" = "1"; then
2705           xpm_problem="Xpm library version and header file version don't match!"
2706         elif test "$xpm_status" = "2"; then
2707           xpm_problem="Xpm library version is too old!"
2708         else
2709           xpm_problem="Internal xpm detection logic error!"
2710         fi
2711         echo "
2712 *** WARNING *** $xpm_problem
2713   I'm not touching that with a 10-foot pole!
2714   If you really want to use the installed version of Xpm, rerun
2715   configure and add '--with-xpm=yes', but don't blame me if XEmacs crashes!"
2716     fi],
2717     [with_xpm=no])
2718     xe_check_libs=
2719     AC_MSG_RESULT($with_xpm)
2720   fi
2721   if test "$with_xpm" = "yes"; then
2722     AC_DEFINE(HAVE_XPM)
2723     XE_PREPEND(-lXpm, libs_x)
2724     AC_MSG_CHECKING(for \"FOR_MSW\" xpm)
2725     xe_check_libs=-lXpm
2726     AC_TRY_LINK(, [XpmCreatePixmapFromData()],
2727     [xpm_for_msw=no],
2728     [xpm_for_msw=yes])
2729     xe_check_libs=
2730     AC_MSG_RESULT($xpm_for_msw)
2731     if test "$xpm_for_msw" = "yes"; then
2732       AC_DEFINE(FOR_MSW)
2733     fi
2734   fi
2735
2736   dnl Autodetect XFACE
2737   test -z "$with_xface" && { AC_CHECK_HEADER(compface.h,          ,with_xface=no) }
2738   test -z "$with_xface" && { AC_CHECK_LIB(compface, UnGenFace,[:] ,with_xface=no) }
2739   test -z "$with_xface" && with_xface=yes
2740   if test "$with_xface" = "yes"; then
2741     AC_DEFINE(HAVE_XFACE)
2742     XE_PREPEND(-lcompface, libs_x)
2743   fi
2744
2745   dnl For a brief period we had the GIF code split out into a separate library,
2746   dnl but patent problems, etc. sort of squashed that idea.
2747   dnl We default to building with builtin GIF decoding
2748   if test "$with_gif" != "no"; then
2749     with_gif="yes"
2750     AC_DEFINE(HAVE_GIF)
2751     XE_ADD_OBJS(dgif_lib.o gif_io.o)
2752   fi
2753
2754   dnl Too many stupid linkers can't detect cascaded lib dependencies until runtime
2755   dnl So we always search for libz compression support.
2756   if test "$with_png $with_tiff" != "no no"; then
2757     AC_CHECK_LIB(c,  inflate, [:], [
2758     AC_CHECK_LIB(z,  inflate, [XE_PREPEND(-lz,  libs_x)],[
2759     AC_CHECK_LIB(gz, inflate, [XE_PREPEND(-lgz, libs_x)])])])
2760   fi
2761
2762   dnl autodetect JPEG
2763   test -z "$with_jpeg" && { AC_CHECK_HEADER(jpeglib.h,                    ,with_jpeg=no) }
2764   test -z "$with_jpeg" && { AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,[:],with_jpeg=no) }
2765   test -z "$with_jpeg" && with_jpeg=yes
2766   if test "$with_jpeg" = "yes"; then
2767     AC_DEFINE(HAVE_JPEG)
2768     XE_PREPEND(-ljpeg, libs_x)
2769   fi
2770
2771   dnl autodetect PNG
2772   png_problem=""
2773   test -z "$with_png" && { AC_CHECK_FUNC(pow,                  ,with_png=no) }
2774   test -z "$with_png" && { AC_CHECK_HEADER(png.h,              ,with_png=no) }
2775   test -z "$with_png" && { AC_CHECK_LIB(png, png_read_image,[:],with_png=no) }
2776   if test -z "$with_png"; then
2777     AC_MSG_CHECKING(for workable png version information)
2778     xe_check_libs="-lpng -lz"
2779     AC_TRY_RUN([#include <png.h>
2780     int main(int c, char **v) {
2781     if (c == 1) return 0;
2782     if (strcmp(png_libpng_ver, PNG_LIBPNG_VER_STRING) != 0) return 1;
2783     return (PNG_LIBPNG_VER < 10002) ? 2 : 0 ;}],
2784     [./conftest dummy_arg; png_status=$?;
2785       if test "$png_status" = "0"; then
2786         with_png=yes;
2787       else
2788         with_png=no;
2789         if test "$png_status" = "1"; then
2790           png_problem="PNG library version and header file don't match!"
2791         elif test "$png_status" = "2"; then
2792           png_problem="PNG library version too old (pre 1.0.2)!"
2793         fi
2794         echo "
2795 *** WARNING *** $png_problem
2796   I'm not touching that with a 10-foot pole!
2797   If you really want to use the installed version of libPNG, rerun
2798   configure and add '--with-png=yes', but don't blame me if XEmacs crashes!"
2799     fi],
2800     [with_png=no])
2801     xe_check_libs=
2802     AC_MSG_RESULT($with_png)
2803   fi
2804   if test "$with_png" = "yes"; then
2805     AC_DEFINE(HAVE_PNG)
2806     XE_PREPEND(-lpng, libs_x)
2807   fi
2808
2809   dnl autodetect TIFF
2810   test -z "$with_tiff" && { AC_CHECK_HEADER(tiffio.h,            ,with_tiff=no) }
2811   test -z "$with_tiff" && { AC_CHECK_LIB(tiff, TIFFClientOpen,[:],with_tiff=no) }
2812   test -z "$with_tiff" && with_tiff=yes
2813   if test "$with_tiff" = "yes"; then
2814     AC_DEFINE(HAVE_TIFF)
2815     XE_PREPEND(-ltiff, libs_x)
2816   fi
2817 fi
2818
2819 dnl ----------------------
2820 dnl X-Specific Graphics libraries
2821 dnl ----------------------
2822
2823 if test "$with_x11" = "yes"; then
2824
2825   AC_CHECKING(for X11 graphics libraries)
2826
2827   dnl Autodetect -lXaw
2828   AC_CHECK_LIB(Xaw, XawScrollbarSetThumb, have_xaw=yes, have_xaw=no)
2829   dnl if test "$have_xaw" = "yes"; then
2830     dnl AC_CHECK_HEADER(X11/Xaw/Reports.h, [
2831       dnl XE_APPEND(pkg-src/tree-x, MAKE_SUBDIR)
2832       dnl XE_APPEND(pkg-src/tree-x, INSTALL_ARCH_DEP_SUBDIR)])
2833   dnl fi
2834
2835   dnl autodetect Motif - but only add to libs_x later (if necessary)
2836   AC_CHECK_HEADER(Xm/Xm.h,
2837    [AC_CHECK_LIB(Xm, XmStringFree, have_motif=yes, have_motif=no)],
2838    have_motif=no)
2839
2840   if test "$have_motif" = "yes"; then
2841     dnl autodetect lesstif
2842     AC_MSG_CHECKING(for Lesstif)
2843     AC_EGREP_CPP(yes,
2844 [#include <Xm/Xm.h>
2845 #ifdef LESSTIF_VERSION
2846 yes
2847 #endif
2848 ], have_lesstif=yes, have_lesstif=no)
2849   AC_MSG_RESULT($have_lesstif)
2850   fi
2851
2852 fi dnl "$with_x11" = "yes"
2853
2854 dnl Finish ensuring that we have values for the various toolkit items.
2855 dnl Not all toolkits support all widgets
2856 dnl if Motif is available we use it for the dialog boxes.
2857
2858 case "$with_menubars" in "" | "yes" | "athena" | "athena3d" )
2859   with_menubars="lucid" ;;
2860 esac
2861 case "$with_dialogs" in "" | "yes" | "lucid" )
2862   if   test "$have_motif" = "yes"; then with_dialogs="motif"
2863   elif test "$have_xaw"   = "yes"; then with_dialogs="athena"
2864   else with_dialogs=no
2865   fi ;;
2866 esac
2867 case "$with_scrollbars" in "" | "yes" )
2868   with_scrollbars="lucid" ;;
2869 esac
2870
2871 all_widgets="$with_menubars $with_scrollbars $with_dialogs $with_toolbars"
2872
2873 case "$all_widgets" in *athena* )
2874   AC_DEFINE(LWLIB_USES_ATHENA)
2875   AC_DEFINE(NEED_ATHENA)
2876   XE_APPEND(lwlib-Xaw.o, lwlib_objs)
2877   XE_PREPEND(-lXaw, libs_x) ;;
2878 esac
2879
2880 case "$all_widgets" in *motif* )
2881   AC_DEFINE(LWLIB_USES_MOTIF)
2882   AC_DEFINE(NEED_MOTIF)
2883   XE_APPEND(lwlib-Xm.o, lwlib_objs)
2884   need_motif=yes ;;
2885 esac
2886
2887 test "$with_menubars"   = "lucid" && XE_APPEND(xlwmenu.o, lwlib_objs)
2888 test "$with_menubars"   = "motif" && XE_APPEND(xlwmenu.o, lwlib_objs)
2889 test "$with_scrollbars" = "lucid" && XE_APPEND(xlwscrollbar.o, lwlib_objs)
2890 case "$all_widgets" in *lucid* )
2891   AC_DEFINE(NEED_LUCID)
2892   XE_APPEND(lwlib-Xlw.o, lwlib_objs) ;;
2893 esac
2894
2895 AC_SUBST(lwlib_objs)
2896
2897 case "$with_scrollbars" in athena* ) AC_DEFINE(LWLIB_SCROLLBARS_ATHENA);; esac
2898 case "$with_dialogs"    in athena* ) AC_DEFINE(LWLIB_DIALOGS_ATHENA)   ;; esac
2899 test "$with_scrollbars" = "athena3d" && AC_DEFINE(LWLIB_SCROLLBARS_ATHENA3D)
2900 test "$with_dialogs"    = "athena3d" && AC_DEFINE(LWLIB_DIALOGS_ATHENA3D)
2901
2902 test "$with_menubars"   != "no"    && AC_DEFINE(HAVE_MENUBARS)
2903 test "$with_scrollbars" != "no"    && AC_DEFINE(HAVE_SCROLLBARS)
2904 test "$with_dialogs"    != "no"    && AC_DEFINE(HAVE_DIALOGS)
2905 test "$with_toolbars"   != "no"    && AC_DEFINE(HAVE_TOOLBARS)
2906
2907 test "$with_menubars"   = "lucid"  && AC_DEFINE(LWLIB_MENUBARS_LUCID)
2908 test "$with_scrollbars" = "lucid"  && AC_DEFINE(LWLIB_SCROLLBARS_LUCID)
2909
2910 test "$with_menubars"   = "motif"  && AC_DEFINE(LWLIB_MENUBARS_MOTIF)
2911 test "$with_scrollbars" = "motif"  && AC_DEFINE(LWLIB_SCROLLBARS_MOTIF)
2912 test "$with_dialogs"    = "motif"  && AC_DEFINE(LWLIB_DIALOGS_MOTIF)
2913
2914 test "$with_menubars"   != "no"      && XE_ADD_OBJS(menubar.o)
2915 test "$with_scrollbars" != "no"      && XE_ADD_OBJS(scrollbar.o)
2916 test "$with_dialogs"    != "no"      && XE_ADD_OBJS(dialog.o)
2917 test "$with_toolbars"   != "no"      && XE_ADD_OBJS(toolbar.o)
2918
2919 if test "$with_x11" = "yes"; then
2920   test "$with_menubars"   != "no"      && XE_ADD_OBJS(menubar-x.o)
2921   test "$with_scrollbars" != "no"      && XE_ADD_OBJS(scrollbar-x.o)
2922   test "$with_dialogs"    != "no"      && XE_ADD_OBJS(dialog-x.o)
2923   test "$with_toolbars"   != "no"      && XE_ADD_OBJS(toolbar-x.o)
2924   test "$all_widgets" != "no no no no" && XE_ADD_OBJS(gui-x.o)
2925 else
2926   if test \( "$with_sound" = "nas" \) -o \( "$with_sound" = "both" \); then
2927     echo "Attempt to Build NAS sound without X"
2928     echo "Please remove NAS configuration or build with X"
2929     exit 1
2930   fi
2931 fi
2932
2933 dnl ----------------------
2934 dnl Mule-dependent options
2935 dnl ----------------------
2936
2937 test -z "$with_mule" && with_mule=no
2938 test -z "$with_file_coding" && with_file_coding=no
2939
2940 dnl if test "$with_mule" = "yes" && test ! -d "$srcdir/lisp/mule"; then
2941 dnl     echo "Attempt to Build with Mule without Mule/Lisp"
2942 dnl     echo "Please install the XEmacs/Mule tarball or"
2943 dnl     echo "rerun configure with --with-mule=no"
2944 dnl     exit 1
2945 dnl fi
2946
2947 if test "$with_file_coding" = "yes" && test "$with_mule" = "no"; then
2948   AC_DEFINE(FILE_CODING)
2949   XE_ADD_OBJS(file-coding.o)
2950 fi
2951
2952 if test "$with_mule" = "yes" ; then
2953   AC_CHECKING(for Mule-related features)
2954   AC_DEFINE(MULE)
2955   AC_DEFINE(FILE_CODING)
2956   XE_ADD_OBJS(mule.o mule-ccl.o mule-charset.o file-coding.o)
2957
2958   dnl Use -lintl to get internationalized strerror for Mule
2959   AC_CHECK_HEADERS(libintl.h)
2960   AC_CHECK_LIB(intl, strerror)
2961
2962   AC_CHECKING(for Mule input methods)
2963   dnl Do we have the XmIm* routines?  And if so, do we want to use them?
2964   dnl XIM seems to be flaky except on Solaris...
2965   dnl test -z "$with_xim" -a "$opsys" != "sol2" && with_xim=no
2966   case "$with_xim" in "" | "yes" )
2967     AC_CHECKING(for XIM)
2968     AC_CHECK_LIB(X11, XOpenIM, with_xim=xlib, with_xim=no)
2969     dnl XIM + Lesstif is not (yet?) usable
2970     if test "$have_motif $have_lesstif" = "yes no"; then
2971       AC_CHECK_LIB(Xm, XmImMbLookupString, with_xim=motif)
2972     fi ;;
2973   esac
2974   if test "$with_xim" != "no"; then
2975     AC_DEFINE(HAVE_XIM)
2976     if test "$with_xim" = "xlib"; then
2977       AC_DEFINE(XIM_XLIB)
2978       XE_ADD_OBJS(input-method-xlib.o)
2979     fi
2980     if test "$with_xim" = "motif"; then
2981       AC_DEFINE(XIM_MOTIF)
2982       need_motif=yes
2983       XE_ADD_OBJS(input-method-motif.o)
2984     fi
2985     if test "$with_xim" = "motif"; then
2986       with_xfs=no
2987     fi
2988   fi
2989
2990   dnl "with_xfs" = "yes"
2991   if test "$with_xfs" = "yes" ; then
2992     AC_CHECKING(for XFontSet)
2993     AC_CHECK_LIB(X11, XmbDrawString, [:], with_xfs=no)
2994     if test "$with_xfs" = "yes" && test "$with_menubars" = "lucid"; then
2995       AC_DEFINE(USE_XFONTSET)
2996       if test "$with_xim" = "no" ; then
2997         XE_ADD_OBJS(input-method-xfs.o)
2998       fi
2999     fi
3000   fi dnl with_xfs
3001
3002   dnl Autodetect WNN
3003   test "$with_wnn6" = "yes" && with_wnn=yes # wnn6 implies wnn support
3004   test -z "$with_wnn" && { AC_CHECK_HEADER(wnn/jllib.h, ,with_wnn=no) }
3005   dnl Detour to find crypt
3006   if test "$with_wnn" != "no"; then
3007     AC_CHECK_FUNCS(crypt)
3008     test "$ac_cv_func_crypt" != "yes" && { AC_CHECK_LIB(crypt, crypt) }
3009   fi
3010   dnl Back to our regularly scheduled wnn hunting
3011   if test -z "$with_wnn" -o "$with_wnn" = "yes"; then
3012     AC_CHECK_LIB(wnn,jl_dic_list_e,libwnn=wnn,
3013       AC_CHECK_LIB(wnn4,jl_dic_list_e,libwnn=wnn4,
3014         AC_CHECK_LIB(wnn6,jl_dic_list_e,libwnn=wnn6,
3015           AC_CHECK_LIB(wnn6_fromsrc,dic_list_e,libwnn=wnn6_fromsrc,with_wnn=no))))
3016   fi
3017   test -z "$with_wnn" && with_wnn=yes
3018   if test "$with_wnn" = "yes"; then
3019     AC_DEFINE(HAVE_WNN)
3020     XE_PREPEND(-l$libwnn, libs_x)
3021     XE_ADD_OBJS(mule-wnnfns.o)
3022     if test "$with_wnn6" != "no"; then
3023       AC_CHECK_LIB($libwnn, jl_fi_dic_list, with_wnn6=yes)
3024       test "$with_wnn6" = "yes" && AC_DEFINE(WNN6)
3025     fi
3026   fi
3027
3028   dnl Autodetect canna
3029   canna_includes_found=no
3030   if test "$with_canna" != "no"; then
3031     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3032   fi
3033   if test "$canna_includes_found" = "no" -a "$with_canna" != "no" -a \
3034       -d "/usr/local/canna/include"; then
3035     save_c_switch_site="$c_switch_site"
3036     c_switch_site="$c_switch_site -I/usr/local/canna/include"
3037     AC_CHECK_HEADER(canna/jrkanji.h,canna_includes_found=yes)
3038     if test "$canna_includes_found" != "yes"; then
3039       c_switch_site="$save_c_switch_site"
3040       with_canna="no"
3041     fi
3042   fi
3043
3044   test -z "$with_canna" && { AC_CHECK_HEADER(canna/RK.h,         , with_canna=no) }
3045   test -z "$with_canna" && { AC_CHECK_LIB(RKC, RkBgnBun,       [:],with_canna=no) }
3046   test -z "$with_canna" && { AC_CHECK_LIB(canna,jrKanjiControl,[:],with_canna=no) }
3047   test -z "$with_canna" && with_canna=yes
3048   if test "$with_canna" = "yes"; then
3049     AC_DEFINE(HAVE_CANNA)
3050     XE_PREPEND(-lcanna -lRKC, libs_x)
3051     XE_ADD_OBJS(mule-canna.o)
3052   fi
3053
3054 else dnl "$with_mule" = "no"
3055   for feature in xim canna wnn; do
3056     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
3057       AC_MSG_WARN("--with-${feature} ignored:  Not valid without Mule support")
3058     fi
3059     eval "with_${feature}=no"
3060   done
3061 fi dnl with_mule
3062
3063
3064 dnl At this point, we know whether we need the motif lib or not.
3065 if test "$need_motif" = "yes" ; then
3066   XE_PREPEND(-lXm, libs_x)
3067   dnl AIX needs the following library for use with Motif
3068   AC_CHECK_LIB(i18n, layout_object_getvalue, [XE_PREPEND(-li18n, libs_x)])
3069   XE_COMPUTE_RUNPATH()
3070 fi
3071
3072 AC_CHECK_FUNCS(cbrt closedir dup2 eaccess fmod fpathconf frexp ftime gethostname getpagesize gettimeofday getcwd getwd logb lrand48 matherr mkdir mktime perror poll random rename res_init rint rmdir select setitimer setpgid setlocale setsid sigblock sighold sigprocmask snprintf strcasecmp strerror tzset ulimit usleep utimes waitpid vsnprintf)
3073
3074 dnl realpath is buggy on linux, decosf and aix4
3075
3076 dnl The realpath() in linux libc (4.6.27) sometimes fails with ELOOP.
3077 dnl The realpath in ELF linux libc's is O.K.
3078 dnl For example, call realpath on a file thirty-five or so directories deep
3079 dnl and you get ELOOP even if no symlinks at all are involved.
3080 dnl Reports as of 11/1997 indicate BSDi has problems too.
3081 dnl The realpath() in UnixWare2.1.3 could not get any pathname fragment in error condition.
3082 case "$opsys" in
3083   linuxaout* | bsdos3* | freebsd* | decosf4-0* | aix4* ) XE_ADD_OBJS(realpath.o) ;;
3084   * )
3085     case "$canonical" in
3086       *-*-sysv4.2uw2* ) XE_ADD_OBJS(realpath.o) ;;
3087       * ) AC_CHECK_FUNCS(realpath)
3088           test "$ac_cv_func_realpath" != "yes" && XE_ADD_OBJS(realpath.o) ;;
3089     esac ;;
3090 esac
3091
3092 dnl Check whether the system provides getloadavg (Solaris 7 has it)
3093 AC_CHECK_FUNCS(getloadavg)
3094
3095 if test "$ac_cv_func_getloadavg" != "yes"
3096 then
3097   XE_ADD_OBJS(getloadavg.o)
3098
3099   dnl Used by getloadavg() - does not require root priveleges
3100   AC_CHECK_LIB(kstat, kstat_open)
3101
3102   dnl Another way to get the load average
3103   AC_CHECK_LIB(kvm, kvm_read)
3104 fi
3105
3106 dnl If netdb.h does not declare h_errno, we must declare it by hand.
3107 AC_MSG_CHECKING(whether netdb declares h_errno)
3108 AC_TRY_LINK([#include <netdb.h>],
3109   [return h_errno;],
3110   [AC_MSG_RESULT(yes)
3111    AC_DEFINE(HAVE_H_ERRNO)],
3112   [AC_MSG_RESULT(no)])
3113
3114 AC_MSG_CHECKING(for sigsetjmp)
3115 AC_TRY_COMPILE([#include <setjmp.h>],
3116         [sigjmp_buf bar; sigsetjmp (bar, 0);],
3117   [AC_MSG_RESULT(yes)
3118    AC_DEFINE(HAVE_SIGSETJMP)],
3119   [AC_MSG_RESULT(no)])
3120
3121 AC_MSG_CHECKING(whether localtime caches TZ)
3122 AC_CACHE_VAL(emacs_cv_localtime_cache,
3123 [if test "$ac_cv_func_tzset" = "yes"; then
3124 AC_TRY_RUN([#include <time.h>
3125 #if STDC_HEADERS
3126 # include <stdlib.h>
3127 #endif
3128 extern char **environ;
3129 unset_TZ ()
3130 {
3131   char **from, **to;
3132   for (to = from = environ; (*to = *from); from++)
3133     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
3134       to++;
3135 }
3136 char TZ_GMT0[] = "TZ=GMT0";
3137 char TZ_PST8[] = "TZ=PST8";
3138 main()
3139 {
3140   time_t now = time ((time_t *) 0);
3141   int hour_GMT0, hour_unset;
3142   if (putenv (TZ_GMT0) != 0)
3143     exit (1);
3144   hour_GMT0 = localtime (&now)->tm_hour;
3145   unset_TZ ();
3146   hour_unset = localtime (&now)->tm_hour;
3147   if (putenv (TZ_PST8) != 0)
3148     exit (1);
3149   if (localtime (&now)->tm_hour == hour_GMT0)
3150     exit (1);
3151   unset_TZ ();
3152   if (localtime (&now)->tm_hour != hour_unset)
3153     exit (1);
3154   exit (0);
3155 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3156 [# If we have tzset, assume the worst when cross-compiling.
3157 emacs_cv_localtime_cache=yes])
3158 else
3159         # If we lack tzset, report that localtime does not cache TZ,
3160         # since we can't invalidate the cache if we don't have tzset.
3161         emacs_cv_localtime_cache=no
3162 fi],[:])dnl
3163 AC_MSG_RESULT($emacs_cv_localtime_cache)
3164 if test $emacs_cv_localtime_cache = yes; then
3165   AC_DEFINE(LOCALTIME_CACHE)
3166 fi
3167
3168 if test "$HAVE_TIMEVAL" = "yes"; then
3169 AC_MSG_CHECKING(whether gettimeofday accepts one or two arguments)
3170 AC_TRY_LINK([
3171 #ifdef TIME_WITH_SYS_TIME
3172 #include <sys/time.h>
3173 #include <time.h>
3174 #else
3175 #ifdef HAVE_SYS_TIME_H
3176 #include <sys/time.h>
3177 #else
3178 #include <time.h>
3179 #endif
3180 #endif
3181   ],
3182   [
3183   struct timeval time;
3184   struct timezone dummy;
3185   gettimeofday (&time, &dummy);
3186 ],
3187   [AC_MSG_RESULT(two)],
3188   [AC_MSG_RESULT(one)
3189    AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
3190 fi
3191
3192
3193 AC_C_INLINE
3194 if test "$ac_cv_c_inline" != "no"; then
3195   AC_DEFINE(HAVE_INLINE)
3196   test "$GCC" = "yes" && XE_ADD_OBJS(inline.o)
3197 fi
3198
3199 dnl HP-UX has a working alloca in libPW.
3200 dnl case "${GCC}${opsys}" in hpux* )
3201 dnl  AC_CHECK_FUNC(alloca, [:], [AC_CHECK_LIB(PW, alloca)])
3202 dnl esac
3203
3204 AC_FUNC_ALLOCA
3205 test -n "$ALLOCA" && XE_ADD_OBJS($ALLOCA)
3206
3207 dnl Check whether vfork exists and works correctly. (This does more
3208 dnl than just check for its existence.) If so, it defines HAVE_VFORK_H.
3209 dnl If not, it defines vfork to be fork.
3210 AC_FUNC_VFORK
3211
3212 dnl Check whether strcoll exists and works correctly. (This does more
3213 dnl than just check for its existence.) If so, it defines HAVE_STRCOLL.
3214 AC_FUNC_STRCOLL
3215
3216 dnl If `getpgrp' takes no argument (the POSIX.1 version), define
3217 dnl `GETPGRP_VOID'.  Otherwise, it is the BSD version, which takes a
3218 dnl process ID as an argument.
3219 AC_CHECK_FUNCS(getpgrp)
3220 AC_FUNC_GETPGRP
3221
3222 dnl We used to call AC_FUNC_MMAP here
3223 dnl Instead we now use following, suggested by Neal Becker
3224 AC_MSG_CHECKING(for working mmap)
3225 case "$opsys" in ultrix* ) have_mmap=no ;; *)
3226 AC_TRY_RUN([#include <stdio.h>
3227 #include <unistd.h>
3228 #include <fcntl.h>
3229 #include <sys/mman.h>
3230
3231 #ifndef MAP_VARIABLE
3232 #define MAP_VARIABLE 0
3233 #endif
3234
3235 #ifndef MAP_FAILED
3236 #define MAP_FAILED -1
3237 #endif
3238
3239 int main (int argc, char *argv[])
3240 {
3241   int fd = -1;
3242   caddr_t p;
3243 #ifndef MAP_ANONYMOUS
3244   fd = open ("/dev/zero", O_RDWR);
3245   if (fd < 0)
3246     return 1;
3247 #define MAP_ANONYMOUS 0
3248 #endif
3249   if (mmap(0, 1024, PROT_READ | PROT_WRITE,
3250            MAP_PRIVATE | MAP_VARIABLE | MAP_ANONYMOUS,
3251            fd, 0) != (void *) MAP_FAILED)
3252     return 0;
3253   perror ("conftest: mmap failed");
3254   return 1;
3255 }], have_mmap=yes, have_mmap=no) ;;
3256 esac
3257 AC_MSG_RESULT($have_mmap)
3258 test "$have_mmap" = "yes" && AC_DEFINE(HAVE_MMAP)
3259 AC_FUNC_MMAP
3260
3261 dnl rel_alloc requires either GNU malloc or system malloc with mmap
3262 dnl We only turn rel_alloc on by default if mmap is available.
3263 test "$GNU_MALLOC" != "yes"   -a "$have_mmap" != "yes" && rel_alloc=no
3264 test "$rel_alloc" = "default" -a "$have_mmap"  = "yes" && rel_alloc=yes
3265 test "$rel_alloc" = "yes" && AC_DEFINE(REL_ALLOC)
3266
3267 dnl Check for terminal I/O variants
3268 dnl TERMIOS systems may have termio.h, but not vice-versa, I think.
3269 AC_CHECK_HEADER(termios.h,
3270   AC_DEFINE(HAVE_TERMIOS)
3271   AC_DEFINE(SIGNALS_VIA_CHARACTERS)
3272   AC_DEFINE(NO_TERMIO),
3273   [AC_CHECK_HEADER(termio.h, [AC_DEFINE(HAVE_TERMIO)])])
3274
3275
3276 dnl Check for Internet sockets.
3277 AC_CHECK_FUNC(socket,
3278  [AC_CHECK_HEADER(netinet/in.h,
3279    [AC_CHECK_HEADER(arpa/inet.h, [
3280   AC_DEFINE(HAVE_SOCKETS)
3281       AC_MSG_CHECKING("for sun_len member in struct sockaddr_un")
3282       AC_TRY_LINK([
3283 #include <sys/types.h>
3284 #include <sys/socket.h>
3285 #include <sys/un.h>
3286       ],
3287       [static struct sockaddr_un x; x.sun_len = 1;],
3288       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)],
3289       [AC_MSG_RESULT(no)])
3290       AC_MSG_CHECKING("for ip_mreq struct in netinet/in.h")
3291       AC_TRY_LINK([
3292 #include <sys/types.h>
3293 #include <netinet/in.h>
3294       ],
3295       [static struct ip_mreq x;],
3296       [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_MULTICAST)],
3297       [AC_MSG_RESULT(no)])])])])
3298
3299 dnl Check for SYS V IPC. (Inferior to sockets.)
3300 AC_CHECK_FUNC(msgget,
3301   [AC_CHECK_HEADER(sys/ipc.h,
3302     [AC_CHECK_HEADER(sys/msg.h,
3303       [AC_DEFINE(HAVE_SYSVIPC)])])])
3304
3305 dnl Check for directory variants
3306 AC_CHECK_HEADER(dirent.h, [AC_DEFINE(SYSV_SYSTEM_DIR)],
3307   [AC_CHECK_HEADER(sys/dir.h, , [AC_DEFINE(NONSYSTEM_DIR_LIBRARY)])])
3308
3309 dnl Check for nlist.h
3310 AC_CHECK_HEADER(nlist.h, AC_DEFINE(NLIST_STRUCT), )
3311
3312 dnl Check for sound of various sorts.
3313
3314 dnl Autodetect native sound
3315 AC_CHECKING("for sound support")
3316 case "$with_sound" in
3317   native | both ) with_native_sound=yes;;
3318   nas    | no   ) with_native_sound=no;;
3319 esac
3320 test -z "$with_native_sound" -a -n "$native_sound_lib" && with_native_sound=yes
3321
3322 if test "$with_native_sound" != "no"; then
3323   dnl Maybe sound is already on include path...
3324   if test -n "$native_sound_lib"; then
3325     AC_CHECK_HEADER(multimedia/audio_device.h,
3326       [sound_found=yes sound_cflags=""
3327       XE_ADD_OBJS(sunplay.o)])
3328   fi
3329
3330   dnl Autodetect Sun native sound from SUNWaudmo package
3331   if test -z "$sound_found" -a -d "/usr/demo/SOUND"; then
3332     sound_found=yes
3333     XE_ADD_OBJS(sunplay.o)
3334     if test -d "/usr/demo/SOUND/include"
3335       then sound_cflags="-I/usr/demo/SOUND/include"
3336       else sound_cflags="-I/usr/demo/SOUND"
3337     fi
3338     if test -z "$native_sound_lib" ; then
3339       if test -r "/usr/demo/SOUND/lib/libaudio.a"
3340         then native_sound_lib="/usr/demo/SOUND/lib/libaudio.a"
3341         else native_sound_lib="/usr/demo/SOUND/libaudio.a"
3342       fi
3343     fi
3344   fi
3345
3346   dnl Check for SGI and HP native sound libs
3347   if test -z "$sound_found"; then
3348     case "$canonical" in
3349     *-sgi-* )
3350       if test -z "$native_sound_lib"; then
3351         AC_CHECK_LIB(audio, ALopenport, native_sound_lib="-laudio")
3352       fi
3353       if test -n "$native_sound_lib"; then
3354         sound_found=yes sound_cflags=""
3355         XE_ADD_OBJS(sgiplay.o)
3356       fi ;;
3357     hppa*-hp-hpux* )
3358       if test -z "$native_sound_lib"; then
3359         AC_CHECK_LIB(Alib, AOpenAudio, native_sound_lib="-lAlib")
3360       fi
3361       if test -n "$native_sound_lib"; then
3362         sound_found=yes
3363         XE_ADD_OBJS(hpplay.o)
3364         if test "$GCC" = "yes" # Kludge city
3365           then sound_cflags="-Dconst= -Dvolatile= -I/usr/audio/examples"
3366           else sound_cflags="+e -I/usr/audio/examples"
3367         fi
3368       fi ;;
3369     esac
3370   fi
3371
3372   dnl Check for Linux/BSD native sound
3373   if test -z "$sound_found"; then
3374     for dir in "machine" "sys" "linux"; do
3375       AC_CHECK_HEADER(${dir}/soundcard.h,
3376         sound_found=yes
3377         XE_ADD_OBJS(linuxplay.o)
3378         [AC_DEFINE_UNQUOTED(SOUNDCARD_H_PATH, "${dir}/soundcard.h")]
3379         break)
3380     done
3381   fi
3382
3383   test "$sound_found" = "yes" && with_native_sound=yes
3384 fi
3385
3386 if test -z "$with_sound"; then
3387   if test "$with_native_sound" = "yes" -o -n "$native_sound_lib"; then
3388     with_sound=native
3389   fi
3390 fi
3391
3392 if test "$with_native_sound" = "yes"; then
3393   AC_DEFINE(HAVE_NATIVE_SOUND)
3394   test -n "$native_sound_lib" && XE_PREPEND($native_sound_lib, LIBS)
3395 fi
3396
3397 case "$with_sound" in both | nas )
3398   AC_DEFINE(HAVE_NAS_SOUND)
3399   XE_ADD_OBJS(nas.o)
3400   XE_PREPEND(-laudio, libs_x)
3401   dnl If the nas library does not contain the error jump point,
3402   dnl then we force safer behavior.
3403   AC_EGREP_HEADER(AuXtErrorJump,audio/Xtutil.h,,[AC_DEFINE(NAS_NO_ERROR_JUMP)])
3404 esac
3405
3406 dnl ---------------------
3407 dnl TTY-dependent options
3408 dnl ---------------------
3409
3410 test -z "$with_tty" && with_tty=yes
3411
3412 if test "$with_tty" = "yes"  ; then
3413   AC_CHECKING(for TTY-related features)
3414   AC_DEFINE(HAVE_TTY)
3415   XE_ADD_OBJS(console-tty.o device-tty.o event-tty.o frame-tty.o objects-tty.o redisplay-tty.o cm.o)
3416
3417   dnl Autodetect ncurses.
3418   if test -z "$with_ncurses"; then
3419     AC_CHECK_LIB(ncurses, tgetent, with_ncurses=yes, with_ncurses=no)
3420   fi
3421   if test "$with_ncurses" = "yes"; then
3422     AC_DEFINE(HAVE_NCURSES)
3423     AC_CHECK_HEADER(ncurses/curses.h, curses_h_path=ncurses/curses.h)
3424     AC_CHECK_HEADER(ncurses/term.h, term_h_path=ncurses/term.h)
3425     XE_ADD_OBJS(terminfo.o)
3426     XE_PREPEND(-lncurses, LIBS)
3427
3428     if test "$ac_cv_header_ncurses_curses_h" != "yes" ; then
3429       dnl Try again, and check for the bogus ncurses/ include bug.
3430       dnl (i.e. ncurses/curses.h bogusly includes <unctrl.h> instead of
3431       dnl <ncurses/unctrl.h>)
3432       save_c_switch_site="$c_switch_site"
3433       c_switch_site="$c_switch_site -I/usr/include/ncurses"
3434       AC_CHECK_HEADER(ncurses/curses.h, curses_h_path=ncurses/curses.h)
3435       if test "$ac_cv_header_ncurses_curses_h" = "yes"
3436         then AC_MSG_WARN("Your system has the bogus ncurses include bug.")
3437         else c_switch_site="$save_c_switch_site"
3438       fi
3439     fi
3440   else dnl "$with_ncurses" = "no"
3441     dnl Autodetect terminfo/-lcurses/-ltermlib/-ltermcap
3442     if test "$have_terminfo" = "yes"; then
3443       XE_ADD_OBJS(terminfo.o)
3444       if test -n "$libs_termcap"; then
3445         XE_PREPEND($libs_termcap, LIBS)
3446       else
3447         for lib in curses termlib termcap; do
3448           AC_CHECK_LIB($lib, tgetent, XE_PREPEND(-l${lib}, LIBS); break)
3449         done
3450       fi
3451     else dnl "$have_terminfo" = "no" && "with_ncurses" = "no"
3452       XE_ADD_OBJS(tparam.o)
3453       dnl The HP-UX curses library seems to have a badly broken version of select(2)
3454       dnl that makes "poll: interrupted system call" messages to appear and
3455       dnl Emacs suprocesses to hang (e.g. TeX compilation w/ AUCTeX) */
3456       case "$opsys" in *-hp-hpux* ) libs_termcap="-ltermcap" ;; esac
3457       if test -n "$libs_termcap"; then
3458         XE_PREPEND($libs_termcap, LIBS)
3459       else
3460         AC_CHECK_LIB(curses, tgetent, XE_PREPEND(-lcurses, LIBS),
3461           AC_CHECK_LIB(termcap, tgetent, XE_PREPEND(-ltermcap, LIBS),
3462             XE_ADD_OBJS(termcap.o)))
3463       fi
3464     fi
3465   fi
3466   AC_DEFINE_UNQUOTED(CURSES_H_PATH, "${curses_h_path-curses.h}")
3467   AC_DEFINE_UNQUOTED(TERM_H_PATH, "${term_h_path-term.h}")
3468
3469   dnl Autodetect gpm
3470   test -z "$with_gpm" && { AC_CHECK_HEADER(gpm.h, , with_gpm=no) }
3471   test -z "$with_gpm" && { AC_CHECK_LIB(gpm, Gpm_Open, with_gpm=yes, with_gpm=no) }
3472   if test "$with_gpm" = "yes"; then
3473     AC_DEFINE(HAVE_GPM)
3474     XE_ADD_OBJS(gpmevent.o)
3475     XE_PREPEND(-lgpm, LIBS)
3476   fi
3477
3478 else dnl "$with_tty" = "no"
3479   for feature in ncurses gpm; do
3480     if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
3481       AC_MSG_WARN("--with-${feature} ignored:  Not valid without TTY support")
3482     fi
3483     eval "with_${feature}=no"
3484   done
3485 fi dnl with_tty
3486
3487 dnl Do we need event-unixoid.o ?
3488 test "$with_x11" = "yes" -o "$with_tty" = "yes" && XE_ADD_OBJS(event-unixoid.o)
3489
3490 dnl Database support
3491 dnl We do not necessarily have to have libdb/lib(g)dbm for DB/(G)DBM support.
3492 dnl On FreeBSD, both DB and DBM are part of libc.
3493 dnl By default, we check for DBM support in libgdbm, then libc, then libdbm.
3494
3495 test "$with_database_gnudbm $with_database_dbm $with_database_berkdb" \
3496   != "no no no" && AC_CHECKING(for database support)
3497
3498 dnl Check for ndbm.h, required for either kind of DBM support.
3499 if test "$with_database_gnudbm $with_database_dbm" != "no no"; then
3500   AC_CHECK_HEADER(ndbm.h, [:], [
3501     test "$with_database_gnudbm" = "yes" -o \
3502          "$with_database_dbm"    = "yes" && \
3503       XE_DIE("Required DBM support cannot be provided.")
3504     with_database_gnudbm=no with_database_dbm=no])
3505 fi
3506
3507 dnl Check for DBM support in libgdbm.
3508 if test "$with_database_gnudbm" != "no"; then
3509   AC_CHECK_LIB(gdbm, dbm_open, [
3510    with_database_gnudbm=yes with_database_dbm=no libdbm=-lgdbm], [
3511    if test "$with_database_gnudbm" = "yes"; then
3512      XE_DIE("Required GNU DBM support cannot be provided.")
3513    fi
3514    with_database_gnudbm=no])
3515 fi
3516
3517 dnl Check for DBM support in libc and libdbm.
3518 if test "$with_database_dbm" != "no"; then
3519   AC_CHECK_FUNC(dbm_open, [with_database_dbm=yes libdbm=], [
3520     AC_CHECK_LIB(dbm, dbm_open, [with_database_dbm=yes libdbm=-ldbm], [
3521       test "$with_database_dbm" = "yes" && \
3522         XE_DIE("Required DBM support cannot be provided.")
3523       with_database_dbm=no])])
3524 fi
3525
3526 dnl Tell make about the DBM support we detected.
3527 test -n "$libdbm" && XE_PREPEND("$libdbm", LIBS)
3528 test "$with_database_gnudbm" = "yes" -o \
3529      "$with_database_dbm"    = "yes" && \
3530   AC_DEFINE(HAVE_DBM)
3531
3532 dnl Check for Berkeley DB.
3533 if test "$with_database_berkdb" != "no"; then
3534   AC_MSG_CHECKING(for Berkeley db.h)
3535   for path in "db/db.h" "db.h"; do
3536     AC_TRY_COMPILE([#ifdef HAVE_INTTYPES_H
3537 #define __BIT_TYPES_DEFINED__
3538 #include <inttypes.h>
3539 typedef uint8_t  u_int8_t;
3540 typedef uint16_t u_int16_t;
3541 typedef uint32_t u_int32_t;
3542 #ifdef WE_DONT_NEED_QUADS
3543 typedef uint64_t u_int64_t;
3544 #endif
3545 #endif
3546 #include <$path>
3547 ],[], db_h_path="$path"; break)
3548   done
3549   if test -z "$db_h_path"
3550   then AC_MSG_RESULT(no); with_database_berkdb=no
3551   else AC_MSG_RESULT($db_h_path)
3552   fi
3553
3554   if test "$with_database_berkdb" != "no"; then
3555     AC_MSG_CHECKING(for Berkeley DB version)
3556     AC_EGREP_CPP(yes,
3557 [#include <$db_h_path>
3558 #if DB_VERSION_MAJOR > 1
3559 yes
3560 #endif
3561 ], [AC_MSG_RESULT(2); dbfunc=db_open], [AC_MSG_RESULT(1); dbfunc=dbopen])
3562     AC_CHECK_FUNC($dbfunc,     with_database_berkdb=yes need_libdb=no, [
3563     AC_CHECK_LIB(db, $dbfunc,  with_database_berkdb=yes need_libdb=yes)])
3564   fi
3565
3566   if test "$with_database_berkdb" = "yes"; then
3567     AC_DEFINE_UNQUOTED(DB_H_PATH, "$db_h_path")
3568     AC_DEFINE(HAVE_BERKELEY_DB)
3569     test "$need_libdb" = "yes" && XE_PREPEND(-ldb, LIBS)
3570   else with_database_berkdb=no
3571   fi
3572 fi
3573
3574 if test "$with_database_gnudbm $with_database_dbm $with_database_berkdb" \
3575      != "no no no"; then
3576   AC_DEFINE(HAVE_DATABASE)
3577   XE_ADD_OBJS(database.o)
3578 fi
3579
3580 dnl Socks support
3581 if test "$with_socks" = "yes"; then
3582   AC_CHECK_LIB(socks, SOCKSinit)
3583   test -n "$ac_cv_lib_socks_SOCKSinit" && AC_DEFINE(HAVE_SOCKS)
3584 fi
3585
3586 dnl Usage tracking (undocumented and likely unused option)
3587 if test "$usage_tracking" = "yes"; then
3588   AC_DEFINE(USAGE_TRACKING)
3589   XE_PREPEND(-Bstatic -lut -Bdynamic, LIBS)
3590 fi
3591
3592 dnl autodetect dll support
3593 AC_CHECK_HEADERS(dlfcn.h, [have_dlfcn=yes
3594   AC_DEFINE(HAVE_DLFCN_H)])
3595 test -z "$with_shlib" && test ! -z "$have_dlfcn" && { AC_CHECK_LIB(dl,  dlopen,   [ AC_DEFINE(HAVE_DLOPEN) DLL_LIB=dl;  with_shlib=yes]) }
3596 test -z "$with_shlib" && test ! -z "$have_dlfcn" && { AC_CHECK_LIB(c,   _dlopen,  [ AC_DEFINE(HAVE_DLOPEN) DLL_LIB=;   with_shlib=yes]) }
3597 test -z "$with_shlib" && test ! -z "$have_dlfcn" && { AC_CHECK_LIB(c,   dlopen,   [ AC_DEFINE(HAVE_DLOPEN) DLL_LIB=;   with_shlib=yes]) }
3598 test -z "$with_shlib" && { AC_CHECK_LIB(dld, shl_load, [ AC_DEFINE(HAVE_SHL_LOAD) DLL_LIB=dld; with_shlib=yes]) }
3599 test -z "$with_shlib" && { AC_CHECK_LIB(dld, dld_init, [ AC_DEFINE(HAVE_DLD_INIT) DLL_LIB=dld; with_shlib=yes]) }
3600 if test "$with_shlib" = "yes"; then
3601   XE_SHLIB_STUFF
3602   if test "$can_build_shared" = "yes"; then
3603     AC_DEFINE(HAVE_SHLIB)
3604     XE_ADD_OBJS(sysdll.o)
3605     XE_ADD_OBJS(emodules.o)
3606     XE_APPEND(src, INSTALL_ARCH_DEP_SUBDIR)
3607     test ! -z "$DLL_LIB" && XE_PREPEND(-l${DLL_LIB}, LIBS)
3608     AC_CHECK_FUNCS(dlerror _dlerror)
3609   else
3610     AC_MSG_WARN(disabling shared library support)
3611     with_shlib=no
3612   fi
3613 fi
3614
3615 dnl Unfortunately, just because we can link doesn't mean we can run.
3616 dnl One of the above link tests may have succeeded but caused resulting
3617 dnl executables to fail to run.  Also any tests using AC_TRY_RUN will
3618 dnl have reported incorrect results.
3619 AC_TRY_RUN([int main(int c,char *v[]){return 0;}],[:],[
3620   echo ""
3621   echo "*** PANIC *** The C compiler can no longer build working executables."
3622   echo "*** PANIC *** Please examine the tail of config.log for runtime errors."
3623   echo "*** PANIC *** The most likely reason for this problem is that configure"
3624   echo "*** PANIC *** links with shared libraries, but those libraries cannot be"
3625   echo "*** PANIC *** found at run time."
3626   echo "*** PANIC ***"
3627   echo "*** PANIC *** On a Linux system, edit /etc/ld.so.conf and re-run ldconfig."
3628   echo "*** PANIC *** On other systems, try telling configure where to find the"
3629   echo "*** PANIC *** shared libraries using the --site-runtime-libraries option"
3630   echo "*** PANIC ***"
3631   echo "*** PANIC *** Another way to shoot yourself in the foot is to specify"
3632   echo "*** PANIC *** --with-FEATURE when FEATURE is not actually installed"
3633   echo "*** PANIC *** on your system.  Don't do that."
3634   exit 1])
3635
3636 dnl Process support
3637 if test "$win32_processes" = "yes"; then
3638   XE_ADD_OBJS(process-nt.o)
3639 else
3640   AC_DEFINE(HAVE_UNIX_PROCESSES)
3641   XE_ADD_OBJS(process-unix.o)
3642 fi
3643
3644 dnl --------------------------------
3645 dnl Compute SUBST-itutable variables
3646 dnl --------------------------------
3647
3648 dnl We ignore (C|LD)_SWITCH_X_(MACHINE|SYSTEM)
3649 dnl Use XE_SPACE instead of plain assignment statements to remove extraneous blanks
3650 XE_SPACE(CFLAGS, $CFLAGS)
3651 XE_SPACE(extra_objs, $extra_objs)
3652 XE_SPACE(c_switch_general, -DHAVE_CONFIG_H $c_switch_site $c_switch_machine $c_switch_system)
3653 XE_SPACE(c_switch_window_system, $c_switch_x_site $X_CFLAGS)
3654 XE_SPACE(c_switch_all, $c_switch_general $c_switch_window_system)
3655 XE_SPACE(ld_switch_general, $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_run)
3656 XE_SPACE(ld_switch_window_system, $ld_switch_x_site)
3657 XE_SPACE(ld_switch_all, $ld_switch_general $ld_switch_window_system)
3658 XE_SPACE(ld_libs_general, $LIBS $libs_machine $libs_system $libs_standard)
3659 XE_SPACE(ld_libs_window_system, $X_EXTRA_LIBS $libs_x $X_PRE_LIBS)
3660 XE_SPACE(ld_libs_all, $ld_libs_window_system $ld_libs_general)
3661
3662 dnl Compute lists of Makefiles and subdirs
3663 AC_SUBST(SRC_SUBDIR_DEPS)
3664 XE_APPEND(src, MAKE_SUBDIR)
3665 internal_makefile_list="Makefile.in"
3666 SUBDIR_MAKEFILES=''
3667 test -d lock || mkdir lock
3668 for dir in $MAKE_SUBDIR; do
3669   case "$dir" in */* ) dnl Implement mkdir -p
3670     ( for d in `echo $dir | sed 's:/: :g'` ; do
3671         test -d "$d" || mkdir "$d"; cd "$d"
3672       done ) ;;
3673    * ) test -d "$dir" || mkdir "$dir" ;;
3674   esac
3675   XE_SPACE(SUBDIR_MAKEFILES, $SUBDIR_MAKEFILES $dir/Makefile $dir/GNUmakefile)
3676   XE_SPACE(internal_makefile_list, $internal_makefile_list $dir/Makefile.in)
3677 done
3678 AC_SUBST(INSTALL_ARCH_DEP_SUBDIR)
3679 AC_SUBST(MAKE_SUBDIR)
3680 AC_SUBST(SUBDIR_MAKEFILES)
3681
3682 dnl Make s&m symlinks in the src directory, for config.h
3683 for dir in src/s src/m; do
3684   if test ! -d "$dir" ; then
3685     echo Making symbolic link to "$srcdir/$dir"
3686     ${LN_S} "$srcdir/$dir" "$dir"
3687   fi
3688 done
3689
3690 if test "$extra_verbose" = "yes"; then
3691   echo ""
3692   PRINT_VAR(extra_objs
3693    c_switch_general  c_switch_window_system  c_switch_all
3694   ld_switch_general ld_switch_window_system ld_switch_all
3695     ld_libs_general   ld_libs_window_system   ld_libs_all)
3696   echo ""
3697 fi
3698
3699 dnl Create some auxiliary files
3700 if test -f $srcdir/src/gdbinit -a ! -f src/gdbinit ; then
3701   echo "creating src/gdbinit"; echo ""
3702   echo "source $srcdir/src/gdbinit" > src/gdbinit
3703 fi
3704
3705 dnl Create top level .sbinit for Sun compilers
3706 if test "$__SUNPRO_C" = "yes"; then
3707   echo "creating .sbinit"; echo ""
3708   ( echo "# For use with Sun WorkShop's Source browser."
3709     echo "# See sbquery(1) and sbinit(4) for more information"
3710     for dir in $MAKE_SUBDIR; do echo "import $dir"; done
3711   ) > .sbinit
3712 fi
3713
3714 dnl There are no more compile tests; remove the core they created.
3715 rm -f core
3716
3717 dnl ----------------------------------------------
3718 dnl Substitute into Makefile, config.h and paths.h
3719 dnl ----------------------------------------------
3720
3721 dnl what sort of things to edit into Makefile, config.h and paths.h
3722 dnl configuration here uncanonicalized to avoid exceeding size limits.
3723
3724 AC_SUBST(PROGNAME)
3725 AC_SUBST(version)
3726 AC_SUBST(configuration)
3727 AC_SUBST(canonical)
3728 AC_SUBST(srcdir)
3729 AC_SUBST(bindir)
3730 AC_SUBST(datadir)
3731 AC_SUBST(pkgdir)
3732 AC_SUBST(statedir)
3733 AC_SUBST(libdir)
3734 AC_SUBST(mandir)
3735
3736 AC_SUBST(prefix)
3737 dnl Yo, Stephen Bourne!  I want to marry you!
3738 PREFIX=$prefix
3739 while true; do
3740   case "$PREFIX" in
3741     *\$* ) eval "PREFIX=$PREFIX" ;;
3742     *) break ;;
3743   esac
3744 done
3745 AC_SUBST(PREFIX)
3746
3747 AC_SUBST(exec_prefix)
3748 EXEC_PREFIX=$exec_prefix
3749 while true; do
3750   case "$EXEC_PREFIX" in
3751     *\$* ) eval "EXEC_PREFIX=$EXEC_PREFIX" ;;
3752     *) break ;;
3753   esac
3754 done
3755 AC_SUBST(EXEC_PREFIX)
3756
3757 AC_SUBST(infodir)
3758 AC_SUBST(INFODIR_USER_DEFINED)
3759 INFODIR=$infodir
3760 while true; do
3761   case "$INFODIR" in
3762     *\$* ) eval "INFODIR=$INFODIR" ;;
3763     *) break ;;
3764   esac
3765 done
3766 AC_SUBST(INFODIR)
3767
3768 AC_SUBST(infopath)
3769 AC_SUBST(INFOPATH_USER_DEFINED)
3770 INFOPATH=$infopath
3771 while true; do
3772   case "$INFOPATH" in
3773     *\$* ) eval "INFOPATH=$INFOPATH" ;;
3774     *) break ;;
3775   esac
3776 done
3777 AC_SUBST(INFOPATH)
3778
3779 AC_SUBST(package_path)
3780 AC_SUBST(PACKAGE_PATH_USER_DEFINED)
3781 PACKAGE_PATH=$package_path
3782 while true; do
3783   case "$PACKAGE_PATH" in
3784     *\$* ) eval "PACKAGE_PATH=$PACKAGE_PATH" ;;
3785     *) break ;;
3786   esac
3787 done
3788 AC_SUBST(PACKAGE_PATH)
3789
3790 AC_SUBST(lispdir)
3791 AC_SUBST(LISPDIR_USER_DEFINED)
3792 LISPDIR=$lispdir
3793 while true; do
3794   case "$LISPDIR" in
3795     *\$* ) eval "LISPDIR=$LISPDIR" ;;
3796     *) break ;;
3797   esac
3798 done
3799 AC_SUBST(LISPDIR)
3800
3801 AC_SUBST(moduledir)
3802 AC_SUBST(MODULEDIR_USER_DEFINED)
3803 MODULEDIR=$moduledir
3804 while true; do
3805   case "$MODULEDIR" in
3806     *\$* ) eval "MODULEDIR=$MODULEDIR" ;;
3807     *) break ;;
3808   esac
3809 done
3810 AC_SUBST(MODULEDIR)
3811
3812 AC_SUBST(sitelispdir)
3813 AC_SUBST(SITELISPDIR_USER_DEFINED)
3814 SITELISPDIR=$sitelispdir
3815 while true; do
3816   case "$SITELISPDIR" in
3817     *\$* ) eval "SITELISPDIR=$SITELISPDIR" ;;
3818     *) break ;;
3819   esac
3820 done
3821 AC_SUBST(SITELISPDIR)
3822
3823 AC_SUBST(sitemoduledir)
3824 AC_SUBST(SITEMODULEDIR_USER_DEFINED)
3825 SITEMODULEDIR=$sitemoduledir
3826 while true; do
3827   case "$SITEMODULEDIR" in
3828     *\$* ) eval "SITEMODULEDIR=$SITEMODULEDIR" ;;
3829     *) break ;;
3830   esac
3831 done
3832 AC_SUBST(SITEMODULEDIR)
3833
3834 AC_SUBST(etcdir)
3835 AC_SUBST(ETCDIR_USER_DEFINED)
3836 ETCDIR=$etcdir
3837 while true; do
3838   case "$ETCDIR" in
3839     *\$* ) eval "ETCDIR=$ETCDIR" ;;
3840     *) break ;;
3841   esac
3842 done
3843 AC_SUBST(ETCDIR)
3844
3845 AC_SUBST(lockdir)
3846 AC_SUBST(LOCKDIR_USER_DEFINED)
3847 LOCKDIR=$lockdir
3848 while true; do
3849   case "$LOCKDIR" in
3850     *\$* ) eval "LOCKDIR=$LOCKDIR" ;;
3851     *) break ;;
3852   esac
3853 done
3854 AC_SUBST(LOCKDIR)
3855
3856 AC_SUBST(archlibdir)
3857 AC_SUBST(ARCHLIBDIR_USER_DEFINED)
3858 ARCHLIBDIR=$archlibdir
3859 while true; do
3860   case "$ARCHLIBDIR" in
3861     *\$* ) eval "ARCHLIBDIR=$ARCHLIBDIR" ;;
3862     *) break ;;
3863   esac
3864 done
3865 AC_SUBST(ARCHLIBDIR)
3866
3867 AC_SUBST(docdir)
3868 AC_SUBST(bitmapdir)
3869 AC_SUBST(extra_objs)
3870
3871 dnl The following flags combine all the information from:
3872 dnl - command line options (user always gets priority)
3873 dnl - user environment variables
3874 dnl - determined by configure
3875 dnl - the s&m header files (required for ellcc)
3876 AC_SUBST(machfile)
3877 AC_SUBST(opsysfile)
3878 AC_SUBST(c_switch_general)
3879 AC_SUBST(c_switch_window_system)
3880 AC_SUBST(c_switch_all)
3881 AC_SUBST(ld_switch_general)
3882 AC_SUBST(ld_switch_window_system)
3883 AC_SUBST(ld_switch_all)
3884 AC_SUBST(ld_libs_general)
3885 AC_SUBST(ld_libs_window_system)
3886 AC_SUBST(ld_libs_all)
3887 AC_SUBST(CFLAGS)
3888 AC_SUBST(CPPFLAGS)
3889 AC_SUBST(LDFLAGS)
3890 RECURSIVE_MAKE="\$(MAKE) \$(MFLAGS) CC='\$(CC)' CFLAGS='\$(CFLAGS)' LDFLAGS='\$(LDFLAGS)' CPPFLAGS='\$(CPPFLAGS)'"
3891 AC_SUBST(RECURSIVE_MAKE)
3892
3893 AC_SUBST(native_sound_lib)
3894 AC_SUBST(sound_cflags)
3895 AC_SUBST(RANLIB)
3896 AC_SUBST(dynodump_arch)
3897
3898 dnl Preliminary support for using a different compiler for xemacs itself.
3899 dnl Useful for building XEmacs with a C++ or 64-bit compiler.
3900 : ${XEMACS_CC:=$CC}
3901 AC_SUBST(XEMACS_CC)
3902
3903
3904 dnl The default is no
3905 if test "$with_site_lisp" = "no"; then
3906   AC_DEFINE(INHIBIT_SITE_LISP)
3907 fi
3908 dnl The default is yes
3909 if test "$with_site_modules" = "no"; then
3910   AC_DEFINE(INHIBIT_SITE_MODULES)
3911 fi
3912
3913 XE_SPACE(ac_configure_args, $ac_configure_args)
3914 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "$canonical")
3915 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "$ac_configure_args")
3916 AC_DEFINE_UNQUOTED(config_machfile,  "$machfile")
3917 AC_DEFINE_UNQUOTED(config_opsysfile, "$opsysfile")
3918
3919 dnl Following are deprecated
3920
3921 null_string=""
3922 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE,     $null_string)
3923 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, $null_string)
3924 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,      $null_string)
3925 AC_DEFINE_UNQUOTED(LD_SWITCH_SITE,       $null_string)
3926 AC_DEFINE_UNQUOTED(C_SWITCH_SITE,        $null_string)
3927
3928 dnl Note: as a general rule, *only* define things here that are not
3929 dnl autodetected.  For things that are autodetected, define them
3930 dnl at the point where the autodetection occurs or would occur,
3931 dnl so that the user gets immediate feedback on the results of the
3932 dnl autodetection.
3933
3934 if   test "$GNU_MALLOC"         = "yes"; then AC_DEFINE(GNU_MALLOC)
3935 elif test "$with_system_malloc" = "yes"; then AC_DEFINE(USE_SYSTEM_MALLOC)
3936 elif test "$with_debug_malloc"  = "yes"; then AC_DEFINE(USE_DEBUG_MALLOC)
3937                                               AC_DEFINE(USE_SYSTEM_MALLOC)
3938 fi
3939 test "$with_i18n3"         = "yes" && AC_DEFINE(I18N3)
3940 test "$GCC"                = "yes" && AC_DEFINE(USE_GCC)
3941 test "$external_widget"    = "yes" && AC_DEFINE(EXTERNAL_WIDGET)
3942 test "$no_doc_file"        = "yes" && AC_DEFINE(NO_DOC_FILE)
3943 dnl test "$const_is_losing"    = "yes" && AC_DEFINE(CONST_IS_LOSING)
3944 test "$with_purify"        = "yes" && AC_DEFINE(PURIFY)
3945 test "$with_quantify"      = "yes" && AC_DEFINE(QUANTIFY)
3946 test "$with_pop"           = "yes" && AC_DEFINE(MAIL_USE_POP)
3947 test "$with_kerberos"      = "yes" && AC_DEFINE(KERBEROS)
3948 test "$with_hesiod"        = "yes" && AC_DEFINE(HESIOD)
3949 test "$use_union_type"     = "yes" && AC_DEFINE(USE_UNION_TYPE)
3950
3951 dnl -------------------------------
3952 dnl Report on what we decided to do
3953 dnl -------------------------------
3954
3955 (
3956 dnl /etc/osversion is on SONY NEWS-OS
3957 if test -f /etc/osversion; then dnl SONY NEWS-OS
3958   echo "osversion: `cat /etc/osversion`"
3959 else
3960   echo "uname -a: `uname -a`"
3961 fi
3962 echo ""
3963 echo "$0 $quoted_arguments"
3964 ) > Installation
3965
3966 xemacs_betaname=""
3967 test ! -z "${emacs_beta_version}" && xemacs_betaname="-b${emacs_beta_version}"
3968
3969 dnl Start stdout redirection to '| tee -a Installation'
3970 (
3971 echo "
3972
3973 XEmacs ${emacs_major_version}.${emacs_minor_version}${xemacs_betaname} \"$xemacs_codename\" configured for \`$canonical'.
3974
3975   Where should the build process find the source code?    $srcdir
3976   What installation prefix should install use?            $prefix
3977   What operating system and machine description files should XEmacs use?
3978         \`$opsysfile' and \`$machfile'
3979   What compiler should XEmacs be built with?              $CC $CFLAGS
3980   Should XEmacs use the GNU version of malloc?            ${GNU_MALLOC}${GNU_MALLOC_reason}
3981   Should XEmacs use the relocating allocator for buffers? $rel_alloc
3982   What window system should XEmacs use?                   ${window_system}"
3983 if test "$with_x11" = "yes"; then
3984   echo "  Where do we find X Windows header files?                $x_includes"
3985   echo "  Where do we find X Windows libraries?                   $x_libraries"
3986 fi
3987 if test -n "$site_includes"; then
3988   echo "  Additional header files:                                $site_includes"
3989 fi
3990 if test -n "$site_libraries"; then
3991   echo "  Additional libraries:                                   $site_libraries"
3992 fi
3993 if test -n "$site_prefixes"; then
3994   echo "  Additional prefixes:                                    $site_prefixes"
3995 fi
3996 if test -n "$runpath"; then
3997   echo "  Runtime library search path:                            $runpath"
3998 fi
3999 test "$with_dnet"  = yes && echo "  Compiling in support for DNET."
4000 test "$with_socks" = yes && echo "  Compiling in support for SOCKS."
4001 test "$with_xauth" = yes && echo "  Compiling in support for XAUTH."
4002 if test "$with_xmu" != yes -a "$with_x11" = yes; then
4003   echo "  No Xmu; substituting equivalent routines."
4004 fi
4005
4006 if test "$with_xpm" = yes; then
4007   echo "  Compiling in support for XPM images."
4008 elif test "$with_x11" = yes; then
4009   echo "  --------------------------------------------------------------------"
4010   echo "  WARNING: Compiling without XPM support."
4011   if test "$xpm_problem" != ""; then
4012     echo "  Reason: $xpm_problem"
4013   fi
4014   echo "  WARNING: You should strongly consider installing XPM."
4015   echo "  WARNING: Otherwise toolbars and other graphics will look suboptimal."
4016   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
4017   echo "  --------------------------------------------------------------------"
4018 fi
4019 if test "$with_png" = yes; then
4020   echo "  Compiling in support for PNG image handling."
4021 elif test "$window_system" != "none"; then
4022   echo "  --------------------------------------------------------------------"
4023   echo "  WARNING: Compiling without PNG image support."
4024   if test "$png_problem" != ""; then
4025     echo "  Reason: $png_problem"
4026   fi
4027   echo "  WARNING: You should strongly consider installing the PNG libraries."
4028   echo "  WARNING: Otherwise certain images and glyphs may not display."
4029   echo "  WARNING: (a copy may be found in ftp://ftp.xemacs.org/pub/xemacs/aux)"
4030   echo "  --------------------------------------------------------------------"
4031 fi
4032 test "$with_gif"   = yes && echo "  Compiling in support for (builtin) GIF image handling."
4033 test "$with_jpeg"  = yes && echo "  Compiling in support for JPEG image handling."
4034 test "$with_tiff"  = yes && echo "  Compiling in support for TIFF image handling."
4035 test "$with_xface" = yes && echo "  Compiling in support for X-Face message headers."
4036 case "$with_sound" in
4037   nas    ) echo "  Compiling in network sound (NAS) support." ;;
4038   native ) echo "  Compiling in native sound support." ;;
4039   both   ) echo "  Compiling in both network and native sound support." ;;
4040 esac
4041 test "$old_nas" = yes && echo "        nas library lacks error trapping, will play synchronously."
4042
4043 test "$with_database_berkdb" = yes && echo "  Compiling in support for Berkeley DB."
4044 test "$with_database_dbm"    = yes && echo "  Compiling in support for DBM."
4045 test "$with_database_gnudbm" = yes && echo "  Compiling in support for GNU DBM."
4046
4047 test "$with_umich_ldap"      = yes && echo "  Compiling in support for LDAP (UMich libs)."
4048 test "$with_ns_ldap"         = yes && echo "  Compiling in support for LDAP (Netscape SDK)."
4049 test "$with_ldap" = yes -a "$with_umich_ldap" = no -a "$with_ns_ldap" = no && echo "  Compiling in support for LDAP (Generic)."
4050
4051 test "$with_ncurses"  = yes && echo "  Compiling in support for ncurses."
4052 test "$with_gpm"      = yes && echo "  Compiling in support for GPM (General Purpose Mouse)."
4053
4054 test "$with_mule"     = yes && echo "  Compiling in Mule (multi-lingual) support."
4055 test "$with_file_coding"     = yes && echo "  Compiling in File coding support."
4056 test "$with_xim"      != no && echo "  Compiling in XIM (X11R5+ I18N input method) support."
4057 test "$with_xim" = motif    && echo "    Using Motif to provide XIM support."
4058 test "$with_xim" = xlib     && echo "    Using raw Xlib to provide XIM support."
4059 test "$with_xfs" = yes      && echo "    Using XFontSet to provide bilingual menubar."
4060 test "$with_canna"    = yes && echo "  Compiling in support for Canna on Mule."
4061 if test "$with_wnn" = yes; then
4062   echo "  Compiling in support for the WNN input method on Mule."
4063   test "$with_wnn6" = yes && echo "    Using WNN version 6."
4064 fi
4065 test "$with_i18n3"    = yes && echo "  Compiling in I18N support, level 3 (doesn't currently work)."
4066
4067 test "$with_cde"      = yes && echo "  Compiling in support for CDE."
4068 test "$with_tooltalk" = yes && echo "  Compiling in support for ToolTalk."
4069 test "$with_offix"    = yes && echo "  Compiling in support for OffiX."
4070 test "$with_dragndrop" = yes && echo "  Compiling in EXPERIMENTAL support for Drag'n'Drop ($dragndrop_proto )."
4071 test "$with_workshop" = yes && echo "  Compiling in support for Sun WorkShop."
4072 test "$with_session"  != no && echo "  Compiling in support for proper session-management."
4073 case "$with_menubars" in
4074   lucid ) echo "  Using Lucid menubars." ;;
4075   motif ) echo "  Using Motif menubars."
4076           echo "  *WARNING*  The Motif menubar implementation is currently buggy."
4077           echo "             We recommend using the Lucid menubar instead."
4078           echo "             Re-run configure with --with-menubars='lucid'." ;;
4079 esac
4080 case "$with_scrollbars" in
4081   lucid    ) echo "  Using Lucid scrollbars."     ;;
4082   motif    ) echo "  Using Motif scrollbars."     ;;
4083   athena   ) echo "  Using Athena scrollbars."    ;;
4084   athena3d ) echo "  Using Athena-3d scrollbars." ;;
4085 esac
4086 case "$with_dialogs" in
4087   motif    )
4088     echo "  Using Motif dialog boxes."
4089     if test "$unexec" = "unexaix.o"; then if test "`uname -v`" = 4 -a "`uname -r`" -ge 3; then
4090       echo "  *WARNING*  The Motif dialog boxes cause problems on AIX 4.3 and higher."
4091       echo "             We recommend using the Athena dialog boxes instead."
4092       echo "             Install libXaw and re-run configure with --with-dialogs='athena'."
4093       echo "             Read the PROBLEMS file for more information."
4094     fi; fi
4095     ;;
4096   athena   ) echo "  Using Athena dialog boxes."    ;;
4097   athena3d ) echo "  Using Athena-3d dialog boxes." ;;
4098 esac
4099 test "$with_shlib" = "yes" && echo "  Compiling in DLL support."
4100 test "$with_clash_detection" = yes && \
4101   echo "  Clash detection will use \"$lockdir\" for locking files."
4102 echo "  movemail will use \"$mail_locking\" for locking mail spool files."
4103 test "$with_pop"        = yes && echo "  Using POP for mail access."
4104 test "$with_kerberos"   = yes && echo "  Using Kerberos for POP authentication."
4105 test "$with_hesiod"     = yes && echo "  Using Hesiod to get POP server host."
4106 test "$use_union_type"  = yes && echo "  Using the union type for Lisp_Objects."
4107 test "$debug"              = yes && echo "  Compiling in extra code for debugging."
4108 test "$usage_tracking"     = yes && echo "  Compiling with usage tracking active (Sun internal)."
4109 if test "$error_check_extents $error_check_typecheck $error_check_bufpos $error_check_gc $error_check_malloc" \
4110   != "no no no no no"; then
4111   echo "  WARNING: ---------------------------------------------------------"
4112   echo "  WARNING: Compiling in support for runtime error checking."
4113   echo "  WARNING: XEmacs will run noticeably more slowly as a result."
4114   echo "  WARNING: Error checking is on by default for XEmacs beta releases."
4115   echo "  WARNING: ---------------------------------------------------------"
4116 fi
4117 echo ""
4118 ) | tee -a Installation
4119 dnl echo "The above configure report is appended to \"Installation\" file."
4120 echo ""
4121
4122 dnl -----------------------------------
4123 dnl Now generate config.h and Makefiles
4124 dnl -----------------------------------
4125 dnl This has to be called in order for this variable to get into config.status
4126 AC_SUBST(internal_makefile_list)
4127 # Remove any trailing slashes in these variables.
4128 test -n "$prefix" &&
4129   prefix=`echo '' "$prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
4130 test -n "$exec_prefix" &&
4131   exec_prefix=`echo '' "$exec_prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
4132
4133 dnl Build Makefile.in's from Makefile.in.in's
4134 dnl except ./Makefile from $srcdir/Makefile.in
4135
4136 for file in $internal_makefile_list; do
4137   test "$file" = src/Makefile.in && \
4138     file="src/Makefile.in:src/Makefile.in.in:src/depend"
4139   ac_output_files="${ac_output_files+$ac_output_files }$file"
4140 done
4141 ac_output_files="$ac_output_files src/paths.h lib-src/config.values"
4142 if test "$with_shlib" = "yes"; then
4143   ac_output_files="$ac_output_files lib-src/ellcc.h"
4144 fi
4145
4146 AC_OUTPUT($ac_output_files,
4147 [for dir in . $MAKE_SUBDIR; do
4148   (
4149     cd $dir
4150     rm -f junk.c
4151     < Makefile.in \
4152       sed -e '/^# Generated/d' \
4153           -e 's%/\*\*/#.*%%' \
4154           -e 's/^ *# */#/' \
4155 dnl Delete Makefile.in.in comment lines
4156           -e '/^##/d' \
4157 dnl Pass through CPP directives unchanged
4158           -e '/^#/ {
4159 p
4160 d
4161 }'        \
4162 dnl Quote other lines to protect from CPP substitution
4163           -e '/./ {
4164 s/\([[\"]]\)/\\\1/g
4165 s/^/"/
4166 s/$/"/
4167 }'  > junk.c;
4168
4169 dnl Create a GNUmakefile and Makefile from Makefile.in.
4170
4171 changequote(<<,>>)dnl
4172 dnl CPP_MAKEFILE(CPPFLAGS,filename)
4173 define(<<CPP_MAKEFILE>>,
4174 echo creating $dir/<<$2>>
4175 $CPP -I. -I${top_srcdir}/src <<$1>> junk.c \
4176 dnl Delete line directives inserted by $CPP
4177   | sed -e 's/^\#.*//'          \
4178 dnl Delete spurious blanks inserted by $CPP
4179         -e 's/^[ TAB][ TAB]*$//'\
4180         -e 's/^ /TAB/'          \
4181 dnl Delete blank lines
4182   | sed -n -e '/^..*$/p'        \
4183 dnl Restore lines quoted above to original contents.
4184   | sed '/^\"/ {
4185         s/\\\([\"]\)/\1/g
4186         s/^[ TAB]*\"//
4187         s/\"[ TAB]*$//
4188 }' > Makefile.new
4189     chmod 444 Makefile.new
4190     mv -f Makefile.new <<$2>>
4191 )dnl CPP_MAKEFILE
4192
4193     CPP_MAKEFILE(,Makefile)
4194     CPP_MAKEFILE(-DUSE_GNU_MAKE,GNUmakefile)
4195 changequote([,])dnl
4196     rm -f junk.c
4197   )
4198 done
4199
4200 dnl Append AC_DEFINE information to lib-src/config.values
4201 dnl (AC_SUBST information is already there (see config.values.sh).
4202 sed < config.status >> lib-src/config.values \
4203   -e '/{ac_dA}.*{ac_dB}.*{ac_dC}.*{ac_dD}$/!d' \
4204   -e 's/\${ac_dA}\(.*\)\${ac_dB}.*\${ac_dC}\(.*\)\${ac_dD}/\1 \2/' \
4205   -e 's/^\([[^ ]]*\) $/\1 ""/' \
4206   -e 's/ 1$/ t/'
4207
4208 ],
4209 [CPP="$CPP"
4210  top_srcdir="$srcdir"
4211  MAKE_SUBDIR="$MAKE_SUBDIR"
4212 ])dnl