lisp/riece-mcat.el

   1 ;;; riece-mcat.el --- message catalog
   2 ;; Copyright (C) 2007 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5
   6 ;; This file is part of Riece.
   7
   8 ;; This program is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; This program is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  21 ;; Boston, MA 02110-1301, USA.
  22
  23 ;;; Code:
  24
  25 (require 'pp)
  26
  27 (defun riece-mcat (string)
  28   "Translate STRING in the current language environment."
  29   (let ((feature (if (featurep 'mule)
  30                      (get-language-info current-language-environment
  31                                         'riece-mcat-feature))))
  32     (if feature
  33         (progn
  34           (require feature)
  35           (or (cdr (assoc string
  36                           (symbol-value
  37                            (intern (concat (symbol-name feature) "-alist")))))
  38               string))
  39       string)))
  40
  41 (defun riece-mcat-extract-from-form (form)
  42   (if (and form (listp form) (listp (cdr form)))
  43       (if (eq (car form) 'riece-mcat)
  44           (cdr form)
  45         (delq nil (apply #'nconc
  46                          (mapcar #'riece-mcat-extract-from-form form))))))
  47
  48 (defun riece-mcat-extract (files)
  49   (save-excursion
  50     (let (message-list pointer)
  51       (while files
  52         (with-temp-buffer
  53           (insert-file-contents (car files))
  54           (goto-char (point-min))
  55           (while (progn
  56                    (while (progn (skip-chars-forward " \t\n\f")
  57                                  (looking-at ";"))
  58                      (forward-line 1))
  59                    (not (eobp)))
  60             (setq message-list
  61                   (nconc message-list
  62                          (riece-mcat-extract-from-form
  63                           (read (current-buffer)))))))
  64         (setq files (cdr files)))
  65       (setq message-list (sort message-list #'string-lessp)
  66             pointer message-list)
  67       (while pointer
  68         (if (member (car pointer) (cdr pointer))
  69             (setcar pointer nil))
  70         (setq pointer (cdr pointer)))
  71       (delq nil message-list))))
  72
  73 (defun riece-mcat-update (files mcat-file mcat-alist-symbol)
  74   "Update MCAT-FILE."
  75   (let ((pp-escape-newlines t)
  76         alist)
  77     (save-excursion
  78       (set-buffer (find-file-noselect mcat-file))
  79       (goto-char (point-min))
  80       (if (re-search-forward (concat "^\\s-*(\\(defvar\\|defconst\\)\\s-+"
  81                                      (regexp-quote (symbol-name
  82                                                     mcat-alist-symbol)))
  83                              nil t)
  84           (progn
  85             (goto-char (match-beginning 0))
  86             (save-excursion
  87               (eval (read (current-buffer))))
  88             (delete-region (point) (progn (forward-sexp) (point))))
  89         (set mcat-alist-symbol nil))
  90       (setq alist (mapcar (lambda (message)
  91                             (or (assoc message
  92                                        (symbol-value mcat-alist-symbol))
  93                                 (list message)))
  94                           (riece-mcat-extract files)))
  95       (insert "(defconst " (symbol-name mcat-alist-symbol) "\n  '(")
  96       (while alist
  97         (insert "(" (pp-to-string (car (car alist))) " . "
  98                 (pp-to-string (cdr (car alist))) ")")
  99         (if (cdr alist)
 100             (insert "\n    "))
 101         (setq alist (cdr alist)))
 102       (insert "))")
 103       (save-buffer))))
 104
 105 (defconst riece-mcat-description "Translate messages")
 106
 107 (defun riece-mcat-insinuate ()
 108   (set-language-info "Japanese" 'riece-mcat-feature 'riece-mcat-japanese))
 109
 110 (defun riece-mcat-uninstall ()
 111   (set-language-info "Japanese" 'riece-mcat-feature nil))
 112
 113 (provide 'riece-mcat)
 114
 115 ;;; riece-mcat.el ends here