git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'text-props)
  29 (defvar menu-bar-mode (featurep 'menubar))
  30 (require 'messagexmas)
  31
  32 (defgroup gnus-xmas nil
  33   "XEmacsoid support for Gnus"
  34   :group 'gnus)
  35
  36 (defcustom gnus-xmas-glyph-directory nil
  37   "Directory where Gnus logos and icons are located.
  38 If this variable is nil, Gnus will try to locate the directory
  39 automatically."
  40   :type '(choice (const :tag "autodetect" nil)
  41                  directory)
  42   :group 'gnus-xmas)
  43
  44 ;;(format "%02x%02x%02x" 114 66 20) "724214"
  45
  46 (defvar gnus-xmas-logo-color-alist
  47   '((flame "#cc3300" "#ff2200")
  48     (pine "#c0cc93" "#f8ffb8")
  49     (moss "#a1cc93" "#d2ffb8")
  50     (irish "#04cc90" "#05ff97")
  51     (sky "#049acc" "#05deff")
  52     (tin "#6886cc" "#82b6ff")
  53     (velvet "#7c68cc" "#8c82ff")
  54     (grape "#b264cc" "#cf7df")
  55     (labia "#cc64c2" "#fd7dff")
  56     (berry "#cc6485" "#ff7db5")
  57     (dino "#724214" "#1e3f03")
  58     (neutral "#b4b4b4" "#878787")
  59     (september "#bf9900" "#ffcc00"))
  60   "Color alist used for the Gnus logo.")
  61
  62 (defcustom gnus-xmas-logo-color-style 'dino
  63   "*Color styles used for the Gnus logo."
  64   :type '(choice (const flame) (const pine) (const moss)
  65                  (const irish) (const sky) (const tin)
  66                  (const velvet) (const grape) (const labia)
  67                  (const berry) (const neutral) (const september)
  68                  (const dino))
  69   :group 'gnus-xmas)
  70
  71 (defvar gnus-xmas-logo-colors
  72   (cdr (assq gnus-xmas-logo-color-style gnus-xmas-logo-color-alist))
  73   "Colors used for the Gnus logo.")
  74
  75 (defcustom gnus-article-x-face-command
  76   (if (or (featurep 'xface)
  77           (featurep 'xpm))
  78       'gnus-xmas-article-display-xface
  79     "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | xv -quit -")
  80   "*String or function to be executed to display an X-Face header.
  81 If it is a string, the command will be executed in a sub-shell
  82 asynchronously.  The compressed face will be piped to this command."
  83   :type '(choice string function))
  84
  85 ;;; Internal variables.
  86
  87 ;; Don't warn about these undefined variables.
  88
  89 (defvar gnus-group-mode-hook)
  90 (defvar gnus-summary-mode-hook)
  91 (defvar gnus-article-mode-hook)
  92
  93 ;;defined in gnus.el
  94 (defvar gnus-active-hashtb)
  95 (defvar gnus-article-buffer)
  96 (defvar gnus-auto-center-summary)
  97 (defvar gnus-current-headers)
  98 (defvar gnus-level-killed)
  99 (defvar gnus-level-zombie)
 100 (defvar gnus-newsgroup-bookmarks)
 101 (defvar gnus-newsgroup-dependencies)
 102 (defvar gnus-newsgroup-selected-overlay)
 103 (defvar gnus-newsrc-hashtb)
 104 (defvar gnus-read-mark)
 105 (defvar gnus-refer-article-method)
 106 (defvar gnus-reffed-article-number)
 107 (defvar gnus-unread-mark)
 108 (defvar gnus-version)
 109 (defvar gnus-view-pseudos)
 110 (defvar gnus-view-pseudos-separately)
 111 (defvar gnus-visual)
 112 (defvar gnus-zombie-list)
 113 ;;defined in gnus-msg.el
 114 (defvar gnus-article-copy)
 115 (defvar gnus-check-before-posting)
 116 ;;defined in gnus-vis.el
 117 (defvar gnus-article-button-face)
 118 (defvar gnus-article-mouse-face)
 119 (defvar gnus-summary-selected-face)
 120 (defvar gnus-group-reading-menu)
 121 (defvar gnus-group-group-menu)
 122 (defvar gnus-group-misc-menu)
 123 (defvar gnus-summary-article-menu)
 124 (defvar gnus-summary-thread-menu)
 125 (defvar gnus-summary-misc-menu)
 126 (defvar gnus-summary-post-menu)
 127 (defvar gnus-summary-kill-menu)
 128 (defvar gnus-article-article-menu)
 129 (defvar gnus-article-treatment-menu)
 130 (defvar gnus-mouse-2)
 131 (defvar standard-display-table)
 132 (defvar gnus-tree-minimize-window)
 133
 134 (defun gnus-xmas-set-text-properties (start end props &optional buffer)
 135   "You should NEVER use this function.  It is ideologically blasphemous.
 136 It is provided only to ease porting of broken FSF Emacs programs."
 137   (if (stringp buffer)
 138       nil
 139     (map-extents (lambda (extent ignored)
 140                    (remove-text-properties
 141                     start end
 142                     (list (extent-property extent 'text-prop) nil)
 143                     buffer)
 144                    nil)
 145                  buffer start end nil nil 'text-prop)
 146     (gnus-add-text-properties start end props buffer)))
 147
 148 (defun gnus-xmas-highlight-selected-summary ()
 149   ;; Highlight selected article in summary buffer
 150   (when gnus-summary-selected-face
 151     (when gnus-newsgroup-selected-overlay
 152       (delete-extent gnus-newsgroup-selected-overlay))
 153     (setq gnus-newsgroup-selected-overlay
 154           (make-extent (gnus-point-at-bol) (gnus-point-at-eol)))
 155     (set-extent-face gnus-newsgroup-selected-overlay
 156                      gnus-summary-selected-face)))
 157
 158 (defcustom gnus-xmas-force-redisplay nil
 159   "*If non-nil, force a redisplay before recentering the summary buffer.
 160 This is ugly, but it works around a bug in `window-displayed-height'."
 161   :type 'boolean
 162   :group 'gnus-xmas)
 163
 164 (defun gnus-xmas-switch-horizontal-scrollbar-off ()
 165   (when (featurep 'scrollbar)
 166     (set-specifier scrollbar-height (cons (current-buffer) 0))))
 167
 168 (defun gnus-xmas-summary-recenter ()
 169   "\"Center\" point in the summary window.
 170 If `gnus-auto-center-summary' is nil, or the article buffer isn't
 171 displayed, no centering will be performed."
 172   ;; Suggested by earle@mahendo.JPL.NASA.GOV (Greg Earle).
 173   ;; Recenter only when requested.  Suggested by popovich@park.cs.columbia.edu.
 174   ;; Force redisplay to get properly computed window height.
 175   (when gnus-xmas-force-redisplay
 176     (sit-for 0))
 177   (when gnus-auto-center-summary
 178     (let* ((height (if (fboundp 'window-displayed-height)
 179                        (window-displayed-height)
 180                      (- (window-height) 2)))
 181            (top (cond ((< height 4) 0)
 182                       ((< height 7) 1)
 183                       (t 2)))
 184            (bottom (save-excursion (goto-char (point-max))
 185                                    (forward-line (- height))
 186                                    (point)))
 187            (window (get-buffer-window (current-buffer))))
 188       (when (get-buffer-window gnus-article-buffer)
 189         ;; Only do recentering when the article buffer is displayed,
 190         ;; Set the window start to either `bottom', which is the biggest
 191         ;; possible valid number, or the second line from the top,
 192         ;; whichever is the least.
 193         (set-window-start
 194          window (min bottom (save-excursion (forward-line (- top)) (point)))))
 195       ;; Do horizontal recentering while we're at it.
 196       (when (and (get-buffer-window (current-buffer) t)
 197                  (not (eq gnus-auto-center-summary 'vertical)))
 198         (let ((selected (selected-window)))
 199           (select-window (get-buffer-window (current-buffer) t))
 200           (gnus-summary-position-point)
 201           (gnus-horizontal-recenter)
 202           (select-window selected))))))
 203
 204 (defun gnus-xmas-summary-set-display-table ()
 205   ;; Setup the display table -- like `gnus-summary-setup-display-table',
 206   ;; but done in an XEmacsish way.
 207   (let ((table (make-display-table))
 208         (i 32))
 209     ;; Nix out all the control chars...
 210     (while (>= (setq i (1- i)) 0)
 211       (aset table i [??]))
 212     ;; ... but not newline and cr, of course.  (cr is necessary for the
 213     ;; selective display).
 214     (aset table ?\n nil)
 215     (aset table ?\r nil)
 216     ;; We keep TAB as well.
 217     (aset table ?\t nil)
 218     ;; We nix out any glyphs over 126 below ctl-arrow.
 219     (let ((i (if (integerp ctl-arrow) ctl-arrow 160)))
 220       (while (>= (setq i (1- i)) 127)
 221         (unless (aref table i)
 222           (aset table i [??]))))
 223     ;; Can't use `set-specifier' because of a bug in 19.14 and earlier
 224     (add-spec-to-specifier current-display-table table (current-buffer) nil)))
 225
 226 (defun gnus-xmas-add-text-properties (start end props &optional object)
 227   (add-text-properties start end props object)
 228   (put-text-property start end 'start-closed nil object))
 229
 230 (defun gnus-xmas-put-text-property (start end prop value &optional object)
 231   (put-text-property start end prop value object)
 232   (put-text-property start end 'start-closed nil object))
 233
 234 (defun gnus-xmas-extent-start-open (point)
 235   (map-extents (lambda (extent arg)
 236                  (set-extent-property extent 'start-open t))
 237                nil point (min (1+ (point)) (point-max))))
 238
 239 (defun gnus-xmas-article-push-button (event)
 240   "Check text under the mouse pointer for a callback function.
 241 If the text under the mouse pointer has a `gnus-callback' property,
 242 call it with the value of the `gnus-data' text property."
 243   (interactive "e")
 244   (set-buffer (window-buffer (event-window event)))
 245   (let* ((pos (event-closest-point event))
 246          (data (get-text-property pos 'gnus-data))
 247          (fun (get-text-property pos 'gnus-callback)))
 248     (when fun
 249       (funcall fun data))))
 250
 251 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 252   (set-extent-endpoints extent start end buffer))
 253
 254 (defun gnus-xmas-kill-all-overlays ()
 255   "Delete all extents in the current buffer."
 256   (map-extents (lambda (extent ignore)
 257                  (delete-extent extent)
 258                  nil)))
 259
 260 ;; Fixed by Christopher Davis <ckd@loiosh.kei.com>.
 261 (defun gnus-xmas-article-add-button (from to fun &optional data)
 262   "Create a button between FROM and TO with callback FUN and data DATA."
 263   (when gnus-article-button-face
 264     (gnus-overlay-put (gnus-make-overlay from to)
 265                       'face gnus-article-button-face))
 266   (gnus-add-text-properties
 267    from to
 268    (nconc
 269     (and gnus-article-mouse-face
 270          (list 'mouse-face gnus-article-mouse-face))
 271     (list 'gnus-callback fun)
 272     (and data (list 'gnus-data data))
 273     (list 'highlight t))))
 274
 275 (defun gnus-xmas-window-top-edge (&optional window)
 276   (nth 1 (window-pixel-edges window)))
 277
 278 (defun gnus-xmas-tree-minimize ()
 279   (when (and gnus-tree-minimize-window
 280              (not (one-window-p)))
 281     (let* ((window-min-height 2)
 282            (height (1+ (count-lines (point-min) (point-max))))
 283            (min (max (1- window-min-height) height))
 284            (tot (if (numberp gnus-tree-minimize-window)
 285                     (min gnus-tree-minimize-window min)
 286                   min))
 287            (win (get-buffer-window (current-buffer)))
 288            (wh (and win (1- (window-height win)))))
 289       (when (and win
 290                  (not (eq tot wh)))
 291         (let ((selected (selected-window)))
 292           (select-window win)
 293           (enlarge-window (- tot wh))
 294           (select-window selected))))))
 295
 296 ;; Select the lowest window on the frame.
 297 (defun gnus-xmas-appt-select-lowest-window ()
 298   (let* ((lowest-window (selected-window))
 299          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 300          (last-window (previous-window))
 301          (window-search t))
 302     (while window-search
 303       (let* ((this-window (next-window))
 304              (next-bottom-edge (car (cdr (cdr (cdr
 305                                                (window-pixel-edges
 306                                                 this-window)))))))
 307         (when (< bottom-edge next-bottom-edge)
 308           (setq bottom-edge next-bottom-edge)
 309           (setq lowest-window this-window))
 310
 311         (select-window this-window)
 312         (when (eq last-window this-window)
 313           (select-window lowest-window)
 314           (setq window-search nil))))))
 315
 316 (defmacro gnus-xmas-menu-add (type &rest menus)
 317   `(gnus-xmas-menu-add-1 ',type ',menus))
 318 (put 'gnus-xmas-menu-add 'lisp-indent-function 1)
 319
 320 (defun gnus-xmas-menu-add-1 (type menus)
 321   (when (and menu-bar-mode
 322              (gnus-visual-p (intern (format "%s-menu" type)) 'menu))
 323     (while menus
 324       (easy-menu-add (symbol-value (pop menus))))))
 325
 326 (defun gnus-xmas-group-menu-add ()
 327   (gnus-xmas-menu-add group
 328     gnus-group-reading-menu gnus-group-group-menu gnus-group-misc-menu))
 329
 330 (defun gnus-xmas-summary-menu-add ()
 331   (gnus-xmas-menu-add summary
 332     gnus-summary-misc-menu gnus-summary-kill-menu
 333     gnus-summary-article-menu gnus-summary-thread-menu
 334     gnus-summary-post-menu ))
 335
 336 (defun gnus-xmas-article-menu-add ()
 337   (gnus-xmas-menu-add article
 338     gnus-article-article-menu gnus-article-treatment-menu))
 339
 340 (defun gnus-xmas-score-menu-add ()
 341   (gnus-xmas-menu-add score
 342     gnus-score-menu))
 343
 344 (defun gnus-xmas-pick-menu-add ()
 345   (gnus-xmas-menu-add pick
 346     gnus-pick-menu))
 347
 348 (defun gnus-xmas-topic-menu-add ()
 349   (gnus-xmas-menu-add topic
 350     gnus-topic-menu))
 351
 352 (defun gnus-xmas-binary-menu-add ()
 353   (gnus-xmas-menu-add binary
 354     gnus-binary-menu))
 355
 356 (defun gnus-xmas-agent-summary-menu-add ()
 357   (gnus-xmas-menu-add agent-summary
 358     gnus-agent-summary-menu))
 359
 360 (defun gnus-xmas-agent-group-menu-add ()
 361   (gnus-xmas-menu-add agent-group
 362     gnus-agent-group-menu))
 363
 364 (defun gnus-xmas-agent-server-menu-add ()
 365   (gnus-xmas-menu-add agent-server
 366     gnus-agent-server-menu))
 367
 368 (defun gnus-xmas-tree-menu-add ()
 369   (gnus-xmas-menu-add tree
 370     gnus-tree-menu))
 371
 372 (defun gnus-xmas-draft-menu-add ()
 373   (gnus-xmas-menu-add draft
 374     gnus-draft-menu))
 375
 376 (defun gnus-xmas-server-menu-add ()
 377   (gnus-xmas-menu-add menu
 378     gnus-server-server-menu gnus-server-connections-menu))
 379
 380 (defun gnus-xmas-browse-menu-add ()
 381   (gnus-xmas-menu-add browse
 382     gnus-browse-menu))
 383
 384 (defun gnus-xmas-grouplens-menu-add ()
 385   (gnus-xmas-menu-add grouplens
 386     gnus-grouplens-menu))
 387
 388 (defun gnus-xmas-read-event-char ()
 389   "Get the next event."
 390   (let ((event (next-command-event)))
 391     (sit-for 0)
 392     ;; We junk all non-key events.  Is this naughty?
 393     (while (not (or (key-press-event-p event)
 394                     (button-press-event-p event)))
 395       (dispatch-event event)
 396       (setq event (next-command-event)))
 397     (cons (and (key-press-event-p event)
 398                (event-to-character event))
 399           event)))
 400
 401 (defun gnus-xmas-seconds-since-epoch (date)
 402   "Return a floating point number that says how many seconds have lapsed between Jan 1 12:00:00 1970 and DATE."
 403   (let* ((tdate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 404                         (timezone-parse-date date)))
 405          (ttime (mapcar (lambda (ti) (and ti (string-to-int ti)))
 406                         (timezone-parse-time
 407                          (aref (timezone-parse-date date) 3))))
 408          (edate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 409                         (timezone-parse-date "Jan 1 12:00:00 1970")))
 410          (tday (- (timezone-absolute-from-gregorian
 411                    (nth 1 tdate) (nth 2 tdate) (nth 0 tdate))
 412                   (timezone-absolute-from-gregorian
 413                    (nth 1 edate) (nth 2 edate) (nth 0 edate)))))
 414     (+ (nth 2 ttime)
 415        (* (nth 1 ttime) 60)
 416        (* (float (nth 0 ttime)) 60 60)
 417        (* (float tday) 60 60 24))))
 418
 419 (defun gnus-xmas-define ()
 420   (setq gnus-mouse-2 [button2])
 421
 422   (unless (memq 'underline (face-list))
 423     (and (fboundp 'make-face)
 424          (funcall (intern "make-face") 'underline)))
 425   ;; Must avoid calling set-face-underline-p directly, because it
 426   ;; is a defsubst in emacs19, and will make the .elc files non
 427   ;; portable!
 428   (unless (face-differs-from-default-p 'underline)
 429     (funcall (intern "set-face-underline-p") 'underline t))
 430
 431   (cond
 432    ((fboundp 'char-or-char-int-p)
 433     ;; Handle both types of marks for XEmacs-20.x.
 434     (fset 'gnus-characterp 'char-or-char-int-p))
 435    ;; V19 of XEmacs, probably.
 436    (t
 437     (fset 'gnus-characterp 'characterp)))
 438
 439   (fset 'gnus-make-overlay 'make-extent)
 440   (fset 'gnus-delete-overlay 'delete-extent)
 441   (fset 'gnus-overlay-put 'set-extent-property)
 442   (fset 'gnus-move-overlay 'gnus-xmas-move-overlay)
 443   (fset 'gnus-overlay-end 'extent-end-position)
 444   (fset 'gnus-kill-all-overlays 'gnus-xmas-kill-all-overlays)
 445   (fset 'gnus-extent-detached-p 'extent-detached-p)
 446   (fset 'gnus-add-text-properties 'gnus-xmas-add-text-properties)
 447   (fset 'gnus-put-text-property 'gnus-xmas-put-text-property)
 448   (fset 'gnus-deactivate-mark 'ignore)
 449   (fset 'gnus-window-edges 'window-pixel-edges)
 450
 451   (if (and (<= emacs-major-version 19)
 452            (< emacs-minor-version 14))
 453       (fset 'gnus-set-text-properties 'gnus-xmas-set-text-properties))
 454
 455   (when (fboundp 'turn-off-scroll-in-place)
 456     (add-hook 'gnus-article-mode-hook 'turn-off-scroll-in-place))
 457
 458   (unless (boundp 'standard-display-table)
 459     (setq standard-display-table nil))
 460
 461   (defvar gnus-mouse-face-prop 'highlight)
 462
 463   (unless (fboundp 'encode-time)
 464     (defun encode-time (sec minute hour day month year &optional zone)
 465       (let ((seconds
 466              (gnus-xmas-seconds-since-epoch
 467               (timezone-make-arpa-date
 468                year month day (timezone-make-time-string hour minute sec)
 469                zone))))
 470         (list (floor (/ seconds (expt 2 16)))
 471               (round (mod seconds (expt 2 16)))))))
 472
 473   (defun gnus-byte-code (func)
 474     "Return a form that can be `eval'ed based on FUNC."
 475     (let ((fval (indirect-function func)))
 476       (if (compiled-function-p fval)
 477           (list 'funcall fval)
 478         (cons 'progn (cdr (cdr fval))))))
 479
 480   (fset 'gnus-x-color-values
 481         (if (fboundp 'x-color-values)
 482             'x-color-values
 483           (lambda (color)
 484             (color-instance-rgb-components
 485              (make-color-instance color))))))
 486
 487 (defun gnus-xmas-redefine ()
 488   "Redefine lots of Gnus functions for XEmacs."
 489   (fset 'gnus-summary-set-display-table 'gnus-xmas-summary-set-display-table)
 490   (fset 'gnus-visual-turn-off-edit-menu 'identity)
 491   (fset 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 492   (fset 'gnus-extent-start-open 'gnus-xmas-extent-start-open)
 493   (fset 'gnus-article-push-button 'gnus-xmas-article-push-button)
 494   (fset 'gnus-article-add-button 'gnus-xmas-article-add-button)
 495   (fset 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 496   (fset 'gnus-read-event-char 'gnus-xmas-read-event-char)
 497   (fset 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 498   (fset 'gnus-tree-minimize 'gnus-xmas-tree-minimize)
 499   (fset 'gnus-appt-select-lowest-window
 500         'gnus-xmas-appt-select-lowest-window)
 501   (fset 'gnus-mail-strip-quoted-names 'gnus-xmas-mail-strip-quoted-names)
 502   (fset 'gnus-character-to-event 'character-to-event)
 503   (fset 'gnus-mode-line-buffer-identification
 504         'gnus-xmas-mode-line-buffer-identification)
 505   (fset 'gnus-key-press-event-p 'key-press-event-p)
 506   (fset 'gnus-region-active-p 'region-active-p)
 507
 508   (add-hook 'gnus-group-mode-hook 'gnus-xmas-group-menu-add)
 509   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-summary-menu-add)
 510   (add-hook 'gnus-article-mode-hook 'gnus-xmas-article-menu-add)
 511   (add-hook 'gnus-score-mode-hook 'gnus-xmas-score-menu-add)
 512
 513   (add-hook 'gnus-pick-mode-hook 'gnus-xmas-pick-menu-add)
 514   (add-hook 'gnus-topic-mode-hook 'gnus-xmas-topic-menu-add)
 515   (add-hook 'gnus-tree-mode-hook 'gnus-xmas-tree-menu-add)
 516   (add-hook 'gnus-binary-mode-hook 'gnus-xmas-binary-menu-add)
 517   (add-hook 'gnus-grouplens-mode-hook 'gnus-xmas-grouplens-menu-add)
 518   (add-hook 'gnus-server-mode-hook 'gnus-xmas-server-menu-add)
 519   (add-hook 'gnus-browse-mode-hook 'gnus-xmas-browse-menu-add)
 520
 521   (add-hook 'gnus-group-mode-hook 'gnus-xmas-setup-group-toolbar)
 522   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-setup-summary-toolbar)
 523
 524   (add-hook 'gnus-agent-summary-mode-hook 'gnus-xmas-agent-summary-menu-add)
 525   (add-hook 'gnus-agent-group-mode-hook 'gnus-xmas-agent-group-menu-add)
 526   (add-hook 'gnus-agent-server-mode-hook 'gnus-xmas-agent-server-menu-add)
 527
 528   (add-hook 'gnus-draft-mode-hook 'gnus-xmas-draft-menu-add)
 529   (add-hook 'gnus-summary-mode-hook
 530             'gnus-xmas-switch-horizontal-scrollbar-off)
 531   (add-hook 'gnus-tree-mode-hook 'gnus-xmas-switch-horizontal-scrollbar-off)
 532
 533   (when (featurep 'mule)
 534     (defun gnus-truncate-string (str end-column &optional start-column padding)
 535       "Truncate string STR to end at column END-COLUMN.
 536 The optional 2nd arg START-COLUMN, if non-nil, specifies
 537 the starting column; that means to return the characters occupying
 538 columns START-COLUMN ... END-COLUMN of STR.
 539
 540 The optional 3rd arg PADDING, if non-nil, specifies a padding character
 541 to add at the end of the result if STR doesn't reach column END-COLUMN,
 542 or if END-COLUMN comes in the middle of a character in STR.
 543 PADDING is also added at the beginning of the result
 544 if column START-COLUMN appears in the middle of a character in STR.
 545
 546 If PADDING is nil, no padding is added in these cases, so
 547 the resulting string may be narrower than END-COLUMN.
 548 \[Emacs 20.3 emulating function]"
 549       (or start-column
 550           (setq start-column 0))
 551       (let ((len (length str))
 552             (idx 0)
 553             (column 0)
 554             (head-padding "") (tail-padding "")
 555             ch last-column last-idx from-idx)
 556         (condition-case nil
 557             (while (< column start-column)
 558               (setq ch (aref str idx)
 559                     column (+ column (char-width ch))
 560                     idx (1+ idx)))
 561           (args-out-of-range (setq idx len)))
 562         (if (< column start-column)
 563             (if padding (make-string end-column padding) "")
 564           (if (and padding (> column start-column))
 565               (setq head-padding
 566                     (make-string (- column start-column) padding)))
 567           (setq from-idx idx)
 568           (if (< end-column column)
 569               (setq idx from-idx)
 570             (condition-case nil
 571                 (while (< column end-column)
 572                   (setq last-column column
 573                         last-idx idx
 574                         ch (aref str idx)
 575                         column (+ column (char-width ch))
 576                         idx (1+ idx)))
 577               (args-out-of-range (setq idx len)))
 578             (if (> column end-column)
 579                 (setq column last-column idx last-idx))
 580             (if (and padding (< column end-column))
 581                 (setq tail-padding
 582                       (make-string (- end-column column) padding))))
 583           (setq str (substring str from-idx idx))
 584           (if padding
 585               (concat head-padding str tail-padding)
 586             str))))
 587
 588     (defun gnus-tilde-pad-form (el pad-width)
 589       "Return a form that pads EL to PAD-WIDTH."
 590       (let ((pad (abs pad-width)))
 591         (if (symbolp el)
 592             (if (< pad-width 0)
 593                 `(concat ,el (make-string
 594                               (max 0 (- ,pad (string-width ,el))) ?\ ))
 595               `(concat (make-string
 596                         (max 0 (- ,pad (string-width ,el))) ?\ )
 597                        ,el))
 598           (if (< pad-width 0)
 599               `(let ((val (eval ,el)))
 600                  (concat val (make-string
 601                               (max 0 (- ,pad (string-width val))) ?\ )))
 602             `(let ((val (eval ,el)))
 603                (concat (make-string
 604                         (max 0 (- ,pad (string-width val))) ?\ )
 605                        val))))))
 606
 607     (defun gnus-tilde-max-form (el max-width)
 608       "Return a form that limits EL to MAX-WIDTH."
 609       (let ((max (abs max-width)))
 610         (if (symbolp el)
 611             (if (< max-width 0)
 612                 `(let ((width (string-width ,el)))
 613                    (gnus-truncate-string ,el width (- width ,max)))
 614               `(gnus-truncate-string ,el ,max))
 615           (if (< max-width 0)
 616               `(let* ((val (eval ,el))
 617                       (width (string-width val)))
 618                  (gnus-truncate-string val width (- width ,max)))
 619             `(let ((val (eval ,el)))
 620                (gnus-truncate-string val ,max))))))
 621
 622     (defun gnus-tilde-cut-form (el cut-width)
 623       "Return a form that cuts CUT-WIDTH off of EL."
 624       (let ((cut (abs cut-width)))
 625         (if (symbolp el)
 626             (if (< cut-width 0)
 627                 `(gnus-truncate-string ,el (- (string-width ,el) ,cut))
 628               `(gnus-truncate-string ,el (string-width ,el) ,cut))
 629           (if (< cut-width 0)
 630               `(let ((val (eval ,el)))
 631                  (gnus-truncate-string val (- (string-width val) ,cut)))
 632             `(let ((val (eval ,el)))
 633                (gnus-truncate-string val (string-width val) ,cut))))))
 634     ))
 635
 636 ;;; XEmacs logo and toolbar.
 637
 638 (defun gnus-xmas-group-startup-message (&optional x y)
 639   "Insert startup message in current buffer."
 640   ;; Insert the message.
 641   (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 642   (erase-buffer)
 643   (cond
 644    ((and (console-on-window-system-p)
 645          (or (featurep 'xpm)
 646              (featurep 'xbm)))
 647     (let* ((logo-xpm (expand-file-name "gnus.xpm" gnus-xmas-glyph-directory))
 648            (logo-xbm (expand-file-name "gnus.xbm" gnus-xmas-glyph-directory))
 649            (glyph (make-glyph
 650                    (cond ((featurep 'xpm)
 651                           `[xpm
 652                             :file ,logo-xpm
 653                             :color-symbols
 654                             (("thing" . ,(car gnus-xmas-logo-colors))
 655                              ("shadow" . ,(cadr gnus-xmas-logo-colors))
 656                              ("background" . ,(face-background 'default)))])
 657                          ((featurep 'xbm)
 658                           `[xbm :file ,logo-xbm])
 659                          (t [nothing])))))
 660       (insert " ")
 661       (set-extent-begin-glyph (make-extent (point) (point)) glyph)
 662       (goto-char (point-min))
 663       (while (not (eobp))
 664         (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 665                              ?\ ))
 666         (forward-line 1))
 667       (setq gnus-simple-splash nil))
 668     (goto-char (point-min))
 669     (let* ((pheight (+ 20 (count-lines (point-min) (point-max))))
 670            (wheight (window-height))
 671            (rest (- wheight pheight)))
 672       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 673    (t
 674     (insert
 675      (format "              %s
 676           _    ___ _             _
 677           _ ___ __ ___  __    _ ___
 678           __   _     ___    __  ___
 679               _           ___     _
 680              _  _ __             _
 681              ___   __            _
 682                    __           _
 683                     _      _   _
 684                    _      _    _
 685                       _  _    _
 686                   __  ___
 687                  _   _ _     _
 688                 _   _
 689               _    _
 690              _    _
 691             _
 692           __
 693
 694 "
 695              ""))
 696     ;; And then hack it.
 697     (gnus-indent-rigidly (point-min) (point-max)
 698                          (/ (max (- (window-width) (or x 46)) 0) 2))
 699     (goto-char (point-min))
 700     (forward-line 1)
 701     (let* ((pheight (count-lines (point-min) (point-max)))
 702            (wheight (window-height))
 703            (rest (- wheight pheight)))
 704       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n)))
 705     ;; Paint it.
 706     (put-text-property (point-min) (point-max) 'face 'gnus-splash-face)))
 707   (setq modeline-buffer-identification
 708         (list (concat gnus-version ": *Group*")))
 709   (set-buffer-modified-p t))
 710
 711
 712 ;;; The toolbar.
 713
 714 (defcustom gnus-use-toolbar (if (featurep 'toolbar)
 715                                 'default-toolbar
 716                               nil)
 717   "*If nil, do not use a toolbar.
 718 If it is non-nil, it must be a toolbar.  The five legal values are
 719 `default-toolbar', `top-toolbar', `bottom-toolbar',
 720 `right-toolbar', and `left-toolbar'."
 721   :type '(choice (const default-toolbar)
 722                  (const top-toolbar) (const bottom-toolbar)
 723                  (const left-toolbar) (const right-toolbar)
 724                  (const :tag "no toolbar" nil))
 725   :group 'gnus-xmas)
 726
 727 (defvar gnus-group-toolbar
 728   '([gnus-group-get-new-news gnus-group-get-new-news t "Get new news"]
 729     [gnus-group-get-new-news-this-group
 730      gnus-group-get-new-news-this-group t "Get new news in this group"]
 731     [gnus-group-catchup-current
 732      gnus-group-catchup-current t "Catchup group"]
 733     [gnus-group-describe-group
 734      gnus-group-describe-group t "Describe group"]
 735     [gnus-group-unsubscribe gnus-group-unsubscribe t "Unsubscribe group"]
 736     [gnus-group-subscribe gnus-group-subscribe t "Subscribe group"]
 737     [gnus-group-kill-group gnus-group-kill-group t "Kill group"]
 738     [gnus-group-exit gnus-group-exit t "Exit Gnus"]
 739     )
 740   "The group buffer toolbar.")
 741
 742 (defvar gnus-summary-toolbar
 743   '([gnus-summary-prev-unread
 744      gnus-summary-prev-page-or-article t "Page up"]
 745     [gnus-summary-next-unread
 746      gnus-summary-next-page t "Page down"]
 747     [gnus-summary-post-news
 748      gnus-summary-post-news t "Post an article"]
 749     [gnus-summary-followup-with-original
 750      gnus-summary-followup-with-original t
 751      "Post a followup and yank the original"]
 752     [gnus-summary-followup
 753      gnus-summary-followup t "Post a followup"]
 754     [gnus-summary-reply-with-original
 755      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 756     [gnus-summary-reply
 757      gnus-summary-reply t "Mail a reply"]
 758     [gnus-summary-caesar-message
 759      gnus-summary-caesar-message t "Rot 13"]
 760     [gnus-uu-decode-uu
 761      gnus-uu-decode-uu t "Decode uuencoded articles"]
 762     [gnus-summary-save-article-file
 763      gnus-summary-save-article-file t "Save article in file"]
 764     [gnus-summary-save-article
 765      gnus-summary-save-article t "Save article"]
 766     [gnus-uu-post-news
 767      gnus-uu-post-news t "Post a uuencoded article"]
 768     [gnus-summary-cancel-article
 769      gnus-summary-cancel-article t "Cancel article"]
 770     [gnus-summary-catchup
 771      gnus-summary-catchup t "Catchup"]
 772     [gnus-summary-catchup-and-exit
 773      gnus-summary-catchup-and-exit t "Catchup and exit"]
 774     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 775     )
 776   "The summary buffer toolbar.")
 777
 778 (defvar gnus-summary-mail-toolbar
 779   '(
 780     [gnus-summary-prev-unread
 781      gnus-summary-prev-unread-article t "Prev unread article"]
 782     [gnus-summary-next-unread
 783      gnus-summary-next-unread-article t "Next unread article"]
 784     [gnus-summary-mail-reply gnus-summary-reply t "Reply"]
 785 ;    [gnus-summary-mail-get gnus-mail-get t "Message get"]
 786     [gnus-summary-mail-originate gnus-summary-post-news t "Originate"]
 787     [gnus-summary-mail-save gnus-summary-save-article t "Save"]
 788     [gnus-summary-mail-copy gnus-summary-copy-article t "Copy message"]
 789 ;    [gnus-summary-mail-delete gnus-summary-delete-article t "Delete message"]
 790     [gnus-summary-mail-forward gnus-summary-mail-forward t "Forward message"]
 791 ;    [gnus-summary-mail-spell gnus-mail-spell t "Spell"]
 792 ;    [gnus-summary-mail-help gnus-mail-help  t "Message help"]
 793     [gnus-summary-caesar-message
 794      gnus-summary-caesar-message t "Rot 13"]
 795     [gnus-uu-decode-uu
 796      gnus-uu-decode-uu t "Decode uuencoded articles"]
 797     [gnus-summary-save-article-file
 798      gnus-summary-save-article-file t "Save article in file"]
 799     [gnus-summary-save-article
 800      gnus-summary-save-article t "Save article"]
 801     [gnus-summary-catchup
 802      gnus-summary-catchup t "Catchup"]
 803     [gnus-summary-catchup-and-exit
 804      gnus-summary-catchup-and-exit t "Catchup and exit"]
 805     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 806     )
 807   "The summary buffer mail toolbar.")
 808
 809 (defun gnus-xmas-setup-group-toolbar ()
 810   (and gnus-use-toolbar
 811        (message-xmas-setup-toolbar gnus-group-toolbar nil "gnus")
 812        (set-specifier (symbol-value gnus-use-toolbar)
 813                       (cons (current-buffer) gnus-group-toolbar))))
 814
 815 (defun gnus-xmas-setup-summary-toolbar ()
 816   (let ((bar (if (gnus-news-group-p gnus-newsgroup-name)
 817                  gnus-summary-toolbar gnus-summary-mail-toolbar)))
 818     (and gnus-use-toolbar
 819          (message-xmas-setup-toolbar bar nil "gnus")
 820          (set-specifier (symbol-value gnus-use-toolbar)
 821                         (cons (current-buffer) bar)))))
 822
 823 (defun gnus-xmas-mail-strip-quoted-names (address)
 824   "Protect mail-strip-quoted-names from NIL input.
 825 XEmacs compatibility workaround."
 826   (if (null address)
 827       nil
 828     (mail-strip-quoted-names address)))
 829
 830 (defun gnus-xmas-call-region (command &rest args)
 831   (apply
 832    'call-process-region (point-min) (point-max) command t '(t nil) nil
 833    args))
 834
 835 (defface gnus-x-face '((t (:foreground "black" :background "white")))
 836   "Face to show X face"
 837   :group 'gnus-xmas)
 838
 839 (defun gnus-xmas-article-display-xface (beg end)
 840   "Display any XFace headers in the current article."
 841   (save-excursion
 842     (let ((xface-glyph
 843            (cond ((featurep 'xface)
 844                   (make-glyph (vector 'xface :data
 845                                       (concat "X-Face: "
 846                                               (buffer-substring beg end)))))
 847                  ((featurep 'xpm)
 848                   (let ((cur (current-buffer)))
 849                     (save-excursion
 850                       (gnus-set-work-buffer)
 851                       (insert (format "%s" (buffer-substring beg end cur)))
 852                       (gnus-xmas-call-region "uncompface")
 853                       (goto-char (point-min))
 854                       (insert "/* Width=48, Height=48 */\n")
 855                       (gnus-xmas-call-region "icontopbm")
 856                       (gnus-xmas-call-region "ppmtoxpm")
 857                       (make-glyph
 858                        (vector 'xpm :data (buffer-string))))))
 859                  (t
 860                   (make-glyph [nothing]))))
 861           (ext (make-extent (progn
 862                               (goto-char (point-min))
 863                               (re-search-forward "^From:" nil t)
 864                               (point))
 865                             (1+ (point)))))
 866       (set-glyph-face xface-glyph 'gnus-x-face)
 867       (set-extent-begin-glyph ext xface-glyph)
 868       (set-extent-property ext 'duplicable t))))
 869
 870 ;;(defvar gnus-xmas-pointer-glyph
 871 ;;  (progn
 872 ;;    (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory
 873 ;;                                     "gnus"))
 874 ;;    (let ((file-xpm (expand-file-name "gnus-pointer.xpm"
 875 ;;                                    gnus-xmas-glyph-directory))
 876 ;;        (file-xbm (expand-file-name "gnus-pointer.xbm"
 877 ;;                                    gnus-xmas-glyph-directory)))
 878 ;;      (make-pointer-glyph
 879 ;;       (list (vector 'xpm ':file file-xpm)
 880 ;;           (vector 'xbm ':file file-xbm))))))
 881
 882 (defvar gnus-xmas-modeline-left-extent
 883   (let ((ext (copy-extent modeline-buffer-id-left-extent)))
 884 ;    (set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 885     ext))
 886
 887 (defvar gnus-xmas-modeline-right-extent
 888   (let ((ext (copy-extent modeline-buffer-id-right-extent)))
 889 ;    (set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 890     ext))
 891
 892 (defvar gnus-xmas-modeline-glyph
 893   (progn
 894     (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 895     (let* ((file-xpm (expand-file-name "gnus-pointer.xpm"
 896                                        gnus-xmas-glyph-directory))
 897            (file-xbm (expand-file-name "gnus-pointer.xbm"
 898                                        gnus-xmas-glyph-directory))
 899            (glyph (make-glyph
 900                    ;; Gag gag gag.
 901                    (cond ((featurep 'xpm)
 902                           ;; Let's try a nifty XPM
 903                           `[xpm :file ,file-xpm])
 904                          ((featurep 'xbm)
 905                           ;; Then a not-so-nifty XBM
 906                           [xbm :file ,file-xbm])
 907                          ;; Then the simple string
 908                          (t [string :data "Gnus:"])))))
 909       (set-glyph-face glyph 'modeline-buffer-id)
 910       glyph)))
 911
 912 (defun gnus-xmas-mode-line-buffer-identification (line)
 913   (let ((line (car line))
 914         chop)
 915     (cond
 916      ;; This is some weird type of id.
 917      ((not (stringp line))
 918       (list line))
 919      ;; This is non-standard, so we just pass it through.
 920      ((not (string-match "^Gnus:" line))
 921       (list line))
 922      ;; We have a standard line, so we colorize and glyphize it a bit.
 923      (t
 924       (setq chop (match-end 0))
 925       (list
 926        (if gnus-xmas-modeline-glyph
 927            (cons gnus-xmas-modeline-left-extent gnus-xmas-modeline-glyph)
 928          (cons gnus-xmas-modeline-left-extent (substring line 0 chop)))
 929        (cons gnus-xmas-modeline-right-extent (substring line chop)))))))
 930
 931 (defun gnus-xmas-splash ()
 932   (when (eq (device-type) 'x)
 933     (gnus-splash)))
 934
 935 (provide 'gnus-xmas)
 936
 937 ;;; gnus-xmas.el ends here