git.chise.org Git - chise/xemacs-chise.git.1/blob - lisp/menubar.el

   1 ;;; menubar.el --- Menubar support for XEmacs
   2
   3 ;; Copyright (C) 1991-4, 1997-1998 Free Software Foundation, Inc.
   4 ;; Copyright (C) 1995 Tinker Systems and INS Engineering Corp.
   5 ;; Copyright (C) 1995, 1996 Ben Wing.
   6
   7 ;; Maintainer: XEmacs Development Team
   8 ;; Keywords: internal, extensions, dumped
   9
  10 ;; This file is part of XEmacs.
  11
  12 ;; XEmacs is free software; you can redistribute it and/or modify it
  13 ;; under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; XEmacs is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with XEmacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Synched up with: Not in FSF. (Completely divergent from FSF menu-bar.el)
  28
  29 ;;; Commentary:
  30
  31 ;; This file is dumped with XEmacs (when menubar support is compiled in).
  32
  33 ;; Some stuff in FSF menu-bar.el is in menubar-items.el
  34
  35 ;;; Code:
  36
  37 (defgroup menu nil
  38   "Input from the menus."
  39   :group 'environment)
  40
  41 (defvar default-menubar nil)
  42
  43 ;; this function is considered "part of the lexicon" by many,
  44 ;; so we'll leave it here.
  45 (defun kill-this-buffer ()      ; for the menubar
  46   "Kill the current buffer."
  47   (interactive)
  48   (kill-buffer (current-buffer)))
  49
  50 (defun set-menubar-dirty-flag ()
  51   "Tell XEmacs that the menubar has to be updated.
  52 NOTE: XEmacs now recognizes when you set a different value for
  53 `current-menubar'.  You *only* need to call this function if you
  54 destructively modify a part of the menubar and don't set `current-menubar'.
  55 Note that all the functions that modify a menu call this automatically."
  56   (setq-default current-menubar (default-value 'current-menubar)))
  57
  58 ;; #### shouldn't this perhaps be `copy-tree'?
  59 (defun set-menubar (menubar)
  60   "Set the default menubar to be MENUBAR.
  61 See `current-menubar' for a description of the syntax of a menubar."
  62   (check-menu-syntax menubar t)
  63   (setq-default current-menubar (copy-sequence menubar)))
  64
  65 (defun set-buffer-menubar (menubar)
  66   "Set the buffer-local menubar to be MENUBAR.
  67 See `current-menubar' for a description of the syntax of a menubar."
  68   (check-menu-syntax menubar t)
  69   (make-local-variable 'current-menubar)
  70   (setq current-menubar (copy-sequence menubar)))
  71
  72 (defun check-menu-syntax (menu &optional menubar-p)
  73   ;; The C code does syntax checking on the value of `current-menubar',
  74   ;; but it's better to do it early, before things have gotten messed up.
  75   (if menubar-p
  76       nil
  77     (or (stringp (car menu))
  78         (signal 'error
  79                 (list "menu name (first element) must be a string" menu)))
  80     ;;(or (cdr menu) (signal 'error (list "menu is empty" menu)))
  81     (setq menu (cdr menu)))
  82   (let (menuitem item)
  83     (while (keywordp (setq item (car menu)))
  84       (or (memq item '(:config :included :filter :accelerator))
  85           (signal 'error
  86                   (list "menu keyword must be :config, :included, :accelerator or :filter"
  87                         item)))
  88       (if (or (not (cdr menu))
  89               (vectorp (nth 1 menu))
  90               (keywordp (nth 1 menu)))
  91           (signal 'error (list "strange keyword value" item (nth 1 menu))))
  92       (setq menu (nthcdr 2 menu)))
  93     (while menu
  94       (setq menuitem (car menu))
  95       (cond
  96        ((stringp menuitem)
  97         (and (string-match "^\\(-+\\|=+\\):\\(.*\\)" menuitem)
  98              (setq item (match-string 2 menuitem))
  99              (or (member item '(;; Motif-compatible
 100                                 "singleLine"
 101                                 "doubleLine"
 102                                 "singleDashedLine"
 103                                 "doubleDashedLine"
 104                                 "noLine"
 105                                 "shadowEtchedIn"
 106                                 "shadowEtchedOut"
 107                                 "shadowEtchedInDash"
 108                                 "shadowEtchedOutDash"
 109                                 ;; non-Motif (Lucid menubar widget only)
 110                                 "shadowDoubleEtchedIn"
 111                                 "shadowDoubleEtchedOut"
 112                                 "shadowDoubleEtchedInDash"
 113                                 "shadowDoubleEtchedOutDash"
 114                                 ))
 115                  (signal 'error (list "bogus separator style in menu item" item)))
 116              ))
 117        ((null menuitem)
 118         (or menubar-p
 119             (signal 'error (list "nil is only permitted in the top level of menubars"))))
 120        ((consp menuitem)
 121         (check-menu-syntax menuitem))
 122        ((vectorp menuitem)
 123         (let ((L (length menuitem))
 124               plistp)
 125           (and (< L 2)
 126                (signal 'error
 127                        (list "button descriptors must be at least 2 long"
 128                              menuitem)))
 129           (setq plistp (or (>= L 5)
 130                            (and (> L 2) (keywordp (aref menuitem 2)))))
 131           (if plistp
 132               (let ((i 2)
 133                     selp
 134                     style
 135                     item)
 136                 (while (< i L)
 137                   (setq item (aref menuitem i))
 138                   (cond ((not (memq item '(:active :suffix :keys :style
 139                                                    :full :included :selected
 140                                                    :accelerator)))
 141                          (signal 'error
 142                                  (list (if (keywordp item)
 143                                            "unknown menu item keyword"
 144                                          "not a keyword")
 145                                        item menuitem)))
 146                         ((eq item :style)
 147                          (setq style (aref menuitem (1+ i)))
 148                          (or (memq style '(nil toggle radio button text))
 149                              (signal 'error (list "unknown style" style
 150                                                   menuitem))))
 151                         ((eq item :selected) (setq selp t))
 152                         )
 153                   (setq i (+ i (if (eq item :full) 1 2))))
 154                 (if (and selp (not (memq style '(toggle button radio))))
 155                     (signal 'error
 156                             (list
 157                              ":selected only makes sense with :style toggle, radio, or button"
 158                              menuitem)))
 159                 )))
 160         )
 161        ;; (t (signal 'error (list "unrecognized menu descriptor" menuitem))))
 162        (t (message "unrecognized menu descriptor %s" (prin1-to-string menuitem))))
 163       (setq menu (cdr menu)))))
 164
 165 \f
 166 ;;; menu manipulation functions
 167
 168 (defun find-menu-item (menubar item-path-list &optional parent)
 169   "Search MENUBAR for item given by ITEM-PATH-LIST starting from PARENT.
 170 Returns (ITEM . PARENT), where PARENT is the immediate parent of
 171  the item found.
 172 If the item does not exist, the car of the returned value is nil.
 173 If some menu in the ITEM-PATH-LIST does not exist, an error is signalled."
 174   (check-argument-type 'listp item-path-list)
 175   (unless parent
 176     (setq item-path-list (mapcar 'normalize-menu-item-name item-path-list)))
 177   (if (not (consp menubar))
 178       nil
 179     (let ((rest menubar)
 180           result)
 181       (when (stringp (car rest))
 182         (setq rest (cdr rest)))
 183       (while (keywordp (car rest))
 184         (setq rest (cddr rest)))
 185       (while rest
 186         (if (and (car rest)
 187                  (equal (car item-path-list)
 188                         (normalize-menu-item-name
 189                          (cond ((vectorp (car rest))
 190                                 (aref (car rest) 0))
 191                                ((stringp (car rest))
 192                                 (car rest))
 193                                (t
 194                                 (caar rest))))))
 195             (setq result (car rest)
 196                   rest nil)
 197           (setq rest (cdr rest))))
 198       (if (cdr item-path-list)
 199           (cond ((consp result)
 200                  (find-menu-item (cdr result) (cdr item-path-list) result))
 201                 (result
 202                  (signal 'error (list (gettext "not a submenu") result)))
 203                 (t
 204                  (signal 'error (list (gettext "no such submenu")
 205                                       (car item-path-list)))))
 206         (cons result parent)))))
 207
 208 (defun add-menu-item-1 (leaf-p menu-path new-item before in-menu)
 209   ;; This code looks like it could be cleaned up some more
 210   ;; Do we really need 6 calls to find-menu-item?
 211   (when before (setq before (normalize-menu-item-name before)))
 212   (let* ((item-name
 213           (cond ((vectorp new-item) (aref new-item 0))
 214                 ((consp   new-item) (car  new-item))
 215                 (t nil)))
 216          (menubar (or in-menu current-menubar))
 217          (menu (condition-case ()
 218                    (car (find-menu-item menubar menu-path))
 219                  (error nil)))
 220          (item-found (cond
 221                       ((null item-name)
 222                        nil)
 223                       ((not (listp menu))
 224                        (signal 'error (list (gettext "not a submenu")
 225                                             menu-path)))
 226                       (menu
 227                        (find-menu-item (cdr menu) (list item-name)))
 228                       (t
 229                        (find-menu-item menubar (list item-name)))
 230                       )))
 231     (unless menubar
 232       (error "`current-menubar' is nil: can't add menus to it."))
 233     (unless menu
 234       (let ((rest menu-path)
 235             (so-far menubar))
 236         (while rest
 237 ;;;       (setq menu (car (find-menu-item (cdr so-far) (list (car rest)))))
 238           (setq menu
 239                 (if (eq so-far menubar)
 240                     (car (find-menu-item so-far (list (car rest))))
 241                   (car (find-menu-item (cdr so-far) (list (car rest))))))
 242           (unless menu
 243             (let ((rest2 so-far))
 244               (while (and (cdr rest2) (car (cdr rest2)))
 245                 (setq rest2 (cdr rest2)))
 246               (setcdr rest2
 247                       (nconc (list (setq menu (list (car rest))))
 248                              (cdr rest2)))))
 249           (setq so-far menu)
 250           (setq rest (cdr rest)))))
 251     (if (and item-found (car item-found))
 252         ;; hack the item in place.
 253         (if menu
 254             ;; Isn't it very bad form to use nsubstitute for side effects?
 255             (nsubstitute new-item (car item-found) menu)
 256           (setq current-menubar (nsubstitute new-item
 257                                              (car item-found)
 258                                              current-menubar)))
 259       ;; OK, we have to add the whole thing...
 260       ;; if BEFORE is specified, try to add it there.
 261       (unless menu (setq menu current-menubar))
 262       (when before
 263         (setq before (car (find-menu-item menu (list before)))))
 264       (let ((rest menu)
 265             (added-before nil))
 266         (while rest
 267           (if (eq before (car (cdr rest)))
 268               (progn
 269                 (setcdr rest (cons new-item (cdr rest)))
 270                 (setq rest nil added-before t))
 271             (setq rest (cdr rest))))
 272         (when (not added-before)
 273           ;; adding before the first item on the menubar itself is harder
 274           (if (and (eq menu menubar) (eq before (car menu)))
 275               (setq menu (cons new-item menu)
 276                     current-menubar menu)
 277             ;; otherwise, add the item to the end.
 278             (nconc menu (list new-item))))))
 279     (set-menubar-dirty-flag)
 280     new-item))
 281
 282 (defun add-menu-button (menu-path menu-leaf &optional before in-menu)
 283   "Add a menu item to some menu, creating the menu first if necessary.
 284 If the named item exists already, it is changed.
 285 MENU-PATH identifies the menu under which the new menu item should be inserted.
 286  It is a list of strings; for example, (\"File\") names the top-level \"File\"
 287  menu.  (\"File\" \"Foo\") names a hypothetical submenu of \"File\".
 288 MENU-LEAF is a menubar leaf node.  See the documentation of `current-menubar'.
 289 BEFORE, if provided, is the name of a menu item before which this item should
 290  be added, if this item is not on the menu already.  If the item is already
 291  present, it will not be moved.
 292 IN-MENU, if provided, means use that instead of `current-menubar' as the
 293  menu to change."
 294   ;; Note easymenu.el uses the fact that menu-leaf can be a submenu.
 295   (add-menu-item-1 t menu-path menu-leaf before in-menu))
 296
 297 ;; I actually liked the old name better, but the interface has changed too
 298 ;; drastically to keep it. --Stig
 299 (defun add-submenu (menu-path submenu &optional before in-menu)
 300   "Add a menu to the menubar or one of its submenus.
 301 If the named menu exists already, it is changed.
 302 MENU-PATH identifies the menu under which the new menu should be inserted.
 303  It is a list of strings; for example, (\"File\") names the top-level \"File\"
 304  menu.  (\"File\" \"Foo\") names a hypothetical submenu of \"File\".
 305  If MENU-PATH is nil, then the menu will be added to the menubar itself.
 306 SUBMENU is the new menu to add.
 307  See the documentation of `current-menubar' for the syntax.
 308 BEFORE, if provided, is the name of a menu before which this menu should
 309  be added, if this menu is not on its parent already.  If the menu is already
 310  present, it will not be moved.
 311 IN-MENU, if provided, means use that instead of `current-menubar' as the
 312  menu to change."
 313   (check-menu-syntax submenu nil)
 314   (add-menu-item-1 nil menu-path submenu before in-menu))
 315 ;; purespace is no more, so this function is unnecessary
 316 ;(defun purecopy-menubar (x)
 317 ;  ;; this calls purecopy on the strings, and the contents of the vectors,
 318 ;  ;; but not on the vectors themselves, or the conses - those must be
 319 ;  ;; writable.
 320 ;  (cond ((vectorp x)
 321 ;        (let ((i (length x)))
 322 ;          (while (> i 0)
 323 ;            (aset x (1- i) (purecopy (aref x (1- i))))
 324 ;            (setq i (1- i))))
 325 ;        x)
 326 ;       ((consp x)
 327 ;        (let ((rest x))
 328 ;          (while rest
 329 ;            (setcar rest (purecopy-menubar (car rest)))
 330 ;            (setq rest (cdr rest))))
 331 ;        x)
 332 ;       (t
 333 ;        (purecopy x))))
 334
 335 (defun delete-menu-item (path &optional from-menu)
 336   "Remove the named menu item from the menu hierarchy.
 337 PATH is a list of strings which identify the position of the menu item
 338 in the menu hierarchy.  The documentation of `add-submenu' describes
 339 menu paths.
 340 FROM-MENU, if provided, means use that instead of `current-menubar'
 341 as the menu to change."
 342   (let* ((pair (condition-case nil (find-menu-item (or from-menu
 343                                                        current-menubar) path)
 344                  (error nil)))
 345          (item (car pair))
 346          (parent (or (cdr pair) current-menubar)))
 347     (if (not item)
 348         nil
 349       ;; the menubar is the only special case, because other menus begin
 350       ;; with their name.
 351       (if (eq parent current-menubar)
 352           (setq current-menubar (delq item parent))
 353         (delq item parent))
 354       (set-menubar-dirty-flag)
 355       item)))
 356
 357 (defun relabel-menu-item (path new-name)
 358   "Change the string of the specified menu item.
 359 PATH is a list of strings which identify the position of the menu item in
 360 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 361 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 362 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\".
 363 NEW-NAME is the string that the menu item will be printed as from now on."
 364   (or (stringp new-name)
 365       (setq new-name (wrong-type-argument 'stringp new-name)))
 366   (let* ((menubar current-menubar)
 367          (pair (find-menu-item menubar path))
 368          (item (car pair))
 369          (menu (cdr pair)))
 370     (or item
 371         (signal 'error (list (if menu (gettext "No such menu item")
 372                                (gettext "No such menu"))
 373                              path)))
 374     (if (and (consp item)
 375              (stringp (car item)))
 376         (setcar item new-name)
 377       (aset item 0 new-name))
 378     (set-menubar-dirty-flag)
 379     item))
 380
 381 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 382 ;;
 383 ;; these are all bad style.  Why in the world would we put evaluable forms
 384 ;; into the menubar if we didn't want people to use 'em?
 385 ;; x-font-menu.el is the only known offender right now and that ought to be
 386 ;; rehashed a bit.
 387 ;;
 388
 389 (defun enable-menu-item-1 (path toggle-p on-p)
 390   (let (menu item)
 391     (if (and (vectorp path) (> (length path) 2)) ; limited syntax checking...
 392         (setq item path)
 393       (let* ((menubar current-menubar)
 394              (pair (find-menu-item menubar path)))
 395         (setq item (car pair)
 396               menu (cdr pair))
 397         (or item
 398             (signal 'error (list (if menu
 399                                      "No such menu item"
 400                                    "No such menu")
 401                                  path)))
 402         (if (consp item)
 403             (error "%S is a menu, not a menu item" path))))
 404     (if (or (> (length item) 4)
 405             (and (symbolp (aref item 2))
 406                  (= ?: (aref (symbol-name (aref item 2)) 0))))
 407         ;; plist-like syntax
 408         (let ((i 2)
 409               (keyword (if toggle-p :selected :active))
 410               (ok nil))
 411           (while (< i (length item))
 412             (cond ((eq (aref item i) keyword)
 413                    (aset item (1+ i) on-p)
 414                    (setq ok t)))
 415             (setq i (+ i 2)))
 416           (cond (ok nil)
 417                 (toggle-p
 418                  (signal 'error (list "not a toggle menu item" item)))
 419                 (t
 420                  ;; Need to copy the item to extend it, sigh...
 421                  (let ((cons (memq item menu))
 422                        (new-item (vconcat item (list keyword on-p))))
 423                    (if cons
 424                        (setcar cons (setq item new-item))
 425                      (if menu
 426                          (error "couldn't find %S on its parent?" item)
 427                        (error "no %S slot to set: %S" keyword item)))))))
 428       ;; positional syntax
 429       (if toggle-p
 430           (signal 'error (list "not a toggle menu item" item))
 431         (aset item 2 on-p)))
 432     (set-menubar-dirty-flag)
 433     item))
 434
 435 (defun enable-menu-item (path)
 436   "Make the named menu item be selectable.
 437 PATH is a list of strings which identify the position of the menu item in
 438 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 439 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 440 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 441   (enable-menu-item-1 path nil t))
 442
 443 (defun disable-menu-item (path)
 444   "Make the named menu item be unselectable.
 445 PATH is a list of strings which identify the position of the menu item in
 446 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 447 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 448 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 449   (enable-menu-item-1 path nil nil))
 450
 451 (defun select-toggle-menu-item (path)
 452   "Make the named toggle- or radio-style menu item be in the `selected' state.
 453 PATH is a list of strings which identify the position of the menu item in
 454 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 455 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 456 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 457   (enable-menu-item-1 path t t))
 458
 459 (defun deselect-toggle-menu-item (path)
 460  "Make the named toggle- or radio-style menu item be in the `unselected' state.
 461 PATH is a list of strings which identify the position of the menu item in
 462 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 463 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 464 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 465   (enable-menu-item-1 path t nil))
 466
 467 \f
 468
 469 ;;;;;;; popup menus
 470
 471 (defvar global-popup-menu nil
 472   "The global popup menu.  This is present in all modes.
 473 See the function `popup-menu' for a description of menu syntax.")
 474
 475 (defvar mode-popup-menu nil
 476   "The mode-specific popup menu.  Automatically buffer local.
 477 This is appended to the default items in `global-popup-menu'.
 478 See the function `popup-menu' for a description of menu syntax.")
 479 (make-variable-buffer-local 'mode-popup-menu)
 480
 481 (defvar activate-popup-menu-hook nil
 482   "Function or functions run before a mode-specific popup menu is made visible.
 483 These functions are called with no arguments, and should interrogate and
 484 modify the value of `global-popup-menu' or `mode-popup-menu' as desired.
 485 Note: this hook is only run if you use `popup-mode-menu' for activating the
 486 global and mode-specific commands; if you have your own binding for button3,
 487 this hook won't be run.")
 488
 489 (defvar last-popup-menu-event nil
 490   "The mouse event that invoked the last popup menu.
 491 NOTE: This is EXPERIMENTAL and may change at any time.")
 492
 493 (defun popup-mode-menu (&optional event)
 494   "Pop up a menu of global and mode-specific commands.
 495 The menu is computed by combining `global-popup-menu' and `mode-popup-menu'
 496 with any items derived from the `context-menu' property of the extent where the
 497 button was clicked."
 498   (interactive "_e")
 499   (setq last-popup-menu-event
 500         (or (and event (button-event-p event) event)
 501             (let* ((mouse-pos (mouse-position))
 502                    (win (car mouse-pos))
 503                    (x (cadr mouse-pos))
 504                    (y (cddr mouse-pos))
 505                    (edges (window-pixel-edges win))
 506                    (winx (first edges))
 507                    (winy (second edges))
 508                    (x (+ x winx))
 509                    (y (+ y winy)))
 510               (make-event 'button-press
 511                           `(button 3 x ,x y ,y channel ,(window-frame win)
 512                                    timestamp ,(current-event-timestamp
 513                                                (cdfw-console win)))))))
 514   (run-hooks 'activate-popup-menu-hook)
 515   (let* ((context-window (and event (event-window event)))
 516          (context-point (and event (event-point event)))
 517          (context-extents (and context-window
 518                                context-point
 519                                (extents-at context-point
 520                                            (window-buffer context-window)
 521                                            'context-menu)))
 522          (context-menu-items
 523           (apply 'append (mapcar #'(lambda (extent)
 524                                      (extent-property extent 'context-menu))
 525                                  context-extents))))
 526     (popup-menu
 527      (cond ((and global-popup-menu mode-popup-menu)
 528             ;; Merge global-popup-menu and mode-popup-menu
 529             (check-menu-syntax mode-popup-menu)
 530             (let* ((title (car mode-popup-menu))
 531                    (items (cdr mode-popup-menu))
 532                    mode-filters)
 533               ;; Strip keywords from local menu for attaching them at the top
 534               (while (and items
 535                           (keywordp (car items)))
 536                 ;; Push both keyword and its argument.
 537                 (push (pop items) mode-filters)
 538                 (push (pop items) mode-filters))
 539               (setq mode-filters (nreverse mode-filters))
 540               ;; If mode-filters contains a keyword already present in
 541               ;; `global-popup-menu', you will probably lose.
 542               (append (list (car global-popup-menu))
 543                       mode-filters
 544                       (cdr global-popup-menu)
 545                       '("---" "---")
 546                       (if popup-menu-titles (list title))
 547                       (if popup-menu-titles '("---" "---"))
 548                       items
 549                       context-menu-items)))
 550            (t
 551             (append
 552              (or mode-popup-menu
 553                  global-popup-menu
 554                  (error "No menu defined in this buffer"))
 555              context-menu-items))))
 556
 557     (while (popup-up-p)
 558       (dispatch-event (next-event)))
 559
 560     ))
 561
 562 (defun popup-buffer-menu (event)
 563   "Pop up a copy of the Buffers menu (from the menubar) where the mouse is clicked."
 564   (interactive "e")
 565   (let ((window (and (event-over-text-area-p event) (event-window event)))
 566         (bmenu nil))
 567     (or window
 568         (error "Pointer must be in a normal window"))
 569     (select-window window)
 570     (if current-menubar
 571         (setq bmenu (assoc "%_Buffers" current-menubar)))
 572     (if (null bmenu)
 573         (setq bmenu (assoc "%_Buffers" default-menubar)))
 574     (if (null bmenu)
 575         (error "Can't find the Buffers menu"))
 576     (popup-menu bmenu)))
 577
 578 (defun popup-menubar-menu (event)
 579   "Pop up a copy of menu that also appears in the menubar."
 580   (interactive "e")
 581   (let ((window (and (event-over-text-area-p event) (event-window event)))
 582         popup-menubar)
 583     (or window
 584         (error "Pointer must be in a normal window"))
 585     (select-window window)
 586     (and current-menubar (run-hooks 'activate-menubar-hook))
 587     ;; #### Instead of having to copy this just to safely get rid of
 588     ;; any nil what we should really do is fix up the internal menubar
 589     ;; code to just ignore nil if generating a popup menu
 590     (setq popup-menubar (delete nil (copy-sequence (or current-menubar
 591                                                        default-menubar))))
 592     (popup-menu (cons "%_Menubar Menu" popup-menubar))
 593     ))
 594
 595 (defun menu-call-at-event (form &optional event default-behavior-fallback)
 596   "Call FORM while temporarily setting point to the position in EVENT.
 597 NOTE: This is EXPERIMENTAL and may change at any time.
 598
 599 FORM is called the way forms in menu specs are: i.e. if a symbol, it's called
 600 with `call-interactively', otherwise with `eval'.  EVENT defaults to
 601 `last-popup-menu-event', making this function especially useful in popup
 602 menus.  The buffer and point are set temporarily within a `save-excursion'.
 603 If EVENT is not a mouse event, or was not over a buffer, nothing
 604 happens unless DEFAULT-BEHAVIOR-FALLBACK is non-nil, in which case the
 605 FORM is called normally."
 606   (or event (setq event last-popup-menu-event))
 607   (let ((buf (event-buffer event))
 608         (p (event-closest-point event)))
 609     (cond ((and buf p (> p 0))
 610            (save-excursion
 611              (set-buffer buf)
 612              (goto-char p)
 613              (if (symbolp form)
 614                  (call-interactively form)
 615                (eval form))))
 616           (default-behavior-fallback
 617             (if (symbolp form)
 618                 (call-interactively form)
 619               (eval form))))))
 620
 621 (global-set-key 'button3 'popup-mode-menu)
 622 ;; shift button3 and shift button2 are reserved for Hyperbole
 623 (global-set-key '(meta control button3) 'popup-buffer-menu)
 624 ;; The following command is way too dangerous with Custom.
 625 ;; (global-set-key '(meta shift button3) 'popup-menubar-menu)
 626
 627 ;; Here's a test of the cool new menu features (from Stig).
 628
 629 ;;(setq mode-popup-menu
 630 ;;      '("Test Popup Menu"
 631 ;;        :filter cdr
 632 ;;        ["this item won't appear because of the menu filter" ding t]
 633 ;;        "--:singleLine"
 634 ;;        "singleLine"
 635 ;;        "--:doubleLine"
 636 ;;        "doubleLine"
 637 ;;        "--:singleDashedLine"
 638 ;;        "singleDashedLine"
 639 ;;        "--:doubleDashedLine"
 640 ;;        "doubleDashedLine"
 641 ;;        "--:noLine"
 642 ;;        "noLine"
 643 ;;        "--:shadowEtchedIn"
 644 ;;        "shadowEtchedIn"
 645 ;;        "--:shadowEtchedOut"
 646 ;;        "shadowEtchedOut"
 647 ;;        "--:shadowDoubleEtchedIn"
 648 ;;        "shadowDoubleEtchedIn"
 649 ;;        "--:shadowDoubleEtchedOut"
 650 ;;        "shadowDoubleEtchedOut"
 651 ;;        "--:shadowEtchedInDash"
 652 ;;        "shadowEtchedInDash"
 653 ;;        "--:shadowEtchedOutDash"
 654 ;;        "shadowEtchedOutDash"
 655 ;;        "--:shadowDoubleEtchedInDash"
 656 ;;        "shadowDoubleEtchedInDash"
 657 ;;        "--:shadowDoubleEtchedOutDash"
 658 ;;        "shadowDoubleEtchedOutDash"
 659 ;;        ))
 660
 661 (defun get-popup-menu-response (menu-desc &optional event)
 662   "Pop up the given menu and wait for a response.
 663 This blocks until the response is received, and returns the misc-user
 664 event that encapsulates the response.  To execute it, you can do
 665   (funcall (event-function response) (event-object response))
 666 If no response was received, nil is returned.
 667
 668 MENU-DESC and EVENT are as in the call to `popup-menu'."
 669   ;; partially stolen from w3
 670   (let ((echo-keystrokes 0)
 671         new-event)
 672     (popup-menu menu-desc event)
 673     (catch 'popup-done
 674       (while t
 675         (setq new-event (next-command-event new-event))
 676         (cond ((misc-user-event-p new-event)
 677                (throw 'popup-done new-event))
 678               ((not (popup-up-p))
 679                (setq unread-command-events (cons new-event
 680                                                  unread-command-events))
 681                (throw 'popup-done nil))
 682               ((button-release-event-p new-event);; don't beep twice
 683                nil)
 684               ((event-matches-key-specifier-p (quit-char))
 685                (signal 'quit nil))
 686               (t
 687                (beep)
 688                (message "please make a choice from the menu.")))))))
 689
 690 (defun popup-menu-and-execute-in-window (menu-desc event)
 691   "Pop up the given menu and execute its response in EVENT's window.
 692 This blocks until the response is received, temporarily selects
 693 EVENT's window, and executes the command specified in the response.
 694 EVENT can also be a window.  See `popup-menu' for the semantics of
 695 MENU-DESC."
 696   (let ((response
 697          (get-popup-menu-response menu-desc
 698                                   (and (eventp event) event))))
 699     (and (misc-user-event-p response)
 700          (save-selected-window
 701            (select-window (if (windowp event) event
 702                             (event-window event)))
 703            (funcall (event-function response)
 704                     (event-object response))))))
 705
 706 ;; provide default bindings for menu accelerator map
 707 (and (boundp 'menu-accelerator-map)
 708      (keymapp menu-accelerator-map)
 709      (progn
 710        (define-key menu-accelerator-map "\e" 'menu-escape)
 711        (define-key menu-accelerator-map [left] 'menu-left)
 712        (define-key menu-accelerator-map [right] 'menu-right)
 713        (define-key menu-accelerator-map [up] 'menu-up)
 714        (define-key menu-accelerator-map [down] 'menu-down)
 715        (define-key menu-accelerator-map [return] 'menu-select)
 716        (define-key menu-accelerator-map [kp_down] 'menu-down)
 717        (define-key menu-accelerator-map [kp_up] 'menu-down)
 718        (define-key menu-accelerator-map [kp_left] 'menu-left)
 719        (define-key menu-accelerator-map [kp_right] 'menu-right)
 720        (define-key menu-accelerator-map [kp_enter] 'menu-select)
 721        (define-key menu-accelerator-map "\C-g" 'menu-quit)))
 722
 723 \f
 724 (provide 'menubar)
 725
 726 ;;; menubar.el ends here