egg/sj3.el

   1 ;;; egg/sj3.el --- SJ3 Support (high level interface) in Egg
   2 ;;;                Input Method Architecture
   3
   4 ;; Copyright (C) 1997 Mule Project, Powered by Electrotechnical
   5 ;; Laboratory, JAPAN.
   6 ;; Project Leader: Satoru Tomura <tomura@etl.go.jp>
   7
   8 ;; Author: NIIBE Yutaka <gniibe@mri.co.jp>
   9 ;; Maintainer: NIIBE Yutaka <gniibe@mri.co.jp>
  10
  11 ;; This file will be part of GNU Emacs (in future).
  12
  13 ;; EGG is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; EGG is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;;; Code:
  31
  32 (defconst sj3-support-languages '("Japanese"))
  33
  34 (defconst sj3-conversion-backend
  35   [ sj3-init
  36
  37     sj3-start-conversion
  38       sj3-get-bunsetsu-converted
  39       sj3-get-bunsetsu-source
  40       sj3-list-candidates
  41           sj3-get-number-of-candidates
  42           sj3-get-current-candidate-number
  43           sj3-get-all-candidates
  44           sj3-decide-candidate
  45       sj3-change-bunsetsu-length
  46     sj3-end-conversion
  47
  48     sj3-fini
  49  ])
  50
  51 (defconst sj3-server-port 3000 "Port number of SJ3 server")
  52 (defvar sj3-stdy-size 0 "STDYSIZE of SJ3 server")
  53 (defvar sj3-hostname "localhost"
  54   "Hostname of SJ3 server")
  55
  56 (defun sj3-open (hostname)
  57   "Establish the connection to SJ3 server.  Return process object."
  58   (let* ((buf (generate-new-buffer " *SJ3*"))
  59          (proc (open-network-stream "SJ3" buf hostname sj3-server-port))
  60          result)
  61     (process-kill-without-query proc)
  62     (set-process-coding-system proc 'no-conversion 'no-conversion)
  63     (set-marker-insertion-type (process-mark proc) t)
  64     (save-excursion
  65       (set-buffer buf)
  66       (erase-buffer)
  67       (buffer-disable-undo)
  68       (setq enable-multibyte-characters nil))
  69     ;; Initialize dictionaries
  70     (setq sj3-sys-dict-list nil)
  71     (setq sj3-user-dict-list nil)
  72     (setq result (sj3rpc-open proc (system-name) (user-login-name)))
  73     (if (< result 0)
  74         (let ((msg (sj3rpc-get-error-message (- result))))
  75           (delete-process proc)
  76           (kill-buffer buf)
  77           (error "Can't open SJ3 session (%s): %s" hostname msg)))
  78     (setq result (sj3rpc-get-stdy-size proc))
  79     (if (< result 0)
  80         (let ((msg (sj3rpc-get-error-message (- result))))
  81           (delete-process proc)
  82           (kill-buffer buf)
  83           (error "Can't get SJ3 STDYSIZE: %s"msg)))
  84     (setq sj3-stdy-size result)
  85     proc))
  86
  87 ;; <env> ::= [ <proc> <dictionary-list> ]
  88 (defvar sj3-environment nil
  89   "Environment for SJ3 kana-kanji conversion")
  90
  91 (defsubst sj3env-get-proc (env)
  92   (aref env 0))
  93 (defsubst sj3env-get-dictionary-list (env)
  94   (aref env 1))
  95
  96 ;; <bunsetsu> ::=
  97 ;;  [ <env> <source> <converted> <rest>
  98 ;;    <stdy> <zenkouho> <zenkouho-pos> <stdy-down> ]
  99 (defsubst sj3-make-bunsetsu (env source converted rest stdy)
 100   (vector env source converted rest stdy nil nil nil))
 101
 102 (defsubst sj3bunsetsu-get-env (b)
 103   (aref b 0))
 104 (defsubst sj3bunsetsu-get-source (b)
 105   (aref b 1))
 106 (defsubst sj3bunsetsu-get-converted (b)
 107   (aref b 2))
 108 (defsubst sj3bunsetsu-get-rest (b)
 109   (aref b 3))
 110 (defsubst sj3bunsetsu-get-stdy (b)
 111   (aref b 4))
 112 (defsubst sj3bunsetsu-get-zenkouho (b)
 113   (aref b 5))
 114 (defsubst sj3bunsetsu-set-zenkouho (b z)
 115   (aset b 5 z))
 116 (defsubst sj3bunsetsu-get-zenkouho-pos (b)
 117   (aref b 6))
 118 (defsubst sj3bunsetsu-set-zenkouho-pos (b p)
 119   (aset b 6 p))
 120 (defsubst sj3bunsetsu-get-stdydown (b)
 121   (aref b 7))
 122 (defsubst sj3bunsetsu-set-stdydown (b s)
 123   (aset b 7 s))
 124
 125 (defun sj3-get-bunsetsu-source (b)
 126   (sj3bunsetsu-get-source b))
 127 (defun sj3-get-bunsetsu-converted (b)
 128   (concat (sj3bunsetsu-get-converted b)
 129           (sj3bunsetsu-get-rest b)))
 130 (defun sj3-get-bunsetsu-stdy (b)
 131   (sj3bunsetsu-get-stdy b))
 132
 133 (defvar sj3-dictionary-specification
 134   '(("study.dat")
 135     ["sj3main.dic" ""]
 136     [("private.dic") ""])
 137   "Dictionary specification of SJ3.")
 138
 139 (defvar sj3-usr-dic-dir (concat "user/" (user-login-name))
 140   "*Directory of user dictionary for SJ3.")
 141
 142 (defun sj3-filename (p)
 143   ""
 144   (cond ((consp p) (concat sj3-usr-dic-dir "/" (car p)))
 145         (t p)))
 146
 147 (defun sj3-get-environment ()
 148   (if sj3-environment
 149       sj3-environment
 150     (let* ((proc (sj3-open sj3-hostname))
 151            (stdy (sj3-filename (car sj3-dictionary-specification)))
 152            (l (cdr sj3-dictionary-specification))
 153            dict-list)
 154       (if (/= (sj3rpc-open-stdy proc stdy) 0)
 155           (error "Dame1")               ; XXX
 156         (while l
 157           (let ((dic (car l))
 158                 dic-id)
 159             (setq dic-id
 160                   (sj3rpc-open-dictionary proc (sj3-filename (aref dic 0))
 161                                           (aref dic 1)))
 162             (if (< dic-id 0)
 163                 (error "Dame2")         ; XXX
 164               (setq dict-list (cons dic-id dict-list)
 165                     l (cdr l))))))
 166         (setq sj3-environment (vector proc dict-list)))))
 167
 168 (defun sj3-init ()
 169   )
 170
 171 (defun sj3-start-conversion (yomi lang)
 172   "Convert YOMI string to kanji, and enter conversion mode.
 173 Return the list of bunsetsu."
 174   (let ((env (sj3-get-environment)))
 175     (sj3rpc-begin env yomi)))
 176
 177 ;; XXX: not implemented yet
 178 (defun sj3-end-conversion (bunsetsu-list)
 179   )
 180
 181 (defun sj3-list-candidates (bunsetsu prev-bunsetsu)
 182   (let* ((env (sj3bunsetsu-get-env bunsetsu))
 183          (yomi (sj3bunsetsu-get-source bunsetsu))
 184          (z (sj3rpc-get-bunsetsu-candidates env yomi)))
 185     (sj3bunsetsu-set-zenkouho bunsetsu z)
 186     (sj3bunsetsu-set-zenkouho-pos bunsetsu 0)
 187     0))
 188
 189 (defun sj3-get-number-of-candidates (bunsetsu)
 190   (let ((l (sj3bunsetsu-get-zenkouho bunsetsu)))
 191     (if l
 192         (length l)
 193       nil)))
 194
 195 (defun sj3-decide-candidate (bunsetsu candidate-pos)
 196   (let* ((candidate-list (sj3bunsetsu-get-zenkouho bunsetsu))
 197          (candidate (nth candidate-pos candidate-list)))
 198     (sj3bunsetsu-set-zenkouho candidate candidate-list)
 199     (sj3bunsetsu-set-zenkouho-pos candidate candidate-pos)
 200     candidate))
 201
 202 (defun sj3-get-current-candidate-number (bunsetsu)
 203   (sj3bunsetsu-get-zenkouho-pos bunsetsu))
 204
 205 (defun sj3-get-all-candidates (bunsetsu)
 206   (let* ((l (sj3bunsetsu-get-zenkouho bunsetsu))
 207          (result (cons nil nil))
 208          (r result))
 209     (catch 'break
 210       (while t
 211         (let ((candidate (car l)))
 212           (setcar r (sj3bunsetsu-get-converted candidate))
 213           (if (null (setq l (cdr l)))
 214               (throw 'break nil)
 215             (setq r (setcdr r (cons nil nil)))))))
 216     result))
 217
 218 (defun sj3-change-bunsetsu-length (b0 b1 b2 len)
 219   (let ((yomi (concat
 220                (sj3bunsetsu-get-source b1)
 221                (if b2 (sj3bunsetsu-get-source b2))))
 222         (env (sj3bunsetsu-get-env b1))
 223         yomi1 yomi2
 224         bunsetsu1 bunsetsu2)
 225     (setq yomi1 (substring yomi 0 len)
 226           yomi2 (substring yomi len))
 227     (setq bunsetsu1
 228           (sj3rpc-tanbunsetsu-conversion env yomi1))
 229     ;; Only set once.
 230     (sj3bunsetsu-set-stdydown bunsetsu1
 231                               (or (sj3bunsetsu-get-stdydown b1)
 232                                   (if b2
 233                                       (list b1 b2)
 234                                     (list b1))))
 235     (if (< 0 (length yomi2))
 236         (setq bunsetsu2 (sj3rpc-tanbunsetsu-conversion env yomi2))
 237       (setq bunsetsu2 nil))
 238     (if bunsetsu2
 239         (list bunsetsu1 bunsetsu2)
 240       (list bunsetsu1))))
 241
 242 ;; XXX: Not implemented yet
 243 (defun sj3-fini (lang)
 244   )
 245
 246 ;;; setup
 247
 248 (require 'egg)
 249 (load "egg/sj3rpc")
 250
 251 ;;;###autoload
 252 (defun egg-activate-sj3 (&rest arg)
 253   "Activate SJ3 backend of Tamagotchy."
 254   (egg-set-support-languages sj3-support-languages)
 255   (egg-set-conversion-backend sj3-conversion-backend
 256                               sj3-support-languages
 257                               nil)
 258   (apply 'egg-mode arg))
 259
 260 ;;; egg/sj3.el ends here.