poe.el

   1 ;;; poe.el --- Portable Outfit for Emacsen; -*-byte-compile-dynamic: t;-*-
   2
   3 ;; Copyright (C) 1995,1996,1997,1998 Free Software Foundation, Inc.
   4
   5 ;; Author: MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; Keywords: emulation, compatibility, NEmacs, MULE, Emacs/mule, XEmacs
   7
   8 ;; This file is part of APEL (A Portable Emacs Library).
   9
  10 ;; This program is free software; you can redistribute it and/or
  11 ;; modify it under the terms of the GNU General Public License as
  12 ;; published by the Free Software Foundation; either version 2, or (at
  13 ;; your option) any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful, but
  16 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 ;; General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This modules does not includes MULE related features.  MULE related
  28 ;; features are supported by `poem'.
  29
  30 ;;; Code:
  31
  32 (defmacro defun-maybe (name &rest everything-else)
  33   (or (and (fboundp name)
  34            (not (get name 'defun-maybe)))
  35       (` (or (fboundp (quote (, name)))
  36              (progn
  37                (defun (, name) (,@ everything-else))
  38                (put (quote (, name)) 'defun-maybe t)
  39                ))
  40          )))
  41
  42 (defmacro defsubst-maybe (name &rest everything-else)
  43   (or (and (fboundp name)
  44            (not (get name 'defsubst-maybe)))
  45       (` (or (fboundp (quote (, name)))
  46              (progn
  47                (defsubst (, name) (,@ everything-else))
  48                (put (quote (, name)) 'defsubst-maybe t)
  49                ))
  50          )))
  51
  52 (defmacro defmacro-maybe (name &rest everything-else)
  53   (or (and (fboundp name)
  54            (not (get name 'defmacro-maybe)))
  55       (` (or (fboundp (quote (, name)))
  56              (progn
  57                (defmacro (, name) (,@ everything-else))
  58                (put (quote (, name)) 'defmacro-maybe t)
  59                ))
  60          )))
  61
  62 (defmacro defalias-maybe (symbol definition)
  63   (setq symbol (eval symbol))
  64   (or (and (fboundp symbol)
  65            (not (get symbol 'defalias-maybe)))
  66       (` (or (fboundp (quote (, symbol)))
  67              (progn
  68                (defalias (quote (, symbol)) (, definition))
  69                (put (quote (, symbol)) 'defalias-maybe t)
  70                ))
  71          )))
  72
  73 (put 'defun-maybe 'lisp-indent-function 'defun)
  74 (put 'defsubst-maybe 'lisp-indent-function 'defun)
  75 (put 'defmacro-maybe 'lisp-indent-function 'defun)
  76
  77 (defmacro defvar-maybe (name &rest everything-else)
  78   (or (and (boundp name)
  79            (not (get name 'defvar-maybe)))
  80       (` (or (boundp (quote (, name)))
  81              (progn
  82                (defvar (, name) (,@ everything-else))
  83                (put (quote (, name)) 'defvar-maybe t)
  84                ))
  85          )))
  86
  87 (defmacro defconst-maybe (name &rest everything-else)
  88   (or (and (boundp name)
  89            (not (get name 'defconst-maybe))
  90            )
  91       (` (or (boundp (quote (, name)))
  92              (progn
  93                (defconst (, name) (,@ everything-else))
  94                (put (quote (, name)) 'defconst-maybe t)
  95                ))
  96          )))
  97
  98 (defconst-maybe emacs-major-version (string-to-int emacs-version))
  99 (defconst-maybe emacs-minor-version
 100   (string-to-int
 101    (substring emacs-version
 102               (string-match (format "%d\\." emacs-major-version)
 103                             emacs-version))))
 104
 105 (cond ((featurep 'xemacs)
 106        (require 'poe-xemacs)
 107        )
 108       ((string-match "XEmacs" emacs-version)
 109        (provide 'xemacs)
 110        (require 'poe-xemacs)
 111        )
 112       ((> emacs-major-version 20))
 113       ((= emacs-major-version 20)
 114        (cond ((fboundp 'string)
 115               ;; Emacs 20.3 or later
 116               )
 117              ((fboundp 'concat-chars)
 118               ;; Emacs 20.1 or later
 119               (defalias 'string 'concat-chars)
 120               ))
 121        )
 122       ((= emacs-major-version 19))
 123       (t
 124        (require 'poe-18)
 125        ))
 126
 127
 128 ;;; @ Emacs 19 emulation
 129 ;;;
 130
 131 (defmacro-maybe eval-and-compile (&rest body)
 132   "Like `progn', but evaluates the body at compile time and at load time."
 133   ;; Remember, it's magic.
 134   (cons 'progn body))
 135
 136 (defun-maybe minibuffer-prompt-width ()
 137   "Return the display width of the minibuffer prompt."
 138   (save-excursion
 139     (set-buffer (window-buffer (minibuffer-window)))
 140     (current-column)))
 141
 142
 143 ;;; @ Emacs 19.29 emulation
 144 ;;;
 145
 146 (defvar path-separator ":"
 147   "Character used to separate concatenated paths.")
 148
 149 (defun-maybe buffer-substring-no-properties (start end)
 150   "Return the characters of part of the buffer, without the text properties.
 151 The two arguments START and END are character positions;
 152 they can be in either order. [Emacs 19.29 emulating function]"
 153   (let ((string (buffer-substring start end)))
 154     (set-text-properties 0 (length string) nil string)
 155     string))
 156
 157 (defun-maybe match-string (num &optional string)
 158   "Return string of text matched by last search.
 159 NUM specifies which parenthesized expression in the last regexp.
 160  Value is nil if NUMth pair didn't match, or there were less than NUM pairs.
 161 Zero means the entire text matched by the whole regexp or whole string.
 162 STRING should be given if the last search was by `string-match' on STRING.
 163 \[Emacs 19.29 emulating function]"
 164   (if (match-beginning num)
 165       (if string
 166           (substring string (match-beginning num) (match-end num))
 167         (buffer-substring (match-beginning num) (match-end num)))))
 168
 169 (or (featurep 'xemacs)
 170     (>= emacs-major-version 20)
 171     (and (= emacs-major-version 19)
 172          (>= emacs-minor-version 29))
 173     ;; for Emacs 19.28 or earlier
 174     (fboundp 'si:read-string)
 175     (eval-and-compile
 176       (fset 'si:read-string (symbol-function 'read-string))
 177       (defun read-string (prompt &optional initial-input history)
 178         "Read a string from the minibuffer, prompting with string PROMPT.
 179 If non-nil, second arg INITIAL-INPUT is a string to insert before reading.
 180 The third arg HISTORY, is dummy for compatibility. [emu.el]
 181 See `read-from-minibuffer' for details of HISTORY argument."
 182         (si:read-string prompt initial-input))
 183       ))
 184
 185
 186 ;;; @ Emacs 19.30 emulation
 187 ;;;
 188
 189 ;; imported from Emacs 19.30.
 190 (defun-maybe add-to-list (list-var element)
 191   "Add to the value of LIST-VAR the element ELEMENT if it isn't there yet.
 192 If you want to use `add-to-list' on a variable that is not defined
 193 until a certain package is loaded, you should put the call to `add-to-list'
 194 into a hook function that will be run only after loading the package.
 195 \[Emacs 19.30 emulating function]"
 196   (or (member element (symbol-value list-var))
 197       (set list-var (cons element (symbol-value list-var)))))
 198
 199 (cond ((fboundp 'insert-file-contents-literally))
 200       ((boundp 'file-name-handler-alist)
 201        (defun insert-file-contents-literally
 202          (filename &optional visit beg end replace)
 203          "Like `insert-file-contents', q.v., but only reads in the file.
 204 A buffer may be modified in several ways after reading into the buffer due
 205 to advanced Emacs features, such as file-name-handlers, format decoding,
 206 find-file-hooks, etc.
 207   This function ensures that none of these modifications will take place.
 208 \[Emacs 19.30 emulating function]"
 209          (let (file-name-handler-alist)
 210            (insert-file-contents filename visit beg end replace)))
 211        )
 212       (t
 213        (defalias 'insert-file-contents-literally 'insert-file-contents)
 214        ))
 215
 216
 217 ;;; @ Emacs 19.31 emulation
 218 ;;;
 219
 220 (defun-maybe buffer-live-p (object)
 221   "Return non-nil if OBJECT is a buffer which has not been killed.
 222 Value is nil if OBJECT is not a buffer or if it has been killed.
 223 \[Emacs 19.31 emulating function]"
 224   (and object
 225        (get-buffer object)
 226        (buffer-name (get-buffer object))))
 227
 228 ;; imported from Emacs 19.33.
 229 (defmacro-maybe save-selected-window (&rest body)
 230   "Execute BODY, then select the window that was selected before BODY.
 231 \[Emacs 19.31 emulating function]"
 232   (list 'let
 233         '((save-selected-window-window (selected-window)))
 234         (list 'unwind-protect
 235               (cons 'progn body)
 236               (list 'select-window 'save-selected-window-window))))
 237
 238
 239 ;;; @ Emacs 20.1 emulation
 240 ;;;
 241
 242 ;; imported from Emacs 20.2.
 243 (defmacro-maybe when (cond &rest body)
 244   "(when COND BODY...): if COND yields non-nil, do BODY, else return nil."
 245   (list 'if cond (cons 'progn body)))
 246
 247 ;; imported from Emacs 20.3.
 248 (defmacro-maybe unless (cond &rest body)
 249   "(unless COND BODY...): if COND yields nil, do BODY, else return nil."
 250   (cons 'if (cons cond (cons nil body))))
 251
 252 (defmacro-maybe save-current-buffer (&rest body)
 253   "Save the current buffer; execute BODY; restore the current buffer.
 254 Executes BODY just like `progn'."
 255   (` (let ((orig-buffer (current-buffer)))
 256        (unwind-protect
 257            (progn (,@ body))
 258          (set-buffer orig-buffer)))))
 259
 260 ;; imported from Emacs 20.2.
 261 (defmacro-maybe with-current-buffer (buffer &rest body)
 262   "Execute the forms in BODY with BUFFER as the current buffer.
 263 The value returned is the value of the last form in BODY.
 264 See also `with-temp-buffer'."
 265   (` (save-current-buffer
 266        (set-buffer (, buffer))
 267        (,@ body))))
 268
 269 ;; imported from Emacs 20.2.
 270 (defmacro-maybe with-temp-file (file &rest forms)
 271   "Create a new buffer, evaluate FORMS there, and write the buffer to FILE.
 272 The value of the last form in FORMS is returned, like `progn'.
 273 See also `with-temp-buffer'."
 274   (let ((temp-file (make-symbol "temp-file"))
 275         (temp-buffer (make-symbol "temp-buffer")))
 276     (` (let (((, temp-file) (, file))
 277              ((, temp-buffer)
 278               (get-buffer-create (generate-new-buffer-name " *temp file*"))))
 279          (unwind-protect
 280              (prog1
 281                  (with-current-buffer (, temp-buffer)
 282                    (,@ forms))
 283                (with-current-buffer (, temp-buffer)
 284                  (widen)
 285                  (write-region (point-min) (point-max) (, temp-file) nil 0)))
 286            (and (buffer-name (, temp-buffer))
 287                 (kill-buffer (, temp-buffer))))))))
 288
 289 ;; imported from Emacs 20.2.
 290 (defmacro-maybe with-temp-buffer (&rest forms)
 291   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 292 See also `with-temp-file' and `with-output-to-string'."
 293   (let ((temp-buffer (make-symbol "temp-buffer")))
 294     (` (let (((, temp-buffer)
 295               (get-buffer-create (generate-new-buffer-name " *temp*"))))
 296          (unwind-protect
 297              (with-current-buffer (, temp-buffer)
 298                (,@ forms))
 299            (and (buffer-name (, temp-buffer))
 300                 (kill-buffer (, temp-buffer))))))))
 301
 302 ;; imported from Emacs 20.3.
 303 (defun-maybe last (x &optional n)
 304   "Return the last link of the list X.  Its car is the last element.
 305 If X is nil, return nil.
 306 If N is non-nil, return the Nth-to-last link of X.
 307 If N is bigger than the length of X, return X."
 308   (if n
 309       (let ((m 0) (p x))
 310         (while (consp p)
 311           (setq m (1+ m) p (cdr p)))
 312         (if (<= n 0) p
 313           (if (< n m) (nthcdr (- m n) x) x)))
 314     (while (cdr x)
 315       (setq x (cdr x)))
 316     x))
 317
 318 ;; imported from Emacs 20.3. (cl function)
 319 (defun-maybe butlast (x &optional n)
 320   "Returns a copy of LIST with the last N elements removed."
 321   (if (and n (<= n 0)) x
 322     (nbutlast (copy-sequence x) n)))
 323
 324 ;; imported from Emacs 20.3. (cl function)
 325 (defun-maybe nbutlast (x &optional n)
 326   "Modifies LIST to remove the last N elements."
 327   (let ((m (length x)))
 328     (or n (setq n 1))
 329     (and (< n m)
 330          (progn
 331            (if (> n 0) (setcdr (nthcdr (- (1- m) n) x) nil))
 332            x))))
 333
 334 ;; imported from XEmacs 21.
 335 (defun-maybe split-string (string &optional pattern)
 336   "Return a list of substrings of STRING which are separated by PATTERN.
 337 If PATTERN is omitted, it defaults to \"[ \\f\\t\\n\\r\\v]+\"."
 338   (or pattern
 339       (setq pattern "[ \f\t\n\r\v]+"))
 340   ;; The FSF version of this function takes care not to cons in case
 341   ;; of infloop.  Maybe we should synch?
 342   (let (parts (start 0))
 343     (while (string-match pattern string start)
 344       (setq parts (cons (substring string start (match-beginning 0)) parts)
 345             start (match-end 0)))
 346     (nreverse (cons (substring string start) parts))))
 347
 348
 349 ;;; @ Emacs 20.3 emulation
 350 ;;;
 351
 352 ;; imported from Emacs 20.3.91.
 353 (defvar-maybe temporary-file-directory
 354   (file-name-as-directory
 355    (cond ((memq system-type '(ms-dos windows-nt))
 356           (or (getenv "TEMP") (getenv "TMPDIR") (getenv "TMP") "c:/temp"))
 357          ((memq system-type '(vax-vms axp-vms))
 358           (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "SYS$SCRATCH:"))
 359          (t
 360           (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "/tmp"))))
 361   "The directory for writing temporary files.")
 362
 363 (defun-maybe line-beginning-position (&optional n)
 364   "Return the character position of the first character on the current line.
 365 With argument N not nil or 1, move forward N - 1 lines first.
 366 If scan reaches end of buffer, return that position.
 367 This function does not move point."
 368   (save-excursion
 369     (if n
 370         (forward-line (1- n))
 371       )
 372     (beginning-of-line)
 373     (point)))
 374
 375 (defun-maybe line-end-position (&optional n)
 376   "Return the character position of the last character on the current line.
 377 With argument N not nil or 1, move forward N - 1 lines first.
 378 If scan reaches end of buffer, return that position.
 379 This function does not move point."
 380   (save-excursion
 381     (if n
 382         (forward-line (1- n))
 383       )
 384     (end-of-line)
 385     (point)))
 386
 387 (defun-maybe string (&rest chars)
 388   "Concatenate all the argument characters and make the result a string."
 389   (mapconcat (function char-to-string) chars "")
 390   )
 391
 392
 393 ;;; @ XEmacs emulation
 394 ;;;
 395
 396 (defun-maybe find-face (face-or-name)
 397   "Retrieve the face of the given name.
 398 If FACE-OR-NAME is a face object, it is simply returned.
 399 Otherwise, FACE-OR-NAME should be a symbol.  If there is no such face,
 400 nil is returned.  Otherwise the associated face object is returned.
 401 \[XEmacs emulating function]"
 402   (car (memq face-or-name (face-list)))
 403   )
 404
 405 (defun-maybe point-at-bol (&optional n buffer)
 406   "Return the character position of the first character on the current line.
 407 With argument N not nil or 1, move forward N - 1 lines first.
 408 If scan reaches end of buffer, return that position.
 409 This function does not move point. [XEmacs emulating function]"
 410   (save-excursion
 411     (if buffer
 412         (set-buffer buffer)
 413       )
 414     (line-beginning-position n)
 415     ))
 416
 417 (defun-maybe point-at-eol (&optional n buffer)
 418   "Return the character position of the last character on the current line.
 419 With argument N not nil or 1, move forward N - 1 lines first.
 420 If scan reaches end of buffer, return that position.
 421 This function does not move point. [XEmacs emulating function]"
 422   (save-excursion
 423     (if buffer
 424         (set-buffer buffer)
 425       )
 426     (line-end-position n)
 427     ))
 428
 429 (defun-maybe functionp (obj)
 430   "Returns t if OBJ is a function, nil otherwise.
 431 \[XEmacs emulating function]"
 432   (or (subrp obj)
 433       (byte-code-function-p obj)
 434       (and (symbolp obj)(fboundp obj))
 435       (and (consp obj)(eq (car obj) 'lambda))
 436       ))
 437
 438 (defsubst-maybe define-obsolete-function-alias (oldfun newfun)
 439   "Define OLDFUN as an obsolete alias for function NEWFUN.
 440 This makes calling OLDFUN equivalent to calling NEWFUN and marks OLDFUN
 441 as obsolete. [XEmacs emulating function]"
 442   (defalias oldfun newfun)
 443   (make-obsolete oldfun newfun)
 444   )
 445
 446
 447 ;;; @ end
 448 ;;;
 449
 450 (provide 'poe)
 451
 452 ;;; poe.el ends here