git.chise.org Git - chise/xemacs-chise.git.1/blob - lisp/menubar.el

   1 ;;; menubar.el --- Menubar support for XEmacs
   2
   3 ;; Copyright (C) 1991-4, 1997-1998 Free Software Foundation, Inc.
   4 ;; Copyright (C) 1995 Tinker Systems and INS Engineering Corp.
   5 ;; Copyright (C) 1995, 1996 Ben Wing.
   6
   7 ;; Maintainer: XEmacs Development Team
   8 ;; Keywords: internal, extensions, dumped
   9
  10 ;; This file is part of XEmacs.
  11
  12 ;; XEmacs is free software; you can redistribute it and/or modify it
  13 ;; under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; XEmacs is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with XEmacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Synched up with: Not in FSF. (Completely divergent from FSF menu-bar.el)
  28
  29 ;;; Commentary:
  30
  31 ;; This file is dumped with XEmacs (when menubar support is compiled in).
  32
  33 ;; Some stuff in FSF menu-bar.el is in x-menubar.el
  34
  35 ;;; Code:
  36
  37 (defgroup menu nil
  38   "Input from the menus."
  39   :group 'environment)
  40
  41 (defvar default-menubar nil)
  42
  43 ;; this function is considered "part of the lexicon" by many,
  44 ;; so we'll leave it here.
  45 (defun kill-this-buffer ()      ; for the menubar
  46   "Kill the current buffer."
  47   (interactive)
  48   (kill-buffer (current-buffer)))
  49
  50 (defun set-menubar-dirty-flag ()
  51   "Tell XEmacs that the menubar has to be updated.
  52 NOTE: XEmacs now recognizes when you set a different value for
  53 `current-menubar'.  You *only* need to call this function if you
  54 destructively modify a part of the menubar and don't set `current-menubar'.
  55 Note that all the functions that modify a menu call this automatically."
  56   (setq-default current-menubar (default-value 'current-menubar)))
  57
  58 ;; #### shouldn't this perhaps be `copy-tree'?
  59 (defun set-menubar (menubar)
  60   "Set the default menubar to be MENUBAR.
  61 See `current-menubar' for a description of the syntax of a menubar."
  62   (check-menu-syntax menubar t)
  63   (setq-default current-menubar (copy-sequence menubar)))
  64
  65 (defun set-buffer-menubar (menubar)
  66   "Set the buffer-local menubar to be MENUBAR.
  67 See `current-menubar' for a description of the syntax of a menubar."
  68   (check-menu-syntax menubar t)
  69   (make-local-variable 'current-menubar)
  70   (setq current-menubar (copy-sequence menubar)))
  71
  72 (defun check-menu-syntax (menu &optional menubar-p)
  73   ;; The C code does syntax checking on the value of `current-menubar',
  74   ;; but it's better to do it early, before things have gotten messed up.
  75   (if menubar-p
  76       nil
  77     (or (stringp (car menu))
  78         (signal 'error
  79                 (list "menu name (first element) must be a string" menu)))
  80     ;;(or (cdr menu) (signal 'error (list "menu is empty" menu)))
  81     (setq menu (cdr menu)))
  82   (let (menuitem item)
  83     (while (keywordp (setq item (car menu)))
  84       (or (memq item '(:config :included :filter :accelerator))
  85           (signal 'error
  86                   (list "menu keyword must be :config, :included, :accelerator or :filter"
  87                         item)))
  88       (if (or (not (cdr menu))
  89               (vectorp (nth 1 menu))
  90               (keywordp (nth 1 menu)))
  91           (signal 'error (list "strange keyword value" item (nth 1 menu))))
  92       (setq menu (nthcdr 2 menu)))
  93     (while menu
  94       (setq menuitem (car menu))
  95       (cond
  96        ((stringp menuitem)
  97         (and (string-match "^\\(-+\\|=+\\):\\(.*\\)" menuitem)
  98              (setq item (match-string 2 menuitem))
  99              (or (member item '(;; Motif-compatible
 100                                 "singleLine"
 101                                 "doubleLine"
 102                                 "singleDashedLine"
 103                                 "doubleDashedLine"
 104                                 "noLine"
 105                                 "shadowEtchedIn"
 106                                 "shadowEtchedOut"
 107                                 "shadowEtchedInDash"
 108                                 "shadowEtchedOutDash"
 109                                 ;; non-Motif (Lucid menubar widget only)
 110                                 "shadowDoubleEtchedIn"
 111                                 "shadowDoubleEtchedOut"
 112                                 "shadowDoubleEtchedInDash"
 113                                 "shadowDoubleEtchedOutDash"
 114                                 ))
 115                  (signal 'error (list "bogus separator style in menu item" item)))
 116              ))
 117        ((null menuitem)
 118         (or menubar-p
 119             (signal 'error (list "nil is only permitted in the top level of menubars"))))
 120        ((consp menuitem)
 121         (check-menu-syntax menuitem))
 122        ((vectorp menuitem)
 123         (let ((L (length menuitem))
 124               plistp)
 125           (and (< L 2)
 126                (signal 'error
 127                        (list "button descriptors must be at least 2 long"
 128                              menuitem)))
 129           (setq plistp (or (>= L 5)
 130                            (and (> L 2) (keywordp (aref menuitem 2)))))
 131           (or (stringp (aref menuitem 0))
 132               (signal 'error
 133                       (list
 134                        "first element of a button must be a string (the label)"
 135                        menuitem)))
 136           (or plistp
 137               (< L 4)
 138               (null (aref menuitem 3))
 139               (stringp (aref menuitem 3))
 140               (signal 'error
 141                       (list
 142                        "fourth element of a button must be a string (the label suffix)"
 143                        menuitem)))
 144           (if plistp
 145               (let ((i 2)
 146                     selp
 147                     style
 148                     item)
 149                 (while (< i L)
 150                   (setq item (aref menuitem i))
 151                   (cond ((not (memq item '(:active :suffix :keys :style
 152                                                    :full :included :selected
 153                                                    :accelerator)))
 154                          (signal 'error
 155                                  (list (if (keywordp item)
 156                                            "unknown menu item keyword"
 157                                          "not a keyword")
 158                                        item menuitem)))
 159                         ((eq item :style)
 160                          (setq style (aref menuitem (1+ i)))
 161                          (or (memq style '(nil toggle radio button text))
 162                              (signal 'error (list "unknown style" style
 163                                                   menuitem))))
 164                         ((eq item :selected) (setq selp t))
 165                         )
 166                   (setq i (+ i (if (eq item :full) 1 2))))
 167                 (if (and selp (not (memq style '(toggle button radio))))
 168                     (signal 'error
 169                             (list
 170                              ":selected only makes sense with :style toggle, radio, or button"
 171                              menuitem)))
 172                 )))
 173         )
 174        ;; (t (signal 'error (list "unrecognized menu descriptor" menuitem))))
 175        (t (message "unrecognized menu descriptor %s" (prin1-to-string menuitem))))
 176       (setq menu (cdr menu)))))
 177
 178 \f
 179 ;;; menu manipulation functions
 180
 181 (defun find-menu-item (menubar item-path-list &optional parent)
 182   "Search MENUBAR for item given by ITEM-PATH-LIST starting from PARENT.
 183 Returns (ITEM . PARENT), where PARENT is the immediate parent of
 184  the item found.
 185 If the item does not exist, the car of the returned value is nil.
 186 If some menu in the ITEM-PATH-LIST does not exist, an error is signalled."
 187   (check-argument-type 'listp item-path-list)
 188   (unless parent
 189     (setq item-path-list (mapcar 'normalize-menu-item-name item-path-list)))
 190   (if (not (consp menubar))
 191       nil
 192     (let ((rest menubar)
 193           result)
 194       (when (stringp (car rest))
 195         (setq rest (cdr rest)))
 196       (while (keywordp (car rest))
 197         (setq rest (cddr rest)))
 198       (while rest
 199         (if (and (car rest)
 200                  (equal (car item-path-list)
 201                         (normalize-menu-item-name
 202                          (cond ((vectorp (car rest))
 203                                 (aref (car rest) 0))
 204                                ((stringp (car rest))
 205                                 (car rest))
 206                                (t
 207                                 (caar rest))))))
 208             (setq result (car rest)
 209                   rest nil)
 210           (setq rest (cdr rest))))
 211       (if (cdr item-path-list)
 212           (cond ((consp result)
 213                  (find-menu-item (cdr result) (cdr item-path-list) result))
 214                 (result
 215                  (signal 'error (list (gettext "not a submenu") result)))
 216                 (t
 217                  (signal 'error (list (gettext "no such submenu")
 218                                       (car item-path-list)))))
 219         (cons result parent)))))
 220
 221 (defun add-menu-item-1 (leaf-p menu-path new-item before in-menu)
 222   ;; This code looks like it could be cleaned up some more
 223   ;; Do we really need 6 calls to find-menu-item?
 224   (when before (setq before (normalize-menu-item-name before)))
 225   (let* ((item-name
 226           (cond ((vectorp new-item) (aref new-item 0))
 227                 ((consp   new-item) (car  new-item))
 228                 (t nil)))
 229          (menubar (or in-menu current-menubar))
 230          (menu (condition-case ()
 231                    (car (find-menu-item menubar menu-path))
 232                  (error nil)))
 233          (item-found (cond
 234                       ((null item-name)
 235                        nil)
 236                       ((not (listp menu))
 237                        (signal 'error (list (gettext "not a submenu")
 238                                             menu-path)))
 239                       (menu
 240                        (find-menu-item (cdr menu) (list item-name)))
 241                       (t
 242                        (find-menu-item menubar (list item-name)))
 243                       )))
 244     (unless menubar
 245       (error "`current-menubar' is nil: can't add menus to it."))
 246     (unless menu
 247       (let ((rest menu-path)
 248             (so-far menubar))
 249         (while rest
 250 ;;;       (setq menu (car (find-menu-item (cdr so-far) (list (car rest)))))
 251           (setq menu
 252                 (if (eq so-far menubar)
 253                     (car (find-menu-item so-far (list (car rest))))
 254                   (car (find-menu-item (cdr so-far) (list (car rest))))))
 255           (unless menu
 256             (let ((rest2 so-far))
 257               (while (and (cdr rest2) (car (cdr rest2)))
 258                 (setq rest2 (cdr rest2)))
 259               (setcdr rest2
 260                       (nconc (list (setq menu (list (car rest))))
 261                              (cdr rest2)))))
 262           (setq so-far menu)
 263           (setq rest (cdr rest)))))
 264     (if (and item-found (car item-found))
 265         ;; hack the item in place.
 266         (if menu
 267             ;; Isn't it very bad form to use nsubstitute for side effects?
 268             (nsubstitute new-item (car item-found) menu)
 269           (setq current-menubar (nsubstitute new-item
 270                                              (car item-found)
 271                                              current-menubar)))
 272       ;; OK, we have to add the whole thing...
 273       ;; if BEFORE is specified, try to add it there.
 274       (unless menu (setq menu current-menubar))
 275       (when before
 276         (setq before (car (find-menu-item menu (list before)))))
 277       (let ((rest menu)
 278             (added-before nil))
 279         (while rest
 280           (if (eq before (car (cdr rest)))
 281               (progn
 282                 (setcdr rest (cons new-item (cdr rest)))
 283                 (setq rest nil added-before t))
 284             (setq rest (cdr rest))))
 285         (when (not added-before)
 286           ;; adding before the first item on the menubar itself is harder
 287           (if (and (eq menu menubar) (eq before (car menu)))
 288               (setq menu (cons new-item menu)
 289                     current-menubar menu)
 290             ;; otherwise, add the item to the end.
 291             (nconc menu (list new-item))))))
 292     (set-menubar-dirty-flag)
 293     new-item))
 294
 295 (defun add-menu-button (menu-path menu-leaf &optional before in-menu)
 296   "Add a menu item to some menu, creating the menu first if necessary.
 297 If the named item exists already, it is changed.
 298 MENU-PATH identifies the menu under which the new menu item should be inserted.
 299  It is a list of strings; for example, (\"File\") names the top-level \"File\"
 300  menu.  (\"File\" \"Foo\") names a hypothetical submenu of \"File\".
 301 MENU-LEAF is a menubar leaf node.  See the documentation of `current-menubar'.
 302 BEFORE, if provided, is the name of a menu item before which this item should
 303  be added, if this item is not on the menu already.  If the item is already
 304  present, it will not be moved.
 305 If IN-MENU is present use that instead of `current-menubar' as the menu to
 306 change.
 307 "
 308   ;; Note easymenu.el uses the fact that menu-leaf can be a submenu.
 309   (add-menu-item-1 t menu-path menu-leaf before in-menu))
 310
 311 ;; I actually liked the old name better, but the interface has changed too
 312 ;; drastically to keep it. --Stig
 313 (defun add-submenu (menu-path submenu &optional before in-menu)
 314   "Add a menu to the menubar or one of its submenus.
 315 If the named menu exists already, it is changed.
 316 MENU-PATH identifies the menu under which the new menu should be inserted.
 317  It is a list of strings; for example, (\"File\") names the top-level \"File\"
 318  menu.  (\"File\" \"Foo\") names a hypothetical submenu of \"File\".
 319  If MENU-PATH is nil, then the menu will be added to the menubar itself.
 320 SUBMENU is the new menu to add.
 321  See the documentation of `current-menubar' for the syntax.
 322 BEFORE, if provided, is the name of a menu before which this menu should
 323  be added, if this menu is not on its parent already.  If the menu is already
 324  present, it will not be moved."
 325   (check-menu-syntax submenu nil)
 326   (add-menu-item-1 nil menu-path submenu before in-menu))
 327
 328 (defun purecopy-menubar (x)
 329   ;; this calls purecopy on the strings, and the contents of the vectors,
 330   ;; but not on the vectors themselves, or the conses - those must be
 331   ;; writable.
 332   (cond ((vectorp x)
 333          (let ((i (length x)))
 334            (while (> i 0)
 335              (aset x (1- i) (purecopy (aref x (1- i))))
 336              (setq i (1- i))))
 337          x)
 338         ((consp x)
 339          (let ((rest x))
 340            (while rest
 341              (setcar rest (purecopy-menubar (car rest)))
 342              (setq rest (cdr rest))))
 343          x)
 344         (t
 345          (purecopy x))))
 346
 347 (defun delete-menu-item (path &optional from-menu)
 348   "Remove the named menu item from the menu hierarchy.
 349 PATH is a list of strings which identify the position of the menu item in
 350 the menu hierarchy.  The documentation of `add-submenu' describes menu-paths."
 351   (let* ((pair (condition-case nil (find-menu-item (or from-menu
 352                                                        current-menubar) path)
 353                  (error nil)))
 354          (item (car pair))
 355          (parent (or (cdr pair) current-menubar)))
 356     (if (not item)
 357         nil
 358       ;; the menubar is the only special case, because other menus begin
 359       ;; with their name.
 360       (if (eq parent current-menubar)
 361           (setq current-menubar (delq item parent))
 362         (delq item parent))
 363       (set-menubar-dirty-flag)
 364       item)))
 365
 366 (defun relabel-menu-item (path new-name)
 367   "Change the string of the specified menu item.
 368 PATH is a list of strings which identify the position of the menu item in
 369 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 370 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 371 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\".
 372 NEW-NAME is the string that the menu item will be printed as from now on."
 373   (or (stringp new-name)
 374       (setq new-name (signal 'wrong-type-argument (list 'stringp new-name))))
 375   (let* ((menubar current-menubar)
 376          (pair (find-menu-item menubar path))
 377          (item (car pair))
 378          (menu (cdr pair)))
 379     (or item
 380         (signal 'error (list (if menu (gettext "No such menu item")
 381                                (gettext "No such menu"))
 382                              path)))
 383     (if (and (consp item)
 384              (stringp (car item)))
 385         (setcar item new-name)
 386       (aset item 0 new-name))
 387     (set-menubar-dirty-flag)
 388     item))
 389
 390 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 391 ;;
 392 ;; these are all bad style.  Why in the world would we put evaluable forms
 393 ;; into the menubar if we didn't want people to use 'em?
 394 ;; x-font-menu.el is the only known offender right now and that ought to be
 395 ;; rehashed a bit.
 396 ;;
 397
 398 (defun enable-menu-item-1 (path toggle-p on-p)
 399   (let (menu item)
 400     (if (and (vectorp path) (> (length path) 2)) ; limited syntax checking...
 401         (setq item path)
 402       (let* ((menubar current-menubar)
 403              (pair (find-menu-item menubar path)))
 404         (setq item (car pair)
 405               menu (cdr pair))
 406         (or item
 407             (signal 'error (list (if menu
 408                                      "No such menu item"
 409                                    "No such menu")
 410                                  path)))
 411         (if (consp item)
 412             (error "%S is a menu, not a menu item" path))))
 413     (if (or (> (length item) 4)
 414             (and (symbolp (aref item 2))
 415                  (= ?: (aref (symbol-name (aref item 2)) 0))))
 416         ;; plist-like syntax
 417         (let ((i 2)
 418               (keyword (if toggle-p :selected :active))
 419               (ok nil))
 420           (while (< i (length item))
 421             (cond ((eq (aref item i) keyword)
 422                    (aset item (1+ i) on-p)
 423                    (setq ok t)))
 424             (setq i (+ i 2)))
 425           (cond (ok nil)
 426                 (toggle-p
 427                  (signal 'error (list "not a toggle menu item" item)))
 428                 (t
 429                  ;; Need to copy the item to extend it, sigh...
 430                  (let ((cons (memq item menu))
 431                        (new-item (vconcat item (list keyword on-p))))
 432                    (if cons
 433                        (setcar cons (setq item new-item))
 434                      (if menu
 435                          (error "couldn't find %S on its parent?" item)
 436                        (error "no %S slot to set: %S" keyword item)))))))
 437       ;; positional syntax
 438       (if toggle-p
 439           (signal 'error (list "not a toggle menu item" item))
 440         (aset item 2 on-p)))
 441     (set-menubar-dirty-flag)
 442     item))
 443
 444 (defun enable-menu-item (path)
 445   "Make the named menu item be selectable.
 446 PATH is a list of strings which identify the position of the menu item in
 447 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 448 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 449 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 450   (enable-menu-item-1 path nil t))
 451
 452 (defun disable-menu-item (path)
 453   "Make the named menu item be unselectable.
 454 PATH is a list of strings which identify the position of the menu item in
 455 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 456 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 457 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 458   (enable-menu-item-1 path nil nil))
 459
 460 (defun select-toggle-menu-item (path)
 461   "Make the named toggle- or radio-style menu item be in the `selected' state.
 462 PATH is a list of strings which identify the position of the menu item in
 463 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 464 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 465 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 466   (enable-menu-item-1 path t t))
 467
 468 (defun deselect-toggle-menu-item (path)
 469  "Make the named toggle- or radio-style menu item be in the `unselected' state.
 470 PATH is a list of strings which identify the position of the menu item in
 471 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 472 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 473 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 474   (enable-menu-item-1 path t nil))
 475
 476 \f
 477 (defun get-popup-menu-response (menu-desc &optional event)
 478   "Pop up the given menu and wait for a response.
 479 This blocks until the response is received, and returns the misc-user
 480 event that encapsulates the response.  To execute it, you can do
 481   (funcall (event-function response) (event-object response))
 482 If no response was received, nil is returned.
 483
 484 MENU-DESC and EVENT are as in the call to `popup-menu'."
 485   ;; partially stolen from w3
 486   (let ((echo-keystrokes 0)
 487         new-event)
 488     (popup-menu menu-desc event)
 489     (catch 'popup-done
 490       (while t
 491         (setq new-event (next-command-event new-event))
 492         (cond ((misc-user-event-p new-event)
 493                (throw 'popup-done new-event))
 494               ((not (popup-up-p))
 495                (setq unread-command-events (cons new-event
 496                                                  unread-command-events))
 497                (throw 'popup-done nil))
 498               ((button-release-event-p new-event);; don't beep twice
 499                nil)
 500               ((event-matches-key-specifier-p (quit-char))
 501                (signal 'quit nil))
 502               (t
 503                (beep)
 504                (message "please make a choice from the menu.")))))))
 505
 506 (defun popup-menu-and-execute-in-window (menu-desc event)
 507   "Pop up the given menu and execute its response in EVENT's window.
 508 This blocks until the response is received, temporarily selects
 509 EVENT's window, and executes the command specified in the response.
 510 EVENT can also be a window.  See `popup-menu' for the semantics of
 511 MENU-DESC."
 512   (let ((response
 513          (get-popup-menu-response menu-desc
 514                                   (and (eventp event) event))))
 515     (and (misc-user-event-p response)
 516          (save-selected-window
 517            (select-window (if (windowp event) event
 518                             (event-window event)))
 519            (funcall (event-function response)
 520                     (event-object response))))))
 521
 522 ;; provide default bindings for menu accelerator map
 523 (and (boundp 'menu-accelerator-map)
 524      (keymapp menu-accelerator-map)
 525      (progn
 526        (define-key menu-accelerator-map "\e" 'menu-escape)
 527        (define-key menu-accelerator-map [left] 'menu-left)
 528        (define-key menu-accelerator-map [right] 'menu-right)
 529        (define-key menu-accelerator-map [up] 'menu-up)
 530        (define-key menu-accelerator-map [down] 'menu-down)
 531        (define-key menu-accelerator-map [return] 'menu-select)
 532        (define-key menu-accelerator-map [kp_down] 'menu-down)
 533        (define-key menu-accelerator-map [kp_up] 'menu-down)
 534        (define-key menu-accelerator-map [kp_left] 'menu-left)
 535        (define-key menu-accelerator-map [kp_right] 'menu-right)
 536        (define-key menu-accelerator-map [kp_enter] 'menu-select)
 537        (define-key menu-accelerator-map "\C-g" 'menu-quit)))
 538
 539 \f
 540 (provide 'menubar)
 541
 542 ;;; menubar.el ends here