emu.el

   1 ;;; emu.el --- Emulation module for each Emacs variants
   2
   3 ;; Copyright (C) 1995,1996,1997,1998 Free Software Foundation, Inc.
   4
   5 ;; Author: MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; Keywords: emulation, compatibility, NEmacs, MULE, Emacs/mule, XEmacs
   7
   8 ;; This file is part of emu.
   9
  10 ;; This program is free software; you can redistribute it and/or
  11 ;; modify it under the terms of the GNU General Public License as
  12 ;; published by the Free Software Foundation; either version 2, or (at
  13 ;; your option) any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful, but
  16 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 ;; General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (defmacro defun-maybe (name &rest everything-else)
  28   (or (and (fboundp name)
  29            (not (get name 'defun-maybe))
  30            )
  31       (` (or (fboundp (quote (, name)))
  32              (progn
  33                (defun (, name) (,@ everything-else))
  34                (put (quote (, name)) 'defun-maybe t)
  35                ))
  36          )))
  37
  38 (defmacro defsubst-maybe (name &rest everything-else)
  39   (or (and (fboundp name)
  40            (not (get name 'defsubst-maybe))
  41            )
  42       (` (or (fboundp (quote (, name)))
  43              (progn
  44                (defsubst (, name) (,@ everything-else))
  45                (put (quote (, name)) 'defsubst-maybe t)
  46                ))
  47          )))
  48
  49 (defmacro defmacro-maybe (name &rest everything-else)
  50   (or (and (fboundp name)
  51            (not (get name 'defmacro-maybe))
  52            )
  53       (` (or (fboundp (quote (, name)))
  54              (progn
  55                (defmacro (, name) (,@ everything-else))
  56                (put (quote (, name)) 'defmacro-maybe t)
  57                ))
  58          )))
  59
  60 (put 'defun-maybe 'lisp-indent-function 'defun)
  61 (put 'defsubst-maybe 'lisp-indent-function 'defun)
  62 (put 'defmacro-maybe 'lisp-indent-function 'defun)
  63
  64 (defmacro defconst-maybe (name &rest everything-else)
  65   (or (and (boundp name)
  66            (not (get name 'defconst-maybe))
  67            )
  68       (` (or (boundp (quote (, name)))
  69              (progn
  70                (defconst (, name) (,@ everything-else))
  71                (put (quote (, name)) 'defconst-maybe t)
  72                ))
  73          )))
  74
  75
  76 (defconst-maybe emacs-major-version (string-to-int emacs-version))
  77 (defconst-maybe emacs-minor-version
  78   (string-to-int
  79    (substring emacs-version
  80               (string-match (format "%d\\." emacs-major-version)
  81                             emacs-version))))
  82
  83 (defvar running-emacs-18 (<= emacs-major-version 18))
  84 (defvar running-xemacs (string-match "XEmacs" emacs-version))
  85
  86 (defvar running-mule-merged-emacs (and (not (boundp 'MULE))
  87                                        (not running-xemacs) (featurep 'mule)))
  88 (defvar running-xemacs-with-mule (and running-xemacs (featurep 'mule)))
  89
  90 (defvar running-emacs-19 (and (not running-xemacs) (= emacs-major-version 19)))
  91 (defvar running-emacs-19_29-or-later
  92   (or (and running-emacs-19 (>= emacs-minor-version 29))
  93       (and (not running-xemacs)(>= emacs-major-version 20))))
  94
  95 (defvar running-xemacs-19 (and running-xemacs
  96                                (= emacs-major-version 19)))
  97 (defvar running-xemacs-20-or-later (and running-xemacs
  98                                         (>= emacs-major-version 20)))
  99 (defvar running-xemacs-19_14-or-later
 100   (or (and running-xemacs-19 (>= emacs-minor-version 14))
 101       running-xemacs-20-or-later))
 102
 103 (cond (running-mule-merged-emacs
 104        ;; for Emacs 20.1 and 20.2
 105        (require 'emu-e20)
 106        )
 107       (running-xemacs-with-mule
 108        ;; for XEmacs with mule
 109        (require 'emu-x20)
 110        )
 111       ((boundp 'MULE)
 112        ;; for MULE 1.* and 2.*
 113        (require 'emu-mule)
 114        )
 115       ((boundp 'NEMACS)
 116        ;; for NEmacs and NEpoch
 117        (require 'emu-nemacs)
 118        )
 119       (t
 120        ;; for Emacs 19 and XEmacs without mule
 121        (require 'emu-latin1)
 122        ))
 123
 124
 125 ;;; @ MIME charset
 126 ;;;
 127
 128 (defun charsets-to-mime-charset (charsets)
 129   "Return MIME charset from list of charset CHARSETS.
 130 This function refers variable `charsets-mime-charset-alist'
 131 and `default-mime-charset'."
 132   (if charsets
 133       (or (catch 'tag
 134             (let ((rest charsets-mime-charset-alist)
 135                   cell)
 136               (while (setq cell (car rest))
 137                 (if (catch 'not-subset
 138                       (let ((set1 charsets)
 139                             (set2 (car cell))
 140                             obj)
 141                         (while set1
 142                           (setq obj (car set1))
 143                           (or (memq obj set2)
 144                               (throw 'not-subset nil)
 145                               )
 146                           (setq set1 (cdr set1))
 147                           )
 148                         t))
 149                     (throw 'tag (cdr cell))
 150                   )
 151                 (setq rest (cdr rest))
 152                 )))
 153           default-mime-charset)))
 154
 155
 156 ;;; @ Emacs 19 emulation
 157 ;;;
 158
 159 (defun-maybe minibuffer-prompt-width ()
 160   "Return the display width of the minibuffer prompt."
 161   (save-excursion
 162     (set-buffer (window-buffer (minibuffer-window)))
 163     (current-column)
 164     ))
 165
 166
 167 ;;; @ Emacs 19.29 emulation
 168 ;;;
 169
 170 (defvar path-separator ":"
 171   "Character used to separate concatenated paths.")
 172
 173 (defun-maybe buffer-substring-no-properties (start end)
 174   "Return the characters of part of the buffer, without the text properties.
 175 The two arguments START and END are character positions;
 176 they can be in either order. [Emacs 19.29 emulating function]"
 177   (let ((string (buffer-substring start end)))
 178     (set-text-properties 0 (length string) nil string)
 179     string))
 180
 181 (defun-maybe match-string (num &optional string)
 182   "Return string of text matched by last search.
 183 NUM specifies which parenthesized expression in the last regexp.
 184  Value is nil if NUMth pair didn't match, or there were less than NUM pairs.
 185 Zero means the entire text matched by the whole regexp or whole string.
 186 STRING should be given if the last search was by `string-match' on STRING.
 187 \[Emacs 19.29 emulating function]"
 188   (if (match-beginning num)
 189       (if string
 190           (substring string (match-beginning num) (match-end num))
 191         (buffer-substring (match-beginning num) (match-end num)))))
 192
 193 (or running-emacs-19_29-or-later
 194     running-xemacs
 195     ;; for Emacs 19.28 or earlier
 196     (fboundp 'si:read-string)
 197     (progn
 198       (fset 'si:read-string (symbol-function 'read-string))
 199
 200       (defun read-string (prompt &optional initial-input history)
 201         "Read a string from the minibuffer, prompting with string PROMPT.
 202 If non-nil, second arg INITIAL-INPUT is a string to insert before reading.
 203 The third arg HISTORY, is dummy for compatibility. [emu.el]
 204 See `read-from-minibuffer' for details of HISTORY argument."
 205         (si:read-string prompt initial-input)
 206         )
 207       ))
 208
 209
 210 ;;; @ Emacs 19.30 emulation
 211 ;;;
 212
 213 ;; This function was imported Emacs 19.30.
 214 (defun-maybe add-to-list (list-var element)
 215   "Add to the value of LIST-VAR the element ELEMENT if it isn't there yet.
 216 If you want to use `add-to-list' on a variable that is not defined
 217 until a certain package is loaded, you should put the call to `add-to-list'
 218 into a hook function that will be run only after loading the package.
 219 \[Emacs 19.30 emulating function]"
 220   (or (member element (symbol-value list-var))
 221       (set list-var (cons element (symbol-value list-var)))
 222       ))
 223
 224 (cond ((fboundp 'insert-file-contents-literally)
 225        )
 226       ((boundp 'file-name-handler-alist)
 227        (defun insert-file-contents-literally
 228          (filename &optional visit beg end replace)
 229          "Like `insert-file-contents', q.v., but only reads in the file.
 230 A buffer may be modified in several ways after reading into the buffer due
 231 to advanced Emacs features, such as file-name-handlers, format decoding,
 232 find-file-hooks, etc.
 233   This function ensures that none of these modifications will take place.
 234 \[Emacs 19.30 emulating function]"
 235          (let (file-name-handler-alist)
 236            (insert-file-contents filename visit beg end replace)
 237            ))
 238        )
 239       (t
 240        (defalias 'insert-file-contents-literally 'insert-file-contents)
 241        ))
 242
 243
 244 ;;; @ Emacs 19.31 emulation
 245 ;;;
 246
 247 (defun-maybe buffer-live-p (object)
 248   "Return non-nil if OBJECT is a buffer which has not been killed.
 249 Value is nil if OBJECT is not a buffer or if it has been killed.
 250 \[Emacs 19.31 emulating function]"
 251   (and object
 252        (get-buffer object)
 253        (buffer-name (get-buffer object))
 254        ))
 255
 256 ;; This macro was imported Emacs 19.33.
 257 (defmacro-maybe save-selected-window (&rest body)
 258   "Execute BODY, then select the window that was selected before BODY.
 259 \[Emacs 19.31 emulating function]"
 260   (list 'let
 261         '((save-selected-window-window (selected-window)))
 262         (list 'unwind-protect
 263               (cons 'progn body)
 264               (list 'select-window 'save-selected-window-window))))
 265
 266
 267 ;;; @ XEmacs emulation
 268 ;;;
 269
 270 (defun-maybe functionp (obj)
 271   "Returns t if OBJ is a function, nil otherwise.
 272 \[XEmacs emulating function]"
 273   (or (subrp obj)
 274       (byte-code-function-p obj)
 275       (and (symbolp obj)(fboundp obj))
 276       (and (consp obj)(eq (car obj) 'lambda))
 277       ))
 278
 279 (defun-maybe point-at-eol (&optional arg buffer)
 280   "Return the character position of the last character on the current line.
 281 With argument N not nil or 1, move forward N - 1 lines first.
 282 If scan reaches end of buffer, return that position.
 283 This function does not move point. [XEmacs emulating function]"
 284   (save-excursion
 285     (if buffer
 286         (set-buffer buffer)
 287       )
 288     (if arg
 289         (forward-line (1- arg))
 290       )
 291     (end-of-line)
 292     (point)
 293     ))
 294
 295
 296 ;;; @ for XEmacs 20
 297 ;;;
 298
 299 (or (fboundp 'char-int)
 300     (fset 'char-int (symbol-function 'identity))
 301     )
 302 (or (fboundp 'int-char)
 303     (fset 'int-char (symbol-function 'identity))
 304     )
 305 (or (fboundp 'char-or-char-int-p)
 306     (fset 'char-or-char-int-p (symbol-function 'integerp))
 307     )
 308
 309
 310 ;;; @ for text/richtext and text/enriched
 311 ;;;
 312
 313 (cond ((fboundp 'richtext-decode)
 314        ;; have richtext.el
 315        )
 316       ((or running-emacs-19_29-or-later running-xemacs-19_14-or-later)
 317        ;; have enriched.el
 318        (autoload 'richtext-decode "richtext")
 319        (or (assq 'text/richtext format-alist)
 320            (setq format-alist
 321                  (cons
 322                   (cons 'text/richtext
 323                         '("Extended MIME text/richtext format."
 324                           "Content-[Tt]ype:[ \t]*text/richtext"
 325                           richtext-decode richtext-encode t enriched-mode))
 326                   format-alist)))
 327        )
 328       (t
 329        ;; don't have enriched.el
 330        (autoload 'richtext-decode "tinyrich")
 331        (autoload 'enriched-decode "tinyrich")
 332        ))
 333
 334
 335 ;;; @ end
 336 ;;;
 337
 338 (provide 'emu)
 339
 340 ;;; emu.el ends here