git.chise.org Git - chise/xemacs-chise.git.1/blob - lisp/finder.el

   1 ;;; finder.el --- topic & keyword-based code finder
   2
   3 ;; Copyright (C) 1992 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   6 ;; Created: 16 Jun 1992
   7 ;; Version: 1.0
   8 ;; Keywords: help
   9 ;; X-Modified-by: Bob Weiner <weiner@mot.com>, 4/18/95, to include Lisp
  10 ;;      library directory names in finder-program-info, for fast display of
  11 ;;      Lisp libraries and associated commentaries.  Added {v}, finder-view,
  12 ;;      and {e}, finder-edit commands for displaying libraries.
  13 ;;
  14 ;;      Added user variable, 'finder-abbreviate-directory-list', used to
  15 ;;      abbreviate directories before they are saved to finder-program-info.
  16 ;;      Such relative directories can be portable from one Emacs installation
  17 ;;      to another.  Default value is based upon the value of Emacs'
  18 ;;      data-directory variable.
  19
  20 ;; This file is part of XEmacs.
  21
  22 ;; XEmacs is free software; you can redistribute it and/or modify it
  23 ;; under the terms of the GNU General Public License as published by
  24 ;; the Free Software Foundation; either version 2, or (at your option)
  25 ;; any later version.
  26
  27 ;; XEmacs is distributed in the hope that it will be useful, but
  28 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  29 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30 ;; General Public License for more details.
  31
  32 ;; You should have received a copy of the GNU General Public License
  33 ;; along with XEmacs; see the file COPYING.  If not, write to the Free
  34 ;; Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  35 ;; 02111-1307, USA.
  36
  37 ;;; Synched up with: FSF 19.34.
  38
  39 ;;; Commentary:
  40
  41 ;; This mode uses the Keywords library header to provide code-finding
  42 ;; services by keyword.
  43 ;;
  44 ;; Things to do:
  45 ;;    1. Support multiple keywords per search.  This could be extremely hairy;
  46 ;; there doesn't seem to be any way to get completing-read to exit on
  47 ;; an EOL with no substring pending, which is what we'd want to end the loop.
  48 ;;    2. Search by string in synopsis line?
  49 ;;    3. Function to check finder-package-info for unknown keywords.
  50
  51 ;;; Code:
  52
  53 (require 'lisp-mnt)
  54 (condition-case nil
  55     (require 'finder-inf)
  56   (t nil))
  57 ;; XEmacs addition
  58 (require 'picture)
  59 (require 'mode-motion)
  60
  61 (defvar finder-emacs-root-directory
  62   (file-name-directory (directory-file-name data-directory))
  63   "Root directory of current emacs tree.")
  64
  65 (defvar finder-abbreviate-directory-list
  66   (list finder-emacs-root-directory)
  67   "*List of directory roots to remove from finder-package-info directory entries.
  68 The first element in the list is used when expanding relative package
  69 directories to view or extract information from package source code.")
  70
  71 (defvar finder-file-regexp "\\.el$"
  72   "Regexp which matches file names but not Emacs Lisp finder keywords.")
  73
  74 ;; Local variable in finder buffer.
  75 (defvar finder-headmark)
  76
  77 (defvar finder-known-keywords
  78   `(
  79     (abbrev     . "abbreviation handling, typing shortcuts, macros")
  80     (bib        . "code related to the `bib' bibliography processor")
  81     (c          . "C, C++, and Objective-C language support")
  82     (calendar   . "calendar and time management support")
  83     (comm       . "communications, networking, remote access to files")
  84     (data       . "support for editing files of data")
  85     (docs       . "support for Emacs documentation")
  86     (dumped     . "files preloaded into Emacs")
  87     (emulations . "emulations of other editors")
  88     (extensions . "Emacs Lisp language extensions")
  89     (faces      . "support for multiple fonts")
  90     (frames     . "support for Emacs frames and window systems")
  91     (games      . "games, jokes and amusements")
  92     (hardware   . "support for interfacing with exotic hardware")
  93     (help       . "support for on-line help systems")
  94     (hypermedia . "support for links between text or other media types")
  95     (i18n       . "internationalization and alternate character-set support")
  96     (internal   . "code for Emacs internals, build process, defaults")
  97     (languages  . "specialized modes for editing programming languages")
  98     (lisp       . "Lisp support, including Emacs Lisp")
  99     (local      . "code local to your site")
 100     (maint      . "maintenance aids for the Emacs development group")
 101     (mail       . "modes for electronic-mail handling")
 102     (matching   . "various sorts of searching and matching")
 103     (mouse      . "mouse support")
 104     ,(when (featurep 'mule)
 105        (cons 'mule "multi-language extensions"))
 106     (news       . "support for netnews reading and posting")
 107     (oop        . "support for object-oriented programming")
 108     (outlines   . "support for hierarchical outlining")
 109     (processes  . "process, subshell, compilation, and job control support")
 110     (terminals  . "support for terminal types")
 111     (tex        . "code related to the TeX formatter")
 112     (tools      . "programming tools")
 113     (unix       . "front-ends/assistants for, or emulators of, UNIX features")
 114     (vms        . "support code for vms")
 115     (wp         . "word processing")
 116     ))
 117
 118 (defvar finder-mode-map nil)
 119 (or finder-mode-map
 120     (let ((map (make-sparse-keymap)))
 121       (define-key map " "       'finder-select)
 122       (define-key map "f"       'finder-select)
 123       (define-key map "\C-m"    'finder-select)
 124       ;; XEmacs changes
 125       (define-key map "e"       'finder-edit)
 126       (define-key map "v"       'finder-view)
 127       (define-key map "?"       'finder-summary)
 128       (define-key map "q"       'finder-exit)
 129       (define-key map "d"       'finder-list-keywords)
 130       ;; XEmacs change
 131       (define-key map [button2] 'finder-mouse-select)
 132       (setq finder-mode-map map)))
 133
 134
 135 ;;; Code for regenerating the keyword list.
 136
 137 (defvar finder-package-info nil
 138   "Assoc list mapping file names to description & keyword lists.")
 139
 140 (defvar finder-compile-keywords-quiet nil
 141   "If non-nil finder-compile-keywords will not print any messages.")
 142
 143 (defun finder-compile-keywords (&rest dirs)
 144   "Regenerate the keywords association list into the file `finder-inf.el'.
 145 Optional arguments are a list of Emacs Lisp directories to compile from; no
 146 arguments compiles from `load-path'."
 147   (save-excursion
 148     ;; XEmacs change
 149     (find-file "finder-inf.el")
 150     (let ((processed nil)
 151           (directory-abbrev-alist
 152            (append
 153             (mapcar (function (lambda (dir) (cons dir "")))
 154                     finder-abbreviate-directory-list)
 155             directory-abbrev-alist))
 156           (using-load-path))
 157       (or dirs (setq dirs load-path))
 158       (setq using-load-path (equal dirs load-path))
 159       (erase-buffer)
 160       (insert ";;; finder-inf.el --- keyword-to-package mapping\n")
 161       (insert ";; Keywords: help\n")
 162       (insert ";;; Commentary:\n")
 163       (insert ";; Don't edit this file.  It's generated by finder.el\n\n")
 164       (insert ";;; Code:\n")
 165       (insert "\n(setq finder-package-info '(\n")
 166       (mapcar
 167        (function
 168         (lambda (d)
 169           (mapcar
 170            (function
 171             (lambda (f)
 172               (if (not (member f processed))
 173                   (let (summary keystart keywords)
 174                     (setq processed (cons f processed))
 175                     (if (not finder-compile-keywords-quiet)
 176                         (message "Processing %s ..." f))
 177                     (save-excursion
 178                       (set-buffer (get-buffer-create "*finder-scratch*"))
 179                       (buffer-disable-undo (current-buffer))
 180                       (erase-buffer)
 181                       (insert-file-contents (expand-file-name f d))
 182                       (condition-case err
 183                           (setq summary  (lm-synopsis)
 184                                 keywords (lm-keywords))
 185                         (t (message "finder: error processing %s %S" f err))))
 186                     (if (not summary)
 187                         nil
 188                       (insert (format "    (\"%s\"\n        " f))
 189                       (prin1 summary (current-buffer))
 190                       (insert "\n        ")
 191                       (setq keystart (point))
 192                       (insert (if keywords (format "(%s)" keywords) "nil"))
 193                       (subst-char-in-region keystart (point) ?, ? )
 194                       (insert "\n        ")
 195                       (prin1 (abbreviate-file-name d) (current-buffer))
 196                       (insert ")\n"))))))
 197            ;;
 198            ;; Skip null, non-existent or relative pathnames, e.g. "./", if
 199            ;; using load-path, so that they do not interfere with a scan of
 200            ;; library directories only.
 201            (if (and using-load-path
 202                     (not (and d (file-name-absolute-p d) (file-exists-p d))))
 203                nil
 204              (setq d (file-name-as-directory (or d ".")))
 205              (directory-files d nil "^[^=].*\\.el$")))))
 206        dirs)
 207       (insert "))\n\n(provide 'finder-inf)\n\n;;; finder-inf.el ends here\n")
 208       (kill-buffer "*finder-scratch*")
 209       (unless noninteractive
 210         (eval-current-buffer)) ; So we get the new keyword list immediately
 211       (basic-save-buffer))))
 212
 213 (defun finder-compile-keywords-make-dist ()
 214   "Regenerate `finder-inf.el' for the Emacs distribution."
 215   (finder-compile-keywords default-directory))
 216
 217 ;;; Now the retrieval code
 218
 219 (defun finder-insert-at-column (column &rest strings)
 220   "Insert list of STRINGS, at column COLUMN."
 221   (if (>= (current-column) column) (insert "\n"))
 222   (move-to-column column)
 223   (let ((col (current-column)))
 224     (if (< col column)
 225         (indent-to column)
 226       (if (and (/= col column)
 227                (= (preceding-char) ?\t))
 228           (let (indent-tabs-mode)
 229             (delete-char -1)
 230             (indent-to col)
 231             (move-to-column column)))))
 232   (apply 'insert strings))
 233
 234 (defun finder-list-keywords ()
 235   "Display descriptions of the keywords in the Finder buffer."
 236   (interactive)
 237   (setq buffer-read-only nil)
 238   (erase-buffer)
 239   (mapcar
 240    (lambda (assoc)
 241      (let ((keyword (car assoc)))
 242        (insert (symbol-name keyword))
 243        (finder-insert-at-column 14 (concat (cdr assoc) "\n"))
 244        (cons (symbol-name keyword) keyword)))
 245    finder-known-keywords)
 246   (goto-char (point-min))
 247   (setq finder-headmark (point))
 248   (setq buffer-read-only t)
 249   (set-buffer-modified-p nil)
 250   ;; XEmacs change
 251   (if (not (one-window-p))
 252       (balance-windows))
 253   (finder-summary))
 254
 255 (defun finder-list-matches (key)
 256   (setq buffer-read-only nil)
 257   (erase-buffer)
 258   (let ((id (intern key)))
 259     (insert
 260      "The following packages match the keyword `" key "':\n\n")
 261     (setq finder-headmark (point))
 262     (mapcar
 263      (lambda (x)
 264        (if (memq id (car (cdr (cdr x))))
 265            (progn
 266              (insert (car x))
 267              (finder-insert-at-column 16 (concat (car (cdr x)) "\n")))))
 268      finder-package-info)
 269     (goto-char (point-min))
 270     (forward-line)
 271     (setq buffer-read-only t)
 272     (set-buffer-modified-p nil)
 273     (shrink-window-if-larger-than-buffer)
 274     (finder-summary)))
 275
 276 ;; Search for a file named FILE the same way `load' would search.
 277 (defun finder-find-library (file)
 278   (if (file-name-absolute-p file)
 279       file
 280     (let ((dirs load-path)
 281           found)
 282       (while (and dirs (not found))
 283         (if (file-exists-p (expand-file-name (concat file ".el") (car dirs)))
 284             (setq found (expand-file-name file (car dirs)))
 285           (if (file-exists-p (expand-file-name file (car dirs)))
 286               (setq found (expand-file-name file (car dirs)))))
 287         (setq dirs (cdr dirs)))
 288       found)))
 289
 290 (defun finder-commentary (file)
 291   (interactive)
 292   (let* ((str (lm-commentary (finder-find-library file))))
 293     (if (null str)
 294         (error "Can't find any Commentary section"))
 295     (pop-to-buffer "*Finder*")
 296     ;; XEmacs change
 297     (setq buffer-read-only nil
 298           mode-motion-hook 'mode-motion-highlight-line)
 299     (erase-buffer)
 300     (insert str)
 301     (goto-char (point-min))
 302     (delete-blank-lines)
 303     (goto-char (point-max))
 304     (delete-blank-lines)
 305     (goto-char (point-min))
 306     (while (re-search-forward "^;+ ?" nil t)
 307       (replace-match "" nil nil))
 308     (goto-char (point-min))
 309     (setq buffer-read-only t)
 310     (set-buffer-modified-p nil)
 311     (shrink-window-if-larger-than-buffer)
 312     (finder-summary)))
 313
 314 (defun finder-current-item ()
 315   (if (and finder-headmark (< (point) finder-headmark))
 316       (error "No keyword or filename on this line")
 317     (save-excursion
 318       (beginning-of-line)
 319       (current-word))))
 320
 321 ;; XEmacs change
 322 (defun finder-edit ()
 323   (interactive)
 324   (let ((entry (finder-current-item)))
 325     (if (string-match finder-file-regexp entry)
 326         (let ((path (finder-find-library entry)))
 327           (if path
 328               (find-file-other-window path)
 329             (error "Can't find Emacs Lisp library: '%s'" entry)))
 330       ;; a finder keyword
 331       (error "Finder-edit works on Emacs Lisp libraries only"))))
 332
 333 ;; XEmacs change
 334 (defun finder-view ()
 335   (interactive)
 336   (let ((entry (finder-current-item)))
 337     (if (string-match finder-file-regexp entry)
 338         (let ((path (finder-find-library entry)))
 339           (if path
 340               (view-file-other-window path)
 341             (error "Can't find Emacs Lisp library: '%s'" entry)))
 342       ;; a finder keyword
 343       (error "Finder-view works on Emacs Lisp libraries only"))))
 344
 345 (defun finder-select ()
 346   (interactive)
 347   (let ((key (finder-current-item)))
 348     ;; XEmacs change
 349     (if (string-match finder-file-regexp key)
 350         (finder-commentary key)
 351       (finder-list-matches key))))
 352
 353 ;; XEmacs change
 354 (defun finder-mouse-select (ev)
 355   (interactive "e")
 356   (goto-char (event-point ev))
 357   (finder-select))
 358
 359 ;; XEmacs change
 360 ;;;###autoload
 361 (defun finder-by-keyword ()
 362   "Find packages matching a given keyword."
 363   (interactive)
 364   (finder-mode)
 365   (finder-list-keywords))
 366
 367 (defun finder-mode ()
 368   "Major mode for browsing package documentation.
 369 \\<finder-mode-map>
 370 \\[finder-select]       more help for the item on the current line
 371 \\[finder-edit] edit Lisp library in another window
 372 \\[finder-view] view Lisp library in another window
 373 \\[finder-exit] exit Finder mode and kill the Finder buffer.
 374 "
 375   (interactive)
 376   (pop-to-buffer "*Finder*")
 377   ;; XEmacs change
 378   (setq buffer-read-only nil
 379         mode-motion-hook 'mode-motion-highlight-line)
 380   (erase-buffer)
 381   (use-local-map finder-mode-map)
 382   (set-syntax-table emacs-lisp-mode-syntax-table)
 383   (setq mode-name "Finder")
 384   (setq major-mode 'finder-mode)
 385   (make-local-variable 'finder-headmark)
 386   (setq finder-headmark nil))
 387
 388 (defun finder-summary ()
 389   "Summarize basic Finder commands."
 390   (interactive)
 391   (message "%s"
 392    (substitute-command-keys
 393     ;; XEmacs change
 394     "\\<finder-mode-map>\\[finder-select] = select, \\[finder-list-keywords] = keywords, \\[finder-edit] = edit, \\[finder-view] = view, \\[finder-exit] = quit, \\[finder-summary] = help")))
 395
 396 (defun finder-exit ()
 397   "Exit Finder mode and kill the buffer"
 398   (interactive)
 399   ;; XEmacs change
 400   (or (one-window-p t 0)
 401       (delete-window))
 402   (kill-buffer "*Finder*"))
 403
 404 (provide 'finder)
 405
 406 ;;; finder.el ends here