git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Katsumi Yamaoka <yamaoka@jpl.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (require 'text-props)
  32 (defvar menu-bar-mode (featurep 'menubar))
  33 (require 'messagexmas)
  34 (require 'wid-edit)
  35
  36 (defgroup gnus-xmas nil
  37   "XEmacsoid support for Gnus"
  38   :group 'gnus)
  39
  40 (defcustom gnus-xmas-glyph-directory nil
  41   "Directory where Gnus logos and icons are located.
  42 If this variable is nil, Gnus will try to locate the directory
  43 automatically."
  44   :type '(choice (const :tag "autodetect" nil)
  45                  directory)
  46   :group 'gnus-xmas)
  47
  48 (unless gnus-xmas-glyph-directory
  49   (unless (setq gnus-xmas-glyph-directory
  50                 (message-xmas-find-glyph-directory "gnus"))
  51     (error "Can't find glyph directory. \
  52 Possibly the `etc' directory has not been installed.")))
  53
  54 ;;; Internal variables.
  55
  56 ;; Don't warn about these undefined variables.
  57
  58 ;;defined in gnus.el
  59 (defvar gnus-active-hashtb)
  60 (defvar gnus-article-buffer)
  61 (defvar gnus-auto-center-summary)
  62 (defvar gnus-current-headers)
  63 (defvar gnus-level-killed)
  64 (defvar gnus-level-zombie)
  65 (defvar gnus-newsgroup-bookmarks)
  66 (defvar gnus-newsgroup-dependencies)
  67 (defvar gnus-newsgroup-selected-overlay)
  68 (defvar gnus-newsrc-hashtb)
  69 (defvar gnus-read-mark)
  70 (defvar gnus-refer-article-method)
  71 (defvar gnus-reffed-article-number)
  72 (defvar gnus-unread-mark)
  73 (defvar gnus-version)
  74 (defvar gnus-view-pseudos)
  75 (defvar gnus-view-pseudos-separately)
  76 (defvar gnus-visual)
  77 (defvar gnus-zombie-list)
  78 ;;defined in gnus-msg.el
  79 (defvar gnus-article-copy)
  80 (defvar gnus-check-before-posting)
  81 ;;defined in gnus-vis.el
  82 (defvar gnus-article-button-face)
  83 (defvar gnus-article-mouse-face)
  84 (defvar gnus-summary-selected-face)
  85 (defvar gnus-group-reading-menu)
  86 (defvar gnus-group-group-menu)
  87 (defvar gnus-group-misc-menu)
  88 (defvar gnus-summary-article-menu)
  89 (defvar gnus-summary-thread-menu)
  90 (defvar gnus-summary-misc-menu)
  91 (defvar gnus-summary-post-menu)
  92 (defvar gnus-summary-kill-menu)
  93 (defvar gnus-article-article-menu)
  94 (defvar gnus-article-treatment-menu)
  95 (defvar gnus-mouse-2)
  96 (defvar standard-display-table)
  97 (defvar gnus-tree-minimize-window)
  98
  99 (defun gnus-xmas-set-text-properties (start end props &optional buffer)
 100   "You should NEVER use this function.  It is ideologically blasphemous.
 101 It is provided only to ease porting of broken FSF Emacs programs."
 102   (if (stringp buffer)
 103       nil
 104     (map-extents (lambda (extent ignored)
 105                    (remove-text-properties
 106                     start end
 107                     (list (extent-property extent 'text-prop) nil)
 108                     buffer)
 109                    nil)
 110                  buffer start end nil nil 'text-prop)
 111     (gnus-add-text-properties start end props buffer)))
 112
 113 (defun gnus-xmas-highlight-selected-summary ()
 114   ;; Highlight selected article in summary buffer
 115   (when gnus-summary-selected-face
 116     (when gnus-newsgroup-selected-overlay
 117       (delete-extent gnus-newsgroup-selected-overlay))
 118     (setq gnus-newsgroup-selected-overlay
 119           (make-extent (gnus-point-at-bol) (gnus-point-at-eol)))
 120     (set-extent-face gnus-newsgroup-selected-overlay
 121                      gnus-summary-selected-face)))
 122
 123 (defcustom gnus-xmas-force-redisplay nil
 124   "*If non-nil, force a redisplay before recentering the summary buffer.
 125 This is ugly, but it works around a bug in `window-displayed-height'."
 126   :type 'boolean
 127   :group 'gnus-xmas)
 128
 129 (defun gnus-xmas-switch-horizontal-scrollbar-off ()
 130   (when (featurep 'scrollbar)
 131     (set-specifier scrollbar-height (cons (current-buffer) 0))))
 132
 133 (defun gnus-xmas-summary-recenter ()
 134   "\"Center\" point in the summary window.
 135 If `gnus-auto-center-summary' is nil, or the article buffer isn't
 136 displayed, no centering will be performed."
 137   ;; Suggested by earle@mahendo.JPL.NASA.GOV (Greg Earle).
 138   ;; Recenter only when requested.  Suggested by popovich@park.cs.columbia.edu.
 139   ;; Force redisplay to get properly computed window height.
 140   (when gnus-xmas-force-redisplay
 141     (sit-for 0))
 142   (when gnus-auto-center-summary
 143     (let* ((height (if (fboundp 'window-displayed-height)
 144                        (window-displayed-height)
 145                      (- (window-height) 2)))
 146            (top (cond ((< height 4) 0)
 147                       ((< height 7) 1)
 148                       (t (if (numberp gnus-auto-center-summary)
 149                              gnus-auto-center-summary
 150                            2))))
 151            (bottom (save-excursion (goto-char (point-max))
 152                                    (forward-line (- height))
 153                                    (point)))
 154            (window (get-buffer-window (current-buffer))))
 155       (when (get-buffer-window gnus-article-buffer)
 156         ;; Only do recentering when the article buffer is displayed,
 157         ;; Set the window start to either `bottom', which is the biggest
 158         ;; possible valid number, or the second line from the top,
 159         ;; whichever is the least.
 160         ;; NOFORCE parameter suggested by Daniel Pittman <daniel@danann.net>.
 161         (set-window-start
 162          window (min bottom (save-excursion (forward-line (- top)) (point)))
 163          t))
 164       ;; Do horizontal recentering while we're at it.
 165       (when (and (get-buffer-window (current-buffer) t)
 166                  (not (eq gnus-auto-center-summary 'vertical)))
 167         (let ((selected (selected-window)))
 168           (select-window (get-buffer-window (current-buffer) t))
 169           (gnus-summary-position-point)
 170           (gnus-horizontal-recenter)
 171           (select-window selected))))))
 172
 173 (defun gnus-xmas-summary-set-display-table ()
 174   ;; Setup the display table -- like `gnus-summary-setup-display-table',
 175   ;; but done in an XEmacsish way.
 176   (let ((table (make-display-table))
 177         (i 32))
 178     ;; Nix out all the control chars...
 179     (while (>= (setq i (1- i)) 0)
 180       (aset table i [??]))
 181     ;; ... but not newline and cr, of course.  (cr is necessary for the
 182     ;; selective display).
 183     (aset table ?\n nil)
 184     (aset table ?\r nil)
 185     ;; We keep TAB as well.
 186     (aset table ?\t nil)
 187     ;; We nix out any glyphs over 126 below ctl-arrow.
 188     (let ((i (if (integerp ctl-arrow) ctl-arrow 160)))
 189       (while (>= (setq i (1- i)) 127)
 190         (unless (aref table i)
 191           (aset table i [??]))))
 192     ;; Can't use `set-specifier' because of a bug in 19.14 and earlier
 193     (add-spec-to-specifier current-display-table table (current-buffer) nil)))
 194
 195 (defun gnus-xmas-add-text-properties (start end props &optional object)
 196   (add-text-properties start end props object)
 197   (put-text-property start end 'start-closed nil object))
 198
 199 (defun gnus-xmas-put-text-property (start end prop value &optional object)
 200   (put-text-property start end prop value object)
 201   (put-text-property start end 'start-closed nil object))
 202
 203 (defun gnus-xmas-extent-start-open (point)
 204   (map-extents (lambda (extent arg)
 205                  (set-extent-property extent 'start-open t))
 206                nil point (min (1+ (point)) (point-max))))
 207
 208 (defun gnus-xmas-article-push-button (event)
 209   "Check text under the mouse pointer for a callback function.
 210 If the text under the mouse pointer has a `gnus-callback' property,
 211 call it with the value of the `gnus-data' text property."
 212   (interactive "e")
 213   (set-buffer (window-buffer (event-window event)))
 214   (let* ((pos (event-closest-point event))
 215          (data (get-text-property pos 'gnus-data))
 216          (fun (get-text-property pos 'gnus-callback)))
 217     (goto-char pos)
 218     (when fun
 219       (funcall fun data))))
 220
 221 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 222   (set-extent-endpoints extent start end buffer))
 223
 224 (defun gnus-xmas-kill-all-overlays ()
 225   "Delete all extents in the current buffer."
 226   (map-extents (lambda (extent ignore)
 227                  (delete-extent extent)
 228                  nil)))
 229
 230 (defun gnus-xmas-window-top-edge (&optional window)
 231   (nth 1 (window-pixel-edges window)))
 232
 233 (defun gnus-xmas-tree-minimize ()
 234   (when (and gnus-tree-minimize-window
 235              (not (one-window-p)))
 236     (let* ((window-min-height 2)
 237            (height (1+ (count-lines (point-min) (point-max))))
 238            (min (max (1- window-min-height) height))
 239            (tot (if (numberp gnus-tree-minimize-window)
 240                     (min gnus-tree-minimize-window min)
 241                   min))
 242            (win (get-buffer-window (current-buffer)))
 243            (wh (and win (1- (window-height win)))))
 244       (when (and win
 245                  (not (eq tot wh)))
 246         (let ((selected (selected-window)))
 247           (select-window win)
 248           (enlarge-window (- tot wh))
 249           (select-window selected))))))
 250
 251 ;; Select the lowest window on the frame.
 252 (defun gnus-xmas-appt-select-lowest-window ()
 253   (let* ((lowest-window (selected-window))
 254          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 255          (last-window (previous-window))
 256          (window-search t))
 257     (while window-search
 258       (let* ((this-window (next-window))
 259              (next-bottom-edge (car (cdr (cdr (cdr
 260                                                (window-pixel-edges
 261                                                 this-window)))))))
 262         (when (< bottom-edge next-bottom-edge)
 263           (setq bottom-edge next-bottom-edge)
 264           (setq lowest-window this-window))
 265
 266         (select-window this-window)
 267         (when (eq last-window this-window)
 268           (select-window lowest-window)
 269           (setq window-search nil))))))
 270
 271 (defmacro gnus-xmas-menu-add (type &rest menus)
 272   `(gnus-xmas-menu-add-1 ',type ',menus))
 273 (put 'gnus-xmas-menu-add 'lisp-indent-function 1)
 274
 275 (defun gnus-xmas-menu-add-1 (type menus)
 276   (when (and menu-bar-mode
 277              (gnus-visual-p (intern (format "%s-menu" type)) 'menu))
 278     (while menus
 279       (easy-menu-add (symbol-value (pop menus))))))
 280
 281 (defun gnus-xmas-group-menu-add ()
 282   (gnus-xmas-menu-add group
 283     gnus-group-reading-menu gnus-group-group-menu gnus-group-misc-menu))
 284
 285 (defun gnus-xmas-summary-menu-add ()
 286   (gnus-xmas-menu-add summary
 287     gnus-summary-misc-menu gnus-summary-kill-menu
 288     gnus-summary-article-menu gnus-summary-thread-menu
 289     gnus-summary-post-menu ))
 290
 291 (defun gnus-xmas-article-menu-add ()
 292   (gnus-xmas-menu-add article
 293     gnus-article-article-menu gnus-article-treatment-menu
 294     gnus-article-post-menu gnus-article-commands-menu))
 295
 296 (defun gnus-xmas-score-menu-add ()
 297   (gnus-xmas-menu-add score
 298     gnus-score-menu))
 299
 300 (defun gnus-xmas-pick-menu-add ()
 301   (gnus-xmas-menu-add pick
 302     gnus-pick-menu))
 303
 304 (defun gnus-xmas-topic-menu-add ()
 305   (gnus-xmas-menu-add topic
 306     gnus-topic-menu))
 307
 308 (defun gnus-xmas-binary-menu-add ()
 309   (gnus-xmas-menu-add binary
 310     gnus-binary-menu))
 311
 312 (defun gnus-xmas-agent-summary-menu-add ()
 313   (gnus-xmas-menu-add agent-summary
 314     gnus-agent-summary-menu))
 315
 316 (defun gnus-xmas-agent-group-menu-add ()
 317   (gnus-xmas-menu-add agent-group
 318     gnus-agent-group-menu))
 319
 320 (defun gnus-xmas-agent-server-menu-add ()
 321   (gnus-xmas-menu-add agent-server
 322     gnus-agent-server-menu))
 323
 324 (defun gnus-xmas-tree-menu-add ()
 325   (gnus-xmas-menu-add tree
 326     gnus-tree-menu))
 327
 328 (defun gnus-xmas-draft-menu-add ()
 329   (gnus-xmas-menu-add draft
 330     gnus-draft-menu))
 331
 332 (defun gnus-xmas-server-menu-add ()
 333   (gnus-xmas-menu-add menu
 334     gnus-server-server-menu gnus-server-connections-menu))
 335
 336 (defun gnus-xmas-browse-menu-add ()
 337   (gnus-xmas-menu-add browse
 338     gnus-browse-menu))
 339
 340 (defun gnus-xmas-grouplens-menu-add ()
 341   (gnus-xmas-menu-add grouplens
 342     gnus-grouplens-menu))
 343
 344 (defun gnus-xmas-read-event-char ()
 345   "Get the next event."
 346   (let ((event (next-command-event)))
 347     (sit-for 0)
 348     ;; We junk all non-key events.  Is this naughty?
 349     (while (not (or (key-press-event-p event)
 350                     (button-press-event-p event)))
 351       (dispatch-event event)
 352       (setq event (next-command-event)))
 353     (cons (and (key-press-event-p event)
 354                (event-to-character event))
 355           event)))
 356
 357 (defun gnus-xmas-define ()
 358   (setq gnus-mouse-2 [button2])
 359   (setq gnus-mouse-3 [button3])
 360   (setq gnus-widget-button-keymap widget-button-keymap)
 361
 362   (unless (memq 'underline (face-list))
 363     (and (fboundp 'make-face)
 364          (funcall (intern "make-face") 'underline)))
 365   ;; Must avoid calling set-face-underline-p directly, because it
 366   ;; is a defsubst in emacs19, and will make the .elc files non
 367   ;; portable!
 368   (unless (face-differs-from-default-p 'underline)
 369     (funcall (intern "set-face-underline-p") 'underline t))
 370
 371   (cond
 372    ((fboundp 'char-or-char-int-p)
 373     ;; Handle both types of marks for XEmacs-20.x.
 374     (defalias 'gnus-characterp 'char-or-char-int-p))
 375    ;; V19 of XEmacs, probably.
 376    (t
 377     (defalias 'gnus-characterp 'characterp)))
 378
 379   (defalias 'gnus-make-overlay 'make-extent)
 380   (defalias 'gnus-delete-overlay 'delete-extent)
 381   (defalias 'gnus-overlay-put 'set-extent-property)
 382   (defalias 'gnus-move-overlay 'gnus-xmas-move-overlay)
 383   (defalias 'gnus-overlay-buffer 'extent-object)
 384   (defalias 'gnus-overlay-start 'extent-start-position)
 385   (defalias 'gnus-overlay-end 'extent-end-position)
 386   (defalias 'gnus-kill-all-overlays 'gnus-xmas-kill-all-overlays)
 387   (defalias 'gnus-extent-detached-p 'extent-detached-p)
 388   (defalias 'gnus-add-text-properties 'gnus-xmas-add-text-properties)
 389   (defalias 'gnus-put-text-property 'gnus-xmas-put-text-property)
 390   (defalias 'gnus-deactivate-mark 'ignore)
 391   (defalias 'gnus-window-edges 'window-pixel-edges)
 392
 393   (if (and (<= emacs-major-version 19)
 394            (< emacs-minor-version 14))
 395       (defalias 'gnus-set-text-properties 'gnus-xmas-set-text-properties))
 396
 397   (unless (boundp 'standard-display-table)
 398     (setq standard-display-table nil))
 399
 400   (defvar gnus-mouse-face-prop 'highlight)
 401
 402   (defun gnus-byte-code (func)
 403     "Return a form that can be `eval'ed based on FUNC."
 404     (let ((fval (indirect-function func)))
 405       (if (compiled-function-p fval)
 406           (list 'funcall fval)
 407         (cons 'progn (cdr (cdr fval))))))
 408
 409   (defalias 'gnus-x-color-values
 410     (if (fboundp 'x-color-values)
 411         'x-color-values
 412       (lambda (color)
 413         (color-instance-rgb-components
 414          (make-color-instance color))))))
 415
 416 (defun gnus-xmas-redefine ()
 417   "Redefine lots of Gnus functions for XEmacs."
 418   (defalias 'gnus-summary-set-display-table 'gnus-xmas-summary-set-display-table)
 419   (defalias 'gnus-visual-turn-off-edit-menu 'identity)
 420   (defalias 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 421   (defalias 'gnus-extent-start-open 'gnus-xmas-extent-start-open)
 422   (defalias 'gnus-article-push-button 'gnus-xmas-article-push-button)
 423   (defalias 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 424   (defalias 'gnus-read-event-char 'gnus-xmas-read-event-char)
 425   (defalias 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 426   (defalias 'gnus-tree-minimize 'gnus-xmas-tree-minimize)
 427   (defalias 'gnus-appt-select-lowest-window
 428     'gnus-xmas-appt-select-lowest-window)
 429   (defalias 'gnus-mail-strip-quoted-names 'gnus-xmas-mail-strip-quoted-names)
 430   (defalias 'gnus-character-to-event 'character-to-event)
 431   (defalias 'gnus-mode-line-buffer-identification
 432     'gnus-xmas-mode-line-buffer-identification)
 433   (defalias 'gnus-key-press-event-p 'key-press-event-p)
 434   (defalias 'gnus-region-active-p 'region-active-p)
 435   (defalias 'gnus-annotation-in-region-p 'gnus-xmas-annotation-in-region-p)
 436   (defalias 'gnus-mime-button-menu 'gnus-xmas-mime-button-menu)
 437   (defalias 'gnus-image-type-available-p 'gnus-xmas-image-type-available-p)
 438   (defalias 'gnus-put-image 'gnus-xmas-put-image)
 439   (defalias 'gnus-create-image 'gnus-xmas-create-image)
 440   (defalias 'gnus-remove-image 'gnus-xmas-remove-image)
 441
 442   (when (or (< emacs-major-version 21)
 443             (and (= emacs-major-version 21)
 444                  (< emacs-minor-version 3)))
 445     (defalias 'gnus-completing-read 'gnus-xmas-completing-read))
 446
 447   ;; These ones are not defcutom'ed, sometimes not even defvar'ed. They
 448   ;; probably should. If that is done, the code below should then be moved
 449   ;; where each variable is defined, in order not to mess with user settings.
 450   ;; -- didier
 451   (add-hook 'gnus-score-mode-hook 'gnus-xmas-score-menu-add)
 452   (add-hook 'gnus-binary-mode-hook 'gnus-xmas-binary-menu-add)
 453   (add-hook 'gnus-grouplens-mode-hook 'gnus-xmas-grouplens-menu-add)
 454   (add-hook 'gnus-server-mode-hook 'gnus-xmas-server-menu-add)
 455   (add-hook 'gnus-browse-mode-hook 'gnus-xmas-browse-menu-add)
 456   (add-hook 'gnus-draft-mode-hook 'gnus-xmas-draft-menu-add)
 457   (add-hook 'gnus-mailing-list-mode-hook 'gnus-xmas-mailing-list-menu-add)
 458
 459   (when (featurep 'mule)
 460     (defun gnus-truncate-string (str end-column &optional start-column padding)
 461       "Truncate string STR to end at column END-COLUMN.
 462 The optional 2nd arg START-COLUMN, if non-nil, specifies
 463 the starting column; that means to return the characters occupying
 464 columns START-COLUMN ... END-COLUMN of STR.
 465
 466 The optional 3rd arg PADDING, if non-nil, specifies a padding character
 467 to add at the end of the result if STR doesn't reach column END-COLUMN,
 468 or if END-COLUMN comes in the middle of a character in STR.
 469 PADDING is also added at the beginning of the result
 470 if column START-COLUMN appears in the middle of a character in STR.
 471
 472 If PADDING is nil, no padding is added in these cases, so
 473 the resulting string may be narrower than END-COLUMN.
 474 \[Emacs 20.3 emulating function]"
 475       (or start-column
 476           (setq start-column 0))
 477       (let ((len (length str))
 478             (idx 0)
 479             (column 0)
 480             (head-padding "") (tail-padding "")
 481             ch last-column last-idx from-idx)
 482         (condition-case nil
 483             (while (< column start-column)
 484               (setq ch (aref str idx)
 485                     column (+ column (char-width ch))
 486                     idx (1+ idx)))
 487           (args-out-of-range (setq idx len)))
 488         (if (< column start-column)
 489             (if padding (make-string end-column padding) "")
 490           (if (and padding (> column start-column))
 491               (setq head-padding
 492                     (make-string (- column start-column) padding)))
 493           (setq from-idx idx)
 494           (if (< end-column column)
 495               (setq idx from-idx)
 496             (condition-case nil
 497                 (while (< column end-column)
 498                   (setq last-column column
 499                         last-idx idx
 500                         ch (aref str idx)
 501                         column (+ column (char-width ch))
 502                         idx (1+ idx)))
 503               (args-out-of-range (setq idx len)))
 504             (if (> column end-column)
 505                 (setq column last-column idx last-idx))
 506             (if (and padding (< column end-column))
 507                 (setq tail-padding
 508                       (make-string (- end-column column) padding))))
 509           (setq str (substring str from-idx idx))
 510           (if padding
 511               (concat head-padding str tail-padding)
 512             str))))))
 513
 514 ;;; XEmacs logo and toolbar.
 515
 516 (defun gnus-xmas-group-startup-message (&optional x y)
 517   "Insert startup message in current buffer."
 518   ;; Insert the message.
 519   (erase-buffer)
 520   (cond
 521    ((and (console-on-window-system-p)
 522          (or (featurep 'xpm)
 523              (featurep 'xbm)))
 524     (let* ((logo-xpm (expand-file-name "gnus.xpm" gnus-xmas-glyph-directory))
 525            (logo-xbm (expand-file-name "gnus.xbm" gnus-xmas-glyph-directory))
 526            (glyph (make-glyph
 527                    (cond ((featurep 'xpm)
 528                           `[xpm
 529                             :file ,logo-xpm
 530                             :color-symbols
 531                             (("thing" . ,(car gnus-logo-colors))
 532                              ("shadow" . ,(cadr gnus-logo-colors))
 533                              ("background" . ,(face-background 'default)))])
 534                          ((featurep 'xbm)
 535                           `[xbm :file ,logo-xbm])
 536                          (t [nothing]))))
 537            (wpheight (window-pixel-height))
 538            (rest (max 0 (1- (/ (* (- wpheight (glyph-height glyph))
 539                                   (window-height))
 540                                wpheight 2)))))
 541       (insert " ")
 542       (set-extent-begin-glyph (make-extent (point) (point)) glyph)
 543       (goto-char (point-min))
 544       (while (not (eobp))
 545         (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 546                              ?\ ))
 547         (forward-line 1))
 548       (setq gnus-simple-splash nil)
 549       (goto-char (point-min))
 550       (insert gnus-product-name " " gnus-version-number
 551               (if (zerop (string-to-number gnus-revision-number))
 552                   ""
 553                 (concat " (r" gnus-revision-number ")"))
 554               " based on " gnus-original-product-name " v"
 555               gnus-original-version-number "\n")
 556       (end-of-line 0)
 557       (put-text-property (point-min) (point) 'face 'gnus-splash-face)
 558       (insert-char ?\  (prog1
 559                            (max 0 (/ (- (window-width) (point)) 2))
 560                          (goto-char (point-min))))
 561       (forward-line 1)
 562       (insert-char ?\n rest)
 563       (set-window-start (selected-window) (point-min))))
 564    (t
 565     (insert "
 566           _    ___ _             _
 567           _ ___ __ ___  __    _ ___
 568           __   _     ___    __  ___
 569               _           ___     _
 570              _  _ __             _
 571              ___   __            _
 572                    __           _
 573                     _      _   _
 574                    _      _    _
 575                       _  _    _
 576                   __  ___
 577                  _   _ _     _
 578                 _   _
 579               _    _
 580              _    _
 581             _
 582           __
 583
 584 "
 585             )
 586     (goto-char (point-min))
 587     (insert gnus-product-name " " gnus-version-number
 588             (if (zerop (string-to-number gnus-revision-number))
 589                 ""
 590               (concat " (r" gnus-revision-number ")"))
 591             " based on " gnus-original-product-name " v"
 592             gnus-original-version-number)
 593     (insert-char ?\  (prog1
 594                          (max 0 (/ (- (window-width) (point)) 2))
 595                        (goto-char (point-min))))
 596     (forward-line 1)
 597     ;; And then hack it.
 598     (gnus-indent-rigidly (point) (point-max)
 599                          (/ (max (- (window-width) (or x 46)) 0) 2))
 600     (goto-char (point-min))
 601     (forward-line 1)
 602     (let* ((pheight (count-lines (point-min) (point-max)))
 603            (wheight (window-height))
 604            (rest (- wheight pheight)))
 605       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n)))
 606     ;; Paint it.
 607     (put-text-property (point-min) (point-max) 'face 'gnus-splash-face)))
 608   (goto-char (point-min))
 609   (setq modeline-buffer-identification
 610         (list (concat gnus-version ": *Group*")))
 611   (set-buffer-modified-p t))
 612
 613
 614 ;;; The toolbar.
 615
 616 (defcustom gnus-use-toolbar (if (featurep 'toolbar)
 617                                 'default-toolbar
 618                               nil)
 619   "*If nil, do not use a toolbar.
 620 If it is non-nil, it must be a toolbar.  The five valid values are
 621 `default-toolbar', `top-toolbar', `bottom-toolbar',
 622 `right-toolbar', and `left-toolbar'."
 623   :type '(choice (const default-toolbar)
 624                  (const top-toolbar) (const bottom-toolbar)
 625                  (const left-toolbar) (const right-toolbar)
 626                  (const :tag "no toolbar" nil))
 627   :group 'gnus-xmas)
 628
 629 (defvar gnus-group-toolbar
 630   '([gnus-group-get-new-news gnus-group-get-new-news t "Get new news"]
 631     [gnus-group-get-new-news-this-group
 632      gnus-group-get-new-news-this-group t "Get new news in this group"]
 633     [gnus-group-catchup-current
 634      gnus-group-catchup-current t "Catchup group"]
 635     [gnus-group-describe-group
 636      gnus-group-describe-group t "Describe group"]
 637     [gnus-group-unsubscribe gnus-group-unsubscribe t "Unsubscribe group"]
 638     [gnus-group-subscribe gnus-group-subscribe t "Subscribe group"]
 639     [gnus-group-kill-group gnus-group-kill-group t "Kill group"]
 640     [gnus-summary-mail-save
 641      gnus-group-save-newsrc t "Save .newsrc files"] ; borrowed icon.
 642     [gnus-group-exit gnus-group-exit t "Exit Gnus"])
 643   "The group buffer toolbar.")
 644
 645 (defvar gnus-summary-toolbar
 646   '([gnus-summary-prev-unread
 647      gnus-summary-prev-page-or-article t "Page up"]
 648     [gnus-summary-next-unread
 649      gnus-summary-next-page t "Page down"]
 650     [gnus-summary-post-news
 651      gnus-summary-post-news t "Post an article"]
 652     [gnus-summary-followup-with-original
 653      gnus-summary-followup-with-original t
 654      "Post a followup and yank the original"]
 655     [gnus-summary-followup
 656      gnus-summary-followup t "Post a followup"]
 657     [gnus-summary-reply-with-original
 658      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 659     [gnus-summary-reply
 660      gnus-summary-reply t "Mail a reply"]
 661     [gnus-summary-caesar-message
 662      gnus-summary-caesar-message t "Rot 13"]
 663     [gnus-uu-decode-uu
 664      gnus-uu-decode-uu t "Decode uuencoded articles"]
 665     [gnus-summary-save-article-file
 666      gnus-summary-save-article-file t "Save article in file"]
 667     [gnus-summary-save-article
 668      gnus-summary-save-article t "Save article"]
 669     [gnus-uu-post-news
 670      gnus-uu-post-news t "Post a uuencoded article"]
 671     [gnus-summary-cancel-article
 672      gnus-summary-cancel-article t "Cancel article"]
 673     [gnus-summary-catchup
 674      gnus-summary-catchup t "Catchup"]
 675     [gnus-summary-catchup-and-exit
 676      gnus-summary-catchup-and-exit t "Catchup and exit"]
 677     [gnus-summary-exit gnus-summary-exit t "Exit this summary"])
 678   "The summary buffer toolbar.")
 679
 680 (defvar gnus-summary-mail-toolbar
 681   '(
 682     [gnus-summary-prev-unread
 683      gnus-summary-prev-unread-article t "Prev unread article"]
 684     [gnus-summary-next-unread
 685      gnus-summary-next-unread-article t "Next unread article"]
 686     [gnus-summary-mail-reply gnus-summary-reply t "Reply"]
 687     [gnus-summary-mail-originate gnus-summary-post-news t "Originate"]
 688     [gnus-summary-mail-save gnus-summary-save-article t "Save"]
 689     [gnus-summary-mail-copy gnus-summary-copy-article t "Copy message"]
 690     [gnus-summary-mail-forward gnus-summary-mail-forward t "Forward message"]
 691     [gnus-summary-caesar-message
 692      gnus-summary-caesar-message t "Rot 13"]
 693     [gnus-uu-decode-uu
 694      gnus-uu-decode-uu t "Decode uuencoded articles"]
 695     [gnus-summary-save-article-file
 696      gnus-summary-save-article-file t "Save article in file"]
 697     [gnus-summary-save-article
 698      gnus-summary-save-article t "Save article"]
 699     [gnus-summary-cancel-article ; usenet : cancellation :: mail : deletion.
 700      gnus-summary-delete-article t "Delete message"]
 701     [gnus-summary-catchup
 702      gnus-summary-catchup t "Catchup"]
 703     [gnus-summary-catchup-and-exit
 704      gnus-summary-catchup-and-exit t "Catchup and exit"]
 705     [gnus-summary-exit gnus-summary-exit t "Exit this summary"])
 706   "The summary buffer mail toolbar.")
 707
 708 (defun gnus-xmas-setup-group-toolbar ()
 709   (and gnus-use-toolbar
 710        (message-xmas-setup-toolbar gnus-group-toolbar nil "gnus")
 711        (set-specifier (symbol-value gnus-use-toolbar)
 712                       (cons (current-buffer) gnus-group-toolbar))))
 713
 714 (defun gnus-xmas-setup-summary-toolbar ()
 715   (let ((bar (if (gnus-news-group-p gnus-newsgroup-name)
 716                  gnus-summary-toolbar gnus-summary-mail-toolbar)))
 717     (and gnus-use-toolbar
 718          (message-xmas-setup-toolbar bar nil "gnus")
 719          (set-specifier (symbol-value gnus-use-toolbar)
 720                         (cons (current-buffer) bar)))))
 721
 722 (defun gnus-xmas-mail-strip-quoted-names (address)
 723   "Protect mail-strip-quoted-names from nil input.
 724 XEmacs compatibility workaround."
 725   (if (null address)
 726       nil
 727     (mail-strip-quoted-names address)))
 728
 729 (defun gnus-xmas-call-region (command &rest args)
 730   (apply
 731    'call-process-region (point-min) (point-max) command t '(t nil) nil
 732    args))
 733
 734 (defvar gnus-xmas-modeline-left-extent
 735   (let ((ext (copy-extent modeline-buffer-id-left-extent)))
 736     ext))
 737
 738 (defvar gnus-xmas-modeline-right-extent
 739   (let ((ext (copy-extent modeline-buffer-id-right-extent)))
 740     ext))
 741
 742 (defvar gnus-xmas-modeline-glyph
 743   (progn
 744     (let* ((file-xpm (expand-file-name "gnus-pointer.xpm"
 745                                        gnus-xmas-glyph-directory))
 746            (file-xbm (expand-file-name "gnus-pointer.xbm"
 747                                        gnus-xmas-glyph-directory))
 748            (glyph (make-glyph
 749                    ;; Gag gag gag.
 750                    (cond ((featurep 'xpm)
 751                           ;; Let's try a nifty XPM
 752                           `[xpm :file ,file-xpm])
 753                          ((featurep 'xbm)
 754                           ;; Then a not-so-nifty XBM
 755                           `[xbm :file ,file-xbm])
 756                          ;; Then the simple string
 757                          (t [string :data "Gnus:"])))))
 758       (set-glyph-face glyph 'modeline-buffer-id)
 759       glyph)))
 760
 761 (defun gnus-xmas-mode-line-buffer-identification (line)
 762   (let ((line (car line))
 763         chop)
 764     (cond
 765      ;; This is some weird type of id.
 766      ((not (stringp line))
 767       (list line))
 768      ;; This is non-standard, so we just pass it through.
 769      ((not (string-match "^Gnus:" line))
 770       (list line))
 771      ;; We have a standard line, so we colorize and glyphize it a bit.
 772      (t
 773       (setq chop (match-end 0))
 774       (list
 775        (if gnus-xmas-modeline-glyph
 776            (cons gnus-xmas-modeline-left-extent gnus-xmas-modeline-glyph)
 777          (cons gnus-xmas-modeline-left-extent (substring line 0 chop)))
 778        (cons gnus-xmas-modeline-right-extent (substring line chop)))))))
 779
 780 (defun gnus-xmas-splash ()
 781   (when (eq (device-type) 'x)
 782     (gnus-splash)))
 783
 784 (defun gnus-xmas-annotation-in-region-p (b e)
 785   (or (map-extents (lambda (e u) t) nil b e nil nil 'mm t)
 786       (if (= b e)
 787           (eq (cadr (memq 'gnus-undeletable (text-properties-at b))) t)
 788         (text-property-any b e 'gnus-undeletable t))))
 789
 790 (defun gnus-xmas-mime-button-menu (event)
 791   "Construct a context-sensitive menu of MIME commands."
 792   (interactive "e")
 793   (let ((response (get-popup-menu-response
 794                    `("MIME Part"
 795                      ,@(mapcar (lambda (c) `[,(caddr c) ,(car c) t])
 796                                gnus-mime-button-commands)))))
 797     (set-buffer (event-buffer event))
 798     (goto-char (event-point event))
 799     (funcall (event-function response) (event-object response))))
 800
 801 (defun gnus-group-add-icon ()
 802   "Add an icon to the current line according to `gnus-group-icon-list'."
 803   (let* ((p (point))
 804          (end (progn (end-of-line) (point)))
 805          ;; now find out where the line starts and leave point there.
 806          (beg (progn (beginning-of-line) (point))))
 807     (save-restriction
 808       (narrow-to-region beg end)
 809       (goto-char beg)
 810       (when (search-forward "==&&==" nil t)
 811         (let* ((group (gnus-group-group-name))
 812                (entry (gnus-group-entry group))
 813                (unread (if (numberp (car entry)) (car entry) 0))
 814                (active (gnus-active group))
 815                (total (if active (1+ (- (cdr active) (car active))) 0))
 816                (info (nth 2 entry))
 817                (method (gnus-server-get-method group (gnus-info-method info)))
 818                (marked (gnus-info-marks info))
 819                (mailp (memq 'mail (assoc (symbol-name
 820                                           (car (or method gnus-select-method)))
 821                                          gnus-valid-select-methods)))
 822                (level (or (gnus-info-level info) gnus-level-killed))
 823                (score (or (gnus-info-score info) 0))
 824                (ticked (gnus-range-length (cdr (assq 'tick marked))))
 825                (group-age (gnus-group-timestamp-delta group))
 826                (inhibit-read-only t)
 827                (list gnus-group-icon-list)
 828                (mystart (match-beginning 0))
 829                (myend (match-end 0)))
 830           (goto-char (point-min))
 831           (while (and list
 832                       (not (eval (caar list))))
 833             (setq list (cdr list)))
 834           (if list
 835               (let* ((file (cdar list))
 836                      (glyph (gnus-group-icon-create-glyph
 837                              (buffer-substring mystart myend)
 838                              file)))
 839                 (if glyph
 840                     (progn
 841                       (mapcar 'delete-annotation (annotations-at myend))
 842                       (let ((ext (make-extent mystart myend))
 843                             (ant (make-annotation glyph myend 'text)))
 844                         ;; set text extent params
 845                         (set-extent-property ext 'end-open t)
 846                         (set-extent-property ext 'start-open t)
 847                         (set-extent-property ext 'invisible t)))
 848                   (delete-region mystart myend)))
 849             (delete-region mystart myend))))
 850       (widen))
 851     (goto-char p)))
 852
 853 (defun gnus-group-icon-create-glyph (substring pixmap)
 854   "Create a glyph for insertion into a group line."
 855   (or
 856    (cdr-safe (assoc pixmap gnus-group-icon-cache))
 857    (let* ((glyph (make-glyph
 858                   (list
 859                    (cons 'x
 860                          (expand-file-name pixmap gnus-xmas-glyph-directory))
 861                    (cons 'mswindows
 862                          (expand-file-name pixmap gnus-xmas-glyph-directory))
 863                    (cons 'tty substring)))))
 864      (setq gnus-group-icon-cache
 865            (cons (cons pixmap glyph) gnus-group-icon-cache))
 866      (set-glyph-face glyph 'default)
 867      glyph)))
 868
 869 (defun gnus-xmas-mailing-list-menu-add ()
 870   (gnus-xmas-menu-add mailing-list
 871     gnus-mailing-list-menu))
 872
 873 (defun gnus-xmas-image-type-available-p (type)
 874   (and window-system
 875        (featurep (if (eq type 'pbm) 'xbm type))))
 876
 877 (defun gnus-xmas-create-image (file &optional type data-p &rest props)
 878   (let ((type (if type
 879                   (symbol-name type)
 880                 (car (last (split-string file "[.]")))))
 881         (face (plist-get props :face))
 882         glyph)
 883     (when (equal type "pbm")
 884       (with-temp-buffer
 885         (if data-p
 886             (insert file)
 887           (insert-file-contents file))
 888         (shell-command-on-region (point-min) (point-max)
 889                                  "ppmtoxpm 2>/dev/null" t)
 890         (setq file (buffer-string)
 891               type "xpm"
 892               data-p t)))
 893     (setq glyph
 894           (if (equal type "xbm")
 895               (make-glyph (list (cons 'x file)))
 896             (with-temp-buffer
 897               (if data-p
 898                   (insert file)
 899                 (insert-file-contents file))
 900               (make-glyph
 901                (vector
 902                 (or (intern type)
 903                     (mm-image-type-from-buffer))
 904                 :data (buffer-string))))))
 905     (when face
 906       (set-glyph-face glyph face))
 907     glyph))
 908
 909 (defun gnus-xmas-put-image (glyph &optional string)
 910   "Insert STRING, but display GLYPH.
 911 Warning: Don't insert text immediately after the image."
 912   (let ((begin (point))
 913         extent)
 914     (if (and (bobp) (not string))
 915         (setq string " "))
 916     (if string
 917         (insert string)
 918       (setq begin (1- begin)))
 919     (setq extent (make-extent begin (point)))
 920     (set-extent-property extent 'gnus-image t)
 921     (set-extent-property extent 'duplicable t)
 922     (if string
 923         (set-extent-property extent 'invisible t))
 924     (set-extent-property extent 'end-glyph glyph))
 925   glyph)
 926
 927 (defun gnus-xmas-remove-image (image)
 928   (map-extents
 929    (lambda (ext unused)
 930      (when (equal (extent-end-glyph ext) image)
 931        (set-extent-property ext 'invisible nil)
 932        (set-extent-property ext 'end-glyph nil))
 933      nil)
 934    nil nil nil nil nil 'gnus-image))
 935
 936 (defun gnus-xmas-completing-read (prompt table &optional
 937                                          predicate require-match history)
 938   (when (and history
 939              (not (boundp history)))
 940     (set history nil))
 941   (completing-read
 942    (if (symbol-value history)
 943        (concat prompt " (" (car (symbol-value history)) "): ")
 944      (concat prompt ": "))
 945    table
 946    predicate
 947    require-match
 948    nil
 949    history))
 950
 951 (provide 'gnus-xmas)
 952
 953 ;;; gnus-xmas.el ends here