git.chise.org Git - chise/xemacs-chise.git.1/blob - lisp/x-faces.el

   1 ;;; x-faces.el --- X-specific face frobnication, aka black magic.
   2
   3 ;; Copyright (C) 1992-4, 1997 Free Software Foundation, Inc.
   4 ;; Copyright (C) 1995, 1996 Ben Wing.
   5
   6 ;; Author: Jamie Zawinski <jwz@netscape.com>
   7 ;; Maintainer: XEmacs Development Team
   8 ;; Keywords: extensions, internal, dumped
   9
  10 ;; This file is part of XEmacs.
  11
  12 ;; XEmacs is free software; you can redistribute it and/or modify it
  13 ;; under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; XEmacs is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with XEmacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Synched up with: Not synched.
  28
  29 ;;; Commentary:
  30
  31 ;; This file is dumped with XEmacs (when X support is compiled in).
  32
  33 ;; Modified by:  Chuck Thompson
  34 ;; Modified by:  Ben Wing
  35 ;; Modified by:  Martin Buchholz
  36
  37 ;; This file does the magic to parse X font names, and make sure that the
  38 ;; default and modeline attributes of new frames are specified enough.
  39
  40 ;;  The resource-manager syntax for faces is
  41
  42 ;;       Emacs.bold.attributeFont:              font-name
  43 ;;       Emacs.bold.attributeForeground:        fg
  44 ;;       Emacs.bold.attributeBackground:        bg
  45 ;;       Emacs.bold.attributeBackgroundPixmap:  file
  46 ;;       Emacs.bold.attributeUnderline:         true/false
  47 ;;       Emacs.bold.attributeStrikethru:        true/false
  48
  49 ;;  You can specify the properties of a face on a per-frame basis.  For
  50 ;;  example, to have the "isearch" face use a red foreground on frames
  51 ;;  named "emacs" (the default) but use a blue foreground on frames that
  52 ;;  you create named "debugger", you could do
  53
  54 ;;       Emacs*emacs.isearch.attributeForeground:       red
  55 ;;       Emacs*debugger.isearch.attributeForeground:    blue
  56
  57 ;;  Generally things that make faces won't set any of the face attributes if
  58 ;;  you have already given them values via the resource database.  You can
  59 ;;  also change this stuff from your .emacs file, by using the functions
  60 ;;  set-face-foreground, set-face-font, etc.  See the code in this file, and
  61 ;;  in faces.el.
  62
  63 ;;; Code:
  64
  65 (defconst x-font-regexp nil)
  66 (defconst x-font-regexp-head nil)
  67 (defconst x-font-regexp-head-2 nil)
  68 (defconst x-font-regexp-weight nil)
  69 (defconst x-font-regexp-slant nil)
  70 (defconst x-font-regexp-pixel nil)
  71 (defconst x-font-regexp-point nil)
  72 (defconst x-font-regexp-foundry-and-family nil)
  73 (defconst x-font-regexp-registry-and-encoding nil)
  74 (defconst x-font-regexp-spacing nil)
  75
  76 ;;; Regexps matching font names in "Host Portable Character Representation."
  77 ;;;
  78 (let ((-                "[-?]")
  79       (foundry          "[^-]*")
  80       (family           "[^-]*")
  81       (weight           "\\(bold\\|demibold\\|medium\\|black\\)")       ; 1
  82 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
  83       (weight\?         "\\([^-]*\\)")                                  ; 1
  84       (slant            "\\([ior]\\)")                                  ; 2
  85 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
  86       (slant\?          "\\([^-]?\\)")                                  ; 2
  87 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
  88       (swidth           "\\([^-]*\\)")                                  ; 3
  89 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
  90       (adstyle          "\\([^-]*\\)")                                  ; 4
  91       (pixelsize        "\\(\\*\\|[0-9]+\\)")                           ; 5
  92       (pointsize        "\\(\\*\\|0\\|[0-9][0-9]+\\)")                  ; 6
  93 ;      (resx            "\\(\\*\\|[0-9][0-9]+\\)")                      ; 7
  94 ;      (resy            "\\(\\*\\|[0-9][0-9]+\\)")                      ; 8
  95       (resx             "\\([*0]\\|[0-9][0-9]+\\)")                     ; 7
  96       (resy             "\\([*0]\\|[0-9][0-9]+\\)")                     ; 8
  97       (spacing          "[cmp?*]")
  98       (avgwidth         "\\(\\*\\|[0-9]+\\)")                           ; 9
  99       (registry         "[^-]*") ; some fonts have omitted registries
 100 ;      (encoding        ".+")           ; note that encoding may contain "-"...
 101       (encoding "[^-]+")                ; false!
 102       )
 103   (setq x-font-regexp
 104         (purecopy
 105          (concat "\\`\\*?[-?*]"
 106                  foundry - family - weight\? - slant\? - swidth - adstyle -
 107                  pixelsize - pointsize - resx - resy - spacing - avgwidth -
 108                  registry - encoding "\\'"
 109                  )))
 110   (setq x-font-regexp-head
 111         (purecopy
 112           (concat "\\`[-?*]" foundry - family - weight\? - slant\?
 113                   "\\([-*?]\\|\\'\\)")))
 114   (setq x-font-regexp-head-2
 115         (purecopy
 116           (concat "\\`[-?*]" foundry - family - weight\? - slant\?
 117                   - swidth - adstyle - pixelsize - pointsize
 118                   "\\([-*?]\\|\\'\\)")))
 119   (setq x-font-regexp-slant (purecopy (concat - slant -)))
 120   (setq x-font-regexp-weight (purecopy (concat - weight -)))
 121   ;; if we can't match any of the more specific regexps (unfortunate) then
 122   ;; look for digits; assume 2+ digits is 10ths of points, and 1-2 digits
 123   ;; is pixels.  Bogus as hell.
 124   (setq x-font-regexp-pixel (purecopy "[-?*]\\([0-9][0-9]?\\)[-?*]"))
 125   (setq x-font-regexp-point (purecopy "[-?*]\\([0-9][0-9]+\\)[-?*]"))
 126   ;; the following two are used by x-font-menu.el.
 127   (setq x-font-regexp-foundry-and-family
 128         (purecopy (concat "\\`[-?*]" foundry - "\\(" family "\\)" -)))
 129   (setq x-font-regexp-registry-and-encoding
 130         (purecopy (concat - "\\(" registry "\\)" - "\\(" encoding "\\)\\'")))
 131   (setq x-font-regexp-spacing
 132         (purecopy (concat - "\\(" spacing "\\)" - avgwidth
 133                           - registry - encoding "\\'")))
 134   )
 135
 136 ;; A "loser font" is something like "8x13" -> "8x13bold".
 137 ;; These are supported only through extreme generosity.
 138 (defconst x-loser-font-regexp (purecopy "\\`[0-9]+x[0-9]+\\'"))
 139
 140 (defun x-frob-font-weight (font which)
 141   (if (font-instance-p font) (setq font (font-instance-name font)))
 142   (cond ((null font) nil)
 143         ((or (string-match x-font-regexp font)
 144              (string-match x-font-regexp-head font)
 145              (string-match x-font-regexp-weight font))
 146          (concat (substring font 0 (match-beginning 1)) which
 147                  (substring font (match-end 1))))
 148         ((string-match x-loser-font-regexp font)
 149          (concat font which))
 150         (t nil)))
 151
 152 (defun x-frob-font-slant (font which)
 153   (if (font-instance-p font) (setq font (font-instance-name font)))
 154   (cond ((null font) nil)
 155         ((or (string-match x-font-regexp font)
 156              (string-match x-font-regexp-head font))
 157          (concat (substring font 0 (match-beginning 2)) which
 158                  (substring font (match-end 2))))
 159         ((string-match x-font-regexp-slant font)
 160          (concat (substring font 0 (match-beginning 1)) which
 161                  (substring font (match-end 1))))
 162         ((string-match x-loser-font-regexp font)
 163          (concat font which))
 164         (t nil)))
 165
 166 (defun x-make-font-bold (font &optional device)
 167   "Given an X font specification, this attempts to make a `bold' font.
 168 If it fails, it returns nil."
 169   ;; Certain Type1 fonts know "bold" as "black"...
 170   (or (try-font-name (x-frob-font-weight font "bold") device)
 171       (try-font-name (x-frob-font-weight font "black") device)
 172       (try-font-name (x-frob-font-weight font "demibold") device)))
 173
 174 (defun x-make-font-unbold (font &optional device)
 175   "Given an X font specification, this attempts to make a non-bold font.
 176 If it fails, it returns nil."
 177   (try-font-name (x-frob-font-weight font "medium") device))
 178
 179 (defcustom try-oblique-before-italic-fonts nil
 180   "*If nil, italic fonts are searched before oblique fonts.
 181 If non-nil, oblique fonts are tried before italic fonts.  This is mostly
 182 applicable to adobe-courier fonts"
 183   :type 'boolean
 184   :group 'x)
 185 (define-obsolete-variable-alias '*try-oblique-before-italic-fonts*
 186   'try-oblique-before-italic-fonts)
 187
 188 (defun x-make-font-italic (font &optional device)
 189   "Given an X font specification, this attempts to make an `italic' font.
 190 If it fails, it returns nil."
 191   (if try-oblique-before-italic-fonts
 192       (or (try-font-name (x-frob-font-slant font "o") device)
 193           (try-font-name (x-frob-font-slant font "i") device))
 194     (or (try-font-name (x-frob-font-slant font "i") device)
 195         (try-font-name (x-frob-font-slant font "o") device))))
 196
 197 (defun x-make-font-unitalic (font &optional device)
 198   "Given an X font specification, this attempts to make a non-italic font.
 199 If it fails, it returns nil."
 200   (try-font-name (x-frob-font-slant font "r") device))
 201
 202 (defun x-make-font-bold-italic (font &optional device)
 203   "Given an X font specification, this attempts to make a `bold-italic' font.
 204 If it fails, it returns nil."
 205   ;; This is haired up to avoid loading the "intermediate" fonts.
 206   (if *try-oblique-before-italic-fonts*
 207       (or (try-font-name
 208            (x-frob-font-slant (x-frob-font-weight font "bold") "o") device)
 209           (try-font-name
 210            (x-frob-font-slant (x-frob-font-weight font "bold") "i") device)
 211           (try-font-name
 212            (x-frob-font-slant (x-frob-font-weight font "black") "o") device)
 213           (try-font-name
 214            (x-frob-font-slant (x-frob-font-weight font "black") "i") device)
 215           (try-font-name
 216            (x-frob-font-slant (x-frob-font-weight font "demibold") "o") device)
 217           (try-font-name
 218            (x-frob-font-slant (x-frob-font-weight font "demibold") "i") device))
 219     (or (try-font-name
 220          (x-frob-font-slant (x-frob-font-weight font "bold") "i") device)
 221         (try-font-name
 222          (x-frob-font-slant (x-frob-font-weight font "bold") "o") device)
 223         (try-font-name
 224          (x-frob-font-slant (x-frob-font-weight font "black") "i") device)
 225         (try-font-name
 226          (x-frob-font-slant (x-frob-font-weight font "black") "o") device)
 227         (try-font-name
 228          (x-frob-font-slant (x-frob-font-weight font "demibold") "i") device)
 229         (try-font-name
 230          (x-frob-font-slant (x-frob-font-weight font "demibold") "o") device))))
 231
 232 (defun x-font-size (font)
 233   "Return the nominal size of the given font.
 234 This is done by parsing its name, so it's likely to lose.
 235 X fonts can be specified (by the user) in either pixels or 10ths of points,
 236  and this returns the first one it finds, so you have to decide which units
 237  the returned value is measured in yourself..."
 238   (if (font-instance-p font) (setq font (font-instance-name font)))
 239   (cond ((or (string-match x-font-regexp font)
 240              (string-match x-font-regexp-head-2 font))
 241          (string-to-int (substring font (match-beginning 6) (match-end 6))))
 242         ((or (string-match x-font-regexp-pixel font)
 243              (string-match x-font-regexp-point font))
 244          (string-to-int (substring font (match-beginning 1) (match-end 1))))
 245         (t nil)))
 246
 247 ;; Given a font name, this function returns a list describing all fonts
 248 ;; of all sizes that otherwise match the given font spec.  Each element
 249 ;; in the list is a list of three items: the pixel size of the font,
 250 ;; the point size (in 1/10ths of a point) of the font, and the fully-
 251 ;; qualified font name.  The first two values may be zero; this
 252 ;; refers to a scalable font.
 253
 254 (defun x-available-font-sizes (font device)
 255   (if (font-instance-p font) (setq font (font-instance-name font)))
 256   (cond ((string-match x-font-regexp font)
 257          ;; turn pixelsize, pointsize, and avgwidth into wildcards
 258          (setq font
 259                (concat (substring font 0 (match-beginning 5)) "*"
 260                        (substring font (match-end 5) (match-beginning 6)) "*"
 261                        (substring font (match-end 6) (match-beginning 9)) "*"
 262                        (substring font (match-end 9) (match-end 0)))))
 263         ((string-match x-font-regexp-head-2 font)
 264          ;; turn pixelsize and pointsize into wildcards
 265          (setq font
 266                (concat (substring font 0 (match-beginning 5)) "*"
 267                        (substring font (match-end 5) (match-beginning 6)) "*"
 268                        (substring font (match-end 6) (match-end 0)))))
 269         ((string-match  "[-?*]\\([0-9]+\\)[-?*]" font)
 270          ;; Turn the first integer we match into a wildcard.
 271          ;; This is pretty dubious...
 272          (setq font
 273                (concat (substring font 0 (match-beginning 1)) "*"
 274                        (substring font (match-end 1) (match-end 0))))))
 275   (sort
 276    (delq nil
 277          (mapcar (function
 278                   (lambda (name)
 279                     (and (string-match x-font-regexp name)
 280                          (list
 281                           (string-to-int (substring name (match-beginning 5)
 282                                                     (match-end 5)))
 283                           (string-to-int (substring name (match-beginning 6)
 284                                                     (match-end 6)))
 285                           name))))
 286                  (list-fonts font device)))
 287    (function (lambda (x y) (if (= (nth 1 x) (nth 1 y))
 288                                (< (nth 0 x) (nth 0 y))
 289                                (< (nth 1 x) (nth 1 y)))))))
 290
 291 ;; Given a font name, this attempts to construct a valid font name for
 292 ;; DEVICE whose size is the next smaller (if UP-P is nil) or larger
 293 ;; (if UP-P is t) size and whose other characteristics are the same
 294 ;; as the given font.
 295
 296 (defun x-frob-font-size (font up-p device)
 297   (if (stringp font) (setq font (make-font-instance font device)))
 298   (if (font-instance-p font) (setq font (font-instance-truename font)))
 299   (let ((available (and font
 300                         (x-available-font-sizes font device))))
 301     (cond
 302      ((null available) nil)
 303      ((or (= 0 (nth 0 (car available)))
 304           (= 0 (nth 1 (car available))))
 305       ;; R5 scalable fonts: change size by 1 point.
 306       ;; If they're scalable the first font will have pixel or point = 0.
 307       ;; Sometimes one is 0 and the other isn't (if it's a bitmap font that
 308       ;; can be scaled), sometimes both are (if it's a true outline font).
 309       (let ((name (nth 2 (car available)))
 310             old-size)
 311         (or (string-match x-font-regexp font) (error "can't parse %S" font))
 312         (setq old-size (string-to-int
 313                         (substring font (match-beginning 6) (match-end 6))))
 314         (or (> old-size 0) (error "font truename has 0 pointsize?"))
 315         (or (string-match x-font-regexp name) (error "can't parse %S" name))
 316         ;; turn pixelsize into a wildcard, and make pointsize be +/- 10,
 317         ;; which is +/- 1 point.  All other fields stay the same as they
 318         ;; were in the "template" font returned by x-available-font-sizes.
 319         ;;
 320         ;; #### But this might return the same font: for example, if the
 321         ;;      truename of "-*-courier-medium-r-normal--*-230-75-75-m-0-*"
 322         ;;      is "...-240-..." (instead of 230) then this loses, because
 323         ;;      the 230 that was passed in as an arg got turned into 240
 324         ;;      by the call to font-instance-truename; then we decrement that
 325         ;;      by 10 and return the result which is the same.  I think the
 326         ;;      way to fix this is to make this be a loop that keeps trying
 327         ;;      progressively larger pointsize deltas until it finds one
 328         ;;      whose truename differs.  Have to be careful to avoid infinite
 329         ;;      loops at the upper end...
 330         ;;
 331         (concat (substring name 0 (match-beginning 5)) "*"
 332                 (substring name (match-end 5) (match-beginning 6))
 333                 (int-to-string (+ old-size (if up-p 10 -10)))
 334                 (substring name (match-end 6) (match-end 0)))))
 335      (t
 336       ;; non-scalable fonts: take the next available size.
 337       (let ((rest available)
 338             (last nil)
 339             result)
 340         (setq font (downcase font))
 341         (while rest
 342           (cond ((and (not up-p) (equal font (downcase (nth 2 (car rest)))))
 343                  (setq result last
 344                        rest nil))
 345                 ((and up-p (equal font (and last (downcase (nth 2 last)))))
 346                  (setq result (car rest)
 347                        rest nil)))
 348           (setq last (car rest))
 349           (setq rest (cdr rest)))
 350         (nth 2 result))))))
 351
 352 (defun x-find-smaller-font (font &optional device)
 353   "Load a new, slightly smaller version of the given font (or font name).
 354 Returns the font if it succeeds, nil otherwise.
 355 If scalable fonts are available, this returns a font which is 1 point smaller.
 356 Otherwise, it returns the next smaller version of this font that is defined."
 357   (x-frob-font-size font nil device))
 358
 359 (defun x-find-larger-font (font &optional device)
 360   "Load a new, slightly larger version of the given font (or font name).
 361 Returns the font if it succeeds, nil otherwise.
 362 If scalable fonts are available, this returns a font which is 1 point larger.
 363 Otherwise, it returns the next larger version of this font that is defined."
 364   (x-frob-font-size font t device))
 365
 366 (defalias 'x-make-face-bold 'make-face-bold)
 367 (defalias 'x-make-face-italic 'make-face-italic)
 368 (defalias 'x-make-face-bold-italic 'make-face-bold-italic)
 369 (defalias 'x-make-face-unbold 'make-face-unbold)
 370 (defalias 'x-make-face-unitalic 'make-face-unitalic)
 371
 372 (make-obsolete 'x-make-face-bold 'make-face-bold)
 373 (make-obsolete 'x-make-face-italic 'make-face-italic)
 374 (make-obsolete 'x-make-face-bold-italic 'make-face-bold-italic)
 375 (make-obsolete 'x-make-face-unbold 'make-face-unbold)
 376 (make-obsolete 'x-make-face-unitalic 'make-face-unitalic)
 377
 378 \f
 379 ;;; internal routines
 380
 381 ;;; x-init-face-from-resources is responsible for initializing a
 382 ;;; newly-created face from the resource database.
 383 ;;;
 384 ;;; When a new frame is created, it is called from `x-init-frame-faces'
 385 ;;; called from `init-frame-faces' called from init_frame_faces()
 386 ;;; from Fmake_frame().  In this case it is called once for each existing
 387 ;;; face, with the newly-created frame as the argument.  It then initializes
 388 ;;; the newly-created faces on that frame.
 389 ;;;
 390 ;;; It's also called from `init-device-faces' and
 391 ;;; `init-global-faces'.
 392 ;;;
 393 ;;; This had better not signal an error.  The frame is in an intermediate
 394 ;;; state where signalling an error or entering the debugger would likely
 395 ;;; result in a crash.
 396
 397 (defun x-init-face-from-resources (face &optional locale set-anyway)
 398
 399   ;;
 400   ;; These are things like "attributeForeground" instead of simply
 401   ;; "foreground" because people tend to do things like "*foreground",
 402   ;; which would cause all faces to be fully qualified, making faces
 403   ;; inherit attributes in a non-useful way.  So we've made them slightly
 404   ;; less obvious to specify in order to make them work correctly in
 405   ;; more random environments.
 406   ;;
 407   ;; I think these should be called "face.faceForeground" instead of
 408   ;; "face.attributeForeground", but they're the way they are for
 409   ;; hysterical reasons. (jwz)
 410
 411   (let* ((append (if set-anyway nil 'append))
 412          ;; Some faces are initialized before XEmacs is dumped.
 413          ;; In order for the X resources to be able to override
 414          ;; those settings, such initialization always uses the
 415          ;; `default' tag.  We remove all specifier specs
 416          ;; containing the `default' tag in the locale before
 417          ;; adding new specs.
 418          (tag-set '(default))
 419          ;; The tag order matters here.  The spec removal
 420          ;; function uses the list cdrs.  We want to remove (x
 421          ;; default) and (default) specs, not (default x) and (x)
 422          ;; specs.
 423          (x-tag-set '(x default))
 424          (tty-tag-set '(tty default))
 425          (device-class nil)
 426          (face-sym (face-name face))
 427          (name (symbol-name face-sym))
 428          (fn (x-get-resource-and-maybe-bogosity-check
 429               (concat name ".attributeFont")
 430               "Face.AttributeFont"
 431               'string locale))
 432          (fg (x-get-resource-and-maybe-bogosity-check
 433               (concat name ".attributeForeground")
 434               "Face.AttributeForeground"
 435               'string locale))
 436          (bg (x-get-resource-and-maybe-bogosity-check
 437               (concat name ".attributeBackground")
 438               "Face.AttributeBackground"
 439               'string locale))
 440          (bgp (x-get-resource-and-maybe-bogosity-check
 441                (concat name ".attributeBackgroundPixmap")
 442                "Face.AttributeBackgroundPixmap"
 443                'string locale))
 444          (ulp (x-get-resource-and-maybe-bogosity-check
 445                (concat name ".attributeUnderline")
 446                "Face.AttributeUnderline"
 447                'boolean locale))
 448          (stp (x-get-resource-and-maybe-bogosity-check
 449                (concat name ".attributeStrikethru")
 450                "Face.AttributeStrikethru"
 451                'boolean locale))
 452          ;; we still resource for these TTY-only resources so that
 453          ;; you can specify resources for TTY frames/devices.  This is
 454          ;; useful when you start up your XEmacs on an X display and later
 455          ;; open some TTY frames.
 456          (hp (x-get-resource-and-maybe-bogosity-check
 457               (concat name ".attributeHighlight")
 458               "Face.AttributeHighlight"
 459               'boolean locale))
 460          (dp (x-get-resource-and-maybe-bogosity-check
 461               (concat name ".attributeDim")
 462               "Face.AttributeDim"
 463               'boolean locale))
 464          (bp (x-get-resource-and-maybe-bogosity-check
 465               (concat name ".attributeBlinking")
 466               "Face.AttributeBlinking"
 467               'boolean locale))
 468          (rp (x-get-resource-and-maybe-bogosity-check
 469               (concat name ".attributeReverse")
 470               "Face.AttributeReverse"
 471               'boolean locale))
 472          )
 473
 474     (cond ((framep locale)
 475            (setq device-class (device-class (frame-device locale))))
 476           ((devicep locale)
 477            (setq device-class (device-class locale))))
 478
 479     (if device-class
 480         (setq tag-set (cons device-class tag-set)
 481               x-tag-set (cons device-class x-tag-set)
 482               tty-tag-set (cons device-class tty-tag-set)))
 483
 484     ;;
 485     ;; If this is the default face, then any unspecified properties should
 486     ;; be defaulted from the global properties.  Can't do this for
 487     ;; frames or devices because then, common resource specs like
 488     ;; "*Foreground: black" will have unwanted effects.
 489     ;;
 490     (if (and (or (eq (face-name face) 'default)
 491                  (eq (face-name face) 'gui-element))
 492              (or (null locale) (eq locale 'global)))
 493         (progn
 494           (or fn (setq fn (x-get-resource
 495                            "font" "Font" 'string locale)))
 496           (or fg (setq fg (x-get-resource
 497                            "foreground" "Foreground" 'string locale)))
 498           (or bg (setq bg (x-get-resource
 499                            "background" "Background" 'string locale)))))
 500     ;;
 501     ;; "*cursorColor: foo" is equivalent to setting the background of the
 502     ;; text-cursor face.
 503     ;;
 504     (if (and (eq (face-name face) 'text-cursor)
 505              (or (null locale) (eq locale 'global)))
 506         (setq bg (or (x-get-resource
 507                       "cursorColor" "CursorColor" 'string locale) bg)))
 508     ;; #### should issue warnings?  I think this should be
 509     ;; done when the instancing actually happens, but I'm not
 510     ;; sure how it should actually be dealt with.
 511     (when fn
 512       (if device-class
 513           ;; Always use the x-tag-set to remove specs, since we don't
 514           ;; know whether the predumped face was initialized with an
 515           ;; 'x tag or not.
 516           (remove-specifier-specs-matching-tag-set-cdrs (face-font face)
 517                                                         locale
 518                                                         x-tag-set)
 519         ;; If there's no device class then we're initializing
 520         ;; globally.  This means we should override global
 521         ;; defaults for all X device classes.
 522         (remove-specifier (face-font face) locale x-tag-set nil))
 523       (set-face-font face fn locale 'x append))
 524     ;; Kludge-o-rooni.  Set the foreground and background resources for
 525     ;; X devices only -- otherwise things tend to get all messed up
 526     ;; if you start up an X frame and then later create a TTY frame.
 527     (when fg
 528       (if device-class
 529           (remove-specifier-specs-matching-tag-set-cdrs (face-foreground face)
 530                                                         locale
 531                                                         x-tag-set)
 532         (remove-specifier (face-foreground face) locale x-tag-set nil))
 533       (set-face-foreground face fg locale 'x append))
 534     (when bg
 535       (if device-class
 536           (remove-specifier-specs-matching-tag-set-cdrs (face-background face)
 537                                                         locale
 538                                                         x-tag-set)
 539         (remove-specifier (face-background face) locale x-tag-set nil))
 540       (set-face-background face bg locale 'x append))
 541     (when bgp
 542       (if device-class
 543           (remove-specifier-specs-matching-tag-set-cdrs (face-background-pixmap
 544                                                          face)
 545                                                         locale
 546                                                         x-tag-set)
 547         (remove-specifier (face-background-pixmap face) locale x-tag-set nil))
 548       (set-face-background-pixmap face bgp locale nil append))
 549     (when ulp
 550       (if device-class
 551           (remove-specifier-specs-matching-tag-set-cdrs (face-property
 552                                                          face 'underline)
 553                                                         locale
 554                                                         tty-tag-set)
 555         (remove-specifier (face-property face 'underline) locale
 556                           tty-tag-set nil))
 557       (set-face-underline-p face ulp locale nil append))
 558     (when stp
 559       (if device-class
 560           (remove-specifier-specs-matching-tag-set-cdrs (face-property
 561                                                          face 'strikethru)
 562                                                         locale
 563                                                         tty-tag-set)
 564         (remove-specifier (face-property face 'strikethru)
 565                           locale tty-tag-set nil))
 566       (set-face-strikethru-p face stp locale nil append))
 567     (when hp
 568       (if device-class
 569           (remove-specifier-specs-matching-tag-set-cdrs (face-property
 570                                                          face 'highlight)
 571                                                         locale
 572                                                         tty-tag-set)
 573         (remove-specifier (face-property face 'highlight)
 574                           locale tty-tag-set nil))
 575       (set-face-highlight-p face hp locale nil append))
 576     (when dp
 577       (if device-class
 578           (remove-specifier-specs-matching-tag-set-cdrs (face-property
 579                                                          face 'dim)
 580                                                         locale
 581                                                         tty-tag-set)
 582         (remove-specifier (face-property face 'dim) locale tty-tag-set nil))
 583       (set-face-dim-p face dp locale nil append))
 584     (when bp
 585       (if device-class
 586           (remove-specifier-specs-matching-tag-set-cdrs (face-property
 587                                                          face 'blinking)
 588                                                         locale
 589                                                         tty-tag-set)
 590         (remove-specifier (face-property face 'blinking) locale
 591                           tty-tag-set nil))
 592       (set-face-blinking-p face bp locale nil append))
 593     (when rp
 594       (if device-class
 595           (remove-specifier-specs-matching-tag-set-cdrs (face-property
 596                                                          face 'reverse)
 597                                                         locale
 598                                                         tty-tag-set)
 599         (remove-specifier (face-property face 'reverse) locale
 600                           tty-tag-set nil))
 601       (set-face-reverse-p face rp locale nil append))
 602     ))
 603
 604 ;; GNU Emacs compatibility. (move to obsolete.el?)
 605 (defalias 'make-face-x-resource-internal 'x-init-face-from-resources)
 606
 607 (defun remove-specifier-specs-matching-tag-set-cdrs (specifier locale tag-set)
 608   (while tag-set
 609     (remove-specifier specifier locale tag-set t)
 610     (setq tag-set (cdr tag-set))))
 611
 612 ;;; x-init-global-faces is responsible for ensuring that the
 613 ;;; default face has some reasonable fallbacks if nothing else is
 614 ;;; specified.
 615 ;;;
 616 (defun x-init-global-faces ()
 617   (or (face-font 'default 'global)
 618       (set-face-font 'default
 619                      "-*-courier-medium-r-*-*-*-120-*-*-*-*-iso8859-*"
 620                      'global '(x default)))
 621   (or (face-foreground 'default 'global)
 622       (set-face-foreground 'default "black" 'global '(x default)))
 623   (or (face-background 'default 'global)
 624       (set-face-background 'default "gray80" 'global '(x default))))
 625
 626 ;;; x-init-device-faces is responsible for initializing default
 627 ;;; values for faces on a newly created device.
 628 ;;;
 629 (defun x-init-device-faces (device)
 630   ;;
 631   ;; If the "default" face didn't have a font specified, try to pick one.
 632   ;;
 633   (or
 634    (face-font-instance 'default device)
 635    ;;
 636    ;; No font specified in the resource database; try to cope.
 637    ;;
 638    ;; At first I wanted to do this by just putting a font-spec in the
 639    ;; fallback resources passed to XtAppInitialize(), but that fails
 640    ;; if there is an Emacs app-defaults file which doesn't specify a
 641    ;; font: apparently the fallback resources are not consulted when
 642    ;; there is an app-defaults file, which seems pretty bogus to me.
 643    ;;
 644    ;; We should also probably try "*xtDefaultFont", but I think that it
 645    ;; might be legal to specify that as "xtDefaultFont:", that is, at
 646    ;; top level, instead of "*xtDefaultFont:", that is, applicable to
 647    ;; every application.  `x-get-resource' can't handle that right now.
 648    ;; Anyway, xtDefaultFont is probably variable-width.
 649    ;;
 650    ;; Some who have LucidaTypewriter think it's a better font than Courier,
 651    ;; but it has the bug that there are no italic and bold italic versions.
 652    ;; We could hair this code up to try and mix-and-match fonts to get a
 653    ;; full complement, but really, why bother.  It's just a default.
 654    ;;
 655    (let (new-x-font)
 656      (setq new-x-font (or
 657       ;;
 658       ;; We default to looking for iso8859 fonts.  Using a wildcard for the
 659       ;; encoding would be bad, because that can cause English speakers to get
 660       ;; Kanji fonts by default.  It is safe to assume that people using a
 661       ;; language other than English have both set $LANG, and have specified
 662       ;; their `font' and `fontList' resources.  In any event, it's better to
 663       ;; err on the side of the English speaker in this case because they are
 664       ;; much less likely to have encountered this problem, and are thus less
 665       ;; likely to know what to do about it.
 666
 667       ;; Try for Courier.  Almost everyone has that.  (Does anyone not?)
 668       (make-font-instance
 669        "-*-courier-medium-r-*-*-*-120-*-*-*-*-iso8859-*" device t)
 670       (make-font-instance
 671        "-*-courier-*-r-*-*-*-120-*-*-*-*-iso8859-*" device t)
 672       ;; Next try for any "medium" charcell or monospaced iso8859 font.
 673       (make-font-instance "-*-*-medium-r-*-*-*-120-*-*-m-*-iso8859-*" device t)
 674       (make-font-instance "-*-*-medium-r-*-*-*-120-*-*-c-*-iso8859-*" device t)
 675       ;; Next try for any charcell or monospaced iso8859 font.
 676       (make-font-instance "-*-*-*-r-*-*-*-120-*-*-m-*-iso8859-*" device t)
 677       (make-font-instance "-*-*-*-r-*-*-*-120-*-*-c-*-iso8859-*" device t)
 678       ;; Ok, let's at least try to stay in 8859...
 679       (make-font-instance "-*-*-*-r-*-*-*-120-*-*-*-*-iso8859-*" device t)
 680       ;; Boy, we sure are losing now.  Try the above, but in any encoding.
 681       (make-font-instance "-*-*-medium-r-*-*-*-120-*-*-m-*-*-*" device t)
 682       (make-font-instance "-*-*-medium-r-*-*-*-120-*-*-c-*-*-*" device t)
 683       (make-font-instance "-*-*-*-r-*-*-*-120-*-*-m-*-*-*" device t)
 684       (make-font-instance "-*-*-*-r-*-*-*-120-*-*-c-*-*-*" device t)
 685       (make-font-instance "-*-*-*-r-*-*-*-120-*-*-*-*-*-*" device t)
 686       ;; Hello?  Please?
 687       (make-font-instance "-*-*-*-*-*-*-*-120-*-*-*-*-*-*" device t)
 688       (make-font-instance "*" device t)
 689       ;; if we get to here we're screwed, and faces.c will fatal()...
 690       ))
 691      (if (not (face-font 'default 'global))
 692          (set-face-font 'default new-x-font)
 693        (set-face-font 'default new-x-font device))))
 694   ;;
 695   ;; If the "default" face didn't have both colors specified, then pick
 696   ;; some, taking into account whether one of the colors was specified.
 697   ;;
 698   (let ((fg (face-foreground-instance 'default device))
 699         (bg (face-background-instance 'default device)))
 700     (if (not (and fg bg))
 701         (if (or (and fg (equal (downcase (color-instance-name fg)) "white"))
 702                 (and bg (equal (downcase (color-instance-name bg)) "black")))
 703             (progn
 704               (or fg (set-face-foreground 'default "white" device))
 705               (or bg (set-face-background 'default "black" device)))
 706           (or fg (set-face-foreground 'default "white" device))
 707           (or bg (set-face-background 'default "black" device)))))
 708
 709   ;; Don't look at reverseVideo now or initialize the modeline.  This
 710   ;; is done on a per-frame basis at the appropriate time.
 711
 712   ;;
 713   ;; Now let's try to pick some reasonable defaults for a few other faces.
 714   ;; This kind of stuff should normally go on the create-frame-hook, but
 715   ;; this way we won't be in danger of the user screwing things up by not
 716   ;; adding hooks in a safe way.
 717   ;;
 718   (x-init-pointer-shape device)  ; from x-mouse.el
 719     )
 720
 721 ;;; This is called from `init-frame-faces', which is called from
 722 ;;; init_frame_faces() which is called from Fmake_frame(), to perform
 723 ;;; any device-specific initialization.
 724 ;;;
 725 (defun x-init-frame-faces (frame)
 726   ;;
 727   ;; The faces already got initialized (by init-frame-faces) from
 728   ;; the resource database or global, non-frame faces.  The default,
 729   ;; bold, bold-italic, and italic faces (plus various other random faces)
 730   ;; got set up then.  But modeline didn't so that reverseVideo can be
 731   ;; frame-specific.
 732   ;;
 733
 734   ;;
 735   ;; If reverseVideo was specified, swap the foreground and background
 736   ;; of the default and modeline faces.
 737   ;;
 738   (cond ((car (x-get-resource "reverseVideo" "ReverseVideo" 'boolean frame))
 739          ;; First make sure the modeline has fg and bg, inherited from the
 740          ;; current default face - for the case where only one is specified,
 741          ;; so that invert-face doesn't do something weird.
 742          (or (face-foreground 'modeline frame)
 743              (set-face-foreground 'modeline
 744                                   (face-foreground-instance 'default frame)
 745                                   frame))
 746          (or (face-background 'modeline frame)
 747              (set-face-background 'modeline
 748                                   (face-background-instance 'default frame)
 749                                   frame))
 750          ;; Now invert both of them.  If they end up looking the same,
 751          ;; make-frame-initial-faces will invert the modeline again later.
 752          (invert-face 'default frame)
 753          (invert-face 'modeline frame)
 754          )))
 755
 756 ;;; x-faces.el ends here