lisp/riece-log.el

   1 ;;; riece-log.el --- Save IRC logs
   2 ;; Copyright (C) 2003 OHASHI Akira
   3 ;; Copyright (C) 2004 Daiki Ueno
   4
   5 ;; Author: OHASHI Akira <bg66@koka-in.org>
   6 ;;      Daiki Ueno <ueno@unixuser.org>
   7 ;; Keywords: IRC, riece
   8
   9 ;; This file is part of Riece.
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; NOTE: This is an add-on module for Riece.
  29
  30 ;;; Code:
  31
  32 (require 'riece-message)
  33 (require 'riece-button)
  34 (require 'riece-mcat)
  35
  36 (defgroup riece-log nil
  37   "Save IRC logs."
  38   :prefix "riece-"
  39   :group 'riece)
  40
  41 (defcustom riece-log-directory
  42   (expand-file-name "log" riece-directory)
  43   "*Where to look for log files."
  44   :type 'directory
  45   :group 'riece-log)
  46
  47 (defcustom riece-log-directory-map nil
  48   "*The map of channel name and directory name."
  49   :type '(repeat (cons (string :tag "Channel name")
  50                        (string :tag "Directory name")))
  51   :group 'riece-log)
  52
  53 (defcustom riece-log-flashback 10
  54   "*If non-nil, irc messages flash back from log files.
  55 If integer, flash back only this line numbers. t means all lines."
  56   :type '(choice (integer :tag "line numbers")
  57                  (const t :tag "of the day")
  58                  (const nil :tag "no flashback"))
  59   :group 'riece-log)
  60
  61 (defcustom riece-log-coding-system nil
  62   "*Coding system used for log files."
  63   :type 'symbol
  64   :group 'riece-log)
  65
  66 (defcustom riece-log-file-name-coding-system
  67   (if (boundp 'file-name-coding-system)
  68       file-name-coding-system)
  69   "*Coding system used for filenames of log files."
  70   :type 'symbol
  71   :group 'riece-log)
  72
  73 (defface riece-log-date-face
  74   '((((class color)
  75       (background dark))
  76      (:foreground "Gray70"))
  77     (((class color)
  78       (background light))
  79      (:foreground "DimGray"))
  80     (t
  81      (:bold t)))
  82   "Face used for displaying \"(YYYY/MM/dd)\" extent."
  83   :group 'riece-highlight-faces)
  84 (defvar riece-log-date-face 'riece-log-date-face)
  85
  86 (defvar riece-log-lock-file nil
  87   "Lock file for riece-log.
  88 It is created if there is at least one instance of Emacs running riece-log.")
  89
  90 (defconst riece-log-file-name-regexp
  91   (concat (riece-make-interval-regexp "[0-9]" 8) "\\.txt\\(\\.\\(.*\\)\\)?$"))
  92
  93 (defconst riece-log-description
  94   "Save IRC logs.")
  95
  96 (defun riece-log-display-message-function (message)
  97   (if (get 'riece-log 'riece-addon-enabled)
  98       (let* ((coding-system-for-write
  99               (if (featurep 'mule)
 100                   (or riece-log-coding-system
 101                       (car (get-language-info current-language-environment
 102                                               'coding-system)))))
 103              (file (riece-log-make-file-name (riece-message-target message)
 104                                              coding-system-for-write))
 105              file-name-coding-system
 106              default-file-name-coding-system)
 107         (unless (file-directory-p (file-name-directory file))
 108           (make-directory (file-name-directory file) t))
 109         (let ((format-message-function
 110                (or (cdr (assq (riece-message-type message)
 111                               riece-message-format-function-alist))
 112                    #'riece-format-message)))
 113           (write-region (concat (format-time-string "%H:%M") " "
 114                                 (funcall format-message-function message))
 115                         nil file t 0
 116                         riece-log-lock-file)))))
 117
 118 (defun riece-log-make-file-name (identity coding-system)
 119   (expand-file-name (if (featurep 'mule)
 120                         (format "%s.txt.%s"
 121                                 (format-time-string "%Y%m%d")
 122                                 coding-system)
 123                       (format "%s.txt"
 124                                 (format-time-string "%Y%m%d")))
 125                     (riece-log-directory identity)))
 126
 127 (defun riece-log-list-files (identity time)
 128   (let ((directory (riece-log-directory identity))
 129         (time-prefix (format-time-string "%Y%m%d" (or time '(0 0))))
 130         files)
 131     (when (file-directory-p directory)
 132       (setq files (nreverse (sort (directory-files
 133                                    directory t
 134                                    (concat "^" riece-log-file-name-regexp)
 135                                    t)
 136                                   #'string-lessp)))
 137       (while (and files
 138                   (string-lessp (file-name-nondirectory (car files))
 139                                 time-prefix))
 140         (setq files (cdr files)))
 141       files)))
 142
 143 (defun riece-log-directory (identity)
 144   (let ((prefix (riece-identity-canonicalize-prefix
 145                  (riece-identity-prefix identity)))
 146         (server (riece-identity-server identity))
 147         (map (assoc (riece-format-identity identity) riece-log-directory-map)))
 148     (if map
 149         (expand-file-name (cdr map) riece-log-directory)
 150       (expand-file-name (riece-log-encode-file-name prefix)
 151                         (expand-file-name
 152                          (concat "." (riece-log-encode-file-name server))
 153                          riece-log-directory)))))
 154
 155 (defun riece-log-encode-file-name (file-name)
 156   (if riece-log-file-name-coding-system
 157       (setq file-name
 158             (encode-coding-string file-name
 159                                   riece-log-file-name-coding-system)))
 160   (let ((index 0)
 161         c)
 162     (while (string-match "[^-0-9A-Za-z_\x80-\xFF]" file-name index)
 163       (setq c (aref file-name (match-beginning 0)))
 164       (if (eq c ?=)
 165           (setq file-name (replace-match "==" nil t file-name)
 166                 index (1+ (match-end 0)))
 167         (setq file-name (replace-match (format "=%02X" c) nil t file-name)
 168               index (+ 2 (match-end 0)))))
 169     file-name))
 170
 171 (defun riece-log-decode-file-name (file-name)
 172   (let ((index 0))
 173     (while (string-match "==\\|=\\([0-7][0-9A-F]\\)" file-name index)
 174       (setq file-name (replace-match
 175                        (if (eq (aref file-name (1- (match-end 0))) ?=)
 176                            "="
 177                          (char-to-string
 178                           (car (read-from-string
 179                                 (concat "?\\x" (match-string 1 file-name))))))
 180                        nil t file-name)
 181             index (1+ (match-beginning 0))))
 182     file-name)
 183   (if riece-log-file-name-coding-system
 184       (setq file-name
 185             (decode-coding-string file-name
 186                                   riece-log-file-name-coding-system)))
 187   file-name)
 188
 189 (defun riece-log-insert (identity lines)
 190   "Insert logs for IDENTITY at most LINES.
 191 If LINES is t, insert today's logs entirely."
 192   (let* (file-name-coding-system
 193          default-file-name-coding-system
 194          (files (riece-log-list-files identity
 195                                       (if (eq lines t) (current-time))))
 196          name coding-system date point)
 197     (while (and (or (eq lines t) (> lines 0)) files)
 198       (save-restriction
 199         (narrow-to-region (point) (point))
 200         (if (and (string-match
 201                   (concat "^" riece-log-file-name-regexp)
 202                   (setq name (file-name-nondirectory (car files))))
 203                  (match-beginning 2))
 204             (progn
 205               (setq coding-system
 206                     (intern (substring name (match-beginning 2))))
 207               (if (featurep 'xemacs)
 208                   (setq coding-system (find-coding-system coding-system))
 209                 (unless (coding-system-p coding-system)
 210                   (setq coding-system nil)))
 211               (if coding-system
 212                   (let ((coding-system-for-read coding-system))
 213                     (insert-file-contents (car files)))
 214                 ;;don't insert file contents if they use non
 215                 ;;supported coding-system.
 216                 ))
 217           ;;if the filename has no coding-system suffix, decode with
 218           ;;riece-log-coding-system.
 219           (let ((coding-system-for-read riece-log-coding-system))
 220             (insert-file-contents (car files))))
 221         ;;lines in the file contents are in reversed order.
 222         (unless (eq lines t)
 223           (goto-char (point-max))
 224           (setq lines (- (forward-line (- lines))))
 225           (delete-region (point-min) (point)))
 226         ;;add (YYYY/MM/dd) suffix on each line left in the current buffer.
 227         (unless (equal (substring name 0 8) (format-time-string "%Y%m%d"))
 228           (setq date (concat " (" (substring name 0 4) "/"
 229                              (substring name 4 6) "/"
 230                              (substring name 6 8) ")"))
 231           (while (not (eobp))
 232             (end-of-line)
 233             (setq point (point))
 234             (insert date)
 235             (put-text-property point (point)
 236                                'riece-overlay-face 'riece-log-date-face)
 237             (forward-line))
 238           (goto-char (point-min))))
 239       (setq files (cdr files)))))
 240
 241 (defun riece-log-flashback (identity)
 242   (when riece-log-flashback
 243     (riece-insert-info (current-buffer)
 244                        (if (eq riece-log-flashback t)
 245                            (riece-mcat "Recent messages of the day:\n")
 246                          (format (riece-mcat
 247                                   "Recent messages up to %d lines:\n")
 248                                  riece-log-flashback)))
 249     (let (buffer-read-only
 250           (point (goto-char (point-max))))
 251       (insert (with-temp-buffer
 252                 (riece-log-insert identity riece-log-flashback)
 253                 (buffer-string)))
 254       (goto-char point)
 255       (while (re-search-forward
 256               (concat "^" riece-time-prefix-regexp
 257                        "\\(<[^>]+>\\|>[^<]+<\\|([^)]+)\\|{[^}]+}\\|=[^=]+=\\)")
 258               nil t)
 259         (put-text-property (1+ (match-beginning 1)) (1- (match-end 1))
 260                            'riece-identity
 261                            (riece-make-identity
 262                             (buffer-substring (1+ (match-beginning 1))
 263                                               (1- (match-end 1)))
 264                             (riece-identity-server identity))))
 265       (run-hook-with-args 'riece-after-insert-functions
 266                           point (goto-char (point-max)))
 267       (set-window-point (get-buffer-window (current-buffer))
 268                         (point)))))
 269
 270 (defun riece-log-dired (&optional channel)
 271   (interactive)
 272   (let ((directory (riece-log-directory (or channel riece-current-channel))))
 273     (if (file-directory-p directory)
 274         (dired directory)
 275       (error "No log directory"))))
 276
 277 (defun riece-log-requires ()
 278   (if (memq 'riece-button riece-addons)
 279       '(riece-button)))
 280
 281 (defun riece-log-insinuate ()
 282   (make-directory riece-log-directory t)
 283   (setq riece-log-lock-file
 284         (expand-file-name (format "!%s-%d-%d"
 285                                   (riece-log-encode-file-name (system-name))
 286                                   (user-uid)
 287                                   (emacs-pid))
 288                           riece-log-directory))
 289   ;; FIXME: Use `riece-after-insert-functions' for trapping change,
 290   ;; notice, wallops and so on. But must add argument.
 291   (add-hook 'riece-after-display-message-functions
 292             'riece-log-display-message-function)
 293   (add-hook 'riece-channel-buffer-create-functions
 294             'riece-log-flashback))
 295
 296 (defun riece-log-uninstall ()
 297   (setq riece-log-lock-file nil)
 298   (remove-hook 'riece-after-display-message-functions
 299                'riece-log-display-message-function)
 300   (remove-hook 'riece-channel-buffer-create-functions
 301                'riece-log-flashback))
 302
 303 (defvar riece-command-mode-map)
 304 (defun riece-log-enable ()
 305   (define-key riece-command-mode-map "\C-cd" 'riece-log-dired))
 306
 307 (defun riece-log-disable ()
 308   (define-key riece-command-mode-map "\C-cd" nil))
 309
 310 (provide 'riece-log)
 311
 312 ;;; riece-log.el ends here