poe-18.el

   1 ;;; poe-18.el --- poe API implementation for Emacs 18.*
   2
   3 ;; Copyright (C) 1995,1996,1997,1998,1999 Free Software Foundation, Inc.
   4 ;; Copyright (C) 1999 Yuuichi Teranishi
   5
   6 ;; Author: MORIOKA Tomohiko <tomo@m17n.org>
   7 ;;      Shuhei KOBAYASHI <shuhei@aqua.ocn.ne.jp>
   8 ;;      Yuuichi Teranishi <teranisi@gohome.org>
   9 ;; Keywords: emulation, compatibility
  10
  11 ;; This file is part of APEL (A Portable Emacs Library).
  12
  13 ;; This program is free software; you can redistribute it and/or
  14 ;; modify it under the terms of the GNU General Public License as
  15 ;; published by the Free Software Foundation; either version 2, or (at
  16 ;; your option) any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful, but
  19 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 ;; General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with this program; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; Note to APEL developers and APEL programmers:
  31 ;;
  32 ;; If old (v18) compiler is used, top-level macros are expanded at
  33 ;; *load-time*, not compile-time. Therefore,
  34 ;;
  35 ;; (1) Definitions with `*-maybe' won't be compiled.
  36 ;;
  37 ;; (2) you cannot use macros defined with `defmacro-maybe' within function
  38 ;;     definitions in the same file.
  39 ;;     (`defmacro-maybe' is evaluated at load-time, therefore byte-compiler
  40 ;;      treats such use of macros as (unknown) functions and compiles them
  41 ;;      into function calls, which will cause errors at run-time.)
  42 ;;
  43 ;; (3) `eval-when-compile' and `eval-and-compile' are evaluated at
  44 ;;     load-time if used at top-level.
  45
  46 ;;; Code:
  47
  48 (require 'pym)
  49
  50
  51 ;;; @ Compilation.
  52 ;;;
  53 (fset 'defalias 'fset)
  54
  55 (defun byte-code-function-p (object)
  56   "Return t if OBJECT is a byte-compiled function object."
  57   (and (consp object) (consp (cdr object))
  58        (let ((rest (cdr (cdr object)))
  59              elt)
  60          (if (stringp (car rest))
  61              (setq rest (cdr rest)))
  62          (catch 'tag
  63            (while rest
  64              (setq elt (car rest))
  65              (if (and (consp elt)
  66                       (eq (car elt) 'byte-code))
  67                  (throw 'tag t))
  68              (setq rest (cdr rest)))))))
  69
  70 ;; (symbol-plist 'cyclic-function-indirection)
  71 (put 'cyclic-function-indirection
  72      'error-conditions
  73      '(cyclic-function-indirection error))
  74 (put 'cyclic-function-indirection
  75      'error-message
  76      "Symbol's chain of function indirections contains a loop")
  77
  78 ;; The following function definition is a direct translation of its
  79 ;; C definition in emacs-20.4/src/data.c.
  80 (defun indirect-function (object)
  81   "Return the function at the end of OBJECT's function chain.
  82 If OBJECT is a symbol, follow all function indirections and return the final
  83 function binding.
  84 If OBJECT is not a symbol, just return it.
  85 Signal a void-function error if the final symbol is unbound.
  86 Signal a cyclic-function-indirection error if there is a loop in the
  87 function chain of symbols."
  88   (let* ((hare object)
  89          (tortoise hare))
  90     (catch 'found
  91       (while t
  92         (or (symbolp hare) (throw 'found hare))
  93         (or (fboundp hare) (signal 'void-function (cons object nil)))
  94         (setq hare (symbol-function hare))
  95         (or (symbolp hare) (throw 'found hare))
  96         (or (fboundp hare) (signal 'void-function (cons object nil)))
  97         (setq hare (symbol-function hare))
  98
  99         (setq tortoise (symbol-function tortoise))
 100
 101         (if (eq hare tortoise)
 102             (signal 'cyclic-function-indirection (cons object nil)))))
 103     hare))
 104
 105 ;;; Emulate all functions and macros of emacs-20.3/lisp/byte-run.el.
 106 ;;; (note: jwz's original compiler and XEmacs compiler have some more
 107 ;;;  macros; they are "nuked" by rms in FSF version.)
 108
 109 ;; Use `*-maybe' here because new byte-compiler may be installed.
 110 (put 'inline 'lisp-indent-hook 0)
 111 (defmacro-maybe inline (&rest body)
 112   "Eval BODY forms sequentially and return value of last one.
 113
 114 This emulating macro does not support function inlining because old \(v18\)
 115 compiler does not support inlining feature."
 116   (cons 'progn body))
 117
 118 (put 'defsubst 'lisp-indent-hook 'defun)
 119 (put 'defsubst 'edebug-form-spec 'defun)
 120 (defmacro-maybe defsubst (name arglist &rest body)
 121   "Define an inline function.  The syntax is just like that of `defun'.
 122
 123 This emulating macro does not support function inlining because old \(v18\)
 124 compiler does not support inlining feature."
 125   (cons 'defun (cons name (cons arglist body))))
 126
 127 (defun-maybe make-obsolete (fn new)
 128   "Make the byte-compiler warn that FUNCTION is obsolete.
 129 The warning will say that NEW should be used instead.
 130 If NEW is a string, that is the `use instead' message.
 131
 132 This emulating function does nothing because old \(v18\) compiler does not
 133 support this feature."
 134   (interactive "aMake function obsolete: \nxObsoletion replacement: ")
 135   fn)
 136
 137 (defun-maybe make-obsolete-variable (var new)
 138   "Make the byte-compiler warn that VARIABLE is obsolete,
 139 and NEW should be used instead.  If NEW is a string, then that is the
 140 `use instead' message.
 141
 142 This emulating function does nothing because old \(v18\) compiler does not
 143 support this feature."
 144   (interactive "vMake variable obsolete: \nxObsoletion replacement: ")
 145   var)
 146
 147 (put 'dont-compile 'lisp-indent-hook 0)
 148 (defmacro-maybe dont-compile (&rest body)
 149   "Like `progn', but the body always runs interpreted \(not compiled\).
 150 If you think you need this, you're probably making a mistake somewhere."
 151   (list 'eval (list 'quote (if (cdr body) (cons 'progn body) (car body)))))
 152
 153 (put 'eval-when-compile 'lisp-indent-hook 0)
 154 (defmacro-maybe eval-when-compile (&rest body)
 155   "Like progn, but evaluates the body at compile-time.
 156
 157 This emulating macro does not do compile-time evaluation at all because
 158 of the limitation of old \(v18\) compiler."
 159   (cons 'progn body))
 160
 161 (put 'eval-and-compile 'lisp-indent-hook 0)
 162 (defmacro-maybe eval-and-compile (&rest body)
 163   "Like progn, but evaluates the body at compile-time as well as at load-time.
 164
 165 This emulating macro does not do compile-time evaluation at all because
 166 of the limitation of old \(v18\) compiler."
 167   (cons 'progn body))
 168
 169
 170 ;;; @ C primitives emulation.
 171 ;;;
 172
 173 (defun member (elt list)
 174   "Return non-nil if ELT is an element of LIST.  Comparison done with EQUAL.
 175 The value is actually the tail of LIST whose car is ELT."
 176   (while (and list (not (equal elt (car list))))
 177     (setq list (cdr list)))
 178   list)
 179
 180 (defun delete (elt list)
 181   "Delete by side effect any occurrences of ELT as a member of LIST.
 182 The modified LIST is returned.  Comparison is done with `equal'.
 183 If the first member of LIST is ELT, deleting it is not a side effect;
 184 it is simply using a different list.
 185 Therefore, write `(setq foo (delete element foo))'
 186 to be sure of changing the value of `foo'."
 187   (if list
 188       (if (equal elt (car list))
 189           (cdr list)
 190         (let ((rest list)
 191               (rrest (cdr list)))
 192           (while (and rrest (not (equal elt (car rrest))))
 193             (setq rest rrest
 194                   rrest (cdr rrest)))
 195           (setcdr rest (cdr rrest))
 196           list))))
 197
 198 (defun default-boundp (symbol)
 199   "Return t if SYMBOL has a non-void default value.
 200 This is the value that is seen in buffers that do not have their own values
 201 for this variable."
 202   (condition-case error
 203       (progn
 204         (default-value symbol)
 205         t)
 206     (void-variable nil)))
 207
 208 ;;; @@ current-time.
 209 ;;;
 210
 211 (defvar current-time-world-timezones
 212   '(("PST" .  -800)("PDT" .  -700)("MST" .  -700)
 213     ("MDT" .  -600)("CST" .  -600)("CDT" .  -500)
 214     ("EST" .  -500)("EDT" .  -400)("AST" .  -400)
 215     ("NST" .  -330)("UT"  .  +000)("GMT" .  +000)
 216     ("BST" .  +100)("MET" .  +100)("EET" .  +200)
 217     ("JST" .  +900)("GMT+1"  .  +100)("GMT+2"  .  +200)
 218     ("GMT+3"  .  +300)("GMT+4"  .  +400)("GMT+5"  .  +500)
 219     ("GMT+6"  .  +600)("GMT+7"  .  +700)("GMT+8"  .  +800)
 220     ("GMT+9"  .  +900)("GMT+10" . +1000)("GMT+11" . +1100)
 221     ("GMT+12" . +1200)("GMT+13" . +1300)("GMT-1"  .  -100)
 222     ("GMT-2"  .  -200)("GMT-3"  .  -300)("GMT-4"  .  -400)
 223     ("GMT-5"  .  -500)("GMT-6"  .  -600)("GMT-7"  .  -700)
 224     ("GMT-8"  .  -800)("GMT-9"  .  -900)("GMT-10" . -1000)
 225     ("GMT-11" . -1100) ("GMT-12" . -1200))
 226   "Time differentials of timezone from GMT in +-HHMM form.
 227 Used in `current-time-zone' (Emacs 19 emulating function in poe-18.el).")
 228
 229 (defvar current-time-local-timezone nil
 230   "*Local timezone name.
 231 Used in `current-time-zone' (Emacs 19 emulating function in poe-18.el).")
 232
 233 (defun set-time-zone-rule (tz)
 234   "Set the local time zone using TZ, a string specifying a time zone rule.
 235 If TZ is nil, use implementation-defined default time zone information.
 236 If TZ is t, use Universal Time."
 237   (cond
 238    ((stringp tz)
 239     (setq current-time-local-timezone tz))
 240    (tz
 241     (setq current-time-local-timezone "GMT"))
 242    (t
 243     (setq current-time-local-timezone
 244           (with-temp-buffer
 245             ;; We use `date' command to get timezone information.
 246             (call-process "date" nil (current-buffer) t)
 247             (goto-char (point-min))
 248             (if (looking-at
 249                  "^.*\\([A-Z][A-Z][A-Z]\\([^ \n\t]*\\)\\).*$")
 250                 (buffer-substring (match-beginning 1)
 251                                   (match-end 1))))))))
 252
 253 (defun current-time-zone (&optional specified-time)
 254   "Return the offset and name for the local time zone.
 255 This returns a list of the form (OFFSET NAME).
 256 OFFSET is an integer number of seconds ahead of UTC (east of Greenwich).
 257     A negative value means west of Greenwich.
 258 NAME is a string giving the name of the time zone.
 259 Optional argument SPECIFIED-TIME is ignored in this implementation.
 260 Some operating systems cannot provide all this information to Emacs;
 261 in this case, `current-time-zone' returns a list containing nil for
 262 the data it can't find."
 263   (let ((local-timezone (or current-time-local-timezone
 264                             (progn
 265                               (set-time-zone-rule nil)
 266                               current-time-local-timezone)))
 267         timezone abszone seconds)
 268     (setq timezone
 269           (or (cdr (assoc (upcase local-timezone)
 270                           current-time-world-timezones))
 271               ;; "+900" style or nil.
 272               local-timezone))
 273     (when timezone
 274       (if (stringp timezone)
 275           (setq timezone (string-to-int timezone)))
 276       ;; Taking account of minute in timezone.
 277       ;; HHMM -> MM
 278       (setq abszone (abs timezone))
 279       (setq seconds (* 60 (+ (* 60 (/ abszone 100)) (% abszone 100))))
 280       (list (if (< timezone 0) (- seconds) seconds)
 281             local-timezone))))
 282
 283 (or (fboundp 'si:current-time-string)
 284     (fset 'si:current-time-string (symbol-function 'current-time-string)))
 285 (defun current-time-string (&optional specified-time)
 286   "Return the current time, as a human-readable string.
 287 Programs can use this function to decode a time,
 288 since the number of columns in each field is fixed.
 289 The format is `Sun Sep 16 01:03:52 1973'.
 290 If an argument SPECIFIED-TIME is given, it specifies a time to format
 291 instead of the current time.  The argument should have the form:
 292   (HIGH . LOW)
 293 or the form:
 294   (HIGH LOW . IGNORED).
 295 Thus, you can use times obtained from `current-time'
 296 and from `file-attributes'."
 297   (if (null specified-time)
 298       (si:current-time-string)
 299     (or (consp specified-time)
 300         (error "Wrong type argument %s" specified-time))
 301     (let ((high (car specified-time))
 302           (low  (cdr specified-time))
 303           (offset (or (car (current-time-zone)) 0))
 304           (mdays '(31 28 31 30 31 30 31 31 30 31 30 31))
 305           (mnames '("Jan" "Feb" "Mar" "Apr" "May" "Jun"
 306                     "Jul" "Aug" "Sep" "Oct" "Nov" "Dec"))
 307           (wnames '("Sun" "Mon" "Tue" "Wed" "Thu" "Fri" "Sat"))
 308           days dd yyyy lyear mm HH MM SS)
 309       (if (consp low)
 310           (setq low (car low)))
 311       (or (integerp high)
 312           (error "Wrong type argument %s" high))
 313       (or (integerp low)
 314           (error "Wrong type argument %s" low))
 315       (setq low (+ low offset))
 316       (while (> low 65535)
 317         (setq high (1+ high)
 318               low (- low 65536)))
 319       (setq yyyy 1970)
 320       (while (or (> high 481)
 321                  (and (= high 481)
 322                       (>= low 13184)))
 323         (if (and (> high 0)
 324                  (< low 13184))
 325             (setq high (1- high)
 326                   low  (+ 65536 low)))
 327         (setq high (- high 481)
 328               low  (- low 13184))
 329         (if (and (zerop (% yyyy 4))
 330                  (or (not (zerop (% yyyy 100)))
 331                      (zerop (% yyyy 400))))
 332             (progn
 333               (if (and (> high 0)
 334                        (< low 20864))
 335                   (setq high (1- high)
 336                         low  (+ 65536 low)))
 337               (setq high (- high 1)
 338                     low (- low 20864))))
 339         (setq yyyy (1+ yyyy)))
 340       (setq dd 1)
 341       (while (or (> high 1)
 342                  (and (= high 1)
 343                       (>= low 20864)))
 344         (if (and (> high 0)
 345                  (< low 20864))
 346             (setq high (1- high)
 347                   low  (+ 65536 low)))
 348         (setq high (- high 1)
 349               low  (- low 20864)
 350               dd (1+ dd)))
 351       (setq days dd)
 352       (if (= high 1)
 353           (setq low (+ 65536 low)))
 354       (setq mm 0)
 355       (setq lyear (and (zerop (% yyyy 4))
 356                        (or (not (zerop (% yyyy 100)))
 357                            (zerop (% yyyy 400)))))
 358       (while (> (- dd (nth mm mdays)) 0)
 359         (if (and (= mm 1) lyear)
 360             (setq dd (- dd 29))
 361           (setq dd (- dd (nth mm mdays))))
 362         (setq mm (1+ mm)))
 363       (setq HH (/ low 3600)
 364             low (% low 3600)
 365             MM (/ low 60)
 366             SS (% low 60))
 367       (format "%s %s %2d %02d:%02d:%02d %4d"
 368               (nth (% (+ days
 369                          (- (+ (* (1- yyyy) 365) (/ (1- yyyy) 400)
 370                                (/ (1- yyyy) 4)) (/ (1- yyyy) 100))) 7)
 371                    wnames)
 372               (nth mm mnames)
 373               dd HH MM SS yyyy))))
 374
 375 (defun current-time ()
 376   "Return the current time, as the number of seconds since 1970-01-01 00:00:00.
 377 The time is returned as a list of three integers.  The first has the
 378 most significant 16 bits of the seconds, while the second has the
 379 least significant 16 bits.  The third integer gives the microsecond
 380 count.
 381
 382 The microsecond count is zero on systems that do not provide
 383 resolution finer than a second."
 384   (let* ((str (current-time-string))
 385          (yyyy (string-to-int (substring str 20 24)))
 386          (mm (length (member (substring str 4 7)
 387                              '("Dec" "Nov" "Oct" "Sep" "Aug" "Jul"
 388                                "Jun" "May" "Apr" "Mar" "Feb" "Jan"))))
 389          (dd (string-to-int (substring str 8 10)))
 390          (HH (string-to-int (substring str 11 13)))
 391          (MM (string-to-int (substring str 14 16)))
 392          (SS (string-to-int (substring str 17 19)))
 393          (offset (or (car (current-time-zone)) 0))
 394          dn ct1 ct2 i1 i2
 395          year uru)
 396     (setq ct1 0 ct2 0 i1 0 i2 0)
 397     (setq year (- yyyy 1970))
 398     (while (> year 0)
 399       (setq year (1- year)
 400             ct1 (+ ct1 481)
 401             ct2 (+ ct2 13184))
 402       (while (> ct2 65535)
 403         (setq ct1 (1+ ct1)
 404               ct2 (- ct2 65536))))
 405     (setq year (- yyyy 1))
 406     (setq uru (- (+ (- (/ year 4) (/ year 100))
 407                     (/ year 400)) 477))
 408     (while (> uru 0)
 409       (setq uru (1- uru)
 410             i1 (1+ i1)
 411             i2 (+ i2 20864))
 412       (if (> i2 65535)
 413           (setq i1 (1+ i1)
 414                 i2 (- i2 65536))))
 415     (setq ct1 (+ ct1 i1)
 416           ct2 (+ ct2 i2))
 417     (while (> ct2 65535)
 418       (setq ct1 (1+ ct1)
 419             ct2 (- ct2 65536)))
 420     (setq dn (+ dd (* 31 (1- mm))))
 421     (if (> mm 2)
 422         (setq dn (+ (- dn (/ (+ 23 (* 4 mm)) 10))
 423                     (if (and (zerop (% yyyy 4))
 424                              (or (not (zerop (% yyyy 100)))
 425                                  (zerop (% yyyy 400))))
 426                         1 0))))
 427     (setq dn (1- dn)
 428           i1 0
 429           i2 0)
 430     (while (> dn 0)
 431       (setq dn (1- dn)
 432             i1 (1+ i1)
 433             i2 (+ i2 20864))
 434       (if (> i2 65535)
 435           (setq i1 (1+ i1)
 436                 i2 (- i2 65536))))
 437     (setq ct1 (+ (+ (+ ct1 i1) (/ ct2 65536))
 438                  (/ (+ (* HH 3600) (* MM 60) SS)
 439                     65536))
 440           ct2 (+ (+ i2 (% ct2 65536))
 441                  (% (+ (* HH 3600) (* MM 60) SS)
 442                     65536)))
 443     (while (< (- ct2 offset) 0)
 444       (setq ct1 (1- ct1)
 445             ct2 (+ ct2 65536)))
 446     (setq ct2 (- ct2 offset))
 447     (while (> ct2 65535)
 448       (setq ct1 (1+ ct1)
 449             ct2 (- ct2 65536)))
 450     (list ct1 ct2 0)))
 451
 452 ;;; @@ Floating point numbers.
 453 ;;;
 454
 455 (defalias 'numberp 'integerp)
 456
 457 (defun abs (arg)
 458   "Return the absolute value of ARG."
 459   (if (< arg 0) (- arg) arg))
 460
 461 (defun floor (arg &optional divisor)
 462   "Return the largest integer no grater than ARG.
 463 With optional DIVISOR, return the largest integer no greater than ARG/DIVISOR."
 464   (if (null divisor)
 465       (setq divisor 1))
 466   (if (< arg 0)
 467       (- (/ (- divisor 1 arg) divisor))
 468     (/ arg divisor)))
 469
 470 (defalias 'mod '%)
 471
 472 ;;; @ Basic lisp subroutines.
 473 ;;;
 474
 475 (defmacro lambda (&rest cdr)
 476   "Return a lambda expression.
 477 A call of the form (lambda ARGS DOCSTRING INTERACTIVE BODY) is
 478 self-quoting; the result of evaluating the lambda expression is the
 479 expression itself.  The lambda expression may then be treated as a
 480 function, i.e., stored as the function value of a symbol, passed to
 481 funcall or mapcar, etc.
 482
 483 ARGS should take the same form as an argument list for a `defun'.
 484 DOCSTRING is an optional documentation string.
 485  If present, it should describe how to call the function.
 486  But documentation strings are usually not useful in nameless functions.
 487 INTERACTIVE should be a call to the function `interactive', which see.
 488 It may also be omitted.
 489 BODY should be a list of lisp expressions."
 490   ;; Note that this definition should not use backquotes; subr.el should not
 491   ;; depend on backquote.el.
 492   (list 'function (cons 'lambda cdr)))
 493
 494 (defun force-mode-line-update (&optional all)
 495   "Force the mode-line of the current buffer to be redisplayed.
 496 With optional non-nil ALL, force redisplay of all mode-lines."
 497   (if all (save-excursion (set-buffer (other-buffer))))
 498   (set-buffer-modified-p (buffer-modified-p)))
 499
 500 (defalias 'set-match-data 'store-match-data)
 501
 502 (defvar save-match-data-internal)
 503
 504 ;; We use save-match-data-internal as the local variable because
 505 ;; that works ok in practice (people should not use that variable elsewhere).
 506 (defmacro save-match-data (&rest body)
 507   "Execute the BODY forms, restoring the global value of the match data."
 508   (` (let ((save-match-data-internal (match-data)))
 509        (unwind-protect (progn (,@ body))
 510          (set-match-data save-match-data-internal)))))
 511
 512
 513 ;;; @ Basic editing commands.
 514 ;;;
 515
 516 ;; 18.55 does not have these variables.
 517 (defvar buffer-undo-list nil)
 518 (defvar-maybe auto-fill-function nil)
 519 (defvar-maybe unread-command-event nil)
 520 (defvar-maybe unread-command-events nil)
 521
 522 (defalias 'buffer-disable-undo 'buffer-flush-undo)
 523 (defalias 'insert-and-inherit 'insert)
 524 (defalias 'insert-before-markers-and-inherit 'insert-before-markers)
 525 (defalias 'number-to-string 'int-to-string)
 526
 527 (defun generate-new-buffer-name (name &optional ignore)
 528   "Return a string that is the name of no existing buffer based on NAME.
 529 If there is no live buffer named NAME, then return NAME.
 530 Otherwise modify name by appending `<NUMBER>', incrementing NUMBER
 531 until an unused name is found, and then return that name.
 532 Optional second argument IGNORE specifies a name that is okay to use
 533 \(if it is in the sequence to be tried\)
 534 even if a buffer with that name exists."
 535   (if (get-buffer name)
 536       (let ((n 2) new)
 537         (while (get-buffer (setq new (format "%s<%d>" name n)))
 538           (setq n (1+ n)))
 539         new)
 540     name))
 541
 542 (or (fboundp 'si:mark)
 543     (fset 'si:mark (symbol-function 'mark)))
 544 (defun mark (&optional force)
 545   (si:mark))
 546
 547 (defun-maybe window-minibuffer-p (&optional window)
 548 "Return non-nil if WINDOW is a minibuffer window."
 549   (eq (or window (selected-window)) (minibuffer-window)))
 550
 551 (defun-maybe window-live-p (obj)
 552   "Returns t if OBJECT is a window which is currently visible."
 553   (and (windowp obj)
 554        (or (eq obj (minibuffer-window))
 555            (eq obj (get-buffer-window (window-buffer obj))))))
 556
 557 ;; Add optinal argument `hist'
 558 (or (fboundp 'si:read-from-minibuffer)
 559     (progn
 560       (fset 'si:read-from-minibuffer (symbol-function 'read-from-minibuffer))
 561       (defun read-from-minibuffer (prompt &optional
 562                                           initial-contents keymap read hist)
 563
 564         "Read a string from the minibuffer, prompting with string PROMPT.
 565 If optional second arg INITIAL-CONTENTS is non-nil, it is a string
 566   to be inserted into the minibuffer before reading input.
 567   If INITIAL-CONTENTS is (STRING . POSITION), the initial input
 568   is STRING, but point is placed at position POSITION in the minibuffer.
 569 Third arg KEYMAP is a keymap to use whilst reading;
 570   if omitted or nil, the default is `minibuffer-local-map'.
 571 If fourth arg READ is non-nil, then interpret the result as a lisp object
 572   and return that object:
 573   in other words, do `(car (read-from-string INPUT-STRING))'
 574 Fifth arg HIST is ignored in this implementatin."
 575         (si:read-from-minibuffer prompt initial-contents keymap read))))
 576
 577 ;; Add optional argument `frame'.
 578 (or (fboundp 'si:get-buffer-window)
 579     (progn
 580       (fset 'si:get-buffer-window (symbol-function 'get-buffer-window))
 581       (defun get-buffer-window (buffer &optional frame)
 582         "Return a window currently displaying BUFFER, or nil if none.
 583 Optional argunemt FRAME is ignored in this implementation."
 584         (si:get-buffer-window buffer))))
 585
 586 (defun-maybe walk-windows (proc &optional minibuf all-frames)
 587   "Cycle through all visible windows, calling PROC for each one.
 588 PROC is called with a window as argument.
 589
 590 Optional second arg MINIBUF t means count the minibuffer window even
 591 if not active.  MINIBUF nil or omitted means count the minibuffer iff
 592 it is active.  MINIBUF neither t nor nil means not to count the
 593 minibuffer even if it is active.
 594 Optional third argunemt ALL-FRAMES is ignored in this implementation."
 595   (if (window-minibuffer-p (selected-window))
 596       (setq minibuf t))
 597   (let* ((walk-windows-start (selected-window))
 598          (walk-windows-current walk-windows-start))
 599     (unwind-protect
 600         (while (progn
 601                  (setq walk-windows-current
 602                        (next-window walk-windows-current minibuf))
 603                  (funcall proc walk-windows-current)
 604                  (not (eq walk-windows-current walk-windows-start))))
 605       (select-window walk-windows-start))))
 606
 607 ;;; @@ Environment variables.
 608 ;;;
 609
 610 (autoload 'setenv "env"
 611   "Set the value of the environment variable named VARIABLE to VALUE.
 612 VARIABLE should be a string.  VALUE is optional; if not provided or is
 613 `nil', the environment variable VARIABLE will be removed.
 614 This function works by modifying `process-environment'."
 615   t)
 616
 617
 618 ;;; @ File input and output commands.
 619 ;;;
 620
 621 (defvar data-directory exec-directory)
 622
 623 ;; In 18.55, `call-process' does not return exit status.
 624 (defun file-executable-p (filename)
 625   "Return t if FILENAME can be executed by you.
 626 For a directory, this means you can access files in that directory."
 627   (if (file-exists-p filename)
 628       (let ((process (start-process "test" nil "test" "-x" filename)))
 629         (while (eq 'run (process-status process)))
 630         (zerop (process-exit-status process)))))
 631
 632 (defun make-directory-internal (dirname)
 633   "Create a directory. One argument, a file name string."
 634  (let ((dir (expand-file-name dirname)))
 635    (if (file-exists-p dir)
 636        (error "Creating directory: %s is already exist" dir)
 637      (call-process "mkdir" nil nil nil dir))))
 638
 639 (defun make-directory (dir &optional parents)
 640   "Create the directory DIR and any nonexistent parent dirs.
 641 The second (optional) argument PARENTS says whether
 642 to create parent directories if they don't exist."
 643   (let ((len (length dir))
 644         (p 0) p1 path)
 645     (catch 'tag
 646       (while (and (< p len) (string-match "[^/]*/?" dir p))
 647         (setq p1 (match-end 0))
 648         (if (= p1 len)
 649             (throw 'tag nil))
 650         (setq path (substring dir 0 p1))
 651         (if (not (file-directory-p path))
 652             (cond ((file-exists-p path)
 653                    (error "Creating directory: %s is not directory" path))
 654                   ((null parents)
 655                    (error "Creating directory: %s is not exist" path))
 656                   (t
 657                    (make-directory-internal path))))
 658         (setq p p1)))
 659     (make-directory-internal dir)))
 660
 661 (defun parse-colon-path (cd-path)
 662   "Explode a colon-separated list of paths into a string list."
 663   (and cd-path
 664        (let (cd-prefix cd-list (cd-start 0) cd-colon)
 665          (setq cd-path (concat cd-path path-separator))
 666          (while (setq cd-colon (string-match path-separator cd-path cd-start))
 667            (setq cd-list
 668                  (nconc cd-list
 669                         (list (if (= cd-start cd-colon)
 670                                   nil
 671                                 (substitute-in-file-name
 672                                  (file-name-as-directory
 673                                   (substring cd-path cd-start cd-colon)))))))
 674            (setq cd-start (+ cd-colon 1)))
 675          cd-list)))
 676
 677 (defun file-relative-name (filename &optional directory)
 678   "Convert FILENAME to be relative to DIRECTORY (default: default-directory)."
 679   (setq filename (expand-file-name filename)
 680         directory (file-name-as-directory (expand-file-name
 681                                            (or directory default-directory))))
 682   (let ((ancestor ""))
 683     (while (not (string-match (concat "^" (regexp-quote directory)) filename))
 684       (setq directory (file-name-directory (substring directory 0 -1))
 685             ancestor (concat "../" ancestor)))
 686     (concat ancestor (substring filename (match-end 0)))))
 687
 688 (or (fboundp 'si:directory-files)
 689     (fset 'si:directory-files (symbol-function 'directory-files)))
 690 (defun directory-files (directory &optional full match nosort)
 691   "Return a list of names of files in DIRECTORY.
 692 There are three optional arguments:
 693 If FULL is non-nil, return absolute file names.  Otherwise return names
 694  that are relative to the specified directory.
 695 If MATCH is non-nil, mention only file names that match the regexp MATCH.
 696 If NOSORT is dummy for compatibility."
 697   (si:directory-files directory full match))
 698
 699 ;;; @ Process.
 700 ;;;
 701 (or (fboundp 'si:accept-process-output)
 702     (progn
 703       (fset 'si:accept-process-output (symbol-function 'accept-process-output))
 704       (defun accept-process-output (&optional process timeout timeout-msecs)
 705         "Allow any pending output from subprocesses to be read by Emacs.
 706 It is read into the process' buffers or given to their filter functions.
 707 Non-nil arg PROCESS means do not return until some output has been received
 708  from PROCESS. Nil arg PROCESS means do not return until some output has
 709  been received from any process.
 710 TIMEOUT and TIMEOUT-MSECS are ignored in this implementation."
 711         (si:accept-process-output process))))
 712
 713 ;;; @ Text property.
 714 ;;;
 715
 716 ;; In Emacs 20.4, these functions are defined in src/textprop.c.
 717 (defun text-properties-at (position &optional object))
 718 (defun get-text-property (position prop &optional object))
 719 (defun get-char-property (position prop &optional object))
 720 (defun next-property-change (position &optional object limit))
 721 (defun next-single-property-change (position prop &optional object limit))
 722 (defun previous-property-change (position &optional object limit))
 723 (defun previous-single-property-change (position prop &optional object limit))
 724 (defun add-text-properties (start end properties &optional object))
 725 (defun put-text-property (start end property value &optional object))
 726 (defun set-text-properties (start end properties &optional object))
 727 (defun remove-text-properties (start end properties &optional object))
 728 (defun text-property-any (start end property value &optional object))
 729 (defun text-property-not-all (start end property value &optional object))
 730 ;; the following two functions are new in v20.
 731 (defun next-char-property-change (position &optional object))
 732 (defun previous-char-property-change (position &optional object))
 733 ;; the following two functions are obsolete.
 734 ;; (defun erase-text-properties (start end &optional object)
 735 ;; (defun copy-text-properties (start end src pos dest &optional prop)
 736
 737
 738 ;;; @ Overlay.
 739 ;;;
 740
 741 (defun overlayp (object))
 742 (defun make-overlay (beg end &optional buffer front-advance rear-advance))
 743 (defun move-overlay (overlay beg end &optional buffer))
 744 (defun delete-overlay (overlay))
 745 (defun overlay-start (overlay))
 746 (defun overlay-end (overlay))
 747 (defun overlay-buffer (overlay))
 748 (defun overlay-properties (overlay))
 749 (defun overlays-at (pos))
 750 (defun overlays-in (beg end))
 751 (defun next-overlay-change (pos))
 752 (defun previous-overlay-change (pos))
 753 (defun overlay-lists ())
 754 (defun overlay-recenter (pos))
 755 (defun overlay-get (overlay prop))
 756 (defun overlay-put (overlay prop value))
 757
 758 ;;; @ End.
 759 ;;;
 760
 761 (require 'product)
 762 (product-provide (provide 'poe-18) (require 'apel-ver))
 763
 764 ;;; poe-18.el ends here