git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'text-props)
  29 (defvar menu-bar-mode (featurep 'menubar))
  30 (require 'messagexmas)
  31
  32 (defgroup gnus-xmas nil
  33   "XEmacsoid support for Gnus"
  34   :group 'gnus)
  35
  36 (defcustom gnus-xmas-glyph-directory nil
  37   "Directory where Gnus logos and icons are located.
  38 If this variable is nil, Gnus will try to locate the directory
  39 automatically."
  40   :type '(choice (const :tag "autodetect" nil)
  41                  directory)
  42   :group 'gnus-xmas)
  43
  44 (defvar gnus-xmas-logo-color-alist
  45   '((flame "#cc3300" "#ff2200")
  46     (pine "#c0cc93" "#f8ffb8")
  47     (moss "#a1cc93" "#d2ffb8")
  48     (irish "#04cc90" "#05ff97")
  49     (sky "#049acc" "#05deff")
  50     (tin "#6886cc" "#82b6ff")
  51     (velvet "#7c68cc" "#8c82ff")
  52     (grape "#b264cc" "#cf7df")
  53     (labia "#cc64c2" "#fd7dff")
  54     (berry "#cc6485" "#ff7db5")
  55     (neutral "#b4b4b4" "#878787")
  56     (september "#bf9900" "#ffcc00"))
  57   "Color alist used for the Gnus logo.")
  58
  59 (defcustom gnus-xmas-logo-color-style 'moss
  60   "*Color styles used for the Gnus logo."
  61   :type '(choice (const flame) (const pine) (const moss)
  62                  (const irish) (const sky) (const tin)
  63                  (const velvet) (const grape) (const labia)
  64                  (const berry) (const neutral) (const september))
  65   :group 'gnus-xmas)
  66
  67 (defvar gnus-xmas-logo-colors
  68   (cdr (assq gnus-xmas-logo-color-style gnus-xmas-logo-color-alist))
  69   "Colors used for the Gnus logo.")
  70
  71 (defcustom gnus-article-x-face-command
  72   (if (or (featurep 'xface)
  73           (featurep 'xpm))
  74       'gnus-xmas-article-display-xface
  75     "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | xv -quit -")
  76   "*String or function to be executed to display an X-Face header.
  77 If it is a string, the command will be executed in a sub-shell
  78 asynchronously.  The compressed face will be piped to this command."
  79   :type '(choice string function))
  80
  81 ;;; Internal variables.
  82
  83 ;; Don't warn about these undefined variables.
  84
  85 (defvar gnus-group-mode-hook)
  86 (defvar gnus-summary-mode-hook)
  87 (defvar gnus-article-mode-hook)
  88
  89 ;;defined in gnus.el
  90 (defvar gnus-active-hashtb)
  91 (defvar gnus-article-buffer)
  92 (defvar gnus-auto-center-summary)
  93 (defvar gnus-current-headers)
  94 (defvar gnus-level-killed)
  95 (defvar gnus-level-zombie)
  96 (defvar gnus-newsgroup-bookmarks)
  97 (defvar gnus-newsgroup-dependencies)
  98 (defvar gnus-newsgroup-selected-overlay)
  99 (defvar gnus-newsrc-hashtb)
 100 (defvar gnus-read-mark)
 101 (defvar gnus-refer-article-method)
 102 (defvar gnus-reffed-article-number)
 103 (defvar gnus-unread-mark)
 104 (defvar gnus-version)
 105 (defvar gnus-view-pseudos)
 106 (defvar gnus-view-pseudos-separately)
 107 (defvar gnus-visual)
 108 (defvar gnus-zombie-list)
 109 ;;defined in gnus-msg.el
 110 (defvar gnus-article-copy)
 111 (defvar gnus-check-before-posting)
 112 ;;defined in gnus-vis.el
 113 (defvar gnus-article-button-face)
 114 (defvar gnus-article-mouse-face)
 115 (defvar gnus-summary-selected-face)
 116 (defvar gnus-group-reading-menu)
 117 (defvar gnus-group-group-menu)
 118 (defvar gnus-group-misc-menu)
 119 (defvar gnus-summary-article-menu)
 120 (defvar gnus-summary-thread-menu)
 121 (defvar gnus-summary-misc-menu)
 122 (defvar gnus-summary-post-menu)
 123 (defvar gnus-summary-kill-menu)
 124 (defvar gnus-article-article-menu)
 125 (defvar gnus-article-treatment-menu)
 126 (defvar gnus-mouse-2)
 127 (defvar standard-display-table)
 128 (defvar gnus-tree-minimize-window)
 129
 130 (defun gnus-xmas-set-text-properties (start end props &optional buffer)
 131   "You should NEVER use this function.  It is ideologically blasphemous.
 132 It is provided only to ease porting of broken FSF Emacs programs."
 133   (if (stringp buffer)
 134       nil
 135     (map-extents (lambda (extent ignored)
 136                    (remove-text-properties
 137                     start end
 138                     (list (extent-property extent 'text-prop) nil)
 139                     buffer)
 140                    nil)
 141                  buffer start end nil nil 'text-prop)
 142     (gnus-add-text-properties start end props buffer)))
 143
 144 (defun gnus-xmas-highlight-selected-summary ()
 145   ;; Highlight selected article in summary buffer
 146   (when gnus-summary-selected-face
 147     (when gnus-newsgroup-selected-overlay
 148       (delete-extent gnus-newsgroup-selected-overlay))
 149     (setq gnus-newsgroup-selected-overlay
 150           (make-extent (gnus-point-at-bol) (gnus-point-at-eol)))
 151     (set-extent-face gnus-newsgroup-selected-overlay
 152                      gnus-summary-selected-face)))
 153
 154 (defcustom gnus-xmas-force-redisplay nil
 155   "*If non-nil, force a redisplay before recentering the summary buffer.
 156 This is ugly, but it works around a bug in `window-displayed-height'."
 157   :type 'boolean
 158   :group 'gnus-xmas)
 159
 160 (defun gnus-xmas-switch-horizontal-scrollbar-off ()
 161   (when (featurep 'scrollbar)
 162     (set-specifier scrollbar-height (cons (current-buffer) 0))))
 163
 164 (defun gnus-xmas-summary-recenter ()
 165   "\"Center\" point in the summary window.
 166 If `gnus-auto-center-summary' is nil, or the article buffer isn't
 167 displayed, no centering will be performed."
 168   ;; Suggested by earle@mahendo.JPL.NASA.GOV (Greg Earle).
 169   ;; Recenter only when requested.  Suggested by popovich@park.cs.columbia.edu.
 170   ;; Force redisplay to get properly computed window height.
 171   (when gnus-xmas-force-redisplay
 172     (sit-for 0))
 173   (when gnus-auto-center-summary
 174     (let* ((height (if (fboundp 'window-displayed-height)
 175                        (window-displayed-height)
 176                      (- (window-height) 2)))
 177            (top (cond ((< height 4) 0)
 178                       ((< height 7) 1)
 179                       (t 2)))
 180            (bottom (save-excursion (goto-char (point-max))
 181                                    (forward-line (- height))
 182                                    (point)))
 183            (window (get-buffer-window (current-buffer))))
 184       (when (get-buffer-window gnus-article-buffer)
 185         ;; Only do recentering when the article buffer is displayed,
 186         ;; Set the window start to either `bottom', which is the biggest
 187         ;; possible valid number, or the second line from the top,
 188         ;; whichever is the least.
 189         (set-window-start
 190          window (min bottom (save-excursion (forward-line (- top)) (point)))))
 191       ;; Do horizontal recentering while we're at it.
 192       (when (and (get-buffer-window (current-buffer) t)
 193                  (not (eq gnus-auto-center-summary 'vertical)))
 194         (let ((selected (selected-window)))
 195           (select-window (get-buffer-window (current-buffer) t))
 196           (gnus-summary-position-point)
 197           (gnus-horizontal-recenter)
 198           (select-window selected))))))
 199
 200 (defun gnus-xmas-summary-set-display-table ()
 201   ;; Setup the display table -- like `gnus-summary-setup-display-table',
 202   ;; but done in an XEmacsish way.
 203   (let ((table (make-display-table))
 204         (i 32))
 205     ;; Nix out all the control chars...
 206     (while (>= (setq i (1- i)) 0)
 207       (aset table i [??]))
 208     ;; ... but not newline and cr, of course.  (cr is necessary for the
 209     ;; selective display).
 210     (aset table ?\n nil)
 211     (aset table ?\r nil)
 212     ;; We keep TAB as well.
 213     (aset table ?\t nil)
 214     ;; We nix out any glyphs over 126 below ctl-arrow.
 215     (let ((i (if (integerp ctl-arrow) ctl-arrow 160)))
 216       (while (>= (setq i (1- i)) 127)
 217         (unless (aref table i)
 218           (aset table i [??]))))
 219     ;; Can't use `set-specifier' because of a bug in 19.14 and earlier
 220     (add-spec-to-specifier current-display-table table (current-buffer) nil)))
 221
 222 (defun gnus-xmas-add-text-properties (start end props &optional object)
 223   (add-text-properties start end props object)
 224   (put-text-property start end 'start-closed nil object))
 225
 226 (defun gnus-xmas-put-text-property (start end prop value &optional object)
 227   (put-text-property start end prop value object)
 228   (put-text-property start end 'start-closed nil object))
 229
 230 (defun gnus-xmas-extent-start-open (point)
 231   (map-extents (lambda (extent arg)
 232                  (set-extent-property extent 'start-open t))
 233                nil point (min (1+ (point)) (point-max))))
 234
 235 (defun gnus-xmas-article-push-button (event)
 236   "Check text under the mouse pointer for a callback function.
 237 If the text under the mouse pointer has a `gnus-callback' property,
 238 call it with the value of the `gnus-data' text property."
 239   (interactive "e")
 240   (set-buffer (window-buffer (event-window event)))
 241   (let* ((pos (event-closest-point event))
 242          (data (get-text-property pos 'gnus-data))
 243          (fun (get-text-property pos 'gnus-callback)))
 244     (when fun
 245       (funcall fun data))))
 246
 247 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 248   (set-extent-endpoints extent start end buffer))
 249
 250 (defun gnus-xmas-kill-all-overlays ()
 251   "Delete all extents in the current buffer."
 252   (map-extents (lambda (extent ignore)
 253                  (delete-extent extent)
 254                  nil)))
 255
 256 ;; Fixed by Christopher Davis <ckd@loiosh.kei.com>.
 257 (defun gnus-xmas-article-add-button (from to fun &optional data)
 258   "Create a button between FROM and TO with callback FUN and data DATA."
 259   (when gnus-article-button-face
 260     (gnus-overlay-put (gnus-make-overlay from to)
 261                       'face gnus-article-button-face))
 262   (gnus-add-text-properties
 263    from to
 264    (nconc
 265     (and gnus-article-mouse-face
 266          (list 'mouse-face gnus-article-mouse-face))
 267     (list 'gnus-callback fun)
 268     (and data (list 'gnus-data data))
 269     (list 'highlight t))))
 270
 271 (defun gnus-xmas-window-top-edge (&optional window)
 272   (nth 1 (window-pixel-edges window)))
 273
 274 (defun gnus-xmas-tree-minimize ()
 275   (when (and gnus-tree-minimize-window
 276              (not (one-window-p)))
 277     (let* ((window-min-height 2)
 278            (height (1+ (count-lines (point-min) (point-max))))
 279            (min (max (1- window-min-height) height))
 280            (tot (if (numberp gnus-tree-minimize-window)
 281                     (min gnus-tree-minimize-window min)
 282                   min))
 283            (win (get-buffer-window (current-buffer)))
 284            (wh (and win (1- (window-height win)))))
 285       (when (and win
 286                  (not (eq tot wh)))
 287         (let ((selected (selected-window)))
 288           (select-window win)
 289           (enlarge-window (- tot wh))
 290           (select-window selected))))))
 291
 292 ;; Select the lowest window on the frame.
 293 (defun gnus-xmas-appt-select-lowest-window ()
 294   (let* ((lowest-window (selected-window))
 295          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 296          (last-window (previous-window))
 297          (window-search t))
 298     (while window-search
 299       (let* ((this-window (next-window))
 300              (next-bottom-edge (car (cdr (cdr (cdr
 301                                                (window-pixel-edges
 302                                                 this-window)))))))
 303         (when (< bottom-edge next-bottom-edge)
 304           (setq bottom-edge next-bottom-edge)
 305           (setq lowest-window this-window))
 306
 307         (select-window this-window)
 308         (when (eq last-window this-window)
 309           (select-window lowest-window)
 310           (setq window-search nil))))))
 311
 312 (defmacro gnus-xmas-menu-add (type &rest menus)
 313   `(gnus-xmas-menu-add-1 ',type ',menus))
 314 (put 'gnus-xmas-menu-add 'lisp-indent-function 1)
 315
 316 (defun gnus-xmas-menu-add-1 (type menus)
 317   (when (and menu-bar-mode
 318              (gnus-visual-p (intern (format "%s-menu" type)) 'menu))
 319     (while menus
 320       (easy-menu-add (symbol-value (pop menus))))))
 321
 322 (defun gnus-xmas-group-menu-add ()
 323   (gnus-xmas-menu-add group
 324     gnus-group-reading-menu gnus-group-group-menu gnus-group-misc-menu))
 325
 326 (defun gnus-xmas-summary-menu-add ()
 327   (gnus-xmas-menu-add summary
 328     gnus-summary-misc-menu gnus-summary-kill-menu
 329     gnus-summary-article-menu gnus-summary-thread-menu
 330     gnus-summary-post-menu ))
 331
 332 (defun gnus-xmas-article-menu-add ()
 333   (gnus-xmas-menu-add article
 334     gnus-article-article-menu gnus-article-treatment-menu))
 335
 336 (defun gnus-xmas-score-menu-add ()
 337   (gnus-xmas-menu-add score
 338     gnus-score-menu))
 339
 340 (defun gnus-xmas-pick-menu-add ()
 341   (gnus-xmas-menu-add pick
 342     gnus-pick-menu))
 343
 344 (defun gnus-xmas-topic-menu-add ()
 345   (gnus-xmas-menu-add topic
 346     gnus-topic-menu))
 347
 348 (defun gnus-xmas-binary-menu-add ()
 349   (gnus-xmas-menu-add binary
 350     gnus-binary-menu))
 351
 352 (defun gnus-xmas-agent-summary-menu-add ()
 353   (gnus-xmas-menu-add agent-summary
 354     gnus-agent-summary-menu))
 355
 356 (defun gnus-xmas-agent-group-menu-add ()
 357   (gnus-xmas-menu-add agent-group
 358     gnus-agent-group-menu))
 359
 360 (defun gnus-xmas-agent-server-menu-add ()
 361   (gnus-xmas-menu-add agent-server
 362     gnus-agent-server-menu))
 363
 364 (defun gnus-xmas-tree-menu-add ()
 365   (gnus-xmas-menu-add tree
 366     gnus-tree-menu))
 367
 368 (defun gnus-xmas-draft-menu-add ()
 369   (gnus-xmas-menu-add draft
 370     gnus-draft-menu))
 371
 372 (defun gnus-xmas-server-menu-add ()
 373   (gnus-xmas-menu-add menu
 374     gnus-server-server-menu gnus-server-connections-menu))
 375
 376 (defun gnus-xmas-browse-menu-add ()
 377   (gnus-xmas-menu-add browse
 378     gnus-browse-menu))
 379
 380 (defun gnus-xmas-grouplens-menu-add ()
 381   (gnus-xmas-menu-add grouplens
 382     gnus-grouplens-menu))
 383
 384 (defun gnus-xmas-read-event-char ()
 385   "Get the next event."
 386   (let ((event (next-command-event)))
 387     (sit-for 0)
 388     ;; We junk all non-key events.  Is this naughty?
 389     (while (not (or (key-press-event-p event)
 390                     (button-press-event-p event)))
 391       (dispatch-event event)
 392       (setq event (next-command-event)))
 393     (cons (and (key-press-event-p event)
 394                (event-to-character event))
 395           event)))
 396
 397 (defun gnus-xmas-seconds-since-epoch (date)
 398   "Return a floating point number that says how many seconds have lapsed between Jan 1 12:00:00 1970 and DATE."
 399   (let* ((tdate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 400                         (timezone-parse-date date)))
 401          (ttime (mapcar (lambda (ti) (and ti (string-to-int ti)))
 402                         (timezone-parse-time
 403                          (aref (timezone-parse-date date) 3))))
 404          (edate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 405                         (timezone-parse-date "Jan 1 12:00:00 1970")))
 406          (tday (- (timezone-absolute-from-gregorian
 407                    (nth 1 tdate) (nth 2 tdate) (nth 0 tdate))
 408                   (timezone-absolute-from-gregorian
 409                    (nth 1 edate) (nth 2 edate) (nth 0 edate)))))
 410     (+ (nth 2 ttime)
 411        (* (nth 1 ttime) 60)
 412        (* (float (nth 0 ttime)) 60 60)
 413        (* (float tday) 60 60 24))))
 414
 415 (defun gnus-xmas-define ()
 416   (setq gnus-mouse-2 [button2])
 417
 418   (unless (memq 'underline (face-list))
 419     (and (fboundp 'make-face)
 420          (funcall (intern "make-face") 'underline)))
 421   ;; Must avoid calling set-face-underline-p directly, because it
 422   ;; is a defsubst in emacs19, and will make the .elc files non
 423   ;; portable!
 424   (unless (face-differs-from-default-p 'underline)
 425     (funcall (intern "set-face-underline-p") 'underline t))
 426
 427   (cond
 428    ((fboundp 'char-or-char-int-p)
 429     ;; Handle both types of marks for XEmacs-20.x.
 430     (fset 'gnus-characterp 'char-or-char-int-p))
 431    ;; V19 of XEmacs, probably.
 432    (t
 433     (fset 'gnus-characterp 'characterp)))
 434
 435   (fset 'gnus-make-overlay 'make-extent)
 436   (fset 'gnus-delete-overlay 'delete-extent)
 437   (fset 'gnus-overlay-put 'set-extent-property)
 438   (fset 'gnus-move-overlay 'gnus-xmas-move-overlay)
 439   (fset 'gnus-overlay-end 'extent-end-position)
 440   (fset 'gnus-kill-all-overlays 'gnus-xmas-kill-all-overlays)
 441   (fset 'gnus-extent-detached-p 'extent-detached-p)
 442   (fset 'gnus-add-text-properties 'gnus-xmas-add-text-properties)
 443   (fset 'gnus-put-text-property 'gnus-xmas-put-text-property)
 444   (fset 'gnus-deactivate-mark 'ignore)
 445   (fset 'gnus-window-edges 'window-pixel-edges)
 446
 447   (if (and (<= emacs-major-version 19)
 448            (< emacs-minor-version 14))
 449       (fset 'gnus-set-text-properties 'gnus-xmas-set-text-properties))
 450
 451   (when (fboundp 'turn-off-scroll-in-place)
 452     (add-hook 'gnus-article-mode-hook 'turn-off-scroll-in-place))
 453
 454   (unless (boundp 'standard-display-table)
 455     (setq standard-display-table nil))
 456
 457   (defvar gnus-mouse-face-prop 'highlight)
 458
 459   (unless (fboundp 'encode-time)
 460     (defun encode-time (sec minute hour day month year &optional zone)
 461       (let ((seconds
 462              (gnus-xmas-seconds-since-epoch
 463               (timezone-make-arpa-date
 464                year month day (timezone-make-time-string hour minute sec)
 465                zone))))
 466         (list (floor (/ seconds (expt 2 16)))
 467               (round (mod seconds (expt 2 16)))))))
 468
 469   (defun gnus-byte-code (func)
 470     "Return a form that can be `eval'ed based on FUNC."
 471     (let ((fval (indirect-function func)))
 472       (if (compiled-function-p fval)
 473           (list 'funcall fval)
 474         (cons 'progn (cdr (cdr fval))))))
 475
 476   (fset 'gnus-x-color-values
 477         (if (fboundp 'x-color-values)
 478             'x-color-values
 479           (lambda (color)
 480             (color-instance-rgb-components
 481              (make-color-instance color)))))
 482
 483   (when (featurep 'mule)
 484     (defun gnus-tilde-pad-form (el pad-width)
 485       "Return a form that pads EL to PAD-WIDTH."
 486       (let ((pad (abs pad-width)))
 487         (if (symbolp el)
 488             (if (< pad-width 0)
 489                 `(let ((val (format "%s" ,el)))
 490                    (concat val (make-string
 491                                 (max 0 (- ,pad (string-width val))) ?\ )))
 492               `(let ((val (format "%s" ,el)))
 493                  (concat (make-string
 494                           (max 0 (- ,pad (string-width val))) ?\ )
 495                          val)))
 496           (if (< pad-width 0)
 497               `(let ((val (eval ,el)))
 498                  (concat val (make-string
 499                               (max 0 (- ,pad (string-width val))) ?\ )))
 500             `(let ((val (eval ,el)))
 501                (concat (make-string
 502                         (max 0 (- ,pad (string-width val))) ?\ )
 503                        val))))))
 504     ))
 505
 506 (defun gnus-xmas-redefine ()
 507   "Redefine lots of Gnus functions for XEmacs."
 508   (fset 'gnus-summary-set-display-table 'gnus-xmas-summary-set-display-table)
 509   (fset 'gnus-visual-turn-off-edit-menu 'identity)
 510   (fset 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 511   (fset 'gnus-extent-start-open 'gnus-xmas-extent-start-open)
 512   (fset 'gnus-article-push-button 'gnus-xmas-article-push-button)
 513   (fset 'gnus-article-add-button 'gnus-xmas-article-add-button)
 514   (fset 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 515   (fset 'gnus-read-event-char 'gnus-xmas-read-event-char)
 516   (fset 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 517   (fset 'gnus-tree-minimize 'gnus-xmas-tree-minimize)
 518   (fset 'gnus-appt-select-lowest-window
 519         'gnus-xmas-appt-select-lowest-window)
 520   (fset 'gnus-mail-strip-quoted-names 'gnus-xmas-mail-strip-quoted-names)
 521   (fset 'gnus-character-to-event 'character-to-event)
 522   (fset 'gnus-mode-line-buffer-identification
 523         'gnus-xmas-mode-line-buffer-identification)
 524   (fset 'gnus-key-press-event-p 'key-press-event-p)
 525   (fset 'gnus-region-active-p 'region-active-p)
 526
 527   (add-hook 'gnus-group-mode-hook 'gnus-xmas-group-menu-add)
 528   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-summary-menu-add)
 529   (add-hook 'gnus-article-mode-hook 'gnus-xmas-article-menu-add)
 530   (add-hook 'gnus-score-mode-hook 'gnus-xmas-score-menu-add)
 531
 532   (add-hook 'gnus-pick-mode-hook 'gnus-xmas-pick-menu-add)
 533   (add-hook 'gnus-topic-mode-hook 'gnus-xmas-topic-menu-add)
 534   (add-hook 'gnus-tree-mode-hook 'gnus-xmas-tree-menu-add)
 535   (add-hook 'gnus-binary-mode-hook 'gnus-xmas-binary-menu-add)
 536   (add-hook 'gnus-grouplens-mode-hook 'gnus-xmas-grouplens-menu-add)
 537   (add-hook 'gnus-server-mode-hook 'gnus-xmas-server-menu-add)
 538   (add-hook 'gnus-browse-mode-hook 'gnus-xmas-browse-menu-add)
 539
 540   (add-hook 'gnus-group-mode-hook 'gnus-xmas-setup-group-toolbar)
 541   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-setup-summary-toolbar)
 542
 543   (add-hook 'gnus-agent-summary-mode-hook 'gnus-xmas-agent-summary-menu-add)
 544   (add-hook 'gnus-agent-group-mode-hook 'gnus-xmas-agent-group-menu-add)
 545   (add-hook 'gnus-agent-server-mode-hook 'gnus-xmas-agent-server-menu-add)
 546
 547   (add-hook 'gnus-draft-mode-hook 'gnus-xmas-draft-menu-add)
 548   (add-hook 'gnus-summary-mode-hook
 549             'gnus-xmas-switch-horizontal-scrollbar-off)
 550   (add-hook 'gnus-tree-mode-hook 'gnus-xmas-switch-horizontal-scrollbar-off)
 551
 552   (when (featurep 'mule)
 553     (defun gnus-truncate-string (str end-column &optional start-column padding)
 554       "Truncate string STR to end at column END-COLUMN.
 555 The optional 2nd arg START-COLUMN, if non-nil, specifies
 556 the starting column; that means to return the characters occupying
 557 columns START-COLUMN ... END-COLUMN of STR.
 558
 559 The optional 3rd arg PADDING, if non-nil, specifies a padding character
 560 to add at the end of the result if STR doesn't reach column END-COLUMN,
 561 or if END-COLUMN comes in the middle of a character in STR.
 562 PADDING is also added at the beginning of the result
 563 if column START-COLUMN appears in the middle of a character in STR.
 564
 565 If PADDING is nil, no padding is added in these cases, so
 566 the resulting string may be narrower than END-COLUMN.
 567 \[Emacs 20.3 emulating function]"
 568       (or start-column
 569           (setq start-column 0))
 570       (let ((len (length str))
 571             (idx 0)
 572             (column 0)
 573             (head-padding "") (tail-padding "")
 574             ch last-column last-idx from-idx)
 575         (condition-case nil
 576             (while (< column start-column)
 577               (setq ch (aref str idx)
 578                     column (+ column (char-width ch))
 579                     idx (1+ idx)))
 580           (args-out-of-range (setq idx len)))
 581         (if (< column start-column)
 582             (if padding (make-string end-column padding) "")
 583           (if (and padding (> column start-column))
 584               (setq head-padding
 585                     (make-string (- column start-column) padding)))
 586           (setq from-idx idx)
 587           (if (< end-column column)
 588               (setq idx from-idx)
 589             (condition-case nil
 590                 (while (< column end-column)
 591                   (setq last-column column
 592                         last-idx idx
 593                         ch (aref str idx)
 594                         column (+ column (char-width ch))
 595                         idx (1+ idx)))
 596               (args-out-of-range (setq idx len)))
 597             (if (> column end-column)
 598                 (setq column last-column idx last-idx))
 599             (if (and padding (< column end-column))
 600                 (setq tail-padding
 601                       (make-string (- end-column column) padding))))
 602           (setq str (substring str from-idx idx))
 603           (if padding
 604               (concat head-padding str tail-padding)
 605             str))))
 606
 607     (defun gnus-tilde-max-form (el max-width)
 608       "Return a form that limits EL to MAX-WIDTH."
 609       (let ((max (abs max-width)))
 610         (if (symbolp el)
 611             (if (< max-width 0)
 612                 `(let ((width (string-width ,el)))
 613                    (gnus-truncate-string ,el width (- width ,max)))
 614               `(gnus-truncate-string ,el ,max))
 615           (if (< max-width 0)
 616               `(let* ((val (eval ,el))
 617                       (width (string-width val)))
 618                  (gnus-truncate-string val width (- width ,max)))
 619             `(let ((val (eval ,el)))
 620                (gnus-truncate-string val ,max))))))
 621
 622     (defun gnus-tilde-cut-form (el cut-width)
 623       "Return a form that cuts CUT-WIDTH off of EL."
 624       (let ((cut (abs cut-width)))
 625         (if (symbolp el)
 626             (if (< cut-width 0)
 627                 `(gnus-truncate-string ,el (- (string-width ,el) ,cut))
 628               `(gnus-truncate-string ,el (string-width ,el) ,cut))
 629           (if (< cut-width 0)
 630               `(let ((val (eval ,el)))
 631                  (gnus-truncate-string val (- (string-width val) ,cut)))
 632             `(let ((val (eval ,el)))
 633                (gnus-truncate-string val (string-width val) ,cut))))))
 634     ))
 635
 636 ;;; XEmacs logo and toolbar.
 637
 638 (defun gnus-xmas-group-startup-message (&optional x y)
 639   "Insert startup message in current buffer."
 640   ;; Insert the message.
 641   (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 642   (erase-buffer)
 643   (cond
 644    ((and (console-on-window-system-p)
 645          (or (featurep 'xpm)
 646              (featurep 'xbm)))
 647     (let* ((logo-xpm (expand-file-name "gnus.xpm" gnus-xmas-glyph-directory))
 648            (logo-xbm (expand-file-name "gnus.xbm" gnus-xmas-glyph-directory))
 649            (glyph (make-glyph
 650                    (cond ((featurep 'xpm)
 651                           `[xpm
 652                             :file ,logo-xpm
 653                             :color-symbols
 654                             (("thing" . ,(car gnus-xmas-logo-colors))
 655                              ("shadow" . ,(cadr gnus-xmas-logo-colors))
 656                              ("background" . ,(face-background 'default)))])
 657                          ((featurep 'xbm)
 658                           `[xbm :file ,logo-xbm])
 659                          (t [nothing])))))
 660       (insert " ")
 661       (set-extent-begin-glyph (make-extent (point) (point)) glyph)
 662       (goto-char (point-min))
 663       (while (not (eobp))
 664         (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 665                              ?\ ))
 666         (forward-line 1))
 667       (setq gnus-simple-splash nil))
 668     (goto-char (point-min))
 669     (let* ((pheight (+ 20 (count-lines (point-min) (point-max))))
 670            (wheight (window-height))
 671            (rest (- wheight pheight)))
 672       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 673    (t
 674     (insert
 675      (format "              %s
 676           _    ___ _             _
 677           _ ___ __ ___  __    _ ___
 678           __   _     ___    __  ___
 679               _           ___     _
 680              _  _ __             _
 681              ___   __            _
 682                    __           _
 683                     _      _   _
 684                    _      _    _
 685                       _  _    _
 686                   __  ___
 687                  _   _ _     _
 688                 _   _
 689               _    _
 690              _    _
 691             _
 692           __
 693
 694 "
 695              ""))
 696     ;; And then hack it.
 697     (gnus-indent-rigidly (point-min) (point-max)
 698                          (/ (max (- (window-width) (or x 46)) 0) 2))
 699     (goto-char (point-min))
 700     (forward-line 1)
 701     (let* ((pheight (count-lines (point-min) (point-max)))
 702            (wheight (window-height))
 703            (rest (- wheight pheight)))
 704       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n)))
 705     ;; Paint it.
 706     (put-text-property (point-min) (point-max) 'face 'gnus-splash-face)))
 707   (setq modeline-buffer-identification
 708         (list (concat gnus-version ": *Group*")))
 709   (set-buffer-modified-p t))
 710
 711
 712 ;;; The toolbar.
 713
 714 (defcustom gnus-use-toolbar (if (featurep 'toolbar)
 715                                 'default-toolbar
 716                               nil)
 717   "*If nil, do not use a toolbar.
 718 If it is non-nil, it must be a toolbar.  The five legal values are
 719 `default-toolbar', `top-toolbar', `bottom-toolbar',
 720 `right-toolbar', and `left-toolbar'."
 721   :type '(choice (const default-toolbar)
 722                  (const top-toolbar) (const bottom-toolbar)
 723                  (const left-toolbar) (const right-toolbar)
 724                  (const :tag "no toolbar" nil))
 725   :group 'gnus-xmas)
 726
 727 (defvar gnus-group-toolbar
 728   '([gnus-group-get-new-news gnus-group-get-new-news t "Get new news"]
 729     [gnus-group-get-new-news-this-group
 730      gnus-group-get-new-news-this-group t "Get new news in this group"]
 731     [gnus-group-catchup-current
 732      gnus-group-catchup-current t "Catchup group"]
 733     [gnus-group-describe-group
 734      gnus-group-describe-group t "Describe group"]
 735     [gnus-group-unsubscribe gnus-group-unsubscribe t "Unsubscribe group"]
 736     [gnus-group-subscribe gnus-group-subscribe t "Subscribe group"]
 737     [gnus-group-kill-group gnus-group-kill-group t "Kill group"]
 738     [gnus-group-exit gnus-group-exit t "Exit Gnus"]
 739     )
 740   "The group buffer toolbar.")
 741
 742 (defvar gnus-summary-toolbar
 743   '([gnus-summary-prev-unread
 744      gnus-summary-prev-page-or-article t "Page up"]
 745     [gnus-summary-next-unread
 746      gnus-summary-next-page t "Page down"]
 747     [gnus-summary-post-news
 748      gnus-summary-post-news t "Post an article"]
 749     [gnus-summary-followup-with-original
 750      gnus-summary-followup-with-original t
 751      "Post a followup and yank the original"]
 752     [gnus-summary-followup
 753      gnus-summary-followup t "Post a followup"]
 754     [gnus-summary-reply-with-original
 755      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 756     [gnus-summary-reply
 757      gnus-summary-reply t "Mail a reply"]
 758     [gnus-summary-caesar-message
 759      gnus-summary-caesar-message t "Rot 13"]
 760     [gnus-uu-decode-uu
 761      gnus-uu-decode-uu t "Decode uuencoded articles"]
 762     [gnus-summary-save-article-file
 763      gnus-summary-save-article-file t "Save article in file"]
 764     [gnus-summary-save-article
 765      gnus-summary-save-article t "Save article"]
 766     [gnus-uu-post-news
 767      gnus-uu-post-news t "Post a uuencoded article"]
 768     [gnus-summary-cancel-article
 769      gnus-summary-cancel-article t "Cancel article"]
 770     [gnus-summary-catchup
 771      gnus-summary-catchup t "Catchup"]
 772     [gnus-summary-catchup-and-exit
 773      gnus-summary-catchup-and-exit t "Catchup and exit"]
 774     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 775     )
 776   "The summary buffer toolbar.")
 777
 778 (defvar gnus-summary-mail-toolbar
 779   '(
 780     [gnus-summary-prev-unread
 781      gnus-summary-prev-unread-article t "Prev unread article"]
 782     [gnus-summary-next-unread
 783      gnus-summary-next-unread-article t "Next unread article"]
 784     [gnus-summary-mail-reply gnus-summary-reply t "Reply"]
 785 ;    [gnus-summary-mail-get gnus-mail-get t "Message get"]
 786     [gnus-summary-mail-originate gnus-summary-post-news t "Originate"]
 787     [gnus-summary-mail-save gnus-summary-save-article t "Save"]
 788     [gnus-summary-mail-copy gnus-summary-copy-article t "Copy message"]
 789 ;    [gnus-summary-mail-delete gnus-summary-delete-article t "Delete message"]
 790     [gnus-summary-mail-forward gnus-summary-mail-forward t "Forward message"]
 791 ;    [gnus-summary-mail-spell gnus-mail-spell t "Spell"]
 792 ;    [gnus-summary-mail-help gnus-mail-help  t "Message help"]
 793     [gnus-summary-caesar-message
 794      gnus-summary-caesar-message t "Rot 13"]
 795     [gnus-uu-decode-uu
 796      gnus-uu-decode-uu t "Decode uuencoded articles"]
 797     [gnus-summary-save-article-file
 798      gnus-summary-save-article-file t "Save article in file"]
 799     [gnus-summary-save-article
 800      gnus-summary-save-article t "Save article"]
 801     [gnus-summary-catchup
 802      gnus-summary-catchup t "Catchup"]
 803     [gnus-summary-catchup-and-exit
 804      gnus-summary-catchup-and-exit t "Catchup and exit"]
 805     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 806     )
 807   "The summary buffer mail toolbar.")
 808
 809 (defun gnus-xmas-setup-group-toolbar ()
 810   (and gnus-use-toolbar
 811        (message-xmas-setup-toolbar gnus-group-toolbar nil "gnus")
 812        (set-specifier (symbol-value gnus-use-toolbar)
 813                       (cons (current-buffer) gnus-group-toolbar))))
 814
 815 (defun gnus-xmas-setup-summary-toolbar ()
 816   (let ((bar (if (gnus-news-group-p gnus-newsgroup-name)
 817                  gnus-summary-toolbar gnus-summary-mail-toolbar)))
 818     (and gnus-use-toolbar
 819          (message-xmas-setup-toolbar bar nil "gnus")
 820          (set-specifier (symbol-value gnus-use-toolbar)
 821                         (cons (current-buffer) bar)))))
 822
 823 (defun gnus-xmas-mail-strip-quoted-names (address)
 824   "Protect mail-strip-quoted-names from NIL input.
 825 XEmacs compatibility workaround."
 826   (if (null address)
 827       nil
 828     (mail-strip-quoted-names address)))
 829
 830 (defun gnus-xmas-call-region (command &rest args)
 831   (apply
 832    'call-process-region (point-min) (point-max) command t '(t nil) nil
 833    args))
 834
 835 (defface gnus-x-face '((t (:foreground "black" :background "white")))
 836   "Face to show X face"
 837   :group 'gnus-xmas)
 838
 839 (defun gnus-xmas-article-display-xface (beg end)
 840   "Display any XFace headers in the current article."
 841   (save-excursion
 842     (let ((xface-glyph
 843            (cond ((featurep 'xface)
 844                   (make-glyph (vector 'xface :data
 845                                       (concat "X-Face: "
 846                                               (buffer-substring beg end)))))
 847                  ((featurep 'xpm)
 848                   (let ((cur (current-buffer)))
 849                     (save-excursion
 850                       (gnus-set-work-buffer)
 851                       (insert (format "%s" (buffer-substring beg end cur)))
 852                       (gnus-xmas-call-region "uncompface")
 853                       (goto-char (point-min))
 854                       (insert "/* Width=48, Height=48 */\n")
 855                       (gnus-xmas-call-region "icontopbm")
 856                       (gnus-xmas-call-region "ppmtoxpm")
 857                       (make-glyph
 858                        (vector 'xpm :data (buffer-string))))))
 859                  (t
 860                   (make-glyph [nothing]))))
 861           (ext (make-extent (progn
 862                               (goto-char (point-min))
 863                               (re-search-forward "^From:" nil t)
 864                               (point))
 865                             (1+ (point)))))
 866       (set-glyph-face xface-glyph 'gnus-x-face)
 867       (set-extent-begin-glyph ext xface-glyph)
 868       (set-extent-property ext 'duplicable t))))
 869
 870 ;;(defvar gnus-xmas-pointer-glyph
 871 ;;  (progn
 872 ;;    (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory
 873 ;;                                     "gnus"))
 874 ;;    (let ((file-xpm (expand-file-name "gnus-pointer.xpm"
 875 ;;                                    gnus-xmas-glyph-directory))
 876 ;;        (file-xbm (expand-file-name "gnus-pointer.xbm"
 877 ;;                                    gnus-xmas-glyph-directory)))
 878 ;;      (make-pointer-glyph
 879 ;;       (list (vector 'xpm ':file file-xpm)
 880 ;;           (vector 'xbm ':file file-xbm))))))
 881
 882 (defvar gnus-xmas-modeline-left-extent
 883   (let ((ext (copy-extent modeline-buffer-id-left-extent)))
 884 ;    (set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 885     ext))
 886
 887 (defvar gnus-xmas-modeline-right-extent
 888   (let ((ext (copy-extent modeline-buffer-id-right-extent)))
 889 ;    (set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 890     ext))
 891
 892 (defvar gnus-xmas-modeline-glyph
 893   (progn
 894     (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 895     (let* ((file-xpm (expand-file-name "gnus-pointer.xpm"
 896                                        gnus-xmas-glyph-directory))
 897            (file-xbm (expand-file-name "gnus-pointer.xbm"
 898                                        gnus-xmas-glyph-directory))
 899            (glyph (make-glyph
 900                    ;; Gag gag gag.
 901                    (cond ((featurep 'xpm)
 902                           ;; Let's try a nifty XPM
 903                           `[xpm :file ,file-xpm])
 904                          ((featurep 'xbm)
 905                           ;; Then a not-so-nifty XBM
 906                           [xbm :file ,file-xbm])
 907                          ;; Then the simple string
 908                          (t [string :data "Gnus:"])))))
 909       (set-glyph-face glyph 'modeline-buffer-id)
 910       glyph)))
 911
 912 (defun gnus-xmas-mode-line-buffer-identification (line)
 913   (let ((line (car line))
 914         chop)
 915     (cond
 916      ;; This is some weird type of id.
 917      ((not (stringp line))
 918       (list line))
 919      ;; This is non-standard, so we just pass it through.
 920      ((not (string-match "^Gnus:" line))
 921       (list line))
 922      ;; We have a standard line, so we colorize and glyphize it a bit.
 923      (t
 924       (setq chop (match-end 0))
 925       (list
 926        (if gnus-xmas-modeline-glyph
 927            (cons gnus-xmas-modeline-left-extent gnus-xmas-modeline-glyph)
 928          (cons gnus-xmas-modeline-left-extent (substring line 0 chop)))
 929        (cons gnus-xmas-modeline-right-extent (substring line chop)))))))
 930
 931 (defun gnus-xmas-splash ()
 932   (when (eq (device-type) 'x)
 933     (gnus-splash)))
 934
 935 (provide 'gnus-xmas)
 936
 937 ;;; gnus-xmas.el ends here