git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2005
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Katsumi Yamaoka <yamaoka@jpl.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (eval-when-compile
  32   (autoload 'gnus-active "gnus" nil nil 'macro)
  33   (autoload 'gnus-group-entry "gnus" nil nil 'macro)
  34   (autoload 'gnus-info-level "gnus" nil nil 'macro)
  35   (autoload 'gnus-info-marks "gnus" nil nil 'macro)
  36   (autoload 'gnus-info-method "gnus" nil nil 'macro)
  37   (autoload 'gnus-info-score "gnus" nil nil 'macro))
  38
  39 (require 'text-props)
  40 (defvar menu-bar-mode (featurep 'menubar))
  41 (require 'messagexmas)
  42 (require 'wid-edit)
  43 (require 'timer-funcs)
  44
  45 (defgroup gnus-xmas nil
  46   "XEmacsoid support for Gnus"
  47   :group 'gnus)
  48
  49 (defcustom gnus-xmas-glyph-directory nil
  50   "Directory where Gnus logos and icons are located.
  51 If this variable is nil, Gnus will try to locate the directory
  52 automatically."
  53   :type '(choice (const :tag "autodetect" nil)
  54                  directory)
  55   :group 'gnus-xmas)
  56
  57 (unless gnus-xmas-glyph-directory
  58   (unless (setq gnus-xmas-glyph-directory
  59                 (message-xmas-find-glyph-directory "gnus"))
  60     (error "Can't find glyph directory. \
  61 Possibly the `etc' directory has not been installed.")))
  62
  63 ;;; Internal variables.
  64
  65 ;; Don't warn about these undefined variables.
  66
  67 ;;defined in gnus.el
  68 (defvar gnus-active-hashtb)
  69 (defvar gnus-article-buffer)
  70 (defvar gnus-auto-center-summary)
  71 (defvar gnus-current-headers)
  72 (defvar gnus-level-killed)
  73 (defvar gnus-level-zombie)
  74 (defvar gnus-newsgroup-bookmarks)
  75 (defvar gnus-newsgroup-dependencies)
  76 (defvar gnus-newsgroup-selected-overlay)
  77 (defvar gnus-newsrc-hashtb)
  78 (defvar gnus-read-mark)
  79 (defvar gnus-refer-article-method)
  80 (defvar gnus-reffed-article-number)
  81 (defvar gnus-unread-mark)
  82 (defvar gnus-version)
  83 (defvar gnus-view-pseudos)
  84 (defvar gnus-view-pseudos-separately)
  85 (defvar gnus-visual)
  86 (defvar gnus-zombie-list)
  87 ;;defined in gnus-msg.el
  88 (defvar gnus-article-copy)
  89 (defvar gnus-check-before-posting)
  90 ;;defined in gnus-vis.el
  91 (defvar gnus-article-button-face)
  92 (defvar gnus-article-mouse-face)
  93 (defvar gnus-summary-selected-face)
  94 (defvar gnus-group-reading-menu)
  95 (defvar gnus-group-group-menu)
  96 (defvar gnus-group-misc-menu)
  97 (defvar gnus-summary-article-menu)
  98 (defvar gnus-summary-thread-menu)
  99 (defvar gnus-summary-misc-menu)
 100 (defvar gnus-summary-post-menu)
 101 (defvar gnus-summary-kill-menu)
 102 (defvar gnus-article-article-menu)
 103 (defvar gnus-article-treatment-menu)
 104 (defvar gnus-mouse-2)
 105 (defvar standard-display-table)
 106 (defvar gnus-tree-minimize-window)
 107
 108 (defun gnus-xmas-highlight-selected-summary ()
 109   ;; Highlight selected article in summary buffer
 110   (when gnus-summary-selected-face
 111     (when gnus-newsgroup-selected-overlay
 112       (delete-extent gnus-newsgroup-selected-overlay))
 113     (setq gnus-newsgroup-selected-overlay
 114           (make-extent (point-at-bol) (point-at-eol)))
 115     (set-extent-face gnus-newsgroup-selected-overlay
 116                      gnus-summary-selected-face)))
 117
 118 (defcustom gnus-xmas-force-redisplay nil
 119   "*If non-nil, force a redisplay before recentering the summary buffer.
 120 This is ugly, but it works around a bug in `window-displayed-height'."
 121   :type 'boolean
 122   :group 'gnus-xmas)
 123
 124 (defun gnus-xmas-switch-horizontal-scrollbar-off ()
 125   (when (featurep 'scrollbar)
 126     (set-specifier scrollbar-height (cons (current-buffer) 0))))
 127
 128 (defun gnus-xmas-summary-recenter ()
 129   "\"Center\" point in the summary window.
 130 If `gnus-auto-center-summary' is nil, or the article buffer isn't
 131 displayed, no centering will be performed."
 132   ;; Suggested by earle@mahendo.JPL.NASA.GOV (Greg Earle).
 133   ;; Recenter only when requested.  Suggested by popovich@park.cs.columbia.edu.
 134   ;; Force redisplay to get properly computed window height.
 135   (when gnus-xmas-force-redisplay
 136     (sit-for 0))
 137   (when gnus-auto-center-summary
 138     (let* ((height (if (fboundp 'window-displayed-height)
 139                        (window-displayed-height)
 140                      (- (window-height) 2)))
 141            (top (cond ((< height 4) 0)
 142                       ((< height 7) 1)
 143                       (t (if (numberp gnus-auto-center-summary)
 144                              gnus-auto-center-summary
 145                            2))))
 146            (bottom (save-excursion (goto-char (point-max))
 147                                    (forward-line (- height))
 148                                    (point)))
 149            (window (get-buffer-window (current-buffer))))
 150       (when (get-buffer-window gnus-article-buffer)
 151         ;; Only do recentering when the article buffer is displayed,
 152         ;; Set the window start to either `bottom', which is the biggest
 153         ;; possible valid number, or the second line from the top,
 154         ;; whichever is the least.
 155         ;; NOFORCE parameter suggested by Daniel Pittman <daniel@danann.net>.
 156         (set-window-start
 157          window (min bottom (save-excursion (forward-line (- top)) (point)))
 158          t))
 159       ;; Do horizontal recentering while we're at it.
 160       (when (and (get-buffer-window (current-buffer) t)
 161                  (not (eq gnus-auto-center-summary 'vertical)))
 162         (let ((selected (selected-window)))
 163           (select-window (get-buffer-window (current-buffer) t))
 164           (gnus-summary-position-point)
 165           (gnus-horizontal-recenter)
 166           (select-window selected))))))
 167
 168 (defun gnus-xmas-summary-set-display-table ()
 169   ;; Setup the display table -- like `gnus-summary-setup-display-table',
 170   ;; but done in an XEmacsish way.
 171   (let ((table (make-display-table))
 172         (i 32))
 173     ;; Nix out all the control chars...
 174     (while (>= (setq i (1- i)) 0)
 175       (aset table i [??]))
 176     ;; ... but not newline and cr, of course.  (cr is necessary for the
 177     ;; selective display).
 178     (aset table ?\n nil)
 179     (aset table ?\r nil)
 180     ;; We keep TAB as well.
 181     (aset table ?\t nil)
 182     ;; We nix out any glyphs over 126 below ctl-arrow.
 183     (let ((i (if (integerp ctl-arrow) ctl-arrow 160)))
 184       (while (>= (setq i (1- i)) 127)
 185         (unless (aref table i)
 186           (aset table i [??]))))
 187     ;; Can't use `set-specifier' because of a bug in 19.14 and earlier
 188     (add-spec-to-specifier current-display-table table (current-buffer) nil)))
 189
 190 (defun gnus-xmas-add-text-properties (start end props &optional object)
 191   (add-text-properties start end props object)
 192   (put-text-property start end 'start-closed nil object))
 193
 194 (defun gnus-xmas-put-text-property (start end prop value &optional object)
 195   (put-text-property start end prop value object)
 196   (put-text-property start end 'start-closed nil object))
 197
 198 (defun gnus-xmas-extent-start-open (point)
 199   (map-extents (lambda (extent arg)
 200                  (set-extent-property extent 'start-open t))
 201                nil point (min (1+ (point)) (point-max))))
 202
 203 (defun gnus-xmas-article-push-button (event)
 204   "Check text under the mouse pointer for a callback function.
 205 If the text under the mouse pointer has a `gnus-callback' property,
 206 call it with the value of the `gnus-data' text property."
 207   (interactive "e")
 208   (set-buffer (window-buffer (event-window event)))
 209   (let* ((pos (event-closest-point event))
 210          (data (get-text-property pos 'gnus-data))
 211          (fun (get-text-property pos 'gnus-callback)))
 212     (goto-char pos)
 213     (when fun
 214       (funcall fun data))))
 215
 216 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 217   (set-extent-endpoints extent start end buffer))
 218
 219 (defun gnus-xmas-kill-all-overlays ()
 220   "Delete all extents in the current buffer."
 221   (map-extents (lambda (extent ignore)
 222                  (delete-extent extent)
 223                  nil)))
 224
 225 (defun gnus-xmas-window-top-edge (&optional window)
 226   (nth 1 (window-pixel-edges window)))
 227
 228 (defun gnus-xmas-tree-minimize ()
 229   (when (and gnus-tree-minimize-window
 230              (not (one-window-p)))
 231     (let* ((window-min-height 2)
 232            (height (1+ (count-lines (point-min) (point-max))))
 233            (min (max (1- window-min-height) height))
 234            (tot (if (numberp gnus-tree-minimize-window)
 235                     (min gnus-tree-minimize-window min)
 236                   min))
 237            (win (get-buffer-window (current-buffer)))
 238            (wh (and win (1- (window-height win)))))
 239       (when (and win
 240                  (not (eq tot wh)))
 241         (let ((selected (selected-window)))
 242           (select-window win)
 243           (enlarge-window (- tot wh))
 244           (select-window selected))))))
 245
 246 ;; Select the lowest window on the frame.
 247 (defun gnus-xmas-select-lowest-window ()
 248   (let* ((lowest-window (selected-window))
 249          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 250          (last-window (previous-window))
 251          (window-search t))
 252     (while window-search
 253       (let* ((this-window (next-window))
 254              (next-bottom-edge (car (cdr (cdr (cdr
 255                                                (window-pixel-edges
 256                                                 this-window)))))))
 257         (when (< bottom-edge next-bottom-edge)
 258           (setq bottom-edge next-bottom-edge)
 259           (setq lowest-window this-window))
 260
 261         (select-window this-window)
 262         (when (eq last-window this-window)
 263           (select-window lowest-window)
 264           (setq window-search nil))))))
 265
 266 (defmacro gnus-xmas-menu-add (type &rest menus)
 267   `(gnus-xmas-menu-add-1 ',type ',menus))
 268 (put 'gnus-xmas-menu-add 'lisp-indent-function 1)
 269
 270 (defun gnus-xmas-menu-add-1 (type menus)
 271   (when (and menu-bar-mode
 272              (gnus-visual-p (intern (format "%s-menu" type)) 'menu))
 273     (while menus
 274       (easy-menu-add (symbol-value (pop menus))))))
 275
 276 (defun gnus-xmas-group-menu-add ()
 277   (gnus-xmas-menu-add group
 278     gnus-group-reading-menu gnus-group-group-menu gnus-group-misc-menu))
 279
 280 (defun gnus-xmas-summary-menu-add ()
 281   (gnus-xmas-menu-add summary
 282     gnus-summary-misc-menu gnus-summary-kill-menu
 283     gnus-summary-article-menu gnus-summary-thread-menu
 284     gnus-summary-post-menu ))
 285
 286 (defun gnus-xmas-article-menu-add ()
 287   (gnus-xmas-menu-add article
 288     gnus-article-article-menu gnus-article-treatment-menu
 289     gnus-article-post-menu gnus-article-commands-menu))
 290
 291 (defun gnus-xmas-score-menu-add ()
 292   (gnus-xmas-menu-add score
 293     gnus-score-menu))
 294
 295 (defun gnus-xmas-pick-menu-add ()
 296   (gnus-xmas-menu-add pick
 297     gnus-pick-menu))
 298
 299 (defun gnus-xmas-topic-menu-add ()
 300   (gnus-xmas-menu-add topic
 301     gnus-topic-menu))
 302
 303 (defun gnus-xmas-binary-menu-add ()
 304   (gnus-xmas-menu-add binary
 305     gnus-binary-menu))
 306
 307 (defun gnus-xmas-agent-summary-menu-add ()
 308   (gnus-xmas-menu-add agent-summary
 309     gnus-agent-summary-menu))
 310
 311 (defun gnus-xmas-agent-group-menu-add ()
 312   (gnus-xmas-menu-add agent-group
 313     gnus-agent-group-menu))
 314
 315 (defun gnus-xmas-agent-server-menu-add ()
 316   (gnus-xmas-menu-add agent-server
 317     gnus-agent-server-menu))
 318
 319 (defun gnus-xmas-tree-menu-add ()
 320   (gnus-xmas-menu-add tree
 321     gnus-tree-menu))
 322
 323 (defun gnus-xmas-draft-menu-add ()
 324   (gnus-xmas-menu-add draft
 325     gnus-draft-menu))
 326
 327 (defun gnus-xmas-server-menu-add ()
 328   (gnus-xmas-menu-add menu
 329     gnus-server-server-menu gnus-server-connections-menu))
 330
 331 (defun gnus-xmas-browse-menu-add ()
 332   (gnus-xmas-menu-add browse
 333     gnus-browse-menu))
 334
 335 (defun gnus-xmas-read-event-char (&optional prompt)
 336   "Get the next event."
 337   (when prompt
 338     (message "%s" prompt))
 339   (let ((event (next-command-event)))
 340     (sit-for 0)
 341     ;; We junk all non-key events.  Is this naughty?
 342     (while (not (or (key-press-event-p event)
 343                     (button-press-event-p event)))
 344       (dispatch-event event)
 345       (setq event (next-command-event)))
 346     (cons (and (key-press-event-p event)
 347                (event-to-character event))
 348           event)))
 349
 350 (defun gnus-xmas-define ()
 351   (setq gnus-mouse-2 [button2])
 352   (setq gnus-mouse-3 [button3])
 353   (setq gnus-widget-button-keymap widget-button-keymap)
 354
 355   (unless (memq 'underline (face-list))
 356     (and (fboundp 'make-face)
 357          (funcall (intern "make-face") 'underline)))
 358   ;; Must avoid calling set-face-underline-p directly, because it
 359   ;; is a defsubst in emacs19, and will make the .elc files non
 360   ;; portable!
 361   (unless (face-differs-from-default-p 'underline)
 362     (funcall (intern "set-face-underline-p") 'underline t))
 363
 364   (cond
 365    ((fboundp 'char-or-char-int-p)
 366     ;; Handle both types of marks for XEmacs-20.x.
 367     (defalias 'gnus-characterp 'char-or-char-int-p))
 368    ;; V19 of XEmacs, probably.
 369    (t
 370     (defalias 'gnus-characterp 'characterp)))
 371
 372   (defalias 'gnus-make-overlay 'make-extent)
 373   (defalias 'gnus-delete-overlay 'delete-extent)
 374   (defalias 'gnus-overlay-put 'set-extent-property)
 375   (defalias 'gnus-move-overlay 'gnus-xmas-move-overlay)
 376   (defalias 'gnus-overlay-buffer 'extent-object)
 377   (defalias 'gnus-overlay-start 'extent-start-position)
 378   (defalias 'gnus-overlay-end 'extent-end-position)
 379   (defalias 'gnus-kill-all-overlays 'gnus-xmas-kill-all-overlays)
 380   (defalias 'gnus-extent-detached-p 'extent-detached-p)
 381   (defalias 'gnus-add-text-properties 'gnus-xmas-add-text-properties)
 382   (defalias 'gnus-put-text-property 'gnus-xmas-put-text-property)
 383   (defalias 'gnus-deactivate-mark 'ignore)
 384   (defalias 'gnus-window-edges 'window-pixel-edges)
 385   (defalias 'gnus-assq-delete-all 'gnus-xmas-assq-delete-all)
 386
 387   (unless (boundp 'standard-display-table)
 388     (setq standard-display-table nil))
 389
 390   (defvar gnus-mouse-face-prop 'highlight)
 391
 392   (defun gnus-byte-code (func)
 393     "Return a form that can be `eval'ed based on FUNC."
 394     (let ((fval (indirect-function func)))
 395       (if (compiled-function-p fval)
 396           (list 'funcall fval)
 397         (cons 'progn (cdr (cdr fval))))))
 398
 399   (defalias 'gnus-x-color-values
 400     (if (fboundp 'x-color-values)
 401         'x-color-values
 402       (lambda (color)
 403         (color-instance-rgb-components
 404          (make-color-instance color)))))
 405
 406   (unless (fboundp 'char-width)
 407     (defalias 'char-width (lambda (ch) 1))))
 408
 409 (defun gnus-xmas-redefine ()
 410   "Redefine lots of Gnus functions for XEmacs."
 411   (defalias 'gnus-summary-set-display-table 'gnus-xmas-summary-set-display-table)
 412   (defalias 'gnus-visual-turn-off-edit-menu 'identity)
 413   (defalias 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 414   (defalias 'gnus-extent-start-open 'gnus-xmas-extent-start-open)
 415   (defalias 'gnus-article-push-button 'gnus-xmas-article-push-button)
 416   (defalias 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 417   (defalias 'gnus-read-event-char 'gnus-xmas-read-event-char)
 418   (defalias 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 419   (defalias 'gnus-tree-minimize 'gnus-xmas-tree-minimize)
 420   (defalias 'gnus-select-lowest-window
 421     'gnus-xmas-select-lowest-window)
 422   (defalias 'gnus-mail-strip-quoted-names 'gnus-xmas-mail-strip-quoted-names)
 423   (defalias 'gnus-character-to-event 'character-to-event)
 424   (defalias 'gnus-mode-line-buffer-identification
 425     'gnus-xmas-mode-line-buffer-identification)
 426   (defalias 'gnus-key-press-event-p 'key-press-event-p)
 427   (defalias 'gnus-region-active-p 'region-active-p)
 428   (defalias 'gnus-mark-active-p 'region-exists-p)
 429   (defalias 'gnus-annotation-in-region-p 'gnus-xmas-annotation-in-region-p)
 430   (defalias 'gnus-mime-button-menu 'gnus-xmas-mime-button-menu)
 431   (defalias 'gnus-image-type-available-p 'gnus-xmas-image-type-available-p)
 432   (defalias 'gnus-put-image 'gnus-xmas-put-image)
 433   (defalias 'gnus-create-image 'gnus-xmas-create-image)
 434   (defalias 'gnus-remove-image 'gnus-xmas-remove-image)
 435
 436   ;; These ones are not defcutom'ed, sometimes not even defvar'ed. They
 437   ;; probably should. If that is done, the code below should then be moved
 438   ;; where each variable is defined, in order not to mess with user settings.
 439   ;; -- didier
 440   (add-hook 'gnus-score-mode-hook 'gnus-xmas-score-menu-add)
 441   (add-hook 'gnus-binary-mode-hook 'gnus-xmas-binary-menu-add)
 442   (add-hook 'gnus-server-mode-hook 'gnus-xmas-server-menu-add)
 443   (add-hook 'gnus-browse-mode-hook 'gnus-xmas-browse-menu-add)
 444   (add-hook 'gnus-draft-mode-hook 'gnus-xmas-draft-menu-add)
 445   (add-hook 'gnus-mailing-list-mode-hook 'gnus-xmas-mailing-list-menu-add)
 446
 447   (when (featurep 'mule)
 448     (defun gnus-truncate-string (str end-column &optional start-column padding)
 449       "Truncate string STR to end at column END-COLUMN.
 450 The optional 2nd arg START-COLUMN, if non-nil, specifies
 451 the starting column; that means to return the characters occupying
 452 columns START-COLUMN ... END-COLUMN of STR.
 453
 454 The optional 3rd arg PADDING, if non-nil, specifies a padding character
 455 to add at the end of the result if STR doesn't reach column END-COLUMN,
 456 or if END-COLUMN comes in the middle of a character in STR.
 457 PADDING is also added at the beginning of the result
 458 if column START-COLUMN appears in the middle of a character in STR.
 459
 460 If PADDING is nil, no padding is added in these cases, so
 461 the resulting string may be narrower than END-COLUMN.
 462 \[Emacs 20.3 emulating function]"
 463       (or start-column
 464           (setq start-column 0))
 465       (let ((len (length str))
 466             (idx 0)
 467             (column 0)
 468             (head-padding "") (tail-padding "")
 469             ch last-column last-idx from-idx)
 470         (condition-case nil
 471             (while (< column start-column)
 472               (setq ch (aref str idx)
 473                     column (+ column (char-width ch))
 474                     idx (1+ idx)))
 475           (args-out-of-range (setq idx len)))
 476         (if (< column start-column)
 477             (if padding (make-string end-column padding) "")
 478           (if (and padding (> column start-column))
 479               (setq head-padding
 480                     (make-string (- column start-column) padding)))
 481           (setq from-idx idx)
 482           (if (< end-column column)
 483               (setq idx from-idx)
 484             (condition-case nil
 485                 (while (< column end-column)
 486                   (setq last-column column
 487                         last-idx idx
 488                         ch (aref str idx)
 489                         column (+ column (char-width ch))
 490                         idx (1+ idx)))
 491               (args-out-of-range (setq idx len)))
 492             (if (> column end-column)
 493                 (setq column last-column idx last-idx))
 494             (if (and padding (< column end-column))
 495                 (setq tail-padding
 496                       (make-string (- end-column column) padding))))
 497           (setq str (substring str from-idx idx))
 498           (if padding
 499               (concat head-padding str tail-padding)
 500             str))))))
 501
 502 ;;; XEmacs logo and toolbar.
 503
 504 (defun gnus-xmas-group-startup-message (&optional x y)
 505   "Insert startup message in current buffer."
 506   ;; Insert the message.
 507   (erase-buffer)
 508   (cond
 509    ((and (console-on-window-system-p)
 510          (or (featurep 'xpm)
 511              (featurep 'xbm)))
 512     (let* ((logo-xpm (expand-file-name "gnus.xpm" gnus-xmas-glyph-directory))
 513            (logo-xbm (expand-file-name "gnus.xbm" gnus-xmas-glyph-directory))
 514            (glyph (make-glyph
 515                    (cond ((featurep 'xpm)
 516                           `[xpm
 517                             :file ,logo-xpm
 518                             :color-symbols
 519                             (("thing" . ,(car gnus-logo-colors))
 520                              ("shadow" . ,(cadr gnus-logo-colors))
 521                              ("oort" . "#eeeeee")
 522                              ("background" . ,(face-background 'default)))])
 523                          ((featurep 'xbm)
 524                           `[xbm :file ,logo-xbm])
 525                          (t [nothing]))))
 526            (wpheight (window-pixel-height))
 527            (rest (max 0 (1- (/ (* (- wpheight (glyph-height glyph))
 528                                   (window-height))
 529                                wpheight 2)))))
 530       (insert " ")
 531       (set-extent-begin-glyph (make-extent (point) (point)) glyph)
 532       (goto-char (point-min))
 533       (while (not (eobp))
 534         (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 535                              ?\ ))
 536         (forward-line 1))
 537       (setq gnus-simple-splash nil)
 538       (goto-char (point-min))
 539       (insert gnus-product-name " " gnus-version-number
 540               (if (zerop (string-to-number gnus-revision-number))
 541                   ""
 542                 (concat " (r" gnus-revision-number ")"))
 543               " based on " gnus-original-product-name " v"
 544               gnus-original-version-number "\n")
 545       (end-of-line 0)
 546       (put-text-property (point-min) (point) 'face 'gnus-splash)
 547       (insert-char ?\  (prog1
 548                            (max 0 (/ (- (window-width) (point)) 2))
 549                          (goto-char (point-min))))
 550       (forward-line 1)
 551       (insert-char ?\n rest)
 552       (set-window-start (selected-window) (point-min))))
 553    (t
 554     (insert "
 555           _    ___ _             _
 556           _ ___ __ ___  __    _ ___
 557           __   _     ___    __  ___
 558               _           ___     _
 559              _  _ __             _
 560              ___   __            _
 561                    __           _
 562                     _      _   _
 563                    _      _    _
 564                       _  _    _
 565                   __  ___
 566                  _   _ _     _
 567                 _   _
 568               _    _
 569              _    _
 570             _
 571           __
 572
 573 "
 574             )
 575     (goto-char (point-min))
 576     (insert gnus-product-name " " gnus-version-number
 577             (if (zerop (string-to-number gnus-revision-number))
 578                 ""
 579               (concat " (r" gnus-revision-number ")"))
 580             " based on " gnus-original-product-name " v"
 581             gnus-original-version-number)
 582     (insert-char ?\  (prog1
 583                          (max 0 (/ (- (window-width) (point)) 2))
 584                        (goto-char (point-min))))
 585     (forward-line 1)
 586     ;; And then hack it.
 587     (gnus-indent-rigidly (point) (point-max)
 588                          (/ (max (- (window-width) (or x 46)) 0) 2))
 589     (goto-char (point-min))
 590     (forward-line 1)
 591     (let* ((pheight (count-lines (point-min) (point-max)))
 592            (wheight (window-height))
 593            (rest (- wheight pheight)))
 594       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n)))
 595     ;; Paint it.
 596     (put-text-property (point-min) (point-max) 'face 'gnus-splash)))
 597   (goto-char (point-min))
 598   (setq modeline-buffer-identification
 599         (list (concat gnus-version ": *Group*")))
 600   (set-buffer-modified-p t))
 601
 602
 603 ;;; The toolbar.
 604
 605 (defun gnus-xmas-update-toolbars ()
 606   "Update the toolbars' appearance."
 607   (when (and (not noninteractive)
 608              (featurep 'gnus-xmas))
 609     (save-excursion
 610       (dolist (buffer (buffer-list))
 611         (set-buffer buffer)
 612         (cond ((eq major-mode 'gnus-group-mode)
 613                (gnus-xmas-setup-group-toolbar))
 614               ((eq major-mode 'gnus-summary-mode)
 615                (gnus-xmas-setup-summary-toolbar)))))))
 616
 617 (defcustom gnus-use-toolbar (if (featurep 'toolbar) 'default)
 618   "*Position to display the toolbar.  Nil means do not use a toolbar.
 619 If it is non-nil, it should be one of the symbols `default', `top',
 620 `bottom', `right', and `left'.  `default' means to use the default
 621 toolbar, the rest mean to display the toolbar on the place which those
 622 names show."
 623   :type '(choice (const default)
 624                  (const top) (const bottom) (const left) (const right)
 625                  (const :tag "no toolbar" nil))
 626   :set (lambda (symbol value)
 627          (set-default
 628           symbol
 629           (if (or (not value)
 630                   (memq value (list 'default 'top 'bottom 'right 'left)))
 631               value
 632             'default))
 633          (gnus-xmas-update-toolbars))
 634   :group 'gnus-xmas)
 635
 636 (defcustom gnus-toolbar-thickness
 637   (if (featurep 'toolbar)
 638       (cons (specifier-instance default-toolbar-height)
 639             (specifier-instance default-toolbar-width)))
 640   "*Cons of the height and the width specifying the thickness of a toolbar.
 641 The height is used for the toolbar displayed on the top or the bottom,
 642 the width is used for the toolbar displayed on the right or the left."
 643   :type '(cons :tag "height & width"
 644                (integer :tag "height") (integer :tag "width"))
 645   :set (lambda (symbol value)
 646          (set-default
 647           symbol
 648           (if (and (consp value) (natnump (car value)) (natnump (cdr value)))
 649               value
 650             '(37 . 40)))
 651          (gnus-xmas-update-toolbars))
 652   :group 'gnus-xmas)
 653
 654 (defvar gnus-group-toolbar
 655   '([gnus-group-get-new-news gnus-group-get-new-news t "Get new news"]
 656     [gnus-group-get-new-news-this-group
 657      gnus-group-get-new-news-this-group t "Get new news in this group"]
 658     [gnus-group-catchup-current
 659      gnus-group-catchup-current t "Catchup group"]
 660     [gnus-group-describe-group
 661      gnus-group-describe-group t "Describe group"]
 662     [gnus-group-unsubscribe gnus-group-unsubscribe t "Unsubscribe group"]
 663     [gnus-group-subscribe gnus-group-subscribe t "Subscribe group"]
 664     [gnus-group-kill-group gnus-group-kill-group t "Kill group"]
 665     [gnus-summary-mail-save
 666      gnus-group-save-newsrc t "Save .newsrc files"] ; borrowed icon.
 667     [gnus-group-exit gnus-group-exit t "Exit Gnus"])
 668   "The group buffer toolbar.")
 669
 670 (defvar gnus-summary-toolbar
 671   '([gnus-summary-prev-unread
 672      gnus-summary-prev-page-or-article t "Page up"]
 673     [gnus-summary-next-unread
 674      gnus-summary-next-page t "Page down"]
 675     [gnus-summary-post-news
 676      gnus-summary-post-news t "Post an article"]
 677     [gnus-summary-followup-with-original
 678      gnus-summary-followup-with-original t
 679      "Post a followup and yank the original"]
 680     [gnus-summary-followup
 681      gnus-summary-followup t "Post a followup"]
 682     [gnus-summary-reply-with-original
 683      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 684     [gnus-summary-reply
 685      gnus-summary-reply t "Mail a reply"]
 686     [gnus-summary-caesar-message
 687      gnus-summary-caesar-message t "Rot 13"]
 688     [gnus-uu-decode-uu
 689      gnus-uu-decode-uu t "Decode uuencoded articles"]
 690     [gnus-summary-save-article-file
 691      gnus-summary-save-article-file t "Save article in file"]
 692     [gnus-summary-save-article
 693      gnus-summary-save-article t "Save article"]
 694     [gnus-uu-post-news
 695      gnus-uu-post-news t "Post a uuencoded article"]
 696     [gnus-summary-cancel-article
 697      gnus-summary-cancel-article t "Cancel article"]
 698     [gnus-summary-catchup
 699      gnus-summary-catchup t "Catchup"]
 700     [gnus-summary-catchup-and-exit
 701      gnus-summary-catchup-and-exit t "Catchup and exit"]
 702     [gnus-summary-exit gnus-summary-exit t "Exit this summary"])
 703   "The summary buffer toolbar.")
 704
 705 (defvar gnus-summary-mail-toolbar
 706   '(
 707     [gnus-summary-prev-unread
 708      gnus-summary-prev-unread-article t "Prev unread article"]
 709     [gnus-summary-next-unread
 710      gnus-summary-next-unread-article t "Next unread article"]
 711     [gnus-summary-mail-reply gnus-summary-reply t "Reply"]
 712     [gnus-summary-mail-originate gnus-summary-post-news t "Originate"]
 713     [gnus-summary-mail-save gnus-summary-save-article t "Save"]
 714     [gnus-summary-mail-copy gnus-summary-copy-article t "Copy message"]
 715     [gnus-summary-mail-forward gnus-summary-mail-forward t "Forward message"]
 716     [gnus-summary-caesar-message
 717      gnus-summary-caesar-message t "Rot 13"]
 718     [gnus-uu-decode-uu
 719      gnus-uu-decode-uu t "Decode uuencoded articles"]
 720     [gnus-summary-save-article-file
 721      gnus-summary-save-article-file t "Save article in file"]
 722     [gnus-summary-save-article
 723      gnus-summary-save-article t "Save article"]
 724     [gnus-summary-cancel-article ; usenet : cancellation :: mail : deletion.
 725      gnus-summary-delete-article t "Delete message"]
 726     [gnus-summary-catchup
 727      gnus-summary-catchup t "Catchup"]
 728     [gnus-summary-catchup-and-exit
 729      gnus-summary-catchup-and-exit t "Catchup and exit"]
 730     [gnus-summary-exit gnus-summary-exit t "Exit this summary"])
 731   "The summary buffer mail toolbar.")
 732
 733 (defun gnus-xmas-setup-toolbar (toolbar)
 734   (when (featurep 'toolbar)
 735     (if (and gnus-use-toolbar
 736              (message-xmas-setup-toolbar toolbar nil "gnus"))
 737         (let ((bar (or (intern-soft (format "%s-toolbar" gnus-use-toolbar))
 738                        'default-toolbar))
 739               (height (car gnus-toolbar-thickness))
 740               (width (cdr gnus-toolbar-thickness))
 741               (cur (current-buffer))
 742               bars)
 743           (set-specifier (symbol-value bar) toolbar cur)
 744           (set-specifier default-toolbar-height height cur)
 745           (set-specifier default-toolbar-width width cur)
 746           (set-specifier top-toolbar-height height cur)
 747           (set-specifier bottom-toolbar-height height cur)
 748           (set-specifier right-toolbar-width width cur)
 749           (set-specifier left-toolbar-width width cur)
 750           (if (eq bar 'default-toolbar)
 751               (progn
 752                 (remove-specifier default-toolbar-visible-p cur)
 753                 (remove-specifier top-toolbar cur)
 754                 (remove-specifier top-toolbar-visible-p cur)
 755                 (remove-specifier bottom-toolbar cur)
 756                 (remove-specifier bottom-toolbar-visible-p cur)
 757                 (remove-specifier right-toolbar cur)
 758                 (remove-specifier right-toolbar-visible-p cur)
 759                 (remove-specifier left-toolbar cur)
 760                 (remove-specifier left-toolbar-visible-p cur))
 761             (set-specifier (symbol-value (intern (format "%s-visible-p" bar)))
 762                            t cur)
 763             (setq bars (delq bar (list 'default-toolbar
 764                                        'bottom-toolbar 'top-toolbar
 765                                        'right-toolbar 'left-toolbar)))
 766             (while bars
 767               (set-specifier (symbol-value (intern (format "%s-visible-p"
 768                                                            (pop bars))))
 769                              nil cur))))
 770       (let ((cur (current-buffer)))
 771         (set-specifier default-toolbar-visible-p nil cur)
 772         (set-specifier top-toolbar-visible-p nil cur)
 773         (set-specifier bottom-toolbar-visible-p nil cur)
 774         (set-specifier right-toolbar-visible-p nil cur)
 775         (set-specifier left-toolbar-visible-p nil cur)))))
 776
 777 (defun gnus-xmas-setup-group-toolbar ()
 778   (gnus-xmas-setup-toolbar gnus-group-toolbar))
 779
 780 (defun gnus-xmas-setup-summary-toolbar ()
 781   (gnus-xmas-setup-toolbar (if (gnus-news-group-p gnus-newsgroup-name)
 782                                gnus-summary-toolbar
 783                              gnus-summary-mail-toolbar)))
 784
 785 (defun gnus-xmas-mail-strip-quoted-names (address)
 786   "Protect mail-strip-quoted-names from nil input.
 787 XEmacs compatibility workaround."
 788   (if (null address)
 789       nil
 790     (mail-strip-quoted-names address)))
 791
 792 (defun gnus-xmas-call-region (command &rest args)
 793   (apply
 794    'call-process-region (point-min) (point-max) command t '(t nil) nil
 795    args))
 796
 797 (defvar gnus-xmas-modeline-left-extent
 798   (let ((ext (copy-extent modeline-buffer-id-left-extent)))
 799     ext))
 800
 801 (defvar gnus-xmas-modeline-right-extent
 802   (let ((ext (copy-extent modeline-buffer-id-right-extent)))
 803     ext))
 804
 805 (defvar gnus-xmas-modeline-glyph
 806   (progn
 807     (let* ((file-xpm (expand-file-name "gnus-pointer.xpm"
 808                                        gnus-xmas-glyph-directory))
 809            (file-xbm (expand-file-name "gnus-pointer.xbm"
 810                                        gnus-xmas-glyph-directory))
 811            (glyph (make-glyph
 812                    ;; Gag gag gag.
 813                    (cond ((featurep 'xpm)
 814                           ;; Let's try a nifty XPM
 815                           `[xpm :file ,file-xpm])
 816                          ((featurep 'xbm)
 817                           ;; Then a not-so-nifty XBM
 818                           `[xbm :file ,file-xbm])
 819                          ;; Then the simple string
 820                          (t [string :data "Gnus:"])))))
 821       (set-glyph-face glyph 'modeline-buffer-id)
 822       glyph)))
 823
 824 (defun gnus-xmas-mode-line-buffer-identification (line)
 825   (let ((line (car line))
 826         chop)
 827     (cond
 828      ;; This is some weird type of id.
 829      ((not (stringp line))
 830       (list line))
 831      ;; This is non-standard, so we just pass it through.
 832      ((not (string-match "^Gnus:" line))
 833       (list line))
 834      ;; We have a standard line, so we colorize and glyphize it a bit.
 835      (t
 836       (setq chop (match-end 0))
 837       (list
 838        (if gnus-xmas-modeline-glyph
 839            (cons gnus-xmas-modeline-left-extent gnus-xmas-modeline-glyph)
 840          (cons gnus-xmas-modeline-left-extent (substring line 0 chop)))
 841        (cons gnus-xmas-modeline-right-extent (substring line chop)))))))
 842
 843 (defun gnus-xmas-splash ()
 844   (when (eq (device-type) 'x)
 845     (gnus-splash)))
 846
 847 (defun gnus-xmas-annotation-in-region-p (b e)
 848   (or (map-extents (lambda (e u) t) nil b e nil nil 'mm t)
 849       (if (= b e)
 850           (eq (cadr (memq 'gnus-undeletable (text-properties-at b))) t)
 851         (text-property-any b e 'gnus-undeletable t))))
 852
 853 (defun gnus-xmas-mime-button-menu (event prefix)
 854   "Construct a context-sensitive menu of MIME commands."
 855   (interactive "e\nP")
 856   (let ((response (get-popup-menu-response
 857                    `("MIME Part"
 858                      ,@(mapcar (lambda (c) `[,(caddr c) ,(car c) t])
 859                                gnus-mime-button-commands)))))
 860     (set-buffer (event-buffer event))
 861     (goto-char (event-point event))
 862     (funcall (event-function response) (event-object response))))
 863
 864 (defun gnus-group-add-icon ()
 865   "Add an icon to the current line according to `gnus-group-icon-list'."
 866   (let* ((p (point))
 867          (end (point-at-eol))
 868          ;; now find out where the line starts and leave point there.
 869          (beg (progn (beginning-of-line) (point))))
 870     (save-restriction
 871       (narrow-to-region beg end)
 872       (goto-char beg)
 873       (when (search-forward "==&&==" nil t)
 874         (let* ((group (gnus-group-group-name))
 875                (entry (gnus-group-entry group))
 876                (unread (if (numberp (car entry)) (car entry) 0))
 877                (active (gnus-active group))
 878                (total (if active (1+ (- (cdr active) (car active))) 0))
 879                (info (nth 2 entry))
 880                (method (gnus-server-get-method group (gnus-info-method info)))
 881                (marked (gnus-info-marks info))
 882                (mailp (memq 'mail (assoc (symbol-name
 883                                           (car (or method gnus-select-method)))
 884                                          gnus-valid-select-methods)))
 885                (level (or (gnus-info-level info) gnus-level-killed))
 886                (score (or (gnus-info-score info) 0))
 887                (ticked (gnus-range-length (cdr (assq 'tick marked))))
 888                (group-age (gnus-group-timestamp-delta group))
 889                (inhibit-read-only t)
 890                (list gnus-group-icon-list)
 891                (mystart (match-beginning 0))
 892                (myend (match-end 0)))
 893           (goto-char (point-min))
 894           (while (and list
 895                       (not (eval (caar list))))
 896             (setq list (cdr list)))
 897           (if list
 898               (let* ((file (cdar list))
 899                      (glyph (gnus-group-icon-create-glyph
 900                              (buffer-substring mystart myend)
 901                              file)))
 902                 (if glyph
 903                     (progn
 904                       (mapcar 'delete-annotation (annotations-at myend))
 905                       (let ((ext (make-extent mystart myend))
 906                             (ant (make-annotation glyph myend 'text)))
 907                         ;; set text extent params
 908                         (set-extent-property ext 'end-open t)
 909                         (set-extent-property ext 'start-open t)
 910                         (set-extent-property ext 'invisible t)))
 911                   (delete-region mystart myend)))
 912             (delete-region mystart myend))))
 913       (widen))
 914     (goto-char p)))
 915
 916 (defun gnus-group-icon-create-glyph (substring pixmap)
 917   "Create a glyph for insertion into a group line."
 918   (or
 919    (cdr-safe (assoc pixmap gnus-group-icon-cache))
 920    (let* ((glyph (make-glyph
 921                   (list
 922                    (cons 'x
 923                          (expand-file-name pixmap gnus-xmas-glyph-directory))
 924                    (cons 'mswindows
 925                          (expand-file-name pixmap gnus-xmas-glyph-directory))
 926                    (cons 'tty substring)))))
 927      (setq gnus-group-icon-cache
 928            (cons (cons pixmap glyph) gnus-group-icon-cache))
 929      (set-glyph-face glyph 'default)
 930      glyph)))
 931
 932 (defun gnus-xmas-mailing-list-menu-add ()
 933   (gnus-xmas-menu-add mailing-list
 934     gnus-mailing-list-menu))
 935
 936 (defun gnus-xmas-image-type-available-p (type)
 937   (and window-system
 938        (featurep (if (eq type 'pbm) 'xbm type))))
 939
 940 (defun gnus-xmas-create-image (file &optional type data-p &rest props)
 941   (let ((type (if type
 942                   (symbol-name type)
 943                 (car (last (split-string file "[.]")))))
 944         (face (plist-get props :face))
 945         glyph)
 946     (when (equal type "pbm")
 947       (with-temp-buffer
 948         (if data-p
 949             (insert file)
 950           (insert-file-contents-literally file))
 951         (shell-command-on-region (point-min) (point-max)
 952                                  "ppmtoxpm 2>/dev/null" t)
 953         (setq file (buffer-string)
 954               type "xpm"
 955               data-p t)))
 956     (setq glyph
 957           (if (equal type "xbm")
 958               (make-glyph (list (cons 'x file)))
 959             (with-temp-buffer
 960               (if data-p
 961                   (insert file)
 962                 (insert-file-contents-literally file))
 963               (make-glyph
 964                (vector
 965                 (or (intern type)
 966                     (mm-image-type-from-buffer))
 967                 :data (buffer-string))))))
 968     (when face
 969       (set-glyph-face glyph face))
 970     glyph))
 971
 972 (defun gnus-xmas-put-image (glyph &optional string category)
 973   "Insert STRING, but display GLYPH.
 974 Warning: Don't insert text immediately after the image."
 975   (let ((begin (point))
 976         extent)
 977     (if (and (bobp) (not string))
 978         (setq string " "))
 979     (if string
 980         (insert string)
 981       (setq begin (1- begin)))
 982     (setq extent (make-extent begin (point)))
 983     (set-extent-property extent 'gnus-image category)
 984     (set-extent-property extent 'duplicable t)
 985     (if string
 986         (set-extent-property extent 'invisible t))
 987     (set-extent-property extent 'end-glyph glyph))
 988   glyph)
 989
 990 (defun gnus-xmas-remove-image (image &optional category)
 991   "Remove the image matching IMAGE and CATEGORY found first."
 992   (map-extents
 993    (lambda (ext unused)
 994      (when (equal (extent-end-glyph ext) image)
 995        (set-extent-property ext 'invisible nil)
 996        (set-extent-property ext 'end-glyph nil)
 997        t))
 998    nil nil nil nil nil 'gnus-image category))
 999
1000 (defun gnus-xmas-assq-delete-all (key alist)
1001   (let ((elem nil))
1002     (while (setq elem (assq key alist))
1003       (setq alist (delq elem alist)))
1004     alist))
1005
1006 (provide 'gnus-xmas)
1007
1008 ;;; gnus-xmas.el ends here