sha1-el.el

   1 ;;; sha1-el.el --- SHA1 Secure Hash Algorithm in Emacs-Lisp.
   2
   3 ;; Copyright (C) 1999, 2001  Free Software Foundation, Inc.
   4
   5 ;; Author: Shuhei KOBAYASHI <shuhei@aqua.ocn.ne.jp>
   6 ;; Keywords: SHA1, FIPS 180-1
   7
   8 ;; This file is part of FLIM (Faithful Library about Internet Message).
   9
  10 ;; This program is free software; you can redistribute it and/or
  11 ;; modify it under the terms of the GNU General Public License as
  12 ;; published by the Free Software Foundation; either version 2, or
  13 ;; (at your option) any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with this program; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This program is implemented from the definition of SHA-1 in FIPS PUB
  28 ;; 180-1 (Federal Information Processing Standards Publication 180-1),
  29 ;; "Announcing the Standard for SECURE HASH STANDARD".
  30 ;; <URL:http://www.itl.nist.gov/div897/pubs/fip180-1.htm>
  31 ;; (EXCEPTION; two optimizations taken from GnuPG/cipher/sha1.c)
  32 ;;
  33 ;; Test cases from FIPS PUB 180-1.
  34 ;;
  35 ;; (sha1 "abc")
  36 ;; => a9993e364706816aba3e25717850c26c9cd0d89d
  37 ;;
  38 ;; (sha1 "abcdbcdecdefdefgefghfghighijhijkijkljklmklmnlmnomnopnopq")
  39 ;; => 84983e441c3bd26ebaae4aa1f95129e5e54670f1
  40 ;;
  41 ;; (sha1 (make-string 1000000 ?a))
  42 ;; => 34aa973cd4c4daa4f61eeb2bdbad27316534016f
  43 ;;
  44 ;; BUGS:
  45 ;;  * It is assumed that length of input string is less than 2^29 bytes.
  46 ;;  * It is caller's responsibility to make string (or region) unibyte.
  47 ;;
  48 ;; TODO:
  49 ;;  * Rewrite from scratch!
  50 ;;    This version is much faster than Keiichi Suzuki's another sha1.el,
  51 ;;    but it is too dirty.
  52
  53 ;;; Code:
  54
  55 (require 'hex-util)
  56
  57 ;;;
  58 ;;; external SHA1 function.
  59 ;;;
  60
  61 (defvar sha1-maximum-internal-length 500
  62   "*Maximum length of message to use lisp version of SHA1 function.
  63 If message is longer than this, `sha1-program' is used instead.
  64
  65 If this variable is set to 0, use extarnal program only.
  66 If this variable is set to nil, use internal function only.")
  67
  68 (defvar sha1-program '("openssl" "sha1")
  69   "*Name of program to compute SHA1.
  70 It must be a string \(program name\) or list of strings \(name and its args\).")
  71
  72 (defun sha1-string-external (string)
  73   ;; `with-temp-buffer' is new in v20, so we do not use it.
  74   (save-excursion
  75     (let (buffer)
  76       (unwind-protect
  77           (let (prog args)
  78             (if (consp sha1-program)
  79                 (setq prog (car sha1-program)
  80                       args (cdr sha1-program))
  81               (setq prog sha1-program
  82                     args nil))
  83             (setq buffer (set-buffer
  84                           (generate-new-buffer " *sha1 external*")))
  85             (insert string)
  86             (apply (function call-process-region)
  87                    (point-min)(point-max)
  88                    prog t t nil args)
  89             ;; SHA1 is 40 bytes long in hexadecimal form.
  90             (buffer-substring (point-min)(+ (point-min) 40)))
  91         (and buffer
  92              (buffer-name buffer)
  93              (kill-buffer buffer))))))
  94
  95 (defun sha1-region-external (beg end)
  96   (sha1-string-external (buffer-substring-no-properties beg end)))
  97
  98 ;;;
  99 ;;; internal SHA1 function.
 100 ;;;
 101
 102 (eval-when-compile
 103   ;; optional second arg of string-to-number is new in v20.
 104   (defconst sha1-K0-high 23170)         ; (string-to-number "5A82" 16)
 105   (defconst sha1-K0-low  31129)         ; (string-to-number "7999" 16)
 106   (defconst sha1-K1-high 28377)         ; (string-to-number "6ED9" 16)
 107   (defconst sha1-K1-low  60321)         ; (string-to-number "EBA1" 16)
 108   (defconst sha1-K2-high 36635)         ; (string-to-number "8F1B" 16)
 109   (defconst sha1-K2-low  48348)         ; (string-to-number "BCDC" 16)
 110   (defconst sha1-K3-high 51810)         ; (string-to-number "CA62" 16)
 111   (defconst sha1-K3-low  49622)         ; (string-to-number "C1D6" 16)
 112
 113 ;;; original definition of sha1-F0.
 114 ;;; (defmacro sha1-F0 (B C D)
 115 ;;;   (` (logior (logand (, B) (, C))
 116 ;;;          (logand (lognot (, B)) (, D)))))
 117 ;;; a little optimization from GnuPG/cipher/sha1.c.
 118   (defmacro sha1-F0 (B C D)
 119     (` (logxor (, D) (logand (, B) (logxor (, C) (, D))))))
 120   (defmacro sha1-F1 (B C D)
 121     (` (logxor (, B) (, C) (, D))))
 122 ;;; original definition of sha1-F2.
 123 ;;; (defmacro sha1-F2 (B C D)
 124 ;;;   (` (logior (logand (, B) (, C))
 125 ;;;          (logand (, B) (, D))
 126 ;;;          (logand (, C) (, D)))))
 127 ;;; a little optimization from GnuPG/cipher/sha1.c.
 128   (defmacro sha1-F2 (B C D)
 129     (` (logior (logand (, B) (, C))
 130                (logand (, D) (logior (, B) (, C))))))
 131   (defmacro sha1-F3 (B C D)
 132     (` (logxor (, B) (, C) (, D))))
 133
 134   (defmacro sha1-S1  (W-high W-low)
 135     (` (let ((W-high (, W-high))
 136              (W-low  (, W-low)))
 137          (setq S1W-high (+ (% (* W-high 2) 65536)
 138                            (/ W-low (, (/ 65536 2)))))
 139          (setq S1W-low (+ (/ W-high (, (/ 65536 2)))
 140                           (% (* W-low 2) 65536))))))
 141   (defmacro sha1-S5  (A-high A-low)
 142     (` (progn
 143          (setq S5A-high (+ (% (* (, A-high) 32) 65536)
 144                            (/ (, A-low) (, (/ 65536 32)))))
 145          (setq S5A-low  (+ (/ (, A-high) (, (/ 65536 32)))
 146                            (% (* (, A-low) 32) 65536))))))
 147   (defmacro sha1-S30 (B-high B-low)
 148     (` (progn
 149          (setq S30B-high (+ (/ (, B-high) 4)
 150                             (* (% (, B-low) 4) (, (/ 65536 4)))))
 151          (setq S30B-low  (+ (/ (, B-low) 4)
 152                             (* (% (, B-high) 4) (, (/ 65536 4))))))))
 153
 154   (defmacro sha1-OP (round)
 155     (` (progn
 156          (sha1-S5 sha1-A-high sha1-A-low)
 157          (sha1-S30 sha1-B-high sha1-B-low)
 158          (setq sha1-A-low (+ ((, (intern (format "sha1-F%d" round)))
 159                               sha1-B-low sha1-C-low sha1-D-low)
 160                              sha1-E-low
 161                              (, (symbol-value
 162                                  (intern (format "sha1-K%d-low" round))))
 163                              (aref block-low idx)
 164                              (progn
 165                                (setq sha1-E-low sha1-D-low)
 166                                (setq sha1-D-low sha1-C-low)
 167                                (setq sha1-C-low S30B-low)
 168                                (setq sha1-B-low sha1-A-low)
 169                                S5A-low)))
 170          (setq carry (/ sha1-A-low 65536))
 171          (setq sha1-A-low (% sha1-A-low 65536))
 172          (setq sha1-A-high (% (+ ((, (intern (format "sha1-F%d" round)))
 173                                   sha1-B-high sha1-C-high sha1-D-high)
 174                                  sha1-E-high
 175                                  (, (symbol-value
 176                                      (intern (format "sha1-K%d-high" round))))
 177                                  (aref block-high idx)
 178                                  (progn
 179                                    (setq sha1-E-high sha1-D-high)
 180                                    (setq sha1-D-high sha1-C-high)
 181                                    (setq sha1-C-high S30B-high)
 182                                    (setq sha1-B-high sha1-A-high)
 183                                    S5A-high)
 184                                  carry)
 185                               65536)))))
 186
 187   (defmacro sha1-add-to-H (H X)
 188     (` (progn
 189          (setq (, (intern (format "sha1-%s-low" H)))
 190                (+ (, (intern (format "sha1-%s-low" H)))
 191                   (, (intern (format "sha1-%s-low" X)))))
 192          (setq carry (/ (, (intern (format "sha1-%s-low" H))) 65536))
 193          (setq (, (intern (format "sha1-%s-low" H)))
 194                (% (, (intern (format "sha1-%s-low" H))) 65536))
 195          (setq (, (intern (format "sha1-%s-high" H)))
 196                (% (+ (, (intern (format "sha1-%s-high" H)))
 197                      (, (intern (format "sha1-%s-high" X)))
 198                      carry)
 199                   65536)))))
 200   )
 201
 202 ;;; buffers (H0 H1 H2 H3 H4).
 203 (defvar sha1-H0-high)
 204 (defvar sha1-H0-low)
 205 (defvar sha1-H1-high)
 206 (defvar sha1-H1-low)
 207 (defvar sha1-H2-high)
 208 (defvar sha1-H2-low)
 209 (defvar sha1-H3-high)
 210 (defvar sha1-H3-low)
 211 (defvar sha1-H4-high)
 212 (defvar sha1-H4-low)
 213
 214 (defun sha1-block (block-high block-low)
 215   (let (;; step (c) --- initialize buffers (A B C D E).
 216         (sha1-A-high sha1-H0-high) (sha1-A-low sha1-H0-low)
 217         (sha1-B-high sha1-H1-high) (sha1-B-low sha1-H1-low)
 218         (sha1-C-high sha1-H2-high) (sha1-C-low sha1-H2-low)
 219         (sha1-D-high sha1-H3-high) (sha1-D-low sha1-H3-low)
 220         (sha1-E-high sha1-H4-high) (sha1-E-low sha1-H4-low)
 221         (idx 16))
 222     ;; step (b).
 223     (let (;; temporary variables used in sha1-S1 macro.
 224           S1W-high S1W-low)
 225       (while (< idx 80)
 226         (sha1-S1 (logxor (aref block-high (- idx 3))
 227                          (aref block-high (- idx 8))
 228                          (aref block-high (- idx 14))
 229                          (aref block-high (- idx 16)))
 230                  (logxor (aref block-low  (- idx 3))
 231                          (aref block-low  (- idx 8))
 232                          (aref block-low  (- idx 14))
 233                          (aref block-low  (- idx 16))))
 234         (aset block-high idx S1W-high)
 235         (aset block-low  idx S1W-low)
 236         (setq idx (1+ idx))))
 237     ;; step (d).
 238     (setq idx 0)
 239     (let (;; temporary variables used in sha1-OP macro.
 240           S5A-high S5A-low S30B-high S30B-low carry)
 241       (while (< idx 20) (sha1-OP 0) (setq idx (1+ idx)))
 242       (while (< idx 40) (sha1-OP 1) (setq idx (1+ idx)))
 243       (while (< idx 60) (sha1-OP 2) (setq idx (1+ idx)))
 244       (while (< idx 80) (sha1-OP 3) (setq idx (1+ idx))))
 245     ;; step (e).
 246     (let (;; temporary variables used in sha1-add-to-H macro.
 247           carry)
 248       (sha1-add-to-H H0 A)
 249       (sha1-add-to-H H1 B)
 250       (sha1-add-to-H H2 C)
 251       (sha1-add-to-H H3 D)
 252       (sha1-add-to-H H4 E))))
 253
 254 (defun sha1-binary (string)
 255   "Return the SHA1 of STRING in binary form."
 256   (let (;; prepare buffers for a block. byte-length of block is 64.
 257         ;; input block is split into two vectors.
 258         ;;
 259         ;; input block: 00 01 02 03 04 05 06 07 08 09 0A 0B 0C 0D 0E 0F ...
 260         ;; block-high:  +-0-+       +-1-+       +-2-+       +-3-+
 261         ;; block-low:         +-0-+       +-1-+       +-2-+       +-3-+
 262         ;;
 263         ;; length of each vector is 80, and elements of each vector are
 264         ;; 16bit integers.  elements 0x10-0x4F of each vector are
 265         ;; assigned later in `sha1-block'.
 266         (block-high (eval-when-compile (make-vector 80 nil)))
 267         (block-low  (eval-when-compile (make-vector 80 nil))))
 268     (unwind-protect
 269         (let* (;; byte-length of input string.
 270                (len (length string))
 271                (lim (* (/ len 64) 64))
 272                (rem (% len 4))
 273                (idx 0)(pos 0))
 274           ;; initialize buffers (H0 H1 H2 H3 H4).
 275           (setq sha1-H0-high 26437      ; (string-to-number "6745" 16)
 276                 sha1-H0-low  8961       ; (string-to-number "2301" 16)
 277                 sha1-H1-high 61389      ; (string-to-number "EFCD" 16)
 278                 sha1-H1-low  43913      ; (string-to-number "AB89" 16)
 279                 sha1-H2-high 39098      ; (string-to-number "98BA" 16)
 280                 sha1-H2-low  56574      ; (string-to-number "DCFE" 16)
 281                 sha1-H3-high 4146       ; (string-to-number "1032" 16)
 282                 sha1-H3-low  21622      ; (string-to-number "5476" 16)
 283                 sha1-H4-high 50130      ; (string-to-number "C3D2" 16)
 284                 sha1-H4-low  57840)     ; (string-to-number "E1F0" 16)
 285           ;; loop for each 64 bytes block.
 286           (while (< pos lim)
 287             ;; step (a).
 288             (setq idx 0)
 289             (while (< idx 16)
 290               (aset block-high idx (+ (* (aref string pos) 256)
 291                                       (aref string (1+ pos))))
 292               (setq pos (+ pos 2))
 293               (aset block-low  idx (+ (* (aref string pos) 256)
 294                                       (aref string (1+ pos))))
 295               (setq pos (+ pos 2))
 296               (setq idx (1+ idx)))
 297             (sha1-block block-high block-low))
 298           ;; last block.
 299           (if (prog1
 300                   (< (- len lim) 56)
 301                 (setq lim (- len rem))
 302                 (setq idx 0)
 303                 (while (< pos lim)
 304                   (aset block-high idx (+ (* (aref string pos) 256)
 305                                           (aref string (1+ pos))))
 306                   (setq pos (+ pos 2))
 307                   (aset block-low  idx (+ (* (aref string pos) 256)
 308                                           (aref string (1+ pos))))
 309                   (setq pos (+ pos 2))
 310                   (setq idx (1+ idx)))
 311                 ;; this is the last (at most) 32bit word.
 312                 (cond
 313                  ((= rem 3)
 314                   (aset block-high idx (+ (* (aref string pos) 256)
 315                                           (aref string (1+ pos))))
 316                   (setq pos (+ pos 2))
 317                   (aset block-low  idx (+ (* (aref string pos) 256)
 318                                           128)))
 319                  ((= rem 2)
 320                   (aset block-high idx (+ (* (aref string pos) 256)
 321                                           (aref string (1+ pos))))
 322                   (aset block-low  idx 32768))
 323                  ((= rem 1)
 324                   (aset block-high idx (+ (* (aref string pos) 256)
 325                                           128))
 326                   (aset block-low  idx 0))
 327                  (t ;; (= rem 0)
 328                   (aset block-high idx 32768)
 329                   (aset block-low  idx 0)))
 330                 (setq idx (1+ idx))
 331                 (while (< idx 16)
 332                   (aset block-high idx 0)
 333                   (aset block-low  idx 0)
 334                   (setq idx (1+ idx))))
 335               ;; last block has enough room to write the length of string.
 336               (progn
 337                 ;; write bit length of string to last 4 bytes of the block.
 338                 (aset block-low  15 (* (% len 8192) 8))
 339                 (setq len (/ len 8192))
 340                 (aset block-high 15 (% len 65536))
 341                 ;; XXX: It is not practical to compute SHA1 of
 342                 ;;      such a huge message on emacs.
 343                 ;; (setq len (/ len 65536))     ; for 64bit emacs.
 344                 ;; (aset block-low  14 (% len 65536))
 345                 ;; (aset block-high 14 (/ len 65536))
 346                 (sha1-block block-high block-low))
 347             ;; need one more block.
 348             (sha1-block block-high block-low)
 349             (fillarray block-high 0)
 350             (fillarray block-low  0)
 351             ;; write bit length of string to last 4 bytes of the block.
 352             (aset block-low  15 (* (% len 8192) 8))
 353             (setq len (/ len 8192))
 354             (aset block-high 15 (% len 65536))
 355             ;; XXX: It is not practical to compute SHA1 of
 356             ;;      such a huge message on emacs.
 357             ;; (setq len (/ len 65536))         ; for 64bit emacs.
 358             ;; (aset block-low  14 (% len 65536))
 359             ;; (aset block-high 14 (/ len 65536))
 360             (sha1-block block-high block-low))
 361           ;; make output string (in binary form).
 362           (let ((result (make-string 20 0)))
 363             (aset result  0 (/ sha1-H0-high 256))
 364             (aset result  1 (% sha1-H0-high 256))
 365             (aset result  2 (/ sha1-H0-low  256))
 366             (aset result  3 (% sha1-H0-low  256))
 367             (aset result  4 (/ sha1-H1-high 256))
 368             (aset result  5 (% sha1-H1-high 256))
 369             (aset result  6 (/ sha1-H1-low  256))
 370             (aset result  7 (% sha1-H1-low  256))
 371             (aset result  8 (/ sha1-H2-high 256))
 372             (aset result  9 (% sha1-H2-high 256))
 373             (aset result 10 (/ sha1-H2-low  256))
 374             (aset result 11 (% sha1-H2-low  256))
 375             (aset result 12 (/ sha1-H3-high 256))
 376             (aset result 13 (% sha1-H3-high 256))
 377             (aset result 14 (/ sha1-H3-low  256))
 378             (aset result 15 (% sha1-H3-low  256))
 379             (aset result 16 (/ sha1-H4-high 256))
 380             (aset result 17 (% sha1-H4-high 256))
 381             (aset result 18 (/ sha1-H4-low  256))
 382             (aset result 19 (% sha1-H4-low  256))
 383             result))
 384       ;; do not leave a copy of input string.
 385       (fillarray block-high nil)
 386       (fillarray block-low  nil))))
 387
 388 (defun sha1-string-internal (string)
 389   (encode-hex-string (sha1-binary string)))
 390
 391 (defun sha1-region-internal (beg end)
 392   (sha1-string-internal (buffer-substring-no-properties beg end)))
 393
 394 ;;;
 395 ;;; application interface.
 396 ;;;
 397
 398 (defun sha1-region (beg end)
 399   (if (and sha1-maximum-internal-length
 400            (> (abs (- end beg)) sha1-maximum-internal-length))
 401       (sha1-region-external beg end)
 402     (sha1-region-internal beg end)))
 403
 404 (defun sha1-string (string)
 405   (if (and sha1-maximum-internal-length
 406            (> (length string) sha1-maximum-internal-length))
 407       (sha1-string-external string)
 408     (sha1-string-internal string)))
 409
 410 (defun sha1 (object &optional beg end)
 411   "Return the SHA1 (Secure Hash Algorithm) of an object.
 412 OBJECT is either a string or a buffer.
 413 Optional arguments BEG and END denote buffer positions for computing the
 414 hash of a portion of OBJECT."
 415   (if (stringp object)
 416       (sha1-string object)
 417     (save-excursion
 418       (set-buffer object)
 419       (sha1-region (or beg (point-min)) (or end (point-max))))))
 420
 421 (provide 'sha1-el)
 422
 423 ;;; sha1-el.el ends here