mel-b.el

   1 ;;; mel-b.el: Base64 encoder/decoder for GNU Emacs
   2
   3 ;; Copyright (C) 1992,1995,1996,1997,1998 Free Software Foundation, Inc.
   4
   5 ;; Author: ENAMI Tsugutomo <enami@sys.ptg.sony.co.jp>
   6 ;;         MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; Created: 1995/6/24
   8 ;; Keywords: MIME, Base64
   9
  10 ;; This file is part of MEL (MIME Encoding Library).
  11
  12 ;; This program is free software; you can redistribute it and/or
  13 ;; modify it under the terms of the GNU General Public License as
  14 ;; published by the Free Software Foundation; either version 2, or (at
  15 ;; your option) any later version.
  16
  17 ;; This program is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Code:
  28
  29 (require 'emu)
  30
  31
  32 ;;; @ variables
  33 ;;;
  34
  35 (defvar base64-external-encoder '("mmencode")
  36   "*list of base64 encoder program name and its arguments.")
  37
  38 (defvar base64-external-decoder '("mmencode" "-u")
  39   "*list of base64 decoder program name and its arguments.")
  40
  41 (defvar base64-external-decoder-option-to-specify-file '("-o")
  42   "*list of options of base64 decoder program to specify file.")
  43
  44 (defvar base64-internal-encoding-limit 1000
  45   "*limit size to use internal base64 encoder.
  46 If size of input to encode is larger than this limit,
  47 external encoder is called.")
  48
  49 (defvar base64-internal-decoding-limit 1000
  50   "*limit size to use internal base64 decoder.
  51 If size of input to decode is larger than this limit,
  52 external decoder is called.")
  53
  54
  55 ;;; @ internal base64 decoder/encoder
  56 ;;;     based on base64 decoder by Enami Tsugutomo
  57
  58 ;;; @@ convert from/to base64 char
  59 ;;;
  60
  61 (defun base64-num-to-char (n)
  62   (cond ((eq n nil) ?=)
  63         ((< n 26) (+ ?A n))
  64         ((< n 52) (+ ?a (- n 26)))
  65         ((< n 62) (+ ?0 (- n 52)))
  66         ((= n 62) ?+)
  67         ((= n 63) ?/)
  68         (t (error "not a base64 integer %d" n))))
  69
  70 (defun base64-char-to-num (c)
  71   (cond ((and (<= ?A c) (<= c ?Z)) (- c ?A))
  72         ((and (<= ?a c) (<= c ?z)) (+ (- c ?a) 26))
  73         ((and (<= ?0 c) (<= c ?9)) (+ (- c ?0) 52))
  74         ((= c ?+) 62)
  75         ((= c ?/) 63)
  76         ((= c ?=) nil)
  77         (t (error "not a base64 character %c" c))))
  78
  79
  80 ;;; @@ encode/decode one base64 unit
  81 ;;;
  82
  83 (defun base64-encode-1 (pack)
  84   (let ((a (car pack))
  85         (b (nth 1 pack))
  86         (c (nth 2 pack)))
  87     (concat
  88      (char-to-string (base64-num-to-char (ash a -2)))
  89      (if b
  90          (concat
  91           (char-to-string
  92            (base64-num-to-char (logior (ash (logand a 3) 4) (ash b -4))))
  93           (if c
  94               (concat
  95                (char-to-string
  96                 (base64-num-to-char (logior (ash (logand b 15) 2) (ash c -6))))
  97                (char-to-string (base64-num-to-char (logand c 63)))
  98                )
  99             (concat (char-to-string
 100                      (base64-num-to-char (ash (logand b 15) 2))) "=")
 101             ))
 102        (concat (char-to-string
 103                 (base64-num-to-char (ash (logand a 3) 4))) "==")
 104        ))))
 105
 106 (defun base64-decode-unit (a b &optional c d)
 107   (condition-case err
 108       (concat
 109        (char-to-string (logior (ash (base64-char-to-num a) 2)
 110                                (ash (setq b (base64-char-to-num b)) -4)))
 111        (if (and c (setq c (base64-char-to-num c)))
 112            (concat (char-to-string
 113                     (logior (ash (logand b 15) 4) (ash c -2)))
 114                    (if (and d (setq d (base64-char-to-num d)))
 115                        (char-to-string (logior (ash (logand c 3) 6) d))
 116                      ))))
 117     (error (message (nth 1 err))
 118            "")))
 119
 120
 121 ;;; @@ base64 encoder/decoder for string
 122 ;;;
 123
 124 (defun base64-encode-string (string)
 125   "Encode STRING to base64, and return the result."
 126   (let ((len (length string))
 127         (b 0)(e 57)
 128         dest)
 129     (while (< e len)
 130       (setq dest
 131             (concat dest
 132                     (mapconcat
 133                      (function base64-encode-1)
 134                      (pack-sequence (substring string b e) 3)
 135                      "")
 136                     "\n"))
 137       (setq b e
 138             e (+ e 57)
 139             )
 140       )
 141     (let* ((es (mapconcat
 142                 (function base64-encode-1)
 143                 (pack-sequence (substring string b) 3)
 144                 ""))
 145            (m (mod (length es) 4))
 146            )
 147       (concat dest es (cond ((= m 3) "=")
 148                             ((= m 2) "==")
 149                             ))
 150       )))
 151
 152 (defun base64-internal-decode-string (string)
 153   "Decode STRING which is encoded in base64, and return the result."
 154   (let ((len (length string))
 155         (i 0)
 156         dest)
 157     (while (< i len)
 158       (let ((a (aref string i)))
 159         (setq i (1+ i))
 160         (unless (eq a ?\n)
 161           (let ((b (aref string i)))
 162             (setq i (1+ i))
 163             (cond
 164              ((eq b ?\n)
 165               ;; invalid
 166               )
 167              ((>= i len)
 168               (setq dest (concat dest (base64-decode-unit a b) ))
 169               )
 170              (t
 171               (let ((c (aref string i)))
 172                 (setq i (1+ i))
 173                 (cond
 174                  ((eq c ?\n)
 175                   (setq dest (concat dest (base64-decode-unit a b)))
 176                   )
 177                  ((>= i len)
 178                   (setq dest (concat dest (base64-decode-unit a b c)))
 179                   )
 180                  (t
 181                   (let ((d (aref string i)))
 182                     (setq i (1+ i))
 183                     (setq dest
 184                           (concat dest
 185                                   (if (eq c ?\n)
 186                                       (base64-decode-unit a b c)
 187                                     (base64-decode-unit a b c d))))
 188                     ))))))))))
 189     dest))
 190
 191 (defalias 'base64-decode-string 'base64-internal-decode-string)
 192
 193
 194 ;;; @ base64 encoder/decoder for region
 195 ;;;
 196
 197 (defun base64-internal-encode-region (beg end)
 198   (save-excursion
 199     (save-restriction
 200       (narrow-to-region beg end)
 201       (let ((str (buffer-substring beg end)))
 202         (delete-region beg end)
 203         (insert (base64-encode-string str))
 204         )
 205       (or (bolp)
 206           (insert "\n")
 207           )
 208       )))
 209
 210 (defun base64-internal-decode-region (beg end)
 211   (save-excursion
 212     (let ((str (buffer-substring beg end)))
 213       (delete-region beg end)
 214       (goto-char beg)
 215       (insert (base64-internal-decode-string str)))))
 216
 217 (defun base64-external-encode-region (beg end)
 218   (save-excursion
 219     (save-restriction
 220       (narrow-to-region beg end)
 221       (as-binary-process (apply (function call-process-region)
 222                                 beg end (car base64-external-encoder)
 223                                 t t nil (cdr base64-external-encoder))
 224                          )
 225       ;; for OS/2
 226       ;;   regularize line break code
 227       (goto-char (point-min))
 228       (while (re-search-forward "\r$" nil t)
 229         (replace-match "")
 230         )
 231       )))
 232
 233 (defun base64-external-decode-region (beg end)
 234   (save-excursion
 235     (as-binary-process (apply (function call-process-region)
 236                               beg end (car base64-external-decoder)
 237                               t t nil (cdr base64-external-decoder))
 238                        )))
 239
 240 (defun base64-encode-region (start end)
 241   "Encode current region by base64.
 242 START and END are buffer positions.
 243 This function calls internal base64 encoder if size of region is
 244 smaller than `base64-internal-encoding-limit', otherwise it calls
 245 external base64 encoder specified by `base64-external-encoder'.  In
 246 this case, you must install the program (maybe mmencode included in
 247 metamail or XEmacs package)."
 248   (interactive "r")
 249   (if (and base64-internal-encoding-limit
 250            (> (- end start) base64-internal-encoding-limit))
 251       (base64-external-encode-region start end)
 252     (base64-internal-encode-region start end)
 253     ))
 254
 255 (defun base64-decode-region (start end)
 256   "Decode current region by base64.
 257 START and END are buffer positions.
 258 This function calls internal base64 decoder if size of region is
 259 smaller than `base64-internal-decoding-limit', otherwise it calls
 260 external base64 decoder specified by `base64-external-decoder'.  In
 261 this case, you must install the program (maybe mmencode included in
 262 metamail or XEmacs package)."
 263   (interactive "r")
 264   (if (and base64-internal-decoding-limit
 265            (> (- end start) base64-internal-decoding-limit))
 266       (base64-external-decode-region start end)
 267     (base64-internal-decode-region start end)
 268     ))
 269
 270
 271 ;;; @ base64 encoder/decoder for file
 272 ;;;
 273
 274 (defun base64-insert-encoded-file (filename)
 275   "Encode contents of file FILENAME to base64, and insert the result.
 276 It calls external base64 encoder specified by
 277 `base64-external-encoder'.  So you must install the program (maybe
 278 mmencode included in metamail or XEmacs package)."
 279   (interactive (list (read-file-name "Insert encoded file: ")))
 280   (apply (function call-process) (car base64-external-encoder)
 281          filename t nil (cdr base64-external-encoder))
 282   )
 283
 284 (defun base64-write-decoded-region (start end filename)
 285   "Decode and write current region encoded by base64 into FILENAME.
 286 START and END are buffer positions."
 287   (interactive
 288    (list (region-beginning) (region-end)
 289          (read-file-name "Write decoded region to file: ")))
 290   (as-binary-process
 291    (apply (function call-process-region)
 292           start end (car base64-external-decoder)
 293           nil nil nil
 294           (append (cdr base64-external-decoder)
 295                   base64-external-decoder-option-to-specify-file
 296                   (list filename))
 297           )))
 298
 299
 300 ;;; @ etc
 301 ;;;
 302
 303 (defun base64-encoded-length (string)
 304   (let ((len (length string)))
 305     (* (+ (/ len 3)
 306           (if (= (mod len 3) 0) 0 1)
 307           ) 4)
 308     ))
 309
 310 (defun pack-sequence (seq size)
 311   "Split sequence SEQ into SIZE elements packs,
 312 and return list of packs. [mel-b; tl-seq function]"
 313   (let ((len (length seq)) (p 0) obj
 314         unit (i 0)
 315         dest)
 316     (while (< p len)
 317       (setq obj (elt seq p))
 318       (setq unit (cons obj unit))
 319       (setq i (1+ i))
 320       (if (= i size)
 321           (progn
 322             (setq dest (cons (reverse unit) dest))
 323             (setq unit nil)
 324             (setq i 0)
 325             ))
 326       (setq p (1+ p))
 327       )
 328     (if unit
 329         (setq dest (cons (reverse unit) dest))
 330       )
 331     (reverse dest)
 332     ))
 333
 334
 335 ;;; @ end
 336 ;;;
 337
 338 (provide 'mel-b)
 339
 340 ;;; mel-b.el ends here.