git.chise.org Git - chise/xemacs-chise.git.1/blob - lisp/finder.el

   1 ;;; finder.el --- topic & keyword-based code finder
   2
   3 ;; Copyright (C) 1992 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   6 ;; Created: 16 Jun 1992
   7 ;; Version: 1.0
   8 ;; Keywords: help
   9 ;; X-Modified-by: Bob Weiner <weiner@mot.com>, 4/18/95, to include Lisp
  10 ;;      library directory names in finder-program-info, for fast display of
  11 ;;      Lisp libraries and associated commentaries.  Added {v}, finder-view,
  12 ;;      and {e}, finder-edit commands for displaying libraries.
  13 ;;
  14 ;;      Added user variable, 'finder-abbreviate-directory-list', used to
  15 ;;      abbreviate directories before they are saved to finder-program-info.
  16 ;;      Such relative directories can be portable from one Emacs installation
  17 ;;      to another.  Default value is based upon the value of Emacs'
  18 ;;      data-directory variable.
  19
  20 ;; This file is part of XEmacs.
  21
  22 ;; XEmacs is free software; you can redistribute it and/or modify it
  23 ;; under the terms of the GNU General Public License as published by
  24 ;; the Free Software Foundation; either version 2, or (at your option)
  25 ;; any later version.
  26
  27 ;; XEmacs is distributed in the hope that it will be useful, but
  28 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  29 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30 ;; General Public License for more details.
  31
  32 ;; You should have received a copy of the GNU General Public License
  33 ;; along with XEmacs; see the file COPYING.  If not, write to the Free
  34 ;; Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  35 ;; 02111-1307, USA.
  36
  37 ;;; Synched up with: FSF 19.34.
  38
  39 ;;; Commentary:
  40
  41 ;; This mode uses the Keywords library header to provide code-finding
  42 ;; services by keyword.
  43 ;;
  44 ;; Things to do:
  45 ;;    1. Support multiple keywords per search.  This could be extremely hairy;
  46 ;; there doesn't seem to be any way to get completing-read to exit on
  47 ;; an EOL with no substring pending, which is what we'd want to end the loop.
  48 ;;    2. Search by string in synopsis line?
  49 ;;    3. Function to check finder-package-info for unknown keywords.
  50
  51 ;;; Code:
  52
  53 (require 'lisp-mnt)
  54 (condition-case nil
  55     (require 'finder-inf)
  56   (t nil))
  57 ;; XEmacs addition
  58 (require 'picture)
  59 (require 'mode-motion)
  60
  61 (defvar finder-emacs-root-directory
  62   (file-name-directory (directory-file-name data-directory))
  63   "Root directory of current emacs tree.")
  64
  65 (defvar finder-abbreviate-directory-list
  66   (list finder-emacs-root-directory)
  67   "*List of directory roots to remove from finder-package-info directory entries.
  68 The first element in the list is used when expanding relative package
  69 directories to view or extract information from package source code.")
  70
  71 (defvar finder-file-regexp "\\.el$"
  72   "Regexp which matches file names but not Emacs Lisp finder keywords.")
  73
  74 ;; Local variable in finder buffer.
  75 (defvar finder-headmark)
  76
  77 (defvar finder-known-keywords
  78   `(
  79     (abbrev     . "abbreviation handling, typing shortcuts, macros")
  80     (bib        . "code related to the `bib' bibliography processor")
  81     (c          . "C, C++, and Objective-C language support")
  82     (calendar   . "calendar and time management support")
  83     (comm       . "communications, networking, remote access to files")
  84     (data       . "support for editing files of data")
  85     (docs       . "support for Emacs documentation")
  86     (dumped     . "files preloaded into Emacs")
  87     (emulations . "emulations of other editors")
  88     (extensions . "Emacs Lisp language extensions")
  89     (faces      . "support for multiple fonts")
  90     (frames     . "support for Emacs frames and window systems")
  91     (games      . "games, jokes and amusements")
  92     (hardware   . "support for interfacing with exotic hardware")
  93     (help       . "support for on-line help systems")
  94     (hypermedia . "support for links between text or other media types")
  95     (i18n       . "internationalization and alternate character-set support")
  96     (internal   . "code for Emacs internals, build process, defaults")
  97     (languages  . "specialized modes for editing programming languages")
  98     (lisp       . "Lisp support, including Emacs Lisp")
  99     (local      . "code local to your site")
 100     (maint      . "maintenance aids for the Emacs development group")
 101     (mail       . "modes for electronic-mail handling")
 102     (matching   . "various sorts of searching and matching")
 103     (mouse      . "mouse support")
 104     ,(when (featurep 'mule)
 105        (cons 'mule "multi-language extensions"))
 106     (news       . "support for netnews reading and posting")
 107     (oop        . "support for object-oriented programming")
 108     (outlines   . "support for hierarchical outlining")
 109     (processes  . "process, subshell, compilation, and job control support")
 110     (terminals  . "support for terminal types")
 111     (tex        . "code related to the TeX formatter")
 112     (tools      . "programming tools")
 113     (unix       . "front-ends/assistants for, or emulators of, UNIX features")
 114     (vms        . "support code for vms")
 115     (wp         . "word processing")
 116     ))
 117
 118 (defvar finder-mode-map nil)
 119 (or finder-mode-map
 120     (let ((map (make-sparse-keymap)))
 121       (define-key map " "       'finder-select)
 122       (define-key map "f"       'finder-select)
 123       (define-key map "\C-m"    'finder-select)
 124       ;; XEmacs changes
 125       (define-key map "e"       'finder-edit)
 126       (define-key map "v"       'finder-view)
 127       (define-key map "?"       'finder-summary)
 128       (define-key map "q"       'finder-exit)
 129       (define-key map "d"       'finder-list-keywords)
 130       ;; XEmacs change
 131       (define-key map [button2] 'finder-mouse-select)
 132       (setq finder-mode-map map)))
 133
 134
 135 ;;; Code for regenerating the keyword list.
 136
 137 (defvar finder-package-info nil
 138   "Assoc list mapping file names to description & keyword lists.")
 139
 140 (defvar finder-compile-keywords-quiet nil
 141   "If non-nil finder-compile-keywords will not print any messages.")
 142
 143 (defun finder-compile-keywords (&rest dirs)
 144   "Regenerate the keywords association list into the file `finder-inf.el'.
 145 Optional arguments are a list of Emacs Lisp directories to compile from; no
 146 arguments compiles from `load-path'."
 147   (save-excursion
 148     ;; XEmacs change
 149     (find-file "finder-inf.el")
 150     (let ((processed nil)
 151           (directory-abbrev-alist
 152            (append
 153            (mapcar (function (lambda (dir)
 154                                (cons (concat "^" (regexp-quote dir))
 155                                      "")))
 156                     finder-abbreviate-directory-list)
 157             directory-abbrev-alist))
 158           (using-load-path))
 159       (or dirs (setq dirs load-path))
 160       (setq using-load-path (equal dirs load-path))
 161       (erase-buffer)
 162       (insert ";;; finder-inf.el --- keyword-to-package mapping\n")
 163       (insert ";; Keywords: help\n")
 164       (insert ";;; Commentary:\n")
 165       (insert ";; Don't edit this file.  It's generated by finder.el\n\n")
 166       (insert ";;; Code:\n")
 167       (insert "\n(defconst finder-package-info '(\n")
 168       (mapcar
 169        (lambda (d)
 170          (mapcar
 171           (lambda (f)
 172             (when (and (not (member f processed)) (file-readable-p f))
 173               (let (summary keystart keywords)
 174                 (setq processed (cons f processed))
 175                 (if (not finder-compile-keywords-quiet)
 176                     (message "Processing %s ..." f))
 177                 (save-excursion
 178                   (set-buffer (get-buffer-create "*finder-scratch*"))
 179                   (buffer-disable-undo (current-buffer))
 180                   (erase-buffer)
 181                   (insert-file-contents (expand-file-name f d))
 182                   (condition-case err
 183                       (setq summary  (lm-synopsis)
 184                             keywords (lm-keywords))
 185                     (t (message "finder: error processing %s %S" f err))))
 186                 (when summary
 187                   (insert (format "    (\"%s\"\n        " f))
 188                   (prin1 summary (current-buffer))
 189                   (insert "\n        ")
 190                   (setq keystart (point))
 191                   (insert (if keywords (format "(%s)" keywords) "nil"))
 192                   (subst-char-in-region keystart (point) ?, ? )
 193                   (insert "\n        ")
 194                   (prin1 (abbreviate-file-name d) (current-buffer))
 195                   (insert ")\n")))))
 196           ;;
 197           ;; Skip null, non-existent or relative pathnames, e.g. "./", if
 198           ;; using load-path, so that they do not interfere with a scan of
 199           ;; library directories only.
 200           (if (and using-load-path
 201                    (not (and d (file-name-absolute-p d) (file-exists-p d))))
 202               nil
 203             (setq d (file-name-as-directory (or d ".")))
 204             (directory-files d nil "^[^=].*\\.el$"))))
 205        dirs)
 206       (insert "))\n\n(provide 'finder-inf)\n\n;;; finder-inf.el ends here\n")
 207       (kill-buffer "*finder-scratch*")
 208       (unless noninteractive
 209         (eval-current-buffer)) ; So we get the new keyword list immediately
 210       (basic-save-buffer))))
 211
 212 (defun finder-compile-keywords-make-dist ()
 213   "Regenerate `finder-inf.el' for the Emacs distribution."
 214   (finder-compile-keywords default-directory))
 215
 216 ;;; Now the retrieval code
 217
 218 (defun finder-insert-at-column (column &rest strings)
 219   "Insert list of STRINGS, at column COLUMN."
 220   (if (>= (current-column) column) (insert "\n"))
 221   (move-to-column column)
 222   (let ((col (current-column)))
 223     (if (< col column)
 224         (indent-to column)
 225       (if (and (/= col column)
 226                (= (preceding-char) ?\t))
 227           (let (indent-tabs-mode)
 228             (delete-char -1)
 229             (indent-to col)
 230             (move-to-column column)))))
 231   (apply 'insert strings))
 232
 233 (defun finder-list-keywords ()
 234   "Display descriptions of the keywords in the Finder buffer."
 235   (interactive)
 236   (setq buffer-read-only nil)
 237   (erase-buffer)
 238   (mapcar
 239    (lambda (assoc)
 240      (let ((keyword (car assoc)))
 241        (insert (symbol-name keyword))
 242        (finder-insert-at-column 14 (concat (cdr assoc) "\n"))
 243        (cons (symbol-name keyword) keyword)))
 244    finder-known-keywords)
 245   (goto-char (point-min))
 246   (setq finder-headmark (point))
 247   (setq buffer-read-only t)
 248   (set-buffer-modified-p nil)
 249   ;; XEmacs change
 250   (if (not (one-window-p))
 251       (balance-windows))
 252   (finder-summary))
 253
 254 (defun finder-list-matches (key)
 255   (setq buffer-read-only nil)
 256   (erase-buffer)
 257   (let ((id (intern key)))
 258     (insert
 259      "The following packages match the keyword `" key "':\n\n")
 260     (setq finder-headmark (point))
 261     (mapcar
 262      (lambda (x)
 263        (if (memq id (car (cdr (cdr x))))
 264            (progn
 265              (insert (car x))
 266              (finder-insert-at-column 16 (concat (car (cdr x)) "\n")))))
 267      finder-package-info)
 268     (goto-char (point-min))
 269     (forward-line)
 270     (setq buffer-read-only t)
 271     (set-buffer-modified-p nil)
 272     (shrink-window-if-larger-than-buffer)
 273     (finder-summary)))
 274
 275 ;; Search for a file named FILE the same way `load' would search.
 276 (defun finder-find-library (file)
 277   (if (file-name-absolute-p file)
 278       file
 279     (let ((dirs load-path)
 280           found)
 281       (while (and dirs (not found))
 282         (if (file-exists-p (expand-file-name (concat file ".el") (car dirs)))
 283             (setq found (expand-file-name file (car dirs)))
 284           (if (file-exists-p (expand-file-name file (car dirs)))
 285               (setq found (expand-file-name file (car dirs)))))
 286         (setq dirs (cdr dirs)))
 287       found)))
 288
 289 (defun finder-commentary (file)
 290   "Display FILE's commentary section.
 291 FILE should be in a form suitable for passing to `locate-library'."
 292   (interactive "sLibrary name: ")
 293   (let* ((str (lm-commentary (or (finder-find-library file)
 294                                  (finder-find-library (concat file ".el"))
 295                                  (error "Can't find library %s" file)))))
 296     (if (null str)
 297         (error "Can't find any Commentary section"))
 298     (pop-to-buffer "*Finder*")
 299     ;; XEmacs change
 300     (setq buffer-read-only nil
 301           mode-motion-hook 'mode-motion-highlight-line)
 302     (erase-buffer)
 303     (insert str)
 304     (goto-char (point-min))
 305     (delete-blank-lines)
 306     (goto-char (point-max))
 307     (delete-blank-lines)
 308     (goto-char (point-min))
 309     (while (re-search-forward "^;+ ?" nil t)
 310       (replace-match "" nil nil))
 311     (goto-char (point-min))
 312     (setq buffer-read-only t)
 313     (set-buffer-modified-p nil)
 314     (shrink-window-if-larger-than-buffer)
 315     (finder-summary)))
 316
 317 (defun finder-current-item ()
 318   (if (and finder-headmark (< (point) finder-headmark))
 319       (error "No keyword or filename on this line")
 320     (save-excursion
 321       (beginning-of-line)
 322       (current-word))))
 323
 324 ;; XEmacs change
 325 (defun finder-edit ()
 326   (interactive)
 327   (let ((entry (finder-current-item)))
 328     (if (string-match finder-file-regexp entry)
 329         (let ((path (finder-find-library entry)))
 330           (if path
 331               (find-file-other-window path)
 332             (error "Can't find Emacs Lisp library: '%s'" entry)))
 333       ;; a finder keyword
 334       (error "Finder-edit works on Emacs Lisp libraries only"))))
 335
 336 ;; XEmacs change
 337 (defun finder-view ()
 338   (interactive)
 339   (let ((entry (finder-current-item)))
 340     (if (string-match finder-file-regexp entry)
 341         (let ((path (finder-find-library entry)))
 342           (if path
 343               (view-file-other-window path)
 344             (error "Can't find Emacs Lisp library: '%s'" entry)))
 345       ;; a finder keyword
 346       (error "Finder-view works on Emacs Lisp libraries only"))))
 347
 348 (defun finder-select ()
 349   (interactive)
 350   (let ((key (finder-current-item)))
 351     ;; XEmacs change
 352     (if (string-match finder-file-regexp key)
 353         (finder-commentary key)
 354       (finder-list-matches key))))
 355
 356 ;; XEmacs change
 357 (defun finder-mouse-select (ev)
 358   (interactive "e")
 359   (goto-char (event-point ev))
 360   (finder-select))
 361
 362 ;; XEmacs change
 363 ;;;###autoload
 364 (defun finder-by-keyword ()
 365   "Find packages matching a given keyword."
 366   (interactive)
 367   (finder-mode)
 368   (finder-list-keywords))
 369
 370 (defun finder-mode ()
 371   "Major mode for browsing package documentation.
 372 \\<finder-mode-map>
 373 \\[finder-select]       more help for the item on the current line
 374 \\[finder-edit] edit Lisp library in another window
 375 \\[finder-view] view Lisp library in another window
 376 \\[finder-exit] exit Finder mode and kill the Finder buffer.
 377 "
 378   (interactive)
 379   (pop-to-buffer "*Finder*")
 380   ;; XEmacs change
 381   (setq buffer-read-only nil
 382         mode-motion-hook 'mode-motion-highlight-line)
 383   (erase-buffer)
 384   (use-local-map finder-mode-map)
 385   (set-syntax-table emacs-lisp-mode-syntax-table)
 386   (setq mode-name "Finder")
 387   (setq major-mode 'finder-mode)
 388   (make-local-variable 'finder-headmark)
 389   (setq finder-headmark nil))
 390
 391 (defun finder-summary ()
 392   "Summarize basic Finder commands."
 393   (interactive)
 394   (message "%s"
 395    (substitute-command-keys
 396     ;; XEmacs change
 397     "\\<finder-mode-map>\\[finder-select] = select, \\[finder-list-keywords] = keywords, \\[finder-edit] = edit, \\[finder-view] = view, \\[finder-exit] = quit, \\[finder-summary] = help")))
 398
 399 (defun finder-exit ()
 400   "Exit Finder mode and kill the buffer"
 401   (interactive)
 402   ;; XEmacs change
 403   (or (one-window-p t 0)
 404       (delete-window))
 405   (kill-buffer "*Finder*"))
 406
 407 (provide 'finder)
 408
 409 ;;; finder.el ends here