git.chise.org Git - chise/xemacs-chise.git.1/blob - lisp/menubar.el

   1 ;;; menubar.el --- Menubar support for XEmacs
   2
   3 ;; Copyright (C) 1991-4, 1997-1998 Free Software Foundation, Inc.
   4 ;; Copyright (C) 1995 Tinker Systems and INS Engineering Corp.
   5 ;; Copyright (C) 1995, 1996 Ben Wing.
   6
   7 ;; Maintainer: XEmacs Development Team
   8 ;; Keywords: internal, extensions, dumped
   9
  10 ;; This file is part of XEmacs.
  11
  12 ;; XEmacs is free software; you can redistribute it and/or modify it
  13 ;; under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; XEmacs is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with XEmacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Synched up with: Not in FSF. (Completely divergent from FSF menu-bar.el)
  28
  29 ;;; Commentary:
  30
  31 ;; This file is dumped with XEmacs (when menubar support is compiled in).
  32
  33 ;; Some stuff in FSF menu-bar.el is in x-menubar.el
  34
  35 ;;; Code:
  36
  37 (defgroup menu nil
  38   "Input from the menus."
  39   :group 'environment)
  40
  41 (defvar default-menubar nil)
  42
  43 ;; this function is considered "part of the lexicon" by many,
  44 ;; so we'll leave it here.
  45 (defun kill-this-buffer ()      ; for the menubar
  46   "Kill the current buffer."
  47   (interactive)
  48   (kill-buffer (current-buffer)))
  49
  50 (defun set-menubar-dirty-flag ()
  51   "Tell XEmacs that the menubar has to be updated.
  52 NOTE: XEmacs now recognizes when you set a different value for
  53 `current-menubar'.  You *only* need to call this function if you
  54 destructively modify a part of the menubar and don't set `current-menubar'.
  55 Note that all the functions that modify a menu call this automatically."
  56   (setq-default current-menubar (default-value 'current-menubar)))
  57
  58 ;; #### shouldn't this perhaps be `copy-tree'?
  59 (defun set-menubar (menubar)
  60   "Set the default menubar to be MENUBAR.
  61 See `current-menubar' for a description of the syntax of a menubar."
  62   (check-menu-syntax menubar t)
  63   (setq-default current-menubar (copy-sequence menubar)))
  64
  65 (defun set-buffer-menubar (menubar)
  66   "Set the buffer-local menubar to be MENUBAR.
  67 See `current-menubar' for a description of the syntax of a menubar."
  68   (check-menu-syntax menubar t)
  69   (make-local-variable 'current-menubar)
  70   (setq current-menubar (copy-sequence menubar)))
  71
  72 (defun check-menu-syntax (menu &optional menubar-p)
  73   ;; The C code does syntax checking on the value of `current-menubar',
  74   ;; but it's better to do it early, before things have gotten messed up.
  75   (if menubar-p
  76       nil
  77     (or (stringp (car menu))
  78         (signal 'error
  79                 (list "menu name (first element) must be a string" menu)))
  80     ;;(or (cdr menu) (signal 'error (list "menu is empty" menu)))
  81     (setq menu (cdr menu)))
  82   (let (menuitem item)
  83     (while (keywordp (setq item (car menu)))
  84       (or (memq item '(:config :included :filter :accelerator))
  85           (signal 'error
  86                   (list "menu keyword must be :config, :included, :accelerator or :filter"
  87                         item)))
  88       (if (or (not (cdr menu))
  89               (vectorp (nth 1 menu))
  90               (keywordp (nth 1 menu)))
  91           (signal 'error (list "strange keyword value" item (nth 1 menu))))
  92       (setq menu (nthcdr 2 menu)))
  93     (while menu
  94       (setq menuitem (car menu))
  95       (cond
  96        ((stringp menuitem)
  97         (and (string-match "^\\(-+\\|=+\\):\\(.*\\)" menuitem)
  98              (setq item (match-string 2 menuitem))
  99              (or (member item '(;; Motif-compatible
 100                                 "singleLine"
 101                                 "doubleLine"
 102                                 "singleDashedLine"
 103                                 "doubleDashedLine"
 104                                 "noLine"
 105                                 "shadowEtchedIn"
 106                                 "shadowEtchedOut"
 107                                 "shadowEtchedInDash"
 108                                 "shadowEtchedOutDash"
 109                                 ;; non-Motif (Lucid menubar widget only)
 110                                 "shadowDoubleEtchedIn"
 111                                 "shadowDoubleEtchedOut"
 112                                 "shadowDoubleEtchedInDash"
 113                                 "shadowDoubleEtchedOutDash"
 114                                 ))
 115                  (signal 'error (list "bogus separator style in menu item" item)))
 116              ))
 117        ((null menuitem)
 118         (or menubar-p
 119             (signal 'error (list "nil is only permitted in the top level of menubars"))))
 120        ((consp menuitem)
 121         (check-menu-syntax menuitem))
 122        ((vectorp menuitem)
 123         (let ((L (length menuitem))
 124               plistp)
 125           (and (< L 2)
 126                (signal 'error
 127                        (list "button descriptors must be at least 2 long"
 128                              menuitem)))
 129           (setq plistp (or (>= L 5)
 130                            (and (> L 2) (keywordp (aref menuitem 2)))))
 131           (if plistp
 132               (let ((i 2)
 133                     selp
 134                     style
 135                     item)
 136                 (while (< i L)
 137                   (setq item (aref menuitem i))
 138                   (cond ((not (memq item '(:active :suffix :keys :style
 139                                                    :full :included :selected
 140                                                    :accelerator)))
 141                          (signal 'error
 142                                  (list (if (keywordp item)
 143                                            "unknown menu item keyword"
 144                                          "not a keyword")
 145                                        item menuitem)))
 146                         ((eq item :style)
 147                          (setq style (aref menuitem (1+ i)))
 148                          (or (memq style '(nil toggle radio button text))
 149                              (signal 'error (list "unknown style" style
 150                                                   menuitem))))
 151                         ((eq item :selected) (setq selp t))
 152                         )
 153                   (setq i (+ i (if (eq item :full) 1 2))))
 154                 (if (and selp (not (memq style '(toggle button radio))))
 155                     (signal 'error
 156                             (list
 157                              ":selected only makes sense with :style toggle, radio, or button"
 158                              menuitem)))
 159                 )))
 160         )
 161        ;; (t (signal 'error (list "unrecognized menu descriptor" menuitem))))
 162        (t (message "unrecognized menu descriptor %s" (prin1-to-string menuitem))))
 163       (setq menu (cdr menu)))))
 164
 165 \f
 166 ;;; menu manipulation functions
 167
 168 (defun find-menu-item (menubar item-path-list &optional parent)
 169   "Search MENUBAR for item given by ITEM-PATH-LIST starting from PARENT.
 170 Returns (ITEM . PARENT), where PARENT is the immediate parent of
 171  the item found.
 172 If the item does not exist, the car of the returned value is nil.
 173 If some menu in the ITEM-PATH-LIST does not exist, an error is signalled."
 174   (check-argument-type 'listp item-path-list)
 175   (unless parent
 176     (setq item-path-list (mapcar 'normalize-menu-item-name item-path-list)))
 177   (if (not (consp menubar))
 178       nil
 179     (let ((rest menubar)
 180           result)
 181       (when (stringp (car rest))
 182         (setq rest (cdr rest)))
 183       (while (keywordp (car rest))
 184         (setq rest (cddr rest)))
 185       (while rest
 186         (if (and (car rest)
 187                  (equal (car item-path-list)
 188                         (normalize-menu-item-name
 189                          (cond ((vectorp (car rest))
 190                                 (aref (car rest) 0))
 191                                ((stringp (car rest))
 192                                 (car rest))
 193                                (t
 194                                 (caar rest))))))
 195             (setq result (car rest)
 196                   rest nil)
 197           (setq rest (cdr rest))))
 198       (if (cdr item-path-list)
 199           (cond ((consp result)
 200                  (find-menu-item (cdr result) (cdr item-path-list) result))
 201                 (result
 202                  (signal 'error (list (gettext "not a submenu") result)))
 203                 (t
 204                  (signal 'error (list (gettext "no such submenu")
 205                                       (car item-path-list)))))
 206         (cons result parent)))))
 207
 208 (defun add-menu-item-1 (leaf-p menu-path new-item before in-menu)
 209   ;; This code looks like it could be cleaned up some more
 210   ;; Do we really need 6 calls to find-menu-item?
 211   (when before (setq before (normalize-menu-item-name before)))
 212   (let* ((item-name
 213           (cond ((vectorp new-item) (aref new-item 0))
 214                 ((consp   new-item) (car  new-item))
 215                 (t nil)))
 216          (menubar (or in-menu current-menubar))
 217          (menu (condition-case ()
 218                    (car (find-menu-item menubar menu-path))
 219                  (error nil)))
 220          (item-found (cond
 221                       ((null item-name)
 222                        nil)
 223                       ((not (listp menu))
 224                        (signal 'error (list (gettext "not a submenu")
 225                                             menu-path)))
 226                       (menu
 227                        (find-menu-item (cdr menu) (list item-name)))
 228                       (t
 229                        (find-menu-item menubar (list item-name)))
 230                       )))
 231     (unless menubar
 232       (error "`current-menubar' is nil: can't add menus to it."))
 233     (unless menu
 234       (let ((rest menu-path)
 235             (so-far menubar))
 236         (while rest
 237 ;;;       (setq menu (car (find-menu-item (cdr so-far) (list (car rest)))))
 238           (setq menu
 239                 (if (eq so-far menubar)
 240                     (car (find-menu-item so-far (list (car rest))))
 241                   (car (find-menu-item (cdr so-far) (list (car rest))))))
 242           (unless menu
 243             (let ((rest2 so-far))
 244               (while (and (cdr rest2) (car (cdr rest2)))
 245                 (setq rest2 (cdr rest2)))
 246               (setcdr rest2
 247                       (nconc (list (setq menu (list (car rest))))
 248                              (cdr rest2)))))
 249           (setq so-far menu)
 250           (setq rest (cdr rest)))))
 251     (if (and item-found (car item-found))
 252         ;; hack the item in place.
 253         (if menu
 254             ;; Isn't it very bad form to use nsubstitute for side effects?
 255             (nsubstitute new-item (car item-found) menu)
 256           (setq current-menubar (nsubstitute new-item
 257                                              (car item-found)
 258                                              current-menubar)))
 259       ;; OK, we have to add the whole thing...
 260       ;; if BEFORE is specified, try to add it there.
 261       (unless menu (setq menu current-menubar))
 262       (when before
 263         (setq before (car (find-menu-item menu (list before)))))
 264       (let ((rest menu)
 265             (added-before nil))
 266         (while rest
 267           (if (eq before (car (cdr rest)))
 268               (progn
 269                 (setcdr rest (cons new-item (cdr rest)))
 270                 (setq rest nil added-before t))
 271             (setq rest (cdr rest))))
 272         (when (not added-before)
 273           ;; adding before the first item on the menubar itself is harder
 274           (if (and (eq menu menubar) (eq before (car menu)))
 275               (setq menu (cons new-item menu)
 276                     current-menubar menu)
 277             ;; otherwise, add the item to the end.
 278             (nconc menu (list new-item))))))
 279     (set-menubar-dirty-flag)
 280     new-item))
 281
 282 (defun add-menu-button (menu-path menu-leaf &optional before in-menu)
 283   "Add a menu item to some menu, creating the menu first if necessary.
 284 If the named item exists already, it is changed.
 285 MENU-PATH identifies the menu under which the new menu item should be inserted.
 286  It is a list of strings; for example, (\"File\") names the top-level \"File\"
 287  menu.  (\"File\" \"Foo\") names a hypothetical submenu of \"File\".
 288 MENU-LEAF is a menubar leaf node.  See the documentation of `current-menubar'.
 289 BEFORE, if provided, is the name of a menu item before which this item should
 290  be added, if this item is not on the menu already.  If the item is already
 291  present, it will not be moved.
 292 If IN-MENU is present use that instead of `current-menubar' as the menu to
 293 change.
 294 "
 295   ;; Note easymenu.el uses the fact that menu-leaf can be a submenu.
 296   (add-menu-item-1 t menu-path menu-leaf before in-menu))
 297
 298 ;; I actually liked the old name better, but the interface has changed too
 299 ;; drastically to keep it. --Stig
 300 (defun add-submenu (menu-path submenu &optional before in-menu)
 301   "Add a menu to the menubar or one of its submenus.
 302 If the named menu exists already, it is changed.
 303 MENU-PATH identifies the menu under which the new menu should be inserted.
 304  It is a list of strings; for example, (\"File\") names the top-level \"File\"
 305  menu.  (\"File\" \"Foo\") names a hypothetical submenu of \"File\".
 306  If MENU-PATH is nil, then the menu will be added to the menubar itself.
 307 SUBMENU is the new menu to add.
 308  See the documentation of `current-menubar' for the syntax.
 309 BEFORE, if provided, is the name of a menu before which this menu should
 310  be added, if this menu is not on its parent already.  If the menu is already
 311  present, it will not be moved."
 312   (check-menu-syntax submenu nil)
 313   (add-menu-item-1 nil menu-path submenu before in-menu))
 314
 315 (defun purecopy-menubar (x)
 316   ;; this calls purecopy on the strings, and the contents of the vectors,
 317   ;; but not on the vectors themselves, or the conses - those must be
 318   ;; writable.
 319   (cond ((vectorp x)
 320          (let ((i (length x)))
 321            (while (> i 0)
 322              (aset x (1- i) (purecopy (aref x (1- i))))
 323              (setq i (1- i))))
 324          x)
 325         ((consp x)
 326          (let ((rest x))
 327            (while rest
 328              (setcar rest (purecopy-menubar (car rest)))
 329              (setq rest (cdr rest))))
 330          x)
 331         (t
 332          (purecopy x))))
 333
 334 (defun delete-menu-item (path &optional from-menu)
 335   "Remove the named menu item from the menu hierarchy.
 336 PATH is a list of strings which identify the position of the menu item in
 337 the menu hierarchy.  The documentation of `add-submenu' describes menu-paths."
 338   (let* ((pair (condition-case nil (find-menu-item (or from-menu
 339                                                        current-menubar) path)
 340                  (error nil)))
 341          (item (car pair))
 342          (parent (or (cdr pair) current-menubar)))
 343     (if (not item)
 344         nil
 345       ;; the menubar is the only special case, because other menus begin
 346       ;; with their name.
 347       (if (eq parent current-menubar)
 348           (setq current-menubar (delq item parent))
 349         (delq item parent))
 350       (set-menubar-dirty-flag)
 351       item)))
 352
 353 (defun relabel-menu-item (path new-name)
 354   "Change the string of the specified menu item.
 355 PATH is a list of strings which identify the position of the menu item in
 356 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 357 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 358 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\".
 359 NEW-NAME is the string that the menu item will be printed as from now on."
 360   (or (stringp new-name)
 361       (setq new-name (signal 'wrong-type-argument (list 'stringp new-name))))
 362   (let* ((menubar current-menubar)
 363          (pair (find-menu-item menubar path))
 364          (item (car pair))
 365          (menu (cdr pair)))
 366     (or item
 367         (signal 'error (list (if menu (gettext "No such menu item")
 368                                (gettext "No such menu"))
 369                              path)))
 370     (if (and (consp item)
 371              (stringp (car item)))
 372         (setcar item new-name)
 373       (aset item 0 new-name))
 374     (set-menubar-dirty-flag)
 375     item))
 376
 377 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 378 ;;
 379 ;; these are all bad style.  Why in the world would we put evaluable forms
 380 ;; into the menubar if we didn't want people to use 'em?
 381 ;; x-font-menu.el is the only known offender right now and that ought to be
 382 ;; rehashed a bit.
 383 ;;
 384
 385 (defun enable-menu-item-1 (path toggle-p on-p)
 386   (let (menu item)
 387     (if (and (vectorp path) (> (length path) 2)) ; limited syntax checking...
 388         (setq item path)
 389       (let* ((menubar current-menubar)
 390              (pair (find-menu-item menubar path)))
 391         (setq item (car pair)
 392               menu (cdr pair))
 393         (or item
 394             (signal 'error (list (if menu
 395                                      "No such menu item"
 396                                    "No such menu")
 397                                  path)))
 398         (if (consp item)
 399             (error "%S is a menu, not a menu item" path))))
 400     (if (or (> (length item) 4)
 401             (and (symbolp (aref item 2))
 402                  (= ?: (aref (symbol-name (aref item 2)) 0))))
 403         ;; plist-like syntax
 404         (let ((i 2)
 405               (keyword (if toggle-p :selected :active))
 406               (ok nil))
 407           (while (< i (length item))
 408             (cond ((eq (aref item i) keyword)
 409                    (aset item (1+ i) on-p)
 410                    (setq ok t)))
 411             (setq i (+ i 2)))
 412           (cond (ok nil)
 413                 (toggle-p
 414                  (signal 'error (list "not a toggle menu item" item)))
 415                 (t
 416                  ;; Need to copy the item to extend it, sigh...
 417                  (let ((cons (memq item menu))
 418                        (new-item (vconcat item (list keyword on-p))))
 419                    (if cons
 420                        (setcar cons (setq item new-item))
 421                      (if menu
 422                          (error "couldn't find %S on its parent?" item)
 423                        (error "no %S slot to set: %S" keyword item)))))))
 424       ;; positional syntax
 425       (if toggle-p
 426           (signal 'error (list "not a toggle menu item" item))
 427         (aset item 2 on-p)))
 428     (set-menubar-dirty-flag)
 429     item))
 430
 431 (defun enable-menu-item (path)
 432   "Make the named menu item be selectable.
 433 PATH is a list of strings which identify the position of the menu item in
 434 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 435 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 436 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 437   (enable-menu-item-1 path nil t))
 438
 439 (defun disable-menu-item (path)
 440   "Make the named menu item be unselectable.
 441 PATH is a list of strings which identify the position of the menu item in
 442 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 443 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 444 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 445   (enable-menu-item-1 path nil nil))
 446
 447 (defun select-toggle-menu-item (path)
 448   "Make the named toggle- or radio-style menu item be in the `selected' state.
 449 PATH is a list of strings which identify the position of the menu item in
 450 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 451 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 452 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 453   (enable-menu-item-1 path t t))
 454
 455 (defun deselect-toggle-menu-item (path)
 456  "Make the named toggle- or radio-style menu item be in the `unselected' state.
 457 PATH is a list of strings which identify the position of the menu item in
 458 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 459 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 460 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 461   (enable-menu-item-1 path t nil))
 462
 463 \f
 464 (defun get-popup-menu-response (menu-desc &optional event)
 465   "Pop up the given menu and wait for a response.
 466 This blocks until the response is received, and returns the misc-user
 467 event that encapsulates the response.  To execute it, you can do
 468   (funcall (event-function response) (event-object response))
 469 If no response was received, nil is returned.
 470
 471 MENU-DESC and EVENT are as in the call to `popup-menu'."
 472   ;; partially stolen from w3
 473   (let ((echo-keystrokes 0)
 474         new-event)
 475     (popup-menu menu-desc event)
 476     (catch 'popup-done
 477       (while t
 478         (setq new-event (next-command-event new-event))
 479         (cond ((misc-user-event-p new-event)
 480                (throw 'popup-done new-event))
 481               ((not (popup-up-p))
 482                (setq unread-command-events (cons new-event
 483                                                  unread-command-events))
 484                (throw 'popup-done nil))
 485               ((button-release-event-p new-event);; don't beep twice
 486                nil)
 487               ((event-matches-key-specifier-p (quit-char))
 488                (signal 'quit nil))
 489               (t
 490                (beep)
 491                (message "please make a choice from the menu.")))))))
 492
 493 (defun popup-menu-and-execute-in-window (menu-desc event)
 494   "Pop up the given menu and execute its response in EVENT's window.
 495 This blocks until the response is received, temporarily selects
 496 EVENT's window, and executes the command specified in the response.
 497 EVENT can also be a window.  See `popup-menu' for the semantics of
 498 MENU-DESC."
 499   (let ((response
 500          (get-popup-menu-response menu-desc
 501                                   (and (eventp event) event))))
 502     (and (misc-user-event-p response)
 503          (save-selected-window
 504            (select-window (if (windowp event) event
 505                             (event-window event)))
 506            (funcall (event-function response)
 507                     (event-object response))))))
 508
 509 ;; provide default bindings for menu accelerator map
 510 (and (boundp 'menu-accelerator-map)
 511      (keymapp menu-accelerator-map)
 512      (progn
 513        (define-key menu-accelerator-map "\e" 'menu-escape)
 514        (define-key menu-accelerator-map [left] 'menu-left)
 515        (define-key menu-accelerator-map [right] 'menu-right)
 516        (define-key menu-accelerator-map [up] 'menu-up)
 517        (define-key menu-accelerator-map [down] 'menu-down)
 518        (define-key menu-accelerator-map [return] 'menu-select)
 519        (define-key menu-accelerator-map [kp_down] 'menu-down)
 520        (define-key menu-accelerator-map [kp_up] 'menu-down)
 521        (define-key menu-accelerator-map [kp_left] 'menu-left)
 522        (define-key menu-accelerator-map [kp_right] 'menu-right)
 523        (define-key menu-accelerator-map [kp_enter] 'menu-select)
 524        (define-key menu-accelerator-map "\C-g" 'menu-quit)))
 525
 526 \f
 527 (provide 'menubar)
 528
 529 ;;; menubar.el ends here