AC_INIT(starttls.el)
AM_INIT_AUTOMAKE(starttls, 0.5)

AM_PATH_LISPDIR

AC_PROG_CC
AC_ISC_POSIX
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AC_PROG_RANLIB

AC_CHECK_HEADERS(libgen.h sys/select.h socks.h)

AC_CHECK_LIB(nsl, gethostbyname)
AC_CHECK_LIB(socket, socket)
AC_CHECK_TYPE(fd_set, int)
AC_REPLACE_FUNCS(basename getaddrinfo)

AC_CACHE_CHECK([for struct addrinfo], ac_cv_struct_addrinfo,
[AC_TRY_COMPILE([#include <netdb.h>
], [struct addrinfo a],
ac_cv_struct_addrinfo=yes, ac_cv_struct_addrinfo=no)])
if test "$ac_cv_struct_addrinfo" = "yes"; then
	AC_DEFINE(HAVE_ADDRINFO)
else
	AC_DEFINE(NEED_ADDRINFO_H)
fi

AC_CACHE_CHECK([for NI_MAXSERV], ac_cv_ni_maxserv,
[AC_EGREP_CPP(yes, [#include <netdb.h>
#ifdef NI_MAXSERV
yes
#endif
], ac_cv_ni_maxserv=yes, ac_cv_ni_maxserv=no)])
test "$ac_cv_ni_maxserv" = "yes" || AC_DEFINE(NEED_ADDRINFO_H)

AC_CACHE_CHECK([for NI_NOFQDN], ac_cv_ni_nofqdn,
[AC_EGREP_CPP(yes, [#include <netdb.h>
#ifdef NI_NOFQDN
yes
#endif
], ac_cv_ni_nofqdn=yes, ac_cv_ni_nofqdn=no)])
test "$ac_cv_ni_nofqdn" = "yes" || AC_DEFINE(NEED_ADDRINFO_H)

AC_ARG_WITH(openssl,[  --with-openssl=PATH     use OpenSSL from PATH])

if test -n "$with_openssl"; then
	CPPFLAGS="${CPPFLAGS} -I${with_openssl}/include"
	LDFLAGS="${LDFLAGS} -L${with_openssl}/lib"
fi

AC_CHECK_HEADER(openssl/ssl.h, [
	AC_CHECK_LIB(crypto, BIO_accept, LIBS="-lcrypto ${LIBS}")
	AC_CHECK_LIB(ssl, SSL_CTX_new, LIBS="-lssl ${LIBS}")],
	AC_MSG_ERROR([OpenSSL not installed - please install first]))

AC_OUTPUT(Makefile)