git.chise.org Git - chise/xemacs-chise.git.1/blob - lisp/lisp.el

   1 ;;; lisp.el --- Lisp editing commands for XEmacs
   2
   3 ;; Copyright (C) 1985, 1986, 1994, 1997 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: lisp, languages, dumped
   7
   8 ;; This file is part of XEmacs.
   9
  10 ;; XEmacs is free software; you can redistribute it and/or modify it
  11 ;; under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; XEmacs is distributed in the hope that it will be useful, but
  16 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 ;; General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with XEmacs; see the file COPYING.  If not, write to the Free
  22 ;; Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  23 ;; 02111-1307, USA.
  24
  25 ;;; Synched up with: Emacs/Mule zeta.
  26
  27 ;;; Commentary:
  28
  29 ;; This file is dumped with XEmacs.
  30
  31 ;; Lisp editing commands to go with Lisp major mode.
  32
  33 ;; 06/11/1997 - Use char-(after|before) instead of
  34 ;;  (following|preceding)-char. -slb
  35
  36 ;;; Code:
  37
  38 ;; Note that this variable is used by non-lisp modes too.
  39 (defcustom defun-prompt-regexp nil
  40   "*Non-nil => regexp to ignore, before the character that starts a defun.
  41 This is only necessary if the opening paren or brace is not in column 0.
  42 See `beginning-of-defun'."
  43   :type '(choice (const :tag "none" nil)
  44                  regexp)
  45   :group 'lisp)
  46
  47 (make-variable-buffer-local 'defun-prompt-regexp)
  48
  49 (defcustom parens-require-spaces t
  50   "Non-nil => `insert-parentheses' should insert whitespace as needed."
  51   :type 'boolean
  52   :group 'editing-basics
  53   :group 'lisp)
  54
  55 (defun forward-sexp (&optional arg)
  56   "Move forward across one balanced expression (sexp).
  57 With argument, do it that many times.  Negative arg -N means
  58 move backward across N balanced expressions."
  59   ;; XEmacs change (for zmacs regions)
  60   (interactive "_p")
  61   (or arg (setq arg 1))
  62   ;; XEmacs: evil hack! The other half of the evil hack below.
  63   (if (and (> arg 0) (looking-at "#s("))
  64       (goto-char (+ (point) 2)))
  65   (goto-char (or (scan-sexps (point) arg) (buffer-end arg)))
  66   (if (< arg 0) (backward-prefix-chars))
  67   ;; XEmacs: evil hack! Skip back over #s so that structures are read
  68   ;; properly.  the current cheesified syntax tables just aren't up to
  69   ;; this.
  70   (if (and (< arg 0)
  71            (eq (char-after (point)) ?\()
  72            (>= (- (point) (point-min)) 2)
  73            (eq (char-after (- (point) 1)) ?s)
  74            (eq (char-after (- (point) 2)) ?#))
  75       (goto-char (- (point) 2))))
  76
  77 (defun backward-sexp (&optional arg)
  78   "Move backward across one balanced expression (sexp).
  79 With argument, do it that many times.  Negative arg -N means
  80 move forward across N balanced expressions."
  81   ;; XEmacs change (for zmacs regions)
  82   (interactive "_p")
  83   (or arg (setq arg 1))
  84   (forward-sexp (- arg)))
  85
  86 (defun mark-sexp (arg)
  87   "Set mark ARG sexps from point.
  88 The place mark goes is the same place \\[forward-sexp] would
  89 move to with the same argument.
  90 Repeat this command to mark more sexps in the same direction."
  91   (interactive "p")
  92   ;; XEmacs change
  93   (mark-something 'mark-sexp 'forward-sexp arg))
  94
  95 (defun forward-list (&optional arg)
  96   "Move forward across one balanced group of parentheses.
  97 With argument, do it that many times.
  98 Negative arg -N means move backward across N groups of parentheses."
  99   ;; XEmacs change
 100   (interactive "_p")
 101   (or arg (setq arg 1))
 102   (goto-char (or (scan-lists (point) arg 0) (buffer-end arg))))
 103
 104 (defun backward-list (&optional arg)
 105   "Move backward across one balanced group of parentheses.
 106 With argument, do it that many times.
 107 Negative arg -N means move forward across N groups of parentheses."
 108   ;; XEmacs change (for zmacs regions)
 109   (interactive "_p")
 110   (or arg (setq arg 1))
 111   (forward-list (- arg)))
 112
 113 (defun down-list (arg)
 114   "Move forward down one level of parentheses.
 115 With argument, do this that many times.
 116 A negative argument means move backward but still go down a level.
 117 In Lisp programs, an argument is required."
 118   ;; XEmacs change (for zmacs regions)
 119   (interactive "_p")
 120   (let ((inc (if (> arg 0) 1 -1)))
 121     (while (/= arg 0)
 122       (goto-char (or (scan-lists (point) inc -1) (buffer-end arg)))
 123       (setq arg (- arg inc)))))
 124
 125 (defun backward-up-list (arg)
 126   "Move backward out of one level of parentheses.
 127 With argument, do this that many times.
 128 A negative argument means move forward but still to a less deep spot.
 129 In Lisp programs, an argument is required."
 130   (interactive "_p")
 131   (up-list (- arg)))
 132
 133 (defun up-list (arg)
 134   "Move forward out of one level of parentheses.
 135 With argument, do this that many times.
 136 A negative argument means move backward but still to a less deep spot.
 137 In Lisp programs, an argument is required."
 138   ;; XEmacs change (for zmacs regions)
 139   (interactive "_p")
 140   (let ((inc (if (> arg 0) 1 -1)))
 141     (while (/= arg 0)
 142       (goto-char (or (scan-lists (point) inc 1) (buffer-end arg)))
 143       (setq arg (- arg inc)))))
 144
 145 (defun kill-sexp (arg)
 146   "Kill the sexp (balanced expression) following the cursor.
 147 With argument, kill that many sexps after the cursor.
 148 Negative arg -N means kill N sexps before the cursor."
 149   (interactive "p")
 150   (let ((opoint (point)))
 151     (forward-sexp arg)
 152     (kill-region opoint (point))))
 153
 154 (defun backward-kill-sexp (arg)
 155   "Kill the sexp (balanced expression) preceding the cursor.
 156 With argument, kill that many sexps before the cursor.
 157 Negative arg -N means kill N sexps after the cursor."
 158   (interactive "p")
 159   (kill-sexp (- arg)))
 160 \f
 161 (defun beginning-of-defun (&optional arg)
 162   "Move backward to the beginning of a defun.
 163 With argument, do it that many times.  Negative arg -N
 164 means move forward to Nth following beginning of defun.
 165 Returns t unless search stops due to beginning or end of buffer.
 166
 167 Normally a defun starts when there is an char with open-parenthesis
 168 syntax at the beginning of a line.  If `defun-prompt-regexp' is
 169 non-nil, then a string which matches that regexp may precede the
 170 open-parenthesis, and point ends up at the beginning of the line."
 171   ;; XEmacs change (for zmacs regions)
 172   (interactive "_p")
 173   (and (beginning-of-defun-raw arg)
 174        (progn (beginning-of-line) t)))
 175
 176 (defun beginning-of-defun-raw (&optional arg)
 177   "Move point to the character that starts a defun.
 178 This is identical to beginning-of-defun, except that point does not move
 179 to the beginning of the line when `defun-prompt-regexp' is non-nil."
 180   (interactive "p")
 181   (and arg (< arg 0) (not (eobp)) (forward-char 1))
 182   (and (re-search-backward (if defun-prompt-regexp
 183                                (concat "^\\s(\\|"
 184                                        "\\(" defun-prompt-regexp "\\)\\s(")
 185                              "^\\s(")
 186                            nil 'move (or arg 1))
 187        (progn (goto-char (1- (match-end 0)))) t))
 188
 189 ;; XEmacs change (optional buffer parameter)
 190 (defun buffer-end (arg &optional buffer)
 191   "Return `point-max' of BUFFER if ARG is > 0; return `point-min' otherwise.
 192 BUFFER defaults to the current buffer if omitted."
 193   (if (> arg 0) (point-max buffer) (point-min buffer)))
 194
 195 (defun end-of-defun (&optional arg)
 196   "Move forward to next end of defun.  With argument, do it that many times.
 197 Negative argument -N means move back to Nth preceding end of defun.
 198
 199 An end of a defun occurs right after the close-parenthesis that matches
 200 the open-parenthesis that starts a defun; see `beginning-of-defun'."
 201   ;; XEmacs change (for zmacs regions)
 202   (interactive "_p")
 203   (if (or (null arg) (= arg 0)) (setq arg 1))
 204   (let ((first t))
 205     (while (and (> arg 0) (< (point) (point-max)))
 206       (let ((pos (point))) ; XEmacs -- remove unused npos.
 207         (while (progn
 208                 (if (and first
 209                          (progn
 210                           (end-of-line 1)
 211                           (beginning-of-defun-raw 1)))
 212                     nil
 213                   (or (bobp) (forward-char -1))
 214                   (beginning-of-defun-raw -1))
 215                 (setq first nil)
 216                 (forward-list 1)
 217                 (skip-chars-forward " \t")
 218                 (if (looking-at "\\s<\\|\n")
 219                     (forward-line 1))
 220                 (<= (point) pos))))
 221       (setq arg (1- arg)))
 222     (while (< arg 0)
 223       (let ((pos (point)))
 224         (beginning-of-defun-raw 1)
 225         (forward-sexp 1)
 226         (forward-line 1)
 227         (if (>= (point) pos)
 228             (if (beginning-of-defun-raw 2)
 229                 (progn
 230                   (forward-list 1)
 231                   (skip-chars-forward " \t")
 232                   (if (looking-at "\\s<\\|\n")
 233                       (forward-line 1)))
 234               (goto-char (point-min)))))
 235       (setq arg (1+ arg)))))
 236
 237 (defun mark-defun ()
 238   "Put mark at end of this defun, point at beginning.
 239 The defun marked is the one that contains point or follows point."
 240   (interactive)
 241   (push-mark (point))
 242   (end-of-defun)
 243   (push-mark (point) nil t)
 244   (beginning-of-defun)
 245   (re-search-backward "^\n" (- (point) 1) t))
 246
 247 (defun narrow-to-defun (&optional arg)
 248   "Make text outside current defun invisible.
 249 The defun visible is the one that contains point or follows point."
 250   (interactive)
 251   (save-excursion
 252     (widen)
 253     (end-of-defun)
 254     (let ((end (point)))
 255       (beginning-of-defun)
 256       (narrow-to-region (point) end))))
 257
 258 (defun insert-parentheses (arg)
 259   "Enclose following ARG sexps in parentheses.  Leave point after open-paren.
 260 A negative ARG encloses the preceding ARG sexps instead.
 261 No argument is equivalent to zero: just insert `()' and leave point between.
 262 If `parens-require-spaces' is non-nil, this command also inserts a space
 263 before and after, depending on the surrounding characters."
 264   (interactive "P")
 265   (if arg (setq arg (prefix-numeric-value arg))
 266     (setq arg 0))
 267   (cond ((> arg 0) (skip-chars-forward " \t"))
 268         ((< arg 0) (forward-sexp arg) (setq arg (- arg))))
 269   (and parens-require-spaces
 270        (not (bobp))
 271        (memq (char-syntax (char-before (point))) '(?w ?_ ?\) ))
 272        (insert " "))
 273   (insert ?\()
 274   (save-excursion
 275     (or (eq arg 0) (forward-sexp arg))
 276     (insert ?\))
 277     (and parens-require-spaces
 278          (not (eobp))
 279          (memq (char-syntax (char-after (point))) '(?w ?_ ?\( ))
 280          (insert " "))))
 281
 282 (defun move-past-close-and-reindent ()
 283   "Move past next `)', delete indentation before it, then indent after it."
 284   (interactive)
 285   (up-list 1)
 286   (forward-char -1)
 287   (while (save-excursion                ; this is my contribution
 288            (let ((before-paren (point)))
 289              (back-to-indentation)
 290              (= (point) before-paren)))
 291     (delete-indentation))
 292   (forward-char 1)
 293   (newline-and-indent))
 294 \f
 295 (defun lisp-complete-symbol ()
 296   "Perform completion on Lisp symbol preceding point.
 297 Compare that symbol against the known Lisp symbols.
 298
 299 The context determines which symbols are considered.
 300 If the symbol starts just after an open-parenthesis, only symbols
 301 with function definitions are considered.  Otherwise, all symbols with
 302 function definitions, values or properties are considered."
 303   (interactive)
 304   (let* ((end (point))
 305          (buffer-syntax (syntax-table))
 306          (beg (unwind-protect
 307                   (save-excursion
 308                     ;; XEmacs change
 309                     (if emacs-lisp-mode-syntax-table
 310                         (set-syntax-table emacs-lisp-mode-syntax-table))
 311                     (backward-sexp 1)
 312                     (while (eq (char-syntax (char-after (point))) ?\')
 313                       (forward-char 1))
 314                     (point))
 315                 (set-syntax-table buffer-syntax)))
 316          (pattern (buffer-substring beg end))
 317          (predicate
 318           (if (eq (char-after (1- beg)) ?\()
 319               'fboundp
 320             ;; XEmacs change
 321             #'(lambda (sym)
 322                 (or (boundp sym) (fboundp sym)
 323                     (symbol-plist sym)))))
 324          (completion (try-completion pattern obarray predicate)))
 325     (cond ((eq completion t))
 326           ((null completion)
 327            (message "Can't find completion for \"%s\"" pattern)
 328            (ding))
 329           ((not (string= pattern completion))
 330            (delete-region beg end)
 331            (insert completion))
 332           (t
 333            (message "Making completion list...")
 334            (let ((list (all-completions pattern obarray predicate))
 335                  ;FSFmacs crock unnecessary in XEmacs
 336                  ;see minibuf.el
 337                  ;(completion-fixup-function
 338                  ; (function (lambda () (if (save-excursion
 339                  ;              (goto-char (max (point-min)
 340                  ;                              (- (point) 4)))
 341                  ;              (looking-at " <f>"))
 342                  ;            (forward-char -4))))
 343                  )
 344              (or (eq predicate 'fboundp)
 345                  (let (new)
 346                    (while list
 347                      (setq new (cons (if (fboundp (intern (car list)))
 348                                          (list (car list) " <f>")
 349                                        (car list))
 350                                      new))
 351                      (setq list (cdr list)))
 352                    (setq list (nreverse new))))
 353              (with-output-to-temp-buffer "*Completions*"
 354                (display-completion-list list)))
 355            (message "Making completion list...%s" "done")))))
 356
 357 ;;; lisp.el ends here