poe-xemacs.el

   1 ;;; poe-xemacs.el --- poe submodule for XEmacs -*-byte-compile-dynamic: t;-*-
   2
   3 ;; Copyright (C) 1995 Free Software Foundation, Inc.
   4 ;; Copyright (C) 1995,1996,1997,1998 MORIOKA Tomohiko
   5
   6 ;; Author: MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; Keywords: emulation, compatibility, XEmacs
   8
   9 ;; This file is part of APEL (A Portable Emacs Library).
  10
  11 ;; This program is free software; you can redistribute it and/or
  12 ;; modify it under the terms of the GNU General Public License as
  13 ;; published by the Free Software Foundation; either version 2, or (at
  14 ;; your option) any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful, but
  17 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 ;; General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with XEmacs; see the file COPYING.  If not, write to the Free
  23 ;; Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  24 ;; 02111-1307, USA.
  25
  26 ;;; Code:
  27
  28 ;;; @ color
  29 ;;;
  30
  31 (defun-maybe set-cursor-color (color-name)
  32   "Set the text cursor color of the selected frame to COLOR.
  33 When called interactively, prompt for the name of the color to use."
  34   (interactive "sColor: ")
  35   (set-frame-property (selected-frame) 'cursor-color
  36                       (if (color-instance-p color-name)
  37                           color-name
  38                         (make-color-instance color-name))))
  39
  40
  41 ;;; @ face
  42 ;;;
  43
  44 (defalias-maybe 'face-list 'list-faces)
  45
  46 (or (memq 'underline (face-list))
  47     (and (fboundp 'make-face)
  48          (make-face 'underline)))
  49
  50 (or (face-differs-from-default-p 'underline)
  51     (set-face-underline-p 'underline t))
  52
  53
  54 ;;; @ overlay
  55 ;;;
  56
  57 (condition-case nil
  58     (require 'overlay)
  59   (error (defalias 'make-overlay 'make-extent)
  60          (defalias 'overlay-put 'set-extent-property)
  61          (defalias 'overlay-buffer 'extent-buffer)
  62          (defun move-overlay (extent start end &optional buffer)
  63            (set-extent-endpoints extent start end)
  64            )
  65          ))
  66
  67
  68 ;;; @ dired
  69 ;;;
  70
  71 (defun-maybe dired-other-frame (dirname &optional switches)
  72   "\"Edit\" directory DIRNAME.  Like `dired' but makes a new frame."
  73   (interactive (dired-read-dir-and-switches "in other frame "))
  74   (switch-to-buffer-other-frame (dired-noselect dirname switches))
  75   )
  76
  77
  78 ;;; @ to avoid bug of XEmacs 19.14
  79 ;;;
  80
  81 (or (string-match "^../"
  82                   (file-relative-name "/usr/local/share" "/usr/local/lib"))
  83     ;; This function was imported from Emacs 19.33.
  84     (defun file-relative-name (filename &optional directory)
  85       "Convert FILENAME to be relative to DIRECTORY
  86 (default: default-directory). [poe-xemacs.el]"
  87       (setq filename (expand-file-name filename)
  88             directory (file-name-as-directory
  89                        (expand-file-name
  90                         (or directory default-directory))))
  91       (let ((ancestor ""))
  92         (while (not (string-match (concat "^" (regexp-quote directory))
  93                                   filename))
  94           (setq directory (file-name-directory (substring directory 0 -1))
  95                 ancestor (concat "../" ancestor)))
  96         (concat ancestor (substring filename (match-end 0)))))
  97     )
  98
  99
 100 ;;; @ for anything older than XEmacs 20.2
 101 ;;;
 102
 103 ;; eval-after-load is not defined in XEmacs but after-load-alist is
 104 ;; usable.  See subr.el in XEmacs.
 105
 106 (defun-maybe eval-after-load (file form)
 107   "Arrange that, if FILE is ever loaded, FORM will be run at that time.
 108 This makes or adds to an entry on `after-load-alist'.
 109 If FILE is already loaded, evaluate FORM right now.
 110 It does nothing if FORM is already on the list for FILE.
 111 FILE should be the name of a library, with no directory name."
 112   ;; Make sure there is an element for FILE.
 113   (or (assoc file after-load-alist)
 114       (setq after-load-alist (cons (list file) after-load-alist)))
 115   ;; Add FORM to the element if it isn't there.
 116   (let ((elt (assoc file after-load-alist)))
 117     (or (member form (cdr elt))
 118         (progn
 119           (nconc elt (list form))
 120           ;; If the file has been loaded already, run FORM right away.
 121           (and (assoc file load-history)
 122                (eval form)))))
 123   form)
 124
 125 ;; (defun-maybe eval-after-load (file form)
 126 ;;   (or (assoc file after-load-alist)
 127 ;;       (setq after-load-alist (cons (list file) after-load-alist)))
 128 ;;   (let ((elt (assoc file after-load-alist)))
 129 ;;     (or (member form (cdr elt))
 130 ;;         (nconc elt (list form))))
 131 ;;   form)
 132
 133
 134 ;;; @ Emacs 20.3 emulation
 135 ;;;
 136
 137 (defalias-maybe 'line-beginning-position 'point-at-bol)
 138
 139 (defalias-maybe 'line-end-position 'point-at-eol)
 140
 141
 142 ;;; @ end
 143 ;;;
 144
 145 (provide 'poe-xemacs)
 146
 147 ;;; poe-xemacs.el ends here