git.chise.org Git - chise/xemacs-chise.git.1/blob - lisp/package-get.el

   1 ;;; package-get.el --- Retrieve XEmacs package
   2
   3 ;; Copyright (C) 1998 by Pete Ware
   4
   5 ;; Author: Pete Ware <ware@cis.ohio-state.edu>
   6 ;; Heavy-Modifications: Greg Klanderman <greg@alphatech.com>
   7 ;;                      Jan Vroonhof    <vroonhof@math.ethz.ch>
   8 ;; Keywords: internal
   9
  10 ;; This file is part of XEmacs.
  11
  12 ;; XEmacs is free software; you can redistribute it and/or modify it
  13 ;; under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; XEmacs is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with XEmacs; see the file COPYING.  If not, write to the Free
  24 ;; Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  25 ;; 02111-1307, USA.
  26
  27 ;;; Synched up with: Not in FSF
  28
  29 ;;; Commentary:
  30
  31 ;; package-get -
  32 ;;      Retrieve a package and any other required packages from an archive
  33 ;;
  34 ;;
  35 ;; Note (JV): Most of this no longer aplies!
  36 ;;
  37 ;; The idea:
  38 ;;      A new XEmacs lisp-only release is generated with the following steps:
  39 ;;      1. The maintainer runs some yet to be written program that
  40 ;;         generates all the dependency information.  This should
  41 ;;         determine all the require and provide statements and associate
  42 ;;         them with a package.
  43 ;;      2. All the packages are then bundled into their own tar balls
  44 ;;         (or whatever format)
  45 ;;      3. Maintainer automatically generates a new `package-get-base'
  46 ;;         data structure which contains information such as the
  47 ;;         package name, the file to be retrieved, an md5 checksum,
  48 ;;         etc (see `package-get-base').
  49 ;;      4. The maintainer posts an announcement with the new version
  50 ;;         of `package-get-base'.
  51 ;;      5. A user/system manager saves this posting and runs
  52 ;;         `package-get-update' which uses the previously saved list
  53 ;;         of packages, `package-get-here' that the user/site
  54 ;;         wants to determine what new versions to download and
  55 ;;         install.
  56 ;;
  57 ;;      A user/site manager can generate a new `package-get-here' structure
  58 ;;      by using `package-get-setup' which generates a customize like
  59 ;;      interface to the list of packages.  The buffer looks something
  60 ;;      like:
  61 ;;
  62 ;;      gnus    - a mail and news reader
  63 ;;      []      Always install
  64 ;;      []      Needs updating
  65 ;;      []      Required by other [packages]
  66 ;;      version: 2.0
  67 ;;
  68 ;;      vm      - a mail reader
  69 ;;      []      Always install
  70 ;;      []      Needs updating
  71 ;;      []      Required by other [packages]
  72 ;;
  73 ;;      Where `[]' indicates a toggle box
  74 ;;
  75 ;;      - Clicking on "Always install" puts this into
  76 ;;        `package-get-here' list.  "Needs updating" indicates a new
  77 ;;        version is available.  Anything already in
  78 ;;        `package-get-here' has this enabled.
  79 ;;      - "Required by other" means some other packages are going to force
  80 ;;        this to be installed.  Clicking on  [packages] gives a list
  81 ;;        of packages that require this.
  82 ;;
  83 ;;      The `package-get-base' should be installed in a file in
  84 ;;      `data-directory'.  The `package-get-here' should be installed in
  85 ;;      site-lisp.  Both are then read at run time.
  86 ;;
  87 ;; TODO:
  88 ;;      - Implement `package-get-setup'
  89 ;;      - Actually put `package-get-base' and `package-get-here' into
  90 ;;        files that are read.
  91 ;;      - Allow users to have their own packages that they want installed
  92 ;;        in ~/.xemacs/.
  93 ;;      - SOMEONE needs to write the programs that generate the
  94 ;;        provides/requires database and makes it into a lisp data
  95 ;;        structure suitable for `package-get-base'
  96 ;;      - Handle errors such as no package providing a required symbol.
  97 ;;      - Tie this into the `require' function to download packages
  98 ;;        transparently.
  99
 100 ;;; Change Log
 101
 102 ;;; Code:
 103
 104 (require 'package-admin)
 105 ;; (require 'package-get-base)
 106
 107 (defgroup package-tools nil
 108   "Tools to manipulate packages."
 109   :group 'emacs)
 110
 111 (defgroup package-get nil
 112   "Automatic Package Fetcher and Installer."
 113   :prefix "package-get"
 114   :group 'package-tools)
 115
 116 (defvar package-get-base nil
 117   "List of packages that are installed at this site.
 118 For each element in the alist,  car is the package name and the cdr is
 119 a plist containing information about the package.   Typical fields
 120 kept in the plist are:
 121
 122 version         - version of this package
 123 provides        - list of symbols provided
 124 requires        - list of symbols that are required.
 125                   These in turn are provided by other packages.
 126 filename        - name of the file.
 127 size            - size of the file (aka the bundled package)
 128 md5sum          - computed md5 checksum
 129 description     - What this package is for.
 130 type            - Whether this is a 'binary (default) or 'single file package
 131
 132 More fields may be added as needed.  An example:
 133
 134 '(
 135  (name
 136   (version \"<version 2>\"
 137    file \"filename\"
 138    description \"what this package is about.\"
 139    provides (<list>)
 140    requires (<list>)
 141    size <integer-bytes>
 142    md5sum \"<checksum\"
 143    type single
 144    )
 145   (version \"<version 1>\"
 146    file \"filename\"
 147    description \"what this package is about.\"
 148    provides (<list>)
 149    requires (<list>)
 150    size <integer-bytes>
 151    md5sum \"<checksum\"
 152    type single
 153    )
 154    ...
 155    ))
 156
 157 For version information, it is assumed things are listed in most
 158 recent to least recent -- in other words, the version names don't have to
 159 be lexically ordered.  It is debatable if it makes sense to have more than
 160 one version of a package available.")
 161
 162 (defcustom package-get-dir (temp-directory)
 163   "*Where to store temporary files for staging."
 164   :tag "Temporary directory"
 165   :type 'directory
 166   :group 'package-get)
 167
 168 (define-widget 'host-name 'string
 169   "A Host name."
 170   :tag "Host")
 171
 172 (defcustom package-get-remote nil
 173   "*List of remote sites to contact for downloading packages.
 174 List format is '(site-name directory-on-site).  Each site is tried in
 175 order until the package is found.  As a special case, `site-name' can be
 176 `nil', in which case `directory-on-site' is treated as a local directory."
 177   :tag "Package repository"
 178   :type '(repeat (choice (list :tag "Local" (const :tag "Local" nil) directory )
 179                          (list :tag "Remote" host-name directory) ))
 180   :group 'package-get)
 181
 182 (defcustom package-get-download-sites
 183   '(
 184     ;; North America
 185     ("xemacs.org" "ftp.xemacs.org" "pub/xemacs/packages")
 186     ("cso.uiuc.edu" "ftp.cso.uiuc.edu" "pub/packages/xemacs/packages")
 187
 188     ;; South America
 189     ("unicamp.br" "ftp.unicamp.br" "pub/xemacs/packages")
 190
 191     ;; Europe
 192     ("sunsite.cnlab-switch.ch" "sunsite.cnlab-switch.ch" "mirror/xemacs/packages")
 193     ("tu-darmstadt.de" "ftp.tu-darmstadt.de" "pub/editors/xemacs/packages")
 194     ("sunsite.auc.dk" "sunsite.auc.dk" "pub/emacs/xemacs/packages")
 195     ("pasteur.fr" "ftp.pasteur.fr" "pub/computing/xemacs/packages")
 196     ("cenatls.cena.dgac.fr" "ftp.cenatls.cena.dgac.fr" "pub/Emacs/xemacs/packages")
 197     ("kfki.hu" "ftp.kfki.hu" "pub/packages/xemacs/packages")
 198     ("uniroma2.it" "ftp.uniroma2.it" "unix/misc/dist/XEMACS/packages")
 199     ("icm.edu.pl" "ftp.icm.edu.pl" "pub/unix/editors/xemacs/packages")
 200     ("sunet.se" "ftp.sunet.se" "pub/gnu/xemacs/packages")
 201     ("doc.ic.ac.uk" "ftp.doc.ic.ac.uk" "packages/xemacs/packages")
 202     ("srcc.msu.su" "ftp1.srcc.msu.su" "mirror/ftp.xemacs.org/packages")
 203
 204     ;; Asia
 205     ("usyd.edu.au" "ftp.usyd.edu.au" "pub/Xemacs/packages")
 206     ("netlab.is.tsukuba.ac.jp" "ftp.netlab.is.tsukuba.ac.jp" "pub/GNU/xemacs/packages")
 207     ("jaist.ac.jp" "ftp.jaist.ac.jp" "pub/GNU/xemacs/packages")
 208     ("ring.aist.go.jp" "ring.aist.go.jp" "pub/text/xemacs/packages")
 209     ("ring.asahi-net.or.jp" "ring.asahi-net.or.jp" "pub/text/xemacs/packages")
 210     ("SunSITE.sut.ac.jp" "SunSITE.sut.ac.jp" "pub/archives/packages/xemacs/packages")
 211     ("dti.ad.jp" "ftp.dti.ad.jp" "pub/unix/editor/xemacs/packages")
 212     ("kreonet.re.kr" "ftp.kreonet.re.kr" "pub/tools/emacs/xemacs/packages")
 213     )
 214   "*List of remote sites available for downloading packages.
 215 List format is '(site-description site-name directory-on-site).
 216 SITE-DESCRIPTION is a textual description of the site.  SITE-NAME
 217 is the internet address of the download site.  DIRECTORY-ON-SITE
 218 is the directory on the site in which packages may be found.
 219 This variable is used to initialize `package-get-remote', the
 220 variable actually used to specify package download sites."
 221   :tag "Package download sites"
 222   :type '(repeat (list hostname directory))
 223   :group 'package-get)
 224
 225 (defcustom package-get-remove-copy t
 226   "*After copying and installing a package, if this is T, then remove the
 227 copy.  Otherwise, keep it around."
 228   :type 'boolean
 229   :group 'package-get)
 230
 231 ;; #### it may make sense for this to be a list of names.
 232 ;; #### also, should we rename "*base*" to "*index*" or "*db*"?
 233 ;;      "base" is a pretty poor name.
 234 (defcustom package-get-base-filename "package-index.LATEST.pgp"
 235   "*Name of the default package-get database file.
 236 This may either be a relative path, in which case it is interpreted
 237 with respect to `package-get-remote', or an absolute path."
 238   :type 'file
 239   :group 'package-get)
 240
 241 (defcustom package-get-always-update nil
 242   "*If Non-nil always make sure we are using the latest package index (base).
 243 Otherwise respect the `force-current' argument of `package-get-require-base'."
 244   :type 'boolean
 245   :group 'package-get)
 246
 247 (defcustom package-get-require-signed-base-updates t
 248   "*If set to a non-nil value, require explicit user confirmation for updates
 249 to the package-get database which cannot have their signature verified via PGP.
 250 When nil, updates which are not PGP signed are allowed without confirmation."
 251   :type 'boolean
 252   :group 'package-get)
 253
 254 (defvar package-get-was-current nil
 255   "Non-nil we did our best to fetch a current database.")
 256
 257 ;;;###autoload
 258 (defun package-get-download-menu ()
 259   "Build the `Add Download Site' menu."
 260   (mapcar (lambda (site)
 261             (vector (car site)
 262                     `(push (quote ,(cdr site))
 263                            package-get-remote)
 264                     :style 'toggle
 265                     :selected `(member (quote ,(cdr site))
 266                                        package-get-remote)))
 267           package-get-download-sites))
 268
 269 ;;;###autoload
 270 (defun package-get-require-base (&optional force-current)
 271   "Require that a package-get database has been loaded.
 272 If the optional FORCE-CURRENT argument or the value of
 273 `package-get-always-update' is Non-nil, try to update the database
 274 from a location in `package-get-remote'. Otherwise a local copy is used
 275 if available and remote access is never done.
 276
 277 Please use FORCE-CURRENT only when the user is explictly dealing with packages
 278 and remote access is likely in the near future."
 279   (setq force-current (or force-current package-get-always-update))
 280   (unless (and (boundp 'package-get-base)
 281                package-get-base
 282                (or (not force-current) package-get-was-current))
 283     (package-get-update-base nil force-current))
 284   (if (or (not (boundp 'package-get-base))
 285           (not package-get-base))
 286       (error "Package-get database not loaded")
 287     (setq package-get-was-current force-current)))
 288
 289 (defconst package-get-pgp-signed-begin-line "^-----BEGIN PGP SIGNED MESSAGE-----"
 290   "Text for start of PGP signed messages.")
 291 (defconst package-get-pgp-signature-begin-line "^-----BEGIN PGP SIGNATURE-----"
 292   "Text for beginning of PGP signature.")
 293 (defconst package-get-pgp-signature-end-line "^-----END PGP SIGNATURE-----"
 294   "Text for end of PGP signature.")
 295
 296 ;;;###autoload
 297 (defun package-get-update-base-entry (entry)
 298   "Update an entry in `package-get-base'."
 299   (let ((existing (assq (car entry) package-get-base)))
 300     (if existing
 301         (setcdr existing (cdr entry))
 302       (setq package-get-base (cons entry package-get-base))
 303       (package-get-custom-add-entry (car entry) (car (cdr entry))))))
 304
 305 (defun package-get-locate-file (file &optional nil-if-not-found no-remote)
 306   "Locate an existing FILE with respect to `package-get-remote'.
 307 If FILE is an absolute path or is not found, simply return FILE.
 308 If optional argument NIL-IF-NOT-FOUND is non-nil, return nil
 309 if FILE can not be located.
 310 If NO-REMOTE is non-nil never search remote locations."
 311   (if (file-name-absolute-p file)
 312       file
 313     (let ((entries package-get-remote)
 314           (expanded nil))
 315       (while entries
 316         (unless (and no-remote (caar entries))
 317           (let ((expn (package-get-remote-filename (car entries) file)))
 318             (if (and expn (file-exists-p expn))
 319                 (setq entries  nil
 320                       expanded expn))))
 321         (setq entries (cdr entries)))
 322       (or expanded
 323           (and (not nil-if-not-found)
 324                file)))))
 325
 326 (defun package-get-locate-index-file (no-remote)
 327   "Locate the package-get index file.  Do not return remote paths if NO-REMOTE
 328 is non-nil."
 329   (or (package-get-locate-file package-get-base-filename t no-remote)
 330       (locate-data-file package-get-base-filename)
 331       package-get-base-filename))
 332
 333 (defvar package-get-user-package-location user-init-directory)
 334
 335 (defun package-get-maybe-save-index (filename)
 336   "Offer to save the current buffer as the local package index file,
 337 if different."
 338   (let ((location (package-get-locate-index-file t)))
 339     (unless (and filename (equal filename location))
 340       (unless (equal (md5 (current-buffer))
 341                      (with-temp-buffer
 342                        (insert-file-contents location)
 343                        (md5 (current-buffer))))
 344         (unless (file-writable-p location)
 345           (setq location (expand-file-name package-get-base-filename
 346                 (expand-file-name "etc/" package-get-user-package-location))))
 347         (when (y-or-n-p (concat "Update package index in" location "? "))
 348           (write-file location))))))
 349
 350
 351 ;;;###autoload
 352 (defun package-get-update-base (&optional db-file force-current)
 353   "Update the package-get database file with entries from DB-FILE.
 354 Unless FORCE-CURRENT is non-nil never try to update the database."
 355   (interactive
 356    (let ((dflt (package-get-locate-index-file nil)))
 357      (list (read-file-name "Load package-get database: "
 358                            (file-name-directory dflt)
 359                            dflt
 360                            t
 361                            (file-name-nondirectory dflt)))))
 362   (setq db-file (expand-file-name (or db-file
 363                                       (package-get-locate-index-file
 364                                          (not force-current)))))
 365   (if (not (file-exists-p db-file))
 366       (error "Package-get database file `%s' does not exist" db-file))
 367   (if (not (file-readable-p db-file))
 368       (error "Package-get database file `%s' not readable" db-file))
 369   (let ((buf (get-buffer-create "*package database*")))
 370     (unwind-protect
 371         (save-excursion
 372           (set-buffer buf)
 373           (erase-buffer buf)
 374           (insert-file-contents-internal db-file)
 375           (package-get-update-base-from-buffer buf)
 376           (if (file-remote-p db-file)
 377               (package-get-maybe-save-index db-file)))
 378       (kill-buffer buf))))
 379
 380 ;;;###autoload
 381 (defun package-get-update-base-from-buffer (&optional buf)
 382   "Update the package-get database with entries from BUFFER.
 383 BUFFER defaults to the current buffer.  This command can be
 384 used interactively, for example from a mail or news buffer."
 385   (interactive)
 386   (setq buf (or buf (current-buffer)))
 387   (let (content-beg content-end beg end)
 388     (save-excursion
 389       (set-buffer buf)
 390       (goto-char (point-min))
 391       (setq content-beg (point))
 392       (setq content-end (save-excursion (goto-char (point-max)) (point)))
 393       (when (re-search-forward package-get-pgp-signed-begin-line nil t)
 394         (setq beg (match-beginning 0))
 395         (setq content-beg (match-end 0)))
 396       (when (re-search-forward package-get-pgp-signature-begin-line nil t)
 397         (setq content-end (match-beginning 0)))
 398       (when (re-search-forward package-get-pgp-signature-end-line nil t)
 399         (setq end (point)))
 400       (if (not (and content-beg content-end beg end))
 401           (or (not package-get-require-signed-base-updates)
 402               (yes-or-no-p "Package-get entries not PGP signed, continue? ")
 403               (error "Package-get database not updated")))
 404       (if (and content-beg content-end beg end)
 405           (if (not (condition-case nil
 406                        (or (fboundp 'mc-pgp-verify-region)
 407                            (load-library "mc-pgp")
 408                            (fboundp 'mc-pgp-verify-region))
 409                      (error nil)))
 410               (or (not package-get-require-signed-base-updates)
 411                   (yes-or-no-p
 412                    "No mailcrypt; can't verify package-get DB signature, continue? ")
 413                   (error "Package-get database not updated"))))
 414       (if (and beg end
 415                (fboundp 'mc-pgp-verify-region)
 416                (or (not
 417                     (condition-case err
 418                         (mc-pgp-verify-region beg end)
 419                       (file-error
 420                        (and (string-match "No such file" (nth 2 err))
 421                             (or (not package-get-require-signed-base-updates)
 422                                 (yes-or-no-p
 423                                  (concat "Can't find PGP, continue without "
 424                                          "package-get DB verification? ")))))
 425                       (t nil)))))
 426           (error "Package-get PGP signature failed to verify"))
 427       ;; ToDo: We shoud call package-get-maybe-save-index on the region
 428       (package-get-update-base-entries content-beg content-end)
 429       (message "Updated package-get database"))))
 430
 431 (defun package-get-update-base-entries (beg end)
 432   "Update the package-get database with the entries found between
 433 BEG and END in the current buffer."
 434   (save-excursion
 435     (goto-char beg)
 436     (if (not (re-search-forward "^(package-get-update-base-entry" nil t))
 437         (error "Buffer does not contain package-get database entries"))
 438     (beginning-of-line)
 439     (let ((count 0))
 440       (while (and (< (point) end)
 441                   (re-search-forward "^(package-get-update-base-entry" nil t))
 442         (beginning-of-line)
 443         (let ((entry (read (current-buffer))))
 444           (if (or (not (consp entry))
 445                   (not (eq (car entry) 'package-get-update-base-entry)))
 446               (error "Invalid package-get database entry found"))
 447           (package-get-update-base-entry
 448            (car (cdr (car (cdr entry)))))
 449           (setq count (1+ count))))
 450       (message "Got %d package-get database entries" count))))
 451
 452 ;;;###autoload
 453 (defun package-get-save-base (file)
 454   "Write the package-get database to FILE.
 455
 456 Note: This database will be unsigned of course."
 457   (interactive "FSave package-get database to: ")
 458   (package-get-require-base t)
 459   (let ((buf (get-buffer-create "*package database*")))
 460     (unwind-protect
 461         (save-excursion
 462           (set-buffer buf)
 463           (erase-buffer buf)
 464           (goto-char (point-min))
 465           (let ((entries package-get-base) entry plist)
 466             (insert ";; Package Index file -- Do not edit manually.\n")
 467             (insert ";;;@@@\n")
 468             (while entries
 469               (setq entry (car entries))
 470               (setq plist (car (cdr entry)))
 471               (insert "(package-get-update-base-entry (quote\n")
 472               (insert (format "(%s\n" (symbol-name (car entry))))
 473               (while plist
 474                 (insert (format "  %s%s %S\n"
 475                                 (if (eq plist (car (cdr entry))) "(" " ")
 476                                 (symbol-name (car plist))
 477                                 (car (cdr plist))))
 478                 (setq plist (cdr (cdr plist))))
 479               (insert "))\n))\n;;;@@@\n")
 480               (setq entries (cdr entries))))
 481           (insert ";; Package Index file ends here\n")
 482           (write-region (point-min) (point-max) file))
 483       (kill-buffer buf))))
 484
 485 (defun package-get-interactive-package-query (get-version package-symbol)
 486   "Perform interactive querying for package and optional version.
 487 Query for a version if GET-VERSION is non-nil.  Return package name as
 488 a symbol instead of a string if PACKAGE-SYMBOL is non-nil.
 489 The return value is suitable for direct passing to `interactive'."
 490   (package-get-require-base t)
 491   (let ( (table (mapcar '(lambda (item)
 492                            (let ( (name (symbol-name (car item))) )
 493                              (cons name name)
 494                              ))
 495                         package-get-base))
 496          package package-symbol default-version version)
 497     (save-window-excursion
 498       (setq package (completing-read "Package: " table nil t))
 499       (setq package-symbol (intern package))
 500       (if get-version
 501           (progn
 502             (setq default-version
 503                   (package-get-info-prop
 504                    (package-get-info-version
 505                     (package-get-info-find-package package-get-base
 506                                                    package-symbol) nil)
 507                    'version))
 508             (while (string=
 509                     (setq version (read-string "Version: " default-version))
 510                     "")
 511               )
 512             (if package-symbol
 513                 (list package-symbol version)
 514               (list package version))
 515             )
 516         (if package-symbol
 517             (list package-symbol)
 518           (list package)))
 519       )))
 520
 521 ;;;###autoload
 522 (defun package-get-delete-package (package &optional pkg-topdir)
 523   "Delete an installation of PACKAGE below directory PKG-TOPDIR.
 524 PACKAGE is a symbol, not a string.
 525 This is just an interactive wrapper for `package-admin-delete-binary-package'."
 526   (interactive (package-get-interactive-package-query nil t))
 527   (package-admin-delete-binary-package package pkg-topdir))
 528
 529 ;;;###autoload
 530 (defun package-get-update-all ()
 531   "Fetch and install the latest versions of all currently installed packages."
 532   (interactive)
 533   (package-get-require-base t)
 534   ;; Load a fresh copy
 535   (catch 'exit
 536     (mapcar (lambda (pkg)
 537               (if (not (package-get (car pkg) nil 'never))
 538                   (throw 'exit nil)             ;; Bail out if error detected
 539                   ))
 540             packages-package-list)))
 541
 542 ;;;###autoload
 543 (defun package-get-all (package version &optional fetched-packages install-dir)
 544   "Fetch PACKAGE with VERSION and all other required packages.
 545 Uses `package-get-base' to determine just what is required and what
 546 package provides that functionality.  If VERSION is nil, retrieves
 547 latest version.  Optional argument FETCHED-PACKAGES is used to keep
 548 track of packages already fetched.  Optional argument INSTALL-DIR,
 549 if non-nil, specifies the package directory where fetched packages
 550 should be installed.
 551
 552 Returns nil upon error."
 553   (interactive (package-get-interactive-package-query t nil))
 554   (let* ((the-package (package-get-info-find-package package-get-base
 555                                                      package))
 556          (this-package (package-get-info-version
 557                         the-package version))
 558          (this-requires (package-get-info-prop this-package 'requires))
 559          )
 560     (catch 'exit
 561       (setq version (package-get-info-prop this-package 'version))
 562       (unless (package-get-installedp package version)
 563         (if (not (package-get package version nil install-dir))
 564             (progn
 565               (setq fetched-packages nil)
 566               (throw 'exit nil))))
 567       (setq fetched-packages
 568             (append (list package)
 569                     (package-get-info-prop this-package 'provides)
 570                     fetched-packages))
 571       ;; grab everything that this package requires plus recursively
 572       ;; grab everything that the requires require.  Keep track
 573       ;; in `fetched-packages' the list of things provided -- this
 574       ;; keeps us from going into a loop
 575       (while this-requires
 576         (if (not (member (car this-requires) fetched-packages))
 577             (let* ((reqd-package (package-get-package-provider
 578                                   (car this-requires) t))
 579                    (reqd-version (cadr reqd-package))
 580                    (reqd-name (car reqd-package)))
 581               (if (null reqd-name)
 582                   (error "Unable to find a provider for %s"
 583                          (car this-requires)))
 584               (if (not (setq fetched-packages
 585                              (package-get-all reqd-name reqd-version
 586                                               fetched-packages
 587                                               install-dir)))
 588                   (throw 'exit nil)))
 589           )
 590         (setq this-requires (cdr this-requires)))
 591       )
 592     fetched-packages
 593     ))
 594
 595 ;;;###autoload
 596 (defun package-get-dependencies (packages)
 597   "Compute dependencies for PACKAGES.
 598 Uses `package-get-base' to determine just what is required and what
 599 package provides that functionality.  Returns the list of packages
 600 required by PACKAGES."
 601   (package-get-require-base t)
 602   (let ((orig-packages packages)
 603         dependencies provided)
 604     (while packages
 605       (let* ((package (car packages))
 606              (the-package (package-get-info-find-package
 607                            package-get-base package))
 608              (this-package (package-get-info-version
 609                             the-package nil))
 610              (this-requires (package-get-info-prop this-package 'requires))
 611              (new-depends   (set-difference
 612                              (mapcar
 613                               #'(lambda (reqd)
 614                                   (let* ((reqd-package (package-get-package-provider reqd))
 615                                          (reqd-name    (car reqd-package)))
 616                                     (if (null reqd-name)
 617                                         (error "Unable to find a provider for %s" reqd))
 618                                     reqd-name))
 619                               this-requires)
 620                              dependencies))
 621              (this-provides (package-get-info-prop this-package 'provides)))
 622         (setq dependencies
 623               (union dependencies new-depends))
 624         (setq provided
 625               (union provided (union (list package) this-provides)))
 626         (setq packages
 627               (union new-depends (cdr packages)))))
 628     (set-difference dependencies orig-packages)))
 629
 630 (defun package-get-load-package-file (lispdir file)
 631   (let (pathname)
 632     (setq pathname (expand-file-name file lispdir))
 633     (condition-case err
 634         (progn
 635           (load pathname t)
 636           t)
 637       (t
 638        (message "Error loading package file \"%s\" %s!" pathname err)
 639        nil))
 640     ))
 641
 642 (defun package-get-init-package (lispdir)
 643   "Initialize the package.
 644 This really assumes that the package has never been loaded.  Updating
 645 a newer package can cause problems, due to old, obsolete functions in
 646 the old package.
 647
 648 Return `t' upon complete success, `nil' if any errors occurred."
 649   (progn
 650     (if (and lispdir
 651              (file-accessible-directory-p lispdir))
 652         (progn
 653           ;; Add lispdir to load-path if it doesn't already exist.
 654           ;; NOTE: this does not take symlinks, etc., into account.
 655           (if (let ( (dirs load-path) )
 656                 (catch 'done
 657                   (while dirs
 658                     (if (string-equal (car dirs) lispdir)
 659                         (throw 'done nil))
 660                     (setq dirs (cdr dirs))
 661                     )
 662                   t))
 663               (setq load-path (cons lispdir load-path)))
 664           (if (not (package-get-load-package-file lispdir "auto-autoloads"))
 665               (package-get-load-package-file lispdir "_pkg"))
 666           t)
 667       nil)
 668     ))
 669
 670 ;;;###autoload
 671 (defun package-get (package &optional version conflict install-dir)
 672   "Fetch PACKAGE from remote site.
 673 Optional arguments VERSION indicates which version to retrieve, nil
 674 means most recent version.  CONFLICT indicates what happens if the
 675 package is already installed.  Valid values for CONFLICT are:
 676 'always always retrieve the package even if it is already installed
 677 'never  do not retrieve the package if it is installed.
 678 INSTALL-DIR, if non-nil, specifies the package directory where
 679 fetched packages should be installed.
 680
 681 The value of `package-get-base' is used to determine what files should
 682 be retrieved.  The value of `package-get-remote' is used to determine
 683 where a package should be retrieved from.  The sites are tried in
 684 order so one is better off listing easily reached sites first.
 685
 686 Once the package is retrieved, its md5 checksum is computed.  If that
 687 sum does not match that stored in `package-get-base' for this version
 688 of the package, an error is signalled.
 689
 690 Returns `t' upon success, the symbol `error' if the package was
 691 successfully installed but errors occurred during initialization, or
 692 `nil' upon error."
 693   (interactive (package-get-interactive-package-query nil t))
 694   (catch 'skip-update
 695   (let* ((this-package
 696           (package-get-info-version
 697            (package-get-info-find-package package-get-base
 698                                           package) version))
 699          (latest (package-get-info-prop this-package 'version))
 700          (installed (package-get-key package :version))
 701          (this-requires (package-get-info-prop this-package 'requires))
 702          (found nil)
 703          (search-dirs package-get-remote)
 704          (base-filename (package-get-info-prop this-package 'filename))
 705          (package-status t)
 706          filenames full-package-filename)
 707     (if (null this-package)
 708         (if package-get-remote
 709             (error "Couldn't find package %s with version %s"
 710                    package version)
 711           (error "No download sites or local package locations specified.")))
 712     (if (null base-filename)
 713         (error "No filename associated with package %s, version %s"
 714                package version))
 715     (setq install-dir
 716           (package-admin-get-install-dir package install-dir
 717                 (or (eq package 'mule-base) (memq 'mule-base this-requires))))
 718
 719     ;; If they asked for the latest using version=nil, don't get an older
 720     ;; version than we already have.
 721     (if installed
 722         (if (> (if (stringp installed)
 723                    (string-to-number installed)
 724                  installed)
 725                (if (stringp latest)
 726                    (string-to-number latest)
 727                  latest))
 728             (if (not (null version))
 729                 (warn "Installing %s package version %s, you had a newer version %s"
 730                       package latest installed)
 731               (warn "Skipping %s package, you have a newer version %s"
 732                     package installed)
 733               (throw 'skip-update t))))
 734
 735     ;; Contrive a list of possible package filenames.
 736     ;; Ugly.  Is there a better way to do this?
 737     (setq filenames (cons base-filename nil))
 738     (if (string-match "^\\(..*\\)\.tar\.gz$" base-filename)
 739         (setq filenames (append filenames
 740                                 (list (concat (match-string 1 base-filename)
 741                                               ".tgz")))))
 742
 743     (setq version latest)
 744     (unless (and (eq conflict 'never)
 745                  (package-get-installedp package version))
 746       ;; Find the package from the search list in package-get-remote
 747       ;; and copy it into the staging directory.  Then validate
 748       ;; the checksum.  Finally, install the package.
 749       (catch 'done
 750         (let (search-filenames current-dir-entry host dir current-filename
 751                                dest-filename)
 752           ;; In each search directory ...
 753           (while search-dirs
 754             (setq current-dir-entry (car search-dirs)
 755                   host (car current-dir-entry)
 756                   dir (car (cdr current-dir-entry))
 757                   search-filenames filenames
 758                   )
 759
 760             ;; Look for one of the possible package filenames ...
 761             (while search-filenames
 762               (setq current-filename (car search-filenames)
 763                     dest-filename (package-get-staging-dir current-filename))
 764               (cond
 765                ;; No host means look on the current system.
 766                ( (null host)
 767                  (setq full-package-filename
 768                        (substitute-in-file-name
 769                         (expand-file-name current-filename
 770                                           (file-name-as-directory dir))))
 771                  )
 772
 773                ;; If it's already on the disk locally, and the size is
 774                ;; greater than zero ...
 775                ( (and (file-exists-p dest-filename)
 776                       (let (attrs)
 777                         ;; file-attributes could return -1 for LARGE files,
 778                         ;; but, hopefully, packages won't be that large.
 779                         (and (setq attrs (file-attributes dest-filename))
 780                              (> (nth 7 attrs) 0))))
 781                  (setq full-package-filename dest-filename)
 782                  )
 783
 784                ;; If the file exists on the remote system ...
 785                ( (file-exists-p (package-get-remote-filename
 786                                  current-dir-entry current-filename))
 787                  ;; Get it
 788                  (setq full-package-filename dest-filename)
 789                  (message "Retrieving package `%s' ..."
 790                           current-filename)
 791                  (sit-for 0)
 792                  (copy-file (package-get-remote-filename current-dir-entry
 793                                                          current-filename)
 794                             full-package-filename t)
 795                  )
 796                )
 797
 798               ;; If we found it, we're done.
 799               (if (and full-package-filename
 800                        (file-exists-p full-package-filename))
 801                   (throw 'done nil))
 802               ;; Didn't find it.  Try the next possible filename.
 803               (setq search-filenames (cdr search-filenames))
 804               )
 805             ;; Try looking in the next possible directory ...
 806             (setq search-dirs (cdr search-dirs))
 807             )
 808           ))
 809
 810       (if (or (not full-package-filename)
 811               (not (file-exists-p full-package-filename)))
 812           (if package-get-remote
 813               (error "Unable to find file %s" base-filename)
 814             (error
 815              "No download sites or local package locations specified.")))
 816       ;; Validate the md5 checksum
 817       ;; Doing it with XEmacs removes the need for an external md5 program
 818       (message "Validating checksum for `%s'..." package) (sit-for 0)
 819       (with-temp-buffer
 820         ;; What ever happened to i-f-c-literally
 821         (let (file-name-handler-alist)
 822           (insert-file-contents-internal full-package-filename))
 823         (if (not (string= (md5 (current-buffer))
 824                           (package-get-info-prop this-package
 825                                                  'md5sum)))
 826             (error "Package %s does not match md5 checksum" base-filename)))
 827
 828       (package-admin-delete-binary-package package install-dir)
 829
 830       (message "Installing package `%s' ..." package) (sit-for 0)
 831       (let ((status
 832              (package-admin-add-binary-package full-package-filename
 833                                                install-dir)))
 834         (if (= status 0)
 835             (progn
 836               ;; clear messages so that only messages from
 837               ;; package-get-init-package are seen, below.
 838               (clear-message)
 839               (if (package-get-init-package (package-admin-get-lispdir
 840                                              install-dir package))
 841                   (progn
 842                     (message "Added package `%s'" package)
 843                     (sit-for 0)
 844                     )
 845                 (progn
 846                   ;; display message only if there isn't already one.
 847                   (if (not (current-message))
 848                       (progn
 849                         (message "Added package `%s' (errors occurred)"
 850                                  package)
 851                         (sit-for 0)
 852                         ))
 853                   (if package-status
 854                       (setq package-status 'errors))
 855                   ))
 856               )
 857           (message "Installation of package %s failed." base-filename)
 858           (sit-for 0)
 859           (switch-to-buffer package-admin-temp-buffer)
 860           (setq package-status nil)
 861           ))
 862       (setq found t))
 863     (if (and found package-get-remove-copy)
 864         (delete-file full-package-filename))
 865     package-status
 866     )))
 867
 868 (defun package-get-info-find-package (which name)
 869   "Look in WHICH for the package called NAME and return all the info
 870 associated with it.  See `package-get-base' for info on the format
 871 returned.
 872
 873  To access fields returned from this, use
 874 `package-get-info-version' to return information about particular a
 875 version.  Use `package-get-info-find-prop' to find particular property
 876 from a version returned by `package-get-info-version'."
 877   (interactive "xPackage list: \nsPackage Name: ")
 878   (if which
 879       (if (eq (caar which) name)
 880           (cdar which)
 881         (if (cdr which)
 882             (package-get-info-find-package (cdr which) name)))))
 883
 884 (defun package-get-info-version (package version)
 885   "In PACKAGE, return the plist associated with a particular VERSION of the
 886   package.  PACKAGE is typically as returned by
 887   `package-get-info-find-package'.  If VERSION is nil, then return the
 888   first (aka most recent) version.  Use `package-get-info-find-prop'
 889   to retrieve a particular property from the value returned by this."
 890   (interactive (package-get-interactive-package-query t t))
 891   (while (and version package (not (string= (plist-get (car package) 'version) version)))
 892     (setq package (cdr package)))
 893   (if package (car package)))
 894
 895 (defun package-get-info-prop (package-version property)
 896   "In PACKAGE-VERSION, return the value associated with PROPERTY.
 897 PACKAGE-VERSION is typically returned by `package-get-info-version'
 898 and PROPERTY is typically (although not limited to) one of the
 899 following:
 900
 901 version         - version of this package
 902 provides                - list of symbols provided
 903 requires                - list of symbols that are required.
 904                   These in turn are provided by other packages.
 905 size            - size of the bundled package
 906 md5sum          - computed md5 checksum"
 907   (interactive "xPackage Version: \nSProperty")
 908   (plist-get package-version property))
 909
 910 (defun package-get-info-version-prop (package-list package version property)
 911   "In PACKAGE-LIST, search for PACKAGE with this VERSION and return
 912   PROPERTY value."
 913   (package-get-info-prop
 914    (package-get-info-version
 915     (package-get-info-find-package package-list package) version) property))
 916
 917 (defun package-get-set-version-prop (package-list package version
 918                                                   property value)
 919   "A utility to make it easier to add a VALUE for a specific PROPERTY
 920   in this VERSION of a specific PACKAGE kept in the PACKAGE-LIST.
 921 Returns the modified PACKAGE-LIST.  Any missing fields are created."
 922   )
 923
 924 (defun package-get-staging-dir (filename)
 925   "Return a good place to stash FILENAME when it is retrieved.
 926 Use `package-get-dir' for directory to store stuff.
 927 Creates `package-get-dir'  it it doesn't exist."
 928   (interactive "FPackage filename: ")
 929   (if (not (file-exists-p package-get-dir))
 930       (make-directory package-get-dir))
 931   (expand-file-name
 932    (file-name-nondirectory (or (and (fboundp 'efs-ftp-path)
 933                                     (nth 2 (efs-ftp-path filename)))
 934                                filename))
 935    (file-name-as-directory package-get-dir)))
 936
 937 (defun package-get-remote-filename (search filename)
 938   "Return FILENAME as a remote filename.
 939 It first checks if FILENAME already is a remote filename.  If it is
 940 not, then it uses the (car search) as the remote site-name and the (cadr
 941 search) as the remote-directory and concatenates filename.  In other
 942 words
 943         site-name:remote-directory/filename
 944 "
 945   (if (efs-ftp-path filename)
 946       filename
 947     (let ((dir (cadr search)))
 948       (concat (if (string-match "@" (car search))
 949                   "/"
 950                 "/anonymous@")
 951               (car search) ":"
 952               (if (string-match "/$" dir)
 953                   dir
 954                 (concat dir "/"))
 955               filename))))
 956
 957
 958 (defun package-get-installedp (package version)
 959   "Determine if PACKAGE with VERSION has already been installed.
 960 I'm not sure if I want to do this by searching directories or checking
 961 some built in variables.  For now, use packages-package-list."
 962   ;; Use packages-package-list which contains name and version
 963   (equal (plist-get
 964           (package-get-info-find-package packages-package-list
 965                                          package) ':version)
 966          (if (floatp version) version (string-to-number version))))
 967
 968 ;;;###autoload
 969 (defun package-get-package-provider (sym &optional force-current)
 970   "Search for a package that provides SYM and return the name and
 971   version.  Searches in `package-get-base' for SYM.   If SYM is a
 972   consp, then it must match a corresponding (provide (SYM VERSION)) from
 973   the package.
 974
 975 If FORCE-CURRENT is non-nil make sure the database is up to date. This might
 976 lead to Emacs accessing remote sites."
 977   (interactive "SSymbol: ")
 978   (package-get-require-base force-current)
 979   (let ((packages package-get-base)
 980         (done nil)
 981         (found nil))
 982     (while (and (not done) packages)
 983       (let* ((this-name (caar packages))
 984              (this-package (cdr (car packages)))) ;strip off package name
 985         (while (and (not done) this-package)
 986           (if (or (eq this-name sym)
 987                   (eq (cons this-name
 988                           (package-get-info-prop (car this-package) 'version))
 989                       sym)
 990                   (member sym
 991                         (package-get-info-prop (car this-package) 'provides)))
 992               (progn (setq done t)
 993                      (setq found
 994                        (list (caar packages)
 995                          (package-get-info-prop (car this-package) 'version))))
 996             (setq this-package (cdr this-package)))))
 997       (setq packages (cdr packages)))
 998     found))
 999
1000 ;;
1001 ;; customize interfaces.
1002 ;; The group is in this file so that custom loads includes this file.
1003 ;;
1004 (defgroup packages nil
1005   "Configure XEmacs packages."
1006   :group 'emacs)
1007
1008 ;;;###autoload
1009 (defun package-get-custom ()
1010   "Fetch and install the latest versions of all customized packages."
1011   (interactive)
1012   (package-get-require-base t)
1013   ;; Load a fresh copy
1014   (load "package-get-custom.el")
1015   (mapcar (lambda (pkg)
1016             (if (eval (intern (concat (symbol-name (car pkg)) "-package")))
1017                 (package-get (car pkg) nil))
1018             t)
1019           package-get-base))
1020
1021 (defun package-get-ever-installed-p (pkg &optional notused)
1022   (string-match "-package$" (symbol-name pkg))
1023   (custom-initialize-set
1024    pkg
1025    (if (package-get-info-find-package
1026         packages-package-list
1027         (intern (substring (symbol-name pkg) 0 (match-beginning 0))))
1028        t)))
1029
1030 (defvar package-get-custom-groups nil
1031   "List of package-get-custom groups")
1032
1033 (defun package-get-custom-add-entry (package props)
1034   (let* ((category (plist-get props 'category))
1035          (group (intern (concat category "-packages")))
1036          (custom-var (intern (concat (symbol-name package) "-package")))
1037          (description (plist-get props 'description)))
1038     (when (not (memq group package-get-custom-groups))
1039       (setq package-get-custom-groups (cons package
1040                                             package-get-custom-groups))
1041       (eval `(defgroup ,group nil
1042                ,(concat category " package group")
1043                :group 'packages)))
1044     (eval `(defcustom ,custom-var nil
1045              ,description
1046              :group ',group
1047              :initialize 'package-get-ever-installed-p
1048              :type 'boolean))))
1049
1050
1051 (provide 'package-get)
1052 ;;; package-get.el ends here